cgit.sxemacs.org Git - riece/blob - lisp/riece-message.el

   1 ;;; riece-message.el --- generate and display message line
   2 ;; Copyright (C) 1999-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: message
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'riece-identity)
  27 (require 'riece-channel)
  28 (require 'riece-user)
  29 (require 'riece-display)
  30 (require 'riece-misc)
  31
  32 (defgroup riece-message nil
  33   "Display messages."
  34   :tag "Message"
  35   :prefix "riece-"
  36   :group 'riece)
  37
  38 (defcustom riece-message-filter-functions nil
  39   "Functions to filter incoming messages."
  40   :type 'function
  41   :group 'riece-message)
  42
  43 (defcustom riece-message-make-open-bracket-function
  44   #'riece-message-make-open-bracket
  45   "Function which makes `open-bracket' string for each message."
  46   :type 'function
  47   :group 'riece-message)
  48
  49 (defcustom riece-message-make-close-bracket-function
  50   #'riece-message-make-close-bracket
  51   "Function which makes `close-bracket' string for each message."
  52   :type 'function
  53   :group 'riece-message)
  54
  55 (defcustom riece-message-make-name-function
  56   #'riece-message-make-name
  57   "Function which makes local identity for each message."
  58   :type 'function
  59   :group 'riece-message)
  60
  61 (defcustom riece-message-make-global-name-function
  62   #'riece-message-make-global-name
  63   "Function which makes global identity for each message."
  64   :type 'function
  65   :group 'riece-message)
  66
  67 (defcustom riece-message-format-function-alist nil
  68   "Alist mapping message types to format functions."
  69   :type 'list
  70   :group 'riece-message)
  71
  72 (defun riece-message-make-open-bracket (message)
  73   "Make `open-bracket' string for MESSAGE."
  74   (if (eq (riece-message-type message) 'notice)
  75       "{"
  76     (if (riece-message-own-p message)
  77         ">"
  78       (if (riece-message-private-p message)
  79           "="
  80         (if (riece-message-external-p message)
  81             "("
  82           "<")))))
  83
  84 (defun riece-message-make-close-bracket (message)
  85   "Make `close-bracket' string for MESSAGE."
  86   (if (eq (riece-message-type message) 'notice)
  87       "}"
  88     (if (riece-message-own-p message)
  89         "<"
  90       (if (riece-message-private-p message)
  91           "="
  92         (if (riece-message-external-p message)
  93             ")"
  94           ">")))))
  95
  96 (defun riece-message-make-name (message)
  97   "Make local identity for MESSAGE."
  98   (if (riece-message-private-p message)
  99       (if (riece-message-own-p message)
 100           (riece-format-identity (riece-message-target message) t)
 101         (riece-format-identity (riece-message-speaker message) t))
 102     (riece-format-identity (riece-message-speaker message) t)))
 103
 104 (defun riece-message-make-global-name (message)
 105   "Make global identity for MESSAGE."
 106   (if (riece-message-private-p message)
 107       (if (riece-message-own-p message)
 108           (riece-format-identity (riece-message-target message) t)
 109         (riece-format-identity (riece-message-speaker message) t))
 110     (concat (riece-format-identity (riece-message-target message) t) ":"
 111             (riece-format-identity (riece-message-speaker message) t))))
 112
 113 (defun riece-message-buffer (message)
 114   "Return the buffer where MESSAGE should appear."
 115   (let ((target (if (riece-message-private-p message)
 116                     (if (riece-message-own-p message)
 117                         (riece-message-target message)
 118                       (riece-message-speaker message))
 119                   (riece-message-target message))))
 120     (unless (riece-identity-member target riece-current-channels)
 121       (riece-join-channel target)
 122       ;; If you are not joined to any channel,
 123       ;; switch to the target immediately.
 124       (unless riece-current-channel
 125         (riece-switch-to-channel target)))
 126     (riece-channel-buffer target)))
 127
 128 (defun riece-message-parent-buffers (message buffer)
 129   "Return the parents of BUFFER where MESSAGE should appear.
 130 Normally they are *Dialogue* and/or *Others*."
 131   (if (and buffer (riece-frozen buffer)) ;the message might not be
 132                                          ;visible in buffer's window
 133       (list riece-dialogue-buffer riece-others-buffer)
 134     (if (and riece-current-channel      ;the message is not sent to
 135                                         ;the current channel
 136              (if (riece-message-private-p message)
 137                  (if (riece-message-own-p message)
 138                      (not (riece-identity-equal
 139                            (riece-message-target message)
 140                            riece-current-channel))
 141                    (not (riece-identity-equal
 142                          (riece-message-speaker message)
 143                          riece-current-channel)))
 144                (not (riece-identity-equal
 145                      (riece-message-target message)
 146                      riece-current-channel))))
 147         (list riece-dialogue-buffer riece-others-buffer)
 148       riece-dialogue-buffer)))
 149
 150 (defun riece-format-message (message &optional global)
 151   (let ((open-bracket
 152          (funcall riece-message-make-open-bracket-function message))
 153         (close-bracket
 154          (funcall riece-message-make-close-bracket-function message))
 155         (name
 156          (if global
 157              (funcall riece-message-make-global-name-function message)
 158            (funcall riece-message-make-name-function message)))
 159         (server-name (riece-identity-server (riece-message-speaker message))))
 160     (riece-with-server-buffer server-name
 161       (concat
 162        (if global
 163            (riece-concat-server-name
 164             (concat open-bracket name close-bracket
 165                     " " (riece-message-text message)))
 166          (concat open-bracket name close-bracket
 167                  " " (riece-message-text message)))
 168        "\n"))))
 169
 170 (defun riece-display-message-1 (message)
 171   (let ((buffer (riece-message-buffer message))
 172         (format-message-function
 173          (or (cdr (assq (riece-message-type message)
 174                         riece-message-format-function-alist))
 175              #'riece-format-message))
 176         parent-buffers)
 177     (when (and buffer
 178                (riece-message-own-p message)
 179                (riece-own-frozen buffer))
 180       (with-current-buffer buffer
 181         (setq riece-freeze nil))
 182       (riece-emit-signal 'buffer-freeze-changed buffer nil))
 183     (setq parent-buffers (riece-message-parent-buffers message buffer))
 184     (riece-insert buffer (funcall format-message-function message))
 185     (riece-insert parent-buffers (funcall format-message-function message t))
 186     (with-current-buffer buffer
 187       (run-hook-with-args 'riece-after-display-message-functions message))))
 188
 189 (defun riece-display-message (message)
 190   "Display MESSAGE object."
 191   (let ((functions riece-message-filter-functions))
 192     (setq message (copy-sequence message))
 193     (while (and functions message)
 194       (setq message (funcall (car functions) message)
 195             functions (cdr functions)))
 196     (if message
 197         (riece-display-message-1 message))))
 198
 199 (defun riece-make-message (speaker target text &optional type own-p)
 200   "Make an instance of message object.
 201 Arguments are appropriate to the sender, the receiver, and text
 202 content, respectively.
 203 Optional 4th argument TYPE specifies the type of the message.
 204 Currently possible values are `nil' or `notice'.
 205 Optional 5th argument is the flag to indicate that this message is not
 206 from the network."
 207   (vector speaker target text type own-p))
 208
 209 (defun riece-message-speaker (message)
 210   "Return the sender of MESSAGE."
 211   (aref message 0))
 212
 213 (defun riece-message-target (message)
 214   "Return the receiver of MESSAGE."
 215   (aref message 1))
 216
 217 (defun riece-message-text (message)
 218   "Return the text part of MESSAGE."
 219   (aref message 2))
 220
 221 (defun riece-message-type (message)
 222   "Return the type of MESSAGE.
 223 Currently possible values are `action' and `notice'."
 224   (aref message 3))
 225
 226 (defun riece-message-own-p (message)
 227   "Return t if MESSAGE is not from the network."
 228   (aref message 4))
 229
 230 (defun riece-message-set-speaker (message speaker)
 231   "Set the sender of MESSAGE."
 232   (aset message 0 speaker))
 233
 234 (defun riece-message-set-target (message target)
 235   "Set the receiver of MESSAGE."
 236   (aset message 1 target))
 237
 238 (defun riece-message-set-text (message text)
 239   "Set the text part of MESSAGE."
 240   (aset message 2 text))
 241
 242 (defun riece-message-set-type (message type)
 243   "Set the type of MESSAGE.
 244 Currently possible values are `action' and `notice'."
 245   (aset message 3 type))
 246
 247 (defun riece-message-set-own-p (message own-p)
 248   "Set t if MESSAGE is not from the network."
 249   (aset message 4 own-p))
 250
 251 (defun riece-message-private-p (message)
 252   "Return t if MESSAGE is a private message."
 253   (not (or (riece-channel-p (riece-identity-prefix
 254                              (riece-message-speaker message)))
 255            (riece-channel-p (riece-identity-prefix
 256                              (riece-message-target message))))))
 257
 258 (defun riece-message-external-p (message)
 259   "Return t if MESSAGE is from outside the channel."
 260   (not (riece-identity-member
 261         (riece-message-speaker message)
 262         (let ((target (riece-message-target message)))
 263           (riece-with-server-buffer (riece-identity-server target)
 264             (mapcar
 265              (lambda (user)
 266                (riece-make-identity (car user) riece-server-name))
 267              (riece-channel-get-users (riece-identity-prefix target))))))))
 268
 269 (provide 'riece-message)
 270
 271 ;;; riece-message.el ends here