cgit.sxemacs.org Git - gnus/blob - lisp/gnus-nocem.el

   1 ;;; gnus-nocem.el --- NoCeM pseudo-cancellation treatment
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'nnmail)
  30 (require 'gnus-art)
  31 (require 'gnus-sum)
  32 (require 'gnus-range)
  33
  34 (defgroup gnus-nocem nil
  35   "NoCeM pseudo-cancellation treatment"
  36   :group 'gnus-score)
  37
  38 (defcustom gnus-nocem-groups
  39   '("news.lists.filters" "news.admin.net-abuse.bulletins"
  40     "alt.nocem.misc" "news.admin.net-abuse.announce")
  41   "List of groups that will be searched for NoCeM messages."
  42   :group 'gnus-nocem
  43   :type '(repeat (string :tag "Group")))
  44
  45 (defcustom gnus-nocem-issuers
  46  '("AutoMoose-1" "Automoose-1"   ; CancelMoose[tm]
  47    "rbraver@ohww.norman.ok.us"   ; Robert Braver
  48    "clewis@ferret.ocunix.on.ca;" ; Chris Lewis
  49    "jem@xpat.com;"               ; Despammer from Korea
  50    "snowhare@xmission.com"       ; Benjamin "Snowhare" Franz
  51    "red@redpoll.mrfs.oh.us (Richard E. Depew)"
  52    )
  53   "List of NoCeM issuers to pay attention to."
  54   :group 'gnus-nocem
  55   :type '(repeat string))
  56
  57 (defcustom gnus-nocem-directory
  58   (nnheader-concat gnus-article-save-directory "NoCeM/")
  59   "*Directory where NoCeM files will be stored."
  60   :group 'gnus-nocem
  61   :type 'directory)
  62
  63 (defcustom gnus-nocem-expiry-wait 15
  64   "*Number of days to keep NoCeM headers in the cache."
  65   :group 'gnus-nocem
  66   :type 'integer)
  67
  68 (defcustom gnus-nocem-verifyer 'mc-verify
  69   "*Function called to verify that the NoCeM message is valid.
  70 One likely value is `mc-verify'.  If the function in this variable
  71 isn't bound, the message will be used unconditionally."
  72   :group 'gnus-nocem
  73   :type '(radio (function-item mc-verify)
  74                 (function :tag "other")))
  75
  76 (defcustom gnus-nocem-liberal-fetch nil
  77   "*If t try to fetch all messages which have @@NCM in the subject.
  78 Otherwise don't fetch messages which have references or whose messsage-id
  79 matches an previously scanned and verified nocem message."
  80   :group 'gnus-nocem
  81   :type 'boolean)
  82
  83 ;;; Internal variables
  84
  85 (defvar gnus-nocem-active nil)
  86 (defvar gnus-nocem-alist nil)
  87 (defvar gnus-nocem-touched-alist nil)
  88 (defvar gnus-nocem-hashtb nil)
  89 (defvar gnus-nocem-seen-message-ids nil)
  90
  91 ;;; Functions
  92
  93 (defun gnus-nocem-active-file ()
  94   (concat (file-name-as-directory gnus-nocem-directory) "active"))
  95
  96 (defun gnus-nocem-cache-file ()
  97   (concat (file-name-as-directory gnus-nocem-directory) "cache"))
  98
  99 (defun gnus-nocem-scan-groups ()
 100   "Scan all NoCeM groups for new NoCeM messages."
 101   (interactive)
 102   (let ((groups gnus-nocem-groups)
 103         group active gactive articles)
 104     (gnus-make-directory gnus-nocem-directory)
 105     ;; Load any previous NoCeM headers.
 106     (gnus-nocem-load-cache)
 107     ;; Read the active file if it hasn't been read yet.
 108     (and (file-exists-p (gnus-nocem-active-file))
 109          (not gnus-nocem-active)
 110          (ignore-errors
 111            (load (gnus-nocem-active-file) t t t)))
 112     ;; Go through all groups and see whether new articles have
 113     ;; arrived.
 114     (while (setq group (pop groups))
 115       (if (not (setq gactive (gnus-activate-group group)))
 116           ()                            ; This group doesn't exist.
 117         (setq active (nth 1 (assoc group gnus-nocem-active)))
 118         (when (and (not (< (cdr gactive) (car gactive))) ; Empty group.
 119                    (or (not active)
 120                        (< (cdr active) (cdr gactive))))
 121           ;; Ok, there are new articles in this group, se we fetch the
 122           ;; headers.
 123           (save-excursion
 124             (let ((dependencies (make-vector 10 nil))
 125                   headers header)
 126               (nnheader-temp-write nil
 127                 (setq headers
 128                       (if (eq 'nov
 129                               (gnus-retrieve-headers
 130                                (setq articles
 131                                      (gnus-uncompress-range
 132                                       (cons
 133                                        (if active (1+ (cdr active))
 134                                          (car gactive))
 135                                        (cdr gactive))))
 136                                group))
 137                           (gnus-get-newsgroup-headers-xover
 138                            articles nil dependencies)
 139                         (gnus-get-newsgroup-headers dependencies)))
 140                 (while (setq header (pop headers))
 141                   ;; We take a closer look on all articles that have
 142                   ;; "@@NCM" in the subject.  Unless we already read
 143                   ;; this cross posted message.  Nocem messages
 144                   ;; are not allowed to have references, so we can
 145                   ;; ignore scanning followups.
 146                   (and (string-match "@@NCM" (mail-header-subject header))
 147                        (or gnus-nocem-liberal-fetch
 148                            (and (string= "" (mail-header-references header))
 149                                 (not (member (mail-header-message-id header)
 150                                              gnus-nocem-seen-message-ids))))
 151                        (gnus-nocem-check-article group header)))))))
 152         (setq gnus-nocem-active
 153               (cons (list group gactive)
 154                     (delq (assoc group gnus-nocem-active)
 155                           gnus-nocem-active)))))
 156     ;; Save the results, if any.
 157     (gnus-nocem-save-cache)
 158     (gnus-nocem-save-active)))
 159
 160 (defun gnus-nocem-check-article (group header)
 161   "Check whether the current article is an NCM article and that we want it."
 162   ;; Get the article.
 163   (gnus-message 7 "Checking article %d in %s for NoCeM..."
 164                 (mail-header-number header) group)
 165   (let ((date (mail-header-date header))
 166         issuer b e)
 167     (when (or (not date)
 168               (nnmail-time-less
 169                (nnmail-time-since (nnmail-date-to-time date))
 170                (nnmail-days-to-time gnus-nocem-expiry-wait)))
 171       (gnus-request-article-this-buffer (mail-header-number header) group)
 172       (goto-char (point-min))
 173       (when (re-search-forward "-----BEGIN PGP MESSAGE-----" nil t)
 174         (delete-region (point-min) (match-beginning 0)))
 175       (when (re-search-forward "-----END PGP MESSAGE-----\n?" nil t)
 176         (delete-region (match-end 0) (point-max)))
 177       (goto-char (point-min))
 178       ;; The article has to have proper NoCeM headers.
 179       (when (and (setq b (search-forward "\n@@BEGIN NCM HEADERS\n" nil t))
 180                  (setq e (search-forward "\n@@BEGIN NCM BODY\n" nil t)))
 181         ;; We get the name of the issuer.
 182         (narrow-to-region b e)
 183         (setq issuer (mail-fetch-field "issuer"))
 184         (widen)
 185         (and (member issuer gnus-nocem-issuers) ; We like her....
 186              (gnus-nocem-verify-issuer issuer) ; She is who she says she is...
 187              (gnus-nocem-enter-article) ; We gobble the message..
 188              (push (mail-header-message-id header) ; But don't come back for
 189                    gnus-nocem-seen-message-ids)))))) ; second helpings.
 190
 191 (defun gnus-nocem-verify-issuer (person)
 192   "Verify using PGP that the canceler is who she says she is."
 193   (if (fboundp gnus-nocem-verifyer)
 194       (funcall gnus-nocem-verifyer)
 195     ;; If we don't have Mailcrypt, then we use the message anyway.
 196     t))
 197
 198 (defun gnus-nocem-enter-article ()
 199   "Enter the current article into the NoCeM cache."
 200   (goto-char (point-min))
 201   (let ((b (search-forward "\n@@BEGIN NCM BODY\n" nil t))
 202         (e (search-forward "\n@@END NCM BODY\n" nil t))
 203         (buf (current-buffer))
 204         ncm id group)
 205     (when (and b e)
 206       (narrow-to-region b (1+ (match-beginning 0)))
 207       (goto-char (point-min))
 208       (while (search-forward "\t" nil t)
 209         (cond
 210          ((not (ignore-errors
 211                  (setq group (let ((obarray gnus-active-hashtb)) (read buf)))))
 212           ;; An error.
 213           )
 214          ((not (symbolp group))
 215           ;; Ignore invalid entries.
 216           )
 217          ((not (boundp group))
 218           ;; Make sure all entries in the hashtb are bound.
 219           (set group nil))
 220          (t
 221           (when (gnus-gethash (symbol-name group) gnus-newsrc-hashtb)
 222             ;; Valid group.
 223             (beginning-of-line)
 224             (while (= (following-char) ?\t)
 225               (forward-line -1))
 226             (setq id (buffer-substring (point) (1- (search-forward "\t"))))
 227             (unless (gnus-gethash id gnus-nocem-hashtb)
 228               ;; only store if not already present
 229               (gnus-sethash id t gnus-nocem-hashtb)
 230               (push id ncm))
 231             (forward-line 1)
 232             (while (= (following-char) ?\t)
 233               (forward-line 1))))))
 234       (when ncm
 235         (setq gnus-nocem-touched-alist t)
 236         (push (cons (let ((time (current-time))) (setcdr (cdr time) nil) time)
 237                     ncm)
 238               gnus-nocem-alist))
 239       t)))
 240
 241 (defun gnus-nocem-load-cache ()
 242   "Load the NoCeM cache."
 243   (unless gnus-nocem-alist
 244     ;; The buffer doesn't exist, so we create it and load the NoCeM
 245     ;; cache.
 246     (when (file-exists-p (gnus-nocem-cache-file))
 247       (load (gnus-nocem-cache-file) t t t)
 248       (gnus-nocem-alist-to-hashtb))))
 249
 250 (defun gnus-nocem-save-cache ()
 251   "Save the NoCeM cache."
 252   (when (and gnus-nocem-alist
 253              gnus-nocem-touched-alist)
 254     (nnheader-temp-write (gnus-nocem-cache-file)
 255       (gnus-prin1 `(setq gnus-nocem-alist ',gnus-nocem-alist)))
 256     (setq gnus-nocem-touched-alist nil)))
 257
 258 (defun gnus-nocem-save-active ()
 259   "Save the NoCeM active file."
 260   (nnheader-temp-write (gnus-nocem-active-file)
 261     (gnus-prin1 `(setq gnus-nocem-active ',gnus-nocem-active))))
 262
 263 (defun gnus-nocem-alist-to-hashtb ()
 264   "Create a hashtable from the Message-IDs we have."
 265   (let* ((alist gnus-nocem-alist)
 266          (pprev (cons nil alist))
 267          (prev pprev)
 268          (expiry (nnmail-days-to-time gnus-nocem-expiry-wait))
 269          entry)
 270     (setq gnus-nocem-hashtb (gnus-make-hashtable (* (length alist) 51)))
 271     (while (setq entry (car alist))
 272       (if (not (nnmail-time-less (nnmail-time-since (car entry)) expiry))
 273           ;; This entry has expired, so we remove it.
 274           (setcdr prev (cdr alist))
 275         (setq prev alist)
 276         ;; This is ok, so we enter it into the hashtable.
 277         (setq entry (cdr entry))
 278         (while entry
 279           (gnus-sethash (car entry) t gnus-nocem-hashtb)
 280           (setq entry (cdr entry))))
 281       (setq alist (cdr alist)))))
 282
 283 (gnus-add-shutdown 'gnus-nocem-close 'gnus)
 284
 285 (defun gnus-nocem-close ()
 286   "Clear internal NoCeM variables."
 287   (setq gnus-nocem-alist nil
 288         gnus-nocem-hashtb nil
 289         gnus-nocem-active nil
 290         gnus-nocem-touched-alist nil
 291         gnus-nocem-seen-message-ids nil))
 292
 293 (defun gnus-nocem-unwanted-article-p (id)
 294   "Say whether article ID in the current group is wanted."
 295   (gnus-gethash id gnus-nocem-hashtb))
 296
 297 (provide 'gnus-nocem)
 298
 299 ;;; gnus-nocem.el ends here