cgit.sxemacs.org Git - gnus/blob - lisp/dns.el

   1 ;;; dns.el --- Domain Name Service lookups
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: network
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar dns-timeout 5
  31   "How many seconds to wait when doing DNS queries.")
  32
  33 (defvar dns-servers nil
  34   "Which DNS servers to query.
  35 If nil, /etc/resolv.conf will be consulted.")
  36
  37 ;;; Internal code:
  38
  39 (defvar dns-query-types
  40   '((A 1)
  41     (NS 2)
  42     (MD 3)
  43     (MF 4)
  44     (CNAME 5)
  45     (SOA 6)
  46     (MB 7)
  47     (MG 8)
  48     (MR 9)
  49     (NULL 10)
  50     (WKS 11)
  51     (PTR 12)
  52     (HINFO 13)
  53     (MINFO 14)
  54     (MX 15)
  55     (TXT 16)
  56     (AAAA 28) ; RFC3596
  57     (SRV 33) ; RFC2782
  58     (AXFR 252)
  59     (MAILB 253)
  60     (MAILA 254)
  61     (* 255))
  62   "Names of query types and their values.")
  63
  64 (defvar dns-classes
  65   '((IN 1)
  66     (CS 2)
  67     (CH 3)
  68     (HS 4))
  69   "Classes of queries.")
  70
  71 (defun dns-write-bytes (value &optional length)
  72   (let (bytes)
  73     (dotimes (i (or length 1))
  74       (push (% value 256) bytes)
  75       (setq value (/ value 256)))
  76     (dolist (byte bytes)
  77       (insert byte))))
  78
  79 (defun dns-read-bytes (length)
  80   (let ((value 0))
  81     (dotimes (i length)
  82       (setq value (logior (* value 256) (following-char)))
  83       (forward-char 1))
  84     value))
  85
  86 (defun dns-get (type spec)
  87   (cadr (assq type spec)))
  88
  89 (defun dns-inverse-get (value spec)
  90   (let ((found nil))
  91     (while (and (not found)
  92                 spec)
  93       (if (eq value (cadr (car spec)))
  94           (setq found (caar spec))
  95         (pop spec)))
  96     found))
  97
  98 (defun dns-write-name (name)
  99   (dolist (part (split-string name "\\."))
 100     (dns-write-bytes (length part))
 101     (insert part))
 102   (dns-write-bytes 0))
 103
 104 (defun dns-read-string-name (string buffer)
 105   (with-temp-buffer
 106     (set-buffer-multibyte nil)
 107     (insert string)
 108     (goto-char (point-min))
 109     (dns-read-name buffer)))
 110
 111 (defun dns-read-name (&optional buffer)
 112   (let ((ended nil)
 113         (name nil)
 114         length)
 115     (while (not ended)
 116       (setq length (dns-read-bytes 1))
 117       (if (= 192 (logand length (lsh 3 6)))
 118           (let ((offset (+ (* (logand 63 length) 256)
 119                            (dns-read-bytes 1))))
 120             (save-excursion
 121               (when buffer
 122                 (set-buffer buffer))
 123               (goto-char (1+ offset))
 124               (setq ended (dns-read-name buffer))))
 125         (if (zerop length)
 126             (setq ended t)
 127           (push (buffer-substring (point)
 128                                   (progn (forward-char length) (point)))
 129                 name))))
 130     (if (stringp ended)
 131         (if (null name)
 132             ended
 133           (concat (mapconcat 'identity (nreverse name) ".") "." ended))
 134       (mapconcat 'identity (nreverse name) "."))))
 135
 136 (defun dns-write (spec &optional tcp-p)
 137   "Write a DNS packet according to SPEC.
 138 If TCP-P, the first two bytes of the package with be the length field."
 139   (with-temp-buffer
 140     (set-buffer-multibyte nil)
 141     (dns-write-bytes (dns-get 'id spec) 2)
 142     (dns-write-bytes
 143      (logior
 144       (lsh (if (dns-get 'response-p spec) 1 0) -7)
 145       (lsh
 146        (cond
 147         ((eq (dns-get 'opcode spec) 'query) 0)
 148         ((eq (dns-get 'opcode spec) 'inverse-query) 1)
 149         ((eq (dns-get 'opcode spec) 'status) 2)
 150         (t (error "No such opcode: %s" (dns-get 'opcode spec))))
 151        -3)
 152       (lsh (if (dns-get 'authoritative-p spec) 1 0) -2)
 153       (lsh (if (dns-get 'truncated-p spec) 1 0) -1)
 154       (lsh (if (dns-get 'recursion-desired-p spec) 1 0) 0)))
 155     (dns-write-bytes
 156      (cond
 157       ((eq (dns-get 'response-code spec) 'no-error) 0)
 158       ((eq (dns-get 'response-code spec) 'format-error) 1)
 159       ((eq (dns-get 'response-code spec) 'server-failure) 2)
 160       ((eq (dns-get 'response-code spec) 'name-error) 3)
 161       ((eq (dns-get 'response-code spec) 'not-implemented) 4)
 162       ((eq (dns-get 'response-code spec) 'refused) 5)
 163       (t 0)))
 164     (dns-write-bytes (length (dns-get 'queries spec)) 2)
 165     (dns-write-bytes (length (dns-get 'answers spec)) 2)
 166     (dns-write-bytes (length (dns-get 'authorities spec)) 2)
 167     (dns-write-bytes (length (dns-get 'additionals spec)) 2)
 168     (dolist (query (dns-get 'queries spec))
 169       (dns-write-name (car query))
 170       (dns-write-bytes (cadr (assq (or (dns-get 'type query) 'A)
 171                                    dns-query-types)) 2)
 172       (dns-write-bytes (cadr (assq (or (dns-get 'class query) 'IN)
 173                                    dns-classes)) 2))
 174     (dolist (slot '(answers authorities additionals))
 175       (dolist (resource (dns-get slot spec))
 176         (dns-write-name (car resource))
 177       (dns-write-bytes (cadr (assq (dns-get 'type resource) dns-query-types))
 178                        2)
 179       (dns-write-bytes (cadr (assq (dns-get 'class resource) dns-classes))
 180                        2)
 181       (dns-write-bytes (dns-get 'ttl resource) 4)
 182       (dns-write-bytes (length (dns-get 'data resource)) 2)
 183       (insert (dns-get 'data resource))))
 184     (when tcp-p
 185       (goto-char (point-min))
 186       (dns-write-bytes (buffer-size) 2))
 187     (buffer-string)))
 188
 189 (defun dns-read (packet)
 190   (with-temp-buffer
 191     (set-buffer-multibyte nil)
 192     (let ((spec nil)
 193           queries answers authorities additionals)
 194       (insert packet)
 195       (goto-char (point-min))
 196       (push (list 'id (dns-read-bytes 2)) spec)
 197       (let ((byte (dns-read-bytes 1)))
 198         (push (list 'response-p (if (zerop (logand byte (lsh 1 7))) nil t))
 199               spec)
 200         (let ((opcode (logand byte (lsh 7 3))))
 201           (push (list 'opcode
 202                       (cond ((eq opcode 0) 'query)
 203                             ((eq opcode 1) 'inverse-query)
 204                             ((eq opcode 2) 'status)))
 205                 spec))
 206         (push (list 'authoritative-p (if (zerop (logand byte (lsh 1 2)))
 207                                          nil t)) spec)
 208         (push (list 'truncated-p (if (zerop (logand byte (lsh 1 2))) nil t))
 209               spec)
 210         (push (list 'recursion-desired-p
 211                     (if (zerop (logand byte (lsh 1 0))) nil t)) spec))
 212       (let ((rc (logand (dns-read-bytes 1) 15)))
 213         (push (list 'response-code
 214                     (cond
 215                      ((eq rc 0) 'no-error)
 216                      ((eq rc 1) 'format-error)
 217                      ((eq rc 2) 'server-failure)
 218                      ((eq rc 3) 'name-error)
 219                      ((eq rc 4) 'not-implemented)
 220                      ((eq rc 5) 'refused)))
 221               spec))
 222       (setq queries (dns-read-bytes 2))
 223       (setq answers (dns-read-bytes 2))
 224       (setq authorities (dns-read-bytes 2))
 225       (setq additionals (dns-read-bytes 2))
 226       (let ((qs nil))
 227         (dotimes (i queries)
 228           (push (list (dns-read-name)
 229                       (list 'type (dns-inverse-get (dns-read-bytes 2)
 230                                                    dns-query-types))
 231                       (list 'class (dns-inverse-get (dns-read-bytes 2)
 232                                                     dns-classes)))
 233                 qs))
 234         (push (list 'queries qs) spec))
 235       (dolist (slot '(answers authorities additionals))
 236         (let ((qs nil)
 237               type)
 238           (dotimes (i (symbol-value slot))
 239             (push (list (dns-read-name)
 240                         (list 'type
 241                               (setq type (dns-inverse-get (dns-read-bytes 2)
 242                                                           dns-query-types)))
 243                         (list 'class (dns-inverse-get (dns-read-bytes 2)
 244                                                       dns-classes))
 245                         (list 'ttl (dns-read-bytes 4))
 246                         (let ((length (dns-read-bytes 2)))
 247                           (list 'data
 248                                 (dns-read-type
 249                                  (buffer-substring
 250                                   (point)
 251                                   (progn (forward-char length) (point)))
 252                                  type))))
 253                   qs))
 254           (push (list slot qs) spec)))
 255       (nreverse spec))))
 256
 257 (defun dns-read-int32 ()
 258   ;; Full 32 bit Integers can't be handled by Emacs.  If we use
 259   ;; floats, it works.
 260   (format "%.0f" (+ (* (dns-read-bytes 1) 16777216.0)
 261                     (dns-read-bytes 3))))
 262
 263 (defun dns-read-type (string type)
 264   (let ((buffer (current-buffer))
 265         (point (point)))
 266     (prog1
 267         (with-temp-buffer
 268           (set-buffer-multibyte nil)
 269           (insert string)
 270           (goto-char (point-min))
 271           (cond
 272            ((eq type 'A)
 273             (let ((bytes nil))
 274               (dotimes (i 4)
 275                 (push (dns-read-bytes 1) bytes))
 276               (mapconcat 'number-to-string (nreverse bytes) ".")))
 277            ((eq type 'AAAA)
 278             (let (hextets)
 279               (dotimes (i 8)
 280                 (push (dns-read-bytes 2) hextets))
 281               (mapconcat (lambda (n) (format "%x" n))
 282                          (nreverse hextets) ":")))
 283            ((eq type 'SOA)
 284             (list (list 'mname (dns-read-name buffer))
 285                   (list 'rname (dns-read-name buffer))
 286                   (list 'serial (dns-read-int32))
 287                   (list 'refresh (dns-read-int32))
 288                   (list 'retry (dns-read-int32))
 289                   (list 'expire (dns-read-int32))
 290                   (list 'minimum (dns-read-int32))))
 291            ((eq type 'SRV)
 292             (list (list 'priority (dns-read-bytes 2))
 293                   (list 'weight (dns-read-bytes 2))
 294                   (list 'port (dns-read-bytes 2))
 295                   (list 'target (dns-read-name buffer))))
 296            ((eq type 'MX)
 297             (cons (dns-read-bytes 2) (dns-read-name buffer)))
 298            ((or (eq type 'CNAME) (eq type 'NS) (eq type 'PTR))
 299             (dns-read-string-name string buffer))
 300            (t string)))
 301       (goto-char point))))
 302
 303 (defun dns-parse-resolv-conf ()
 304   (when (file-exists-p "/etc/resolv.conf")
 305     (with-temp-buffer
 306       (insert-file-contents "/etc/resolv.conf")
 307       (goto-char (point-min))
 308       (while (re-search-forward "^nameserver[\t ]+\\([^ \t\n]+\\)" nil t)
 309         (push (match-string 1) dns-servers))
 310       (setq dns-servers (nreverse dns-servers)))))
 311
 312 (defun dns-read-txt (string)
 313   (if (> (length string) 1)
 314       (substring string 1)
 315     string))
 316
 317 (defun dns-get-txt-answer (answers)
 318   (let ((result "")
 319         (do-next nil))
 320     (dolist (answer answers)
 321       (dolist (elem answer)
 322         (when (consp elem)
 323           (cond
 324            ((eq (car elem) 'type)
 325             (setq do-next (eq (cadr elem) 'TXT)))
 326            ((eq (car elem) 'data)
 327             (when do-next
 328               (setq result (concat result (dns-read-txt (cadr elem))))))))))
 329     result))
 330
 331 ;;; Interface functions.
 332 (defmacro dns-make-network-process (server)
 333   (if (featurep 'xemacs)
 334       `(let ((coding-system-for-read 'binary)
 335              (coding-system-for-write 'binary))
 336          (open-network-stream "dns" (current-buffer)
 337                               ,server "domain" 'udp))
 338     `(let ((server ,server)
 339            (coding-system-for-read 'binary)
 340            (coding-system-for-write 'binary))
 341        (if (fboundp 'make-network-process)
 342            (make-network-process
 343             :name "dns"
 344             :coding 'binary
 345             :buffer (current-buffer)
 346             :host server
 347             :service "domain"
 348             :type 'datagram)
 349          ;; Older versions of Emacs doesn't have
 350          ;; `make-network-process', so we fall back on opening a TCP
 351          ;; connection to the DNS server.
 352          (open-network-stream "dns" (current-buffer) server "domain")))))
 353
 354 (defvar dns-cache (make-vector 4096 0))
 355
 356 (defun query-dns-cached (name &optional type fullp reversep)
 357   (let* ((key (format "%s:%s:%s:%s" name type fullp reversep))
 358          (sym (intern-soft key dns-cache)))
 359     (if (and sym
 360              (boundp sym))
 361         (symbol-value sym)
 362       (let ((result (query-dns name type fullp reversep)))
 363         (set (intern key dns-cache) result)
 364         result))))
 365
 366 (defun query-dns (name &optional type fullp reversep)
 367   "Query a DNS server for NAME of TYPE.
 368 If FULLP, return the entire record returned.
 369 If REVERSEP, look up an IP address."
 370   (setq type (or type 'A))
 371   (unless dns-servers
 372     (dns-parse-resolv-conf))
 373
 374   (when reversep
 375     (setq name (concat
 376                 (mapconcat 'identity (nreverse (split-string name "\\.")) ".")
 377                 ".in-addr.arpa")
 378           type 'PTR))
 379
 380   (if (not dns-servers)
 381       (message "No DNS server configuration found")
 382     (with-temp-buffer
 383       (set-buffer-multibyte nil)
 384       (let ((process (condition-case ()
 385                          (dns-make-network-process (car dns-servers))
 386                        (error
 387                         (message
 388                          "dns: Got an error while trying to talk to %s"
 389                          (car dns-servers))
 390                         nil)))
 391             (tcp-p (and (not (fboundp 'make-network-process))
 392                         (not (featurep 'xemacs))))
 393             (step 100)
 394             (times (* dns-timeout 1000))
 395             (id (random 65000)))
 396         (when process
 397           (process-send-string
 398            process
 399            (dns-write `((id ,id)
 400                         (opcode query)
 401                         (queries ((,name (type ,type))))
 402                         (recursion-desired-p t))
 403                       tcp-p))
 404           (while (and (zerop (buffer-size))
 405                       (> times 0))
 406             (sit-for (/ step 1000.0))
 407             (accept-process-output process 0 step)
 408             (setq times (- times step)))
 409           (condition-case nil
 410               (delete-process process)
 411             (error nil))
 412           (when (and tcp-p
 413                      (>= (buffer-size) 2))
 414             (goto-char (point-min))
 415             (delete-region (point) (+ (point) 2)))
 416           (when (and (>= (buffer-size) 2)
 417                      ;; We had a time-out.
 418                      (> times 0))
 419             (let ((result (dns-read (buffer-string))))
 420               (if fullp
 421                   result
 422                 (let ((answer (car (dns-get 'answers result))))
 423                   (when (eq type (dns-get 'type answer))
 424                     (if (eq type 'TXT)
 425                         (dns-get-txt-answer (dns-get 'answers result))
 426                       (dns-get 'data answer))))))))))))
 427
 428 (provide 'dns)
 429
 430 ;; arch-tag: d0edd0c4-4cce-4538-ae92-06c3356ee80a
 431 ;;; dns.el ends here