cgit.sxemacs.org Git - gnus/blob - lisp/time-date.el

   1 ;;; time-date.el --- Date and time handling functions
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2004, 2005
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu Umeda <umerin@mse.kyutech.ac.jp>
   7 ;; Keywords: mail news util
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Time values come in three formats.  The oldest format is a cons
  29 ;; cell of the form (HIGH . LOW).  This format is obsolete, but still
  30 ;; supported.  The two other formats are the lists (HIGH LOW) and
  31 ;; (HIGH LOW MICRO).  The first two formats specify HIGH * 2^16 + LOW
  32 ;; seconds; the third format specifies HIGH * 2^16 + LOW + MICRO /
  33 ;; 1000000 seconds.  We should have 0 <= MICRO < 1000000 and 0 <= LOW
  34 ;; < 2^16.  If the time value represents a point in time, then HIGH is
  35 ;; nonnegative.  If the time value is a time difference, then HIGH can
  36 ;; be negative as well.  The macro `with-decoded-time-value' and the
  37 ;; function `encode-time-value' make it easier to deal with these
  38 ;; three formats.  See `time-subtract' for an example of how to use
  39 ;; them.
  40
  41 ;;; Code:
  42
  43 (defmacro with-decoded-time-value (varlist &rest body)
  44   "Decode a time value and bind it according to VARLIST, then eval BODY.
  45
  46 The value of the last form in BODY is returned.
  47
  48 Each element of the list VARLIST is a list of the form
  49 \(HIGH-SYMBOL LOW-SYMBOL MICRO-SYMBOL [TYPE-SYMBOL] TIME-VALUE).
  50 The time value TIME-VALUE is decoded and the result it bound to
  51 the symbols HIGH-SYMBOL, LOW-SYMBOL and MICRO-SYMBOL.
  52
  53 The optional TYPE-SYMBOL is bound to the type of the time value.
  54 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH
  55 LOW), and type 3 is the list (HIGH LOW MICRO)."
  56   (declare (indent 1)
  57            (debug ((&rest (symbolp symbolp symbolp &or [symbolp form] form))
  58                    body)))
  59   (if varlist
  60       (let* ((elt (pop varlist))
  61              (high (pop elt))
  62              (low (pop elt))
  63              (micro (pop elt))
  64              (type (unless (eq (length elt) 1)
  65                      (pop elt)))
  66              (time-value (car elt))
  67              (gensym (make-symbol "time")))
  68         `(let* ,(append `((,gensym ,time-value)
  69                           (,high (pop ,gensym))
  70                           ,low ,micro)
  71                         (when type `(,type)))
  72            (if (consp ,gensym)
  73                (progn
  74                  (setq ,low (pop ,gensym))
  75                  (if ,gensym
  76                      ,(append `(setq ,micro (car ,gensym))
  77                               (when type `(,type 2)))
  78                    ,(append `(setq ,micro 0)
  79                             (when type `(,type 1)))))
  80              ,(append `(setq ,low ,gensym ,micro 0)
  81                       (when type `(,type 0))))
  82            (with-decoded-time-value ,varlist ,@body)))
  83     `(progn ,@body)))
  84
  85 (defun encode-time-value (high low micro type)
  86   "Encode HIGH, LOW, and MICRO into a time value of type TYPE.
  87 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH LOW),
  88 and type 3 is the list (HIGH LOW MICRO)."
  89   (cond
  90    ((eq type 0) (cons high low))
  91    ((eq type 1) (list high low))
  92    ((eq type 2) (list high low micro))))
  93
  94 (autoload 'parse-time-string "parse-time")
  95 (autoload 'timezone-make-date-arpa-standard "timezone")
  96
  97 ;;;###autoload
  98 (defun date-to-time (date)
  99   "Parse a string that represents a date-time and return a time value."
 100   (condition-case ()
 101       (apply 'encode-time
 102              (parse-time-string
 103               ;; `parse-time-string' isn't sufficiently general or
 104               ;; robust.  It fails to grok some of the formats that
 105               ;; timezone does (e.g. dodgy post-2000 stuff from some
 106               ;; Elms) and either fails or returns bogus values.  Lars
 107               ;; reverted this change, but that loses non-trivially
 108               ;; often for me.  -- fx
 109               (timezone-make-date-arpa-standard date)))
 110     (error (error "Invalid date: %s" date))))
 111
 112 (defun time-to-seconds (time)
 113   "Convert time value TIME to a floating point number.
 114 You can use `float-time' instead."
 115   (with-decoded-time-value ((high low micro time))
 116     (+ (* 1.0 high 65536)
 117        low
 118        (/ micro 1000000.0))))
 119
 120 ;;;###autoload
 121 (defun seconds-to-time (seconds)
 122   "Convert SECONDS (a floating point number) to a time value."
 123   (list (floor seconds 65536)
 124         (floor (mod seconds 65536))
 125         (floor (* (- seconds (ffloor seconds)) 1000000))))
 126
 127 ;;;###autoload
 128 (defun time-less-p (t1 t2)
 129   "Say whether time value T1 is less than time value T2."
 130   (with-decoded-time-value ((high1 low1 micro1 t1)
 131                             (high2 low2 micro2 t2))
 132     (or (< high1 high2)
 133         (and (= high1 high2)
 134              (or (< low1 low2)
 135                  (and (= low1 low2)
 136                       (< micro1 micro2)))))))
 137
 138 ;;;###autoload
 139 (defun days-to-time (days)
 140   "Convert DAYS into a time value."
 141   (let* ((seconds (* 1.0 days 60 60 24))
 142          (high (condition-case nil (floor (/ seconds 65536))
 143                  (range-error most-positive-fixnum))))
 144     (list high (condition-case nil (floor (- seconds (* 1.0 high 65536)))
 145                  (range-error 65535)))))
 146
 147 ;;;###autoload
 148 (defun time-since (time)
 149   "Return the time elapsed since TIME.
 150 TIME should be either a time value or a date-time string."
 151   (when (stringp time)
 152     ;; Convert date strings to internal time.
 153     (setq time (date-to-time time)))
 154   (time-subtract (current-time) time))
 155
 156 ;;;###autoload
 157 (defalias 'subtract-time 'time-subtract)
 158
 159 ;;;###autoload
 160 (defun time-subtract (t1 t2)
 161   "Subtract two time values.
 162 Return the difference in the format of a time value."
 163   (with-decoded-time-value ((high low micro type t1)
 164                             (high2 low2 micro2 type2 t2))
 165     (setq high (- high high2)
 166           low (- low low2)
 167           micro (- micro micro2)
 168           type (max type type2))
 169     (when (< micro 0)
 170       (setq low (1- low)
 171             micro (+ micro 1000000)))
 172     (when (< low 0)
 173       (setq high (1- high)
 174             low (+ low 65536)))
 175     (encode-time-value high low micro type)))
 176
 177 ;;;###autoload
 178 (defun time-add (t1 t2)
 179   "Add two time values.  One should represent a time difference."
 180   (with-decoded-time-value ((high low micro type t1)
 181                             (high2 low2 micro2 type2 t2))
 182     (setq high (+ high high2)
 183           low (+ low low2)
 184           micro (+ micro micro2)
 185           type (max type type2))
 186     (when (>= micro 1000000)
 187       (setq low (1+ low)
 188             micro (- micro 1000000)))
 189     (when (>= low 65536)
 190       (setq high (1+ high)
 191             low (- low 65536)))
 192     (encode-time-value high low micro type)))
 193
 194 ;;;###autoload
 195 (defun date-to-day (date)
 196   "Return the number of days between year 1 and DATE.
 197 DATE should be a date-time string."
 198   (time-to-days (date-to-time date)))
 199
 200 ;;;###autoload
 201 (defun days-between (date1 date2)
 202   "Return the number of days between DATE1 and DATE2.
 203 DATE1 and DATE2 should be date-time strings."
 204   (- (date-to-day date1) (date-to-day date2)))
 205
 206 ;;;###autoload
 207 (defun date-leap-year-p (year)
 208   "Return t if YEAR is a leap year."
 209   (or (and (zerop (% year 4))
 210            (not (zerop (% year 100))))
 211       (zerop (% year 400))))
 212
 213 ;;;###autoload
 214 (defun time-to-day-in-year (time)
 215   "Return the day number within the year of the date month/day/year."
 216   (let* ((tim (decode-time time))
 217          (month (nth 4 tim))
 218          (day (nth 3 tim))
 219          (year (nth 5 tim))
 220          (day-of-year (+ day (* 31 (1- month)))))
 221     (when (> month 2)
 222       (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 223       (when (date-leap-year-p year)
 224         (setq day-of-year (1+ day-of-year))))
 225     day-of-year))
 226
 227 ;;;###autoload
 228 (defun time-to-days (time)
 229   "The number of days between the Gregorian date 0001-12-31bce and TIME.
 230 TIME should be a time value.
 231 The Gregorian date Sunday, December 31, 1bce is imaginary."
 232   (let* ((tim (decode-time time))
 233          (month (nth 4 tim))
 234          (day (nth 3 tim))
 235          (year (nth 5 tim)))
 236     (+ (time-to-day-in-year time)       ;       Days this year
 237        (* 365 (1- year))                ;       + Days in prior years
 238        (/ (1- year) 4)                  ;       + Julian leap years
 239        (- (/ (1- year) 100))            ;       - century years
 240        (/ (1- year) 400))))             ;       + Gregorian leap years
 241
 242 (defun time-to-number-of-days (time)
 243   "Return the number of days represented by TIME.
 244 The number of days will be returned as a floating point number."
 245   (/ (time-to-seconds time) (* 60 60 24)))
 246
 247 ;;;###autoload
 248 (defun safe-date-to-time (date)
 249   "Parse a string that represents a date-time and return a time value.
 250 If DATE is malformed, return a time value of zeros."
 251   (condition-case ()
 252       (date-to-time date)
 253     (error '(0 0))))
 254
 255 (provide 'time-date)
 256
 257 ;;; arch-tag: addcf07b-b20a-465b-af72-550b8ac5190f
 258 ;;; time-date.el ends here