cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (eval-when-compile (require 'cl))
  30
  31 (defvar gnus-cache-directory
  32   (concat (file-name-as-directory gnus-article-save-directory) "cache/")
  33   "*The directory where cached articles will be stored.")
  34
  35 (defvar gnus-cache-active-file
  36   (concat (file-name-as-directory gnus-cache-directory) "active")
  37   "*The cache active file.")
  38
  39 (defvar gnus-cache-enter-articles '(ticked dormant)
  40   "*Classes of articles to enter into the cache.")
  41
  42 (defvar gnus-cache-remove-articles '(read)
  43   "*Classes of articles to remove from the cache.")
  44
  45 (defvar gnus-uncacheable-groups nil
  46   "*Groups that match this regexp will not be cached.
  47
  48 If you want to avoid caching your nnml groups, you could set this
  49 variable to \"^nnml\".")
  50
  51 \f
  52
  53 ;;; Internal variables.
  54
  55 (defvar gnus-cache-buffer nil)
  56 (defvar gnus-cache-active-hashtb nil)
  57 (defvar gnus-cache-active-altered nil)
  58
  59 (eval-and-compile
  60   (autoload 'nnml-generate-nov-databases-1 "nnml")
  61   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  62
  63 \f
  64
  65 ;;; Functions called from Gnus.
  66
  67 (defun gnus-cache-open ()
  68   "Initialize the cache."
  69   (gnus-cache-read-active))
  70
  71 (defun gnus-cache-close ()
  72   "Shut down the cache."
  73   (gnus-cache-write-active)
  74   (gnus-cache-save-buffers)
  75   (setq gnus-cache-active-hashtb nil))
  76
  77 (defun gnus-cache-save-buffers ()
  78   ;; save the overview buffer if it exists and has been modified
  79   ;; delete empty cache subdirectories
  80   (if (null gnus-cache-buffer)
  81       ()
  82     (let ((buffer (cdr gnus-cache-buffer))
  83           (overview-file (gnus-cache-file-name
  84                           (car gnus-cache-buffer) ".overview")))
  85       ;; write the overview only if it was modified
  86       (if (buffer-modified-p buffer)
  87           (save-excursion
  88             (set-buffer buffer)
  89             (if (> (buffer-size) 0)
  90                 ;; non-empty overview, write it out
  91                 (progn
  92                   (gnus-make-directory (file-name-directory overview-file))
  93                   (write-region (point-min) (point-max)
  94                                 overview-file nil 'quietly))
  95               ;; empty overview file, remove it
  96               (and (file-exists-p overview-file)
  97                    (delete-file overview-file))
  98               ;; if possible, remove group's cache subdirectory
  99               (condition-case nil
 100                   ;; FIXME: we can detect the error type and warn the user
 101                   ;; of any inconsistencies (articles w/o nov entries?).
 102                   ;; for now, just be conservative...delete only if safe -- sj
 103                   (delete-directory (file-name-directory overview-file))
 104                 (error nil)))))
 105       ;; kill the buffer, it's either unmodified or saved
 106       (gnus-kill-buffer buffer)
 107       (setq gnus-cache-buffer nil))))
 108
 109 (defun gnus-cache-possibly-enter-article
 110   (group article headers ticked dormant unread &optional force)
 111   (when (and (or force (not (eq gnus-use-cache 'passive)))
 112              (vectorp headers)) ; This might be a dummy article.
 113     ;; If this is a virtual group, we find the real group.
 114     (when (gnus-virtual-group-p group)
 115       (let ((result (nnvirtual-find-group-art group article)))
 116         (setq group (car result)
 117               article (cdr result)
 118               headers (copy-sequence headers))
 119         (aset headers 0 article)))
 120     (let ((number (mail-header-number headers))
 121           file dir)
 122       (when (and (> number 0)           ; Reffed article.
 123                  (or (not gnus-uncacheable-groups)
 124                      (not (string-match gnus-uncacheable-groups group)))
 125                  (or force
 126                      (gnus-cache-member-of-class
 127                       gnus-cache-enter-articles ticked dormant unread))
 128                  (not (file-exists-p (setq file (gnus-cache-file-name
 129                                                  group article)))))
 130         ;; Possibly create the cache directory.
 131         (or (file-exists-p (setq dir (file-name-directory file)))
 132             (gnus-make-directory dir))
 133         ;; Save the article in the cache.
 134         (if (file-exists-p file)
 135             t                           ; The article already is saved.
 136           (save-excursion
 137             (set-buffer nntp-server-buffer)
 138             (let ((gnus-use-cache nil))
 139               (gnus-request-article-this-buffer article group))
 140             (when (> (buffer-size) 0)
 141               (write-region (point-min) (point-max) file nil 'quiet)
 142               (gnus-cache-change-buffer group)
 143               (set-buffer (cdr gnus-cache-buffer))
 144               (goto-char (point-max))
 145               (forward-line -1)
 146               (while (condition-case ()
 147                          (and (not (bobp))
 148                               (> (read (current-buffer)) number))
 149                        (error
 150                         ;; The line was malformed, so we just remove it!!
 151                         (gnus-delete-line)
 152                         t))
 153                 (forward-line -1))
 154               (if (bobp)
 155                   (if (not (eobp))
 156                       (progn
 157                         (beginning-of-line)
 158                         (if (< (read (current-buffer)) number)
 159                             (forward-line 1)))
 160                     (beginning-of-line))
 161                 (forward-line 1))
 162               (beginning-of-line)
 163               ;; [number subject from date id references chars lines xref]
 164               (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 165                               (mail-header-number headers)
 166                               (mail-header-subject headers)
 167                               (mail-header-from headers)
 168                               (mail-header-date headers)
 169                               (mail-header-id headers)
 170                               (or (mail-header-references headers) "")
 171                               (or (mail-header-chars headers) "")
 172                               (or (mail-header-lines headers) "")
 173                               (or (mail-header-xref headers) "")))
 174               ;; Update the active info.
 175               (set-buffer gnus-summary-buffer)
 176               (gnus-cache-update-active group number)
 177               (push number gnus-newsgroup-cached)
 178               (gnus-summary-update-secondary-mark article))
 179             t))))))
 180
 181 (defun gnus-cache-enter-remove-article (article)
 182   "Mark ARTICLE for later possible removal."
 183   (when article
 184     (push article gnus-cache-removable-articles)))
 185
 186 (defun gnus-cache-possibly-remove-articles ()
 187   "Possibly remove some of the removable articles."
 188   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 189       (gnus-cache-possibly-remove-articles-1)
 190     (let ((arts gnus-cache-removable-articles)
 191           ga)
 192       (while arts
 193         (when (setq ga (nnvirtual-find-group-art
 194                         gnus-newsgroup-name (pop arts)))
 195           (let ((gnus-cache-removable-articles (list (cdr ga)))
 196                 (gnus-newsgroup-name (car ga)))
 197             (gnus-cache-possibly-remove-articles-1)))))
 198     (setq gnus-cache-removable-articles nil)))
 199
 200 (defun gnus-cache-possibly-remove-articles-1 ()
 201   "Possibly remove some of the removable articles."
 202   (unless (eq gnus-use-cache 'passive)
 203     (let ((articles gnus-cache-removable-articles)
 204           (cache-articles gnus-newsgroup-cached)
 205           article)
 206       (gnus-cache-change-buffer gnus-newsgroup-name)
 207       (while articles
 208         (if (memq (setq article (pop articles)) cache-articles)
 209             ;; The article was in the cache, so we see whether we are
 210             ;; supposed to remove it from the cache.
 211             (gnus-cache-possibly-remove-article
 212              article (memq article gnus-newsgroup-marked)
 213              (memq article gnus-newsgroup-dormant)
 214              (or (memq article gnus-newsgroup-unreads)
 215                  (memq article gnus-newsgroup-unselected))))))
 216     ;; The overview file might have been modified, save it
 217     ;; safe because we're only called at group exit anyway.
 218     (gnus-cache-save-buffers)))
 219
 220 (defun gnus-cache-request-article (article group)
 221   "Retrieve ARTICLE in GROUP from the cache."
 222   (let ((file (gnus-cache-file-name group article))
 223         (buffer-read-only nil))
 224     (when (file-exists-p file)
 225       (erase-buffer)
 226       (gnus-kill-all-overlays)
 227       (insert-file-contents file)
 228       t)))
 229
 230 (defun gnus-cache-possibly-alter-active (group active)
 231   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 232   (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 233     (and cache-active
 234          (< (car cache-active) (car active))
 235          (setcar active (car cache-active)))
 236     (and cache-active
 237          (> (cdr cache-active) (cdr active))
 238          (setcdr active (cdr cache-active)))))
 239
 240 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 241   "Retrieve the headers for ARTICLES in GROUP."
 242   (let* ((cached
 243           (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group)))
 244          (articles (gnus-sorted-complement articles cached))
 245          (cache-file (gnus-cache-file-name group ".overview"))
 246          type)
 247     ;; We first retrieve all the headers that we don't have in
 248     ;; the cache.
 249     (let ((gnus-use-cache nil))
 250       (setq type (and articles
 251                       (gnus-retrieve-headers articles group fetch-old))))
 252     (gnus-cache-save-buffers)
 253     ;; Then we insert the cached headers.
 254     (save-excursion
 255       (cond
 256        ((not (file-exists-p cache-file))
 257         ;; There are no cached headers.
 258         type)
 259        ((null type)
 260         ;; There were no uncached headers (or retrieval was
 261         ;; unsuccessful), so we use the cached headers exclusively.
 262         (set-buffer nntp-server-buffer)
 263         (erase-buffer)
 264         (insert-file-contents cache-file)
 265         'nov)
 266        ((eq type 'nov)
 267         ;; We have both cached and uncached NOV headers, so we
 268         ;; braid them.
 269         (gnus-cache-braid-nov group cached)
 270         type)
 271        (t
 272         ;; We braid HEADs.
 273         (gnus-cache-braid-heads group cached)
 274         type)))))
 275
 276 (defun gnus-cache-enter-article (&optional n)
 277   "Enter the next N articles into the cache.
 278 If not given a prefix, use the process marked articles instead.
 279 Returns the list of articles entered."
 280   (interactive "P")
 281   (gnus-set-global-variables)
 282   (let ((articles (gnus-summary-work-articles n))
 283         article out)
 284     (while articles
 285       (setq article (pop articles))
 286       (when (gnus-cache-possibly-enter-article
 287              gnus-newsgroup-name article (gnus-summary-article-header article)
 288              nil nil nil t)
 289         (push article out))
 290       (gnus-summary-remove-process-mark article)
 291       (gnus-summary-update-secondary-mark article))
 292     (gnus-summary-next-subject 1)
 293     (gnus-summary-position-point)
 294     (nreverse out)))
 295
 296 (defun gnus-cache-remove-article (n)
 297   "Remove the next N articles from the cache.
 298 If not given a prefix, use the process marked articles instead.
 299 Returns the list of articles removed."
 300   (interactive "P")
 301   (gnus-set-global-variables)
 302   (let ((articles (gnus-summary-work-articles n))
 303         article out)
 304     (while articles
 305       (setq article (pop articles))
 306       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 307         (push article out))
 308       (gnus-summary-remove-process-mark article)
 309       (gnus-summary-update-secondary-mark article))
 310     (gnus-summary-position-point)
 311     (nreverse out)))
 312
 313 (defun gnus-cached-article-p (article)
 314   "Say whether ARTICLE is cached in the current group."
 315   (memq article gnus-newsgroup-cached))
 316
 317 ;;; Internal functions.
 318
 319 (defun gnus-cache-change-buffer (group)
 320   (and gnus-cache-buffer
 321        ;; See if the current group's overview cache has been loaded.
 322        (or (string= group (car gnus-cache-buffer))
 323            ;; Another overview cache is current, save it.
 324            (gnus-cache-save-buffers)))
 325   ;; if gnus-cache buffer is nil, create it
 326   (or gnus-cache-buffer
 327       ;; Create cache buffer
 328       (save-excursion
 329         (setq gnus-cache-buffer
 330               (cons group
 331                     (set-buffer (get-buffer-create " *gnus-cache-overview*"))))
 332         (buffer-disable-undo (current-buffer))
 333         ;; Insert the contents of this group's cache overview.
 334         (erase-buffer)
 335         (let ((file (gnus-cache-file-name group ".overview")))
 336           (and (file-exists-p file)
 337                (insert-file-contents file)))
 338         ;; We have a fresh (empty/just loaded) buffer,
 339         ;; mark it as unmodified to save a redundant write later.
 340         (set-buffer-modified-p nil))))
 341
 342 ;; Return whether an article is a member of a class.
 343 (defun gnus-cache-member-of-class (class ticked dormant unread)
 344   (or (and ticked (memq 'ticked class))
 345       (and dormant (memq 'dormant class))
 346       (and unread (memq 'unread class))
 347       (and (not unread) (memq 'read class))))
 348
 349 (defun gnus-cache-file-name (group article)
 350   (concat (file-name-as-directory gnus-cache-directory)
 351           (file-name-as-directory
 352            (if (gnus-use-long-file-name 'not-cache)
 353                group
 354              (let ((group (concat group "")))
 355                (if (string-match ":" group)
 356                    (aset group (match-beginning 0) ?/))
 357                (nnheader-replace-chars-in-string group ?. ?/))))
 358           (if (stringp article) article (int-to-string article))))
 359
 360 (defun gnus-cache-update-article (group article)
 361   "If ARTICLE is in the cache, remove it and re-enter it."
 362   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 363     (gnus-cache-possibly-enter-article
 364      gnus-newsgroup-name article (gnus-summary-article-header article)
 365      nil nil nil t)))
 366
 367 (defun gnus-cache-possibly-remove-article
 368   (article ticked dormant unread &optional force)
 369   "Possibly remove ARTICLE from the cache."
 370   (let ((file (gnus-cache-file-name gnus-newsgroup-name article)))
 371     (when (and (file-exists-p file)
 372                (or force
 373                    (gnus-cache-member-of-class
 374                     gnus-cache-remove-articles ticked dormant unread)))
 375       (save-excursion
 376         (delete-file file)
 377         (set-buffer (cdr gnus-cache-buffer))
 378         (goto-char (point-min))
 379         (if (or (looking-at (concat (int-to-string article) "\t"))
 380                 (search-forward (concat "\n" (int-to-string article) "\t")
 381                                 (point-max) t))
 382             (delete-region (progn (beginning-of-line) (point))
 383                            (progn (forward-line 1) (point)))))
 384       (setq gnus-newsgroup-cached
 385             (delq article gnus-newsgroup-cached))
 386       (gnus-summary-update-secondary-mark article)
 387       t)))
 388
 389 (defun gnus-cache-articles-in-group (group)
 390   "Return a sorted list of cached articles in GROUP."
 391   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 392         articles)
 393     (when (file-exists-p dir)
 394       (sort (mapcar (lambda (name) (string-to-int name))
 395                     (directory-files dir nil "^[0-9]+$" t))
 396             '<))))
 397
 398 (defun gnus-cache-braid-nov (group cached)
 399   (let ((cache-buf (get-buffer-create " *gnus-cache*"))
 400         beg end)
 401     (gnus-cache-save-buffers)
 402     (save-excursion
 403       (set-buffer cache-buf)
 404       (buffer-disable-undo (current-buffer))
 405       (erase-buffer)
 406       (insert-file-contents (gnus-cache-file-name group ".overview"))
 407       (goto-char (point-min))
 408       (insert "\n")
 409       (goto-char (point-min)))
 410     (set-buffer nntp-server-buffer)
 411     (goto-char (point-min))
 412     (while cached
 413       (while (and (not (eobp))
 414                   (< (read (current-buffer)) (car cached)))
 415         (forward-line 1))
 416       (beginning-of-line)
 417       (save-excursion
 418         (set-buffer cache-buf)
 419         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 420                             nil t)
 421             (setq beg (progn (beginning-of-line) (point))
 422                   end (progn (end-of-line) (point)))
 423           (setq beg nil)))
 424       (if beg (progn (insert-buffer-substring cache-buf beg end)
 425                      (insert "\n")))
 426       (setq cached (cdr cached)))
 427     (kill-buffer cache-buf)))
 428
 429 (defun gnus-cache-braid-heads (group cached)
 430   (let ((cache-buf (get-buffer-create " *gnus-cache*")))
 431     (save-excursion
 432       (set-buffer cache-buf)
 433       (buffer-disable-undo (current-buffer))
 434       (erase-buffer))
 435     (set-buffer nntp-server-buffer)
 436     (goto-char (point-min))
 437     (while cached
 438       (while (and (not (eobp))
 439                   (looking-at "2.. +\\([0-9]+\\) ")
 440                   (< (progn (goto-char (match-beginning 1))
 441                             (read (current-buffer)))
 442                      (car cached)))
 443         (search-forward "\n.\n" nil 'move))
 444       (beginning-of-line)
 445       (save-excursion
 446         (set-buffer cache-buf)
 447         (erase-buffer)
 448         (insert-file-contents (gnus-cache-file-name group (car cached)))
 449         (goto-char (point-min))
 450         (insert "220 " (int-to-string (car cached)) " Article retrieved.\n")
 451         (search-forward "\n\n" nil 'move)
 452         (delete-region (point) (point-max))
 453         (forward-char -1)
 454         (insert "."))
 455       (insert-buffer-substring cache-buf)
 456       (setq cached (cdr cached)))
 457     (kill-buffer cache-buf)))
 458
 459 ;;;###autoload
 460 (defun gnus-jog-cache ()
 461   "Go through all groups and put the articles into the cache."
 462   (interactive)
 463   (let ((gnus-mark-article-hook nil)
 464         (gnus-expert-user t)
 465         (nnmail-spool-file nil)
 466         (gnus-use-dribble-file nil)
 467         (gnus-novice-user nil)
 468         (gnus-large-newsgroup nil))
 469     ;; Start Gnus.
 470     (gnus)
 471     ;; Go through all groups...
 472     (gnus-group-mark-buffer)
 473     (gnus-group-universal-argument
 474      nil nil
 475      (lambda ()
 476        (gnus-summary-read-group nil nil t)
 477        ;; ... and enter the articles into the cache.
 478        (when (eq major-mode 'gnus-summary-mode)
 479          (gnus-uu-mark-buffer)
 480          (gnus-cache-enter-article)
 481          (kill-buffer (current-buffer)))))))
 482
 483 (defun gnus-cache-read-active (&optional force)
 484   "Read the cache active file."
 485   (if (not (and (file-exists-p gnus-cache-active-file)
 486                 (or force (not gnus-cache-active-hashtb))))
 487       ;; There is no active file, so we generate one.
 488       (gnus-cache-generate-active)
 489     ;; We simply read the active file.
 490     (save-excursion
 491       (gnus-set-work-buffer)
 492       (insert-file-contents gnus-cache-active-file)
 493       (gnus-active-to-gnus-format
 494        nil (setq gnus-cache-active-hashtb
 495                  (gnus-make-hashtable
 496                   (count-lines (point-min) (point-max)))))
 497       (setq gnus-cache-active-altered nil))))
 498
 499 (defun gnus-cache-write-active (&optional force)
 500   "Write the active hashtb to the active file."
 501   (when (or force
 502             (and gnus-cache-active-hashtb
 503                  gnus-cache-active-altered))
 504     (save-excursion
 505       (gnus-set-work-buffer)
 506       (mapatoms
 507        (lambda (sym)
 508          (when (and sym (boundp sym))
 509            (insert (format "%s %d %d y\n"
 510                            (symbol-name sym) (cdr (symbol-value sym))
 511                            (car (symbol-value sym))))))
 512        gnus-cache-active-hashtb)
 513       (gnus-make-directory (file-name-directory gnus-cache-active-file))
 514       (write-region
 515        (point-min) (point-max) gnus-cache-active-file nil 'silent))
 516     ;; Mark the active hashtb as unaltered.
 517     (setq gnus-cache-active-altered nil)))
 518
 519 (defun gnus-cache-update-active (group number &optional low)
 520   "Update the upper bound of the active info of GROUP to NUMBER.
 521 If LOW, update the lower bound instead."
 522   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 523     (if (null active)
 524         ;; We just create a new active entry for this group.
 525         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 526       ;; Update the lower or upper bound.
 527       (if low
 528           (setcar active number)
 529         (setcdr active number))
 530       ;; Mark the active hashtb as altered.
 531       (setq gnus-cache-active-altered t))))
 532
 533 ;;;###autoload
 534 (defun gnus-cache-generate-active (&optional directory)
 535   "Generate the cache active file."
 536   (interactive)
 537   (let* ((top (null directory))
 538          (directory (expand-file-name (or directory gnus-cache-directory)))
 539          (files (directory-files directory 'full))
 540          (group
 541           (if top
 542               ""
 543             (string-match
 544              (concat "^" (file-name-as-directory
 545                           (expand-file-name gnus-cache-directory)))
 546              (directory-file-name directory))
 547             (nnheader-replace-chars-in-string
 548              (substring (directory-file-name directory) (match-end 0))
 549              ?/ ?.)))
 550          nums alphs)
 551     (when top
 552       (gnus-message 5 "Generating the cache active file...")
 553       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 554     ;; Separate articles from all other files and directories.
 555     (while files
 556       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 557           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 558         (push (pop files) alphs)))
 559     ;; If we have nums, then this is probably a valid group.
 560     (when (setq nums (sort nums '<))
 561       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 562                     gnus-cache-active-hashtb))
 563     ;; Go through all the other files.
 564     (while alphs
 565       (when (and (file-directory-p (car alphs))
 566                  (not (string-match "^\\.\\.?$"
 567                                     (file-name-nondirectory (car alphs)))))
 568         ;; We descend directories.
 569         (gnus-cache-generate-active (car alphs)))
 570       (setq alphs (cdr alphs)))
 571     ;; Write the new active file.
 572     (when top
 573       (gnus-cache-write-active t)
 574       (gnus-message 5 "Generating the cache active file...done"))))
 575
 576 ;;;###autoload
 577 (defun gnus-cache-generate-nov-databases (dir)
 578   "Generate NOV files recursively starting in DIR."
 579   (interactive (list gnus-cache-directory))
 580   (gnus-cache-close)
 581   (let ((nnml-generate-active-function 'identity))
 582     (nnml-generate-nov-databases-1 dir)))
 583
 584 (provide 'gnus-cache)
 585
 586 ;;; gnus-cache.el ends here