cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cus.el

   1 ;;; gnus-cus.el --- customization commands for Gnus
   2 ;;
   3 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'wid-edit)
  30 (require 'gnus-score)
  31
  32 ;;; Widgets:
  33
  34 ;; There should be special validation for this.
  35 (define-widget 'gnus-email-address 'string
  36   "An email address")
  37
  38 (defun gnus-custom-mode ()
  39   "Major mode for editing Gnus customization buffers.
  40
  41 The following commands are available:
  42
  43 \\[widget-forward]              Move to next button or editable field.
  44 \\[widget-backward]             Move to previous button or editable field.
  45 \\[widget-button-click]         Activate button under the mouse pointer.
  46 \\[widget-button-press]         Activate button under point.
  47
  48 Entry to this mode calls the value of `gnus-custom-mode-hook'
  49 if that value is non-nil."
  50   (kill-all-local-variables)
  51   (setq major-mode 'gnus-custom-mode
  52         mode-name "Gnus Customize")
  53   (use-local-map widget-keymap)
  54   (gnus-run-hooks 'gnus-custom-mode-hook))
  55
  56 ;;; Group Customization:
  57
  58 (defconst gnus-group-parameters
  59   '((to-address (gnus-email-address :tag "To Address") "\
  60 This will be used when doing followups and posts.
  61
  62 This is primarily useful in mail groups that represent closed
  63 mailing lists--mailing lists where it's expected that everybody that
  64 writes to the mailing list is subscribed to it.  Since using this
  65 parameter ensures that the mail only goes to the mailing list itself,
  66 it means that members won't receive two copies of your followups.
  67
  68 Using `to-address' will actually work whether the group is foreign or
  69 not.  Let's say there's a group on the server that is called
  70 `fa.4ad-l'.  This is a real newsgroup, but the server has gotten the
  71 articles from a mail-to-news gateway.  Posting directly to this group
  72 is therefore impossible--you have to send mail to the mailing list
  73 address instead.")
  74
  75     (to-list (gnus-email-address :tag "To List") "\
  76 This address will be used when doing a `a' in the group.
  77
  78 It is totally ignored when doing a followup--except that if it is
  79 present in a news group, you'll get mail group semantics when doing
  80 `f'.")
  81
  82     (broken-reply-to (const :tag "Broken Reply To" t) "\
  83 Ignore `Reply-To' headers in this group.
  84
  85 That can be useful if you're reading a mailing list group where the
  86 listserv has inserted `Reply-To' headers that point back to the
  87 listserv itself.  This is broken behavior.  So there!")
  88
  89     (to-group (string :tag "To Group") "\
  90 All posts will be send to the specified group.")
  91
  92     (gcc-self (choice :tag  "GCC"
  93                       :value t
  94                       (const t)
  95                       (const none)
  96                       (string :format "%v" :hide-front-space t)) "\
  97 Specify default value for GCC header.
  98
  99 If this symbol is present in the group parameter list and set to `t',
 100 new composed messages will be `Gcc''d to the current group. If it is
 101 present and set to `none', no `Gcc:' header will be generated, if it
 102 is present and a string, this string will be inserted literally as a
 103 `gcc' header (this symbol takes precedence over any default `Gcc'
 104 rules as described later).")
 105
 106     (auto-expire (const :tag "Automatic Expire" t) "\
 107 All articles that are read will be marked as expirable.")
 108
 109     (total-expire (const :tag "Total Expire" t) "\
 110 All read articles will be put through the expiry process
 111
 112 This happens even if they are not marked as expirable.
 113 Use with caution.")
 114
 115     (expiry-wait (choice :tag  "Expire Wait"
 116                          :value never
 117                          (const never)
 118                          (const immediate)
 119                          (number :hide-front-space t
 120                                  :format "%v")) "\
 121 When to expire.
 122
 123 Overrides any `nnmail-expiry-wait' and `nnmail-expiry-wait-function'
 124 when expiring expirable messages. The value can either be a number of
 125 days (not necessarily an integer) or the symbols `never' or
 126 `immediate'.")
 127
 128     (score-file (file :tag "Score File") "\
 129 Make the specified file into the current score file.
 130 This means that all score commands you issue will end up in this file.")
 131
 132     (adapt-file (file :tag "Adapt File") "\
 133 Make the specified file into the current adaptive file.
 134 All adaptive score entries will be put into this file.")
 135
 136     (admin-address (gnus-email-address :tag "Admin Address") "\
 137 Administration address for a mailing list.
 138
 139 When unsubscribing to a mailing list you should never send the
 140 unsubscription notice to the mailing list itself.  Instead, you'd
 141 send messages to the administrative address.  This parameter allows
 142 you to put the admin address somewhere convenient.")
 143
 144     (display (choice :tag "Display"
 145                      :value default
 146                      (const all)
 147                      (const default)) "\
 148 Which articles to display on entering the group.
 149
 150 `all'
 151      Display all articles, both read and unread.
 152
 153 `default'
 154      Display the default visible articles, which normally includes
 155      unread and ticked articles.")
 156
 157     (comment (string :tag  "Comment") "\
 158 An arbitrary comment on the group.")
 159
 160     (visible (const :tag "Permanently visible" t) "\
 161 Always display this group, even when there are no unread articles
 162 in it.."))
 163   "Alist of valid group parameters.
 164
 165 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 166 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 167 DOC is a documentation string for the parameter.")
 168
 169 (defvar gnus-custom-params)
 170 (defvar gnus-custom-method)
 171 (defvar gnus-custom-group)
 172
 173 (defun gnus-group-customize (group &optional part)
 174   "Edit the group on the current line."
 175   (interactive (list (gnus-group-group-name)))
 176   (let ((part (or part 'info))
 177         info
 178         (types (mapcar (lambda (entry)
 179                          `(cons :format "%v%h\n"
 180                                 :doc ,(nth 2 entry)
 181                                 (const :format "" ,(nth 0 entry))
 182                                 ,(nth 1 entry)))
 183                        gnus-group-parameters)))
 184     (unless group
 185       (error "No group on current line"))
 186     (unless (setq info (gnus-get-info group))
 187       (error "Killed group; can't be edited"))
 188     ;; Ready.
 189     (kill-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 190     (switch-to-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 191     (gnus-custom-mode)
 192     (make-local-variable 'gnus-custom-group)
 193     (setq gnus-custom-group group)
 194     (widget-insert "Customize the ")
 195     (widget-create 'info-link
 196                    :help-echo "Push me to learn more."
 197                    :tag "group parameters"
 198                    "(gnus)Group Parameters")
 199     (widget-insert " for <")
 200     (widget-insert group)
 201     (widget-insert "> and press ")
 202     (widget-create 'push-button
 203                    :tag "done"
 204                    :help-echo "Push me when done customizing."
 205                    :action 'gnus-group-customize-done)
 206     (widget-insert ".\n\n")
 207     (make-local-variable 'gnus-custom-params)
 208     (setq gnus-custom-params
 209           (widget-create 'group
 210                          :value (gnus-info-params info)
 211                          `(set :inline t
 212                                :greedy t
 213                                :tag "Parameters"
 214                                :format "%t:\n%h%v"
 215                                :doc "\
 216 These special paramerters are recognized by Gnus.
 217 Check the [ ] for the parameters you want to apply to this group, then
 218 edit the value to suit your taste."
 219                                ,@types)
 220                          '(repeat :inline t
 221                                   :tag "Variables"
 222                                   :format "%t:\n%h%v%i\n\n"
 223                                   :doc "\
 224 Set variables local to the group you are entering.
 225
 226 If you want to turn threading off in `news.answers', you could put
 227 `(gnus-show-threads nil)' in the group parameters of that group.
 228 `gnus-show-threads' will be made into a local variable in the summary
 229 buffer you enter, and the form `nil' will be `eval'ed there.
 230
 231 This can also be used as a group-specific hook function, if you'd
 232 like.  If you want to hear a beep when you enter a group, you could
 233 put something like `(dummy-variable (ding))' in the parameters of that
 234 group.  `dummy-variable' will be set to the result of the `(ding)'
 235 form, but who cares?"
 236                                   (group :value (nil nil)
 237                                          (symbol :tag "Variable")
 238                                          (sexp :tag
 239                                                "Value")))
 240
 241                          '(repeat :inline t
 242                                   :tag "Unknown entries"
 243                                   sexp)))
 244     (widget-insert "\n\nYou can also edit the ")
 245     (widget-create 'info-link
 246                    :tag "select method"
 247                    :help-echo "Push me to learn more about select methods."
 248                    "(gnus)Select Methods")
 249     (widget-insert " for the group.\n")
 250     (setq gnus-custom-method
 251           (widget-create 'sexp
 252                          :tag "Method"
 253                          :value (gnus-info-method info)))
 254     (use-local-map widget-keymap)
 255     (widget-setup)))
 256
 257 (defun gnus-group-customize-done (&rest ignore)
 258   "Apply changes and bury the buffer."
 259   (interactive)
 260   (gnus-group-edit-group-done 'params gnus-custom-group
 261                               (widget-value gnus-custom-params))
 262   (gnus-group-edit-group-done 'method gnus-custom-group
 263                               (widget-value gnus-custom-method))
 264   (bury-buffer))
 265
 266 ;;; Score Customization:
 267
 268 (defconst gnus-score-parameters
 269   '((mark (number :tag "Mark") "\
 270 The value of this entry should be a number.
 271 Any articles with a score lower than this number will be marked as read.")
 272
 273     (expunge (number :tag "Expunge") "\
 274 The value of this entry should be a number.
 275 Any articles with a score lower than this number will be removed from
 276 the summary buffer.")
 277
 278     (mark-and-expunge (number :tag "Mark-and-expunge") "\
 279 The value of this entry should be a number.
 280 Any articles with a score lower than this number will be marked as
 281 read and removed from the summary buffer.")
 282
 283     (thread-mark-and-expunge (number :tag "Thread-mark-and-expunge") "\
 284 The value of this entry should be a number.
 285 All articles that belong to a thread that has a total score below this
 286 number will be marked as read and removed from the summary buffer.
 287 `gnus-thread-score-function' says how to compute the total score
 288 for a thread.")
 289
 290     (files (repeat :inline t :tag "Files" file) "\
 291 The value of this entry should be any number of file names.
 292 These files are assumed to be score files as well, and will be loaded
 293 the same way this one was.")
 294
 295     (exclude-files (repeat :inline t :tag "Exclude-files" file) "\
 296 The clue of this entry should be any number of files.
 297 These files will not be loaded, even though they would normally be so,
 298 for some reason or other.")
 299
 300     (eval (sexp :tag "Eval" :value nil) "\
 301 The value of this entry will be `eval'el.
 302 This element will be ignored when handling global score files.")
 303
 304     (read-only (boolean :tag "Read-only" :value t) "\
 305 Read-only score files will not be updated or saved.
 306 Global score files should feature this atom.")
 307
 308     (orphan (number :tag "Orphan") "\
 309 The value of this entry should be a number.
 310 Articles that do not have parents will get this number added to their
 311 scores.  Imagine you follow some high-volume newsgroup, like
 312 `comp.lang.c'.  Most likely you will only follow a few of the threads,
 313 also want to see any new threads.
 314
 315 You can do this with the following two score file entries:
 316
 317      (orphan -500)
 318      (mark-and-expunge -100)
 319
 320 When you enter the group the first time, you will only see the new
 321 threads.  You then raise the score of the threads that you find
 322 interesting (with `I T' or `I S'), and ignore (`C y') the rest.
 323 Next time you enter the group, you will see new articles in the
 324 interesting threads, plus any new threads.
 325
 326 I.e.---the orphan score atom is for high-volume groups where there
 327 exist a few interesting threads which can't be found automatically
 328 by ordinary scoring rules.")
 329
 330     (adapt (choice :tag "Adapt"
 331                    (const t)
 332                    (const ignore)
 333                    (sexp :format "%v"
 334                          :hide-front-space t)) "\
 335 This entry controls the adaptive scoring.
 336 If it is `t', the default adaptive scoring rules will be used.  If it
 337 is `ignore', no adaptive scoring will be performed on this group.  If
 338 it is a list, this list will be used as the adaptive scoring rules.
 339 If it isn't present, or is something other than `t' or `ignore', the
 340 default adaptive scoring rules will be used.  If you want to use
 341 adaptive scoring on most groups, you'd set `gnus-use-adaptive-scoring'
 342 to `t', and insert an `(adapt ignore)' in the groups where you do not
 343 want adaptive scoring.  If you only want adaptive scoring in a few
 344 groups, you'd set `gnus-use-adaptive-scoring' to `nil', and insert
 345 `(adapt t)' in the score files of the groups where you want it.")
 346
 347     (adapt-file (file :tag "Adapt-file") "\
 348 All adaptive score entries will go to the file named by this entry.
 349 It will also be applied when entering the group.  This atom might
 350 be handy if you want to adapt on several groups at once, using the
 351 same adaptive file for a number of groups.")
 352
 353     (local (repeat :tag "Local"
 354                    (group :value (nil nil)
 355                           (symbol :tag "Variable")
 356                           (sexp :tag "Value"))) "\
 357 The value of this entry should be a list of `(VAR VALUE)' pairs.
 358 Each VAR will be made buffer-local to the current summary buffer,
 359 and set to the value specified.  This is a convenient, if somewhat
 360 strange, way of setting variables in some groups if you don't like
 361 hooks much.")
 362     (touched (sexp :format "Touched\n") "Internal variable."))
 363   "Alist of valid symbolic score parameters.
 364
 365 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 366 itself (a symbol), TYPE is the parameters type (a sexp widget), and DOC is a
 367 documentation string for the parameter.")
 368
 369 (define-widget 'gnus-score-string 'group
 370   "Edit score entries for string-valued headers."
 371   :convert-widget 'gnus-score-string-convert)
 372
 373 (defun gnus-score-string-convert (widget)
 374   ;; Set args appropriately.
 375   (let* ((tag (widget-get widget :tag))
 376          (item `(const :format "" :value ,(downcase tag)))
 377          (match '(string :tag "Match"))
 378          (score '(choice :tag "Score"
 379                         (const :tag "default" nil)
 380                         (integer :format "%v"
 381                                  :hide-front-space t)))
 382          (expire '(choice :tag "Expire"
 383                           (const :tag "off" nil)
 384                           (integer :format "%v"
 385                                    :hide-front-space t)))
 386          (type '(choice :tag "Type"
 387                         :value s
 388                         ;; I should really create a forgiving :match
 389                         ;; function for each type below, that only
 390                         ;; looked at the first letter.
 391                         (const :tag "Regexp" r)
 392                         (const :tag "Regexp (fixed case)" R)
 393                         (const :tag "Substring" s)
 394                         (const :tag "Substring (fixed case)" S)
 395                         (const :tag "Exact" e)
 396                         (const :tag "Exact (fixed case)" E)
 397                         (const :tag "Word" w)
 398                         (const :tag "Word (fixed case)" W)
 399                         (const :tag "default" nil)))
 400          (group `(group ,match ,score ,expire ,type))
 401          (doc (concat (or (widget-get widget :doc)
 402                           (concat "Change score based on the " tag
 403                                   " header.\n"))
 404                       "
 405 You can have an arbitrary number of score entries for this header,
 406 each score entry has four elements:
 407
 408 1. The \"match element\".  This should be the string to look for in the
 409    header.
 410
 411 2. The \"score element\".  This number should be an integer in the
 412    neginf to posinf interval.  This number is added to the score
 413    of the article if the match is successful.  If this element is
 414    not present, the `gnus-score-interactive-default-score' number
 415    will be used instead.  This is 1000 by default.
 416
 417 3. The \"date element\".  This date says when the last time this score
 418    entry matched, which provides a mechanism for expiring the
 419    score entries.  It this element is not present, the score
 420    entry is permanent.  The date is represented by the number of
 421    days since December 31, 1 ce.
 422
 423 4. The \"type element\".  This element specifies what function should
 424    be used to see whether this score entry matches the article.
 425
 426    There are the regexp, as well as substring types, and exact match,
 427    and word match types.  If this element is not present, Gnus will
 428    assume that substring matching should be used.  There is case
 429    sensitive variants of all match types.")))
 430     (widget-put widget :args `(,item
 431                                (repeat :inline t
 432                                        :indent 0
 433                                        :tag ,tag
 434                                        :doc ,doc
 435                                        :format "%t:\n%h%v%i\n\n"
 436                                        (choice :format "%v"
 437                                                :value ("" nil nil s)
 438                                                ,group
 439                                                sexp)))))
 440   widget)
 441
 442 (define-widget 'gnus-score-integer 'group
 443   "Edit score entries for integer-valued headers."
 444   :convert-widget 'gnus-score-integer-convert)
 445
 446 (defun gnus-score-integer-convert (widget)
 447   ;; Set args appropriately.
 448   (let* ((tag (widget-get widget :tag))
 449          (item `(const :format "" :value ,(downcase tag)))
 450          (match '(integer :tag "Match"))
 451          (score '(choice :tag "Score"
 452                         (const :tag "default" nil)
 453                         (integer :format "%v"
 454                                  :hide-front-space t)))
 455          (expire '(choice :tag "Expire"
 456                           (const :tag "off" nil)
 457                           (integer :format "%v"
 458                                    :hide-front-space t)))
 459          (type '(choice :tag "Type"
 460                         :value <
 461                         (const <)
 462                         (const >)
 463                         (const =)
 464                         (const >=)
 465                         (const <=)))
 466          (group `(group ,match ,score ,expire ,type))
 467          (doc (concat (or (widget-get widget :doc)
 468                           (concat "Change score based on the " tag
 469                                   " header.")))))
 470     (widget-put widget :args `(,item
 471                                (repeat :inline t
 472                                        :indent 0
 473                                        :tag ,tag
 474                                        :doc ,doc
 475                                        :format "%t:\n%h%v%i\n\n"
 476                                        ,group))))
 477   widget)
 478
 479 (define-widget 'gnus-score-date 'group
 480   "Edit score entries for date-valued headers."
 481   :convert-widget 'gnus-score-date-convert)
 482
 483 (defun gnus-score-date-convert (widget)
 484   ;; Set args appropriately.
 485   (let* ((tag (widget-get widget :tag))
 486          (item `(const :format "" :value ,(downcase tag)))
 487          (match '(string :tag "Match"))
 488          (score '(choice :tag "Score"
 489                         (const :tag "default" nil)
 490                         (integer :format "%v"
 491                                  :hide-front-space t)))
 492          (expire '(choice :tag "Expire"
 493                           (const :tag "off" nil)
 494                           (integer :format "%v"
 495                                    :hide-front-space t)))
 496          (type '(choice :tag "Type"
 497                         :value regexp
 498                         (const regexp)
 499                         (const before)
 500                         (const at)
 501                         (const after)))
 502          (group `(group ,match ,score ,expire ,type))
 503          (doc (concat (or (widget-get widget :doc)
 504                           (concat "Change score based on the " tag
 505                                   " header."))
 506                       "
 507 For the Date header we have three kinda silly match types: `before',
 508 `at' and `after'.  I can't really imagine this ever being useful, but,
 509 like, it would feel kinda silly not to provide this function.  Just in
 510 case.  You never know.  Better safe than sorry.  Once burnt, twice
 511 shy.  Don't judge a book by its cover.  Never not have sex on a first
 512 date.  (I have been told that at least one person, and I quote,
 513 \"found this function indispensable\", however.)
 514
 515 A more useful match type is `regexp'.  With it, you can match the date
 516 string using a regular expression.  The date is normalized to ISO8601
 517 compact format first---`YYYYMMDDTHHMMSS'.  If you want to match all
 518 articles that have been posted on April 1st in every year, you could
 519 use `....0401.........' as a match string, for instance.  (Note that
 520 the date is kept in its original time zone, so this will match
 521 articles that were posted when it was April 1st where the article was
 522 posted from.  Time zones are such wholesome fun for the whole family,
 523 eh?")))
 524     (widget-put widget :args `(,item
 525                                (repeat :inline t
 526                                        :indent 0
 527                                        :tag ,tag
 528                                        :doc ,doc
 529                                        :format "%t:\n%h%v%i\n\n"
 530                                        ,group))))
 531   widget)
 532
 533 (defvar gnus-custom-scores)
 534 (defvar gnus-custom-score-alist)
 535
 536 (defun gnus-score-customize (file)
 537   "Customize score file FILE."
 538   (interactive (list gnus-current-score-file))
 539   (let ((scores (gnus-score-load file))
 540         (types (mapcar (lambda (entry)
 541                  `(group :format "%v%h\n"
 542                          :doc ,(nth 2 entry)
 543                          (const :format "" ,(nth 0 entry))
 544                          ,(nth 1 entry)))
 545                gnus-score-parameters)))
 546     ;; Ready.
 547     (kill-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 548     (switch-to-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 549     (gnus-custom-mode)
 550     (make-local-variable 'gnus-custom-score-alist)
 551     (setq gnus-custom-score-alist scores)
 552     (widget-insert "Customize the ")
 553     (widget-create 'info-link
 554                    :help-echo "Push me to learn more."
 555                    :tag "score entries"
 556                    "(gnus)Score File Format")
 557     (widget-insert " for\n\t")
 558     (widget-insert file)
 559     (widget-insert "\nand press ")
 560     (widget-create 'push-button
 561                    :tag "done"
 562                    :help-echo "Push me when done customizing."
 563                    :action 'gnus-score-customize-done)
 564     (widget-insert ".\n
 565 Check the [ ] for the entries you want to apply to this score file, then
 566 edit the value to suit your taste.  Don't forget to mark the checkbox,
 567 if you do all your changes will be lost.  ")
 568     (widget-create 'push-button
 569                    :action (lambda (&rest ignore)
 570                              (require 'gnus-audio)
 571                              (gnus-audio-play "Evil_Laugh.au"))
 572                    "Bhahahah!")
 573     (widget-insert "\n\n")
 574     (make-local-variable 'gnus-custom-scores)
 575     (setq gnus-custom-scores
 576           (widget-create 'group
 577                          :value scores
 578                          `(checklist :inline t
 579                                      :greedy t
 580                                      (gnus-score-string :tag "From")
 581                                      (gnus-score-string :tag "Subject")
 582                                      (gnus-score-string :tag "References")
 583                                      (gnus-score-string :tag "Xref")
 584                                      (gnus-score-string :tag "Message-ID")
 585                                      (gnus-score-integer :tag "Lines")
 586                                      (gnus-score-integer :tag "Chars")
 587                                      (gnus-score-date :tag "Date")
 588                                      (gnus-score-string :tag "Head"
 589                                                         :doc "\
 590 Match all headers in the article.
 591
 592 Using one of `Head', `Body', `All' will slow down scoring considerable.
 593 ")
 594                                      (gnus-score-string :tag "Body"
 595                                                         :doc "\
 596 Match the body sans header of the article.
 597
 598 Using one of `Head', `Body', `All' will slow down scoring considerable.
 599 ")
 600                                      (gnus-score-string :tag "All"
 601                                                         :doc "\
 602 Match the entire article, including both headers and body.
 603
 604 Using one of `Head', `Body', `All' will slow down scoring
 605 considerable.
 606 ")
 607                                      (gnus-score-string :tag
 608                                                         "Followup"
 609                                                         :doc "\
 610 Score all followups to the specified authors.
 611
 612 This entry is somewhat special, in that it will match the `From:'
 613 header, and affect the score of not only the matching articles, but
 614 also all followups to the matching articles.  This allows you
 615 e.g. increase the score of followups to your own articles, or decrease
 616 the score of followups to the articles of some known trouble-maker.
 617 ")
 618                                      (gnus-score-string :tag "Thread"
 619                                                         :doc "\
 620 Add a score entry on all articles that are part of a thread.
 621
 622 This match key works along the same lines as the `Followup' match key.
 623 If you say that you want to score on a (sub-)thread that is started by
 624 an article with a `Message-ID' X, then you add a `thread' match.  This
 625 will add a new `thread' match for each article that has X in its
 626 `References' header.  (These new `thread' matches will use the
 627 `Message-ID's of these matching articles.)  This will ensure that you
 628 can raise/lower the score of an entire thread, even though some
 629 articles in the thread may not have complete `References' headers.
 630 Note that using this may lead to undeterministic scores of the
 631 articles in the thread.
 632 ")
 633                                      ,@types)
 634                          '(repeat :inline t
 635                                   :tag "Unknown entries"
 636                                   sexp)))
 637     (use-local-map widget-keymap)
 638     (widget-setup)))
 639
 640 (defun gnus-score-customize-done (&rest ignore)
 641   "Reset the score alist with the present value."
 642   (let ((alist gnus-custom-score-alist)
 643         (value (widget-value gnus-custom-scores)))
 644     (setcar alist (car value))
 645     (setcdr alist (cdr value))
 646     (gnus-score-set 'touched '(t) alist))
 647   (bury-buffer))
 648
 649 ;;; The End:
 650
 651 (provide 'gnus-cus)
 652
 653 ;;; gnus-cus.el ends here