cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (eval-when-compile (require 'cl))
  30
  31 (defvar gnus-cache-directory
  32   (concat (file-name-as-directory gnus-article-save-directory) "cache/")
  33   "*The directory where cached articles will be stored.")
  34
  35 (defvar gnus-cache-active-file
  36   (concat (file-name-as-directory gnus-cache-directory) "active")
  37   "*The cache active file.")
  38
  39 (defvar gnus-cache-enter-articles '(ticked dormant)
  40   "*Classes of articles to enter into the cache.")
  41
  42 (defvar gnus-cache-remove-articles '(read)
  43   "*Classes of articles to remove from the cache.")
  44
  45 (defvar gnus-uncacheable-groups nil
  46   "*Groups that match this regexp will not be cached.
  47
  48 If you want to avoid caching your nnml groups, you could set this
  49 variable to \"^nnml\".")
  50
  51 \f
  52
  53 ;;; Internal variables.
  54
  55 (defvar gnus-cache-buffer nil)
  56 (defvar gnus-cache-active-hashtb nil)
  57 (defvar gnus-cache-active-altered nil)
  58
  59 (eval-and-compile
  60   (autoload 'nnml-generate-nov-databases-1 "nnml")
  61   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  62
  63 \f
  64
  65 ;;; Functions called from Gnus.
  66
  67 (defun gnus-cache-open ()
  68   "Initialize the cache."
  69   (gnus-cache-read-active))
  70
  71 (defun gnus-cache-close ()
  72   "Shut down the cache."
  73   (gnus-cache-write-active)
  74   (gnus-cache-save-buffers)
  75   (setq gnus-cache-active-hashtb nil))
  76
  77 (defun gnus-cache-save-buffers ()
  78   ;; save the overview buffer if it exists and has been modified
  79   ;; delete empty cache subdirectories
  80   (if (null gnus-cache-buffer)
  81       ()
  82     (let ((buffer (cdr gnus-cache-buffer))
  83           (overview-file (gnus-cache-file-name
  84                           (car gnus-cache-buffer) ".overview")))
  85       ;; write the overview only if it was modified
  86       (if (buffer-modified-p buffer)
  87           (save-excursion
  88             (set-buffer buffer)
  89             (if (> (buffer-size) 0)
  90                 ;; non-empty overview, write it out
  91                 (progn
  92                   (gnus-make-directory (file-name-directory overview-file))
  93                   (write-region (point-min) (point-max)
  94                                 overview-file nil 'quietly))
  95               ;; empty overview file, remove it
  96               (and (file-exists-p overview-file)
  97                    (delete-file overview-file))
  98               ;; if possible, remove group's cache subdirectory
  99               (condition-case nil
 100                   ;; FIXME: we can detect the error type and warn the user
 101                   ;; of any inconsistencies (articles w/o nov entries?).
 102                   ;; for now, just be conservative...delete only if safe -- sj
 103                   (delete-directory (file-name-directory overview-file))
 104                 (error nil)))))
 105       ;; kill the buffer, it's either unmodified or saved
 106       (gnus-kill-buffer buffer)
 107       (setq gnus-cache-buffer nil))))
 108
 109 (defun gnus-cache-possibly-enter-article
 110   (group article headers ticked dormant unread &optional force)
 111   (when (and (or force (not (eq gnus-use-cache 'passive)))
 112              (vectorp headers)) ; This might be a dummy article.
 113     ;; If this is a virtual group, we find the real group.
 114     (when (gnus-virtual-group-p group)
 115       (let ((result (nnvirtual-find-group-art group article)))
 116         (setq group (car result)
 117               article (cdr result)
 118               headers (copy-sequence headers))
 119         (aset headers 0 article)))
 120     (let ((number (mail-header-number headers))
 121           file dir)
 122       (when (and (> number 0)           ; Reffed article.
 123                  (or (not gnus-uncacheable-groups)
 124                      (not (string-match gnus-uncacheable-groups group)))
 125                  (or force
 126                      (gnus-cache-member-of-class
 127                       gnus-cache-enter-articles ticked dormant unread))
 128                  (not (file-exists-p (setq file (gnus-cache-file-name
 129                                                  group article)))))
 130         ;; Possibly create the cache directory.
 131         (or (file-exists-p (setq dir (file-name-directory file)))
 132             (gnus-make-directory dir))
 133         ;; Save the article in the cache.
 134         (if (file-exists-p file)
 135             t                           ; The article already is saved.
 136           (save-excursion
 137             (set-buffer nntp-server-buffer)
 138             (let ((gnus-use-cache nil))
 139               (gnus-request-article-this-buffer article group))
 140             (when (> (buffer-size) 0)
 141               (write-region (point-min) (point-max) file nil 'quiet)
 142               (gnus-cache-change-buffer group)
 143               (set-buffer (cdr gnus-cache-buffer))
 144               (goto-char (point-max))
 145               (forward-line -1)
 146               (while (condition-case ()
 147                          (and (not (bobp))
 148                               (> (read (current-buffer)) number))
 149                        (error
 150                         ;; The line was malformed, so we just remove it!!
 151                         (gnus-delete-line)
 152                         t))
 153                 (forward-line -1))
 154               (if (bobp)
 155                   (if (not (eobp))
 156                       (progn
 157                         (beginning-of-line)
 158                         (if (< (read (current-buffer)) number)
 159                             (forward-line 1)))
 160                     (beginning-of-line))
 161                 (forward-line 1))
 162               (beginning-of-line)
 163               ;; [number subject from date id references chars lines xref]
 164               (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 165                               (mail-header-number headers)
 166                               (mail-header-subject headers)
 167                               (mail-header-from headers)
 168                               (mail-header-date headers)
 169                               (mail-header-id headers)
 170                               (or (mail-header-references headers) "")
 171                               (or (mail-header-chars headers) "")
 172                               (or (mail-header-lines headers) "")
 173                               (or (mail-header-xref headers) "")))
 174               ;; Update the active info.
 175               (set-buffer gnus-summary-buffer)
 176               (gnus-cache-update-active group number)
 177               (push number gnus-newsgroup-cached)
 178               (gnus-summary-update-secondary-mark article))
 179             t))))))
 180
 181 (defun gnus-cache-enter-remove-article (article)
 182   "Mark ARTICLE for later possible removal."
 183   (when article
 184     (push article gnus-cache-removable-articles)))
 185
 186 (defun gnus-cache-possibly-remove-articles ()
 187   "Possibly remove some of the removable articles."
 188   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 189       (gnus-cache-possibly-remove-articles-1)
 190     (let ((arts gnus-cache-removable-articles)
 191           ga)
 192       (while arts
 193         (when (setq ga (nnvirtual-find-group-art
 194                         gnus-newsgroup-name (pop arts)))
 195           (let ((gnus-cache-removable-articles (list (cdr ga)))
 196                 (gnus-newsgroup-name (car ga)))
 197             (gnus-cache-possibly-remove-articles-1)))))
 198     (setq gnus-cache-removable-articles nil)))
 199
 200 (defun gnus-cache-possibly-remove-articles-1 ()
 201   "Possibly remove some of the removable articles."
 202   (unless (eq gnus-use-cache 'passive)
 203     (let ((articles gnus-cache-removable-articles)
 204           (cache-articles gnus-newsgroup-cached)
 205           article)
 206       (gnus-cache-change-buffer gnus-newsgroup-name)
 207       (while articles
 208         (if (memq (setq article (pop articles)) cache-articles)
 209             ;; The article was in the cache, so we see whether we are
 210             ;; supposed to remove it from the cache.
 211             (gnus-cache-possibly-remove-article
 212              article (memq article gnus-newsgroup-marked)
 213              (memq article gnus-newsgroup-dormant)
 214              (or (memq article gnus-newsgroup-unreads)
 215                  (memq article gnus-newsgroup-unselected))))))
 216     ;; The overview file might have been modified, save it
 217     ;; safe because we're only called at group exit anyway.
 218     (gnus-cache-save-buffers)))
 219
 220 (defun gnus-cache-request-article (article group)
 221   "Retrieve ARTICLE in GROUP from the cache."
 222   (let ((file (gnus-cache-file-name group article))
 223         (buffer-read-only nil))
 224     (when (file-exists-p file)
 225       (erase-buffer)
 226       (gnus-kill-all-overlays)
 227       (insert-file-contents file)
 228       t)))
 229
 230 (defun gnus-cache-possibly-alter-active (group active)
 231   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 232   (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 233     (and cache-active
 234          (< (car cache-active) (car active))
 235          (setcar active (car cache-active)))
 236     (and cache-active
 237          (> (cdr cache-active) (cdr active))
 238          (setcdr active (cdr cache-active)))))
 239
 240 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 241   "Retrieve the headers for ARTICLES in GROUP."
 242   (let* ((cached
 243           (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group)))
 244          (articles (gnus-sorted-complement articles cached))
 245          (cache-file (gnus-cache-file-name group ".overview"))
 246          type)
 247     ;; We first retrieve all the headers that we don't have in
 248     ;; the cache.
 249     (let ((gnus-use-cache nil))
 250       (setq type (and articles
 251                       (gnus-retrieve-headers articles group fetch-old))))
 252     (gnus-cache-save-buffers)
 253     ;; Then we insert the cached headers.
 254     (save-excursion
 255       (cond
 256        ((not (file-exists-p cache-file))
 257         ;; There are no cached headers.
 258         type)
 259        ((null type)
 260         ;; There were no uncached headers (or retrieval was
 261         ;; unsuccessful), so we use the cached headers exclusively.
 262         (set-buffer nntp-server-buffer)
 263         (erase-buffer)
 264         (insert-file-contents cache-file)
 265         'nov)
 266        ((eq type 'nov)
 267         ;; We have both cached and uncached NOV headers, so we
 268         ;; braid them.
 269         (gnus-cache-braid-nov group cached)
 270         type)
 271        (t
 272         ;; We braid HEADs.
 273         (gnus-cache-braid-heads group cached)
 274         type)))))
 275
 276 (defun gnus-cache-enter-article (&optional n)
 277   "Enter the next N articles into the cache.
 278 If not given a prefix, use the process marked articles instead.
 279 Returns the list of articles entered."
 280   (interactive "P")
 281   (gnus-set-global-variables)
 282   (let ((articles (gnus-summary-work-articles n))
 283         article out)
 284     (while articles
 285       (setq article (pop articles))
 286       (when (gnus-cache-possibly-enter-article
 287              gnus-newsgroup-name article (gnus-summary-article-header article)
 288              nil nil nil t)
 289         (push article out))
 290       (gnus-summary-remove-process-mark article)
 291       (gnus-summary-update-secondary-mark article))
 292     (gnus-summary-position-point)
 293     (nreverse out)))
 294
 295 (defun gnus-cache-remove-article (n)
 296   "Remove the next N articles from the cache.
 297 If not given a prefix, use the process marked articles instead.
 298 Returns the list of articles removed."
 299   (interactive "P")
 300   (gnus-set-global-variables)
 301   (let ((articles (gnus-summary-work-articles n))
 302         article out)
 303     (while articles
 304       (setq article (pop articles))
 305       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 306         (push article out))
 307       (gnus-summary-remove-process-mark article)
 308       (gnus-summary-update-secondary-mark article))
 309     (gnus-summary-position-point)
 310     (nreverse out)))
 311
 312 (defun gnus-cached-article-p (article)
 313   "Say whether ARTICLE is cached in the current group."
 314   (memq article gnus-newsgroup-cached))
 315
 316 ;;; Internal functions.
 317
 318 (defun gnus-cache-change-buffer (group)
 319   (and gnus-cache-buffer
 320        ;; See if the current group's overview cache has been loaded.
 321        (or (string= group (car gnus-cache-buffer))
 322            ;; Another overview cache is current, save it.
 323            (gnus-cache-save-buffers)))
 324   ;; if gnus-cache buffer is nil, create it
 325   (or gnus-cache-buffer
 326       ;; Create cache buffer
 327       (save-excursion
 328         (setq gnus-cache-buffer
 329               (cons group
 330                     (set-buffer (get-buffer-create " *gnus-cache-overview*"))))
 331         (buffer-disable-undo (current-buffer))
 332         ;; Insert the contents of this group's cache overview.
 333         (erase-buffer)
 334         (let ((file (gnus-cache-file-name group ".overview")))
 335           (and (file-exists-p file)
 336                (insert-file-contents file)))
 337         ;; We have a fresh (empty/just loaded) buffer,
 338         ;; mark it as unmodified to save a redundant write later.
 339         (set-buffer-modified-p nil))))
 340
 341 ;; Return whether an article is a member of a class.
 342 (defun gnus-cache-member-of-class (class ticked dormant unread)
 343   (or (and ticked (memq 'ticked class))
 344       (and dormant (memq 'dormant class))
 345       (and unread (memq 'unread class))
 346       (and (not unread) (memq 'read class))))
 347
 348 (defun gnus-cache-file-name (group article)
 349   (concat (file-name-as-directory gnus-cache-directory)
 350           (file-name-as-directory
 351            (if (gnus-use-long-file-name 'not-cache)
 352                group
 353              (let ((group (concat group "")))
 354                (if (string-match ":" group)
 355                    (aset group (match-beginning 0) ?/))
 356                (nnheader-replace-chars-in-string group ?. ?/))))
 357           (if (stringp article) article (int-to-string article))))
 358
 359 (defun gnus-cache-update-article (group article)
 360   "If ARTICLE is in the cache, remove it and re-enter it."
 361   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 362     (gnus-cache-possibly-enter-article
 363      gnus-newsgroup-name article (gnus-summary-article-header article)
 364      nil nil nil t)))
 365
 366 (defun gnus-cache-possibly-remove-article
 367   (article ticked dormant unread &optional force)
 368   "Possibly remove ARTICLE from the cache."
 369   (let ((file (gnus-cache-file-name gnus-newsgroup-name article)))
 370     (when (and (file-exists-p file)
 371                (or force
 372                    (gnus-cache-member-of-class
 373                     gnus-cache-remove-articles ticked dormant unread)))
 374       (save-excursion
 375         (delete-file file)
 376         (set-buffer (cdr gnus-cache-buffer))
 377         (goto-char (point-min))
 378         (if (or (looking-at (concat (int-to-string article) "\t"))
 379                 (search-forward (concat "\n" (int-to-string article) "\t")
 380                                 (point-max) t))
 381             (delete-region (progn (beginning-of-line) (point))
 382                            (progn (forward-line 1) (point)))))
 383       (setq gnus-newsgroup-cached
 384             (delq article gnus-newsgroup-cached))
 385       (gnus-summary-update-secondary-mark article)
 386       t)))
 387
 388 (defun gnus-cache-articles-in-group (group)
 389   "Return a sorted list of cached articles in GROUP."
 390   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 391         articles)
 392     (when (file-exists-p dir)
 393       (sort (mapcar (lambda (name) (string-to-int name))
 394                     (directory-files dir nil "^[0-9]+$" t))
 395             '<))))
 396
 397 (defun gnus-cache-braid-nov (group cached)
 398   (let ((cache-buf (get-buffer-create " *gnus-cache*"))
 399         beg end)
 400     (gnus-cache-save-buffers)
 401     (save-excursion
 402       (set-buffer cache-buf)
 403       (buffer-disable-undo (current-buffer))
 404       (erase-buffer)
 405       (insert-file-contents (gnus-cache-file-name group ".overview"))
 406       (goto-char (point-min))
 407       (insert "\n")
 408       (goto-char (point-min)))
 409     (set-buffer nntp-server-buffer)
 410     (goto-char (point-min))
 411     (while cached
 412       (while (and (not (eobp))
 413                   (< (read (current-buffer)) (car cached)))
 414         (forward-line 1))
 415       (beginning-of-line)
 416       (save-excursion
 417         (set-buffer cache-buf)
 418         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 419                             nil t)
 420             (setq beg (progn (beginning-of-line) (point))
 421                   end (progn (end-of-line) (point)))
 422           (setq beg nil)))
 423       (if beg (progn (insert-buffer-substring cache-buf beg end)
 424                      (insert "\n")))
 425       (setq cached (cdr cached)))
 426     (kill-buffer cache-buf)))
 427
 428 (defun gnus-cache-braid-heads (group cached)
 429   (let ((cache-buf (get-buffer-create " *gnus-cache*")))
 430     (save-excursion
 431       (set-buffer cache-buf)
 432       (buffer-disable-undo (current-buffer))
 433       (erase-buffer))
 434     (set-buffer nntp-server-buffer)
 435     (goto-char (point-min))
 436     (while cached
 437       (while (and (not (eobp))
 438                   (looking-at "2.. +\\([0-9]+\\) ")
 439                   (< (progn (goto-char (match-beginning 1))
 440                             (read (current-buffer)))
 441                      (car cached)))
 442         (search-forward "\n.\n" nil 'move))
 443       (beginning-of-line)
 444       (save-excursion
 445         (set-buffer cache-buf)
 446         (erase-buffer)
 447         (insert-file-contents (gnus-cache-file-name group (car cached)))
 448         (goto-char (point-min))
 449         (insert "220 " (int-to-string (car cached)) " Article retrieved.\n")
 450         (search-forward "\n\n" nil 'move)
 451         (delete-region (point) (point-max))
 452         (forward-char -1)
 453         (insert "."))
 454       (insert-buffer-substring cache-buf)
 455       (setq cached (cdr cached)))
 456     (kill-buffer cache-buf)))
 457
 458 ;;;###autoload
 459 (defun gnus-jog-cache ()
 460   "Go through all groups and put the articles into the cache."
 461   (interactive)
 462   (let ((gnus-mark-article-hook nil)
 463         (gnus-expert-user t)
 464         (nnmail-spool-file nil)
 465         (gnus-use-dribble-file nil)
 466         (gnus-novice-user nil)
 467         (gnus-large-newsgroup nil))
 468     ;; Start Gnus.
 469     (gnus)
 470     ;; Go through all groups...
 471     (gnus-group-mark-buffer)
 472     (gnus-group-universal-argument
 473      nil nil
 474      (lambda ()
 475        (gnus-summary-read-group nil nil t)
 476        ;; ... and enter the articles into the cache.
 477        (when (eq major-mode 'gnus-summary-mode)
 478          (gnus-uu-mark-buffer)
 479          (gnus-cache-enter-article)
 480          (kill-buffer (current-buffer)))))))
 481
 482 (defun gnus-cache-read-active (&optional force)
 483   "Read the cache active file."
 484   (if (not (and (file-exists-p gnus-cache-active-file)
 485                 (or force (not gnus-cache-active-hashtb))))
 486       ;; There is no active file, so we generate one.
 487       (gnus-cache-generate-active)
 488     ;; We simply read the active file.
 489     (save-excursion
 490       (gnus-set-work-buffer)
 491       (insert-file-contents gnus-cache-active-file)
 492       (gnus-active-to-gnus-format
 493        nil (setq gnus-cache-active-hashtb
 494                  (gnus-make-hashtable
 495                   (count-lines (point-min) (point-max)))))
 496       (setq gnus-cache-active-altered nil))))
 497
 498 (defun gnus-cache-write-active (&optional force)
 499   "Write the active hashtb to the active file."
 500   (when (or force
 501             (and gnus-cache-active-hashtb
 502                  gnus-cache-active-altered))
 503     (save-excursion
 504       (gnus-set-work-buffer)
 505       (mapatoms
 506        (lambda (sym)
 507          (when (and sym (boundp sym))
 508            (insert (format "%s %d %d y\n"
 509                            (symbol-name sym) (cdr (symbol-value sym))
 510                            (car (symbol-value sym))))))
 511        gnus-cache-active-hashtb)
 512       (gnus-make-directory (file-name-directory gnus-cache-active-file))
 513       (write-region
 514        (point-min) (point-max) gnus-cache-active-file nil 'silent))
 515     ;; Mark the active hashtb as unaltered.
 516     (setq gnus-cache-active-altered nil)))
 517
 518 (defun gnus-cache-update-active (group number &optional low)
 519   "Update the upper bound of the active info of GROUP to NUMBER.
 520 If LOW, update the lower bound instead."
 521   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 522     (if (null active)
 523         ;; We just create a new active entry for this group.
 524         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 525       ;; Update the lower or upper bound.
 526       (if low
 527           (setcar active number)
 528         (setcdr active number))
 529       ;; Mark the active hashtb as altered.
 530       (setq gnus-cache-active-altered t))))
 531
 532 ;;;###autoload
 533 (defun gnus-cache-generate-active (&optional directory)
 534   "Generate the cache active file."
 535   (interactive)
 536   (let* ((top (null directory))
 537          (directory (expand-file-name (or directory gnus-cache-directory)))
 538          (files (directory-files directory 'full))
 539          (group
 540           (if top
 541               ""
 542             (string-match
 543              (concat "^" (file-name-as-directory
 544                           (expand-file-name gnus-cache-directory)))
 545              (directory-file-name directory))
 546             (nnheader-replace-chars-in-string
 547              (substring (directory-file-name directory) (match-end 0))
 548              ?/ ?.)))
 549          nums alphs)
 550     (when top
 551       (gnus-message 5 "Generating the cache active file...")
 552       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 553     ;; Separate articles from all other files and directories.
 554     (while files
 555       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 556           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 557         (push (pop files) alphs)))
 558     ;; If we have nums, then this is probably a valid group.
 559     (setq nums (sort nums '<))
 560     (if nums
 561         (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 562                       gnus-cache-active-hashtb))
 563     ;; Go through all the other files.
 564     (while alphs
 565       (when (and (file-directory-p (car alphs))
 566                  (not (string-match "^\\.\\.?$"
 567                                     (file-name-nondirectory (car alphs)))))
 568         ;; We descend directories.
 569         (gnus-cache-generate-active (car alphs)))
 570       (setq alphs (cdr alphs)))
 571     ;; Write the new active file.
 572     (when top
 573       (gnus-cache-write-active t)
 574       (gnus-message 5 "Generating the cache active file...done"))))
 575
 576 ;;;###autoload
 577 (defun gnus-cache-generate-nov-databases (dir)
 578   "Generate NOV files recursively starting in DIR."
 579   (interactive (list gnus-cache-directory))
 580   (gnus-cache-close)
 581   (let ((nnml-generate-active-function 'identity))
 582     (nnml-generate-nov-databases-1 dir)))
 583
 584 (provide 'gnus-cache)
 585
 586 ;;; gnus-cache.el ends here