cgit.sxemacs.org Git - sxemacs/blob - m4/sxe-linker.m4

   1 dnl sxe-linker.m4 -- Linker stuff, esp. dynamic linking
   2 dnl needed for emodules for one
   3
   4 AC_DEFUN([SXE_CHECK_LINKER_FLAGS], [dnl
   5 dnl just like SXE_CHECK_COMPILER_FLAGS but calls the linker
   6 dnl SXE_CHECK_LINKER_FLAGS(<FLAG>, <ACTION-IF-FOUND>, <ACTION-IF-NOT-FOUND>,
   7 dnl     <ADDITIONAL-FLAGS>)
   8         AC_MSG_CHECKING([whether linker accepts $1])
   9
  10         dnl Some hackery here since AC_CACHE_VAL can't handle a non-literal varname:
  11         SXE_LANG_WERROR([push+on])
  12         AS_LITERAL_IF([$1], [
  13                 AC_CACHE_VAL(AS_TR_SH(sxe_cv_[]_AC_LANG_ABBREV[]_flags_$1), [
  14                         sxe_save_FLAGS=$[]_AC_LANG_PREFIX[]FLAGS
  15                         _AC_LANG_PREFIX[]FLAGS="$4 ${XFLAG} $1"
  16                         AC_LINK_IFELSE([AC_LANG_PROGRAM()],
  17                                 AS_TR_SH(sxe_cv_[]_AC_LANG_ABBREV[]_flags_$1)="yes",
  18                                 AS_TR_SH(sxe_cv_[]_AC_LANG_ABBREV[]_flags_$1)="no")
  19                         _AC_LANG_PREFIX[]FLAGS=$sxe_save_FLAGS])], [
  20                 sxe_save_FLAGS=$[]_AC_LANG_PREFIX[]FLAGS
  21                 _AC_LANG_PREFIX[]FLAGS="$4 ${XFLAG} $1"
  22                 AC_LINK_IFELSE([AC_LANG_PROGRAM()],
  23                         eval AS_TR_SH(sxe_cv_[]_AC_LANG_ABBREV[]_flags_$1)="yes",
  24                         eval AS_TR_SH(sxe_cv_[]_AC_LANG_ABBREV[]_flags_$1)="no")
  25                 _AC_LANG_PREFIX[]FLAGS=$sxe_save_FLAGS])
  26         eval sxe_check_linker_flags=$AS_TR_SH(sxe_cv_[]_AC_LANG_ABBREV[]_flags_$1)
  27         SXE_LANG_WERROR([pop])
  28
  29         AC_MSG_RESULT([$sxe_check_linker_flags])
  30         if test "$sxe_check_linker_flags" = "yes"; then
  31                 m4_default([$2], :)
  32         else
  33                 m4_default([$3], :)
  34         fi
  35 ])dnl SXE_CHECK_LINKER_FLAGS
  36
  37
  38 AC_DEFUN([SXE_CHECK_LD_ZFLAG], [dnl
  39         pushdef([LD_ZFLAG], [$1])
  40         pushdef([cv_zflag], [sxe_cv_ld__z_]translit(LD_ZFLAG,[-.=],[___]))
  41
  42         SXE_CHECK_LINKER_FLAGS([-z ]LD_ZFLAG[])
  43
  44 dnl Use the check that actually calls the compiler/linker to examine the flags
  45 dnl     AC_CACHE_CHECK([whether linker supports -z ]LD_ZFLAG[],
  46 dnl             []cv_zflag[], [_SXE_CHECK_LD_ZFLAG(LD_ZFLAG)])
  47
  48         popdef([cv_zflag])
  49         popdef([LD_ZFLAG])
  50 ])dnl SXE_CHECK_LD_ZFLAG
  51
  52 AC_DEFUN([_SXE_CHECK_LD_ZFLAG], [dnl
  53         ## arg1 is the flag to check for
  54         pushdef([LD_ZFLAG], [$1])
  55         pushdef([cv_zflag], [sxe_cv_ld__z_]translit(LD_ZFLAG,[-.=],[___]))
  56
  57         if test "$GCC" = "yes"; then
  58                 if test "($CC -Xlinker --help 2>&1 | \
  59                         grep \"-z []LD_ZFLAG[]\" > /dev/null 2>&1 ) "; then
  60                         cv_zflag="yes"
  61                 else
  62                         cv_zflag="no"
  63                 fi
  64         elif test -n "$LD"; then
  65                 if test "($LD --help 2>&1 | \
  66                         grep \"-z []LD_ZFLAG[]\" > /dev/null 2>&1 )"; then
  67                         cv_zflag="yes"
  68                 else
  69                         cv_zflag="no"
  70                 fi
  71         else
  72                 cv_zflag="no"
  73         fi
  74
  75         popdef([cv_zflag])
  76         popdef([LD_ZFLAG])
  77 ])dnl _SXE_CHECK_LD_ZFLAG
  78
  79 AC_DEFUN([SXE_CHECK_LDFLAGS], [dnl
  80         AC_REQUIRE([SXE_CHECK_COMPILER_XFLAG])
  81
  82         ## relocation
  83         SXE_CHECK_LD_ZFLAG([combreloc])
  84         SXE_CHECK_LD_ZFLAG([nocombreloc])
  85         ## symbols
  86         SXE_CHECK_LD_ZFLAG([defs])
  87         SXE_CHECK_LD_ZFLAG([muldefs])
  88         ## search paths
  89         SXE_CHECK_LD_ZFLAG([nodefaultlib])
  90         ## binding policy
  91         SXE_CHECK_LD_ZFLAG([lazy])
  92         SXE_CHECK_LD_ZFLAG([now])
  93
  94         LDFLAGS="${ldflags} ${ac_cv_env_LDFLAGS_value}"
  95         AC_MSG_CHECKING([for preferred LDFLAGS])
  96         AC_MSG_RESULT([${LDFLAGS}])
  97
  98         AC_MSG_NOTICE([
  99 If you wish to ADD your own flags you want to stop here and rerun the
 100 configure script like so:
 101   configure LDFLAGS=<to-be-added-flags>
 102
 103 You can always override the determined LDFLAGS, partially or totally,
 104 using
 105   make -C <directory> LDFLAGS=<your-own-flags> [target]
 106 or
 107   make LDFLAGS=<your-own-flags> [target]
 108 respectively
 109
 110 NOTE: -C <directory> option is not available on all systems
 111                 ])
 112 ])dnl SXE_CHECK_LDFLAGS
 113
 114 AC_DEFUN([SXE_PREPEND_LINKER_FLAG], [dnl
 115         ## a convenience function to add such linker flags to variables
 116         ## arg1 is the flag to add (must include -z if applicable)
 117         ## arg2 is the variable whither to prepend
 118         pushdef([FLAG], [$1])
 119         pushdef([__FLAG], [-Wl,]patsubst([$1], [ ], [[,]]))
 120         pushdef([VAR], [$2])
 121
 122         []VAR[]="[]__FLAG[] $[]VAR[]"
 123         if test "$extra_verbose" = "yes"; then
 124                 echo "    Prepending linker flag \"[]__FLAG[]\" to \$[]VAR[]"
 125         fi
 126
 127         popdef([VAR])
 128         popdef([__FLAG])
 129         popdef([FLAG])
 130 ])dnl SXE_PREPEND_LINKER_FLAG
 131
 132 dnl sxe-linker.m4 ends here