cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-ems)
  33 (require 'message)
  34 (require 'gnus-art)
  35
  36 (defcustom gnus-post-method nil
  37   "*Preferred method for posting USENET news.
  38
  39 If this variable is `current', Gnus will use the \"current\" select
  40 method when posting.  If it is nil (which is the default), Gnus will
  41 use the native posting method of the server.
  42
  43 This method will not be used in mail groups and the like, only in
  44 \"real\" newsgroups.
  45
  46 If not nil nor `native', the value must be a valid method as discussed
  47 in the documentation of `gnus-select-method'. It can also be a list of
  48 methods. If that is the case, the user will be queried for what select
  49 method to use when posting."
  50   :group 'gnus-group-foreign
  51   :type `(choice (const nil)
  52                  (const current)
  53                  (const native)
  54                  (sexp :tag "Methods" ,gnus-select-method)))
  55
  56 (defvar gnus-outgoing-message-group nil
  57   "*All outgoing messages will be put in this group.
  58 If you want to store all your outgoing mail and articles in the group
  59 \"nnml:archive\", you set this variable to that value.  This variable
  60 can also be a list of group names.
  61
  62 If you want to have greater control over what group to put each
  63 message in, you can set this variable to a function that checks the
  64 current newsgroup name and then returns a suitable group name (or list
  65 of names).")
  66
  67 (defvar gnus-mailing-list-groups nil
  68   "*Regexp matching groups that are really mailing lists.
  69 This is useful when you're reading a mailing list that has been
  70 gatewayed to a newsgroup, and you want to followup to an article in
  71 the group.")
  72
  73 (defvar gnus-add-to-list nil
  74   "*If non-nil, add a `to-list' parameter automatically.")
  75
  76 (defvar gnus-crosspost-complaint
  77   "Hi,
  78
  79 You posted the article below with the following Newsgroups header:
  80
  81 Newsgroups: %s
  82
  83 The %s group, at least, was an inappropriate recipient
  84 of this message.  Please trim your Newsgroups header to exclude this
  85 group before posting in the future.
  86
  87 Thank you.
  88
  89 "
  90   "Format string to be inserted when complaining about crossposts.
  91 The first %s will be replaced by the Newsgroups header;
  92 the second with the current group name.")
  93
  94 (defvar gnus-message-setup-hook nil
  95   "Hook run after setting up a message buffer.")
  96
  97 (defvar gnus-bug-create-help-buffer t
  98   "*Should we create the *Gnus Help Bug* buffer?")
  99
 100 (defvar gnus-posting-styles nil
 101   "*Alist of styles to use when posting.")
 102
 103 (defvar gnus-posting-style-alist
 104   '((organization . message-user-organization)
 105     (signature . message-signature)
 106     (signature-file . message-signature-file)
 107     (address . user-mail-address)
 108     (name . user-full-name))
 109   "*Mapping from style parameters to variables.")
 110
 111 ;;; Internal variables.
 112
 113 (defvar gnus-inhibit-posting-styles nil
 114   "Inhibit the use of posting styles.")
 115
 116 (defvar gnus-message-buffer "*Mail Gnus*")
 117 (defvar gnus-article-copy nil)
 118 (defvar gnus-last-posting-server nil)
 119 (defvar gnus-message-group-art nil)
 120
 121 (defconst gnus-bug-message
 122   "Sending a bug report to the Gnus Towers.
 123 ========================================
 124
 125 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 126 be sent to the Gnus Bug Exterminators.
 127
 128 At the bottom of the buffer you'll see lots of variable settings.
 129 Please do not delete those.  They will tell the Bug People what your
 130 environment is, so that it will be easier to locate the bugs.
 131
 132 If you have found a bug that makes Emacs go \"beep\", set
 133 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 134 and include the backtrace in your bug report.
 135
 136 Please describe the bug in annoying, painstaking detail.
 137
 138 Thank you for your help in stamping out bugs.
 139 ")
 140
 141 (eval-and-compile
 142   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 143   (autoload 'news-setup "rnewspost")
 144   (autoload 'news-reply-mode "rnewspost")
 145   (autoload 'rmail-dont-reply-to "mail-utils")
 146   (autoload 'rmail-output "rmailout"))
 147
 148 \f
 149 ;;;
 150 ;;; Gnus Posting Functions
 151 ;;;
 152
 153 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 154   "p" gnus-summary-post-news
 155   "f" gnus-summary-followup
 156   "F" gnus-summary-followup-with-original
 157   "c" gnus-summary-cancel-article
 158   "s" gnus-summary-supersede-article
 159   "r" gnus-summary-reply
 160   "R" gnus-summary-reply-with-original
 161   "w" gnus-summary-wide-reply
 162   "W" gnus-summary-wide-reply-with-original
 163   "n" gnus-summary-followup-to-mail
 164   "N" gnus-summary-followup-to-mail-with-original
 165   "m" gnus-summary-mail-other-window
 166   "u" gnus-uu-post-news
 167   "\M-c" gnus-summary-mail-crosspost-complaint
 168   "om" gnus-summary-mail-forward
 169   "op" gnus-summary-post-forward
 170   "Om" gnus-uu-digest-mail-forward
 171   "Op" gnus-uu-digest-post-forward)
 172
 173 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 174   "b" gnus-summary-resend-bounced-mail
 175   ;; "c" gnus-summary-send-draft
 176   "r" gnus-summary-resend-message)
 177
 178 ;;; Internal functions.
 179
 180 (defvar gnus-article-reply nil)
 181 (defmacro gnus-setup-message (config &rest forms)
 182   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 183         (buffer (make-symbol "gnus-setup-message-buffer"))
 184         (article (make-symbol "gnus-setup-message-article"))
 185         (group (make-symbol "gnus-setup-message-group")))
 186     `(let ((,winconf (current-window-configuration))
 187            (,buffer (buffer-name (current-buffer)))
 188            (,article (and gnus-article-reply (gnus-summary-article-number)))
 189            (,group gnus-newsgroup-name)
 190            (message-header-setup-hook
 191             (copy-sequence message-header-setup-hook))
 192            (message-mode-hook (copy-sequence message-mode-hook)))
 193        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 194        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 195        (add-hook 'message-mode-hook 'gnus-configure-posting-styles)
 196        (unwind-protect
 197            (progn
 198              ,@forms)
 199          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 200          (setq gnus-message-buffer (current-buffer))
 201          (set (make-local-variable 'gnus-message-group-art)
 202               (cons ,group ,article))
 203          (make-local-variable 'gnus-newsgroup-name)
 204          (gnus-run-hooks 'gnus-message-setup-hook))
 205        (gnus-add-buffer)
 206        (gnus-configure-windows ,config t)
 207        (set-buffer-modified-p nil))))
 208
 209 (defun gnus-inews-add-send-actions (winconf buffer article)
 210   (make-local-hook 'message-sent-hook)
 211   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 212   (setq message-post-method
 213         `(lambda (arg)
 214            (gnus-post-method arg ,gnus-newsgroup-name)))
 215   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 216   (message-add-action
 217    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 218   (message-add-action
 219    `(when (gnus-buffer-exists-p ,buffer)
 220       (save-excursion
 221         (set-buffer ,buffer)
 222         ,(when article
 223            `(gnus-summary-mark-article-as-replied ,article))))
 224    'send))
 225
 226 (put 'gnus-setup-message 'lisp-indent-function 1)
 227 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 228
 229 ;;; Post news commands of Gnus group mode and summary mode
 230
 231 (defun gnus-group-mail (&optional arg)
 232   "Start composing a mail.
 233 If ARG, use the group under the point to find a posting style.
 234 If ARG is 1, prompt for a group name to find the posting style."
 235   (interactive "P")
 236   (let ((gnus-newsgroup-name
 237          (if arg
 238              (if (= 1 (prefix-numeric-value arg))
 239                  (completing-read "Use style of group: " gnus-active-hashtb nil
 240                                   (gnus-read-active-file-p))
 241                (gnus-group-group-name))
 242            "")))
 243     (gnus-setup-message 'message (message-mail))
 244     ))
 245
 246 (defun gnus-group-post-news (&optional arg)
 247   "Start composing a news message.
 248 If ARG, post to the group under point.
 249 If ARG is 1, prompt for a group name."
 250   (interactive "P")
 251   ;; Bind this variable here to make message mode hooks work ok.
 252   (let ((gnus-newsgroup-name
 253          (if arg
 254              (if (= 1 (prefix-numeric-value arg))
 255                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 256                                   (gnus-read-active-file-p))
 257                (gnus-group-group-name))
 258            "")))
 259     (gnus-post-news 'post gnus-newsgroup-name)))
 260
 261 (defun gnus-summary-post-news ()
 262   "Start composing a news message."
 263   (interactive)
 264   (gnus-post-news 'post gnus-newsgroup-name))
 265
 266 (defun gnus-summary-followup (yank &optional force-news)
 267   "Compose a followup to an article.
 268 If prefix argument YANK is non-nil, original article is yanked automatically."
 269   (interactive
 270    (list (and current-prefix-arg
 271               (gnus-summary-work-articles 1))))
 272   (when yank
 273     (gnus-summary-goto-subject (car yank)))
 274   (save-window-excursion
 275     (gnus-summary-select-article))
 276   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 277         (gnus-newsgroup-name gnus-newsgroup-name))
 278     ;; Send a followup.
 279     (gnus-post-news nil gnus-newsgroup-name
 280                     headers gnus-article-buffer
 281                     yank nil force-news)))
 282
 283 (defun gnus-summary-followup-with-original (n &optional force-news)
 284   "Compose a followup to an article and include the original article."
 285   (interactive "P")
 286   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 287
 288 (defun gnus-summary-followup-to-mail (&optional arg)
 289   "Followup to the current mail message via news."
 290   (interactive
 291    (list (and current-prefix-arg
 292               (gnus-summary-work-articles 1))))
 293   (gnus-summary-followup arg t))
 294
 295 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 296   "Followup to the current mail message via news."
 297   (interactive "P")
 298   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 299
 300 (defun gnus-inews-yank-articles (articles)
 301   (let (beg article)
 302     (message-goto-body)
 303     (while (setq article (pop articles))
 304       (save-window-excursion
 305         (set-buffer gnus-summary-buffer)
 306         (gnus-summary-select-article nil nil nil article)
 307         (gnus-summary-remove-process-mark article))
 308       (gnus-copy-article-buffer)
 309       (let ((message-reply-buffer gnus-article-copy)
 310             (message-reply-headers gnus-current-headers))
 311         (message-yank-original)
 312         (setq beg (or beg (mark t))))
 313       (when articles
 314         (insert "\n")))
 315     (push-mark)
 316     (goto-char beg)))
 317
 318 (defun gnus-summary-cancel-article (&optional n symp)
 319   "Cancel an article you posted.
 320 Uses the process-prefix convention.  If given the symbolic
 321 prefix `a', cancel using the standard posting method; if not
 322 post using the current select method."
 323   (interactive (gnus-interactive "P\ny"))
 324   (let ((articles (gnus-summary-work-articles n))
 325         (message-post-method
 326          `(lambda (arg)
 327             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 328         article)
 329     (while (setq article (pop articles))
 330       (when (gnus-summary-select-article t nil nil article)
 331         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 332                 (message-cancel-news))
 333           (gnus-summary-mark-as-read article gnus-canceled-mark)
 334           (gnus-cache-remove-article 1))
 335         (gnus-article-hide-headers-if-wanted))
 336       (gnus-summary-remove-process-mark article))))
 337
 338 (defun gnus-summary-supersede-article ()
 339   "Compose an article that will supersede a previous article.
 340 This is done simply by taking the old article and adding a Supersedes
 341 header line with the old Message-ID."
 342   (interactive)
 343   (let ((article (gnus-summary-article-number)))
 344     (gnus-setup-message 'reply-yank
 345       (gnus-summary-select-article t)
 346       (set-buffer gnus-original-article-buffer)
 347       (message-supersede)
 348       (push
 349        `((lambda ()
 350            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 351              (save-excursion
 352                (set-buffer ,gnus-summary-buffer)
 353                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 354                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 355        message-send-actions))))
 356
 357 \f
 358
 359 (defun gnus-copy-article-buffer (&optional article-buffer)
 360   ;; make a copy of the article buffer with all text properties removed
 361   ;; this copy is in the buffer gnus-article-copy.
 362   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 363   ;; this buffer should be passed to all mail/news reply/post routines.
 364   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 365   (save-excursion
 366     (set-buffer gnus-article-copy)
 367     (mm-enable-multibyte))
 368   (let ((article-buffer (or article-buffer gnus-article-buffer))
 369         end beg)
 370     (if (not (and (get-buffer article-buffer)
 371                   (gnus-buffer-exists-p article-buffer)))
 372         (error "Can't find any article buffer")
 373       (save-excursion
 374         (set-buffer article-buffer)
 375         (save-restriction
 376           ;; Copy over the (displayed) article buffer, delete
 377           ;; hidden text and remove text properties.
 378           (widen)
 379           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 380           (set-buffer gnus-article-copy)
 381           (gnus-article-delete-text-of-type 'annotation)
 382           (gnus-remove-text-with-property 'gnus-prev)
 383           (gnus-remove-text-with-property 'gnus-next)
 384           (insert
 385            (prog1
 386                (format "%s" (buffer-string))
 387              (erase-buffer)))
 388           ;; Find the original headers.
 389           (set-buffer gnus-original-article-buffer)
 390           (goto-char (point-min))
 391           (while (looking-at message-unix-mail-delimiter)
 392             (forward-line 1))
 393           (setq beg (point))
 394           (setq end (or (search-forward "\n\n" nil t) (point)))
 395           ;; Delete the headers from the displayed articles.
 396           (set-buffer gnus-article-copy)
 397           (delete-region (goto-char (point-min))
 398                          (or (search-forward "\n\n" nil t) (point)))
 399           ;; Insert the original article headers.
 400           (insert-buffer-substring gnus-original-article-buffer beg end)
 401           (article-decode-encoded-words)))
 402       gnus-article-copy)))
 403
 404 (defun gnus-post-news (post &optional group header article-buffer yank subject
 405                             force-news)
 406   (when article-buffer
 407     (gnus-copy-article-buffer))
 408   (let ((gnus-article-reply article-buffer)
 409         (add-to-list gnus-add-to-list))
 410     (gnus-setup-message (cond (yank 'reply-yank)
 411                               (article-buffer 'reply)
 412                               (t 'message))
 413       (let* ((group (or group gnus-newsgroup-name))
 414              (pgroup group)
 415              to-address to-group mailing-list to-list
 416              newsgroup-p)
 417         (when group
 418           (setq to-address (gnus-group-find-parameter group 'to-address)
 419                 to-group (gnus-group-find-parameter group 'to-group)
 420                 to-list (gnus-group-find-parameter group 'to-list)
 421                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 422                 mailing-list (when gnus-mailing-list-groups
 423                                (string-match gnus-mailing-list-groups group))
 424                 group (gnus-group-real-name group)))
 425         (if (or (and to-group
 426                      (gnus-news-group-p to-group))
 427                 newsgroup-p
 428                 force-news
 429                 (and (gnus-news-group-p
 430                       (or pgroup gnus-newsgroup-name)
 431                       (if header (mail-header-number header)
 432                         gnus-current-article))
 433                      (not mailing-list)
 434                      (not to-list)
 435                      (not to-address)))
 436             ;; This is news.
 437             (if post
 438                 (message-news (or to-group group))
 439               (set-buffer gnus-article-copy)
 440               (gnus-msg-treat-broken-reply-to)
 441               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 442           ;; The is mail.
 443           (if post
 444               (progn
 445                 (message-mail (or to-address to-list))
 446                 ;; Arrange for mail groups that have no `to-address' to
 447                 ;; get that when the user sends off the mail.
 448                 (when (and (not to-list)
 449                            (not to-address)
 450                            add-to-list)
 451                   (push (list 'gnus-inews-add-to-address pgroup)
 452                         message-send-actions)))
 453             (set-buffer gnus-article-copy)
 454             (gnus-msg-treat-broken-reply-to)
 455             (message-wide-reply to-address)))
 456         (when yank
 457           (gnus-inews-yank-articles yank))))))
 458
 459 (defun gnus-msg-treat-broken-reply-to ()
 460   "Remove the Reply-to header iff broken-reply-to."
 461   (when (gnus-group-find-parameter
 462          gnus-newsgroup-name 'broken-reply-to)
 463     (save-restriction
 464       (message-narrow-to-head)
 465       (message-remove-header "reply-to"))))
 466
 467 (defun gnus-post-method (arg group &optional silent)
 468   "Return the posting method based on GROUP and ARG.
 469 If SILENT, don't prompt the user."
 470   (let ((group-method (gnus-find-method-for-group group)))
 471     (cond
 472      ;; If the group-method is nil (which shouldn't happen) we use
 473      ;; the default method.
 474      ((null group-method)
 475       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 476                gnus-select-method message-post-method))
 477      ;; We want the inverse of the default
 478      ((and arg (not (eq arg 0)))
 479       (if (eq gnus-post-method 'active)
 480           gnus-select-method
 481         group-method))
 482      ;; We query the user for a post method.
 483      ((or arg
 484           (and gnus-post-method
 485                (not (eq gnus-post-method 'current))
 486                (listp (car gnus-post-method))))
 487       (let* ((methods
 488               ;; Collect all methods we know about.
 489               (append
 490                (when (and gnus-post-method
 491                           (not (eq gnus-post-method 'current)))
 492                  (if (listp (car gnus-post-method))
 493                      gnus-post-method
 494                    (list gnus-post-method)))
 495                gnus-secondary-select-methods
 496                (mapcar 'cdr gnus-server-alist)
 497                (mapcar 'car gnus-opened-servers)
 498                (list gnus-select-method)
 499                (list group-method)))
 500              method-alist post-methods method)
 501         ;; Weed out all mail methods.
 502         (while methods
 503           (setq method (gnus-server-get-method "" (pop methods)))
 504           (when (and (or (gnus-method-option-p method 'post)
 505                          (gnus-method-option-p method 'post-mail))
 506                      (not (member method post-methods)))
 507             (push method post-methods)))
 508         ;; Create a name-method alist.
 509         (setq method-alist
 510               (mapcar
 511                (lambda (m)
 512                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 513                post-methods))
 514         ;; Query the user.
 515         (cadr
 516          (assoc
 517           (setq gnus-last-posting-server
 518                 (if (and silent
 519                          gnus-last-posting-server)
 520                     ;; Just use the last value.
 521                     gnus-last-posting-server
 522                   (completing-read
 523                    "Posting method: " method-alist nil t
 524                    (cons (or gnus-last-posting-server "") 0))))
 525           method-alist))))
 526      ;; Override normal method.
 527      ((and (eq gnus-post-method 'current)
 528            (not (eq (car group-method) 'nndraft))
 529            (not arg))
 530       group-method)
 531      ((and gnus-post-method
 532            (not (eq gnus-post-method 'current)))
 533       gnus-post-method)
 534      ;; Use the normal select method.
 535      (t gnus-select-method))))
 536
 537 \f
 538
 539 ;; Dummies to avoid byte-compile warning.
 540 (defvar nnspool-rejected-article-hook)
 541 (defvar xemacs-codename)
 542
 543 (defun gnus-extended-version ()
 544   "Stringified Gnus version and Emacs version."
 545   (interactive)
 546   (concat
 547    "Gnus/" (prin1-to-string (gnus-continuum-version gnus-version) t)
 548    " (" gnus-version ")"
 549    " "
 550    (cond
 551     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 552      (concat "Emacs/" (match-string 1 emacs-version)))
 553     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
 554                    emacs-version)
 555      (concat (match-string 1 emacs-version)
 556              (format "/%d.%d" emacs-major-version emacs-minor-version)
 557              (if (match-beginning 3)
 558                  (match-string 3 emacs-version)
 559                "")
 560              (if (boundp 'xemacs-codename)
 561                  (concat " (" xemacs-codename ")")
 562                "")))
 563     (t emacs-version))))
 564
 565 \f
 566 ;;;
 567 ;;; Gnus Mail Functions
 568 ;;;
 569
 570 ;;; Mail reply commands of Gnus summary mode
 571
 572 (defun gnus-summary-reply (&optional yank wide)
 573   "Start composing a reply mail to the current message.
 574 If prefix argument YANK is non-nil, the original article is yanked
 575 automatically."
 576   (interactive
 577    (list (and current-prefix-arg
 578               (gnus-summary-work-articles 1))))
 579   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 580   (when yank
 581     (gnus-summary-goto-subject (car yank)))
 582   (let ((gnus-article-reply t))
 583     (gnus-setup-message (if yank 'reply-yank 'reply)
 584       (gnus-summary-select-article)
 585       (set-buffer (gnus-copy-article-buffer))
 586       (gnus-msg-treat-broken-reply-to)
 587       (message-reply nil wide)
 588       (when yank
 589         (gnus-inews-yank-articles yank)))))
 590
 591 (defun gnus-summary-reply-with-original (n &optional wide)
 592   "Start composing a reply mail to the current message.
 593 The original article will be yanked."
 594   (interactive "P")
 595   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 596
 597 (defun gnus-summary-wide-reply (&optional yank)
 598   "Start composing a wide reply mail to the current message.
 599 If prefix argument YANK is non-nil, the original article is yanked
 600 automatically."
 601   (interactive
 602    (list (and current-prefix-arg
 603               (gnus-summary-work-articles 1))))
 604   (gnus-summary-reply yank t))
 605
 606 (defun gnus-summary-wide-reply-with-original (n)
 607   "Start composing a wide reply mail to the current message.
 608 The original article will be yanked."
 609   (interactive "P")
 610   (gnus-summary-reply-with-original n t))
 611
 612 (defun gnus-summary-mail-forward (&optional full-headers post)
 613   "Forward the current message to another user.
 614 If FULL-HEADERS (the prefix), include full headers when forwarding."
 615   (interactive "P")
 616   (gnus-setup-message 'forward
 617     (gnus-summary-select-article)
 618     (set-buffer gnus-original-article-buffer)
 619     (let ((message-included-forward-headers
 620            (if full-headers "" message-included-forward-headers)))
 621       (message-forward post))))
 622
 623 (defun gnus-summary-resend-message (address n)
 624   "Resend the current article to ADDRESS."
 625   (interactive "sResend message(s) to: \nP")
 626   (let ((articles (gnus-summary-work-articles n))
 627         article)
 628     (while (setq article (pop articles))
 629       (gnus-summary-select-article nil nil nil article)
 630       (save-excursion
 631         (set-buffer gnus-original-article-buffer)
 632         (message-resend address)))))
 633
 634 (defun gnus-summary-post-forward (&optional full-headers)
 635   "Forward the current article to a newsgroup.
 636 If FULL-HEADERS (the prefix), include full headers when forwarding."
 637   (interactive "P")
 638   (gnus-summary-mail-forward full-headers t))
 639
 640 (defvar gnus-nastygram-message
 641   "The following article was inappropriately posted to %s.\n\n"
 642   "Format string to insert in nastygrams.
 643 The current group name will be inserted at \"%s\".")
 644
 645 (defun gnus-summary-mail-nastygram (n)
 646   "Send a nastygram to the author of the current article."
 647   (interactive "P")
 648   (when (or gnus-expert-user
 649             (gnus-y-or-n-p
 650              "Really send a nastygram to the author of the current article? "))
 651     (let ((group gnus-newsgroup-name))
 652       (gnus-summary-reply-with-original n)
 653       (set-buffer gnus-message-buffer)
 654       (message-goto-body)
 655       (insert (format gnus-nastygram-message group))
 656       (message-send-and-exit))))
 657
 658 (defun gnus-summary-mail-crosspost-complaint (n)
 659   "Send a complaint about crossposting to the current article(s)."
 660   (interactive "P")
 661   (let ((articles (gnus-summary-work-articles n))
 662         article)
 663     (while (setq article (pop articles))
 664       (set-buffer gnus-summary-buffer)
 665       (gnus-summary-goto-subject article)
 666       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 667             newsgroups followup-to)
 668         (gnus-summary-select-article)
 669         (set-buffer gnus-original-article-buffer)
 670         (if (and (<= (length (message-tokenize-header
 671                               (setq newsgroups (mail-fetch-field "newsgroups"))
 672                               ", "))
 673                      1)
 674                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 675                      (not (member group (message-tokenize-header
 676                                          followup-to ", ")))))
 677             (if followup-to
 678                 (gnus-message 1 "Followup-to restricted")
 679               (gnus-message 1 "Not a crossposted article"))
 680           (set-buffer gnus-summary-buffer)
 681           (gnus-summary-reply-with-original 1)
 682           (set-buffer gnus-message-buffer)
 683           (message-goto-body)
 684           (insert (format gnus-crosspost-complaint newsgroups group))
 685           (message-goto-subject)
 686           (re-search-forward " *$")
 687           (replace-match " (crosspost notification)" t t)
 688           (gnus-deactivate-mark)
 689           (when (gnus-y-or-n-p "Send this complaint? ")
 690             (message-send-and-exit)))))))
 691
 692 (defun gnus-summary-mail-other-window ()
 693   "Compose mail in other window."
 694   (interactive)
 695   (gnus-setup-message 'message
 696     (message-mail)))
 697
 698 (defun gnus-mail-parse-comma-list ()
 699   (let (accumulated
 700         beg)
 701     (skip-chars-forward " ")
 702     (while (not (eobp))
 703       (setq beg (point))
 704       (skip-chars-forward "^,")
 705       (while (zerop
 706               (save-excursion
 707                 (save-restriction
 708                   (let ((i 0))
 709                     (narrow-to-region beg (point))
 710                     (goto-char beg)
 711                     (logand (progn
 712                               (while (search-forward "\"" nil t)
 713                                 (incf i))
 714                               (if (zerop i) 2 i))
 715                             2)))))
 716         (skip-chars-forward ",")
 717         (skip-chars-forward "^,"))
 718       (skip-chars-backward " ")
 719       (push (buffer-substring beg (point))
 720             accumulated)
 721       (skip-chars-forward "^,")
 722       (skip-chars-forward ", "))
 723     accumulated))
 724
 725 (defun gnus-inews-add-to-address (group)
 726   (let ((to-address (mail-fetch-field "to")))
 727     (when (and to-address
 728                (gnus-alive-p))
 729       ;; This mail group doesn't have a `to-list', so we add one
 730       ;; here.  Magic!
 731       (when (gnus-y-or-n-p
 732              (format "Do you want to add this as `to-list': %s " to-address))
 733         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 734
 735 (defun gnus-put-message ()
 736   "Put the current message in some group and return to Gnus."
 737   (interactive)
 738   (let ((reply gnus-article-reply)
 739         (winconf gnus-prev-winconf)
 740         (group gnus-newsgroup-name))
 741
 742     (or (and group (not (gnus-group-read-only-p group)))
 743         (setq group (read-string "Put in group: " nil
 744                                  (gnus-writable-groups))))
 745     (when (gnus-gethash group gnus-newsrc-hashtb)
 746       (error "No such group: %s" group))
 747
 748     (save-excursion
 749       (save-restriction
 750         (widen)
 751         (message-narrow-to-headers)
 752         (let (gnus-deletable-headers)
 753           (if (message-news-p)
 754               (message-generate-headers message-required-news-headers)
 755             (message-generate-headers message-required-mail-headers)))
 756         (goto-char (point-max))
 757         (insert "Gcc: " group "\n")
 758         (widen)))
 759
 760     (gnus-inews-do-gcc)
 761
 762     (when (get-buffer gnus-group-buffer)
 763       (when (gnus-buffer-exists-p (car-safe reply))
 764         (set-buffer (car reply))
 765         (and (cdr reply)
 766              (gnus-summary-mark-article-as-replied
 767               (cdr reply))))
 768       (when winconf
 769         (set-window-configuration winconf)))))
 770
 771 (defun gnus-article-mail (yank)
 772   "Send a reply to the address near point.
 773 If YANK is non-nil, include the original article."
 774   (interactive "P")
 775   (let ((address
 776          (buffer-substring
 777           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 778           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 779     (when address
 780       (message-reply address)
 781       (when yank
 782         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 783
 784 (defvar nntp-server-type)
 785 (defun gnus-bug ()
 786   "Send a bug report to the Gnus maintainers."
 787   (interactive)
 788   (unless (gnus-alive-p)
 789     (error "Gnus has been shut down"))
 790   (gnus-setup-message 'bug
 791     (delete-other-windows)
 792     (when gnus-bug-create-help-buffer
 793       (switch-to-buffer "*Gnus Help Bug*")
 794       (erase-buffer)
 795       (insert gnus-bug-message)
 796       (goto-char (point-min)))
 797     (message-pop-to-buffer "*Gnus Bug*")
 798     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 799     (when gnus-bug-create-help-buffer
 800       (push `(gnus-bug-kill-buffer) message-send-actions))
 801     (goto-char (point-min))
 802     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 803     (forward-line 1)
 804     (insert (gnus-version) "\n"
 805             (emacs-version) "\n")
 806     (when (and (boundp 'nntp-server-type)
 807                (stringp nntp-server-type))
 808       (insert nntp-server-type))
 809     (insert "\n\n\n\n\n")
 810     (gnus-debug)
 811     (goto-char (point-min))
 812     (search-forward "Subject: " nil t)
 813     (message "")))
 814
 815 (defun gnus-bug-kill-buffer ()
 816   (when (get-buffer "*Gnus Help Bug*")
 817     (kill-buffer "*Gnus Help Bug*")))
 818
 819 (defun gnus-debug ()
 820   "Attempts to go through the Gnus source file and report what variables have been changed.
 821 The source file has to be in the Emacs load path."
 822   (interactive)
 823   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 824                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 825                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 826                  "nnmail.el" "message.el"))
 827         (point (point))
 828         file expr olist sym)
 829     (gnus-message 4 "Please wait while we snoop your variables...")
 830     (sit-for 0)
 831     ;; Go through all the files looking for non-default values for variables.
 832     (save-excursion
 833       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
 834       (while files
 835         (erase-buffer)
 836         (when (and (setq file (locate-library (pop files)))
 837                    (file-exists-p file))
 838           (insert-file-contents file)
 839           (goto-char (point-min))
 840           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 841               (gnus-message 4 "Malformed sources in file %s" file)
 842             (narrow-to-region (point-min) (point))
 843             (goto-char (point-min))
 844             (while (setq expr (ignore-errors (read (current-buffer))))
 845               (ignore-errors
 846                 (and (or (eq (car expr) 'defvar)
 847                          (eq (car expr) 'defcustom))
 848                      (stringp (nth 3 expr))
 849                      (or (not (boundp (nth 1 expr)))
 850                          (not (equal (eval (nth 2 expr))
 851                                      (symbol-value (nth 1 expr)))))
 852                      (push (nth 1 expr) olist)))))))
 853       (kill-buffer (current-buffer)))
 854     (when (setq olist (nreverse olist))
 855       (insert "------------------ Environment follows ------------------\n\n"))
 856     (while olist
 857       (if (boundp (car olist))
 858           (condition-case ()
 859               (pp `(setq ,(car olist)
 860                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 861                                   (and (symbolp sym)
 862                                        (not (or (eq sym nil)
 863                                                 (eq sym t)))))
 864                               (list 'quote (symbol-value (car olist)))
 865                             (symbol-value (car olist))))
 866                   (current-buffer))
 867             (error
 868              (format "(setq %s 'whatever)\n" (car olist))))
 869         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 870       (setq olist (cdr olist)))
 871     (insert "\n\n")
 872     ;; Remove any control chars - they seem to cause trouble for some
 873     ;; mailers.  (Byte-compiled output from the stuff above.)
 874     (goto-char point)
 875     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 876       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 877                      t t))))
 878
 879 ;;; Treatment of rejected articles.
 880 ;;; Bounced mail.
 881
 882 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 883   "Re-mail the current message.
 884 This only makes sense if the current message is a bounce message than
 885 contains some mail you have written which has been bounced back to
 886 you.
 887 If FETCH, try to fetch the article that this is a reply to, if indeed
 888 this is a reply."
 889   (interactive "P")
 890   (gnus-summary-select-article t)
 891   (set-buffer gnus-original-article-buffer)
 892   (gnus-setup-message 'compose-bounce
 893     (let* ((references (mail-fetch-field "references"))
 894            (parent (and references (gnus-parent-id references))))
 895       (message-bounce)
 896       ;; If there are references, we fetch the article we answered to.
 897       (and fetch parent
 898            (gnus-summary-refer-article parent)
 899            (gnus-summary-show-all-headers)))))
 900
 901 ;;; Gcc handling.
 902
 903 ;; Do Gcc handling, which copied the message over to some group.
 904 (defun gnus-inews-do-gcc (&optional gcc)
 905   (interactive)
 906   (when (gnus-alive-p)
 907     (save-excursion
 908       (save-restriction
 909         (message-narrow-to-headers)
 910         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 911               (cur (current-buffer))
 912               groups group method)
 913           (when gcc
 914             (message-remove-header "gcc")
 915             (widen)
 916             (setq groups (message-tokenize-header gcc " ,"))
 917             ;; Copy the article over to some group(s).
 918             (while (setq group (pop groups))
 919               (gnus-check-server
 920                (setq method
 921                      (cond ((and (null (gnus-get-info group))
 922                                  (eq (car gnus-message-archive-method)
 923                                      (car
 924                                       (gnus-server-to-method
 925                                        (gnus-group-method group)))))
 926                             ;; If the group doesn't exist, we assume
 927                             ;; it's an archive group...
 928                             gnus-message-archive-method)
 929                            ;; Use the method.
 930                            ((gnus-info-method (gnus-get-info group))
 931                             (gnus-info-method (gnus-get-info group)))
 932                            ;; Find the method.
 933                            (t (gnus-group-method group)))))
 934               (gnus-check-server method)
 935               (unless (gnus-request-group group t method)
 936                 (gnus-request-create-group group method))
 937               (save-excursion
 938                 (nnheader-set-temp-buffer " *acc*")
 939                 (insert-buffer-substring cur)
 940                 (goto-char (point-min))
 941                 (when (re-search-forward
 942                        (concat "^" (regexp-quote mail-header-separator) "$")
 943                        nil t)
 944                   (replace-match "" t t ))
 945                 (unless (gnus-request-accept-article group method t t)
 946                   (gnus-message 1 "Couldn't store article in group %s: %s"
 947                                 group (gnus-status-message method))
 948                   (sit-for 2))
 949                 (kill-buffer (current-buffer))))))))))
 950
 951 (defun gnus-inews-insert-gcc ()
 952   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 953   (save-excursion
 954     (save-restriction
 955       (message-narrow-to-headers)
 956       (let* ((group gnus-outgoing-message-group)
 957              (gcc (cond
 958                    ((gnus-functionp group)
 959                     (funcall group))
 960                    ((or (stringp group) (list group))
 961                     group))))
 962         (when gcc
 963           (insert "Gcc: "
 964                   (if (stringp gcc) gcc
 965                     (mapconcat 'identity gcc " "))
 966                   "\n"))))))
 967
 968 (defun gnus-inews-insert-archive-gcc (&optional group)
 969   "Insert the Gcc to say where the article is to be archived."
 970   (let* ((var gnus-message-archive-group)
 971          (group (or group gnus-newsgroup-name ""))
 972          (gcc-self-val
 973           (and gnus-newsgroup-name
 974                (gnus-group-find-parameter
 975                 gnus-newsgroup-name 'gcc-self)))
 976          result
 977          (groups
 978           (cond
 979            ((null gnus-message-archive-method)
 980             ;; Ignore.
 981             nil)
 982            ((stringp var)
 983             ;; Just a single group.
 984             (list var))
 985            ((null var)
 986             ;; We don't want this.
 987             nil)
 988            ((and (listp var) (stringp (car var)))
 989             ;; A list of groups.
 990             var)
 991            ((gnus-functionp var)
 992             ;; A function.
 993             (funcall var group))
 994            (t
 995             ;; An alist of regexps/functions/forms.
 996             (while (and var
 997                         (not
 998                          (setq result
 999                                (cond
1000                                 ((stringp (caar var))
1001                                  ;; Regexp.
1002                                  (when (string-match (caar var) group)
1003                                    (cdar var)))
1004                                 ((gnus-functionp (car var))
1005                                  ;; Function.
1006                                  (funcall (car var) group))
1007                                 (t
1008                                  (eval (car var)))))))
1009               (setq var (cdr var)))
1010             result)))
1011          name)
1012     (when (or groups gcc-self-val)
1013       (when (stringp groups)
1014         (setq groups (list groups)))
1015       (save-excursion
1016         (save-restriction
1017           (message-narrow-to-headers)
1018           (goto-char (point-max))
1019           (insert "Gcc: ")
1020           (if gcc-self-val
1021               ;; Use the `gcc-self' param value instead.
1022               (progn
1023                 (insert
1024                  (if (stringp gcc-self-val)
1025                      gcc-self-val
1026                    group))
1027                 (if (not (eq gcc-self-val 'none))
1028                     (insert "\n")
1029                   (progn
1030                     (beginning-of-line)
1031                     (kill-line))))
1032             ;; Use the list of groups.
1033             (while (setq name (pop groups))
1034               (insert (if (string-match ":" name)
1035                           name
1036                         (gnus-group-prefixed-name
1037                          name gnus-message-archive-method)))
1038               (when groups
1039                 (insert " ")))
1040             (insert "\n")))))))
1041
1042 ;;; Posting styles.
1043
1044 (defvar gnus-message-style-insertions nil)
1045
1046 (defun gnus-configure-posting-styles ()
1047   "Configure posting styles according to `gnus-posting-styles'."
1048   (unless gnus-inhibit-posting-styles
1049     (let ((styles gnus-posting-styles)
1050           (gnus-newsgroup-name (or gnus-newsgroup-name ""))
1051           style match variable attribute value value-value)
1052       (make-local-variable 'gnus-message-style-insertions)
1053       ;; Go through all styles and look for matches.
1054       (while styles
1055         (setq style (pop styles)
1056               match (pop style))
1057         (when (cond ((stringp match)
1058                      ;; Regexp string match on the group name.
1059                      (string-match match gnus-newsgroup-name))
1060                     ((or (symbolp match)
1061                          (gnus-functionp match))
1062                      (cond ((gnus-functionp match)
1063                             ;; Function to be called.
1064                             (funcall match))
1065                            ((boundp match)
1066                             ;; Variable to be checked.
1067                             (symbol-value match))))
1068                     ((listp match)
1069                      ;; This is a form to be evaled.
1070                      (eval match)))
1071           ;; We have a match, so we set the variables.
1072           (while style
1073             (setq attribute (pop style)
1074                   value (cadr attribute)
1075                   variable nil)
1076             ;; We find the variable that is to be modified.
1077             (if (and (not (stringp (car attribute)))
1078                      (not (eq 'body (car attribute)))
1079                      (not (setq variable
1080                                 (cdr (assq (car attribute)
1081                                            gnus-posting-style-alist)))))
1082                 (message "Couldn't find attribute %s" (car attribute))
1083               ;; We get the value.
1084               (setq value-value
1085                     (cond ((stringp value)
1086                            value)
1087                           ((or (symbolp value)
1088                                (gnus-functionp value))
1089                            (cond ((gnus-functionp value)
1090                                   (funcall value))
1091                                  ((boundp value)
1092                                   (symbol-value value))))
1093                           ((listp value)
1094                            (eval value))))
1095               (if variable
1096                   ;; This is an ordinary variable.
1097                   (set (make-local-variable variable) value-value)
1098                 ;; This is either a body or a header to be inserted in the
1099                 ;; message.
1100                 (when value-value
1101                   (let ((attr (car attribute)))
1102                     (make-local-variable 'message-setup-hook)
1103                     (if (eq 'body attr)
1104                         (add-hook 'message-setup-hook
1105                                   `(lambda ()
1106                                      (save-excursion
1107                                        (message-goto-body)
1108                                        (insert ,value-value))))
1109                       (add-hook 'message-setup-hook
1110                                 'gnus-message-insert-stylings)
1111                       (push (cons (if (stringp attr) attr
1112                                     (symbol-name attr))
1113                                   value-value)
1114                             gnus-message-style-insertions))))))))))))
1115
1116 (defun gnus-message-insert-stylings ()
1117   (let (val)
1118     (save-excursion
1119       (message-goto-eoh)
1120       (while (setq val (pop gnus-message-style-insertions))
1121         (when (cdr val)
1122           (insert (car val) ": " (cdr val) "\n"))
1123         (gnus-pull (car val) gnus-message-style-insertions)))))
1124
1125 ;;; Allow redefinition of functions.
1126
1127 (gnus-ems-redefine)
1128
1129 (provide 'gnus-msg)
1130
1131 ;;; gnus-msg.el ends here