cgit.sxemacs.org Git - gnus/blob - lisp/auth-source.el

   1 ;;; auth-source.el --- authentication sources for Gnus and Emacs
   2
   3 ;; Copyright (C) 2008-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is the auth-source.el package.  It lets users tell Gnus how to
  26 ;; authenticate in a single place.  Simplicity is the goal.  Instead
  27 ;; of providing 5000 options, we'll stick to simple, easy to
  28 ;; understand options.
  29
  30 ;; See the auth.info Info documentation for details.
  31
  32 ;; TODO:
  33
  34 ;; - never decode the backend file unless it's necessary
  35 ;; - a more generic way to match backends and search backend contents
  36 ;; - absorb netrc.el and simplify it
  37 ;; - protect passwords better
  38 ;; - allow creating and changing netrc lines (not files) e.g. change a password
  39
  40 ;;; Code:
  41
  42 (require 'password-cache)
  43 (require 'mm-util)
  44 (require 'gnus-util)
  45 (require 'netrc)
  46 (require 'assoc)
  47 (eval-when-compile (require 'cl))
  48 (eval-and-compile
  49   (or (ignore-errors (require 'eieio))
  50       ;; gnus-fallback-lib/ from gnus/lisp/gnus-fallback-lib
  51       (ignore-errors
  52         (let ((load-path (cons (expand-file-name
  53                                 "gnus-fallback-lib/eieio"
  54                                 (file-name-directory (locate-library "gnus")))
  55                                load-path)))
  56           (require 'eieio)))
  57       (error
  58        "eieio not found in `load-path' or gnus-fallback-lib/ directory.")))
  59
  60 (autoload 'secrets-create-item "secrets")
  61 (autoload 'secrets-delete-item "secrets")
  62 (autoload 'secrets-get-alias "secrets")
  63 (autoload 'secrets-get-attributes "secrets")
  64 (autoload 'secrets-get-secret "secrets")
  65 (autoload 'secrets-list-collections "secrets")
  66 (autoload 'secrets-search-items "secrets")
  67
  68 (defvar secrets-enabled)
  69
  70 (defgroup auth-source nil
  71   "Authentication sources."
  72   :version "23.1" ;; No Gnus
  73   :group 'gnus)
  74
  75 ;;;###autoload
  76 (defcustom auth-source-cache-expiry 7200
  77   "How many seconds passwords are cached, or nil to disable
  78 expiring.  Overrides `password-cache-expiry' through a
  79 let-binding."
  80   :group 'auth-source
  81   :type '(choice (const :tag "Never" nil)
  82                  (const :tag "All Day" 86400)
  83                  (const :tag "2 Hours" 7200)
  84                  (const :tag "30 Minutes" 1800)
  85                  (integer :tag "Seconds")))
  86
  87 (defclass auth-source-backend ()
  88   ((type :initarg :type
  89          :initform 'netrc
  90          :type symbol
  91          :custom symbol
  92          :documentation "The backend type.")
  93    (source :initarg :source
  94            :type string
  95            :custom string
  96            :documentation "The backend source.")
  97    (host :initarg :host
  98          :initform t
  99          :type t
 100          :custom string
 101          :documentation "The backend host.")
 102    (user :initarg :user
 103          :initform t
 104          :type t
 105          :custom string
 106          :documentation "The backend user.")
 107    (port :initarg :port
 108          :initform t
 109          :type t
 110          :custom string
 111          :documentation "The backend protocol.")
 112    (create-function :initarg :create-function
 113                     :initform ignore
 114                     :type function
 115                     :custom function
 116                     :documentation "The create function.")
 117    (search-function :initarg :search-function
 118                     :initform ignore
 119                     :type function
 120                     :custom function
 121                     :documentation "The search function.")))
 122
 123 (defcustom auth-source-protocols '((imap "imap" "imaps" "143" "993")
 124                                    (pop3 "pop3" "pop" "pop3s" "110" "995")
 125                                    (ssh  "ssh" "22")
 126                                    (sftp "sftp" "115")
 127                                    (smtp "smtp" "25"))
 128   "List of authentication protocols and their names"
 129
 130   :group 'auth-source
 131   :version "23.2" ;; No Gnus
 132   :type '(repeat :tag "Authentication Protocols"
 133                  (cons :tag "Protocol Entry"
 134                        (symbol :tag "Protocol")
 135                        (repeat :tag "Names"
 136                                (string :tag "Name")))))
 137
 138 ;;; generate all the protocols in a format Customize can use
 139 ;;; TODO: generate on the fly from auth-source-protocols
 140 (defconst auth-source-protocols-customize
 141   (mapcar (lambda (a)
 142             (let ((p (car-safe a)))
 143               (list 'const
 144                     :tag (upcase (symbol-name p))
 145                     p)))
 146           auth-source-protocols))
 147
 148 (defvar auth-source-creation-defaults nil
 149   "Defaults for creating token values.  Usually let-bound.")
 150
 151 (make-obsolete 'auth-source-hide-passwords nil "Emacs 24.1")
 152
 153 (defvar auth-source-magic "auth-source-magic ")
 154
 155 (defcustom auth-source-do-cache t
 156   "Whether auth-source should cache information with `password-cache'."
 157   :group 'auth-source
 158   :version "23.2" ;; No Gnus
 159   :type `boolean)
 160
 161 (defcustom auth-source-debug nil
 162   "Whether auth-source should log debug messages.
 163
 164 If the value is nil, debug messages are not logged.
 165
 166 If the value is t, debug messages are logged with `message'.  In
 167 that case, your authentication data will be in the clear (except
 168 for passwords).
 169
 170 If the value is a function, debug messages are logged by calling
 171  that function using the same arguments as `message'."
 172   :group 'auth-source
 173   :version "23.2" ;; No Gnus
 174   :type `(choice
 175           :tag "auth-source debugging mode"
 176           (const :tag "Log using `message' to the *Messages* buffer" t)
 177           (function :tag "Function that takes arguments like `message'")
 178           (const :tag "Don't log anything" nil)))
 179
 180 (defcustom auth-sources '("~/.authinfo.gpg" "~/.authinfo")
 181   "List of authentication sources.
 182
 183 The default will get login and password information from
 184 \"~/.authinfo.gpg\", which you should set up with the EPA/EPG
 185 packages to be encrypted.  If that file doesn't exist, it will
 186 try the unencrypted version \"~/.authinfo\".
 187
 188 See the auth.info manual for details.
 189
 190 Each entry is the authentication type with optional properties.
 191
 192 It's best to customize this with `M-x customize-variable' because the choices
 193 can get pretty complex."
 194   :group 'auth-source
 195   :version "24.1" ;; No Gnus
 196   :type `(repeat :tag "Authentication Sources"
 197                  (choice
 198                   (string :tag "Just a file")
 199                   (const :tag "Default Secrets API Collection" 'default)
 200                   (const :tag "Login Secrets API Collection" "secrets:Login")
 201                   (const :tag "Temp Secrets API Collection" "secrets:session")
 202                   (list :tag "Source definition"
 203                         (const :format "" :value :source)
 204                         (choice :tag "Authentication backend choice"
 205                                 (string :tag "Authentication Source (file)")
 206                                 (list
 207                                  :tag "Secret Service API/KWallet/GNOME Keyring"
 208                                  (const :format "" :value :secrets)
 209                                  (choice :tag "Collection to use"
 210                                          (string :tag "Collection name")
 211                                          (const :tag "Default" 'default)
 212                                          (const :tag "Login" "Login")
 213                                          (const
 214                                           :tag "Temporary" "session"))))
 215                         (repeat :tag "Extra Parameters" :inline t
 216                                 (choice :tag "Extra parameter"
 217                                         (list
 218                                          :tag "Host"
 219                                          (const :format "" :value :host)
 220                                          (choice :tag "Host (machine) choice"
 221                                                  (const :tag "Any" t)
 222                                                  (regexp
 223                                                   :tag "Regular expression")))
 224                                         (list
 225                                          :tag "Protocol"
 226                                          (const :format "" :value :port)
 227                                          (choice
 228                                           :tag "Protocol"
 229                                           (const :tag "Any" t)
 230                                           ,@auth-source-protocols-customize))
 231                                         (list :tag "User" :inline t
 232                                               (const :format "" :value :user)
 233                                               (choice :tag "Personality/Username"
 234                                                       (const :tag "Any" t)
 235                                                       (string :tag "Name")))))))))
 236
 237 (defcustom auth-source-gpg-encrypt-to t
 238   "List of recipient keys that `authinfo.gpg' encrypted to.
 239 If the value is not a list, symmetric encryption will be used."
 240   :group 'auth-source
 241   :version "24.1" ;; No Gnus
 242   :type '(choice (const :tag "Symmetric encryption" t)
 243                  (repeat :tag "Recipient public keys"
 244                          (string :tag "Recipient public key"))))
 245
 246 ;; temp for debugging
 247 ;; (unintern 'auth-source-protocols)
 248 ;; (unintern 'auth-sources)
 249 ;; (customize-variable 'auth-sources)
 250 ;; (setq auth-sources nil)
 251 ;; (format "%S" auth-sources)
 252 ;; (customize-variable 'auth-source-protocols)
 253 ;; (setq auth-source-protocols nil)
 254 ;; (format "%S" auth-source-protocols)
 255 ;; (auth-source-pick nil :host "a" :port 'imap)
 256 ;; (auth-source-user-or-password "login" "imap.myhost.com" 'imap)
 257 ;; (auth-source-user-or-password "password" "imap.myhost.com" 'imap)
 258 ;; (auth-source-user-or-password-imap "login" "imap.myhost.com")
 259 ;; (auth-source-user-or-password-imap "password" "imap.myhost.com")
 260 ;; (auth-source-protocol-defaults 'imap)
 261
 262 ;; (let ((auth-source-debug 'debug)) (auth-source-do-debug "hello"))
 263 ;; (let ((auth-source-debug t)) (auth-source-do-debug "hello"))
 264 ;; (let ((auth-source-debug nil)) (auth-source-do-debug "hello"))
 265 (defun auth-source-do-debug (&rest msg)
 266   (when auth-source-debug
 267     (apply 'auth-source-do-warn msg)))
 268
 269 (defun auth-source-do-warn (&rest msg)
 270   (apply
 271     ;; set logger to either the function in auth-source-debug or 'message
 272     ;; note that it will be 'message if auth-source-debug is nil
 273    (if (functionp auth-source-debug)
 274        auth-source-debug
 275      'message)
 276    msg))
 277
 278
 279 ;; (auth-source-pick nil :host "any" :port 'imap :user "joe")
 280 ;; (auth-source-pick t :host "any" :port 'imap :user "joe")
 281 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 282 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 283 ;;                   (:source (:secrets "Login") :host t :port t)
 284 ;;                   (:source "~/.authinfo.gpg" :host t :port t)))
 285
 286 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 287 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 288 ;;                   (:source (:secrets "Login") :host t :port t)
 289 ;;                   ))
 290
 291 ;; (setq auth-sources '((:source "~/.authinfo.gpg" :host t :port t)))
 292
 293 ;; (auth-source-backend-parse "myfile.gpg")
 294 ;; (auth-source-backend-parse 'default)
 295 ;; (auth-source-backend-parse "secrets:Login")
 296
 297 (defun auth-source-backend-parse (entry)
 298   "Creates an auth-source-backend from an ENTRY in `auth-sources'."
 299   (auth-source-backend-parse-parameters
 300    entry
 301    (cond
 302     ;; take 'default and recurse to get it as a Secrets API default collection
 303     ;; matching any user, host, and protocol
 304     ((eq entry 'default)
 305      (auth-source-backend-parse '(:source (:secrets default))))
 306     ;; take secrets:XYZ and recurse to get it as Secrets API collection "XYZ"
 307     ;; matching any user, host, and protocol
 308     ((and (stringp entry) (string-match "^secrets:\\(.+\\)" entry))
 309      (auth-source-backend-parse `(:source (:secrets ,(match-string 1 entry)))))
 310     ;; take just a file name and recurse to get it as a netrc file
 311     ;; matching any user, host, and protocol
 312     ((stringp entry)
 313      (auth-source-backend-parse `(:source ,entry)))
 314
 315     ;; a file name with parameters
 316     ((stringp (plist-get entry :source))
 317      (auth-source-backend
 318       (plist-get entry :source)
 319       :source (plist-get entry :source)
 320       :type 'netrc
 321       :search-function 'auth-source-netrc-search
 322       :create-function 'auth-source-netrc-create))
 323
 324     ;; the Secrets API.  We require the package, in order to have a
 325     ;; defined value for `secrets-enabled'.
 326     ((and
 327       (not (null (plist-get entry :source))) ; the source must not be nil
 328       (listp (plist-get entry :source))      ; and it must be a list
 329       (require 'secrets nil t)               ; and we must load the Secrets API
 330       secrets-enabled)                       ; and that API must be enabled
 331
 332      ;; the source is either the :secrets key in ENTRY or
 333      ;; if that's missing or nil, it's "session"
 334      (let ((source (or (plist-get (plist-get entry :source) :secrets)
 335                        "session")))
 336
 337        ;; if the source is a symbol, we look for the alias named so,
 338        ;; and if that alias is missing, we use "Login"
 339        (when (symbolp source)
 340          (setq source (or (secrets-get-alias (symbol-name source))
 341                           "Login")))
 342
 343        (if (featurep 'secrets)
 344            (auth-source-backend
 345             (format "Secrets API (%s)" source)
 346             :source source
 347             :type 'secrets
 348             :search-function 'auth-source-secrets-search
 349             :create-function 'auth-source-secrets-create)
 350          (auth-source-do-warn
 351           "auth-source-backend-parse: no Secrets API, ignoring spec: %S" entry)
 352          (auth-source-backend
 353           (format "Ignored Secrets API (%s)" source)
 354           :source ""
 355           :type 'ignore))))
 356
 357     ;; none of them
 358     (t
 359      (auth-source-do-warn
 360       "auth-source-backend-parse: invalid backend spec: %S" entry)
 361      (auth-source-backend
 362       "Empty"
 363       :source ""
 364       :type 'ignore)))))
 365
 366 (defun auth-source-backend-parse-parameters (entry backend)
 367   "Fills in the extra auth-source-backend parameters of ENTRY.
 368 Using the plist ENTRY, get the :host, :port, and :user search
 369 parameters."
 370   (let ((entry (if (stringp entry)
 371                    nil
 372                  entry))
 373         val)
 374     (when (setq val (plist-get entry :host))
 375       (oset backend host val))
 376     (when (setq val (plist-get entry :user))
 377       (oset backend user val))
 378     (when (setq val (plist-get entry :port))
 379       (oset backend port val)))
 380   backend)
 381
 382 ;; (mapcar 'auth-source-backend-parse auth-sources)
 383
 384 (defun* auth-source-search (&rest spec
 385                                   &key type max host user port secret
 386                                   create delete
 387                                   &allow-other-keys)
 388   "Search or modify authentication backends according to SPEC.
 389
 390 This function parses `auth-sources' for matches of the SPEC
 391 plist.  It can optionally create or update an authentication
 392 token if requested.  A token is just a standard Emacs property
 393 list with a :secret property that can be a function; all the
 394 other properties will always hold scalar values.
 395
 396 Typically the :secret property, if present, contains a password.
 397
 398 Common search keys are :max, :host, :port, and :user.  In
 399 addition, :create specifies how tokens will be or created.
 400 Finally, :type can specify which backend types you want to check.
 401
 402 A string value is always matched literally.  A symbol is matched
 403 as its string value, literally.  All the SPEC values can be
 404 single values (symbol or string) or lists thereof (in which case
 405 any of the search terms matches).
 406
 407 :create t means to create a token if possible.
 408
 409 A new token will be created if no matching tokens were found.
 410 The new token will have only the keys the backend requires.  For
 411 the netrc backend, for instance, that's the user, host, and
 412 port keys.
 413
 414 Here's an example:
 415
 416 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 417                                         (A    . \"default A\"))))
 418   (auth-source-search :host \"mine\" :type 'netrc :max 1
 419                       :P \"pppp\" :Q \"qqqq\"
 420                       :create t))
 421
 422 which says:
 423
 424 \"Search for any entry matching host 'mine' in backends of type
 425  'netrc', maximum one result.
 426
 427  Create a new entry if you found none.  The netrc backend will
 428  automatically require host, user, and port.  The host will be
 429  'mine'.  We prompt for the user with default 'defaultUser' and
 430  for the port without a default.  We will not prompt for A, Q,
 431  or P.  The resulting token will only have keys user, host, and
 432  port.\"
 433
 434 :create '(A B C) also means to create a token if possible.
 435
 436 The behavior is like :create t but if the list contains any
 437 parameter, that parameter will be required in the resulting
 438 token.  The value for that parameter will be obtained from the
 439 search parameters or from user input.  If any queries are needed,
 440 the alist `auth-source-creation-defaults' will be checked for the
 441 default prompt.
 442
 443 Here's an example:
 444
 445 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 446                                         (A    . \"default A\"))))
 447   (auth-source-search :host '(\"nonesuch\" \"twosuch\") :type 'netrc :max 1
 448                       :P \"pppp\" :Q \"qqqq\"
 449                       :create '(A B Q)))
 450
 451 which says:
 452
 453 \"Search for any entry matching host 'nonesuch'
 454  or 'twosuch' in backends of type 'netrc', maximum one result.
 455
 456  Create a new entry if you found none.  The netrc backend will
 457  automatically require host, user, and port.  The host will be
 458  'nonesuch' and Q will be 'qqqq'.  We prompt for A with default
 459  'default A', for B and port with default nil, and for the
 460  user with default 'defaultUser'.  We will not prompt for Q.  The
 461  resulting token will have keys user, host, port, A, B, and Q.
 462  It will not have P with any value, even though P is used in the
 463  search to find only entries that have P set to 'pppp'.\"
 464
 465 When multiple values are specified in the search parameter, the
 466 user is prompted for which one.  So :host (X Y Z) would ask the
 467 user to choose between X, Y, and Z.
 468
 469 This creation can fail if the search was not specific enough to
 470 create a new token (it's up to the backend to decide that).  You
 471 should `catch' the backend-specific error as usual.  Some
 472 backends (netrc, at least) will prompt the user rather than throw
 473 an error.
 474
 475 :delete t means to delete any found entries.  nil by default.
 476 Use `auth-source-delete' in ELisp code instead of calling
 477 `auth-source-search' directly with this parameter.
 478
 479 :type (X Y Z) will check only those backend types.  'netrc and
 480 'secrets are the only ones supported right now.
 481
 482 :max N means to try to return at most N items (defaults to 1).
 483 When 0 the function will return just t or nil to indicate if any
 484 matches were found.  More than N items may be returned, depending
 485 on the search and the backend.
 486
 487 :host (X Y Z) means to match only hosts X, Y, or Z according to
 488 the match rules above.  Defaults to t.
 489
 490 :user (X Y Z) means to match only users X, Y, or Z according to
 491 the match rules above.  Defaults to t.
 492
 493 :port (P Q R) means to match only protocols P, Q, or R.
 494 Defaults to t.
 495
 496 :K (V1 V2 V3) for any other key K will match values V1, V2, or
 497 V3 (note the match rules above).
 498
 499 The return value is a list with at most :max tokens.  Each token
 500 is a plist with keys :backend :host :port :user, plus any other
 501 keys provided by the backend (notably :secret).  But note the
 502 exception for :max 0, which see above.
 503
 504 The token's :secret key can hold a function.  In that case you
 505 must call it to obtain the actual value."
 506   (let* ((backends (mapcar 'auth-source-backend-parse auth-sources))
 507          (max (or max 1))
 508          (ignored-keys '(:create :delete :max))
 509          (keys (loop for i below (length spec) by 2
 510                      unless (memq (nth i spec) ignored-keys)
 511                      collect (nth i spec)))
 512          (found (auth-source-recall spec))
 513          filtered-backends accessor-key found-here goal matches)
 514
 515     (if (and found auth-source-do-cache)
 516         (auth-source-do-debug
 517          "auth-source-search: found %d CACHED results matching %S"
 518          (length found) spec)
 519
 520       (assert
 521        (or (eq t create) (listp create)) t
 522        "Invalid auth-source :create parameter (must be nil, t, or a list): %s %s")
 523
 524       (setq filtered-backends (copy-sequence backends))
 525       (dolist (backend backends)
 526         (dolist (key keys)
 527           ;; ignore invalid slots
 528           (condition-case signal
 529               (unless (eval `(auth-source-search-collection
 530                               (plist-get spec key)
 531                               (oref backend ,key)))
 532                 (setq filtered-backends (delq backend filtered-backends))
 533                 (return))
 534             (invalid-slot-name))))
 535
 536       (auth-source-do-debug
 537        "auth-source-search: found %d backends matching %S"
 538        (length filtered-backends) spec)
 539
 540       ;; (debug spec "filtered" filtered-backends)
 541       (setq goal max)
 542       ;; First go through all the backends without :create, so we can
 543       ;; query them all.
 544       (let ((uspec (copy-sequence spec)))
 545         (plist-put uspec :create nil)
 546         (dolist (backend filtered-backends)
 547           (let ((match (apply
 548                         (slot-value backend 'search-function)
 549                         :backend backend
 550                         uspec)))
 551             (when match
 552               (push (list backend match) matches)))))
 553       ;; If we didn't find anything, then we allow the backend(s) to
 554       ;; create the entries.
 555       (when (and create
 556                  (not matches))
 557         (let ((match (apply
 558                       (slot-value backend 'search-function)
 559                       :backend backend
 560                       :create create
 561                       :delete delete
 562                       spec)))
 563           (when match
 564             (push (list backend match) matches))))
 565
 566       (setq backend (caar matches)
 567             found-here (cadar matches))
 568
 569       (block nil
 570         ;; if max is 0, as soon as we find something, return it
 571         (when (and (zerop max) (> 0 (length found-here)))
 572           (return t))
 573
 574         ;; decrement the goal by the number of new results
 575         (decf goal (length found-here))
 576         ;; and append the new results to the full list
 577         (setq found (append found found-here))
 578
 579         (auth-source-do-debug
 580          "auth-source-search: found %d results (max %d/%d) in %S matching %S"
 581          (length found-here) max goal backend spec)
 582
 583         ;; return full list if the goal is 0 or negative
 584         (when (zerop (max 0 goal))
 585           (return found))
 586
 587         ;; change the :max parameter in the spec to the goal
 588         (setq spec (plist-put spec :max goal))
 589
 590         (when (and found auth-source-do-cache)
 591           (auth-source-remember spec found))))
 592
 593     found))
 594
 595 ;;; (auth-source-search :max 1)
 596 ;;; (funcall (plist-get (nth 0 (auth-source-search :max 1)) :secret))
 597 ;;; (auth-source-search :host "nonesuch" :type 'netrc :K 1)
 598 ;;; (auth-source-search :host "nonesuch" :type 'secrets)
 599
 600 (defun* auth-source-delete (&rest spec
 601                                   &key delete
 602                                   &allow-other-keys)
 603   "Delete entries from the authentication backends according to SPEC.
 604 Calls `auth-source-search' with the :delete property in SPEC set to t.
 605 The backend may not actually delete the entries.
 606
 607 Returns the deleted entries."
 608   (auth-source-search (plist-put spec :delete t)))
 609
 610 (defun auth-source-search-collection (collection value)
 611   "Returns t is VALUE is t or COLLECTION is t or contains VALUE."
 612   (when (and (atom collection) (not (eq t collection)))
 613     (setq collection (list collection)))
 614
 615   ;; (debug :collection collection :value value)
 616   (or (eq collection t)
 617       (eq value t)
 618       (equal collection value)
 619       (member value collection)))
 620
 621 (defun auth-source-forget-all-cached ()
 622   "Forget all cached auth-source data."
 623   (interactive)
 624   (loop for sym being the symbols of password-data
 625         ;; when the symbol name starts with auth-source-magic
 626         when (string-match (concat "^" auth-source-magic)
 627                            (symbol-name sym))
 628         ;; remove that key
 629         do (password-cache-remove (symbol-name sym))))
 630
 631 (defun auth-source-remember (spec found)
 632   "Remember FOUND search results for SPEC."
 633   (let ((password-cache-expiry auth-source-cache-expiry))
 634     (password-cache-add
 635      (concat auth-source-magic (format "%S" spec)) found)))
 636
 637 (defun auth-source-recall (spec)
 638   "Recall FOUND search results for SPEC."
 639   (password-read-from-cache
 640    (concat auth-source-magic (format "%S" spec))))
 641
 642 (defun auth-source-forget (spec)
 643   "Forget any cached data matching SPEC exactly.
 644
 645 This is the same SPEC you passed to `auth-source-search'.
 646 Returns t or nil for forgotten or not found."
 647   (password-cache-remove (concat auth-source-magic (format "%S" spec))))
 648
 649 ;;; (loop for sym being the symbols of password-data when (string-match (concat "^" auth-source-magic) (symbol-name sym)) collect (symbol-name sym))
 650
 651 ;;; (auth-source-remember '(:host "wedd") '(4 5 6))
 652 ;;; (auth-source-remember '(:host "xedd") '(1 2 3))
 653 ;;; (auth-source-recall '(:host "xedd"))
 654 ;;; (auth-source-recall '(:host t))
 655 ;;; (auth-source-forget+ :host t)
 656
 657 (defun* auth-source-forget+ (&rest spec &allow-other-keys)
 658   "Forget any cached data matching SPEC.  Returns forgotten count.
 659
 660 This is not a full `auth-source-search' spec but works similarly.
 661 For instance, \(:host \"myhost\" \"yourhost\") would find all the
 662 cached data that was found with a search for those two hosts,
 663 while \(:host t) would find all host entries."
 664   (let ((count 0)
 665         sname)
 666     (loop for sym being the symbols of password-data
 667           ;; when the symbol name matches with auth-source-magic
 668           when (and (setq sname (symbol-name sym))
 669                     (string-match (concat "^" auth-source-magic "\\(.+\\)")
 670                                   sname)
 671                     ;; and the spec matches what was stored in the cache
 672                     (auth-source-specmatchp spec (read (match-string 1 sname))))
 673           ;; remove that key
 674           do (progn
 675                (password-cache-remove sname)
 676                (incf count)))
 677     count))
 678
 679 (defun auth-source-specmatchp (spec stored)
 680   (let ((keys (loop for i below (length spec) by 2
 681                    collect (nth i spec))))
 682     (not (eq
 683           (dolist (key keys)
 684             (unless (auth-source-search-collection (plist-get stored key)
 685                                                    (plist-get spec key))
 686               (return 'no)))
 687           'no))))
 688
 689 ;;; Backend specific parsing: netrc/authinfo backend
 690
 691 ;;; (auth-source-netrc-parse "~/.authinfo.gpg")
 692 (defun* auth-source-netrc-parse (&rest
 693                                  spec
 694                                  &key file max host user port delete
 695                                  &allow-other-keys)
 696   "Parse FILE and return a list of all entries in the file.
 697 Note that the MAX parameter is used so we can exit the parse early."
 698   (if (listp file)
 699       ;; We got already parsed contents; just return it.
 700       file
 701     (when (file-exists-p file)
 702       (with-temp-buffer
 703         (let ((tokens '("machine" "host" "default" "login" "user"
 704                         "password" "account" "macdef" "force"
 705                         "port" "protocol"))
 706               (max (or max 5000))       ; sanity check: default to stop at 5K
 707               (modified 0)
 708               alist elem result pair)
 709           (insert-file-contents file)
 710           (goto-char (point-min))
 711           ;; Go through the file, line by line.
 712           (while (and (not (eobp))
 713                       (> max 0))
 714
 715             (narrow-to-region (point) (point-at-eol))
 716             ;; For each line, get the tokens and values.
 717             (while (not (eobp))
 718               (skip-chars-forward "\t ")
 719               ;; Skip lines that begin with a "#".
 720               (if (eq (char-after) ?#)
 721                   (goto-char (point-max))
 722                 (unless (eobp)
 723                   (setq elem
 724                         (if (= (following-char) ?\")
 725                             (read (current-buffer))
 726                           (buffer-substring
 727                            (point) (progn (skip-chars-forward "^\t ")
 728                                           (point)))))
 729                   (cond
 730                    ((equal elem "macdef")
 731                     ;; We skip past the macro definition.
 732                     (widen)
 733                     (while (and (zerop (forward-line 1))
 734                                 (looking-at "$")))
 735                     (narrow-to-region (point) (point)))
 736                    ((member elem tokens)
 737                     ;; Tokens that don't have a following value are ignored,
 738                     ;; except "default".
 739                     (when (and pair (or (cdr pair)
 740                                         (equal (car pair) "default")))
 741                       (push pair alist))
 742                     (setq pair (list elem)))
 743                    (t
 744                     ;; Values that haven't got a preceding token are ignored.
 745                     (when pair
 746                       (setcdr pair elem)
 747                       (push pair alist)
 748                       (setq pair nil)))))))
 749
 750             (when (and alist
 751                        (> max 0)
 752                        (auth-source-search-collection
 753                         host
 754                         (or
 755                          (aget alist "machine")
 756                          (aget alist "host")
 757                          t))
 758                        (auth-source-search-collection
 759                         user
 760                         (or
 761                          (aget alist "login")
 762                          (aget alist "account")
 763                          (aget alist "user")
 764                          t))
 765                        (auth-source-search-collection
 766                         port
 767                         (or
 768                          (aget alist "port")
 769                          (aget alist "protocol")
 770                          t)))
 771               (decf max)
 772               (push (nreverse alist) result)
 773               ;; to delete a line, we just comment it out
 774               (when delete
 775                 (goto-char (point-min))
 776                 (insert "#")
 777                 (incf modified)))
 778             (setq alist nil
 779                   pair nil)
 780             (widen)
 781             (forward-line 1))
 782
 783           (when (< 0 modified)
 784             (when auth-source-gpg-encrypt-to
 785               ;; (see bug#7487) making `epa-file-encrypt-to' local to
 786               ;; this buffer lets epa-file skip the key selection query
 787               ;; (see the `local-variable-p' check in
 788               ;; `epa-file-write-region').
 789               (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
 790                 (make-local-variable 'epa-file-encrypt-to))
 791               (if (listp auth-source-gpg-encrypt-to)
 792                   (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
 793
 794             ;; ask AFTER we've successfully opened the file
 795             (when (y-or-n-p (format "Save file %s? (%d modifications)"
 796                                     file modified))
 797               (write-region (point-min) (point-max) file nil 'silent)
 798               (auth-source-do-debug
 799                "auth-source-netrc-parse: modified %d lines in %s"
 800                modified file)))
 801
 802           (nreverse result))))))
 803
 804 (defun auth-source-netrc-normalize (alist)
 805   (mapcar (lambda (entry)
 806             (let (ret item)
 807               (while (setq item (pop entry))
 808                 (let ((k (car item))
 809                       (v (cdr item)))
 810
 811                   ;; apply key aliases
 812                   (setq k (cond ((member k '("machine")) "host")
 813                                 ((member k '("login" "account")) "user")
 814                                 ((member k '("protocol")) "port")
 815                                 ((member k '("password")) "secret")
 816                                 (t k)))
 817
 818                   ;; send back the secret in a function (lexical binding)
 819                   (when (equal k "secret")
 820                     (setq v (lexical-let ((v v))
 821                               (lambda () v))))
 822
 823                   (setq ret (plist-put ret
 824                                        (intern (concat ":" k))
 825                                        v))
 826                   ))
 827               ret))
 828           alist))
 829
 830 ;;; (setq secret (plist-get (nth 0 (auth-source-search :host t :type 'netrc :K 1 :max 1)) :secret))
 831 ;;; (funcall secret)
 832
 833 (defun* auth-source-netrc-search (&rest
 834                                   spec
 835                                   &key backend create delete
 836                                   type max host user port
 837                                   &allow-other-keys)
 838 "Given a property list SPEC, return search matches from the :backend.
 839 See `auth-source-search' for details on SPEC."
 840   ;; just in case, check that the type is correct (null or same as the backend)
 841   (assert (or (null type) (eq type (oref backend type)))
 842           t "Invalid netrc search: %s %s")
 843
 844   (let ((results (auth-source-netrc-normalize
 845                   (auth-source-netrc-parse
 846                    :max max
 847                    :delete delete
 848                    :file (oref backend source)
 849                    :host (or host t)
 850                    :user (or user t)
 851                    :port (or port t)))))
 852
 853     ;; if we need to create an entry AND none were found to match
 854     (when (and create
 855                (= 0 (length results)))
 856
 857       ;; create based on the spec and record the value
 858       (setq results (or
 859                      ;; if the user did not want to create the entry
 860                      ;; in the file, it will be returned
 861                      (apply (slot-value backend 'create-function) spec)
 862                      ;; if not, we do the search again without :create
 863                      ;; to get the updated data.
 864
 865                      ;; the result will be returned, even if the search fails
 866                      (apply 'auth-source-netrc-search
 867                             (plist-put spec :create nil)))))
 868     results))
 869
 870 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t)
 871 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t :create-extra-keys '((A "default A") (B)))
 872
 873 (defun* auth-source-netrc-create (&rest spec
 874                                         &key backend
 875                                         secret host user port create
 876                                         &allow-other-keys)
 877   (let* ((base-required '(host user port secret))
 878          ;; we know (because of an assertion in auth-source-search) that the
 879          ;; :create parameter is either t or a list (which includes nil)
 880          (create-extra (if (eq t create) nil create))
 881          (required (append base-required create-extra))
 882          (file (oref backend source))
 883          (add "")
 884          (show "")
 885          ;; `valist' is an alist
 886          valist
 887          ;; `artificial' will be returned if no creation is needed
 888          artificial)
 889
 890     ;; only for base required elements (defined as function parameters):
 891     ;; fill in the valist with whatever data we may have from the search
 892     ;; we complete the first value if it's a list and use the value otherwise
 893     (dolist (br base-required)
 894       (when (symbol-value br)
 895         (let ((br-choice (cond
 896                           ;; all-accepting choice (predicate is t)
 897                           ((eq t (symbol-value br)) nil)
 898                           ;; just the value otherwise
 899                           (t (symbol-value br)))))
 900           (when br-choice
 901             (aput 'valist br br-choice)))))
 902
 903     ;; for extra required elements, see if the spec includes a value for them
 904     (dolist (er create-extra)
 905       (let ((name (concat ":" (symbol-name er)))
 906             (keys (loop for i below (length spec) by 2
 907                         collect (nth i spec))))
 908         (dolist (k keys)
 909           (when (equal (symbol-name k) name)
 910             (aput 'valist er (plist-get spec k))))))
 911
 912     ;; for each required element
 913     (dolist (r required)
 914       (let* ((data (aget valist r))
 915              (given-default (aget auth-source-creation-defaults r))
 916              ;; the defaults are simple
 917              (default (cond
 918                        ((and (not given-default) (eq r 'user))
 919                         (user-login-name))
 920                        ;; note we need this empty string
 921                        ((and (not given-default) (eq r 'port))
 922                         "")
 923                        (t given-default)))
 924              ;; the prompt's default string depends on the data so far
 925              (default-string (if (and default (< 0 (length default)))
 926                                  (format " (default %s)" default)
 927                                " (no default)"))
 928              ;; the prompt should also show what's entered so far
 929              (user-value (aget valist 'user))
 930              (host-value (aget valist 'host))
 931              (port-value (aget valist 'port))
 932              ;; note this handles lists by just printing them
 933              ;; later we allow the user to use completing-read to pick
 934              (info-so-far (concat (if user-value
 935                                       (format "%s@" user-value)
 936                                     "[USER?]")
 937                                   (if host-value
 938                                       (format "%s" host-value)
 939                                     "[HOST?]")
 940                                   (if port-value
 941                                       ;; this distinguishes protocol between
 942                                       (if (zerop (length port-value))
 943                                           "" ; 'entered as "no default"' vs.
 944                                         (format ":%s" port-value)) ; given
 945                                     ;; and this is when the protocol is unknown
 946                                     "[PORT?]"))))
 947
 948         ;; now prompt if the search SPEC did not include a required key;
 949         ;; take the result and put it in `data' AND store it in `valist'
 950         (aput 'valist r
 951               (setq data
 952                     (cond
 953                      ((and (null data) (eq r 'secret))
 954                       ;; special case prompt for passwords
 955                       (read-passwd (format "Password for %s: " info-so-far)))
 956                      ((null data)
 957                       (read-string
 958                        (format "Enter %s for %s%s: "
 959                                r info-so-far default-string)
 960                        nil nil default))
 961                      ((listp data)
 962                       (completing-read
 963                        (format "Enter %s for %s (TAB to see the choices): "
 964                                r info-so-far)
 965                        data
 966                        nil              ; no predicate
 967                        t                ; require a match
 968                        ;; note the default is nil, but if the user
 969                        ;; hits RET we'll get "", which is handled OK later
 970                        nil))
 971                      (t data))))
 972
 973         (when data
 974           (setq artificial (plist-put artificial
 975                                       (intern (concat ":" (symbol-name r)))
 976                                       (if (eq r 'secret)
 977                                           (lexical-let ((data data))
 978                                             (lambda () data))
 979                                         data))))
 980
 981         ;; when r is not an empty string...
 982         (when (and (stringp data)
 983                    (< 0 (length data)))
 984           (let ((printer (lambda (hide)
 985                            ;; append the key (the symbol name of r)
 986                            ;; and the value in r
 987                            (format "%s%s %S"
 988                                    ;; prepend a space
 989                                    (if (zerop (length add)) "" " ")
 990                                    ;; remap auth-source tokens to netrc
 991                                    (case r
 992                                      ('user "login")
 993                                      ('host "machine")
 994                                      ('secret "password")
 995                                      ('port "port") ; redundant but clearer
 996                                      (t (symbol-name r)))
 997                                    ;; the value will be printed in %S format
 998                                    (if (and hide (eq r 'secret))
 999                                        "HIDDEN_SECRET"
1000                                      data)))))
1001             (setq add (concat add (funcall printer nil)))
1002             (setq show (concat show (funcall printer t)))))))
1003
1004     (with-temp-buffer
1005       (when (file-exists-p file)
1006         (insert-file-contents file))
1007       (when auth-source-gpg-encrypt-to
1008         ;; (see bug#7487) making `epa-file-encrypt-to' local to
1009         ;; this buffer lets epa-file skip the key selection query
1010         ;; (see the `local-variable-p' check in
1011         ;; `epa-file-write-region').
1012         (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
1013           (make-local-variable 'epa-file-encrypt-to))
1014         (if (listp auth-source-gpg-encrypt-to)
1015             (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
1016       (goto-char (point-max))
1017
1018       ;; ask AFTER we've successfully opened the file
1019       (if (y-or-n-p (format "Add to file %s: line [%s]" file show))
1020           (progn
1021             (unless (bolp)
1022               (insert "\n"))
1023             (insert add "\n")
1024             (write-region (point-min) (point-max) file nil 'silent)
1025             (auth-source-do-debug
1026              "auth-source-netrc-create: wrote 1 new line to %s"
1027              file)
1028             nil)
1029         (list artificial)))))
1030
1031 ;;; Backend specific parsing: Secrets API backend
1032
1033 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :create t))
1034 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :delete t))
1035 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1))
1036 ;;; (let ((auth-sources '(default))) (auth-source-search))
1037 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1))
1038 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1 :signon_realm "https://git.gnus.org/Git"))
1039
1040 (defun* auth-source-secrets-search (&rest
1041                                     spec
1042                                     &key backend create delete label
1043                                     type max host user port
1044                                     &allow-other-keys)
1045   "Search the Secrets API; spec is like `auth-source'.
1046
1047 The :label key specifies the item's label.  It is the only key
1048 that can specify a substring.  Any :label value besides a string
1049 will allow any label.
1050
1051 All other search keys must match exactly.  If you need substring
1052 matching, do a wider search and narrow it down yourself.
1053
1054 You'll get back all the properties of the token as a plist.
1055
1056 Here's an example that looks for the first item in the 'Login'
1057 Secrets collection:
1058
1059  \(let ((auth-sources '(\"secrets:Login\")))
1060     (auth-source-search :max 1)
1061
1062 Here's another that looks for the first item in the 'Login'
1063 Secrets collection whose label contains 'gnus':
1064
1065  \(let ((auth-sources '(\"secrets:Login\")))
1066     (auth-source-search :max 1 :label \"gnus\")
1067
1068 And this one looks for the first item in the 'Login' Secrets
1069 collection that's a Google Chrome entry for the git.gnus.org site
1070 authentication tokens:
1071
1072  \(let ((auth-sources '(\"secrets:Login\")))
1073     (auth-source-search :max 1 :signon_realm \"https://git.gnus.org/Git\"))
1074 "
1075
1076   ;; TODO
1077   (assert (not create) nil
1078           "The Secrets API auth-source backend doesn't support creation yet")
1079   ;; TODO
1080   ;; (secrets-delete-item coll elt)
1081   (assert (not delete) nil
1082           "The Secrets API auth-source backend doesn't support deletion yet")
1083
1084   (let* ((coll (oref backend source))
1085          (max (or max 5000))     ; sanity check: default to stop at 5K
1086          (ignored-keys '(:create :delete :max :backend :label))
1087          (search-keys (loop for i below (length spec) by 2
1088                             unless (memq (nth i spec) ignored-keys)
1089                             collect (nth i spec)))
1090          ;; build a search spec without the ignored keys
1091          ;; if a search key is nil or t (match anything), we skip it
1092          (search-spec (apply 'append (mapcar
1093                                       (lambda (k)
1094                                         (if (or (null (plist-get spec k))
1095                                                 (eq t (plist-get spec k)))
1096                                             nil
1097                                           (list k (plist-get spec k))))
1098                               search-keys)))
1099          ;; needed keys (always including host, login, port, and secret)
1100          (returned-keys (mm-delete-duplicates (append
1101                                                '(:host :login :port :secret)
1102                                                search-keys)))
1103          (items (loop for item in (apply 'secrets-search-items coll search-spec)
1104                       unless (and (stringp label)
1105                                   (not (string-match label item)))
1106                       collect item))
1107          ;; TODO: respect max in `secrets-search-items', not after the fact
1108          (items (butlast items (- (length items) max)))
1109          ;; convert the item name to a full plist
1110          (items (mapcar (lambda (item)
1111                           (append
1112                            ;; make an entry for the secret (password) element
1113                            (list
1114                             :secret
1115                             (lexical-let ((v (secrets-get-secret coll item)))
1116                               (lambda () v)))
1117                            ;; rewrite the entry from ((k1 v1) (k2 v2)) to plist
1118                            (apply 'append
1119                                   (mapcar (lambda (entry)
1120                                             (list (car entry) (cdr entry)))
1121                                           (secrets-get-attributes coll item)))))
1122                         items))
1123          ;; ensure each item has each key in `returned-keys'
1124          (items (mapcar (lambda (plist)
1125                           (append
1126                            (apply 'append
1127                                   (mapcar (lambda (req)
1128                                             (if (plist-get plist req)
1129                                                 nil
1130                                               (list req nil)))
1131                                           returned-keys))
1132                            plist))
1133                         items)))
1134     items))
1135
1136 (defun* auth-source-secrets-create (&rest
1137                                     spec
1138                                     &key backend type max host user port
1139                                     &allow-other-keys)
1140   ;; TODO
1141   ;; (apply 'secrets-create-item (auth-get-source entry) name passwd spec)
1142   (debug spec))
1143
1144 ;;; older API
1145
1146 ;;; (auth-source-user-or-password '("login" "password") "imap.myhost.com" t "tzz")
1147
1148 ;; deprecate the old interface
1149 (make-obsolete 'auth-source-user-or-password
1150                'auth-source-search "Emacs 24.1")
1151 (make-obsolete 'auth-source-forget-user-or-password
1152                'auth-source-forget "Emacs 24.1")
1153
1154 (defun auth-source-user-or-password
1155   (mode host port &optional username create-missing delete-existing)
1156   "Find MODE (string or list of strings) matching HOST and PORT.
1157
1158 DEPRECATED in favor of `auth-source-search'!
1159
1160 USERNAME is optional and will be used as \"login\" in a search
1161 across the Secret Service API (see secrets.el) if the resulting
1162 items don't have a username.  This means that if you search for
1163 username \"joe\" and it matches an item but the item doesn't have
1164 a :user attribute, the username \"joe\" will be returned.
1165
1166 A non nil DELETE-EXISTING means deleting any matching password
1167 entry in the respective sources.  This is useful only when
1168 CREATE-MISSING is non nil as well; the intended use case is to
1169 remove wrong password entries.
1170
1171 If no matching entry is found, and CREATE-MISSING is non nil,
1172 the password will be retrieved interactively, and it will be
1173 stored in the password database which matches best (see
1174 `auth-sources').
1175
1176 MODE can be \"login\" or \"password\"."
1177   (auth-source-do-debug
1178    "auth-source-user-or-password: DEPRECATED get %s for %s (%s) + user=%s"
1179    mode host port username)
1180
1181   (let* ((listy (listp mode))
1182          (mode (if listy mode (list mode)))
1183          (cname (if username
1184                     (format "%s %s:%s %s" mode host port username)
1185                   (format "%s %s:%s" mode host port)))
1186          (search (list :host host :port port))
1187          (search (if username (append search (list :user username)) search))
1188          (search (if create-missing
1189                      (append search (list :create t))
1190                    search))
1191          (search (if delete-existing
1192                      (append search (list :delete t))
1193                    search))
1194          ;; (found (if (not delete-existing)
1195          ;;            (gethash cname auth-source-cache)
1196          ;;          (remhash cname auth-source-cache)
1197          ;;          nil)))
1198          (found nil))
1199     (if found
1200         (progn
1201           (auth-source-do-debug
1202            "auth-source-user-or-password: DEPRECATED cached %s=%s for %s (%s) + %s"
1203            mode
1204            ;; don't show the password
1205            (if (and (member "password" mode) t)
1206                "SECRET"
1207              found)
1208            host port username)
1209           found)                        ; return the found data
1210       ;; else, if not found, search with a max of 1
1211       (let ((choice (nth 0 (apply 'auth-source-search
1212                                   (append '(:max 1) search)))))
1213         (when choice
1214           (dolist (m mode)
1215             (cond
1216              ((equal "password" m)
1217               (push (if (plist-get choice :secret)
1218                       (funcall (plist-get choice :secret))
1219                     nil) found))
1220              ((equal "login" m)
1221               (push (plist-get choice :user) found)))))
1222         (setq found (nreverse found))
1223         (setq found (if listy found (car-safe found)))))
1224
1225         found))
1226
1227 (provide 'auth-source)
1228
1229 ;;; auth-source.el ends here