cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Version: 4.19
   7 ;; Keywords: news, path
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defalias 'facep 'ignore)
  31
  32 (require 'cl)
  33
  34 (defvar srcdir (or (getenv "srcdir") "."))
  35
  36 (defun my-getenv (str)
  37   (let ((val (getenv str)))
  38     (if (equal val "no") nil val)))
  39
  40 (if (my-getenv "lispdir")
  41     (push (my-getenv "lispdir") load-path))
  42
  43 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" srcdir))
  44       load-path)
  45
  46 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" srcdir))
  47       load-path)
  48
  49 ;(push "/usr/share/emacs/site-lisp" load-path)
  50
  51 (unless (featurep 'xemacs)
  52   (define-compiler-macro last (&whole form x &optional n)
  53     (if (and (fboundp 'last)
  54              (subrp (symbol-function 'last)))
  55         form
  56       (if n
  57           `(let* ((x ,x)
  58                   (n ,n)
  59                   (m 0)
  60                   (p x))
  61              (while (consp p)
  62                (incf m)
  63                (pop p))
  64              (if (<= n 0)
  65                  p
  66                (if (< n m)
  67                    (nthcdr (- m n) x)
  68                  x)))
  69         `(let ((x ,x))
  70            (while (consp (cdr x))
  71              (pop x))
  72            x))))
  73
  74   (define-compiler-macro coerce (&whole form x type)
  75     (if (and (fboundp 'coerce)
  76              (subrp (symbol-function 'coerce)))
  77         form
  78       `(let ((x ,x)
  79              (type ,type))
  80          (cond ((eq type 'list) (if (listp x) x (append x nil)))
  81                ((eq type 'vector) (if (vectorp x) x (vconcat x)))
  82                ((eq type 'string) (if (stringp x) x (concat x)))
  83                ((eq type 'array) (if (arrayp x) x (vconcat x)))
  84                ((and (eq type 'character) (stringp x) (= (length x) 1))
  85                 (aref x 0))
  86                ((and (eq type 'character) (symbolp x)
  87                      (= (length (symbol-name x)) 1))
  88                 (aref (symbol-name x) 0))
  89                ((eq type 'float) (float x))
  90                ((typep x type) x)
  91                (t (error "Can't coerce %s to type %s" x type))))))
  92
  93   (define-compiler-macro merge (&whole form type seq1 seq2 pred &rest keys)
  94     (if (and (fboundp 'merge)
  95              (subrp (symbol-function 'merge)))
  96         form
  97       `(let ((type ,type)
  98              (seq1 ,seq1)
  99              (seq2 ,seq2)
 100              (pred ,pred))
 101          (or (listp seq1) (setq seq1 (append seq1 nil)))
 102          (or (listp seq2) (setq seq2 (append seq2 nil)))
 103          (let ((res nil))
 104            (while (and seq1 seq2)
 105              (if (funcall pred (car seq2) (car seq1))
 106                  (push (pop seq2) res)
 107                (push (pop seq1) res)))
 108            (coerce (nconc (nreverse res) seq1 seq2) type)))))
 109
 110   (define-compiler-macro subseq (&whole form seq start &optional end)
 111     (if (and (fboundp 'subseq)
 112              (subrp (symbol-function 'subseq)))
 113         form
 114       (if end
 115           `(let ((seq ,seq)
 116                  (start ,start)
 117                  (end ,end))
 118              (if (stringp seq)
 119                  (substring seq start end)
 120                (let (len)
 121                  (if (< end 0)
 122                      (setq end (+ end (setq len (length seq)))))
 123                  (if (< start 0)
 124                      (setq start (+ start (or len (setq len (length seq))))))
 125                  (cond ((listp seq)
 126                         (if (> start 0)
 127                             (setq seq (nthcdr start seq)))
 128                         (let ((res nil))
 129                           (while (>= (setq end (1- end)) start)
 130                             (push (pop seq) res))
 131                           (nreverse res)))
 132                        (t
 133                         (let ((res (make-vector (max (- end start) 0) nil))
 134                               (i 0))
 135                           (while (< start end)
 136                             (aset res i (aref seq start))
 137                             (setq i (1+ i)
 138                                   start (1+ start)))
 139                           res))))))
 140         `(let ((seq ,seq)
 141                (start ,start))
 142            (if (stringp seq)
 143                (substring seq start)
 144              (let (len)
 145                (if (< start 0)
 146                    (setq start (+ start (or len (setq len (length seq))))))
 147                (cond ((listp seq)
 148                       (if (> start 0)
 149                           (setq seq (nthcdr start seq)))
 150                       (copy-sequence seq))
 151                      (t
 152                       (let* ((end (or len (length seq)))
 153                              (res (make-vector (max (- end start) 0) nil))
 154                              (i 0))
 155                         (while (< start end)
 156                           (aset res i (aref seq start))
 157                           (setq i (1+ i)
 158                                 start (1+ start)))
 159                         res)))))))))
 160
 161   (define-compiler-macro copy-list (&whole form list)
 162     (if (and (fboundp 'copy-list)
 163              (subrp (symbol-function 'copy-list)))
 164         form
 165       `(let ((list ,list))
 166          (if (consp list)
 167              (let ((res nil))
 168                (while (consp list) (push (pop list) res))
 169                (prog1 (nreverse res) (setcdr res list)))
 170            (car list)))))
 171   )
 172
 173 ;; If we are building w3 in a different directory than the source
 174 ;; directory, we must read *.el from source directory and write *.elc
 175 ;; into the building directory.  For that, we define this function
 176 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
 177 (defun byte-compile-dest-file (filename)
 178   "Convert an Emacs Lisp source file name to a compiled file name.
 179  In addition, remove directory name part from FILENAME."
 180   (setq filename (byte-compiler-base-file-name filename))
 181   (setq filename (file-name-sans-versions filename))
 182   (setq filename (file-name-nondirectory filename))
 183   (if (memq system-type '(win32 w32 mswindows windows-nt))
 184       (setq filename (downcase filename)))
 185   (cond ((eq system-type 'vax-vms)
 186          (concat (substring filename 0 (string-match ";" filename)) "c"))
 187         ((string-match emacs-lisp-file-regexp filename)
 188          (concat (substring filename 0 (match-beginning 0)) ".elc"))
 189         (t (concat filename ".elc"))))
 190
 191 (require 'bytecomp)
 192 (require 'byte-opt)
 193 ;; To avoid having defsubsts and inlines happen.
 194 ;(defun byte-optimize-inline-handler (form)
 195 ;  "byte-optimize-handler for the `inline' special-form."
 196 ;  (cons 'progn (cdr form)))
 197 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
 198
 199 (push srcdir load-path)
 200 (load (expand-file-name "lpath.el" srcdir) nil t)
 201
 202 (defalias 'device-sound-enabled-p 'ignore)
 203 (defalias 'play-sound-file 'ignore)
 204 (defalias 'nndb-request-article 'ignore)
 205 (defalias 'efs-re-read-dir 'ignore)
 206 (defalias 'ange-ftp-re-read-dir 'ignore)
 207 (defalias 'define-mail-user-agent 'ignore)
 208
 209 (eval-and-compile
 210   (unless (featurep 'xemacs)
 211     (defalias 'get-popup-menu-response 'ignore)
 212     (defalias 'event-object 'ignore)
 213     (defalias 'x-defined-colors 'ignore)
 214     (defalias 'read-color 'ignore)))
 215
 216 (defun dgnushack-compile (&optional warn)
 217   ;;(setq byte-compile-dynamic t)
 218   (unless warn
 219     (setq byte-compile-warnings
 220           '(free-vars unresolved callargs redefine)))
 221   (unless (locate-library "cus-edit")
 222     (error "You do not seem to have Custom installed.
 223 Fetch it from <URL:http://www.dina.kvl.dk/~abraham/custom/>.
 224 You also then need to add the following to the lisp/dgnushack.el file:
 225
 226      (push \"~/lisp/custom\" load-path)
 227
 228 Modify to suit your needs."))
 229   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 230         ;;(byte-compile-generate-call-tree t)
 231         file elc)
 232     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 233     ;; installed.
 234     (when (featurep 'xemacs)
 235       (setq gnus-xmas-glyph-directory "dummy"))
 236     (dolist (file '("dgnushack.el" "lpath.el"))
 237       (setq files (delete file files)))
 238     (when (featurep 'base64)
 239       (setq files (delete "base64.el" files)))
 240     (condition-case code
 241         (require 'w3-parse)
 242       (error
 243        (message "No w3: %s %s" code (locate-library "w3-parse"))
 244        (dolist (file '("nnultimate.el" "webmail.el" "nnwfm.el"))
 245          (setq files (delete file files)))))
 246     (condition-case code
 247         (require 'mh-e)
 248       (error
 249        (message "No mh-e: %s %s" code (locate-library "mh-e"))
 250        (setq files (delete "gnus-mh.el" files))))
 251     (condition-case code
 252         (require 'xml)
 253       (error
 254        (message "No xml: %s %s" code (locate-library "xml"))
 255        (setq files (delete "nnrss.el" files))))
 256     (dolist (file
 257              (if (featurep 'xemacs)
 258                 '("md5.el")
 259                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el" "smiley.el")))
 260       (setq files (delete file files)))
 261
 262     (dolist (file files)
 263       (setq file (expand-file-name file srcdir))
 264       (when (and (file-exists-p
 265                   (setq elc (concat (file-name-nondirectory file) "c")))
 266                  (file-newer-than-file-p file elc))
 267         (delete-file elc)))
 268
 269     (while (setq file (pop files))
 270       (setq file (expand-file-name file srcdir))
 271       (when (or (not (file-exists-p
 272                       (setq elc (concat (file-name-nondirectory file) "c"))))
 273                 (file-newer-than-file-p file elc))
 274         (ignore-errors
 275           (byte-compile-file file))))))
 276
 277 (defun dgnushack-recompile ()
 278   (require 'gnus)
 279   (byte-recompile-directory "." 0))
 280
 281 (defvar dgnushack-gnus-load-file (expand-file-name "gnus-load.el"))
 282 (defvar dgnushack-cus-load-file (expand-file-name "cus-load.el"))
 283
 284 (defun dgnushack-make-cus-load ()
 285   (load "cus-dep")
 286   (let ((cusload-base-file dgnushack-cus-load-file))
 287     (if (fboundp 'custom-make-dependencies)
 288         (custom-make-dependencies)
 289       (Custom-make-dependencies))))
 290
 291 (defun dgnushack-make-auto-load ()
 292   (require 'autoload)
 293   (unless (make-autoload '(define-derived-mode child parent name
 294                             "docstring" body)
 295                          "file")
 296     (defadvice make-autoload (around handle-define-derived-mode activate)
 297       "Handle `define-derived-mode'."
 298       (if (eq (car-safe (ad-get-arg 0)) 'define-derived-mode)
 299           (setq ad-return-value
 300                 (list 'autoload
 301                       (list 'quote (nth 1 (ad-get-arg 0)))
 302                       (ad-get-arg 1)
 303                       (nth 4 (ad-get-arg 0))
 304                       t nil))
 305         ad-do-it))
 306     (put 'define-derived-mode 'doc-string-elt 3))
 307   (let ((generated-autoload-file dgnushack-gnus-load-file)
 308         (make-backup-files nil)
 309         (autoload-package-name "gnus"))
 310     (if (featurep 'xemacs)
 311         (if (file-exists-p generated-autoload-file)
 312             (delete-file generated-autoload-file))
 313       (with-temp-file generated-autoload-file
 314         (insert ?\014)))
 315     (batch-update-autoloads)))
 316
 317 (defun dgnushack-make-load ()
 318   (message (format "Generating %s..." dgnushack-gnus-load-file))
 319   (with-temp-file dgnushack-gnus-load-file
 320     (insert-file-contents dgnushack-cus-load-file)
 321     (delete-file dgnushack-cus-load-file)
 322     (goto-char (point-min))
 323     (search-forward ";;; Code:")
 324     (forward-line)
 325     (delete-region (point-min) (point))
 326     (insert "\
 327 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 328 ;;
 329 ;;; Code:
 330 ")
 331     (goto-char (point-max))
 332     (if (search-backward "custom-versions-load-alist" nil t)
 333         (forward-line -1)
 334       (forward-line -1)
 335       (while (eq (char-after) ?\;)
 336         (forward-line -1))
 337       (forward-line))
 338     (delete-region (point) (point-max))
 339     (insert "\n")
 340     ;; smiley-* are duplicated. Remove them all.
 341     (let ((point (point)))
 342       (insert-file-contents dgnushack-gnus-load-file)
 343       (goto-char point)
 344       (while (search-forward "smiley-" nil t)
 345         (beginning-of-line)
 346         (if (looking-at "(autoload ")
 347             (delete-region (point) (progn (forward-sexp) (point)))
 348           (forward-line))))
 349     ;;
 350     (goto-char (point-max))
 351     (when (search-backward "\n(provide " nil t)
 352       (forward-line -1)
 353       (delete-region (point) (point-max)))
 354     (insert "\
 355
 356 \(provide 'gnus-load)
 357
 358 ;;; Local Variables:
 359 ;;; version-control: never
 360 ;;; no-byte-compile: t
 361 ;;; no-update-autoloads: t
 362 ;;; End:
 363 ;;; gnus-load.el ends here
 364 ")
 365     ;; Workaround the bug in some version of XEmacs.
 366     (when (featurep 'xemacs)
 367       (condition-case nil
 368           (require 'cus-load)
 369         (error nil))
 370       (goto-char (point-min))
 371       (when (and (fboundp 'custom-add-loads)
 372                  (not (search-forward "\n(autoload 'custom-add-loads " nil t)))
 373         (search-forward "\n;;; Code:" nil t)
 374         (forward-line 1)
 375         (insert "\n(autoload 'custom-add-loads \"cus-load\")\n"))))
 376   (message (format "Compiling %s..." dgnushack-gnus-load-file))
 377   (byte-compile-file dgnushack-gnus-load-file))
 378
 379 ;;; dgnushack.el ends here