cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2 ;; Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
   3
   4 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; Code:
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33
  34 (eval-and-compile
  35   (autoload 'mm-url-insert "mm-url"))
  36
  37 (defgroup spam-report nil
  38   "Spam reporting configuration.")
  39
  40 (defcustom spam-report-gmane-regex nil
  41   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  42 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  43 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  44 instead."
  45   :type '(radio (const nil)
  46                 (regexp :format "%t: %v\n" :size 0 :value "^nntp\+.*:gmane\."))
  47   :group 'spam-report)
  48
  49 (defcustom spam-report-gmane-spam-header
  50   "^X-Report-Spam: http://\\([^/]+\\)\\(.*\\)$"
  51   "String matching Gmane spam-reporting header.  Two match groups are needed."
  52   :type 'regexp
  53   :group 'spam-report)
  54
  55 (defcustom spam-report-gmane-use-article-number t
  56   "Whether the article number (faster!) or the header should be used."
  57   :type 'boolean
  58   :group 'spam-report)
  59
  60 (defcustom spam-report-url-ping-function
  61   'spam-report-url-ping-plain
  62   "Function to use for url ping spam reporting.
  63 The function must accept the arguments `host' and `report'."
  64   :type '(choice
  65           (const :tag "Connect directly"
  66                  spam-report-url-ping-plain)
  67           (const :tag "Use the external program specified in `mm-url-program'"
  68                  spam-report-url-ping-mm-url)
  69           (const :tag "Store request URLs in `spam-report-requests-file'"
  70                  spam-report-url-to-file)
  71           (function :tag "User defined function" nil))
  72   :group 'spam-report)
  73
  74 (defcustom spam-report-requests-file
  75   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  76   ;; Is there a convention for the extension of such a file?
  77   ;; Should we use `spam-directory'?
  78   "File where spam report request are stored."
  79   :type 'file
  80   :group 'spam-report)
  81
  82 (defvar spam-report-url-ping-temp-agent-function nil
  83   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  84 This variable will store the value of `spam-report-url-ping-function' from
  85 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  86 undo that change.")
  87
  88 (defun spam-report-gmane (&rest articles)
  89   "Report an article as spam through Gmane"
  90   (dolist (article articles)
  91     (when (and gnus-newsgroup-name
  92                (or (null spam-report-gmane-regex)
  93                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
  94       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
  95       (if spam-report-gmane-use-article-number
  96           (spam-report-url-ping "spam.gmane.org"
  97                                 (format "/%s:%d"
  98                                         (gnus-group-real-name gnus-newsgroup-name)
  99                                         article))
 100         (with-current-buffer nntp-server-buffer
 101           (gnus-request-head article gnus-newsgroup-name)
 102           (goto-char (point-min))
 103           (if (re-search-forward spam-report-gmane-spam-header nil t)
 104               (let* ((host (match-string 1))
 105                      (report (match-string 2))
 106                      (url (format "http://%s%s" host report)))
 107                 (gnus-message 7 "Reporting spam through URL %s..." url)
 108                 (spam-report-url-ping host report))
 109             (gnus-message 3 "Could not find X-Report-Spam in article %d..."
 110                           article)))))))
 111
 112 (defun spam-report-url-ping (host report)
 113   "Ping a host through HTTP, addressing a specific GET resource using
 114 the function specified by `spam-report-url-ping-function'."
 115   (funcall spam-report-url-ping-function host report))
 116
 117 (defun spam-report-url-ping-plain (host report)
 118   "Ping a host through HTTP, addressing a specific GET resource."
 119   (let ((tcp-connection))
 120     (with-temp-buffer
 121       (or (setq tcp-connection
 122                 (open-network-stream
 123                  "URL ping"
 124                  (buffer-name)
 125                  host
 126                  80))
 127           (error "Could not open connection to %s" host))
 128       (set-marker (process-mark tcp-connection) (point-min))
 129       (process-send-string
 130        tcp-connection
 131        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 132                report (gnus-emacs-version) host)))))
 133
 134 ;;;###autoload
 135 (defun spam-report-process-queue (&optional file keep)
 136   "Report all queued requests from `spam-report-requests-file'.
 137
 138 If FILE is given, use it instead of `spam-report-requests-file'.
 139 If KEEP is t, leave old requests in the file.  If KEEP is the
 140 symbol `ask', query before flushing the queue file."
 141   (interactive
 142    (list (read-file-name
 143           "File: "
 144           (file-name-directory spam-report-requests-file)
 145           spam-report-requests-file
 146           nil
 147           (file-name-nondirectory spam-report-requests-file))
 148          current-prefix-arg))
 149   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 150       (error (concat "Cannot process requests when "
 151                      "`spam-report-url-ping-function' is "
 152                      "`spam-report-url-to-file'."))
 153     (gnus-message 7 "Processing requests using `%s'."
 154                   spam-report-url-ping-function))
 155   (or file (setq file spam-report-requests-file))
 156   (save-excursion
 157     (set-buffer (find-file-noselect file))
 158     (goto-char (point-min))
 159     (while (and (not (eobp))
 160                 (re-search-forward
 161                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 162       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 163       (forward-line 1))
 164     (if (or (eq keep nil)
 165             (and (eq keep 'ask)
 166                  (y-or-n-p
 167                   (format
 168                    "Flush requests from `%s'? " (current-buffer)))))
 169         (progn
 170           (gnus-message 7 "Flushing request file `%s'"
 171                         spam-report-requests-file)
 172           (erase-buffer)
 173           (save-buffer)
 174           (kill-buffer (current-buffer)))
 175       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 176
 177 ;;;###autoload
 178 (defun spam-report-url-ping-mm-url (host report)
 179   "Ping a host through HTTP, addressing a specific GET resource. Use
 180 the external program specified in `mm-url-program' to connect to
 181 server."
 182   (with-temp-buffer
 183     (let ((url (concat "http://" host report)))
 184       (mm-url-insert url t))))
 185
 186 ;;;###autoload
 187 (defun spam-report-url-to-file (host report)
 188   "Collect spam report requests in `spam-report-requests-file'.
 189 Customize `spam-report-url-ping-function' to use this function."
 190   (let ((url (concat "http://" host report))
 191         (file spam-report-requests-file))
 192     (gnus-make-directory (file-name-directory file))
 193     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 194     (with-temp-buffer
 195       (insert url)
 196       (newline)
 197       (append-to-file (point-min) (point-max) file))))
 198
 199 ;;;###autoload
 200 (defun spam-report-agentize ()
 201   "Add spam-report support to the Agent.
 202 Spam reports will be queued with \\[spam-report-url-to-file] when
 203 the Agent is unplugged, and will be submitted in a batch when the
 204 Agent is plugged."
 205   (interactive)
 206   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 207   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 208
 209 ;;;###autoload
 210 (defun spam-report-deagentize ()
 211   "Remove spam-report support from the Agent.
 212 Spam reports will be queued with the method used when
 213 \\[spam-report-agentize] was run."
 214   (interactive)
 215   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 216   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 217
 218 (defun spam-report-plug-agent ()
 219   "Adjust spam report settings for plugged state.
 220 Process queued spam reports."
 221   ;; Process the queue, unless the user only wanted to report to a file
 222   ;; anyway.
 223   (unless (equal spam-report-url-ping-temp-agent-function
 224                  'spam-report-url-to-file)
 225     (spam-report-process-queue))
 226   ;; Set the reporting function, if we have memorized something otherwise,
 227   ;; stick with plain URL reporting.
 228   (setq spam-report-url-ping-function
 229         (or spam-report-url-ping-temp-agent-function
 230             'spam-report-url-ping-plain)))
 231
 232 (defun spam-report-unplug-agent ()
 233   "Restore spam report settings for unplugged state."
 234   ;; save the old value
 235   (setq spam-report-url-ping-temp-agent-function
 236         spam-report-url-ping-function)
 237   ;; store all reports to file
 238   (setq spam-report-url-ping-function
 239         'spam-report-url-to-file))
 240
 241 (provide 'spam-report)
 242
 243 ;;; spam-report.el ends here.