cgit.sxemacs.org Git - gnus/blob - lisp/gnus-nocem.el

   1 ;;; gnus-nocem.el --- NoCeM pseudo-cancellation treatment
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'nnmail)
  30 (require 'gnus-art)
  31 (require 'gnus-range)
  32
  33 (defvar gnus-nocem-groups
  34   '("alt.nocem.misc" "news.admin.net-abuse.announce")
  35   "*List of groups that will be searched for NoCeM messages.")
  36
  37 (defvar gnus-nocem-issuers
  38   '("Automoose-1" ; The CancelMoose[tm] on autopilot.
  39     "clewis@ferret.ocunix.on.ca;" ; Chris Lewis -- Canadian angel & despammer.
  40     "jem@xpat.com;"  ; John Milburn -- despammer in Korea.
  41     "red@redpoll.mrfs.oh.us (Richard E. Depew)" ; Spew/bincancel guy.
  42     )
  43   "*List of NoCeM issuers to pay attention to.")
  44
  45 (defvar gnus-nocem-directory
  46   (concat (file-name-as-directory gnus-article-save-directory) "NoCeM/")
  47   "*Directory where NoCeM files will be stored.")
  48
  49 (defvar gnus-nocem-expiry-wait 15
  50   "*Number of days to keep NoCeM headers in the cache.")
  51
  52 (defvar gnus-nocem-verifyer nil
  53   "*Function called to verify that the NoCeM message is valid.
  54 One likely value is `mc-verify'.  If the function in this variable
  55 isn't bound, the message will be used unconditionally.")
  56
  57 ;;; Internal variables
  58
  59 (defvar gnus-nocem-active nil)
  60 (defvar gnus-nocem-alist nil)
  61 (defvar gnus-nocem-touched-alist nil)
  62 (defvar gnus-nocem-hashtb nil)
  63
  64 ;;; Functions
  65
  66 (defun gnus-nocem-active-file ()
  67   (concat (file-name-as-directory gnus-nocem-directory) "active"))
  68
  69 (defun gnus-nocem-cache-file ()
  70   (concat (file-name-as-directory gnus-nocem-directory) "cache"))
  71
  72 (defun gnus-nocem-scan-groups ()
  73   "Scan all NoCeM groups for new NoCeM messages."
  74   (interactive)
  75   (let ((groups gnus-nocem-groups)
  76         group active gactive articles)
  77     (or (file-exists-p gnus-nocem-directory)
  78         (make-directory gnus-nocem-directory t))
  79     ;; Load any previous NoCeM headers.
  80     (gnus-nocem-load-cache)
  81     ;; Read the active file if it hasn't been read yet.
  82     (and (file-exists-p (gnus-nocem-active-file))
  83          (not gnus-nocem-active)
  84          (condition-case ()
  85              (load (gnus-nocem-active-file) t t t)
  86            (error nil)))
  87     ;; Go through all groups and see whether new articles have
  88     ;; arrived.
  89     (while (setq group (pop groups))
  90       (if (not (setq gactive (gnus-activate-group group)))
  91           () ; This group doesn't exist.
  92         (setq active (nth 1 (assoc group gnus-nocem-active)))
  93         (when (and (not (< (cdr gactive) (car gactive))) ; Empty group.
  94                    (or (not active)
  95                        (< (cdr active) (cdr gactive))))
  96           ;; Ok, there are new articles in this group, se we fetch the
  97           ;; headers.
  98           (save-excursion
  99             (let ((dependencies (make-vector 10 nil))
 100                   (buffer (nnheader-set-temp-buffer " *Gnus NoCeM*"))
 101                   headers)
 102               (setq headers
 103                     (if (eq 'nov
 104                             (gnus-retrieve-headers
 105                              (setq articles
 106                                    (gnus-uncompress-range
 107                                     (cons
 108                                      (if active (1+ (cdr active))
 109                                        (car gactive))
 110                                      (cdr gactive))))
 111                              group))
 112                         (gnus-get-newsgroup-headers-xover
 113                          articles nil dependencies)
 114                       (gnus-get-newsgroup-headers dependencies)))
 115               (while headers
 116                 ;; We take a closer look on all articles that have
 117                 ;; "@@NCM" in the subject.
 118                 (when (string-match "@@NCM"
 119                                     (mail-header-subject (car headers)))
 120                   (gnus-nocem-check-article group (car headers)))
 121                 (setq headers (cdr headers)))
 122               (kill-buffer (current-buffer)))))
 123         (setq gnus-nocem-active
 124               (cons (list group gactive)
 125                     (delq (assoc group gnus-nocem-active)
 126                           gnus-nocem-active)))))
 127     ;; Save the results, if any.
 128     (gnus-nocem-save-cache)
 129     (gnus-nocem-save-active)))
 130
 131 (defun gnus-nocem-check-article (group header)
 132   "Check whether the current article is an NCM article and that we want it."
 133   ;; Get the article.
 134   (gnus-message 7 "Checking article %d in %s for NoCeM..."
 135                 (mail-header-number header) group)
 136   (let ((date (mail-header-date header))
 137         issuer b e)
 138     (when (or (not date)
 139               (nnmail-time-less
 140                (nnmail-time-since (nnmail-date-to-time date))
 141                (nnmail-days-to-time gnus-nocem-expiry-wait)))
 142       (gnus-request-article-this-buffer (mail-header-number header) group)
 143       (goto-char (point-min))
 144       ;; The article has to have proper NoCeM headers.
 145       (when (and (setq b (search-forward "\n@@BEGIN NCM HEADERS\n" nil t))
 146                  (setq e (search-forward "\n@@BEGIN NCM BODY\n" nil t)))
 147         ;; We get the name of the issuer.
 148         (narrow-to-region b e)
 149         (setq issuer (mail-fetch-field "issuer"))
 150         (and (member issuer gnus-nocem-issuers) ; We like her...
 151              (gnus-nocem-verify-issuer issuer) ; She is who she says she is..
 152              (gnus-nocem-enter-article)))))) ; We gobble the message.
 153
 154 (defun gnus-nocem-verify-issuer (person)
 155   "Verify using PGP that the canceler is who she says she is."
 156   (widen)
 157   (if (fboundp gnus-nocem-verifyer)
 158       (funcall gnus-nocem-verifyer)
 159     ;; If we don't have MailCrypt, then we use the message anyway.
 160     t))
 161
 162 (defun gnus-nocem-enter-article ()
 163   "Enter the current article into the NoCeM cache."
 164   (goto-char (point-min))
 165   (let ((b (search-forward "\n@@BEGIN NCM BODY\n" nil t))
 166         (e (search-forward "\n@@END NCM BODY\n" nil t))
 167         (buf (current-buffer))
 168         ncm id)
 169     (when (and b e)
 170       (narrow-to-region b (1+ (match-beginning 0)))
 171       (goto-char (point-min))
 172       (while (search-forward "\t" nil t)
 173         (when (condition-case nil
 174                   (boundp (let ((obarray gnus-active-hashtb)) (read buf)))
 175                 (error nil))
 176           (beginning-of-line)
 177           (while (= (following-char) ?\t)
 178             (forward-line -1))
 179           (setq id (buffer-substring (point) (1- (search-forward "\t"))))
 180           (push id ncm)
 181           (gnus-sethash id t gnus-nocem-hashtb)
 182           (forward-line 1)
 183           (while (= (following-char) ?\t)
 184             (forward-line 1))))
 185       (when ncm
 186         (setq gnus-nocem-touched-alist t)
 187         (push (cons (let ((time (current-time))) (setcdr (cdr time) nil) time)
 188                     ncm)
 189               gnus-nocem-alist)))))
 190
 191 (defun gnus-nocem-load-cache ()
 192   "Load the NoCeM cache."
 193   (unless gnus-nocem-alist
 194     ;; The buffer doesn't exist, so we create it and load the NoCeM
 195     ;; cache.
 196     (when (file-exists-p (gnus-nocem-cache-file))
 197       (load (gnus-nocem-cache-file) t t t)
 198       (gnus-nocem-alist-to-hashtb))))
 199
 200 (defun gnus-nocem-save-cache ()
 201   "Save the NoCeM cache."
 202   (when (and gnus-nocem-alist
 203              gnus-nocem-touched-alist)
 204     (nnheader-temp-write (gnus-nocem-cache-file)
 205       (prin1 `(setq gnus-nocem-alist ',gnus-nocem-alist) (current-buffer)))
 206     (setq gnus-nocem-touched-alist nil)))
 207
 208 (defun gnus-nocem-save-active ()
 209   "Save the NoCeM active file."
 210   (nnheader-temp-write (gnus-nocem-active-file)
 211     (prin1 `(setq gnus-nocem-active ',gnus-nocem-active) (current-buffer))))
 212
 213 (defun gnus-nocem-alist-to-hashtb ()
 214   "Create a hashtable from the Message-IDs we have."
 215   (let* ((alist gnus-nocem-alist)
 216          (pprev (cons nil alist))
 217          (prev pprev)
 218          (expiry (nnmail-days-to-time gnus-nocem-expiry-wait))
 219          entry)
 220     (setq gnus-nocem-hashtb (gnus-make-hashtable (* (length alist) 51)))
 221     (while (setq entry (car alist))
 222       (if (not (nnmail-time-less (nnmail-time-since (car entry)) expiry))
 223           ;; This entry has expired, so we remove it.
 224           (setcdr prev (cdr alist))
 225         (setq prev alist)
 226         ;; This is ok, so we enter it into the hashtable.
 227         (setq entry (cdr entry))
 228         (while entry
 229           (gnus-sethash (car entry) t gnus-nocem-hashtb)
 230           (setq entry (cdr entry))))
 231       (setq alist (cdr alist)))))
 232
 233 (gnus-add-shutdown 'gnus-nocem-close 'gnus)
 234
 235 (defun gnus-nocem-close ()
 236   "Clear internal NoCeM variables."
 237   (setq gnus-nocem-alist nil
 238         gnus-nocem-hashtb nil
 239         gnus-nocem-active nil
 240         gnus-nocem-touched-alist nil))
 241
 242 (defun gnus-nocem-unwanted-article-p (id)
 243   "Say whether article ID in the current group is wanted."
 244   (gnus-gethash id gnus-nocem-hashtb))
 245
 246 (provide 'gnus-nocem)
 247
 248 ;;; gnus-nocem.el ends here