cgit.sxemacs.org Git - gnus/blob - lisp/gnus-art.el

   1 ;;; gnus-art.el --- article mode commands for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-sum)
  30 (require 'article)
  31 (require 'gnus-spec)
  32 (require 'gnus-int)
  33 (require 'browse-url)
  34
  35 (defcustom gnus-article-save-directory gnus-directory
  36   "*Name of the directory articles will be saved in (default \"~/News\")."
  37   :group 'article
  38   :type 'directory)
  39
  40 (defcustom gnus-save-all-headers t
  41   "*If non-nil, don't remove any headers before saving."
  42   :group 'article
  43   :type 'boolean)
  44
  45 (defcustom gnus-prompt-before-saving 'always
  46   "*This variable says how much prompting is to be done when saving articles.
  47 If it is nil, no prompting will be done, and the articles will be
  48 saved to the default files.  If this variable is `always', each and
  49 every article that is saved will be preceded by a prompt, even when
  50 saving large batches of articles.  If this variable is neither nil not
  51 `always', there the user will be prompted once for a file name for
  52 each invocation of the saving commands."
  53   :group 'article
  54   :type '(choice (item always)
  55                  (item :tag "never" nil)
  56                  (sexp :tag "once" :format "%t")))
  57
  58 (defcustom gnus-saved-headers gnus-visible-headers
  59   "Headers to keep if `gnus-save-all-headers' is nil.
  60 If `gnus-save-all-headers' is non-nil, this variable will be ignored.
  61 If that variable is nil, however, all headers that match this regexp
  62 will be kept while the rest will be deleted before saving."
  63   :group 'article
  64   :type '(repeat string))
  65
  66 (defcustom gnus-default-article-saver 'gnus-summary-save-in-rmail
  67   "A function to save articles in your favourite format.
  68 The function must be interactively callable (in other words, it must
  69 be an Emacs command).
  70
  71 Gnus provides the following functions:
  72
  73 * gnus-summary-save-in-rmail (Rmail format)
  74 * gnus-summary-save-in-mail (Unix mail format)
  75 * gnus-summary-save-in-folder (MH folder)
  76 * gnus-summary-save-in-file (article format)
  77 * gnus-summary-save-in-vm (use VM's folder format)
  78 * gnus-summary-write-to-file (article format -- overwrite)."
  79   :group 'article
  80   :type '(radio (function-item gnus-summary-save-in-rmail)
  81                 (function-item gnus-summary-save-in-mail)
  82                 (function-item gnus-summary-save-in-folder)
  83                 (function-item gnus-summary-save-in-file)
  84                 (function-item gnus-summary-save-in-vm)
  85                 (function-item gnus-summary-write-to-file)))
  86
  87 (defcustom gnus-rmail-save-name 'gnus-plain-save-name
  88   "A function generating a file name to save articles in Rmail format.
  89 The function is called with NEWSGROUP, HEADERS, and optional LAST-FILE."
  90   :group 'article
  91   :type 'function)
  92
  93 (defcustom gnus-mail-save-name 'gnus-plain-save-name
  94   "A function generating a file name to save articles in Unix mail format.
  95 The function is called with NEWSGROUP, HEADERS, and optional LAST-FILE."
  96   :group 'article
  97   :type 'function)
  98
  99 (defcustom gnus-folder-save-name 'gnus-folder-save-name
 100   "A function generating a file name to save articles in MH folder.
 101 The function is called with NEWSGROUP, HEADERS, and optional LAST-FOLDER."
 102   :group 'article
 103   :type 'function)
 104
 105 (defcustom gnus-file-save-name 'gnus-numeric-save-name
 106   "A function generating a file name to save articles in article format.
 107 The function is called with NEWSGROUP, HEADERS, and optional
 108 LAST-FILE."
 109   :group 'article
 110   :type 'function)
 111
 112 (defcustom gnus-split-methods
 113   '((gnus-article-archive-name))
 114   "Variable used to suggest where articles are to be saved.
 115 For instance, if you would like to save articles related to Gnus in
 116 the file \"gnus-stuff\", and articles related to VM in \"vm-stuff\",
 117 you could set this variable to something like:
 118
 119  '((\"^Subject:.*gnus\\|^Newsgroups:.*gnus\" \"gnus-stuff\")
 120    (\"^Subject:.*vm\\|^Xref:.*vm\" \"vm-stuff\"))
 121
 122 This variable is an alist where the where the key is the match and the
 123 value is a list of possible files to save in if the match is non-nil.
 124
 125 If the match is a string, it is used as a regexp match on the
 126 article.  If the match is a symbol, that symbol will be funcalled
 127 from the buffer of the article to be saved with the newsgroup as the
 128 parameter.  If it is a list, it will be evaled in the same buffer.
 129
 130 If this form or function returns a string, this string will be used as
 131 a possible file name; and if it returns a non-nil list, that list will
 132 be used as possible file names."
 133   :group 'article
 134   :type '(repeat (choice (list function)
 135                          (cons regexp (repeat string))
 136                          sexp)))
 137
 138 (defcustom gnus-strict-mime t
 139   "*If nil, MIME-decode even if there is no Mime-Version header."
 140   :group 'article
 141   :type 'boolean)
 142
 143 (defcustom gnus-show-mime-method 'metamail-buffer
 144   "Function to process a MIME message.
 145 The function is called from the article buffer."
 146   :group 'article
 147   :type 'function)
 148
 149 (defcustom gnus-decode-encoded-word-method 'gnus-article-de-quoted-unreadable
 150   "*Function to decode MIME encoded words.
 151 The function is called from the article buffer."
 152   :group 'article
 153   :type 'function)
 154
 155 (defcustom gnus-page-delimiter "^\^L"
 156   "*Regexp describing what to use as article page delimiters.
 157 The default value is \"^\^L\", which is a form linefeed at the
 158 beginning of a line."
 159   :type 'regexp
 160   :group 'article)
 161
 162 (defcustom gnus-article-mode-line-format "Gnus: %%b %S"
 163   "*The format specification for the article mode line.
 164 See `gnus-summary-mode-line-format' for a closer description."
 165   :type 'string
 166   :group 'article)
 167
 168 (defcustom gnus-article-mode-hook nil
 169   "*A hook for Gnus article mode."
 170   :type 'hook
 171   :group 'article)
 172
 173 (defcustom gnus-article-menu-hook nil
 174   "*Hook run after the creation of the article mode menu."
 175   :type 'hook
 176   :group 'article)
 177
 178 (defcustom gnus-article-prepare-hook nil
 179   "*A hook called after an article has been prepared in the article buffer.
 180 If you want to run a special decoding program like nkf, use this hook."
 181   :type 'hook
 182   :group 'article)
 183
 184 (defcustom gnus-article-button-face 'bold
 185   "Face used for highlighting buttons in the article buffer.
 186
 187 An article button is a piece of text that you can activate by pressing
 188 `RET' or `mouse-2' above it."
 189   :type 'face
 190   :group 'article)
 191
 192 (defcustom gnus-article-mouse-face 'highlight
 193   "Face used for mouse highlighting in the article buffer.
 194
 195 Article buttons will be displayed in this face when the cursor is
 196 above them."
 197   :type 'face
 198   :group 'article)
 199
 200 (defcustom gnus-signature-face 'italic
 201   "Face used for highlighting a signature in the article buffer."
 202   :type 'face
 203   :group 'article)
 204
 205 (defface gnus-header-from-face
 206   '((((class color)
 207       (background dark))
 208      (:foreground "light blue" :bold t :italic t))
 209     (((class color)
 210       (background light))
 211      (:foreground "MidnightBlue" :bold t :italic t))
 212     (t
 213      (:bold t :italic t)))
 214   "Face used for displaying from headers."
 215   :group 'article)
 216
 217 (defface gnus-header-subject-face
 218   '((((class color)
 219       (background dark))
 220      (:foreground "pink" :bold t :italic t))
 221     (((class color)
 222       (background light))
 223      (:foreground "firebrick" :bold t :italic t))
 224     (t
 225      (:bold t :italic t)))
 226   "Face used for displaying subject headers."
 227   :group 'article)
 228
 229 (defface gnus-header-newsgroups-face
 230   '((((class color)
 231       (background dark))
 232      (:foreground "yellow" :bold t :italic t))
 233     (((class color)
 234       (background light))
 235      (:foreground "indianred" :bold t :italic t))
 236     (t
 237      (:bold t :italic t)))
 238   "Face used for displaying newsgroups headers."
 239   :group 'article)
 240
 241 (defface gnus-header-name-face
 242   '((((class color)
 243       (background dark))
 244      (:foreground "cyan" :bold t))
 245     (((class color)
 246       (background light))
 247      (:foreground "DarkGreen" :bold t))
 248     (t
 249      (:bold t)))
 250   "Face used for displaying header names."
 251   :group 'article)
 252
 253 (defface gnus-header-content-face
 254   '((((class color)
 255       (background dark))
 256      (:foreground "forest green" :italic t))
 257     (((class color)
 258       (background light))
 259      (:foreground "DarkGreen" :italic t))
 260     (t
 261      (:italic t)))  "Face used for displaying header content."
 262   :group 'article)
 263
 264 (defcustom gnus-header-face-alist
 265   '(("From" nil gnus-header-from-face)
 266     ("Subject" nil gnus-header-subject-face)
 267     ("Newsgroups:.*," nil gnus-header-newsgroups-face)
 268     ("" gnus-header-name-face gnus-header-content-face))
 269   "Controls highlighting of article header.
 270
 271 An alist of the form (HEADER NAME CONTENT).
 272
 273 HEADER is a regular expression which should match the name of an
 274 header header and NAME and CONTENT are either face names or nil.
 275
 276 The name of each header field will be displayed using the face
 277 specified by the first element in the list where HEADER match the
 278 header name and NAME is non-nil.  Similarly, the content will be
 279 displayed by the first non-nil matching CONTENT face."
 280   :group 'article
 281   :type '(repeat (list (regexp :tag "Header")
 282                        (choice :tag "Name"
 283                                (item :tag "skip" nil)
 284                                (face :value default))
 285                        (choice :tag "Content"
 286                                (item :tag "skip" nil)
 287                                (face :value default)))))
 288
 289 ;;; Internal variables
 290
 291 (defvar gnus-article-mode-syntax-table
 292   (let ((table (copy-syntax-table text-mode-syntax-table)))
 293     ;;(modify-syntax-entry ?_ "w" table)
 294     table)
 295   "Syntax table used in article mode buffers.
 296 Initialized from `text-mode-syntax-table.")
 297
 298 (defvar gnus-save-article-buffer nil)
 299
 300 (defvar gnus-article-mode-line-format-alist
 301     (nconc '((?w (gnus-article-wash-status) ?s))
 302            gnus-summary-mode-line-format-alist))
 303
 304 (defvar gnus-number-of-articles-to-be-saved nil)
 305
 306 ;;; Provide a mapping from `gnus-*' commands to Article commands.
 307
 308 (eval-and-compile
 309   (mapcar
 310    (lambda (func)
 311      (let (afunc gfunc)
 312        (if (consp func)
 313            (setq afunc (car func)
 314                  gfunc (cdr func))
 315          (setq afunc func
 316                gfunc (intern (format "gnus-%s" func))))
 317        (fset gfunc
 318              `(lambda (&optional interactive &rest args)
 319                 ,(documentation afunc t)
 320                 (interactive (list t))
 321                 (save-excursion
 322                   (set-buffer gnus-article-buffer)
 323                   (if interactive
 324                       (call-interactively ',afunc)
 325                     (apply ',afunc args)))))))
 326    '(article-hide-headers
 327      article-hide-boring-headers
 328      article-treat-overstrike
 329      (article-fill . gnus-article-word-wrap)
 330      article-remove-cr
 331      article-display-x-face
 332      article-de-quoted-unreadable
 333      article-mime-decode-quoted-printable
 334      article-hide-pgp
 335      article-hide-pem
 336      article-hide-signature
 337      article-remove-trailing-blank-lines
 338      article-strip-leading-blank-lines
 339      article-strip-multiple-blank-lines
 340      article-strip-blank-lines
 341      article-date-local
 342      article-date-original
 343      article-date-lapsed
 344      article-emphasize
 345      (article-show-all . gnus-article-show-all-headers))))
 346
 347 (defalias 'gnus-decode-rfc1522 'article-decode-rfc1522)
 348
 349 (defvar gnus-summary-article-menu)
 350
 351 ;;; Saving functions.
 352
 353 (defun gnus-article-save (save-buffer file &optional num)
 354   "Save the currently selected article."
 355   (unless gnus-save-all-headers
 356     ;; Remove headers according to `gnus-saved-headers'.
 357     (let ((gnus-visible-headers
 358            (or gnus-saved-headers gnus-visible-headers))
 359           (gnus-article-buffer save-buffer))
 360       (gnus-article-hide-headers 1 t)))
 361   (save-window-excursion
 362     (if (not gnus-default-article-saver)
 363         (error "No default saver is defined.")
 364       ;; !!! Magic!  The saving functions all save
 365       ;; `gnus-original-article-buffer' (or so they think), but we
 366       ;; bind that variable to our save-buffer.
 367       (set-buffer gnus-article-buffer)
 368       (let* ((gnus-save-article-buffer save-buffer)
 369              (filename
 370               (cond
 371                ((not gnus-prompt-before-saving) 'default)
 372                ((eq gnus-prompt-before-saving 'always) nil)
 373                (t file)))
 374              (gnus-number-of-articles-to-be-saved
 375               (when (eq gnus-prompt-before-saving t)
 376                 num)))                  ; Magic
 377         (set-buffer gnus-summary-buffer)
 378         (funcall gnus-default-article-saver filename)))))
 379
 380 (defun gnus-read-save-file-name (prompt default-name &optional filename)
 381   (cond
 382    ((eq filename 'default)
 383     default-name)
 384    (filename filename)
 385    (t
 386     (let* ((split-name (gnus-get-split-value gnus-split-methods))
 387            (prompt
 388             (format prompt (if (and gnus-number-of-articles-to-be-saved
 389                                     (> gnus-number-of-articles-to-be-saved 1))
 390                                (format "these %d articles"
 391                                        gnus-number-of-articles-to-be-saved)
 392                              "this article")))
 393            (file
 394             ;; Let the split methods have their say.
 395             (cond
 396              ;; No split name was found.
 397              ((null split-name)
 398               (read-file-name
 399                (concat prompt " (default "
 400                        (file-name-nondirectory default-name) ") ")
 401                (file-name-directory default-name)
 402                default-name))
 403              ;; A single split name was found
 404              ((= 1 (length split-name))
 405               (let* ((name (car split-name))
 406                      (dir (cond ((file-directory-p name)
 407                                  (file-name-as-directory name))
 408                                 ((file-exists-p name) name)
 409                                 (t gnus-article-save-directory))))
 410                 (read-file-name
 411                  (concat prompt " (default " name ") ")
 412                  dir name)))
 413              ;; A list of splits was found.
 414              (t
 415               (setq split-name (nreverse split-name))
 416               (let (result)
 417                 (let ((file-name-history (nconc split-name file-name-history)))
 418                   (setq result
 419                         (read-file-name
 420                          (concat prompt " (`M-p' for defaults) ")
 421                          gnus-article-save-directory
 422                          (car split-name))))
 423                 (car (push result file-name-history)))))))
 424       ;; Create the directory.
 425       (gnus-make-directory (file-name-directory file))
 426       ;; If we have read a directory, we append the default file name.
 427       (when (file-directory-p file)
 428         (setq file (concat (file-name-as-directory file)
 429                            (file-name-nondirectory default-name))))
 430       ;; Possibly translate some characters.
 431       (nnheader-translate-file-chars file)))))
 432
 433 (defun gnus-article-archive-name (group)
 434   "Return the first instance of an \"Archive-name\" in the current buffer."
 435   (let ((case-fold-search t))
 436     (when (re-search-forward "archive-name: *\\([^ \n\t]+\\)[ \t]*$" nil t)
 437       (nnheader-concat gnus-article-save-directory
 438                        (match-string 1)))))
 439
 440 (defun gnus-summary-save-in-rmail (&optional filename)
 441   "Append this article to Rmail file.
 442 Optional argument FILENAME specifies file name.
 443 Directory to save to is default to `gnus-article-save-directory'."
 444   (interactive)
 445   (gnus-set-global-variables)
 446   (let ((default-name
 447           (funcall gnus-rmail-save-name gnus-newsgroup-name
 448                    gnus-current-headers gnus-newsgroup-last-rmail)))
 449     (setq filename (gnus-read-save-file-name
 450                     "Save %s in rmail file:" default-name filename))
 451     (gnus-make-directory (file-name-directory filename))
 452     (gnus-eval-in-buffer-window gnus-save-article-buffer
 453       (save-excursion
 454         (save-restriction
 455           (widen)
 456           (gnus-output-to-rmail filename))))
 457     ;; Remember the directory name to save articles
 458     (setq gnus-newsgroup-last-rmail filename)))
 459
 460 (defun gnus-summary-save-in-mail (&optional filename)
 461   "Append this article to Unix mail file.
 462 Optional argument FILENAME specifies file name.
 463 Directory to save to is default to `gnus-article-save-directory'."
 464   (interactive)
 465   (gnus-set-global-variables)
 466   (let ((default-name
 467           (funcall gnus-mail-save-name gnus-newsgroup-name
 468                    gnus-current-headers gnus-newsgroup-last-mail)))
 469     (setq filename (gnus-read-save-file-name
 470                     "Save %s in Unix mail file:" default-name filename))
 471     (setq filename
 472           (expand-file-name filename
 473                             (and default-name
 474                                  (file-name-directory default-name))))
 475     (gnus-make-directory (file-name-directory filename))
 476     (gnus-eval-in-buffer-window gnus-save-article-buffer
 477       (save-excursion
 478         (save-restriction
 479           (widen)
 480           (if (and (file-readable-p filename) (mail-file-babyl-p filename))
 481               (gnus-output-to-rmail filename)
 482             (let ((mail-use-rfc822 t))
 483               (rmail-output filename 1 t t))))))
 484     ;; Remember the directory name to save articles.
 485     (setq gnus-newsgroup-last-mail filename)))
 486
 487 (defun gnus-summary-save-in-file (&optional filename overwrite)
 488   "Append this article to file.
 489 Optional argument FILENAME specifies file name.
 490 Directory to save to is default to `gnus-article-save-directory'."
 491   (interactive)
 492   (gnus-set-global-variables)
 493   (let ((default-name
 494           (funcall gnus-file-save-name gnus-newsgroup-name
 495                    gnus-current-headers gnus-newsgroup-last-file)))
 496     (setq filename (gnus-read-save-file-name
 497                     "Save %s in file:" default-name filename))
 498     (gnus-make-directory (file-name-directory filename))
 499     (gnus-eval-in-buffer-window gnus-save-article-buffer
 500       (save-excursion
 501         (save-restriction
 502           (widen)
 503           (when (and overwrite
 504                      (file-exists-p filename))
 505             (delete-file filename))
 506           (gnus-output-to-file filename))))
 507     ;; Remember the directory name to save articles.
 508     (setq gnus-newsgroup-last-file filename)))
 509
 510 (defun gnus-summary-write-to-file (&optional filename)
 511   "Write this article to a file.
 512 Optional argument FILENAME specifies file name.
 513 The directory to save in defaults to `gnus-article-save-directory'."
 514   (interactive)
 515   (gnus-summary-save-in-file nil t))
 516
 517 (defun gnus-summary-save-body-in-file (&optional filename)
 518   "Append this article body to a file.
 519 Optional argument FILENAME specifies file name.
 520 The directory to save in defaults to `gnus-article-save-directory'."
 521   (interactive)
 522   (gnus-set-global-variables)
 523   (let ((default-name
 524           (funcall gnus-file-save-name gnus-newsgroup-name
 525                    gnus-current-headers gnus-newsgroup-last-file)))
 526     (setq filename (gnus-read-save-file-name
 527                     "Save %s body in file:" default-name filename))
 528     (gnus-make-directory (file-name-directory filename))
 529     (gnus-eval-in-buffer-window gnus-save-article-buffer
 530       (save-excursion
 531         (save-restriction
 532           (widen)
 533           (goto-char (point-min))
 534           (when (search-forward "\n\n" nil t)
 535             (narrow-to-region (point) (point-max)))
 536           (gnus-output-to-file filename))))
 537     ;; Remember the directory name to save articles.
 538     (setq gnus-newsgroup-last-file filename)))
 539
 540 (defun gnus-summary-save-in-pipe (&optional command)
 541   "Pipe this article to subprocess."
 542   (interactive)
 543   (gnus-set-global-variables)
 544   (setq command
 545         (cond ((eq command 'default)
 546                gnus-last-shell-command)
 547               (command command)
 548               (t (read-string "Shell command on article: "
 549                               gnus-last-shell-command))))
 550   (when (string-equal command "")
 551     (setq command gnus-last-shell-command))
 552   (gnus-eval-in-buffer-window gnus-article-buffer
 553     (save-restriction
 554       (widen)
 555       (shell-command-on-region (point-min) (point-max) command nil)))
 556   (setq gnus-last-shell-command command))
 557
 558 ;;; Article file names when saving.
 559
 560 (defun gnus-capitalize-newsgroup (newsgroup)
 561   "Capitalize NEWSGROUP name."
 562   (when (not (zerop (length newsgroup)))
 563     (concat (char-to-string (upcase (aref newsgroup 0)))
 564             (substring newsgroup 1))))
 565
 566 (defun gnus-Numeric-save-name (newsgroup headers &optional last-file)
 567   "Generate file name from NEWSGROUP, HEADERS, and optional LAST-FILE.
 568 If variable `gnus-use-long-file-name' is nil, it is ~/News/News.group/num.
 569 Otherwise, it is like ~/News/news/group/num."
 570   (let ((default
 571           (expand-file-name
 572            (concat (if (gnus-use-long-file-name 'not-save)
 573                        (gnus-capitalize-newsgroup newsgroup)
 574                      (gnus-newsgroup-directory-form newsgroup))
 575                    "/" (int-to-string (mail-header-number headers)))
 576            gnus-article-save-directory)))
 577     (if (and last-file
 578              (string-equal (file-name-directory default)
 579                            (file-name-directory last-file))
 580              (string-match "^[0-9]+$" (file-name-nondirectory last-file)))
 581         default
 582       (or last-file default))))
 583
 584 (defun gnus-numeric-save-name (newsgroup headers &optional last-file)
 585   "Generate file name from NEWSGROUP, HEADERS, and optional LAST-FILE.
 586 If variable `gnus-use-long-file-name' is non-nil, it is
 587 ~/News/news.group/num.  Otherwise, it is like ~/News/news/group/num."
 588   (let ((default
 589           (expand-file-name
 590            (concat (if (gnus-use-long-file-name 'not-save)
 591                        newsgroup
 592                      (gnus-newsgroup-directory-form newsgroup))
 593                    "/" (int-to-string (mail-header-number headers)))
 594            gnus-article-save-directory)))
 595     (if (and last-file
 596              (string-equal (file-name-directory default)
 597                            (file-name-directory last-file))
 598              (string-match "^[0-9]+$" (file-name-nondirectory last-file)))
 599         default
 600       (or last-file default))))
 601
 602 (defun gnus-Plain-save-name (newsgroup headers &optional last-file)
 603   "Generate file name from NEWSGROUP, HEADERS, and optional LAST-FILE.
 604 If variable `gnus-use-long-file-name' is non-nil, it is
 605 ~/News/News.group.  Otherwise, it is like ~/News/news/group/news."
 606   (or last-file
 607       (expand-file-name
 608        (if (gnus-use-long-file-name 'not-save)
 609            (gnus-capitalize-newsgroup newsgroup)
 610          (concat (gnus-newsgroup-directory-form newsgroup) "/news"))
 611        gnus-article-save-directory)))
 612
 613 (defun gnus-plain-save-name (newsgroup headers &optional last-file)
 614   "Generate file name from NEWSGROUP, HEADERS, and optional LAST-FILE.
 615 If variable `gnus-use-long-file-name' is non-nil, it is
 616 ~/News/news.group.  Otherwise, it is like ~/News/news/group/news."
 617   (or last-file
 618       (expand-file-name
 619        (if (gnus-use-long-file-name 'not-save)
 620            newsgroup
 621          (concat (gnus-newsgroup-directory-form newsgroup) "/news"))
 622        gnus-article-save-directory)))
 623
 624 \f
 625 ;;;
 626 ;;; Gnus article mode
 627 ;;;
 628
 629 (put 'gnus-article-mode 'mode-class 'special)
 630
 631 (when t
 632   (gnus-define-keys gnus-article-mode-map
 633     " " gnus-article-goto-next-page
 634     "\177" gnus-article-goto-prev-page
 635     [delete] gnus-article-goto-prev-page
 636     "\C-c^" gnus-article-refer-article
 637     "h" gnus-article-show-summary
 638     "s" gnus-article-show-summary
 639     "\C-c\C-m" gnus-article-mail
 640     "?" gnus-article-describe-briefly
 641     gnus-mouse-2 gnus-article-push-button
 642     "\r" gnus-article-press-button
 643     "\t" gnus-article-next-button
 644     "\M-\t" gnus-article-prev-button
 645     "e" gnus-article-edit
 646     "<" beginning-of-buffer
 647     ">" end-of-buffer
 648     "\C-c\C-i" gnus-info-find-node
 649     "\C-c\C-b" gnus-bug
 650
 651     "\C-d" gnus-article-read-summary-keys
 652     "\M-*" gnus-article-read-summary-keys
 653     "\M-g" gnus-article-read-summary-keys)
 654
 655   (substitute-key-definition
 656    'undefined 'gnus-article-read-summary-keys gnus-article-mode-map))
 657
 658 (defun gnus-article-make-menu-bar ()
 659   (gnus-turn-off-edit-menu 'article)
 660   (unless (boundp 'gnus-article-article-menu)
 661     (easy-menu-define
 662      gnus-article-article-menu gnus-article-mode-map ""
 663      '("Article"
 664        ["Scroll forwards" gnus-article-goto-next-page t]
 665        ["Scroll backwards" gnus-article-goto-prev-page t]
 666        ["Show summary" gnus-article-show-summary t]
 667        ["Fetch Message-ID at point" gnus-article-refer-article t]
 668        ["Mail to address at point" gnus-article-mail t]))
 669
 670     (easy-menu-define
 671      gnus-article-treatment-menu gnus-article-mode-map ""
 672      '("Treatment"
 673        ["Hide headers" gnus-article-hide-headers t]
 674        ["Hide signature" gnus-article-hide-signature t]
 675        ["Hide citation" gnus-article-hide-citation t]
 676        ["Treat overstrike" gnus-article-treat-overstrike t]
 677        ["Remove carriage return" gnus-article-remove-cr t]
 678        ["Remove quoted-unreadable" gnus-article-de-quoted-unreadable t]))
 679
 680     (define-key gnus-article-mode-map [Article] gnus-summary-article-menu)
 681
 682     (run-hooks 'gnus-article-menu-hook)))
 683
 684 (defun gnus-article-mode ()
 685   "Major mode for displaying an article.
 686
 687 All normal editing commands are switched off.
 688
 689 The following commands are available in addition to all summary mode
 690 commands:
 691 \\<gnus-article-mode-map>
 692 \\[gnus-article-next-page]\t Scroll the article one page forwards
 693 \\[gnus-article-prev-page]\t Scroll the article one page backwards
 694 \\[gnus-article-refer-article]\t Go to the article referred to by an article id near point
 695 \\[gnus-article-show-summary]\t Display the summary buffer
 696 \\[gnus-article-mail]\t Send a reply to the address near point
 697 \\[gnus-article-describe-briefly]\t Describe the current mode briefly
 698 \\[gnus-info-find-node]\t Go to the Gnus info node"
 699   (interactive)
 700   (when (and menu-bar-mode
 701              (gnus-visual-p 'article-menu 'menu))
 702     (gnus-article-make-menu-bar))
 703   (kill-all-local-variables)
 704   (gnus-simplify-mode-line)
 705   (setq mode-name "Article")
 706   (setq major-mode 'gnus-article-mode)
 707   (make-local-variable 'minor-mode-alist)
 708   (unless (assq 'gnus-show-mime minor-mode-alist)
 709     (push (list 'gnus-show-mime " MIME") minor-mode-alist))
 710   (use-local-map gnus-article-mode-map)
 711   (gnus-update-format-specifications nil 'article-mode)
 712   (set (make-local-variable 'page-delimiter) gnus-page-delimiter)
 713   (gnus-set-default-directory)
 714   (buffer-disable-undo (current-buffer))
 715   (setq buffer-read-only t)
 716   (set-syntax-table gnus-article-mode-syntax-table)
 717   (run-hooks 'gnus-article-mode-hook))
 718
 719 (defun gnus-article-setup-buffer ()
 720   "Initialize the article buffer."
 721   (let* ((name (if gnus-single-article-buffer "*Article*"
 722                  (concat "*Article " gnus-newsgroup-name "*")))
 723          (original
 724           (progn (string-match "\\*Article" name)
 725                  (concat " *Original Article"
 726                          (substring name (match-end 0))))))
 727     (setq gnus-article-buffer name)
 728     (setq gnus-original-article-buffer original)
 729     ;; This might be a variable local to the summary buffer.
 730     (unless gnus-single-article-buffer
 731       (save-excursion
 732         (set-buffer gnus-summary-buffer)
 733         (setq gnus-article-buffer name)
 734         (setq gnus-original-article-buffer original)
 735         (gnus-set-global-variables)))
 736     ;; Init original article buffer.
 737     (save-excursion
 738       (set-buffer (get-buffer-create gnus-original-article-buffer))
 739       (buffer-disable-undo (current-buffer))
 740       (setq major-mode 'gnus-original-article-mode)
 741       (gnus-add-current-to-buffer-list)
 742       (make-local-variable 'gnus-original-article))
 743     (if (get-buffer name)
 744         (save-excursion
 745           (set-buffer name)
 746           (buffer-disable-undo (current-buffer))
 747           (setq buffer-read-only t)
 748           (gnus-add-current-to-buffer-list)
 749           (unless (eq major-mode 'gnus-article-mode)
 750             (gnus-article-mode))
 751           (current-buffer))
 752       (save-excursion
 753         (set-buffer (get-buffer-create name))
 754         (gnus-add-current-to-buffer-list)
 755         (gnus-article-mode)
 756         (make-local-variable 'gnus-summary-buffer)
 757         (current-buffer)))))
 758
 759 ;; Set article window start at LINE, where LINE is the number of lines
 760 ;; from the head of the article.
 761 (defun gnus-article-set-window-start (&optional line)
 762   (set-window-start
 763    (get-buffer-window gnus-article-buffer t)
 764    (save-excursion
 765      (set-buffer gnus-article-buffer)
 766      (goto-char (point-min))
 767      (if (not line)
 768          (point-min)
 769        (gnus-message 6 "Moved to bookmark")
 770        (search-forward "\n\n" nil t)
 771        (forward-line line)
 772        (point)))))
 773
 774 (defun gnus-article-prepare (article &optional all-headers header)
 775   "Prepare ARTICLE in article mode buffer.
 776 ARTICLE should either be an article number or a Message-ID.
 777 If ARTICLE is an id, HEADER should be the article headers.
 778 If ALL-HEADERS is non-nil, no headers are hidden."
 779   (save-excursion
 780     ;; Make sure we start in a summary buffer.
 781     (unless (eq major-mode 'gnus-summary-mode)
 782       (set-buffer gnus-summary-buffer))
 783     (setq gnus-summary-buffer (current-buffer))
 784     ;; Make sure the connection to the server is alive.
 785     (unless (gnus-server-opened
 786              (gnus-find-method-for-group gnus-newsgroup-name))
 787       (gnus-check-server (gnus-find-method-for-group gnus-newsgroup-name))
 788       (gnus-request-group gnus-newsgroup-name t))
 789     (let* ((article (if header (mail-header-number header) article))
 790            (summary-buffer (current-buffer))
 791            (internal-hook gnus-article-internal-prepare-hook)
 792            (group gnus-newsgroup-name)
 793            result)
 794       (save-excursion
 795         (gnus-article-setup-buffer)
 796         (set-buffer gnus-article-buffer)
 797         ;; Deactivate active regions.
 798         (when (and (boundp 'transient-mark-mode)
 799                    transient-mark-mode)
 800           (setq mark-active nil))
 801         (if (not (setq result (let ((buffer-read-only nil))
 802                                 (gnus-request-article-this-buffer
 803                                  article group))))
 804             ;; There is no such article.
 805             (save-excursion
 806               (when (and (numberp article)
 807                          (not (memq article gnus-newsgroup-sparse)))
 808                 (setq gnus-article-current
 809                       (cons gnus-newsgroup-name article))
 810                 (set-buffer gnus-summary-buffer)
 811                 (setq gnus-current-article article)
 812                 (gnus-summary-mark-article article gnus-canceled-mark))
 813               (unless (memq article gnus-newsgroup-sparse)
 814                 (gnus-error
 815                  1 "No such article (may have expired or been canceled)")))
 816           (if (or (eq result 'pseudo) (eq result 'nneething))
 817               (progn
 818                 (save-excursion
 819                   (set-buffer summary-buffer)
 820                   (setq gnus-last-article gnus-current-article
 821                         gnus-newsgroup-history (cons gnus-current-article
 822                                                      gnus-newsgroup-history)
 823                         gnus-current-article 0
 824                         gnus-current-headers nil
 825                         gnus-article-current nil)
 826                   (if (eq result 'nneething)
 827                       (gnus-configure-windows 'summary)
 828                     (gnus-configure-windows 'article))
 829                   (gnus-set-global-variables))
 830                 (gnus-set-mode-line 'article))
 831             ;; The result from the `request' was an actual article -
 832             ;; or at least some text that is now displayed in the
 833             ;; article buffer.
 834             (when (and (numberp article)
 835                        (not (eq article gnus-current-article)))
 836               ;; Seems like a new article has been selected.
 837               ;; `gnus-current-article' must be an article number.
 838               (save-excursion
 839                 (set-buffer summary-buffer)
 840                 (setq gnus-last-article gnus-current-article
 841                       gnus-newsgroup-history (cons gnus-current-article
 842                                                    gnus-newsgroup-history)
 843                       gnus-current-article article
 844                       gnus-current-headers
 845                       (gnus-summary-article-header gnus-current-article)
 846                       gnus-article-current
 847                       (cons gnus-newsgroup-name gnus-current-article))
 848                 (unless (vectorp gnus-current-headers)
 849                   (setq gnus-current-headers nil))
 850                 (gnus-summary-show-thread)
 851                 (run-hooks 'gnus-mark-article-hook)
 852                 (gnus-set-mode-line 'summary)
 853                 (when (gnus-visual-p 'article-highlight 'highlight)
 854                   (run-hooks 'gnus-visual-mark-article-hook))
 855                 ;; Set the global newsgroup variables here.
 856                 ;; Suggested by Jim Sisolak
 857                 ;; <sisolak@trans4.neep.wisc.edu>.
 858                 (gnus-set-global-variables)
 859                 (setq gnus-have-all-headers
 860                       (or all-headers gnus-show-all-headers))
 861                 (and gnus-use-cache
 862                      (vectorp (gnus-summary-article-header article))
 863                      (gnus-cache-possibly-enter-article
 864                       group article
 865                       (gnus-summary-article-header article)
 866                       (memq article gnus-newsgroup-marked)
 867                       (memq article gnus-newsgroup-dormant)
 868                       (memq article gnus-newsgroup-unreads)))))
 869             (when (or (numberp article)
 870                       (stringp article))
 871               ;; Hooks for getting information from the article.
 872               ;; This hook must be called before being narrowed.
 873               (let (buffer-read-only)
 874                 (run-hooks 'internal-hook)
 875                 (run-hooks 'gnus-article-prepare-hook)
 876                 ;; Decode MIME message.
 877                 (when gnus-show-mime
 878                   (if (or (not gnus-strict-mime)
 879                           (gnus-fetch-field "Mime-Version"))
 880                       (funcall gnus-show-mime-method)
 881                     (funcall gnus-decode-encoded-word-method)))
 882                 ;; Perform the article display hooks.
 883                 (run-hooks 'gnus-article-display-hook))
 884               ;; Do page break.
 885               (goto-char (point-min))
 886               (when gnus-break-pages
 887                 (gnus-narrow-to-page)))
 888             (gnus-set-mode-line 'article)
 889             (gnus-configure-windows 'article)
 890             (goto-char (point-min))
 891             t))))))
 892
 893 (defun gnus-article-wash-status ()
 894   "Return a string which display status of article washing."
 895   (save-excursion
 896     (set-buffer gnus-article-buffer)
 897     (let ((cite (article-hidden-text-p 'cite))
 898           (headers (article-hidden-text-p 'headers))
 899           (boring (article-hidden-text-p 'boring-headers))
 900           (pgp (article-hidden-text-p 'pgp))
 901           (pem (article-hidden-text-p 'pem))
 902           (signature (article-hidden-text-p 'signature))
 903           (overstrike (article-hidden-text-p 'overstrike))
 904           (emphasis (article-hidden-text-p 'emphasis))
 905           (mime gnus-show-mime))
 906       (format "%c%c%c%c%c%c%c"
 907               (if cite ?c ? )
 908               (if (or headers boring) ?h ? )
 909               (if (or pgp pem) ?p ? )
 910               (if signature ?s ? )
 911               (if overstrike ?o ? )
 912               (if mime ?m ? )
 913               (if emphasis ?e ? )))))
 914
 915 (defun gnus-article-hide-headers-if-wanted ()
 916   "Hide unwanted headers if `gnus-have-all-headers' is nil.
 917 Provided for backwards compatibility."
 918   (or (save-excursion (set-buffer gnus-summary-buffer) gnus-have-all-headers)
 919       gnus-inhibit-hiding
 920       (gnus-article-hide-headers)))
 921
 922 ;;; Article savers.
 923
 924 (defun gnus-output-to-rmail (file-name)
 925   "Append the current article to an Rmail file named FILE-NAME."
 926   (require 'rmail)
 927   ;; Most of these codes are borrowed from rmailout.el.
 928   (setq file-name (expand-file-name file-name))
 929   (setq rmail-default-rmail-file file-name)
 930   (let ((artbuf (current-buffer))
 931         (tmpbuf (get-buffer-create " *Gnus-output*")))
 932     (save-excursion
 933       (or (get-file-buffer file-name)
 934           (file-exists-p file-name)
 935           (if (gnus-yes-or-no-p
 936                (concat "\"" file-name "\" does not exist, create it? "))
 937               (let ((file-buffer (create-file-buffer file-name)))
 938                 (save-excursion
 939                   (set-buffer file-buffer)
 940                   (rmail-insert-rmail-file-header)
 941                   (let ((require-final-newline nil))
 942                     (gnus-write-buffer file-name)))
 943                 (kill-buffer file-buffer))
 944             (error "Output file does not exist")))
 945       (set-buffer tmpbuf)
 946       (buffer-disable-undo (current-buffer))
 947       (erase-buffer)
 948       (insert-buffer-substring artbuf)
 949       (gnus-convert-article-to-rmail)
 950       ;; Decide whether to append to a file or to an Emacs buffer.
 951       (let ((outbuf (get-file-buffer file-name)))
 952         (if (not outbuf)
 953             (append-to-file (point-min) (point-max) file-name)
 954           ;; File has been visited, in buffer OUTBUF.
 955           (set-buffer outbuf)
 956           (let ((buffer-read-only nil)
 957                 (msg (and (boundp 'rmail-current-message)
 958                           (symbol-value 'rmail-current-message))))
 959             ;; If MSG is non-nil, buffer is in RMAIL mode.
 960             (when msg
 961               (widen)
 962               (narrow-to-region (point-max) (point-max)))
 963             (insert-buffer-substring tmpbuf)
 964             (when msg
 965               (goto-char (point-min))
 966               (widen)
 967               (search-backward "\^_")
 968               (narrow-to-region (point) (point-max))
 969               (goto-char (1+ (point-min)))
 970               (rmail-count-new-messages t)
 971               (rmail-show-message msg))))))
 972     (kill-buffer tmpbuf)))
 973
 974 (defun gnus-output-to-file (file-name)
 975   "Append the current article to a file named FILE-NAME."
 976   (let ((artbuf (current-buffer)))
 977     (nnheader-temp-write nil
 978       (insert-buffer-substring artbuf)
 979       ;; Append newline at end of the buffer as separator, and then
 980       ;; save it to file.
 981       (goto-char (point-max))
 982       (insert "\n")
 983       (append-to-file (point-min) (point-max) file-name))))
 984
 985 (defun gnus-convert-article-to-rmail ()
 986   "Convert article in current buffer to Rmail message format."
 987   (let ((buffer-read-only nil))
 988     ;; Convert article directly into Babyl format.
 989     ;; Suggested by Rob Austein <sra@lcs.mit.edu>
 990     (goto-char (point-min))
 991     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 992     (while (search-forward "\n\^_" nil t) ;single char
 993       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 994     (goto-char (point-max))
 995     (insert "\^_")))
 996
 997 (defun gnus-narrow-to-page (&optional arg)
 998   "Narrow the article buffer to a page.
 999 If given a numerical ARG, move forward ARG pages."
1000   (interactive "P")
1001   (setq arg (if arg (prefix-numeric-value arg) 0))
1002   (save-excursion
1003     (set-buffer gnus-article-buffer)
1004     (goto-char (point-min))
1005     (widen)
1006     ;; Remove any old next/prev buttons.
1007     (when (gnus-visual-p 'page-marker)
1008       (let ((buffer-read-only nil))
1009         (gnus-remove-text-with-property 'gnus-prev)
1010         (gnus-remove-text-with-property 'gnus-next)))
1011     (when
1012         (cond ((< arg 0)
1013                (re-search-backward page-delimiter nil 'move (1+ (abs arg))))
1014               ((> arg 0)
1015                (re-search-forward page-delimiter nil 'move arg)))
1016       (goto-char (match-end 0)))
1017     (narrow-to-region
1018      (point)
1019      (if (re-search-forward page-delimiter nil 'move)
1020          (match-beginning 0)
1021        (point)))
1022     (when (and (gnus-visual-p 'page-marker)
1023                (not (= (point-min) 1)))
1024       (save-excursion
1025         (goto-char (point-min))
1026         (gnus-insert-prev-page-button)))
1027     (when (and (gnus-visual-p 'page-marker)
1028                (< (+ (point-max) 2) (buffer-size)))
1029       (save-excursion
1030         (goto-char (point-max))
1031         (gnus-insert-next-page-button)))))
1032
1033 ;; Article mode commands
1034
1035 (defun gnus-article-goto-next-page ()
1036   "Show the next page of the article."
1037   (interactive)
1038   (when (gnus-article-next-page)
1039     (gnus-article-read-summary-keys nil (gnus-character-to-event ?n))))
1040
1041 (defun gnus-article-goto-prev-page ()
1042   "Show the next page of the article."
1043   (interactive)
1044   (if (bobp) (gnus-article-read-summary-keys nil (gnus-character-to-event ?n))
1045     (gnus-article-prev-page nil)))
1046
1047 (defun gnus-article-next-page (&optional lines)
1048   "Show the next page of the current article.
1049 If end of article, return non-nil.  Otherwise return nil.
1050 Argument LINES specifies lines to be scrolled up."
1051   (interactive "p")
1052   (move-to-window-line -1)
1053   (if (save-excursion
1054         (end-of-line)
1055         (and (pos-visible-in-window-p)  ;Not continuation line.
1056              (eobp)))
1057       ;; Nothing in this page.
1058       (if (or (not gnus-break-pages)
1059               (save-excursion
1060                 (save-restriction
1061                   (widen) (forward-line 1) (eobp)))) ;Real end-of-buffer?
1062           t                             ;Nothing more.
1063         (gnus-narrow-to-page 1)         ;Go to next page.
1064         nil)
1065     ;; More in this page.
1066     (let ((scroll-in-place nil))
1067       (condition-case ()
1068           (scroll-up lines)
1069         (end-of-buffer
1070          ;; Long lines may cause an end-of-buffer error.
1071          (goto-char (point-max)))))
1072     (move-to-window-line 0)
1073     nil))
1074
1075 (defun gnus-article-prev-page (&optional lines)
1076   "Show previous page of current article.
1077 Argument LINES specifies lines to be scrolled down."
1078   (interactive "p")
1079   (move-to-window-line 0)
1080   (if (and gnus-break-pages
1081            (bobp)
1082            (not (save-restriction (widen) (bobp)))) ;Real beginning-of-buffer?
1083       (progn
1084         (gnus-narrow-to-page -1)        ;Go to previous page.
1085         (goto-char (point-max))
1086         (recenter -1))
1087     (let ((scroll-in-place nil))
1088       (prog1
1089           (ignore-errors
1090             (scroll-down lines))
1091         (move-to-window-line 0)))))
1092
1093 (defun gnus-article-refer-article ()
1094   "Read article specified by message-id around point."
1095   (interactive)
1096   (let ((point (point)))
1097     (search-forward ">" nil t)          ;Move point to end of "<....>".
1098     (if (re-search-backward "\\(<[^<> \t\n]+>\\)" nil t)
1099         (let ((message-id (match-string 1)))
1100           (goto-char point)
1101           (set-buffer gnus-summary-buffer)
1102           (gnus-summary-refer-article message-id))
1103       (goto-char (point))
1104       (error "No references around point"))))
1105
1106 (defun gnus-article-show-summary ()
1107   "Reconfigure windows to show summary buffer."
1108   (interactive)
1109   (gnus-configure-windows 'article)
1110   (gnus-summary-goto-subject gnus-current-article))
1111
1112 (defun gnus-article-describe-briefly ()
1113   "Describe article mode commands briefly."
1114   (interactive)
1115   (gnus-message 6
1116                 (substitute-command-keys "\\<gnus-article-mode-map>\\[gnus-article-goto-next-page]:Next page     \\[gnus-article-goto-prev-page]:Prev page  \\[gnus-article-show-summary]:Show summary  \\[gnus-info-find-node]:Run Info  \\[gnus-article-describe-briefly]:This help")))
1117
1118 (defun gnus-article-summary-command ()
1119   "Execute the last keystroke in the summary buffer."
1120   (interactive)
1121   (let ((obuf (current-buffer))
1122         (owin (current-window-configuration))
1123         func)
1124     (switch-to-buffer gnus-summary-buffer 'norecord)
1125     (setq func (lookup-key (current-local-map) (this-command-keys)))
1126     (call-interactively func)
1127     (set-buffer obuf)
1128     (set-window-configuration owin)
1129     (set-window-point (get-buffer-window (current-buffer)) (point))))
1130
1131 (defun gnus-article-summary-command-nosave ()
1132   "Execute the last keystroke in the summary buffer."
1133   (interactive)
1134   (let (func)
1135     (pop-to-buffer gnus-summary-buffer 'norecord)
1136     (setq func (lookup-key (current-local-map) (this-command-keys)))
1137     (call-interactively func)))
1138
1139 (defun gnus-article-read-summary-keys (&optional arg key not-restore-window)
1140   "Read a summary buffer key sequence and execute it from the article buffer."
1141   (interactive "P")
1142   (let ((nosaves
1143          '("q" "Q"  "c" "r" "R" "\C-c\C-f" "m"  "a" "f" "F"
1144            "Zc" "ZC" "ZE" "ZQ" "ZZ" "Zn" "ZR" "ZG" "ZN" "ZP"
1145            "=" "^" "\M-^" "|"))
1146         (nosave-but-article
1147          '("A\r"))
1148         (nosave-in-article
1149          '("\C-d"))
1150         keys)
1151     (save-excursion
1152       (set-buffer gnus-summary-buffer)
1153       (push (or key last-command-event) unread-command-events)
1154       (setq keys (read-key-sequence nil)))
1155     (message "")
1156
1157     (if (or (member keys nosaves)
1158             (member keys nosave-but-article)
1159             (member keys nosave-in-article))
1160         (let (func)
1161           (save-window-excursion
1162             (pop-to-buffer gnus-summary-buffer 'norecord)
1163             (setq func (lookup-key (current-local-map) keys)))
1164           (if (not func)
1165               (ding)
1166             (unless (member keys nosave-in-article)
1167               (set-buffer gnus-summary-buffer))
1168             (call-interactively func))
1169           (when (member keys nosave-but-article)
1170             (pop-to-buffer gnus-article-buffer 'norecord)))
1171       ;; These commands should restore window configuration.
1172       (let ((obuf (current-buffer))
1173             (owin (current-window-configuration))
1174             (opoint (point))
1175             func in-buffer)
1176         (if not-restore-window
1177             (pop-to-buffer gnus-summary-buffer 'norecord)
1178           (switch-to-buffer gnus-summary-buffer 'norecord))
1179         (setq in-buffer (current-buffer))
1180         (if (setq func (lookup-key (current-local-map) keys))
1181             (call-interactively func)
1182           (ding))
1183         (when (eq in-buffer (current-buffer))
1184           (set-buffer obuf)
1185           (unless not-restore-window
1186             (set-window-configuration owin))
1187           (set-window-point (get-buffer-window (current-buffer)) opoint))))))
1188
1189 (defun gnus-article-hide (&optional arg force)
1190   "Hide all the gruft in the current article.
1191 This means that PGP stuff, signatures, cited text and (some)
1192 headers will be hidden.
1193 If given a prefix, show the hidden text instead."
1194   (interactive (list current-prefix-arg 'force))
1195   (gnus-article-hide-headers arg)
1196   (gnus-article-hide-pgp arg)
1197   (gnus-article-hide-citation-maybe arg force)
1198   (gnus-article-hide-signature arg))
1199
1200 (defun gnus-article-maybe-highlight ()
1201   "Do some article highlighting if `article-visual' is non-nil."
1202   (when (gnus-visual-p 'article-highlight 'highlight)
1203     (gnus-article-highlight-some)))
1204
1205 (defun gnus-request-article-this-buffer (article group)
1206   "Get an article and insert it into this buffer."
1207   (let (do-update-line)
1208     (prog1
1209         (save-excursion
1210           (erase-buffer)
1211           (gnus-kill-all-overlays)
1212           (setq group (or group gnus-newsgroup-name))
1213
1214           ;; Open server if it has closed.
1215           (gnus-check-server (gnus-find-method-for-group group))
1216
1217           ;; Using `gnus-request-article' directly will insert the article into
1218           ;; `nntp-server-buffer' - so we'll save some time by not having to
1219           ;; copy it from the server buffer into the article buffer.
1220
1221           ;; We only request an article by message-id when we do not have the
1222           ;; headers for it, so we'll have to get those.
1223           (when (stringp article)
1224             (let ((gnus-override-method gnus-refer-article-method))
1225               (gnus-read-header article)))
1226
1227           ;; If the article number is negative, that means that this article
1228           ;; doesn't belong in this newsgroup (possibly), so we find its
1229           ;; message-id and request it by id instead of number.
1230           (when (and (numberp article)
1231                      gnus-summary-buffer
1232                      (get-buffer gnus-summary-buffer)
1233                      (buffer-name (get-buffer gnus-summary-buffer)))
1234             (save-excursion
1235               (set-buffer gnus-summary-buffer)
1236               (let ((header (gnus-summary-article-header article)))
1237                 (when (< article 0)
1238                   (cond
1239                    ((memq article gnus-newsgroup-sparse)
1240                     ;; This is a sparse gap article.
1241                     (setq do-update-line article)
1242                     (setq article (mail-header-id header))
1243                     (let ((gnus-override-method gnus-refer-article-method))
1244                       (gnus-read-header article))
1245                     (setq gnus-newsgroup-sparse
1246                           (delq article gnus-newsgroup-sparse)))
1247                    ((vectorp header)
1248                     ;; It's a real article.
1249                     (setq article (mail-header-id header)))
1250                    (t
1251                     ;; It is an extracted pseudo-article.
1252                     (setq article 'pseudo)
1253                     (gnus-request-pseudo-article header))))
1254
1255                 (let ((method (gnus-find-method-for-group
1256                                gnus-newsgroup-name)))
1257                   (if (not (eq (car method) 'nneething))
1258                       ()
1259                     (let ((dir (concat (file-name-as-directory (nth 1 method))
1260                                        (mail-header-subject header))))
1261                       (when (file-directory-p dir)
1262                         (setq article 'nneething)
1263                         (gnus-group-enter-directory dir))))))))
1264
1265           (cond
1266            ;; Refuse to select canceled articles.
1267            ((and (numberp article)
1268                  gnus-summary-buffer
1269                  (get-buffer gnus-summary-buffer)
1270                  (buffer-name (get-buffer gnus-summary-buffer))
1271                  (eq (cdr (save-excursion
1272                             (set-buffer gnus-summary-buffer)
1273                             (assq article gnus-newsgroup-reads)))
1274                      gnus-canceled-mark))
1275             nil)
1276            ;; We first check `gnus-original-article-buffer'.
1277            ((and (get-buffer gnus-original-article-buffer)
1278                  (numberp article)
1279                  (save-excursion
1280                    (set-buffer gnus-original-article-buffer)
1281                    (and (equal (car gnus-original-article) group)
1282                         (eq (cdr gnus-original-article) article))))
1283             (insert-buffer-substring gnus-original-article-buffer)
1284             'article)
1285            ;; Check the backlog.
1286            ((and gnus-keep-backlog
1287                  (gnus-backlog-request-article group article (current-buffer)))
1288             'article)
1289            ;; Check asynchronous pre-fetch.
1290            ((gnus-async-request-fetched-article group article (current-buffer))
1291             (gnus-async-prefetch-next group article gnus-summary-buffer)
1292             'article)
1293            ;; Check the cache.
1294            ((and gnus-use-cache
1295                  (numberp article)
1296                  (gnus-cache-request-article article group))
1297             'article)
1298            ;; Get the article and put into the article buffer.
1299            ((or (stringp article) (numberp article))
1300             (let ((gnus-override-method
1301                    (and (stringp article) gnus-refer-article-method))
1302                   (buffer-read-only nil))
1303               (erase-buffer)
1304               (gnus-kill-all-overlays)
1305               (when (gnus-request-article article group (current-buffer))
1306                 (when (numberp article)
1307                   (gnus-async-prefetch-next group article gnus-summary-buffer)
1308                   (when gnus-keep-backlog
1309                     (gnus-backlog-enter-article
1310                      group article (current-buffer))))
1311                 'article)))
1312            ;; It was a pseudo.
1313            (t article)))
1314
1315       ;; Take the article from the original article buffer
1316       ;; and place it in the buffer it's supposed to be in.
1317       (when (and (get-buffer gnus-article-buffer)
1318                  ;;(numberp article)
1319                  (equal (buffer-name (current-buffer))
1320                         (buffer-name (get-buffer gnus-article-buffer))))
1321         (save-excursion
1322           (if (get-buffer gnus-original-article-buffer)
1323               (set-buffer (get-buffer gnus-original-article-buffer))
1324             (set-buffer (get-buffer-create gnus-original-article-buffer))
1325             (buffer-disable-undo (current-buffer))
1326             (setq major-mode 'gnus-original-article-mode)
1327             (setq buffer-read-only t)
1328             (gnus-add-current-to-buffer-list))
1329           (let (buffer-read-only)
1330             (erase-buffer)
1331             (insert-buffer-substring gnus-article-buffer))
1332           (setq gnus-original-article (cons group article))))
1333
1334       ;; Update sparse articles.
1335       (when (and do-update-line
1336                  (or (numberp article)
1337                      (stringp article)))
1338         (let ((buf (current-buffer)))
1339           (set-buffer gnus-summary-buffer)
1340           (gnus-summary-update-article do-update-line)
1341           (gnus-summary-goto-subject do-update-line nil t)
1342           (set-window-point (get-buffer-window (current-buffer) t)
1343                             (point))
1344           (set-buffer buf))))))
1345
1346 (defun gnus-article-date-ut (&optional type highlight)
1347   "Convert DATE date to universal time in the current article.
1348 If TYPE is `local', convert to local time; if it is `lapsed', output
1349 how much time has lapsed since DATE."
1350   (interactive (list 'ut t))
1351   (let ((headers (or gnus-current-headers (gnus-summary-article-header))))
1352     (save-excursion
1353       (set-buffer gnus-article-buffer)
1354       (article-date-ut type highlight headers))))
1355
1356 ;;;
1357 ;;; Article editing
1358 ;;;
1359
1360 (defcustom gnus-article-edit-mode-hook nil
1361   "Hook run in article edit mode buffers."
1362   :group 'article
1363   :type 'hook)
1364
1365 (defvar gnus-article-edit-done-function nil)
1366
1367 (defvar gnus-article-edit-mode-map nil)
1368
1369 (unless gnus-article-edit-mode-map
1370   (setq gnus-article-edit-mode-map (copy-keymap text-mode-map))
1371
1372   (gnus-define-keys gnus-article-edit-mode-map
1373     "\C-c\C-c" gnus-article-edit-done
1374     "\C-c\C-k" gnus-article-edit-exit)
1375
1376   (gnus-define-keys (gnus-article-edit-wash-map
1377                      "\C-c\C-w" gnus-article-edit-mode-map)
1378     "f" gnus-article-edit-full-stops))
1379
1380 (defun gnus-article-edit-mode ()
1381   "Major mode for editing articles.
1382 This is an extended text-mode.
1383
1384 \\{gnus-article-edit-mode-map}"
1385   (interactive)
1386   (kill-all-local-variables)
1387   (setq major-mode 'gnus-article-edit-mode)
1388   (setq mode-name "Article Edit")
1389   (use-local-map gnus-article-edit-mode-map)
1390   (make-local-variable 'gnus-article-edit-done-function)
1391   (make-local-variable 'gnus-prev-winconf)
1392   (setq buffer-read-only nil)
1393   (buffer-enable-undo)
1394   (widen)
1395   (run-hooks 'text-mode 'gnus-article-edit-mode-hook))
1396
1397 (defun gnus-article-edit (&optional force)
1398   "Edit the current article.
1399 This will have permanent effect only in mail groups.
1400 If FORCE is non-nil, allow editing of articles even in read-only
1401 groups."
1402   (interactive "P")
1403   (when (and (not force)
1404              (gnus-group-read-only-p))
1405     (error "The current newsgroup does not support article editing."))
1406   (gnus-article-edit-article
1407    `(lambda ()
1408       (gnus-summary-edit-article-done
1409        ,(or (mail-header-references gnus-current-headers) "")
1410        ,(gnus-group-read-only-p) ,gnus-summary-buffer))))
1411
1412 (defun gnus-article-edit-article (exit-func)
1413   "Start editing the contents of the current article buffer."
1414   (let ((winconf (current-window-configuration)))
1415     (set-buffer gnus-article-buffer)
1416     (gnus-article-edit-mode)
1417     (set-text-properties (point-min) (point-max) nil)
1418     (gnus-configure-windows 'edit-article)
1419     (setq gnus-article-edit-done-function exit-func)
1420     (setq gnus-prev-winconf winconf)
1421     (gnus-message 6 "C-c C-c to end edits")))
1422
1423 (defun gnus-article-edit-done ()
1424   "Update the article edits and exit."
1425   (interactive)
1426   (let ((func gnus-article-edit-done-function)
1427         (buf (current-buffer))
1428         (start (window-start)))
1429     (gnus-article-edit-exit)
1430     (save-excursion
1431       (set-buffer buf)
1432       (let ((buffer-read-only nil))
1433         (funcall func)))
1434     (set-buffer buf)
1435     (set-window-start (get-buffer-window buf) start)
1436     (set-window-point (get-buffer-window buf) (point))))
1437
1438 (defun gnus-article-edit-exit ()
1439   "Exit the article editing without updating."
1440   (interactive)
1441   ;; We remove all text props from the article buffer.
1442   (let ((buf (format "%s" (buffer-string)))
1443         (curbuf (current-buffer))
1444         (p (point))
1445         (window-start (window-start)))
1446     (erase-buffer)
1447     (insert buf)
1448     (let ((winconf gnus-prev-winconf))
1449       (gnus-article-mode)
1450       ;; The cache and backlog have to be flushed somewhat.
1451       (when gnus-use-cache
1452         (gnus-cache-update-article
1453          (car gnus-article-current) (cdr gnus-article-current)))
1454       (when gnus-keep-backlog
1455         (gnus-backlog-remove-article
1456          (car gnus-article-current) (cdr gnus-article-current)))
1457       ;; Flush original article as well.
1458       (save-excursion
1459         (when (get-buffer gnus-original-article-buffer)
1460           (set-buffer gnus-original-article-buffer)
1461           (setq gnus-original-article nil)))
1462       (set-window-configuration winconf)
1463       ;; Tippy-toe some to make sure that point remains where it was.
1464       (let ((buf (current-buffer)))
1465         (set-buffer curbuf)
1466         (set-window-start (get-buffer-window (current-buffer)) window-start)
1467         (goto-char p)
1468         (set-buffer buf)))))
1469
1470 (defun gnus-article-edit-full-stops ()
1471   "Interactively repair spacing at end of sentences."
1472   (interactive)
1473   (save-excursion
1474     (goto-char (point-min))
1475     (search-forward-regexp "^$" nil t)
1476     (let ((case-fold-search nil))
1477       (query-replace-regexp "\\([.!?][])}]* \\)\\([[({A-Z]\\)" "\\1 \\2"))))
1478
1479 ;;;
1480 ;;; Article highlights
1481 ;;;
1482
1483 ;; Written by Per Abrahamsen <abraham@iesd.auc.dk>.
1484
1485 ;;; Internal Variables:
1486
1487 (defcustom gnus-button-url-regexp "\\b\\(s?https?\\|ftp\\|file\\|gopher\\|news\\|telnet\\|wais\\|mailto\\):\\(//[-a-zA-Z0-9_.]+:[0-9]*\\)?[-\\wa-zA-Z0-9_=!?#$@~`%&*+|\\/:;.,]*[-\\wa-zA-Z0-9_=#$@~`%&*+|\\/]"
1488   "Regular expression that matches URLs."
1489   :group 'article
1490   :type 'regexp)
1491
1492 (defcustom gnus-button-alist
1493   `(("\\bin\\( +article\\)? +\\(<\\([^\n @<>]+@[^\n @<>]+\\)>\\)" 2
1494      t gnus-button-message-id 3)
1495     ("\\(<?\\(url: ?\\)?news://\\([^>\n\t ]*\\)>?\\)" 1 t
1496      gnus-button-fetch-group 3)
1497     ("\\(<?\\(url: ?\\)?news:\\([^>\n\t ]*\\)>?\\)" 1 t
1498      gnus-button-message-id 3)
1499     ("\\(<URL: *\\)?mailto: *\\([^> \n\t]+\\)>?" 0 t gnus-url-mailto 2)
1500     ;; This is how URLs _should_ be embedded in text...
1501     ("<URL: *\\([^\n\r>]*\\)>" 0 t gnus-button-url 1)
1502     ;; Next regexp stolen from highlight-headers.el.
1503     ;; Modified by Vladimir Alexiev.
1504     (,gnus-button-url-regexp 0 t gnus-button-url 0))
1505   "Alist of regexps matching buttons in article bodies.
1506
1507 Each entry has the form (REGEXP BUTTON FORM CALLBACK PAR...), where
1508 REGEXP: is the string matching text around the button,
1509 BUTTON: is the number of the regexp grouping actually matching the button,
1510 FORM: is a lisp expression which must eval to true for the button to
1511 be added,
1512 CALLBACK: is the function to call when the user push this button, and each
1513 PAR: is a number of a regexp grouping whose text will be passed to CALLBACK.
1514
1515 CALLBACK can also be a variable, in that case the value of that
1516 variable it the real callback function."
1517   :group 'article
1518   :type '(repeat (list regexp
1519                        (integer :tag "Button")
1520                        (sexp :tag "Form")
1521                        (function :tag "Callback")
1522                        (repeat :tag "Par"
1523                                :inline t
1524                                (integer :tag "Regexp group")))))
1525
1526 (defcustom gnus-header-button-alist
1527   `(("^\\(References\\|Message-I[Dd]\\):" "<[^>]+>"
1528      0 t gnus-button-message-id 0)
1529     ("^\\(From\\|Reply-To\\):" ": *\\(.+\\)$" 1 t gnus-button-reply 1)
1530     ("^\\(Cc\\|To\\):" "[^ \t\n<>,()\"]+@[^ \t\n<>,()\"]+"
1531      0 t gnus-button-mailto 0)
1532     ("^X-[Uu][Rr][Ll]:" ,gnus-button-url-regexp 0 t gnus-button-url 0)
1533     ("^[^:]+:" ,gnus-button-url-regexp 0 t gnus-button-url 0)
1534     ("^[^:]+:" "\\(<\\(url: \\)?news:\\([^>\n ]*\\)>\\)" 1 t
1535      gnus-button-message-id 3))
1536   "Alist of headers and regexps to match buttons in article heads.
1537
1538 This alist is very similar to `gnus-button-alist', except that each
1539 alist has an additional HEADER element first in each entry:
1540
1541 \(HEADER REGEXP BUTTON FORM CALLBACK PAR)
1542
1543 HEADER is a regexp to match a header.  For a fuller explanation, see
1544 `gnus-button-alist'."
1545   :group 'article
1546   :type '(repeat (list (regexp :tag "Header")
1547                        regexp
1548                        (integer :tag "Button")
1549                        (sexp :tag "Form")
1550                        (function :tag "Callback")
1551                        (repeat :tag "Par"
1552                                :inline t
1553                                (integer :tag "Regexp group")))))
1554
1555 (defvar gnus-button-regexp nil)
1556 (defvar gnus-button-marker-list nil)
1557 ;; Regexp matching any of the regexps from `gnus-button-alist'.
1558
1559 (defvar gnus-button-last nil)
1560 ;; The value of `gnus-button-alist' when `gnus-button-regexp' was build.
1561
1562 ;;; Commands:
1563
1564 (defun gnus-article-push-button (event)
1565   "Check text under the mouse pointer for a callback function.
1566 If the text under the mouse pointer has a `gnus-callback' property,
1567 call it with the value of the `gnus-data' text property."
1568   (interactive "e")
1569   (set-buffer (window-buffer (posn-window (event-start event))))
1570   (let* ((pos (posn-point (event-start event)))
1571          (data (get-text-property pos 'gnus-data))
1572          (fun (get-text-property pos 'gnus-callback)))
1573     (when fun
1574       (funcall fun data))))
1575
1576 (defun gnus-article-press-button ()
1577   "Check text at point for a callback function.
1578 If the text at point has a `gnus-callback' property,
1579 call it with the value of the `gnus-data' text property."
1580   (interactive)
1581   (let* ((data (get-text-property (point) 'gnus-data))
1582          (fun (get-text-property (point) 'gnus-callback)))
1583     (when fun
1584       (funcall fun data))))
1585
1586 (defun gnus-article-prev-button (n)
1587   "Move point to N buttons backward.
1588 If N is negative, move forward instead."
1589   (interactive "p")
1590   (gnus-article-next-button (- n)))
1591
1592 (defun gnus-article-next-button (n)
1593   "Move point to N buttons forward.
1594 If N is negative, move backward instead."
1595   (interactive "p")
1596   (let ((function (if (< n 0) 'previous-single-property-change
1597                     'next-single-property-change))
1598         (inhibit-point-motion-hooks t)
1599         (backward (< n 0))
1600         (limit (if (< n 0) (point-min) (point-max))))
1601     (setq n (abs n))
1602     (while (and (not (= limit (point)))
1603                 (> n 0))
1604       ;; Skip past the current button.
1605       (when (get-text-property (point) 'gnus-callback)
1606         (goto-char (funcall function (point) 'gnus-callback nil limit)))
1607       ;; Go to the next (or previous) button.
1608       (gnus-goto-char (funcall function (point) 'gnus-callback nil limit))
1609       ;; Put point at the start of the button.
1610       (when (and backward (not (get-text-property (point) 'gnus-callback)))
1611         (goto-char (funcall function (point) 'gnus-callback nil limit)))
1612       ;; Skip past intangible buttons.
1613       (when (get-text-property (point) 'intangible)
1614         (incf n))
1615       (decf n))
1616     (unless (zerop n)
1617       (gnus-message 5 "No more buttons"))
1618     n))
1619
1620 (defun gnus-article-highlight (&optional force)
1621   "Highlight current article.
1622 This function calls `gnus-article-highlight-headers',
1623 `gnus-article-highlight-citation',
1624 `gnus-article-highlight-signature', and `gnus-article-add-buttons' to
1625 do the highlighting.  See the documentation for those functions."
1626   (interactive (list 'force))
1627   (gnus-article-highlight-headers)
1628   (gnus-article-highlight-citation force)
1629   (gnus-article-highlight-signature)
1630   (gnus-article-add-buttons force)
1631   (gnus-article-add-buttons-to-head))
1632
1633 (defun gnus-article-highlight-some (&optional force)
1634   "Highlight current article.
1635 This function calls `gnus-article-highlight-headers',
1636 `gnus-article-highlight-signature', and `gnus-article-add-buttons' to
1637 do the highlighting.  See the documentation for those functions."
1638   (interactive (list 'force))
1639   (gnus-article-highlight-headers)
1640   (gnus-article-highlight-signature)
1641   (gnus-article-add-buttons))
1642
1643 (defun gnus-article-highlight-headers ()
1644   "Highlight article headers as specified by `gnus-header-face-alist'."
1645   (interactive)
1646   (save-excursion
1647     (set-buffer gnus-article-buffer)
1648     (save-restriction
1649       (let ((alist gnus-header-face-alist)
1650             (buffer-read-only nil)
1651             (case-fold-search t)
1652             (inhibit-point-motion-hooks t)
1653             entry regexp header-face field-face from hpoints fpoints)
1654         (goto-char (point-min))
1655         (when (search-forward "\n\n" nil t)
1656           (narrow-to-region (1- (point)) (point-min))
1657           (while (setq entry (pop alist))
1658             (goto-char (point-min))
1659             (setq regexp (concat "^\\("
1660                                  (if (string-equal "" (nth 0 entry))
1661                                      "[^\t ]"
1662                                    (nth 0 entry))
1663                                  "\\)")
1664                   header-face (nth 1 entry)
1665                   field-face (nth 2 entry))
1666             (while (and (re-search-forward regexp nil t)
1667                         (not (eobp)))
1668               (beginning-of-line)
1669               (setq from (point))
1670               (unless (search-forward ":" nil t)
1671                 (forward-char 1))
1672               (when (and header-face
1673                          (not (memq (point) hpoints)))
1674                 (push (point) hpoints)
1675                 (gnus-put-text-property from (point) 'face header-face))
1676               (when (and field-face
1677                          (not (memq (setq from (point)) fpoints)))
1678                 (push from fpoints)
1679                 (if (re-search-forward "^[^ \t]" nil t)
1680                     (forward-char -2)
1681                   (goto-char (point-max)))
1682                 (gnus-put-text-property from (point) 'face field-face)))))))))
1683
1684 (defun gnus-article-highlight-signature ()
1685   "Highlight the signature in an article.
1686 It does this by highlighting everything after
1687 `gnus-signature-separator' using `gnus-signature-face'."
1688   (interactive)
1689   (save-excursion
1690     (set-buffer gnus-article-buffer)
1691     (let ((buffer-read-only nil)
1692           (inhibit-point-motion-hooks t))
1693       (save-restriction
1694         (when (and gnus-signature-face
1695                    (article-narrow-to-signature))
1696           (gnus-overlay-put (gnus-make-overlay (point-min) (point-max))
1697                             'face gnus-signature-face)
1698           (widen)
1699           (article-search-signature)
1700           (let ((start (match-beginning 0))
1701                 (end (set-marker (make-marker) (1+ (match-end 0)))))
1702             (gnus-article-add-button start (1- end) 'gnus-signature-toggle
1703                                      end)))))))
1704
1705 (defun gnus-article-add-buttons (&optional force)
1706   "Find external references in the article and make buttons of them.
1707 \"External references\" are things like Message-IDs and URLs, as
1708 specified by `gnus-button-alist'."
1709   (interactive (list 'force))
1710   (save-excursion
1711     (set-buffer gnus-article-buffer)
1712     ;; Remove all old markers.
1713     (while gnus-button-marker-list
1714       (set-marker (pop gnus-button-marker-list) nil))
1715     (let ((buffer-read-only nil)
1716           (inhibit-point-motion-hooks t)
1717           (case-fold-search t)
1718           (alist gnus-button-alist)
1719           beg entry regexp)
1720       (goto-char (point-min))
1721       ;; We skip the headers.
1722       (unless (search-forward "\n\n" nil t)
1723         (goto-char (point-max)))
1724       (setq beg (point))
1725       (while (setq entry (pop alist))
1726         (setq regexp (car entry))
1727         (goto-char beg)
1728         (while (re-search-forward regexp nil t)
1729           (let* ((start (and entry (match-beginning (nth 1 entry))))
1730                  (end (and entry (match-end (nth 1 entry))))
1731                  (from (match-beginning 0)))
1732             (when (or (eq t (nth 1 entry))
1733                       (eval (nth 1 entry)))
1734               ;; That optional form returned non-nil, so we add the
1735               ;; button.
1736               (gnus-article-add-button
1737                start end 'gnus-button-push
1738                (car (push (set-marker (make-marker) from)
1739                           gnus-button-marker-list))))))))))
1740
1741 ;; Add buttons to the head of an article.
1742 (defun gnus-article-add-buttons-to-head ()
1743   "Add buttons to the head of the article."
1744   (interactive)
1745   (save-excursion
1746     (set-buffer gnus-article-buffer)
1747     (let ((buffer-read-only nil)
1748           (inhibit-point-motion-hooks t)
1749           (case-fold-search t)
1750           (alist gnus-header-button-alist)
1751           entry beg end)
1752       (nnheader-narrow-to-headers)
1753       (while alist
1754         ;; Each alist entry.
1755         (setq entry (car alist)
1756               alist (cdr alist))
1757         (goto-char (point-min))
1758         (while (re-search-forward (car entry) nil t)
1759           ;; Each header matching the entry.
1760           (setq beg (match-beginning 0))
1761           (setq end (or (and (re-search-forward "^[^ \t]" nil t)
1762                              (match-beginning 0))
1763                         (point-max)))
1764           (goto-char beg)
1765           (while (re-search-forward (nth 1 entry) end t)
1766             ;; Each match within a header.
1767             (let* ((entry (cdr entry))
1768                    (start (match-beginning (nth 1 entry)))
1769                    (end (match-end (nth 1 entry)))
1770                    (form (nth 2 entry)))
1771               (goto-char (match-end 0))
1772               (when (eval form)
1773                 (gnus-article-add-button
1774                  start end (nth 3 entry)
1775                  (buffer-substring (match-beginning (nth 4 entry))
1776                                    (match-end (nth 4 entry)))))))
1777           (goto-char end))))
1778     (widen)))
1779
1780 ;;; External functions:
1781
1782 (defun gnus-article-add-button (from to fun &optional data)
1783   "Create a button between FROM and TO with callback FUN and data DATA."
1784   (when gnus-article-button-face
1785     (gnus-overlay-put (gnus-make-overlay from to)
1786                       'face gnus-article-button-face))
1787   (gnus-add-text-properties
1788    from to
1789    (nconc (and gnus-article-mouse-face
1790                (list gnus-mouse-face-prop gnus-article-mouse-face))
1791           (list 'gnus-callback fun)
1792           (and data (list 'gnus-data data)))))
1793
1794 ;;; Internal functions:
1795
1796 (defun gnus-signature-toggle (end)
1797   (save-excursion
1798     (set-buffer gnus-article-buffer)
1799     (let ((buffer-read-only nil)
1800           (inhibit-point-motion-hooks t))
1801       (if (get-text-property end 'invisible)
1802           (article-unhide-text end (point-max))
1803         (article-hide-text end (point-max) gnus-hidden-properties)))))
1804
1805 (defun gnus-button-entry ()
1806   ;; Return the first entry in `gnus-button-alist' matching this place.
1807   (let ((alist gnus-button-alist)
1808         (entry nil))
1809     (while alist
1810       (setq entry (pop alist))
1811       (if (looking-at (car entry))
1812           (setq alist nil)
1813         (setq entry nil)))
1814     entry))
1815
1816 (defun gnus-button-push (marker)
1817   ;; Push button starting at MARKER.
1818   (save-excursion
1819     (set-buffer gnus-article-buffer)
1820     (goto-char marker)
1821     (let* ((entry (gnus-button-entry))
1822            (inhibit-point-motion-hooks t)
1823            (fun (nth 3 entry))
1824            (args (mapcar (lambda (group)
1825                            (let ((string (buffer-substring
1826                                           (match-beginning group)
1827                                           (match-end group))))
1828                              (gnus-set-text-properties
1829                               0 (length string) nil string)
1830                              string))
1831                          (nthcdr 4 entry))))
1832       (cond
1833        ((fboundp fun)
1834         (apply fun args))
1835        ((and (boundp fun)
1836              (fboundp (symbol-value fun)))
1837         (apply (symbol-value fun) args))
1838        (t
1839         (gnus-message 1 "You must define `%S' to use this button"
1840                       (cons fun args)))))))
1841
1842 (defun gnus-button-message-id (message-id)
1843   "Fetch MESSAGE-ID."
1844   (save-excursion
1845     (set-buffer gnus-summary-buffer)
1846     (gnus-summary-refer-article message-id)))
1847
1848 (defun gnus-button-fetch-group (address)
1849   "Fetch GROUP specified by ADDRESS."
1850   (if (not (string-match "^\\([^:/]+\\)\\(:\\([^/]+\\)\\)?/\\(.*\\)$" address))
1851       (error "Can't parse %s" address)
1852     (gnus-group-read-ephemeral-group
1853      (match-string 4 address)
1854      `(nntp ,(match-string 1 address) (nntp-address ,(match-string 1 address))
1855             (nntp-port-number ,(if (match-end 3)
1856                                    (match-string 3 address)
1857                                  "nntp"))))))
1858
1859 (defun gnus-split-string (string pattern)
1860   "Return a list of substrings of STRING which are separated by PATTERN."
1861   (let (parts (start 0))
1862     (while (string-match pattern string start)
1863       (setq parts (cons (substring string start (match-beginning 0)) parts)
1864             start (match-end 0)))
1865     (nreverse (cons (substring string start) parts))))
1866
1867 (defun gnus-url-parse-query-string (query &optional downcase)
1868   (let (retval pairs cur key val)
1869     (setq pairs (gnus-split-string query "&"))
1870     (while pairs
1871       (setq cur (car pairs)
1872             pairs (cdr pairs))
1873       (if (not (string-match "=" cur))
1874           nil                           ; Grace
1875         (setq key (gnus-url-unhex-string (substring cur 0 (match-beginning 0)))
1876               val (gnus-url-unhex-string (substring cur (match-end 0) nil)))
1877         (if downcase
1878             (setq key (downcase key)))
1879         (setq cur (assoc key retval))
1880         (if cur
1881             (setcdr cur (cons val (cdr cur)))
1882           (setq retval (cons (list key val) retval)))))
1883     retval))
1884
1885 (defun gnus-url-unhex (x)
1886   (if (> x ?9)
1887       (if (>= x ?a)
1888           (+ 10 (- x ?a))
1889         (+ 10 (- x ?A)))
1890     (- x ?0)))
1891
1892 (defun gnus-url-unhex-string (str &optional allow-newlines)
1893   "Remove %XXX embedded spaces, etc in a url.
1894 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
1895 decoding of carriage returns and line feeds in the string, which is normally
1896 forbidden in URL encoding."
1897   (setq str (or str ""))
1898   (let ((tmp "")
1899         (case-fold-search t))
1900     (while (string-match "%[0-9a-f][0-9a-f]" str)
1901       (let* ((start (match-beginning 0))
1902              (ch1 (gnus-url-unhex (elt str (+ start 1))))
1903              (code (+ (* 16 ch1)
1904                       (gnus-url-unhex (elt str (+ start 2))))))
1905         (setq tmp (concat
1906                    tmp (substring str 0 start)
1907                    (cond
1908                     (allow-newlines
1909                      (char-to-string code))
1910                     ((or (= code ?\n) (= code ?\r))
1911                      " ")
1912                     (t (char-to-string code))))
1913               str (substring str (match-end 0)))))
1914     (setq tmp (concat tmp str))
1915     tmp))
1916
1917 (defun gnus-url-mailto (url)
1918   ;; Send mail to someone
1919   (if (not (string-match "mailto:/*\\(.*\\)" url))
1920       (error "Malformed mailto link: %s" url))
1921   (setq url (substring url (match-beginning 1) nil))
1922   (let (to args source-url subject func)
1923     (if (string-match (regexp-quote "?") url)
1924         (setq to (gnus-url-unhex-string (substring url 0 (match-beginning 0)))
1925               args (gnus-url-parse-query-string
1926                     (substring url (match-end 0) nil) t))
1927       (setq to (gnus-url-unhex-string url)))
1928     (setq args (cons (list "to" to) args)
1929           subject (cdr-safe (assoc "subject" args)))
1930     (message-mail)
1931     (while args
1932       (setq func (intern-soft (concat "message-goto-" (downcase (caar args)))))
1933       (if (fboundp func)
1934           (funcall func)
1935         (message-position-on-field (caar args)))
1936       (insert (mapconcat 'identity (cdar args) ", "))
1937       (setq args (cdr args)))
1938     (if subject
1939         (message-goto-body)
1940       (message-goto-subject))))
1941
1942 (defun gnus-button-mailto (address)
1943   ;; Mail to ADDRESS.
1944   (set-buffer (gnus-copy-article-buffer))
1945   (message-reply address))
1946
1947 (defun gnus-button-reply (address)
1948   ;; Reply to ADDRESS.
1949   (message-reply address))
1950
1951 (defun gnus-button-url (address)
1952   "Browse ADDRESS."
1953   (funcall browse-url-browser-function address))
1954
1955 ;;; Next/prev buttons in the article buffer.
1956
1957 (defvar gnus-next-page-line-format "%{%(Next page...%)%}\n")
1958 (defvar gnus-prev-page-line-format "%{%(Previous page...%)%}\n")
1959
1960 (defvar gnus-prev-page-map nil)
1961 (unless gnus-prev-page-map
1962   (setq gnus-prev-page-map (make-sparse-keymap))
1963   (define-key gnus-prev-page-map gnus-mouse-2 'gnus-button-prev-page)
1964   (define-key gnus-prev-page-map "\r" 'gnus-button-prev-page))
1965
1966 (defun gnus-insert-prev-page-button ()
1967   (let ((buffer-read-only nil))
1968     (gnus-eval-format
1969      gnus-prev-page-line-format nil
1970      `(gnus-prev t local-map ,gnus-prev-page-map
1971                  gnus-callback gnus-article-button-prev-page))))
1972
1973 (defvar gnus-next-page-map nil)
1974 (unless gnus-next-page-map
1975   (setq gnus-next-page-map (make-keymap))
1976   (suppress-keymap gnus-prev-page-map)
1977   (define-key gnus-next-page-map gnus-mouse-2 'gnus-button-next-page)
1978   (define-key gnus-next-page-map "\r" 'gnus-button-next-page))
1979
1980 (defun gnus-button-next-page ()
1981   "Go to the next page."
1982   (interactive)
1983   (let ((win (selected-window)))
1984     (select-window (get-buffer-window gnus-article-buffer t))
1985     (gnus-article-next-page)
1986     (select-window win)))
1987
1988 (defun gnus-button-prev-page ()
1989   "Go to the prev page."
1990   (interactive)
1991   (let ((win (selected-window)))
1992     (select-window (get-buffer-window gnus-article-buffer t))
1993     (gnus-article-prev-page)
1994     (select-window win)))
1995
1996 (defun gnus-insert-next-page-button ()
1997   (let ((buffer-read-only nil))
1998     (gnus-eval-format gnus-next-page-line-format nil
1999                       `(gnus-next t local-map ,gnus-next-page-map
2000                                   gnus-callback
2001                                   gnus-article-button-next-page))))
2002
2003 (defun gnus-article-button-next-page (arg)
2004   "Go to the next page."
2005   (interactive "P")
2006   (let ((win (selected-window)))
2007     (select-window (get-buffer-window gnus-article-buffer t))
2008     (gnus-article-next-page)
2009     (select-window win)))
2010
2011 (defun gnus-article-button-prev-page (arg)
2012   "Go to the prev page."
2013   (interactive "P")
2014   (let ((win (selected-window)))
2015     (select-window (get-buffer-window gnus-article-buffer t))
2016     (gnus-article-prev-page)
2017     (select-window win)))
2018
2019 (provide 'gnus-art)
2020
2021 (run-hooks 'gnus-art-load-hook)
2022
2023 ;;; gnus-art.el ends here