cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-int)
  30 (require 'gnus)
  31
  32 (defvar gnus-demon-handlers nil
  33   "Alist of daemonic handlers to be run at intervals.
  34 Each handler is a list on the form
  35
  36 \(FUNCTION TIME IDLE)
  37
  38 FUNCTION is the function to be called.
  39 TIME is the number of `gnus-demon-timestep's between each call.
  40 If nil, never call.  If t, call each `gnus-demon-timestep'.
  41 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  42 is a number, only call when Emacs has been idle more than this number
  43 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  44 idleness.  If IDLE is a number and TIME is nil, then call once each
  45 time Emacs has been idle for IDLE `gnus-demon-timestep's.")
  46
  47 (defvar gnus-demon-timestep 60
  48   "*Number of seconds in each demon timestep.")
  49
  50 ;;; Internal variables.
  51
  52 (defvar gnus-demon-timer nil)
  53 (defvar gnus-demon-idle-has-been-called nil)
  54 (defvar gnus-demon-idle-time 0)
  55 (defvar gnus-demon-handler-state nil)
  56 (defvar gnus-demon-is-idle nil)
  57 (defvar gnus-demon-last-keys nil)
  58
  59 (eval-and-compile
  60   (autoload 'timezone-parse-date "timezone")
  61   (autoload 'timezone-make-arpa-date "timezone"))
  62
  63 ;;; Functions.
  64
  65 (defun gnus-demon-add-handler (function time idle)
  66   "Add the handler FUNCTION to be run at TIME and IDLE."
  67   ;; First remove any old handlers that use this function.
  68   (gnus-demon-remove-handler function)
  69   ;; Then add the new one.
  70   (push (list function time idle) gnus-demon-handlers)
  71   (gnus-demon-init))
  72
  73 (defun gnus-demon-remove-handler (function &optional no-init)
  74   "Remove the handler FUNCTION from the list of handlers."
  75   (setq gnus-demon-handlers
  76         (delq (assq function gnus-demon-handlers)
  77               gnus-demon-handlers))
  78   (or no-init (gnus-demon-init)))
  79
  80 (defun gnus-demon-init ()
  81   "Initialize the Gnus daemon."
  82   (interactive)
  83   (gnus-demon-cancel)
  84   (if (null gnus-demon-handlers)
  85       () ; Nothing to do.
  86     ;; Set up timer.
  87     (setq gnus-demon-timer
  88           (nnheader-run-at-time
  89            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
  90     ;; Reset control variables.
  91     (setq gnus-demon-handler-state
  92           (mapcar
  93            (lambda (handler)
  94              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
  95                    (nth 2 handler)))
  96            gnus-demon-handlers))
  97     (setq gnus-demon-idle-time 0)
  98     (setq gnus-demon-idle-has-been-called nil)
  99     (setq gnus-use-demon t)))
 100
 101 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 102
 103 (defun gnus-demon-cancel ()
 104   "Cancel any Gnus daemons."
 105   (interactive)
 106   (and gnus-demon-timer
 107        (nnheader-cancel-timer gnus-demon-timer))
 108   (setq gnus-demon-timer nil
 109         gnus-use-demon nil)
 110   (nnheader-cancel-function-timers 'gnus-demon))
 111
 112 (defun gnus-demon-is-idle-p ()
 113   "Whether Emacs is idle or not."
 114   ;; We do this simply by comparing the 100 most recent keystrokes
 115   ;; with the ones we had last time.  If they are the same, one might
 116   ;; guess that Emacs is indeed idle.  This only makes sense if one
 117   ;; calls this function seldom -- like once a minute, which is what
 118   ;; we do here.
 119   (let ((keys (recent-keys)))
 120     (or (equal keys gnus-demon-last-keys)
 121         (progn
 122           (setq gnus-demon-last-keys keys)
 123           nil))))
 124
 125 (defun gnus-demon-time-to-step (time)
 126   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 127   (if (not (stringp time))
 128       time
 129     (let* ((date (current-time-string))
 130            (dv (timezone-parse-date date))
 131            (tdate (timezone-make-arpa-date
 132                    (string-to-number (aref dv 0))
 133                    (string-to-number (aref dv 1))
 134                    (string-to-number (aref dv 2)) time
 135                    (or (aref dv 4) "UT")))
 136            (nseconds (gnus-time-minus
 137                       (gnus-encode-date tdate) (gnus-encode-date date))))
 138       (round
 139        (/ (if (< nseconds 0)
 140               (+ nseconds (* 60 60 24))
 141             nseconds) gnus-demon-timestep)))))
 142
 143 (defun gnus-demon ()
 144   "The Gnus daemon that takes care of running all Gnus handlers."
 145   ;; Increase or reset the time Emacs has been idle.
 146   (if (gnus-demon-is-idle-p)
 147       (incf gnus-demon-idle-time)
 148     (setq gnus-demon-idle-time 0)
 149     (setq gnus-demon-idle-has-been-called nil))
 150   ;; Then we go through all the handler and call those that are
 151   ;; sufficiently ripe.
 152   (let ((handlers gnus-demon-handler-state)
 153         handler time idle)
 154     (while handlers
 155       (setq handler (pop handlers))
 156       (cond
 157        ((numberp (setq time (nth 1 handler)))
 158         ;; These handlers use a regular timeout mechanism.  We decrease
 159         ;; the timer if it hasn't reached zero yet.
 160         (or (zerop time)
 161             (setcar (nthcdr 1 handler) (decf time)))
 162         (and (zerop time)               ; If the timer now is zero...
 163              (or (not (setq idle (nth 2 handler))) ; Don't care about idle.
 164                  (and (numberp idle)    ; Numerical idle...
 165                       (< idle gnus-demon-idle-time)) ; Idle timed out.
 166                  gnus-demon-is-idle)    ; Or just need to be idle.
 167              ;; So we call the handler.
 168              (progn
 169                (funcall (car handler))
 170                ;; And reset the timer.
 171                (setcar (nthcdr 1 handler)
 172                        (gnus-demon-time-to-step
 173                         (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 174        ;; These are only supposed to be called when Emacs is idle.
 175        ((null (setq idle (nth 2 handler)))
 176         ;; We do nothing.
 177         )
 178        ((not (numberp idle))
 179         ;; We want to call this handler each and every time that
 180         ;; Emacs is idle.
 181         (funcall (car handler)))
 182        (t
 183         ;; We want to call this handler only if Emacs has been idle
 184         ;; for a specified number of timesteps.
 185         (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 186              (< idle gnus-demon-idle-time)
 187              (progn
 188                (funcall (car handler))
 189                ;; Make sure the handler won't be called once more in
 190                ;; this idle-cycle.
 191                (push (car handler) gnus-demon-idle-has-been-called))))))))
 192
 193 (defun gnus-demon-add-nocem ()
 194   "Add daemonic NoCeM handling to Gnus."
 195   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 t))
 196
 197 (defun gnus-demon-scan-nocem ()
 198   "Scan NoCeM groups for NoCeM messages."
 199   (gnus-nocem-scan-groups))
 200
 201 (defun gnus-demon-add-disconnection ()
 202   "Add daemonic server disconnection to Gnus."
 203   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 204
 205 (defun gnus-demon-close-connections ()
 206   (gnus-close-backends))
 207
 208 (defun gnus-demon-add-scanmail ()
 209   "Add daemonic scanning of mail from the mail backends."
 210   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 211
 212 (defun gnus-demon-scan-mail ()
 213   (let ((servers gnus-opened-servers)
 214         server)
 215     (while (setq server (car (pop servers)))
 216       (and (gnus-check-backend-function 'request-scan (car server))
 217            (or (gnus-server-opened server)
 218                (gnus-open-server server))
 219            (gnus-request-scan nil server)))))
 220
 221 (provide 'gnus-demon)
 222
 223 ;;; gnus-demon.el ends here