cgit.sxemacs.org Git - gnus/blob - lisp/uudecode.el

   1 ;;; uudecode.el -- elisp native uudecode
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   7 ;; Keywords: uudecode news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (eval-and-compile
  33   (defalias 'uudecode-char-int
  34     (if (fboundp 'char-int)
  35         'char-int
  36       'identity)))
  37
  38 (defcustom uudecode-decoder-program "uudecode"
  39   "*Non-nil value should be a string that names a uu decoder.
  40 The program should expect to read uu data on its standard
  41 input and write the converted data to its standard output."
  42   :type 'string
  43   :group 'gnus-extract)
  44
  45 (defcustom uudecode-decoder-switches nil
  46   "*List of command line flags passed to `uudecode-decoder-program'."
  47   :group 'gnus-extract
  48   :type '(repeat string))
  49
  50 (defcustom uudecode-use-external
  51   (executable-find uudecode-decoder-program)
  52   "*Use external uudecode program."
  53   :version "22.1"
  54   :group 'gnus-extract
  55   :type 'boolean)
  56
  57 (defconst uudecode-alphabet "\040-\140")
  58
  59 (defconst uudecode-begin-line "^begin[ \t]+[0-7][0-7][0-7][ \t]+\\(.*\\)$")
  60 (defconst uudecode-end-line "^end[ \t]*$")
  61
  62 (defconst uudecode-body-line
  63   (let ((i 61) (str "^M"))
  64     (while (> (setq i (1- i)) 0)
  65       (setq str (concat str "[^a-z]")))
  66     (concat str ".?$")))
  67
  68 (defvar uudecode-temporary-file-directory
  69   (cond ((fboundp 'temp-directory) (temp-directory))
  70         ((boundp 'temporary-file-directory) temporary-file-directory)
  71         ("/tmp")))
  72
  73 ;;;###autoload
  74 (defun uudecode-decode-region-external (start end &optional file-name)
  75   "Uudecode region between START and END using external program.
  76 If FILE-NAME is non-nil, save the result to FILE-NAME.  The program
  77 used is specified by `uudecode-decoder-program'."
  78   (interactive "r\nP")
  79   (let ((cbuf (current-buffer)) tempfile firstline status)
  80     (save-excursion
  81       (goto-char start)
  82       (when (re-search-forward uudecode-begin-line nil t)
  83         (forward-line 1)
  84         (setq firstline (point))
  85         (cond ((null file-name))
  86               ((stringp file-name))
  87               (t
  88                (setq file-name (read-file-name "File to Name:"
  89                                                nil nil nil
  90                                                (match-string 1)))))
  91         (setq tempfile (if file-name
  92                            (expand-file-name file-name)
  93                            (if (fboundp 'make-temp-file)
  94                                (let ((temporary-file-directory
  95                                       uudecode-temporary-file-directory))
  96                                  (make-temp-file "uu"))
  97                              (expand-file-name
  98                               (make-temp-name "uu")
  99                               uudecode-temporary-file-directory))))
 100         (let ((cdir default-directory)
 101               (default-process-coding-system
 102                 (if (featurep 'xemacs)
 103                     ;; In XEmacs, `nil' is not a valid coding system.
 104                     '(binary . binary)
 105                   nil)))
 106           (unwind-protect
 107               (with-temp-buffer
 108                 (insert "begin 600 " (file-name-nondirectory tempfile) "\n")
 109                 (insert-buffer-substring cbuf firstline end)
 110                 (cd (file-name-directory tempfile))
 111                 (apply 'call-process-region
 112                        (point-min)
 113                        (point-max)
 114                        uudecode-decoder-program
 115                        nil
 116                        nil
 117                        nil
 118                        uudecode-decoder-switches))
 119             (cd cdir) (set-buffer cbuf)))
 120         (if (file-exists-p tempfile)
 121             (unless file-name
 122               (goto-char start)
 123               (delete-region start end)
 124               (let (format-alist)
 125                 (insert-file-contents-literally tempfile)))
 126           (message "Can not uudecode")))
 127       (ignore-errors (or file-name (delete-file tempfile))))))
 128
 129 ;;;###autoload
 130 (defun uudecode-decode-region-internal (start end &optional file-name)
 131   "Uudecode region between START and END without using an external program.
 132 If FILE-NAME is non-nil, save the result to FILE-NAME."
 133   (interactive "r\nP")
 134   (let ((done nil)
 135         (counter 0)
 136         (remain 0)
 137         (bits 0)
 138         (lim 0) inputpos result
 139         (non-data-chars (concat "^" uudecode-alphabet)))
 140     (save-excursion
 141       (goto-char start)
 142       (when (re-search-forward uudecode-begin-line nil t)
 143         (cond ((null file-name))
 144               ((stringp file-name))
 145               (t
 146                (setq file-name (expand-file-name
 147                                 (read-file-name "File to Name:"
 148                                                 nil nil nil
 149                                                 (match-string 1))))))
 150         (forward-line 1)
 151         (skip-chars-forward non-data-chars end)
 152         (while (not done)
 153           (setq inputpos (point))
 154           (setq remain 0 bits 0 counter 0)
 155           (cond
 156            ((> (skip-chars-forward uudecode-alphabet end) 0)
 157             (setq lim (point))
 158             (setq remain
 159                   (logand (- (uudecode-char-int (char-after inputpos)) 32)
 160                           63))
 161             (setq inputpos (1+ inputpos))
 162             (if (= remain 0) (setq done t))
 163             (while (and (< inputpos lim) (> remain 0))
 164               (setq bits (+ bits
 165                             (logand
 166                              (-
 167                               (uudecode-char-int (char-after inputpos)) 32)
 168                              63)))
 169               (if (/= counter 0) (setq remain (1- remain)))
 170               (setq counter (1+ counter)
 171                     inputpos (1+ inputpos))
 172               (cond ((= counter 4)
 173                      (setq result (cons
 174                                    (concat
 175                                     (char-to-string (lsh bits -16))
 176                                     (char-to-string (logand (lsh bits -8) 255))
 177                                     (char-to-string (logand bits 255)))
 178                                    result))
 179                      (setq bits 0 counter 0))
 180                     (t (setq bits (lsh bits 6)))))))
 181           (cond
 182            (done)
 183            ((> 0 remain)
 184             (error "uucode line ends unexpectly")
 185             (setq done t))
 186            ((and (= (point) end) (not done))
 187             ;;(error "uucode ends unexpectly")
 188             (setq done t))
 189            ((= counter 3)
 190             (setq result (cons
 191                           (concat
 192                            (char-to-string (logand (lsh bits -16) 255))
 193                            (char-to-string (logand (lsh bits -8) 255)))
 194                           result)))
 195            ((= counter 2)
 196             (setq result (cons
 197                           (char-to-string (logand (lsh bits -10) 255))
 198                           result))))
 199           (skip-chars-forward non-data-chars end))
 200         (if file-name
 201             (let (default-enable-multibyte-characters)
 202               (with-temp-file file-name
 203                 (insert (apply 'concat (nreverse result)))))
 204           (or (markerp end) (setq end (set-marker (make-marker) end)))
 205           (goto-char start)
 206           (if enable-multibyte-characters
 207               (mapc #'(lambda (x) (insert (string-to-multibyte x)))
 208                     (nreverse result))
 209             (insert (apply 'concat (nreverse result))))
 210           (delete-region (point) end))))))
 211
 212 ;;;###autoload
 213 (defun uudecode-decode-region (start end &optional file-name)
 214   "Uudecode region between START and END.
 215 If FILE-NAME is non-nil, save the result to FILE-NAME."
 216   (if uudecode-use-external
 217       (uudecode-decode-region-external start end file-name)
 218     (uudecode-decode-region-internal start end file-name)))
 219
 220 (provide 'uudecode)
 221
 222 ;;; arch-tag: e1f09ed5-62b4-4677-9f13-4e81c4fe8ce3
 223 ;;; uudecode.el ends here