cgit.sxemacs.org Git - gnus/blob - lisp/spam-stat.el

   1 ;;; spam-stat.el --- detecting spam based on statistics
   2
   3 ;; Copyright (C) 2002  Free Software Foundation, Inc.
   4
   5 ;; Author: Alex Schroeder <alex@gnu.org>
   6 ;; Keywords: network
   7 ;; URL: http://www.emacswiki.org/cgi-bin/wiki.pl?SpamStat
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; This is free software; you can redistribute it and/or modify it
  12 ;; under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; This is distributed in the hope that it will be useful, but WITHOUT
  17 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  18 ;; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public
  19 ;; License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This implements spam analysis according to Paul Graham in "A Plan
  29 ;; for Spam".  The basis for all this is a statistical distribution of
  30 ;; words for your spam and non-spam mails.  We need this information
  31 ;; in a hash-table so that the analysis can use the information when
  32 ;; looking at your mails.  Therefore, before you begin, you need tons
  33 ;; of mails (Graham uses 4000 non-spam and 4000 spam mails for his
  34 ;; experiments).
  35 ;;
  36 ;; The main interface to using spam-stat, are the following functions:
  37 ;;
  38 ;; `spam-stat-buffer-is-spam' -- called in a buffer, that buffer is
  39 ;; considered to be a new spam mail; use this for new mail that has
  40 ;; not been processed before
  41 ;;
  42 ;; `spam-stat-buffer-is-non-spam' -- called in a buffer, that buffer
  43 ;; is considered to be a new non-spam mail; use this for new mail that
  44 ;; has not been processed before
  45 ;;
  46 ;; `spam-stat-buffer-change-to-spam' -- called in a buffer, that
  47 ;; buffer is no longer considered to be normal mail but spam; use this
  48 ;; to change the status of a mail that has already been processed as
  49 ;; non-spam
  50 ;;
  51 ;; `spam-stat-buffer-change-to-non-spam' -- called in a buffer, that
  52 ;; buffer is no longer considered to be spam but normal mail; use this
  53 ;; to change the status of a mail that has already been processed as
  54 ;; spam
  55 ;;
  56 ;; `spam-stat-save' -- save the hash table to the file; the filename
  57 ;; used is stored in the variable `spam-stat-file'
  58 ;;
  59 ;; `spam-stat-load' -- load the hash table from a file; the filename
  60 ;; used is stored in the variable `spam-stat-file'
  61 ;;
  62 ;; `spam-stat-score-word' -- return the spam score for a word
  63 ;;
  64 ;; `spam-stat-score-buffer' -- return the spam score for a buffer
  65 ;;
  66 ;; `spam-stat-split-fancy' -- for fancy mail splitting; add
  67 ;; the rule (: spam-stat-split-fancy) to `nnmail-split-fancy'
  68 ;;
  69 ;; This requires the following in your ~/.gnus file:
  70 ;;
  71 ;; (require 'spam-stat)
  72 ;; (spam-stat-load)
  73
  74 ;;; Testing:
  75
  76 ;; Typical test will involve calls to the following functions:
  77 ;;
  78 ;; Reset: (spam-stat-reset)
  79 ;; Learn spam: (spam-stat-process-spam-directory "~/Mail/mail/spam")
  80 ;; Learn non-spam: (spam-stat-process-non-spam-directory "~/Mail/mail/misc")
  81 ;; Save table: (spam-stat-save)
  82 ;; File size: (nth 7 (file-attributes spam-stat-file))
  83 ;; Number of words: (hash-table-count spam-stat)
  84 ;; Test spam: (spam-stat-test-directory "~/Mail/mail/spam")
  85 ;; Test non-spam: (spam-stat-test-directory "~/Mail/mail/misc")
  86 ;; Reduce table size: (spam-stat-reduce-size)
  87 ;; Save table: (spam-stat-save)
  88 ;; File size: (nth 7 (file-attributes spam-stat-file))
  89 ;; Number of words: (hash-table-count spam-stat)
  90 ;; Test spam: (spam-stat-test-directory "~/Mail/mail/spam")
  91 ;; Test non-spam: (spam-stat-test-directory "~/Mail/mail/misc")
  92
  93 ;;; Dictionary Creation:
  94
  95 ;; Typically, you will filter away mailing lists etc. using specific
  96 ;; rules in `nnmail-split-fancy'.  Somewhere among these rules, you
  97 ;; will filter spam.  Here is how you would create your dictionary:
  98
  99 ;; Reset: (spam-stat-reset)
 100 ;; Learn spam: (spam-stat-process-spam-directory "~/Mail/mail/spam")
 101 ;; Learn non-spam: (spam-stat-process-non-spam-directory "~/Mail/mail/misc")
 102 ;; Repeat for any other non-spam group you need...
 103 ;; Reduce table size: (spam-stat-reduce-size)
 104 ;; Save table: (spam-stat-save)
 105
 106 ;;; Todo:
 107
 108 ;; Speed it up.  Integrate with Gnus such that it uses spam and expiry
 109 ;; marks to call the appropriate functions when leaving the summary
 110 ;; buffer and saves the hash table when leaving Gnus.  More testing:
 111 ;; More mails, disabling SpamAssassin, double checking algorithm, find
 112 ;; improved algorithm.
 113
 114 ;;; Thanks:
 115
 116 ;; Ted Zlatanov <tzz@lifelogs.com>
 117 ;; Jesper Harder <harder@myrealbox.com>
 118 ;; Dan Schmidt <dfan@dfan.org>
 119 ;; Lasse Rasinen <lrasinen@iki.fi>
 120 ;; Milan Zamazal <pdm@zamazal.org>
 121
 122 \f
 123
 124 ;;; Code:
 125
 126 (defgroup spam-stat nil
 127   "Statistical spam detection for Emacs.
 128 Use the functions to build a dictionary of words and their statistical
 129 distribution in spam and non-spam mails.  Then use a function to determine
 130 wether a buffer contains spam or not."
 131   :group 'gnus)
 132
 133 (defcustom spam-stat-file "~/.spam-stat.el"
 134   "File used to save and load the dictionary.
 135 See `spam-stat-to-hash-table' for the format of the file."
 136   :type 'file
 137   :group 'spam-stat)
 138
 139 (defcustom spam-stat-unknown-word-score 0.2
 140   "The score to use for unknown words.
 141 Also used for words that don't appear often enough."
 142   :type 'number
 143   :group 'spam-stat)
 144
 145 (defcustom spam-stat-max-word-length 15
 146   "Only words shorter than this will be considered."
 147   :type 'integer
 148   :group 'spam-stat)
 149
 150 (defcustom spam-stat-max-buffer-length 10240
 151   "Only the beginning of buffers will be analyzed.
 152 This variable says how many characters this will be."
 153   :type 'integer
 154   :group 'spam-stat)
 155
 156 (defcustom spam-stat-split-fancy-spam-group "mail.spam"
 157   "Name of the group where spam should be stored, if
 158 `spam-stat-split-fancy' is used in fancy splitting rules."
 159   :type 'string
 160   :group 'spam-stat)
 161
 162 (defvar spam-stat-syntax-table
 163   (let ((table (copy-syntax-table text-mode-syntax-table)))
 164     (modify-syntax-entry ?- "w" table)
 165     (modify-syntax-entry ?_ "w" table)
 166     (modify-syntax-entry ?. "w" table)
 167     (modify-syntax-entry ?! "w" table)
 168     (modify-syntax-entry ?? "w" table)
 169     (modify-syntax-entry ?+ "w" table)
 170     table)
 171   "Syntax table used when processing mails for statistical analysis.
 172 The important part is which characters are word constituents.")
 173
 174 (defvar spam-stat-buffer nil
 175   "Buffer to use for scoring while splitting.
 176 This is set by hooking into Gnus.")
 177
 178 (defvar spam-stat-buffer-name " *spam stat buffer*"
 179   "Name of the `spam-stat-buffer'.")
 180
 181 ;; Functions missing in Emacs 20
 182
 183 (when (memq nil (mapcar 'fboundp
 184                         '(gethash hash-table-count make-hash-table
 185                                   mapc puthash)))
 186   (require 'cl)
 187   (unless (fboundp 'puthash)
 188     ;; alias puthash is missing from Emacs 20 cl-extra.el
 189     (defalias 'puthash 'cl-puthash)))
 190
 191 (eval-when-compile
 192   (unless (fboundp 'with-syntax-table)
 193     ;; Imported from Emacs 21.2
 194     (defmacro with-syntax-table (table &rest body) "\
 195 Evaluate BODY with syntax table of current buffer set to a copy of TABLE.
 196 The syntax table of the current buffer is saved, BODY is evaluated, and the
 197 saved table is restored, even in case of an abnormal exit.
 198 Value is what BODY returns."
 199       (let ((old-table (make-symbol "table"))
 200             (old-buffer (make-symbol "buffer")))
 201         `(let ((,old-table (syntax-table))
 202                (,old-buffer (current-buffer)))
 203            (unwind-protect
 204                (progn
 205                  (set-syntax-table (copy-syntax-table ,table))
 206                  ,@body)
 207              (save-current-buffer
 208                (set-buffer ,old-buffer)
 209                (set-syntax-table ,old-table))))))))
 210
 211 ;; Hooking into Gnus
 212
 213 (defun spam-stat-store-current-buffer ()
 214   "Store a copy of the current buffer in `spam-stat-buffer'."
 215   (save-excursion
 216     (let ((str (buffer-string)))
 217       (set-buffer (get-buffer-create spam-stat-buffer-name))
 218       (erase-buffer)
 219       (insert str)
 220       (setq spam-stat-buffer (current-buffer)))))
 221
 222 (defun spam-stat-store-gnus-article-buffer ()
 223   "Store a copy of the current article in `spam-stat-buffer'.
 224 This uses `gnus-article-buffer'."
 225   (save-excursion
 226     (set-buffer gnus-original-article-buffer)
 227     (spam-stat-store-current-buffer)))
 228
 229 (add-hook 'nnmail-prepare-incoming-message-hook
 230           'spam-stat-store-current-buffer)
 231 (add-hook 'gnus-select-article-hook
 232           'spam-stat-store-gnus-article-buffer)
 233
 234 ;; Data -- not using defstruct in order to save space and time
 235
 236 (defvar spam-stat (make-hash-table :test 'equal)
 237   "Hash table used to store the statistics.
 238 Use `spam-stat-load' to load the file.
 239 Every word is used as a key in this table.  The value is a vector.
 240 Use `spam-stat-ngood', `spam-stat-nbad', `spam-stat-good',
 241 `spam-stat-bad', and `spam-stat-score' to access this vector.")
 242
 243 (defvar spam-stat-ngood 0
 244   "The number of good mails in the dictionary.")
 245
 246 (defvar spam-stat-nbad 0
 247   "The number of bad mails in the dictionary.")
 248
 249 (defsubst spam-stat-good (entry)
 250   "Return the number of times this word belongs to good mails."
 251   (aref entry 0))
 252
 253 (defsubst spam-stat-bad (entry)
 254   "Return the number of times this word belongs to bad mails."
 255   (aref entry 1))
 256
 257 (defsubst spam-stat-score (entry)
 258   "Set the score of this word."
 259   (if entry
 260       (aref entry 2)
 261     spam-stat-unknown-word-score))
 262
 263 (defsubst spam-stat-set-good (entry value)
 264   "Set the number of times this word belongs to good mails."
 265   (aset entry 0 value))
 266
 267 (defsubst spam-stat-set-bad (entry value)
 268   "Set the number of times this word belongs to bad mails."
 269   (aset entry 1 value))
 270
 271 (defsubst spam-stat-set-score (entry value)
 272   "Set the score of this word."
 273   (aset entry 2 value))
 274
 275 (defsubst spam-stat-make-entry (good bad)
 276   "Return a vector with the given properties."
 277   (let ((entry (vector good bad nil)))
 278     (spam-stat-set-score entry (spam-stat-compute-score entry))
 279     entry))
 280
 281 ;; Computing
 282
 283 (defun spam-stat-compute-score (entry)
 284   "Compute the score of this word.  1.0 means spam."
 285    ;; promote all numbers to floats for the divisions
 286    (let* ((g (* 2.0 (spam-stat-good entry)))
 287           (b (float (spam-stat-bad entry))))
 288      (cond ((< (+ g b) 5)
 289             .2)
 290            ((= 0 spam-stat-ngood)
 291             .99)
 292            ((= 0 spam-stat-nbad)
 293             .01)
 294            (t
 295             (max .01
 296                  (min .99 (/ (/ b spam-stat-nbad)
 297                              (+ (/ g spam-stat-ngood)
 298                                 (/ b spam-stat-nbad)))))))))
 299
 300 ;; Parsing
 301
 302 (defmacro with-spam-stat-max-buffer-size (&rest body)
 303   "Narrows the buffer down to the first 4k characters, then evaluates BODY."
 304   `(save-restriction
 305      (when (> (- (point-max)
 306                  (point-min))
 307               spam-stat-max-buffer-length)
 308        (narrow-to-region (point-min)
 309                          (+ (point-min) spam-stat-max-buffer-length)))
 310      ,@body))
 311
 312 (defun spam-stat-buffer-words ()
 313   "Return a hash table of words and number of occurences in the buffer."
 314   (with-spam-stat-max-buffer-size
 315    (with-syntax-table spam-stat-syntax-table
 316      (goto-char (point-min))
 317      (let ((result (make-hash-table :test 'equal))
 318            word count)
 319        (while (re-search-forward "\\w+" nil t)
 320          (setq word (match-string-no-properties 0)
 321                count (1+ (gethash word result 0)))
 322          (when (< (length word) spam-stat-max-word-length)
 323            (puthash word count result)))
 324        result))))
 325
 326 (defun spam-stat-buffer-is-spam ()
 327   "Consider current buffer to be a new spam mail."
 328   (setq spam-stat-nbad (1+ spam-stat-nbad))
 329   (maphash
 330    (lambda (word count)
 331      (let ((entry (gethash word spam-stat)))
 332        (if entry
 333            (spam-stat-set-bad entry (+ count (spam-stat-bad entry)))
 334          (setq entry (spam-stat-make-entry 0 count)))
 335        (spam-stat-set-score entry (spam-stat-compute-score entry))
 336        (puthash word entry spam-stat)))
 337    (spam-stat-buffer-words)))
 338
 339 (defun spam-stat-buffer-is-non-spam ()
 340   "Consider current buffer to be a new non-spam mail."
 341   (setq spam-stat-ngood (1+ spam-stat-ngood))
 342   (maphash
 343    (lambda (word count)
 344      (let ((entry (gethash word spam-stat)))
 345        (if entry
 346            (spam-stat-set-good entry (+ count (spam-stat-good entry)))
 347          (setq entry (spam-stat-make-entry count 0)))
 348        (spam-stat-set-score entry (spam-stat-compute-score entry))
 349        (puthash word entry spam-stat)))
 350    (spam-stat-buffer-words)))
 351
 352 (defun spam-stat-buffer-change-to-spam ()
 353   "Consider current buffer no longer normal mail but spam."
 354   (setq spam-stat-nbad (1+ spam-stat-nbad)
 355         spam-stat-ngood (1- spam-stat-ngood))
 356   (maphash
 357    (lambda (word count)
 358      (let ((entry (gethash word spam-stat)))
 359        (if (not entry)
 360            (error "This buffer has unknown words in it.")
 361          (spam-stat-set-good entry (- (spam-stat-good entry) count))
 362          (spam-stat-set-bad entry (+ (spam-stat-bad entry) count))
 363          (spam-stat-set-score entry (spam-stat-compute-score entry))
 364          (puthash word entry spam-stat))))
 365    (spam-stat-buffer-words)))
 366
 367 (defun spam-stat-buffer-change-to-non-spam ()
 368   "Consider current buffer no longer spam but normal mail."
 369   (setq spam-stat-nbad (1- spam-stat-nbad)
 370         spam-stat-ngood (1+ spam-stat-ngood))
 371   (maphash
 372    (lambda (word count)
 373      (let ((entry (gethash word spam-stat)))
 374        (if (not entry)
 375            (error "This buffer has unknown words in it.")
 376          (spam-stat-set-good entry (+ (spam-stat-good entry) count))
 377          (spam-stat-set-bad entry (- (spam-stat-bad entry) count))
 378          (spam-stat-set-score entry (spam-stat-compute-score entry))
 379          (puthash word entry spam-stat))))
 380    (spam-stat-buffer-words)))
 381
 382 ;; Saving and Loading
 383
 384 (defun spam-stat-save ()
 385   "Save the `spam-stat' hash table as lisp file."
 386   (interactive)
 387   (with-temp-buffer
 388     (let ((standard-output (current-buffer)))
 389       (insert "(setq spam-stat-ngood "
 390               (number-to-string spam-stat-ngood)
 391               " spam-stat-nbad "
 392               (number-to-string spam-stat-nbad)
 393               " spam-stat (spam-stat-to-hash-table '(")
 394       (maphash (lambda (word entry)
 395                  (prin1 (list word
 396                               (spam-stat-good entry)
 397                               (spam-stat-bad entry))))
 398                spam-stat)
 399       (insert ")))"))
 400     (write-file spam-stat-file)))
 401
 402 (defun spam-stat-load ()
 403   "Read the `spam-stat' hash table from disk."
 404   (load-file spam-stat-file))
 405
 406 (defun spam-stat-to-hash-table (entries)
 407   "Turn list ENTRIES into a hash table and store as `spam-stat'.
 408 Every element in ENTRIES has the form \(WORD GOOD BAD) where WORD is
 409 the word string, NGOOD is the number of good mails it has appeared in,
 410 NBAD is the number of bad mails it has appeared in, GOOD is the number
 411 of times it appeared in good mails, and BAD is the number of times it
 412 has appeared in bad mails."
 413   (let ((table (make-hash-table :test 'equal)))
 414     (mapc (lambda (l)
 415             (puthash (car l)
 416                      (spam-stat-make-entry (nth 1 l) (nth 2 l))
 417                      table))
 418           entries)
 419     table))
 420
 421 (defun spam-stat-reset ()
 422   "Reset `spam-stat' to an empty hash-table.
 423 This deletes all the statistics."
 424   (interactive)
 425   (setq spam-stat (make-hash-table :test 'equal)
 426         spam-stat-ngood 0
 427         spam-stat-nbad 0))
 428
 429 ;; Scoring buffers
 430
 431 (defvar spam-stat-score-data nil
 432   "Raw data used in the last run of `spam-stat-score-buffer'.")
 433
 434 (defsubst spam-stat-score-word (word)
 435   "Return score for WORD.
 436 The default score for unknown words is stored in
 437 `spam-stat-unknown-word-score'."
 438   (spam-stat-score (gethash word spam-stat)))
 439
 440 (defun spam-stat-buffer-words-with-scores ()
 441   "Process current buffer, return the 15 most conspicuous words.
 442 These are the words whose spam-stat differs the most from 0.5.
 443 The list returned contains elements of the form \(WORD SCORE DIFF),
 444 where DIFF is the difference between SCORE and 0.5."
 445   (with-spam-stat-max-buffer-size
 446    (with-syntax-table spam-stat-syntax-table
 447      (let (result word score)
 448        (maphash (lambda (word ignore)
 449                   (setq score (spam-stat-score-word word)
 450                         result (cons (list word score (abs (- score 0.5)))
 451                                      result)))
 452                 (spam-stat-buffer-words))
 453        (setq result (sort result (lambda (a b) (< (nth 2 b) (nth 2 a)))))
 454        (setcdr (nthcdr 14 result) nil)
 455        result))))
 456
 457 (defun spam-stat-score-buffer ()
 458   "Return a score describing the spam-probability for this buffer."
 459   (setq spam-stat-score-data (spam-stat-buffer-words-with-scores))
 460   (let* ((probs (mapcar (lambda (e) (cadr e)) spam-stat-score-data))
 461          (prod (apply #'* probs)))
 462     (/ prod (+ prod (apply #'* (mapcar #'(lambda (x) (- 1 x))
 463                                        probs))))))
 464
 465 (defun spam-stat-split-fancy ()
 466   "Return the name of the spam group if the current mail is spam.
 467 Use this function on `nnmail-split-fancy'.  If you are interested in
 468 the raw data used for the last run of `spam-stat-score-buffer',
 469 check the variable `spam-stat-score-data'."
 470   (condition-case var
 471       (progn
 472         (set-buffer spam-stat-buffer)
 473         (goto-char (point-min))
 474         (when (> (spam-stat-score-buffer) 0.9)
 475           (when (boundp 'nnmail-split-trace)
 476             (mapc (lambda (entry)
 477                     (push entry nnmail-split-trace))
 478                   spam-stat-score-data))
 479           spam-stat-split-fancy-spam-group))
 480     (error (message "Error in spam-stat-split-fancy: %S" var)
 481            nil)))
 482
 483 ;; Testing
 484
 485 (defun spam-stat-process-directory (dir func)
 486   "Process all the regular files in directory DIR using function FUNC."
 487   (let* ((files (directory-files dir t "^[^.]"))
 488          (max (/ (length files) 100.0))
 489          (count 0))
 490     (with-temp-buffer
 491       (dolist (f files)
 492         (when (and (file-readable-p f)
 493                    (file-regular-p f))
 494           (setq count (1+ count))
 495           (message "Reading %s: %.2f%%" dir (/ count max))
 496           (insert-file-contents f)
 497           (funcall func)
 498           (erase-buffer))))))
 499
 500 (defun spam-stat-process-spam-directory (dir)
 501   "Process all the regular files in directory DIR as spam."
 502   (interactive "D")
 503   (spam-stat-process-directory dir 'spam-stat-buffer-is-spam))
 504
 505 (defun spam-stat-process-non-spam-directory (dir)
 506   "Process all the regular files in directory DIR as non-spam."
 507   (interactive "D")
 508   (spam-stat-process-directory dir 'spam-stat-buffer-is-non-spam))
 509
 510 (defun spam-stat-count ()
 511   "Return size of `spam-stat'."
 512   (interactive)
 513   (hash-table-count spam-stat))
 514
 515 (defun spam-stat-test-directory (dir)
 516   "Test all the regular files in directory DIR for spam.
 517 If the result is 1.0, then all files are considered spam.
 518 If the result is 0.0, non of the files is considered spam.
 519 You can use this to determine error rates."
 520   (interactive "D")
 521   (let* ((files (directory-files dir t "^[^.]"))
 522          (total (length files))
 523          (score 0.0); float
 524          (max (/ total 100.0)); float
 525          (count 0))
 526     (with-temp-buffer
 527       (dolist (f files)
 528         (when (and (file-readable-p f)
 529                    (file-regular-p f))
 530           (setq count (1+ count))
 531           (message "Reading %.2f%%, score %.2f%%"
 532                    (/ count max) (/ score count))
 533           (insert-file-contents f)
 534           (when (> (spam-stat-score-buffer) 0.9)
 535             (setq score (1+ score)))
 536           (erase-buffer))))
 537     (message "Final score: %d / %d = %f" score total (/ score total))))
 538
 539 ;; Shrinking the dictionary
 540
 541 (defun spam-stat-reduce-size (&optional count)
 542   "Reduce the size of `spam-stat'.
 543 This removes all words that occur less than COUNT from the dictionary.
 544 COUNT defaults to 5"
 545   (interactive)
 546   (setq count (or count 5))
 547   (maphash (lambda (key entry)
 548              (when (< (+ (spam-stat-good entry)
 549                          (spam-stat-bad entry))
 550                       count)
 551                (remhash key spam-stat)))
 552            spam-stat))
 553
 554 (provide 'spam-stat)
 555
 556 ;;; spam-stat.el ends here