cgit.sxemacs.org Git - riece/blob - lisp/riece-ignore.el

   1 ;;; riece-ignore.el --- ignore user
   2 ;; Copyright (C) 1998-2004 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; To use, add the following line to your ~/.riece/init.el:
  28 ;; (add-to-list 'riece-addons 'riece-ignore)
  29
  30 ;;; Code:
  31
  32 (require 'riece-signal)
  33 (require 'riece-identity)
  34 (require 'riece-message)
  35
  36 (defgroup riece-ignore nil
  37   "Ignore messages in IRC buffers."
  38   :group 'riece)
  39
  40 (defcustom riece-ignore-discard-message t
  41   "If non-nil, messages from ignored user are completely discarded.
  42 Otherwise, they are left there but not visible."
  43   :group 'riece-ignore
  44   :type 'boolean)
  45
  46 (defvar riece-ignored-user-list nil)
  47
  48 (defun riece-ignore-user-rename-signal-function (signal handback)
  49   (let ((pointer (riece-identity-member (car (riece-signal-args signal))
  50                                         riece-ignored-user-list)))
  51     (if pointer
  52         (setcar pointer (nth 1 (riece-signal-args signal))))))
  53
  54 (defun riece-ignore-user (user toggle)
  55   (interactive
  56    (let ((completion-ignore-case t))
  57      (list (if current-prefix-arg
  58                (riece-completing-read-identity
  59                 "Unignore user: "
  60                 riece-ignored-user-list)
  61              (riece-completing-read-identity
  62               "Ignore user: "
  63               (riece-get-users-on-server (riece-current-server-name))
  64               (lambda (user)
  65                 (not (riece-identity-member
  66                       (riece-parse-identity user)
  67                       riece-ignored-user-list)))))
  68            (not current-prefix-arg))))
  69   (if toggle
  70       (progn
  71         (setq riece-ignored-user-list (cons user riece-ignored-user-list))
  72         (riece-connect-signal
  73          'user-renamed
  74          #'riece-ignore-user-rename-signal-function))
  75     (let ((pointer (riece-identity-member user riece-ignored-user-list)))
  76       (setq riece-ignored-user-list (delq (car pointer)
  77                                           riece-ignored-user-list))
  78       (riece-disconnect-signal
  79        'user-renamed
  80        #'riece-ignore-user-rename-signal-function))))
  81
  82 (defun riece-ignore-message-filter (message)
  83   (if (riece-identity-member (riece-message-speaker message)
  84                              riece-ignored-user-list)
  85       (unless riece-ignore-discard-message
  86         (put-text-property 0 (length (riece-message-text message))
  87                            'invisible 'riece-ignore
  88                            (riece-message-text message))
  89         message)
  90     message))
  91
  92 (defvar riece-command-mode-map)
  93 (defun riece-ignore-insinuate ()
  94   (add-hook 'riece-message-filter-functions 'riece-ignore-message-filter)
  95   (define-key riece-command-mode-map
  96     "\C-ck" 'riece-ignore-user))
  97
  98 (provide 'riece-ignore)
  99
 100 ;;; riece-ignore.el ends here