cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-ems)
  33 (require 'message)
  34 (require 'gnus-art)
  35
  36 (defcustom gnus-post-method nil
  37   "*Preferred method for posting USENET news.
  38
  39 If this variable is `current', Gnus will use the \"current\" select
  40 method when posting.  If it is nil (which is the default), Gnus will
  41 use the native posting method of the server.
  42
  43 This method will not be used in mail groups and the like, only in
  44 \"real\" newsgroups.
  45
  46 If not nil nor `native', the value must be a valid method as discussed
  47 in the documentation of `gnus-select-method'. It can also be a list of
  48 methods. If that is the case, the user will be queried for what select
  49 method to use when posting."
  50   :group 'gnus-group-foreign
  51   :type `(choice (const nil)
  52                  (const current)
  53                  (const native)
  54                  (sexp :tag "Methods" ,gnus-select-method)))
  55
  56 (defvar gnus-outgoing-message-group nil
  57   "*All outgoing messages will be put in this group.
  58 If you want to store all your outgoing mail and articles in the group
  59 \"nnml:archive\", you set this variable to that value.  This variable
  60 can also be a list of group names.
  61
  62 If you want to have greater control over what group to put each
  63 message in, you can set this variable to a function that checks the
  64 current newsgroup name and then returns a suitable group name (or list
  65 of names).")
  66
  67 (defvar gnus-mailing-list-groups nil
  68   "*Regexp matching groups that are really mailing lists.
  69 This is useful when you're reading a mailing list that has been
  70 gatewayed to a newsgroup, and you want to followup to an article in
  71 the group.")
  72
  73 (defvar gnus-add-to-list nil
  74   "*If non-nil, add a `to-list' parameter automatically.")
  75
  76 (defvar gnus-crosspost-complaint
  77   "Hi,
  78
  79 You posted the article below with the following Newsgroups header:
  80
  81 Newsgroups: %s
  82
  83 The %s group, at least, was an inappropriate recipient
  84 of this message.  Please trim your Newsgroups header to exclude this
  85 group before posting in the future.
  86
  87 Thank you.
  88
  89 "
  90   "Format string to be inserted when complaining about crossposts.
  91 The first %s will be replaced by the Newsgroups header;
  92 the second with the current group name.")
  93
  94 (defvar gnus-message-setup-hook nil
  95   "Hook run after setting up a message buffer.")
  96
  97 (defvar gnus-bug-create-help-buffer t
  98   "*Should we create the *Gnus Help Bug* buffer?")
  99
 100 (defvar gnus-posting-styles nil
 101   "*Alist of styles to use when posting.")
 102
 103 (defvar gnus-posting-style-alist
 104   '((organization . message-user-organization)
 105     (signature . message-signature)
 106     (signature-file . message-signature-file)
 107     (address . user-mail-address)
 108     (name . user-full-name))
 109   "*Mapping from style parameters to variables.")
 110
 111 ;;; Internal variables.
 112
 113 (defvar gnus-inhibit-posting-styles nil
 114   "Inhibit the use of posting styles.")
 115
 116 (defvar gnus-message-buffer "*Mail Gnus*")
 117 (defvar gnus-article-copy nil)
 118 (defvar gnus-last-posting-server nil)
 119 (defvar gnus-message-group-art nil)
 120
 121 (defconst gnus-bug-message
 122   "Sending a bug report to the Gnus Towers.
 123 ========================================
 124
 125 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 126 be sent to the Gnus Bug Exterminators.
 127
 128 At the bottom of the buffer you'll see lots of variable settings.
 129 Please do not delete those.  They will tell the Bug People what your
 130 environment is, so that it will be easier to locate the bugs.
 131
 132 If you have found a bug that makes Emacs go \"beep\", set
 133 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 134 and include the backtrace in your bug report.
 135
 136 Please describe the bug in annoying, painstaking detail.
 137
 138 Thank you for your help in stamping out bugs.
 139 ")
 140
 141 (eval-and-compile
 142   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 143   (autoload 'news-setup "rnewspost")
 144   (autoload 'news-reply-mode "rnewspost")
 145   (autoload 'rmail-dont-reply-to "mail-utils")
 146   (autoload 'rmail-output "rmailout"))
 147
 148 \f
 149 ;;;
 150 ;;; Gnus Posting Functions
 151 ;;;
 152
 153 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 154   "p" gnus-summary-post-news
 155   "f" gnus-summary-followup
 156   "F" gnus-summary-followup-with-original
 157   "c" gnus-summary-cancel-article
 158   "s" gnus-summary-supersede-article
 159   "r" gnus-summary-reply
 160   "R" gnus-summary-reply-with-original
 161   "w" gnus-summary-wide-reply
 162   "W" gnus-summary-wide-reply-with-original
 163   "n" gnus-summary-followup-to-mail
 164   "N" gnus-summary-followup-to-mail-with-original
 165   "m" gnus-summary-mail-other-window
 166   "u" gnus-uu-post-news
 167   "\M-c" gnus-summary-mail-crosspost-complaint
 168   "om" gnus-summary-mail-forward
 169   "op" gnus-summary-post-forward
 170   "Om" gnus-uu-digest-mail-forward
 171   "Op" gnus-uu-digest-post-forward)
 172
 173 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 174   "b" gnus-summary-resend-bounced-mail
 175   ;; "c" gnus-summary-send-draft
 176   "r" gnus-summary-resend-message)
 177
 178 ;;; Internal functions.
 179
 180 (defvar gnus-article-reply nil)
 181 (defmacro gnus-setup-message (config &rest forms)
 182   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 183         (buffer (make-symbol "gnus-setup-message-buffer"))
 184         (article (make-symbol "gnus-setup-message-article"))
 185         (group (make-symbol "gnus-setup-message-group")))
 186     `(let ((,winconf (current-window-configuration))
 187            (,buffer (buffer-name (current-buffer)))
 188            (,article (and gnus-article-reply (gnus-summary-article-number)))
 189            (,group gnus-newsgroup-name)
 190            (message-header-setup-hook
 191             (copy-sequence message-header-setup-hook))
 192            (message-mode-hook (copy-sequence message-mode-hook)))
 193        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 194        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 195        (add-hook 'message-mode-hook 'gnus-configure-posting-styles)
 196        (unwind-protect
 197            (progn
 198              ,@forms)
 199          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 200          (setq gnus-message-buffer (current-buffer))
 201          (set (make-local-variable 'gnus-message-group-art)
 202               (cons ,group ,article))
 203          (make-local-variable 'gnus-newsgroup-name)
 204          (gnus-run-hooks 'gnus-message-setup-hook))
 205        (gnus-add-buffer)
 206        (gnus-configure-windows ,config t)
 207        (set-buffer-modified-p nil))))
 208
 209 (defun gnus-inews-add-send-actions (winconf buffer article)
 210   (make-local-hook 'message-sent-hook)
 211   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 212   (setq message-post-method
 213         `(lambda (arg)
 214            (gnus-post-method arg ,gnus-newsgroup-name)))
 215   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 216   (message-add-action
 217    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 218   (message-add-action
 219    `(when (gnus-buffer-exists-p ,buffer)
 220       (save-excursion
 221         (set-buffer ,buffer)
 222         ,(when article
 223            `(gnus-summary-mark-article-as-replied ,article))))
 224    'send))
 225
 226 (put 'gnus-setup-message 'lisp-indent-function 1)
 227 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 228
 229 ;;; Post news commands of Gnus group mode and summary mode
 230
 231 (defun gnus-group-mail (&optional arg)
 232   "Start composing a mail.
 233 If ARG, use the group under the point to find a posting style.
 234 If ARG is 1, prompt for a group name to find the posting style."
 235   (interactive "P")
 236   (let ((gnus-newsgroup-name
 237          (if arg
 238              (if (= 1 (prefix-numeric-value arg))
 239                  (completing-read "Use posting style of group: "
 240                                   gnus-active-hashtb nil
 241                                   (gnus-read-active-file-p))
 242                (gnus-group-group-name))
 243            "")))
 244     (gnus-setup-message 'message (message-mail))))
 245
 246 (defun gnus-group-post-news (&optional arg)
 247   "Start composing a news message.
 248 If ARG, post to the group under point.
 249 If ARG is 1, prompt for a group name."
 250   (interactive "P")
 251   ;; Bind this variable here to make message mode hooks work ok.
 252   (let ((gnus-newsgroup-name
 253          (if arg
 254              (if (= 1 (prefix-numeric-value arg))
 255                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 256                                   (gnus-read-active-file-p))
 257                (gnus-group-group-name))
 258            "")))
 259     (gnus-post-news 'post gnus-newsgroup-name)))
 260
 261 (defun gnus-summary-post-news ()
 262   "Start composing a news message."
 263   (interactive)
 264   (gnus-post-news 'post gnus-newsgroup-name))
 265
 266 (defun gnus-summary-followup (yank &optional force-news)
 267   "Compose a followup to an article.
 268 If prefix argument YANK is non-nil, original article is yanked automatically."
 269   (interactive
 270    (list (and current-prefix-arg
 271               (gnus-summary-work-articles 1))))
 272   (when yank
 273     (gnus-summary-goto-subject (car yank)))
 274   (save-window-excursion
 275     (gnus-summary-select-article))
 276   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 277         (gnus-newsgroup-name gnus-newsgroup-name))
 278     ;; Send a followup.
 279     (gnus-post-news nil gnus-newsgroup-name
 280                     headers gnus-article-buffer
 281                     yank nil force-news)))
 282
 283 (defun gnus-summary-followup-with-original (n &optional force-news)
 284   "Compose a followup to an article and include the original article."
 285   (interactive "P")
 286   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 287
 288 (defun gnus-summary-followup-to-mail (&optional arg)
 289   "Followup to the current mail message via news."
 290   (interactive
 291    (list (and current-prefix-arg
 292               (gnus-summary-work-articles 1))))
 293   (gnus-summary-followup arg t))
 294
 295 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 296   "Followup to the current mail message via news."
 297   (interactive "P")
 298   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 299
 300 (defun gnus-inews-yank-articles (articles)
 301   (let (beg article)
 302     (message-goto-body)
 303     (while (setq article (pop articles))
 304       (save-window-excursion
 305         (set-buffer gnus-summary-buffer)
 306         (gnus-summary-select-article nil nil nil article)
 307         (gnus-summary-remove-process-mark article))
 308       (gnus-copy-article-buffer)
 309       (let ((message-reply-buffer gnus-article-copy)
 310             (message-reply-headers gnus-current-headers))
 311         (message-yank-original)
 312         (setq beg (or beg (mark t))))
 313       (when articles
 314         (insert "\n")))
 315     (push-mark)
 316     (goto-char beg)))
 317
 318 (defun gnus-summary-cancel-article (&optional n symp)
 319   "Cancel an article you posted.
 320 Uses the process-prefix convention.  If given the symbolic
 321 prefix `a', cancel using the standard posting method; if not
 322 post using the current select method."
 323   (interactive (gnus-interactive "P\ny"))
 324   (let ((articles (gnus-summary-work-articles n))
 325         (message-post-method
 326          `(lambda (arg)
 327             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 328         article)
 329     (while (setq article (pop articles))
 330       (when (gnus-summary-select-article t nil nil article)
 331         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 332                 (message-cancel-news))
 333           (gnus-summary-mark-as-read article gnus-canceled-mark)
 334           (gnus-cache-remove-article 1))
 335         (gnus-article-hide-headers-if-wanted))
 336       (gnus-summary-remove-process-mark article))))
 337
 338 (defun gnus-summary-supersede-article ()
 339   "Compose an article that will supersede a previous article.
 340 This is done simply by taking the old article and adding a Supersedes
 341 header line with the old Message-ID."
 342   (interactive)
 343   (let ((article (gnus-summary-article-number)))
 344     (gnus-setup-message 'reply-yank
 345       (gnus-summary-select-article t)
 346       (set-buffer gnus-original-article-buffer)
 347       (message-supersede)
 348       (push
 349        `((lambda ()
 350            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 351              (save-excursion
 352                (set-buffer ,gnus-summary-buffer)
 353                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 354                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 355        message-send-actions))))
 356
 357 \f
 358
 359 (defun gnus-copy-article-buffer (&optional article-buffer)
 360   ;; make a copy of the article buffer with all text properties removed
 361   ;; this copy is in the buffer gnus-article-copy.
 362   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 363   ;; this buffer should be passed to all mail/news reply/post routines.
 364   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 365   (save-excursion
 366     (set-buffer gnus-article-copy)
 367     (mm-enable-multibyte))
 368   (let ((article-buffer (or article-buffer gnus-article-buffer))
 369         end beg)
 370     (if (not (and (get-buffer article-buffer)
 371                   (gnus-buffer-exists-p article-buffer)))
 372         (error "Can't find any article buffer")
 373       (save-excursion
 374         (set-buffer article-buffer)
 375         (save-restriction
 376           ;; Copy over the (displayed) article buffer, delete
 377           ;; hidden text and remove text properties.
 378           (widen)
 379           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 380           (set-buffer gnus-article-copy)
 381           (gnus-article-delete-text-of-type 'annotation)
 382           (gnus-remove-text-with-property 'gnus-prev)
 383           (gnus-remove-text-with-property 'gnus-next)
 384           (insert
 385            (prog1
 386                (format "%s" (buffer-string))
 387              (erase-buffer)))
 388           ;; Find the original headers.
 389           (set-buffer gnus-original-article-buffer)
 390           (goto-char (point-min))
 391           (while (looking-at message-unix-mail-delimiter)
 392             (forward-line 1))
 393           (setq beg (point))
 394           (setq end (or (search-forward "\n\n" nil t) (point)))
 395           ;; Delete the headers from the displayed articles.
 396           (set-buffer gnus-article-copy)
 397           (delete-region (goto-char (point-min))
 398                          (or (search-forward "\n\n" nil t) (point-max)))
 399           ;; Insert the original article headers.
 400           (insert-buffer-substring gnus-original-article-buffer beg end)
 401           (article-decode-encoded-words)))
 402       gnus-article-copy)))
 403
 404 (defun gnus-post-news (post &optional group header article-buffer yank subject
 405                             force-news)
 406   (when article-buffer
 407     (gnus-copy-article-buffer))
 408   (let ((gnus-article-reply article-buffer)
 409         (add-to-list gnus-add-to-list))
 410     (gnus-setup-message (cond (yank 'reply-yank)
 411                               (article-buffer 'reply)
 412                               (t 'message))
 413       (let* ((group (or group gnus-newsgroup-name))
 414              (pgroup group)
 415              to-address to-group mailing-list to-list
 416              newsgroup-p)
 417         (when group
 418           (setq to-address (gnus-group-find-parameter group 'to-address)
 419                 to-group (gnus-group-find-parameter group 'to-group)
 420                 to-list (gnus-group-find-parameter group 'to-list)
 421                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 422                 mailing-list (when gnus-mailing-list-groups
 423                                (string-match gnus-mailing-list-groups group))
 424                 group (gnus-group-real-name group)))
 425         (if (or (and to-group
 426                      (gnus-news-group-p to-group))
 427                 newsgroup-p
 428                 force-news
 429                 (and (gnus-news-group-p
 430                       (or pgroup gnus-newsgroup-name)
 431                       (if header (mail-header-number header)
 432                         gnus-current-article))
 433                      (not mailing-list)
 434                      (not to-list)
 435                      (not to-address)))
 436             ;; This is news.
 437             (if post
 438                 (message-news (or to-group group))
 439               (set-buffer gnus-article-copy)
 440               (gnus-msg-treat-broken-reply-to)
 441               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 442           ;; The is mail.
 443           (if post
 444               (progn
 445                 (message-mail (or to-address to-list))
 446                 ;; Arrange for mail groups that have no `to-address' to
 447                 ;; get that when the user sends off the mail.
 448                 (when (and (not to-list)
 449                            (not to-address)
 450                            add-to-list)
 451                   (push (list 'gnus-inews-add-to-address pgroup)
 452                         message-send-actions)))
 453             (set-buffer gnus-article-copy)
 454             (gnus-msg-treat-broken-reply-to)
 455             (message-wide-reply to-address)))
 456         (when yank
 457           (gnus-inews-yank-articles yank))))))
 458
 459 (defun gnus-msg-treat-broken-reply-to ()
 460   "Remove the Reply-to header iff broken-reply-to."
 461   (when (gnus-group-find-parameter
 462          gnus-newsgroup-name 'broken-reply-to)
 463     (save-restriction
 464       (message-narrow-to-head)
 465       (message-remove-header "reply-to"))))
 466
 467 (defun gnus-post-method (arg group &optional silent)
 468   "Return the posting method based on GROUP and ARG.
 469 If SILENT, don't prompt the user."
 470   (let ((group-method (gnus-find-method-for-group group)))
 471     (cond
 472      ;; If the group-method is nil (which shouldn't happen) we use
 473      ;; the default method.
 474      ((null group-method)
 475       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 476                gnus-select-method message-post-method))
 477      ;; We want the inverse of the default
 478      ((and arg (not (eq arg 0)))
 479       (if (eq gnus-post-method 'active)
 480           gnus-select-method
 481         group-method))
 482      ;; We query the user for a post method.
 483      ((or arg
 484           (and gnus-post-method
 485                (not (eq gnus-post-method 'current))
 486                (listp (car gnus-post-method))))
 487       (let* ((methods
 488               ;; Collect all methods we know about.
 489               (append
 490                (when (and gnus-post-method
 491                           (not (eq gnus-post-method 'current)))
 492                  (if (listp (car gnus-post-method))
 493                      gnus-post-method
 494                    (list gnus-post-method)))
 495                gnus-secondary-select-methods
 496                (mapcar 'cdr gnus-server-alist)
 497                (mapcar 'car gnus-opened-servers)
 498                (list gnus-select-method)
 499                (list group-method)))
 500              method-alist post-methods method)
 501         ;; Weed out all mail methods.
 502         (while methods
 503           (setq method (gnus-server-get-method "" (pop methods)))
 504           (when (and (or (gnus-method-option-p method 'post)
 505                          (gnus-method-option-p method 'post-mail))
 506                      (not (member method post-methods)))
 507             (push method post-methods)))
 508         ;; Create a name-method alist.
 509         (setq method-alist
 510               (mapcar
 511                (lambda (m)
 512                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 513                post-methods))
 514         ;; Query the user.
 515         (cadr
 516          (assoc
 517           (setq gnus-last-posting-server
 518                 (if (and silent
 519                          gnus-last-posting-server)
 520                     ;; Just use the last value.
 521                     gnus-last-posting-server
 522                   (completing-read
 523                    "Posting method: " method-alist nil t
 524                    (cons (or gnus-last-posting-server "") 0))))
 525           method-alist))))
 526      ;; Override normal method.
 527      ((and (eq gnus-post-method 'current)
 528            (not (eq (car group-method) 'nndraft))
 529            (not arg))
 530       group-method)
 531      ((and gnus-post-method
 532            (not (eq gnus-post-method 'current)))
 533       gnus-post-method)
 534      ;; Use the normal select method.
 535      (t gnus-select-method))))
 536
 537 \f
 538
 539 ;; Dummies to avoid byte-compile warning.
 540 (defvar nnspool-rejected-article-hook)
 541 (defvar xemacs-codename)
 542
 543 (defun gnus-extended-version ()
 544   "Stringified Gnus version and Emacs version."
 545   (interactive)
 546   (concat
 547    "Gnus/" (prin1-to-string (gnus-continuum-version gnus-version) t)
 548    " (" gnus-version ")"
 549    " "
 550    (cond
 551     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 552      (concat "Emacs/" (match-string 1 emacs-version)))
 553     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
 554                    emacs-version)
 555      (concat (match-string 1 emacs-version)
 556              (format "/%d.%d" emacs-major-version emacs-minor-version)
 557              (if (match-beginning 3)
 558                  (match-string 3 emacs-version)
 559                "")
 560              (if (boundp 'xemacs-codename)
 561                  (concat " (" xemacs-codename ")")
 562                "")))
 563     (t emacs-version))))
 564
 565 \f
 566 ;;;
 567 ;;; Gnus Mail Functions
 568 ;;;
 569
 570 ;;; Mail reply commands of Gnus summary mode
 571
 572 (defun gnus-summary-reply (&optional yank wide)
 573   "Start composing a reply mail to the current message.
 574 If prefix argument YANK is non-nil, the original article is yanked
 575 automatically."
 576   (interactive
 577    (list (and current-prefix-arg
 578               (gnus-summary-work-articles 1))))
 579   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 580   (when yank
 581     (gnus-summary-goto-subject (car yank)))
 582   (let ((gnus-article-reply t))
 583     (gnus-setup-message (if yank 'reply-yank 'reply)
 584       (gnus-summary-select-article)
 585       (set-buffer (gnus-copy-article-buffer))
 586       (gnus-msg-treat-broken-reply-to)
 587       (message-reply nil wide)
 588       (when yank
 589         (gnus-inews-yank-articles yank)))))
 590
 591 (defun gnus-summary-reply-with-original (n &optional wide)
 592   "Start composing a reply mail to the current message.
 593 The original article will be yanked."
 594   (interactive "P")
 595   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 596
 597 (defun gnus-summary-wide-reply (&optional yank)
 598   "Start composing a wide reply mail to the current message.
 599 If prefix argument YANK is non-nil, the original article is yanked
 600 automatically."
 601   (interactive
 602    (list (and current-prefix-arg
 603               (gnus-summary-work-articles 1))))
 604   (gnus-summary-reply yank t))
 605
 606 (defun gnus-summary-wide-reply-with-original (n)
 607   "Start composing a wide reply mail to the current message.
 608 The original article will be yanked."
 609   (interactive "P")
 610   (gnus-summary-reply-with-original n t))
 611
 612 (defun gnus-summary-mail-forward (&optional full-headers post)
 613   "Forward the current message to another user.
 614 If FULL-HEADERS (the prefix), include full headers when forwarding."
 615   (interactive "P")
 616   (gnus-setup-message 'forward
 617     (gnus-summary-select-article)
 618     (let (text)
 619       (save-excursion
 620         (set-buffer gnus-original-article-buffer)
 621         (setq text (buffer-string)))
 622       (set-buffer (gnus-get-buffer-create " *Gnus forward*"))
 623       (erase-buffer)
 624       (insert text)
 625       (run-hooks 'gnus-article-decode-hook)
 626       (let ((message-included-forward-headers
 627              (if full-headers "" message-included-forward-headers)))
 628         (message-forward post)))))
 629
 630 (defun gnus-summary-resend-message (address n)
 631   "Resend the current article to ADDRESS."
 632   (interactive "sResend message(s) to: \nP")
 633   (let ((articles (gnus-summary-work-articles n))
 634         article)
 635     (while (setq article (pop articles))
 636       (gnus-summary-select-article nil nil nil article)
 637       (save-excursion
 638         (set-buffer gnus-original-article-buffer)
 639         (message-resend address)))))
 640
 641 (defun gnus-summary-post-forward (&optional full-headers)
 642   "Forward the current article to a newsgroup.
 643 If FULL-HEADERS (the prefix), include full headers when forwarding."
 644   (interactive "P")
 645   (gnus-summary-mail-forward full-headers t))
 646
 647 (defvar gnus-nastygram-message
 648   "The following article was inappropriately posted to %s.\n\n"
 649   "Format string to insert in nastygrams.
 650 The current group name will be inserted at \"%s\".")
 651
 652 (defun gnus-summary-mail-nastygram (n)
 653   "Send a nastygram to the author of the current article."
 654   (interactive "P")
 655   (when (or gnus-expert-user
 656             (gnus-y-or-n-p
 657              "Really send a nastygram to the author of the current article? "))
 658     (let ((group gnus-newsgroup-name))
 659       (gnus-summary-reply-with-original n)
 660       (set-buffer gnus-message-buffer)
 661       (message-goto-body)
 662       (insert (format gnus-nastygram-message group))
 663       (message-send-and-exit))))
 664
 665 (defun gnus-summary-mail-crosspost-complaint (n)
 666   "Send a complaint about crossposting to the current article(s)."
 667   (interactive "P")
 668   (let ((articles (gnus-summary-work-articles n))
 669         article)
 670     (while (setq article (pop articles))
 671       (set-buffer gnus-summary-buffer)
 672       (gnus-summary-goto-subject article)
 673       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 674             newsgroups followup-to)
 675         (gnus-summary-select-article)
 676         (set-buffer gnus-original-article-buffer)
 677         (if (and (<= (length (message-tokenize-header
 678                               (setq newsgroups
 679                                     (mail-fetch-field "newsgroups"))
 680                               ", "))
 681                      1)
 682                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 683                      (not (member group (message-tokenize-header
 684                                          followup-to ", ")))))
 685             (if followup-to
 686                 (gnus-message 1 "Followup-to restricted")
 687               (gnus-message 1 "Not a crossposted article"))
 688           (set-buffer gnus-summary-buffer)
 689           (gnus-summary-reply-with-original 1)
 690           (set-buffer gnus-message-buffer)
 691           (message-goto-body)
 692           (insert (format gnus-crosspost-complaint newsgroups group))
 693           (message-goto-subject)
 694           (re-search-forward " *$")
 695           (replace-match " (crosspost notification)" t t)
 696           (gnus-deactivate-mark)
 697           (when (gnus-y-or-n-p "Send this complaint? ")
 698             (message-send-and-exit)))))))
 699
 700 (defun gnus-summary-mail-other-window ()
 701   "Compose mail in other window."
 702   (interactive)
 703   (gnus-setup-message 'message
 704     (message-mail)))
 705
 706 (defun gnus-mail-parse-comma-list ()
 707   (let (accumulated
 708         beg)
 709     (skip-chars-forward " ")
 710     (while (not (eobp))
 711       (setq beg (point))
 712       (skip-chars-forward "^,")
 713       (while (zerop
 714               (save-excursion
 715                 (save-restriction
 716                   (let ((i 0))
 717                     (narrow-to-region beg (point))
 718                     (goto-char beg)
 719                     (logand (progn
 720                               (while (search-forward "\"" nil t)
 721                                 (incf i))
 722                               (if (zerop i) 2 i))
 723                             2)))))
 724         (skip-chars-forward ",")
 725         (skip-chars-forward "^,"))
 726       (skip-chars-backward " ")
 727       (push (buffer-substring beg (point))
 728             accumulated)
 729       (skip-chars-forward "^,")
 730       (skip-chars-forward ", "))
 731     accumulated))
 732
 733 (defun gnus-inews-add-to-address (group)
 734   (let ((to-address (mail-fetch-field "to")))
 735     (when (and to-address
 736                (gnus-alive-p))
 737       ;; This mail group doesn't have a `to-list', so we add one
 738       ;; here.  Magic!
 739       (when (gnus-y-or-n-p
 740              (format "Do you want to add this as `to-list': %s " to-address))
 741         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 742
 743 (defun gnus-put-message ()
 744   "Put the current message in some group and return to Gnus."
 745   (interactive)
 746   (let ((reply gnus-article-reply)
 747         (winconf gnus-prev-winconf)
 748         (group gnus-newsgroup-name))
 749
 750     (or (and group (not (gnus-group-read-only-p group)))
 751         (setq group (read-string "Put in group: " nil
 752                                  (gnus-writable-groups))))
 753     (when (gnus-gethash group gnus-newsrc-hashtb)
 754       (error "No such group: %s" group))
 755
 756     (save-excursion
 757       (save-restriction
 758         (widen)
 759         (message-narrow-to-headers)
 760         (let (gnus-deletable-headers)
 761           (if (message-news-p)
 762               (message-generate-headers message-required-news-headers)
 763             (message-generate-headers message-required-mail-headers)))
 764         (goto-char (point-max))
 765         (insert "Gcc: " group "\n")
 766         (widen)))
 767
 768     (gnus-inews-do-gcc)
 769
 770     (when (get-buffer gnus-group-buffer)
 771       (when (gnus-buffer-exists-p (car-safe reply))
 772         (set-buffer (car reply))
 773         (and (cdr reply)
 774              (gnus-summary-mark-article-as-replied
 775               (cdr reply))))
 776       (when winconf
 777         (set-window-configuration winconf)))))
 778
 779 (defun gnus-article-mail (yank)
 780   "Send a reply to the address near point.
 781 If YANK is non-nil, include the original article."
 782   (interactive "P")
 783   (let ((address
 784          (buffer-substring
 785           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 786           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 787     (when address
 788       (message-reply address)
 789       (when yank
 790         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 791
 792 (defvar nntp-server-type)
 793 (defun gnus-bug ()
 794   "Send a bug report to the Gnus maintainers."
 795   (interactive)
 796   (unless (gnus-alive-p)
 797     (error "Gnus has been shut down"))
 798   (gnus-setup-message 'bug
 799     (delete-other-windows)
 800     (when gnus-bug-create-help-buffer
 801       (switch-to-buffer "*Gnus Help Bug*")
 802       (erase-buffer)
 803       (insert gnus-bug-message)
 804       (goto-char (point-min)))
 805     (message-pop-to-buffer "*Gnus Bug*")
 806     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 807     (when gnus-bug-create-help-buffer
 808       (push `(gnus-bug-kill-buffer) message-send-actions))
 809     (goto-char (point-min))
 810     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 811     (forward-line 1)
 812     (insert (gnus-version) "\n"
 813             (emacs-version) "\n")
 814     (when (and (boundp 'nntp-server-type)
 815                (stringp nntp-server-type))
 816       (insert nntp-server-type))
 817     (insert "\n\n\n\n\n")
 818     (gnus-debug)
 819     (goto-char (point-min))
 820     (search-forward "Subject: " nil t)
 821     (message "")))
 822
 823 (defun gnus-bug-kill-buffer ()
 824   (when (get-buffer "*Gnus Help Bug*")
 825     (kill-buffer "*Gnus Help Bug*")))
 826
 827 (defun gnus-debug ()
 828   "Attempts to go through the Gnus source file and report what variables have been changed.
 829 The source file has to be in the Emacs load path."
 830   (interactive)
 831   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 832                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 833                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 834                  "nnmail.el" "message.el"))
 835         (point (point))
 836         file expr olist sym)
 837     (gnus-message 4 "Please wait while we snoop your variables...")
 838     (sit-for 0)
 839     ;; Go through all the files looking for non-default values for variables.
 840     (save-excursion
 841       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
 842       (while files
 843         (erase-buffer)
 844         (when (and (setq file (locate-library (pop files)))
 845                    (file-exists-p file))
 846           (insert-file-contents file)
 847           (goto-char (point-min))
 848           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 849               (gnus-message 4 "Malformed sources in file %s" file)
 850             (narrow-to-region (point-min) (point))
 851             (goto-char (point-min))
 852             (while (setq expr (ignore-errors (read (current-buffer))))
 853               (ignore-errors
 854                 (and (or (eq (car expr) 'defvar)
 855                          (eq (car expr) 'defcustom))
 856                      (stringp (nth 3 expr))
 857                      (or (not (boundp (nth 1 expr)))
 858                          (not (equal (eval (nth 2 expr))
 859                                      (symbol-value (nth 1 expr)))))
 860                      (push (nth 1 expr) olist)))))))
 861       (kill-buffer (current-buffer)))
 862     (when (setq olist (nreverse olist))
 863       (insert "------------------ Environment follows ------------------\n\n"))
 864     (while olist
 865       (if (boundp (car olist))
 866           (condition-case ()
 867               (pp `(setq ,(car olist)
 868                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 869                                   (and (symbolp sym)
 870                                        (not (or (eq sym nil)
 871                                                 (eq sym t)))))
 872                               (list 'quote (symbol-value (car olist)))
 873                             (symbol-value (car olist))))
 874                   (current-buffer))
 875             (error
 876              (format "(setq %s 'whatever)\n" (car olist))))
 877         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 878       (setq olist (cdr olist)))
 879     (insert "\n\n")
 880     ;; Remove any control chars - they seem to cause trouble for some
 881     ;; mailers.  (Byte-compiled output from the stuff above.)
 882     (goto-char point)
 883     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 884       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 885                      t t))))
 886
 887 ;;; Treatment of rejected articles.
 888 ;;; Bounced mail.
 889
 890 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 891   "Re-mail the current message.
 892 This only makes sense if the current message is a bounce message than
 893 contains some mail you have written which has been bounced back to
 894 you.
 895 If FETCH, try to fetch the article that this is a reply to, if indeed
 896 this is a reply."
 897   (interactive "P")
 898   (gnus-summary-select-article t)
 899   (set-buffer gnus-original-article-buffer)
 900   (gnus-setup-message 'compose-bounce
 901     (let* ((references (mail-fetch-field "references"))
 902            (parent (and references (gnus-parent-id references))))
 903       (message-bounce)
 904       ;; If there are references, we fetch the article we answered to.
 905       (and fetch parent
 906            (gnus-summary-refer-article parent)
 907            (gnus-summary-show-all-headers)))))
 908
 909 ;;; Gcc handling.
 910
 911 ;; Do Gcc handling, which copied the message over to some group.
 912 (defun gnus-inews-do-gcc (&optional gcc)
 913   (interactive)
 914   (when (gnus-alive-p)
 915     (save-excursion
 916       (save-restriction
 917         (message-narrow-to-headers)
 918         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 919               (cur (current-buffer))
 920               groups group method)
 921           (when gcc
 922             (message-remove-header "gcc")
 923             (widen)
 924             (setq groups (message-tokenize-header gcc " ,"))
 925             ;; Copy the article over to some group(s).
 926             (while (setq group (pop groups))
 927               (gnus-check-server
 928                (setq method
 929                      (cond ((and (null (gnus-get-info group))
 930                                  (eq (car gnus-message-archive-method)
 931                                      (car
 932                                       (gnus-server-to-method
 933                                        (gnus-group-method group)))))
 934                             ;; If the group doesn't exist, we assume
 935                             ;; it's an archive group...
 936                             gnus-message-archive-method)
 937                            ;; Use the method.
 938                            ((gnus-info-method (gnus-get-info group))
 939                             (gnus-info-method (gnus-get-info group)))
 940                            ;; Find the method.
 941                            (t (gnus-group-method group)))))
 942               (gnus-check-server method)
 943               (unless (gnus-request-group group t method)
 944                 (gnus-request-create-group group method))
 945               (save-excursion
 946                 (nnheader-set-temp-buffer " *acc*")
 947                 (insert-buffer-substring cur)
 948                 (goto-char (point-min))
 949                 (when (re-search-forward
 950                        (concat "^" (regexp-quote mail-header-separator) "$")
 951                        nil t)
 952                   (replace-match "" t t ))
 953                 (unless (gnus-request-accept-article group method t t)
 954                   (gnus-message 1 "Couldn't store article in group %s: %s"
 955                                 group (gnus-status-message method))
 956                   (sit-for 2))
 957                 (kill-buffer (current-buffer))))))))))
 958
 959 (defun gnus-inews-insert-gcc ()
 960   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 961   (save-excursion
 962     (save-restriction
 963       (message-narrow-to-headers)
 964       (let* ((group gnus-outgoing-message-group)
 965              (gcc (cond
 966                    ((gnus-functionp group)
 967                     (funcall group))
 968                    ((or (stringp group) (list group))
 969                     group))))
 970         (when gcc
 971           (insert "Gcc: "
 972                   (if (stringp gcc) gcc
 973                     (mapconcat 'identity gcc " "))
 974                   "\n"))))))
 975
 976 (defun gnus-inews-insert-archive-gcc (&optional group)
 977   "Insert the Gcc to say where the article is to be archived."
 978   (let* ((var gnus-message-archive-group)
 979          (group (or group gnus-newsgroup-name ""))
 980          (gcc-self-val
 981           (and gnus-newsgroup-name
 982                (gnus-group-find-parameter
 983                 gnus-newsgroup-name 'gcc-self)))
 984          result
 985          (groups
 986           (cond
 987            ((null gnus-message-archive-method)
 988             ;; Ignore.
 989             nil)
 990            ((stringp var)
 991             ;; Just a single group.
 992             (list var))
 993            ((null var)
 994             ;; We don't want this.
 995             nil)
 996            ((and (listp var) (stringp (car var)))
 997             ;; A list of groups.
 998             var)
 999            ((gnus-functionp var)
1000             ;; A function.
1001             (funcall var group))
1002            (t
1003             ;; An alist of regexps/functions/forms.
1004             (while (and var
1005                         (not
1006                          (setq result
1007                                (cond
1008                                 ((stringp (caar var))
1009                                  ;; Regexp.
1010                                  (when (string-match (caar var) group)
1011                                    (cdar var)))
1012                                 ((gnus-functionp (car var))
1013                                  ;; Function.
1014                                  (funcall (car var) group))
1015                                 (t
1016                                  (eval (car var)))))))
1017               (setq var (cdr var)))
1018             result)))
1019          name)
1020     (when (or groups gcc-self-val)
1021       (when (stringp groups)
1022         (setq groups (list groups)))
1023       (save-excursion
1024         (save-restriction
1025           (message-narrow-to-headers)
1026           (goto-char (point-max))
1027           (insert "Gcc: ")
1028           (if gcc-self-val
1029               ;; Use the `gcc-self' param value instead.
1030               (progn
1031                 (insert
1032                  (if (stringp gcc-self-val)
1033                      gcc-self-val
1034                    group))
1035                 (if (not (eq gcc-self-val 'none))
1036                     (insert "\n")
1037                   (progn
1038                     (beginning-of-line)
1039                     (kill-line))))
1040             ;; Use the list of groups.
1041             (while (setq name (pop groups))
1042               (insert (if (string-match ":" name)
1043                           name
1044                         (gnus-group-prefixed-name
1045                          name gnus-message-archive-method)))
1046               (when groups
1047                 (insert " ")))
1048             (insert "\n")))))))
1049
1050 ;;; Posting styles.
1051
1052 (defvar gnus-message-style-insertions nil)
1053
1054 (defun gnus-configure-posting-styles ()
1055   "Configure posting styles according to `gnus-posting-styles'."
1056   (unless gnus-inhibit-posting-styles
1057     (let ((styles gnus-posting-styles)
1058           (gnus-newsgroup-name (or gnus-newsgroup-name ""))
1059           style match variable attribute value value-value)
1060       (make-local-variable 'gnus-message-style-insertions)
1061       ;; Go through all styles and look for matches.
1062       (while styles
1063         (setq style (pop styles)
1064               match (pop style))
1065         (when (cond ((stringp match)
1066                      ;; Regexp string match on the group name.
1067                      (string-match match gnus-newsgroup-name))
1068                     ((or (symbolp match)
1069                          (gnus-functionp match))
1070                      (cond ((gnus-functionp match)
1071                             ;; Function to be called.
1072                             (funcall match))
1073                            ((boundp match)
1074                             ;; Variable to be checked.
1075                             (symbol-value match))))
1076                     ((listp match)
1077                      ;; This is a form to be evaled.
1078                      (eval match)))
1079           ;; We have a match, so we set the variables.
1080           (while style
1081             (setq attribute (pop style)
1082                   value (cadr attribute)
1083                   variable nil)
1084             ;; We find the variable that is to be modified.
1085             (if (and (not (stringp (car attribute)))
1086                      (not (eq 'body (car attribute)))
1087                      (not (setq variable
1088                                 (cdr (assq (car attribute)
1089                                            gnus-posting-style-alist)))))
1090                 (message "Couldn't find attribute %s" (car attribute))
1091               ;; We get the value.
1092               (setq value-value
1093                     (cond ((stringp value)
1094                            value)
1095                           ((or (symbolp value)
1096                                (gnus-functionp value))
1097                            (cond ((gnus-functionp value)
1098                                   (funcall value))
1099                                  ((boundp value)
1100                                   (symbol-value value))))
1101                           ((listp value)
1102                            (eval value))))
1103               (if variable
1104                   ;; This is an ordinary variable.
1105                   (set (make-local-variable variable) value-value)
1106                 ;; This is either a body or a header to be inserted in the
1107                 ;; message.
1108                 (when value-value
1109                   (let ((attr (car attribute)))
1110                     (make-local-variable 'message-setup-hook)
1111                     (if (eq 'body attr)
1112                         (add-hook 'message-setup-hook
1113                                   `(lambda ()
1114                                      (save-excursion
1115                                        (message-goto-body)
1116                                        (insert ,value-value))))
1117                       (add-hook 'message-setup-hook
1118                                 'gnus-message-insert-stylings)
1119                       (push (cons (if (stringp attr) attr
1120                                     (symbol-name attr))
1121                                   value-value)
1122                             gnus-message-style-insertions))))))))))))
1123
1124 (defun gnus-message-insert-stylings ()
1125   (let (val)
1126     (save-excursion
1127       (message-goto-eoh)
1128       (while (setq val (pop gnus-message-style-insertions))
1129         (when (cdr val)
1130           (insert (car val) ": " (cdr val) "\n"))
1131         (gnus-pull (car val) gnus-message-style-insertions)))))
1132
1133 ;;; Allow redefinition of functions.
1134
1135 (gnus-ems-redefine)
1136
1137 (provide 'gnus-msg)
1138
1139 ;;; gnus-msg.el ends here