cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-ems)
  31 (require 'message)
  32 (require 'gnus-art)
  33
  34 ;; Added by Sudish Joseph <joseph@cis.ohio-state.edu>.
  35 (defvar gnus-post-method nil
  36   "*Preferred method for posting USENET news.
  37 If this variable is nil, Gnus will use the current method to decide
  38 which method to use when posting.  If it is non-nil, it will override
  39 the current method.  This method will not be used in mail groups and
  40 the like, only in \"real\" newsgroups.
  41
  42 The value must be a valid method as discussed in the documentation of
  43 `gnus-select-method'.  It can also be a list of methods.  If that is
  44 the case, the user will be queried for what select method to use when
  45 posting.")
  46
  47 (defvar gnus-outgoing-message-group nil
  48   "*All outgoing messages will be put in this group.
  49 If you want to store all your outgoing mail and articles in the group
  50 \"nnml:archive\", you set this variable to that value.  This variable
  51 can also be a list of group names.
  52
  53 If you want to have greater control over what group to put each
  54 message in, you can set this variable to a function that checks the
  55 current newsgroup name and then returns a suitable group name (or list
  56 of names).")
  57
  58 (defvar gnus-mailing-list-groups nil
  59   "*Regexp matching groups that are really mailing lists.
  60 This is useful when you're reading a mailing list that has been
  61 gatewayed to a newsgroup, and you want to followup to an article in
  62 the group.")
  63
  64 (defvar gnus-sent-message-ids-file
  65   (nnheader-concat gnus-directory "Sent-Message-IDs")
  66   "File where Gnus saves a cache of sent message ids.")
  67
  68 (defvar gnus-sent-message-ids-length 1000
  69   "The number of sent Message-IDs to save.")
  70
  71 (defvar gnus-crosspost-complaint
  72   "Hi,
  73
  74 You posted the article below with the following Newsgroups header:
  75
  76 Newsgroups: %s
  77
  78 The %s group, at least, was an inappropriate recipient
  79 of this message.  Please trim your Newsgroups header to exclude this
  80 group before posting in the future.
  81
  82 Thank you.
  83
  84 "
  85   "Format string to be inserted when complaining about crossposts.
  86 The first %s will be replaced by the Newsgroups header;
  87 the second with the current group name.")
  88
  89 (defvar gnus-message-setup-hook nil
  90   "Hook run after setting up a message buffer.")
  91
  92 ;;; Internal variables.
  93
  94 (defvar gnus-message-buffer "*Mail Gnus*")
  95 (defvar gnus-article-copy nil)
  96 (defvar gnus-last-posting-server nil)
  97
  98 (defconst gnus-bug-message
  99   "Sending a bug report to the Gnus Towers.
 100 ========================================
 101
 102 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 103 be sent to the Gnus Bug Exterminators.
 104
 105 At the bottom of the buffer you'll see lots of variable settings.
 106 Please do not delete those.  They will tell the Bug People what your
 107 environment is, so that it will be easier to locate the bugs.
 108
 109 If you have found a bug that makes Emacs go \"beep\", set
 110 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 111 and include the backtrace in your bug report.
 112
 113 Please describe the bug in annoying, painstaking detail.
 114
 115 Thank you for your help in stamping out bugs.
 116 ")
 117
 118 (eval-and-compile
 119   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 120   (autoload 'news-setup "rnewspost")
 121   (autoload 'news-reply-mode "rnewspost")
 122   (autoload 'rmail-dont-reply-to "mail-utils")
 123   (autoload 'rmail-output "rmailout"))
 124
 125 \f
 126 ;;;
 127 ;;; Gnus Posting Functions
 128 ;;;
 129
 130 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 131   "p" gnus-summary-post-news
 132   "f" gnus-summary-followup
 133   "F" gnus-summary-followup-with-original
 134   "c" gnus-summary-cancel-article
 135   "s" gnus-summary-supersede-article
 136   "r" gnus-summary-reply
 137   "R" gnus-summary-reply-with-original
 138   "w" gnus-summary-wide-reply
 139   "W" gnus-summary-wide-reply-with-original
 140   "n" gnus-summary-followup-to-mail
 141   "N" gnus-summary-followup-to-mail-with-original
 142   "m" gnus-summary-mail-other-window
 143   "u" gnus-uu-post-news
 144   "\M-c" gnus-summary-mail-crosspost-complaint
 145   "om" gnus-summary-mail-forward
 146   "op" gnus-summary-post-forward
 147   "Om" gnus-uu-digest-mail-forward
 148   "Op" gnus-uu-digest-post-forward)
 149
 150 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 151   "b" gnus-summary-resend-bounced-mail
 152   ;; "c" gnus-summary-send-draft
 153   "r" gnus-summary-resend-message)
 154
 155 ;;; Internal functions.
 156
 157 (defvar gnus-article-reply nil)
 158 (defmacro gnus-setup-message (config &rest forms)
 159   (let ((winconf (make-symbol "winconf"))
 160         (buffer (make-symbol "buffer"))
 161         (article (make-symbol "article")))
 162     `(let ((,winconf (current-window-configuration))
 163            (,buffer (buffer-name (current-buffer)))
 164            (,article (and gnus-article-reply (gnus-summary-article-number)))
 165            (message-header-setup-hook
 166             (copy-sequence message-header-setup-hook)))
 167        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 168        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 169        (unwind-protect
 170            ,@forms
 171          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 172          (setq gnus-message-buffer (current-buffer))
 173          (make-local-variable 'gnus-newsgroup-name)
 174          (run-hooks 'gnus-message-setup-hook))
 175        (gnus-configure-windows ,config t))))
 176
 177 (defun gnus-inews-add-send-actions (winconf buffer article)
 178   (make-local-hook 'message-sent-hook)
 179   (gnus-add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 180   (setq message-post-method
 181         `(lambda (arg)
 182            (gnus-post-method arg ,gnus-newsgroup-name)))
 183   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 184   (message-add-action
 185    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 186   (message-add-action
 187    `(when (buffer-name (get-buffer ,buffer))
 188       (save-excursion
 189         (set-buffer (get-buffer ,buffer))
 190         ,(when article
 191            `(gnus-summary-mark-article-as-replied ,article))))
 192    'send))
 193
 194 (put 'gnus-setup-message 'lisp-indent-function 1)
 195 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 196
 197 ;;; Post news commands of Gnus group mode and summary mode
 198
 199 (defun gnus-group-mail ()
 200   "Start composing a mail."
 201   (interactive)
 202   (gnus-setup-message 'message
 203     (message-mail)))
 204
 205 (defun gnus-group-post-news (&optional arg)
 206   "Start composing a news message.
 207 If ARG, post to the group under point.
 208 If ARG is 1, prompt for a group name."
 209   (interactive "P")
 210   ;; Bind this variable here to make message mode hooks
 211   ;; work ok.
 212   (let ((gnus-newsgroup-name
 213          (if arg
 214              (if (= 1 (prefix-numeric-value arg))
 215                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 216                                   (gnus-read-active-file-p))
 217                (gnus-group-group-name))
 218            "")))
 219     (gnus-post-news 'post gnus-newsgroup-name)))
 220
 221 (defun gnus-summary-post-news ()
 222   "Start composing a news message."
 223   (interactive)
 224   (gnus-set-global-variables)
 225   (gnus-post-news 'post gnus-newsgroup-name))
 226
 227 (defun gnus-summary-followup (yank &optional force-news)
 228   "Compose a followup to an article.
 229 If prefix argument YANK is non-nil, original article is yanked automatically."
 230   (interactive
 231    (list (and current-prefix-arg
 232               (gnus-summary-work-articles 1))))
 233   (gnus-set-global-variables)
 234   (when yank
 235     (gnus-summary-goto-subject (car yank)))
 236   (save-window-excursion
 237     (gnus-summary-select-article))
 238   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 239         (gnus-newsgroup-name gnus-newsgroup-name))
 240     ;; Send a followup.
 241     (gnus-post-news nil gnus-newsgroup-name
 242                     headers gnus-article-buffer
 243                     yank nil force-news)))
 244
 245 (defun gnus-summary-followup-with-original (n &optional force-news)
 246   "Compose a followup to an article and include the original article."
 247   (interactive "P")
 248   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 249
 250 (defun gnus-summary-followup-to-mail (&optional arg)
 251   "Followup to the current mail message via news."
 252   (interactive
 253    (list (and current-prefix-arg
 254               (gnus-summary-work-articles 1))))
 255   (gnus-summary-followup arg t))
 256
 257 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 258   "Followup to the current mail message via news."
 259   (interactive "P")
 260   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 261
 262 (defun gnus-inews-yank-articles (articles)
 263   (let (beg article)
 264     (message-goto-body)
 265     (while (setq article (pop articles))
 266       (save-window-excursion
 267         (set-buffer gnus-summary-buffer)
 268         (gnus-summary-select-article nil nil nil article)
 269         (gnus-summary-remove-process-mark article))
 270       (gnus-copy-article-buffer)
 271       (let ((message-reply-buffer gnus-article-copy)
 272             (message-reply-headers gnus-current-headers))
 273         (message-yank-original)
 274         (setq beg (or beg (mark t))))
 275       (when articles
 276         (insert "\n")))
 277     (push-mark)
 278     (goto-char beg)))
 279
 280 (defun gnus-summary-cancel-article (n)
 281   "Cancel an article you posted."
 282   (interactive "P")
 283   (gnus-set-global-variables)
 284   (let ((articles (gnus-summary-work-articles n))
 285         (message-post-method
 286          `(lambda (arg)
 287             (gnus-post-method nil ,gnus-newsgroup-name)))
 288         article)
 289     (while (setq article (pop articles))
 290       (when (gnus-summary-select-article t nil nil article)
 291         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 292                 (message-cancel-news))
 293           (gnus-summary-mark-as-read article gnus-canceled-mark)
 294           (gnus-cache-remove-article 1))
 295         (gnus-article-hide-headers-if-wanted))
 296       (gnus-summary-remove-process-mark article))))
 297
 298 (defun gnus-summary-supersede-article ()
 299   "Compose an article that will supersede a previous article.
 300 This is done simply by taking the old article and adding a Supersedes
 301 header line with the old Message-ID."
 302   (interactive)
 303   (gnus-set-global-variables)
 304   (let ((article (gnus-summary-article-number)))
 305     (gnus-setup-message 'reply-yank
 306       (gnus-summary-select-article t)
 307       (set-buffer gnus-original-article-buffer)
 308       (message-supersede)
 309       (push
 310        `((lambda ()
 311            (gnus-cache-possibly-remove-article ,article nil nil nil t)))
 312        message-send-actions)
 313       (push
 314        `((lambda ()
 315            (when (buffer-name (get-buffer ,gnus-summary-buffer))
 316              (save-excursion
 317                (set-buffer (get-buffer ,gnus-summary-buffer))
 318                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 319        message-send-actions))))
 320
 321 \f
 322
 323 (defun gnus-copy-article-buffer (&optional article-buffer)
 324   ;; make a copy of the article buffer with all text properties removed
 325   ;; this copy is in the buffer gnus-article-copy.
 326   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 327   ;; this buffer should be passed to all mail/news reply/post routines.
 328   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 329   (buffer-disable-undo gnus-article-copy)
 330   (or (memq gnus-article-copy gnus-buffer-list)
 331       (push gnus-article-copy gnus-buffer-list))
 332   (let ((article-buffer (or article-buffer gnus-article-buffer))
 333         end beg contents)
 334     (if (not (and (get-buffer article-buffer)
 335                   (buffer-name (get-buffer article-buffer))))
 336         (error "Can't find any article buffer")
 337       (save-excursion
 338         (set-buffer article-buffer)
 339         (save-restriction
 340           ;; Copy over the (displayed) article buffer, delete
 341           ;; hidden text and remove text properties.
 342           (widen)
 343           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 344           (set-buffer gnus-article-copy)
 345           (gnus-article-delete-text-of-type 'annotation)
 346           (gnus-remove-text-with-property 'gnus-prev)
 347           (gnus-remove-text-with-property 'gnus-next)
 348           (insert
 349            (prog1
 350                (format "%s" (buffer-string))
 351              (erase-buffer)))
 352           ;; Find the original headers.
 353           (set-buffer gnus-original-article-buffer)
 354           (goto-char (point-min))
 355           (while (looking-at message-unix-mail-delimiter)
 356             (forward-line 1))
 357           (setq beg (point))
 358           (setq end (or (search-forward "\n\n" nil t) (point)))
 359           ;; Delete the headers from the displayed articles.
 360           (set-buffer gnus-article-copy)
 361           (delete-region (goto-char (point-min))
 362                          (or (search-forward "\n\n" nil t) (point)))
 363           ;; Insert the original article headers.
 364           (insert-buffer-substring gnus-original-article-buffer beg end)
 365           (gnus-article-decode-rfc1522)))
 366       gnus-article-copy)))
 367
 368 (defun gnus-post-news (post &optional group header article-buffer yank subject
 369                             force-news)
 370   (when article-buffer
 371     (gnus-copy-article-buffer))
 372   (let ((gnus-article-reply article-buffer))
 373     (gnus-setup-message (cond (yank 'reply-yank)
 374                               (article-buffer 'reply)
 375                               (t 'message))
 376       (let* ((group (or group gnus-newsgroup-name))
 377              (pgroup group)
 378              to-address to-group mailing-list to-list
 379              newsgroup-p)
 380         (when group
 381           (setq to-address (gnus-group-find-parameter group 'to-address)
 382                 to-group (gnus-group-find-parameter group 'to-group)
 383                 to-list (gnus-group-find-parameter group 'to-list)
 384                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 385                 mailing-list (when gnus-mailing-list-groups
 386                                (string-match gnus-mailing-list-groups group))
 387                 group (gnus-group-real-name group)))
 388         (if (or (and to-group
 389                      (gnus-news-group-p to-group))
 390                 newsgroup-p
 391                 force-news
 392                 (and (gnus-news-group-p
 393                       (or pgroup gnus-newsgroup-name)
 394                       (if header (mail-header-number header)
 395                         gnus-current-article))
 396                      (not mailing-list)
 397                      (not to-list)
 398                      (not to-address)))
 399             ;; This is news.
 400             (if post
 401                 (message-news (or to-group group))
 402               (set-buffer gnus-article-copy)
 403               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 404           ;; The is mail.
 405           (if post
 406               (progn
 407                 (message-mail (or to-address to-list))
 408                 ;; Arrange for mail groups that have no `to-address' to
 409                 ;; get that when the user sends off the mail.
 410                 (push (list 'gnus-inews-add-to-address pgroup)
 411                       message-send-actions))
 412             (set-buffer gnus-article-copy)
 413             (message-wide-reply to-address)))
 414         (when yank
 415           (gnus-inews-yank-articles yank))))))
 416
 417 (defun gnus-post-method (arg group &optional silent)
 418   "Return the posting method based on GROUP and ARG.
 419 If SILENT, don't prompt the user."
 420   (let ((group-method (gnus-find-method-for-group group)))
 421     (cond
 422      ;; If the group-method is nil (which shouldn't happen) we use
 423      ;; the default method.
 424      ((null group-method)
 425       (or gnus-post-method gnus-select-method message-post-method))
 426      ;; We want this group's method.
 427      ((and arg (not (eq arg 0)))
 428       group-method)
 429      ;; We query the user for a post method.
 430      ((or arg
 431           (and gnus-post-method
 432                (listp (car gnus-post-method))))
 433       (let* ((methods
 434               ;; Collect all methods we know about.
 435               (append
 436                (when gnus-post-method
 437                  (if (listp (car gnus-post-method))
 438                      gnus-post-method
 439                    (list gnus-post-method)))
 440                gnus-secondary-select-methods
 441                (list gnus-select-method)
 442                (list group-method)))
 443              method-alist post-methods method)
 444         ;; Weed out all mail methods.
 445         (while methods
 446           (setq method (gnus-server-get-method "" (pop methods)))
 447           (when (or (gnus-method-option-p method 'post)
 448                     (gnus-method-option-p method 'post-mail))
 449             (push method post-methods)))
 450         ;; Create a name-method alist.
 451         (setq method-alist
 452               (mapcar
 453                (lambda (m)
 454                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 455                post-methods))
 456         ;; Query the user.
 457         (cadr
 458          (assoc
 459           (setq gnus-last-posting-server
 460                 (if (and silent
 461                          gnus-last-posting-server)
 462                     ;; Just use the last value.
 463                     gnus-last-posting-server
 464                   (completing-read
 465                    "Posting method: " method-alist nil t
 466                    (cons (or gnus-last-posting-server "") 0))))
 467           method-alist))))
 468      ;; Override normal method.
 469      (gnus-post-method
 470       gnus-post-method)
 471      ;; Use the normal select method.
 472      (t gnus-select-method))))
 473
 474 ;;;
 475 ;;; Check whether the message has been sent already.
 476 ;;;
 477
 478 (defvar gnus-inews-sent-ids nil)
 479
 480 (defun gnus-inews-reject-message ()
 481   "Check whether this message has already been sent."
 482   (when gnus-sent-message-ids-file
 483     (let ((message-id (save-restriction (message-narrow-to-headers)
 484                                         (mail-fetch-field "message-id")))
 485           end)
 486       (when message-id
 487         (unless gnus-inews-sent-ids
 488           (ignore-errors
 489             (load t t t)))
 490         (if (member message-id gnus-inews-sent-ids)
 491             ;; Reject this message.
 492             (not (gnus-yes-or-no-p
 493                   (format "Message %s already sent.  Send anyway? "
 494                           message-id)))
 495           (push message-id gnus-inews-sent-ids)
 496           ;; Chop off the last Message-IDs.
 497           (when (setq end (nthcdr gnus-sent-message-ids-length
 498                                   gnus-inews-sent-ids))
 499             (setcdr end nil))
 500           (nnheader-temp-write gnus-sent-message-ids-file
 501             (gnus-prin1 `(setq gnus-inews-sent-ids ',gnus-inews-sent-ids)))
 502           nil)))))
 503
 504 \f
 505
 506 ;; Dummy to avoid byte-compile warning.
 507 (defvar nnspool-rejected-article-hook)
 508
 509 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 510 ;;; as well include the Emacs version as well.
 511 ;;; The following function works with later GNU Emacs, and XEmacs.
 512 (defun gnus-extended-version ()
 513   "Stringified Gnus version and Emacs version"
 514   (interactive)
 515   (concat
 516    gnus-version
 517    "/"
 518    (cond
 519     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 520      (concat "Emacs " (substring emacs-version
 521                                  (match-beginning 1)
 522                                  (match-end 1))))
 523     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
 524                    emacs-version)
 525      (concat (substring emacs-version
 526                         (match-beginning 1)
 527                         (match-end 1))
 528              (format " %d.%d" emacs-major-version emacs-minor-version)
 529              (if (match-beginning 3)
 530                  (substring emacs-version
 531                             (match-beginning 3)
 532                             (match-end 3))
 533                "")))
 534     (t emacs-version))))
 535
 536 ;; Written by "Mr. Per Persson" <pp@gnu.ai.mit.edu>.
 537 (defun gnus-inews-insert-mime-headers ()
 538   (goto-char (point-min))
 539   (let ((mail-header-separator
 540          (progn
 541            (goto-char (point-min))
 542            (if (and (search-forward (concat "\n" mail-header-separator "\n")
 543                                     nil t)
 544                     (not (search-backward "\n\n" nil t)))
 545                mail-header-separator
 546              ""))))
 547     (or (mail-position-on-field "Mime-Version")
 548         (insert "1.0")
 549         (cond ((save-restriction
 550                  (widen)
 551                  (goto-char (point-min))
 552                  (re-search-forward "[\200-\377]" nil t))
 553                (or (mail-position-on-field "Content-Type")
 554                    (insert "text/plain; charset=ISO-8859-1"))
 555                (or (mail-position-on-field "Content-Transfer-Encoding")
 556                    (insert "8bit")))
 557               (t (or (mail-position-on-field "Content-Type")
 558                      (insert "text/plain; charset=US-ASCII"))
 559                  (or (mail-position-on-field "Content-Transfer-Encoding")
 560                      (insert "7bit")))))))
 561
 562 \f
 563 ;;;
 564 ;;; Gnus Mail Functions
 565 ;;;
 566
 567 ;;; Mail reply commands of Gnus summary mode
 568
 569 (defun gnus-summary-reply (&optional yank wide)
 570   "Start composing a reply mail to the current message.
 571 If prefix argument YANK is non-nil, the original article is yanked
 572 automatically."
 573   (interactive
 574    (list (and current-prefix-arg
 575               (gnus-summary-work-articles 1))))
 576   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 577   (gnus-set-global-variables)
 578   (when yank
 579     (gnus-summary-goto-subject (car yank)))
 580   (let ((gnus-article-reply t))
 581     (gnus-setup-message (if yank 'reply-yank 'reply)
 582       (gnus-summary-select-article)
 583       (set-buffer (gnus-copy-article-buffer))
 584       (message-reply nil wide (gnus-group-find-parameter
 585                                gnus-newsgroup-name 'broken-reply-to))
 586       (when yank
 587         (gnus-inews-yank-articles yank)))))
 588
 589 (defun gnus-summary-reply-with-original (n &optional wide)
 590   "Start composing a reply mail to the current message.
 591 The original article will be yanked."
 592   (interactive "P")
 593   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 594
 595 (defun gnus-summary-wide-reply (&optional yank)
 596   "Start composing a wide reply mail to the current message.
 597 If prefix argument YANK is non-nil, the original article is yanked
 598 automatically."
 599   (interactive
 600    (list (and current-prefix-arg
 601               (gnus-summary-work-articles 1))))
 602   (gnus-summary-reply yank t))
 603
 604 (defun gnus-summary-wide-reply-with-original (n)
 605   "Start composing a wide reply mail to the current message.
 606 The original article will be yanked."
 607   (interactive "P")
 608   (gnus-summary-reply-with-original n t))
 609
 610 (defun gnus-summary-mail-forward (&optional full-headers post)
 611   "Forward the current message to another user.
 612 If FULL-HEADERS (the prefix), include full headers when forwarding."
 613   (interactive "P")
 614   (gnus-set-global-variables)
 615   (gnus-setup-message 'forward
 616     (gnus-summary-select-article)
 617     (set-buffer gnus-original-article-buffer)
 618     (let ((message-included-forward-headers
 619            (if full-headers "" message-included-forward-headers)))
 620       (message-forward post))))
 621
 622 (defun gnus-summary-resend-message (address n)
 623   "Resend the current article to ADDRESS."
 624   (interactive "sResend message(s) to: \nP")
 625   (let ((articles (gnus-summary-work-articles n))
 626         article)
 627     (while (setq article (pop articles))
 628       (gnus-summary-select-article nil nil nil article)
 629       (save-excursion
 630         (set-buffer gnus-original-article-buffer)
 631         (message-resend address)))))
 632
 633 (defun gnus-summary-post-forward (&optional full-headers)
 634   "Forward the current article to a newsgroup.
 635 If FULL-HEADERS (the prefix), include full headers when forwarding."
 636   (interactive "P")
 637   (gnus-summary-mail-forward full-headers t))
 638
 639 (defvar gnus-nastygram-message
 640   "The following article was inappropriately posted to %s.\n\n"
 641   "Format string to insert in nastygrams.
 642 The current group name will be inserted at \"%s\".")
 643
 644 (defun gnus-summary-mail-nastygram (n)
 645   "Send a nastygram to the author of the current article."
 646   (interactive "P")
 647   (when (or gnus-expert-user
 648             (gnus-y-or-n-p
 649              "Really send a nastygram to the author of the current article? "))
 650     (let ((group gnus-newsgroup-name))
 651       (gnus-summary-reply-with-original n)
 652       (set-buffer gnus-message-buffer)
 653       (message-goto-body)
 654       (insert (format gnus-nastygram-message group))
 655       (message-send-and-exit))))
 656
 657 (defun gnus-summary-mail-crosspost-complaint (n)
 658   "Send a complaint about crossposting to the current article(s)."
 659   (interactive "P")
 660   (let ((articles (gnus-summary-work-articles n))
 661         article)
 662     (while (setq article (pop articles))
 663       (set-buffer gnus-summary-buffer)
 664       (gnus-summary-goto-subject article)
 665       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 666             newsgroups followup-to)
 667         (gnus-summary-select-article)
 668         (set-buffer gnus-original-article-buffer)
 669         (if (and (<= (length (message-tokenize-header
 670                               (setq newsgroups (mail-fetch-field "newsgroups"))
 671                               ", "))
 672                      1)
 673                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 674                      (not (member group (message-tokenize-header
 675                                          followup-to ", ")))))
 676             (if followup-to
 677                 (gnus-message 1 "Followup-to restricted")
 678               (gnus-message 1 "Not a crossposted article"))
 679           (set-buffer gnus-summary-buffer)
 680           (gnus-summary-reply-with-original 1)
 681           (set-buffer gnus-message-buffer)
 682           (message-goto-body)
 683           (insert (format gnus-crosspost-complaint newsgroups group))
 684           (message-goto-subject)
 685           (re-search-forward " *$")
 686           (replace-match " (crosspost notification)" t t)
 687           (when (gnus-y-or-n-p "Send this complaint? ")
 688             (message-send-and-exit)))))))
 689
 690 (defun gnus-summary-mail-other-window ()
 691   "Compose mail in other window."
 692   (interactive)
 693   (gnus-setup-message 'message
 694     (message-mail)))
 695
 696 (defun gnus-mail-parse-comma-list ()
 697   (let (accumulated
 698         beg)
 699     (skip-chars-forward " ")
 700     (while (not (eobp))
 701       (setq beg (point))
 702       (skip-chars-forward "^,")
 703       (while (zerop
 704               (save-excursion
 705                 (save-restriction
 706                   (let ((i 0))
 707                     (narrow-to-region beg (point))
 708                     (goto-char beg)
 709                     (logand (progn
 710                               (while (search-forward "\"" nil t)
 711                                 (incf i))
 712                               (if (zerop i) 2 i))
 713                             2)))))
 714         (skip-chars-forward ",")
 715         (skip-chars-forward "^,"))
 716       (skip-chars-backward " ")
 717       (push (buffer-substring beg (point))
 718             accumulated)
 719       (skip-chars-forward "^,")
 720       (skip-chars-forward ", "))
 721     accumulated))
 722
 723 (defun gnus-inews-add-to-address (group)
 724   (let ((to-address (mail-fetch-field "to")))
 725     (when (and to-address
 726                (gnus-alive-p))
 727       ;; This mail group doesn't have a `to-list', so we add one
 728       ;; here.  Magic!
 729       (gnus-group-add-parameter group (cons 'to-list to-address)))))
 730
 731 (defun gnus-put-message ()
 732   "Put the current message in some group and return to Gnus."
 733   (interactive)
 734   (let ((reply gnus-article-reply)
 735         (winconf gnus-prev-winconf)
 736         (group gnus-newsgroup-name))
 737
 738     (or (and group (not (gnus-group-read-only-p group)))
 739         (setq group (read-string "Put in group: " nil
 740                                  (gnus-writable-groups))))
 741     (when (gnus-gethash group gnus-newsrc-hashtb)
 742       (error "No such group: %s" group))
 743
 744     (save-excursion
 745       (save-restriction
 746         (widen)
 747         (message-narrow-to-headers)
 748         (let (gnus-deletable-headers)
 749           (if (message-news-p)
 750               (message-generate-headers message-required-news-headers)
 751             (message-generate-headers message-required-mail-headers)))
 752         (goto-char (point-max))
 753         (insert "Gcc: " group "\n")
 754         (widen)))
 755
 756     (gnus-inews-do-gcc)
 757
 758     (when (get-buffer gnus-group-buffer)
 759       (when (gnus-buffer-exists-p (car-safe reply))
 760         (set-buffer (car reply))
 761         (and (cdr reply)
 762              (gnus-summary-mark-article-as-replied
 763               (cdr reply))))
 764       (when winconf
 765         (set-window-configuration winconf)))))
 766
 767 (defun gnus-article-mail (yank)
 768   "Send a reply to the address near point.
 769 If YANK is non-nil, include the original article."
 770   (interactive "P")
 771   (let ((address
 772          (buffer-substring
 773           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 774           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 775     (when address
 776       (message-reply address)
 777       (when yank
 778         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 779
 780 (defvar nntp-server-type)
 781 (defun gnus-bug ()
 782   "Send a bug report to the Gnus maintainers."
 783   (interactive)
 784   (unless (gnus-alive-p)
 785     (error "Gnus has been shut down"))
 786   (gnus-setup-message 'bug
 787     (delete-other-windows)
 788     (switch-to-buffer "*Gnus Help Bug*")
 789     (erase-buffer)
 790     (insert gnus-bug-message)
 791     (goto-char (point-min))
 792     (message-pop-to-buffer "*Gnus Bug*")
 793     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 794     (push `(gnus-bug-kill-buffer) message-send-actions)
 795     (goto-char (point-min))
 796     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 797     (forward-line 1)
 798     (insert (gnus-version) "\n")
 799     (insert (emacs-version) "\n")
 800     (when (and (boundp 'nntp-server-type)
 801                (stringp nntp-server-type))
 802       (insert nntp-server-type))
 803     (insert "\n\n\n\n\n")
 804     (gnus-debug)
 805     (goto-char (point-min))
 806     (search-forward "Subject: " nil t)
 807     (message "")))
 808
 809 (defun gnus-bug-kill-buffer ()
 810   (when (get-buffer "*Gnus Help Bug*")
 811     (kill-buffer "*Gnus Help Bug*")))
 812
 813 (defun gnus-debug ()
 814   "Attempts to go through the Gnus source file and report what variables have been changed.
 815 The source file has to be in the Emacs load path."
 816   (interactive)
 817   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 818                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 819                  "gnus-msg.el" "gnus-score.el" "gnus-win.el"
 820                  "nnmail.el" "message.el"))
 821         file expr olist sym)
 822     (gnus-message 4 "Please wait while we snoop your variables...")
 823     (sit-for 0)
 824     ;; Go through all the files looking for non-default values for variables.
 825     (save-excursion
 826       (set-buffer (get-buffer-create " *gnus bug info*"))
 827       (buffer-disable-undo (current-buffer))
 828       (while files
 829         (erase-buffer)
 830         (when (and (setq file (locate-library (pop files)))
 831                    (file-exists-p file))
 832           (insert-file-contents file)
 833           (goto-char (point-min))
 834           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 835               (gnus-message 4 "Malformed sources in file %s" file)
 836             (narrow-to-region (point-min) (point))
 837             (goto-char (point-min))
 838             (while (setq expr (ignore-errors (read (current-buffer))))
 839               (ignore-errors
 840                 (and (or (eq (car expr) 'defvar)
 841                          (eq (car expr) 'defcustom))
 842                      (stringp (nth 3 expr))
 843                      (or (not (boundp (nth 1 expr)))
 844                          (not (equal (eval (nth 2 expr))
 845                                      (symbol-value (nth 1 expr)))))
 846                      (push (nth 1 expr) olist)))))))
 847       (kill-buffer (current-buffer)))
 848     (when (setq olist (nreverse olist))
 849       (insert "------------------ Environment follows ------------------\n\n"))
 850     (while olist
 851       (if (boundp (car olist))
 852           (condition-case ()
 853               (pp `(setq ,(car olist)
 854                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 855                                   (and (symbolp sym)
 856                                        (not (or (eq sym nil)
 857                                                 (eq sym t)))))
 858                               (list 'quote (symbol-value (car olist)))
 859                             (symbol-value (car olist))))
 860                   (current-buffer))
 861             (error
 862              (format "(setq %s 'whatever)\n" (car olist))))
 863         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 864       (setq olist (cdr olist)))
 865     (insert "\n\n")
 866     ;; Remove any null chars - they seem to cause trouble for some
 867     ;; mailers.  (Byte-compiled output from the stuff above.)
 868     (goto-char (point-min))
 869     (while (re-search-forward "[\000\200]" nil t)
 870       (replace-match "" t t))))
 871
 872 ;;; Treatment of rejected articles.
 873 ;;; Bounced mail.
 874
 875 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 876   "Re-mail the current message.
 877 This only makes sense if the current message is a bounce message than
 878 contains some mail you have written which has been bounced back to
 879 you.
 880 If FETCH, try to fetch the article that this is a reply to, if indeed
 881 this is a reply."
 882   (interactive "P")
 883   (gnus-summary-select-article t)
 884   (set-buffer gnus-original-article-buffer)
 885   (gnus-setup-message 'compose-bounce
 886     (let* ((references (mail-fetch-field "references"))
 887            (parent (and references (gnus-parent-id references))))
 888       (message-bounce)
 889       ;; If there are references, we fetch the article we answered to.
 890       (and fetch parent
 891            (gnus-summary-refer-article parent)
 892            (gnus-summary-show-all-headers)))))
 893
 894 ;;; Gcc handling.
 895
 896 ;; Do Gcc handling, which copied the message over to some group.
 897 (defun gnus-inews-do-gcc (&optional gcc)
 898   (interactive)
 899   (when (gnus-alive-p)
 900     (save-excursion
 901       (save-restriction
 902         (message-narrow-to-headers)
 903         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 904               (cur (current-buffer))
 905               groups group method)
 906           (when gcc
 907             (message-remove-header "gcc")
 908             (widen)
 909             (setq groups (message-tokenize-header gcc " ,"))
 910             ;; Copy the article over to some group(s).
 911             (while (setq group (pop groups))
 912               (gnus-check-server
 913                (setq method
 914                      (cond ((and (null (gnus-get-info group))
 915                                  (eq (car gnus-message-archive-method)
 916                                      (car
 917                                       (gnus-server-to-method
 918                                        (gnus-group-method group)))))
 919                             ;; If the group doesn't exist, we assume
 920                             ;; it's an archive group...
 921                             gnus-message-archive-method)
 922                            ;; Use the method.
 923                            ((gnus-info-method (gnus-get-info group))
 924                             (gnus-info-method (gnus-get-info group)))
 925                            ;; Find the method.
 926                            (t (gnus-group-method group)))))
 927               (gnus-check-server method)
 928               (unless (gnus-request-group group t method)
 929                 (gnus-request-create-group group method))
 930               (save-excursion
 931                 (nnheader-set-temp-buffer " *acc*")
 932                 (insert-buffer-substring cur)
 933                 (goto-char (point-min))
 934                 (when (re-search-forward
 935                        (concat "^" (regexp-quote mail-header-separator) "$")
 936                        nil t)
 937                   (replace-match "" t t ))
 938                 (unless (gnus-request-accept-article group method t)
 939                   (gnus-message 1 "Couldn't store article in group %s: %s"
 940                                 group (gnus-status-message method))
 941                   (sit-for 2))
 942                 (kill-buffer (current-buffer))))))))))
 943
 944 (defun gnus-inews-insert-gcc ()
 945   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 946   (save-excursion
 947     (save-restriction
 948       (message-narrow-to-headers)
 949       (let* ((group gnus-outgoing-message-group)
 950              (gcc (cond
 951                    ((gnus-functionp group)
 952                     (funcall group))
 953                    ((or (stringp group) (list group))
 954                     group))))
 955         (when gcc
 956           (insert "Gcc: "
 957                   (if (stringp gcc) gcc
 958                     (mapconcat 'identity gcc " "))
 959                   "\n"))))))
 960
 961 (defun gnus-inews-insert-archive-gcc (&optional group)
 962   "Insert the Gcc to say where the article is to be archived."
 963   (let* ((var gnus-message-archive-group)
 964          (group (or group gnus-newsgroup-name ""))
 965          result
 966          gcc-self-val
 967          (groups
 968           (cond
 969            ((null gnus-message-archive-method)
 970             ;; Ignore.
 971             nil)
 972            ((stringp var)
 973             ;; Just a single group.
 974             (list var))
 975            ((null var)
 976             ;; We don't want this.
 977             nil)
 978            ((and (listp var) (stringp (car var)))
 979             ;; A list of groups.
 980             var)
 981            ((gnus-functionp var)
 982             ;; A function.
 983             (funcall var group))
 984            (t
 985             ;; An alist of regexps/functions/forms.
 986             (while (and var
 987                         (not
 988                          (setq result
 989                                (cond
 990                                 ((stringp (caar var))
 991                                  ;; Regexp.
 992                                  (when (string-match (caar var) group)
 993                                    (cdar var)))
 994                                 ((gnus-functionp (car var))
 995                                  ;; Function.
 996                                  (funcall (car var) group))
 997                                 (t
 998                                  (eval (car var)))))))
 999               (setq var (cdr var)))
1000             result)))
1001          name)
1002     (when groups
1003       (when (stringp groups)
1004         (setq groups (list groups)))
1005       (save-excursion
1006         (save-restriction
1007           (message-narrow-to-headers)
1008           (goto-char (point-max))
1009           (insert "Gcc: ")
1010           (if (and gnus-newsgroup-name
1011                    (setq gcc-self-val
1012                          (gnus-group-find-parameter
1013                           gnus-newsgroup-name 'gcc-self)))
1014               (progn
1015                 (insert
1016                  (if (stringp gcc-self-val)
1017                      gcc-self-val
1018                    group))
1019                 (if (not (eq gcc-self-val 'none))
1020                     (insert "\n")
1021                   (progn
1022                     (beginning-of-line)
1023                     (kill-line))))
1024             (while (setq name (pop groups))
1025               (insert (if (string-match ":" name)
1026                           name
1027                         (gnus-group-prefixed-name
1028                          name gnus-message-archive-method)))
1029               (when groups
1030                 (insert " ")))
1031             (insert "\n")))))))
1032
1033 (defun gnus-summary-send-draft ()
1034   "Enter a mail/post buffer to edit and send the draft."
1035   (interactive)
1036   (gnus-set-global-variables)
1037   (let (buf)
1038     (if (not (setq buf (gnus-request-restore-buffer
1039                         (gnus-summary-article-number) gnus-newsgroup-name)))
1040         (error "Couldn't restore the article")
1041       (switch-to-buffer buf)
1042       (when (eq major-mode 'news-reply-mode)
1043         (local-set-key "\C-c\C-c" 'gnus-inews-news))
1044       ;; Insert the separator.
1045       (goto-char (point-min))
1046       (search-forward "\n\n")
1047       (forward-char -1)
1048       (insert mail-header-separator)
1049       ;; Configure windows.
1050       (let ((gnus-draft-buffer (current-buffer)))
1051         (gnus-configure-windows 'draft t)
1052         (goto-char (point))))))
1053
1054 (gnus-add-shutdown 'gnus-inews-close 'gnus)
1055
1056 (defun gnus-inews-close ()
1057   (setq gnus-inews-sent-ids nil))
1058
1059 ;;; Allow redefinition of functions.
1060
1061 (gnus-ems-redefine)
1062
1063 (provide 'gnus-msg)
1064
1065 ;;; gnus-msg.el ends here