cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-int)
  30 (require 'nnheader)
  31 (require 'gnus)
  32 (eval-and-compile
  33   (if (string-match "XEmacs" (emacs-version))
  34       (require 'itimer)
  35     (require 'timer)))
  36
  37 (defvar gnus-demon-handlers nil
  38   "Alist of daemonic handlers to be run at intervals.
  39 Each handler is a list on the form
  40
  41 \(FUNCTION TIME IDLE)
  42
  43 FUNCTION is the function to be called.
  44 TIME is the number of `gnus-demon-timestep's between each call.
  45 If nil, never call.  If t, call each `gnus-demon-timestep'.
  46 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  47 is a number, only call when Emacs has been idle more than this number
  48 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  49 idleness.  If IDLE is a number and TIME is nil, then call once each
  50 time Emacs has been idle for IDLE `gnus-demon-timestep's.")
  51
  52 (defvar gnus-demon-timestep 60
  53   "*Number of seconds in each demon timestep.")
  54
  55 ;;; Internal variables.
  56
  57 (defvar gnus-demon-timer nil)
  58 (defvar gnus-demon-idle-has-been-called nil)
  59 (defvar gnus-demon-idle-time 0)
  60 (defvar gnus-demon-handler-state nil)
  61 (defvar gnus-demon-is-idle nil)
  62 (defvar gnus-demon-last-keys nil)
  63
  64 (eval-and-compile
  65   (autoload 'timezone-parse-date "timezone")
  66   (autoload 'timezone-make-arpa-date "timezone"))
  67
  68 ;;; Functions.
  69
  70 (defun gnus-demon-add-handler (function time idle)
  71   "Add the handler FUNCTION to be run at TIME and IDLE."
  72   ;; First remove any old handlers that use this function.
  73   (gnus-demon-remove-handler function)
  74   ;; Then add the new one.
  75   (push (list function time idle) gnus-demon-handlers)
  76   (gnus-demon-init))
  77
  78 (defun gnus-demon-remove-handler (function &optional no-init)
  79   "Remove the handler FUNCTION from the list of handlers."
  80   (setq gnus-demon-handlers
  81         (delq (assq function gnus-demon-handlers)
  82               gnus-demon-handlers))
  83   (or no-init (gnus-demon-init)))
  84
  85 (defun gnus-demon-init ()
  86   "Initialize the Gnus daemon."
  87   (interactive)
  88   (gnus-demon-cancel)
  89   (if (null gnus-demon-handlers)
  90       ()                                ; Nothing to do.
  91     ;; Set up timer.
  92     (setq gnus-demon-timer
  93           (nnheader-run-at-time
  94            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
  95     ;; Reset control variables.
  96     (setq gnus-demon-handler-state
  97           (mapcar
  98            (lambda (handler)
  99              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
 100                    (nth 2 handler)))
 101            gnus-demon-handlers))
 102     (setq gnus-demon-idle-time 0)
 103     (setq gnus-demon-idle-has-been-called nil)
 104     (setq gnus-use-demon t)))
 105
 106 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 107
 108 (defun gnus-demon-cancel ()
 109   "Cancel any Gnus daemons."
 110   (interactive)
 111   (and gnus-demon-timer
 112        (nnheader-cancel-timer gnus-demon-timer))
 113   (setq gnus-demon-timer nil
 114         gnus-use-demon nil)
 115   (condition-case ()
 116       (nnheader-cancel-function-timers 'gnus-demon)
 117     (error t)))
 118
 119 (defun gnus-demon-is-idle-p ()
 120   "Whether Emacs is idle or not."
 121   ;; We do this simply by comparing the 100 most recent keystrokes
 122   ;; with the ones we had last time.  If they are the same, one might
 123   ;; guess that Emacs is indeed idle.  This only makes sense if one
 124   ;; calls this function seldom -- like once a minute, which is what
 125   ;; we do here.
 126   (let ((keys (recent-keys)))
 127     (or (equal keys gnus-demon-last-keys)
 128         (progn
 129           (setq gnus-demon-last-keys keys)
 130           nil))))
 131
 132 (defun gnus-demon-time-to-step (time)
 133   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 134   (if (not (stringp time))
 135       time
 136     (let* ((date (current-time-string))
 137            (dv (timezone-parse-date date))
 138            (tdate (timezone-make-arpa-date
 139                    (string-to-number (aref dv 0))
 140                    (string-to-number (aref dv 1))
 141                    (string-to-number (aref dv 2)) time
 142                    (or (aref dv 4) "UT")))
 143            (nseconds (gnus-time-minus
 144                       (gnus-encode-date tdate) (gnus-encode-date date))))
 145       (round
 146        (/ (if (< nseconds 0)
 147               (+ nseconds (* 60 60 24))
 148             nseconds) gnus-demon-timestep)))))
 149
 150 (defun gnus-demon ()
 151   "The Gnus daemon that takes care of running all Gnus handlers."
 152   ;; Increase or reset the time Emacs has been idle.
 153   (if (gnus-demon-is-idle-p)
 154       (incf gnus-demon-idle-time)
 155     (setq gnus-demon-idle-time 0)
 156     (setq gnus-demon-idle-has-been-called nil))
 157   ;; Then we go through all the handler and call those that are
 158   ;; sufficiently ripe.
 159   (let ((handlers gnus-demon-handler-state)
 160         handler time idle)
 161     (while handlers
 162       (setq handler (pop handlers))
 163       (cond
 164        ((numberp (setq time (nth 1 handler)))
 165         ;; These handlers use a regular timeout mechanism.  We decrease
 166         ;; the timer if it hasn't reached zero yet.
 167         (or (zerop time)
 168             (setcar (nthcdr 1 handler) (decf time)))
 169         (and (zerop time)               ; If the timer now is zero...
 170              (or (not (setq idle (nth 2 handler))) ; Don't care about idle.
 171                  (and (numberp idle)    ; Numerical idle...
 172                       (< idle gnus-demon-idle-time)) ; Idle timed out.
 173                  gnus-demon-is-idle)    ; Or just need to be idle.
 174              ;; So we call the handler.
 175              (progn
 176                (funcall (car handler))
 177                ;; And reset the timer.
 178                (setcar (nthcdr 1 handler)
 179                        (gnus-demon-time-to-step
 180                         (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 181        ;; These are only supposed to be called when Emacs is idle.
 182        ((null (setq idle (nth 2 handler)))
 183         ;; We do nothing.
 184         )
 185        ((not (numberp idle))
 186         ;; We want to call this handler each and every time that
 187         ;; Emacs is idle.
 188         (funcall (car handler)))
 189        (t
 190         ;; We want to call this handler only if Emacs has been idle
 191         ;; for a specified number of timesteps.
 192         (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 193              (< idle gnus-demon-idle-time)
 194              (progn
 195                (funcall (car handler))
 196                ;; Make sure the handler won't be called once more in
 197                ;; this idle-cycle.
 198                (push (car handler) gnus-demon-idle-has-been-called))))))))
 199
 200 (defun gnus-demon-add-nocem ()
 201   "Add daemonic NoCeM handling to Gnus."
 202   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 t))
 203
 204 (defun gnus-demon-scan-nocem ()
 205   "Scan NoCeM groups for NoCeM messages."
 206   (gnus-nocem-scan-groups))
 207
 208 (defun gnus-demon-add-disconnection ()
 209   "Add daemonic server disconnection to Gnus."
 210   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 211
 212 (defun gnus-demon-close-connections ()
 213   (gnus-close-backends))
 214
 215 (defun gnus-demon-add-scanmail ()
 216   "Add daemonic scanning of mail from the mail backends."
 217   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 218
 219 (defun gnus-demon-scan-mail ()
 220   (let ((servers gnus-opened-servers)
 221         server)
 222     (while (setq server (car (pop servers)))
 223       (and (gnus-check-backend-function 'request-scan (car server))
 224            (or (gnus-server-opened server)
 225                (gnus-open-server server))
 226            (gnus-request-scan nil server)))))
 227
 228 (defun gnus-demon-add-rescan ()
 229   "Add daemonic scanning of new articles from all backends."
 230   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 231
 232 (defun gnus-demon-scan-news ()
 233   (when (gnus-alive-p)
 234     (save-excursion
 235       (set-buffer gnus-group-buffer)
 236       (gnus-group-get-new-news))))
 237
 238 (provide 'gnus-demon)
 239
 240 ;;; gnus-demon.el ends here