cgit.sxemacs.org Git - riece/blob - lisp/riece-log.el

   1 ;;; riece-log.el --- saving irc logs add-on
   2 ;; Copyright (C) 2003 OHASHI Akira
   3
   4 ;; Author: OHASHI Akira <bg66@koka-in.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This add-on saves irc logs for every channel.
  27
  28 ;; To use, add the following line to your ~/.riece/init.el:
  29 ;; (add-to-list 'riece-addons 'riece-log)
  30
  31 ;;; Code:
  32
  33 (require 'riece-message)
  34 (require 'riece-button)
  35
  36 (defgroup riece-log nil
  37   "Save irc log"
  38   :group 'riece)
  39
  40 (defcustom riece-log-directory
  41   (expand-file-name "log" riece-directory)
  42   "*Where to look for log files."
  43   :type 'directory
  44   :group 'riece-log)
  45
  46 (defcustom riece-log-directory-map nil
  47   "*The map of channel name and directory name."
  48   :type '(repeat (cons (string :tag "Channel name")
  49                        (string :tag "Directory name")))
  50   :group 'riece-log)
  51
  52 (defcustom riece-log-flashback 10
  53   "*If non-nil, irc messages flash back from log files.
  54 If integer, flash back only this line numbers. t means all lines."
  55   :type '(choice (integer :tag "line numbers")
  56                  (boolean :tag "flash back or not"))
  57   :group 'riece-log)
  58
  59 (defcustom riece-log-coding-system nil
  60   "*Coding system used for log files."
  61   :type 'symbol
  62   :group 'riece-log)
  63
  64 (defcustom riece-log-file-name-coding-system
  65   (if (boundp 'file-name-coding-system)
  66       file-name-coding-system)
  67   "*Coding system used for filenames of log files."
  68   :type 'symbol
  69   :group 'riece-log)
  70
  71 (defcustom riece-log-open-directory-function 'find-file
  72   "*Function for opening a directory."
  73   :type 'function
  74   :group 'riece-log)
  75
  76 (defvar riece-log-enabled nil)
  77
  78 (defconst riece-log-description
  79   "Saving IRC logs")
  80
  81 (defun riece-log-display-message-function (message)
  82   (if riece-log-enabled
  83       (let ((file (riece-log-get-file (riece-message-target message)))
  84             (coding-system-for-write riece-log-coding-system))
  85         (unless (file-directory-p (file-name-directory file))
  86           (make-directory (file-name-directory file) t))
  87         (write-region (concat (format-time-string "%H:%M") " "
  88                               (riece-format-message message))
  89                       nil file t 0))))
  90
  91 (defun riece-log-get-file (identity)
  92   (expand-file-name
  93    (concat (format-time-string "%Y%m%d") ".log")
  94    (riece-log-get-directory identity)))
  95
  96 (defun riece-log-get-files (identity)
  97   (let ((files (directory-files (riece-log-get-directory identity) t
  98                                 (concat "^"
  99                                         (riece-make-interval-regexp "[0-9]" 8)
 100                                         "\\.log$")
 101                                 t)))
 102     (nreverse (sort files #'string-lessp))))
 103
 104 (defun riece-log-get-directory (identity)
 105   (let ((channel (riece-identity-canonicalize-prefix
 106                   (riece-identity-prefix identity)))
 107         (server (riece-identity-server identity))
 108         (map (assoc (riece-format-identity identity) riece-log-directory-map))
 109         name)
 110     (cond (map (setq name (cdr map)))
 111           ((string-match riece-strict-channel-regexp channel)
 112            (let ((suffix (match-string 2 channel)))
 113              (setq name (substring channel (match-end 1) (match-beginning 2)))
 114              (when (and (stringp suffix)
 115                         (string-match "^:\\*\\.\\(.*\\)" suffix))
 116                (setq name (concat name "-" (match-string 1 suffix))))))
 117           (t (setq name "priv")))
 118     (if server
 119         (expand-file-name name (expand-file-name server riece-log-directory))
 120       (expand-file-name name riece-log-directory))))
 121
 122 (defun riece-log-get-directory-1 (identity)
 123   (let ((prefix (riece-identity-canonicalize-prefix
 124                  (riece-identity-prefix identity)))
 125         (server (riece-identity-server identity))
 126         (map (assoc (riece-format-identity identity) riece-log-directory-map))
 127         name)
 128     (if map
 129         (setq name (cdr map))
 130       (expand-file-name (riece-log-encode-file-name prefix)
 131                         (expand-file-name
 132                          (concat "." (riece-log-encode-file-name server))
 133                          riece-log-directory)))))
 134
 135 (defun riece-log-encode-file-name (file-name)
 136   (if riece-log-file-name-coding-system
 137       (setq file-name
 138             (encode-coding-string file-name
 139                                   riece-log-file-name-coding-system)))
 140   (let ((index 0)
 141         c)
 142     (while (string-match "[^-0-9A-Za-z_\x80-\xFF]" file-name index)
 143       (setq c (aref file-name (match-beginning 0)))
 144       (if (eq c ?=)
 145           (setq file-name (replace-match "==" nil t file-name)
 146                 index (1+ (match-end 0)))
 147         (setq file-name (replace-match (format "=%02X" c) nil t file-name)
 148               index (+ 2 (match-end 0)))))
 149     file-name))
 150
 151 (defun riece-log-decode-file-name (file-name)
 152   (let ((index 0))
 153     (while (string-match "==\\|=\\([0-7][0-9A-F]\\)" file-name index)
 154       (setq file-name (replace-match
 155                        (if (eq (aref file-name (1- (match-end 0))) ?=)
 156                            "="
 157                          (char-to-string
 158                           (car (read-from-string
 159                                 (concat "?\\x" (match-string 1 file-name))))))
 160                        nil t file-name)
 161             index (1+ (match-beginning 0))))
 162     file-name)
 163   (if riece-log-file-name-coding-system
 164       (setq file-name
 165             (decode-coding-string file-name
 166                                   riece-log-file-name-coding-system)))
 167   file-name)
 168
 169 (defun riece-log-flashback-1 (identity)
 170   (if (eq riece-log-flashback t)
 171       (let ((file (riece-log-get-file identity)))
 172         (if (file-exists-p file)
 173             (insert-file-contents file)))
 174     (let ((files (riece-log-get-files identity))
 175           (lines (- riece-log-flashback))
 176           date point)
 177       (while (and (< lines 0) files)
 178         (if (and (file-exists-p (car files))
 179                  (string-match (concat "\\("
 180                                        (riece-make-interval-regexp "[0-9]" 4)
 181                                        "\\)\\("
 182                                        (riece-make-interval-regexp "[0-9]" 2)
 183                                        "\\)\\("
 184                                        (riece-make-interval-regexp "[0-9]" 2)
 185                                        "\\).log$")
 186                                (car files)))
 187             (save-restriction
 188               (narrow-to-region (point-min) (point-min))
 189               (setq date (concat " (" (match-string 1 (car files)) "/"
 190                                  (match-string 2 (car files)) "/"
 191                                  (match-string 3 (car files)) ")"))
 192               (insert-file-contents (car files))
 193               (goto-char (point-max))
 194               (setq lines (forward-line lines)
 195                     point (point))
 196               (while (not (eobp))
 197                 (end-of-line)
 198                 (insert date)
 199                 (forward-line))
 200               (goto-char point)))
 201         (setq files (cdr files)))
 202       (if (zerop lines)
 203           (delete-region (point-min) (point))))))
 204
 205 (defun riece-log-flashback (identity)
 206   (when riece-log-flashback
 207     (let (buffer-read-only
 208           (point (goto-char (point-max))))
 209       (insert (with-temp-buffer
 210                 (riece-log-flashback-1 identity)
 211                 (buffer-string)))
 212       (goto-char point)
 213       (while (re-search-forward
 214               "^[0-9][0-9]:[0-9][0-9] [<>]\\([^<>]+\\)[<>] " nil t)
 215         (put-text-property (match-beginning 1) (match-end 1)
 216                            'riece-identity
 217                            (riece-make-identity
 218                             (riece-match-string-no-properties 1)
 219                             (riece-identity-server identity))))
 220       (when (and (memq 'riece-button riece-addons)
 221                  riece-button-enabled)
 222         (riece-button-update-buffer))
 223       (goto-char (point-max))
 224       (set-window-point (get-buffer-window (current-buffer))
 225                         (point)))))
 226
 227 (defun riece-log-open-directory (&optional channel)
 228   (interactive)
 229   (let ((directory (riece-log-get-directory
 230                     (or channel riece-current-channel))))
 231     (if (file-directory-p directory)
 232         (funcall riece-log-open-directory-function directory)
 233       (error "No log directory"))))
 234
 235 (defun riece-log-requires ()
 236   (if (memq 'riece-button riece-addons)
 237       '(riece-button)))
 238
 239 (defun riece-log-insinuate ()
 240   ;; FIXME: Use `riece-after-insert-functions' for trapping change,
 241   ;; notice, wallops and so on. But must add argument.
 242   (add-hook 'riece-after-display-message-functions
 243             'riece-log-display-message-function)
 244   (add-hook 'riece-channel-buffer-create-functions
 245             'riece-log-flashback))
 246
 247 (defvar riece-command-mode-map)
 248 (defun riece-log-enable ()
 249   (define-key riece-command-mode-map "\C-cd" 'riece-log-open-directory)
 250   (setq riece-log-enabled t))
 251
 252 (defun riece-log-disable ()
 253   (define-key riece-command-mode-map "\C-cd" nil)
 254   (setq riece-log-enabled nil))
 255
 256 (provide 'riece-log)
 257
 258 ;;; riece-log.el ends here