cgit.sxemacs.org Git - gnus/blob - lisp/smime.el

   1 ;;; smime.el --- S/MIME support library
   2 ;; Copyright (c) 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <simon@josefsson.org>
   5 ;; Keywords: SMIME X.509 PEM OpenSSL
   6
   7 ;; This file is not a part of GNU Emacs, but the same permissions apply.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published
  11 ;; by the Free Software Foundation; either version 2, or (at your
  12 ;; option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This library perform S/MIME operations from within Emacs.
  27 ;;
  28 ;; Functions for fetching certificates from public repositories are
  29 ;; provided, currently only from DNS.  LDAP support (via EUDC) is planned.
  30 ;;
  31 ;; It uses OpenSSL (tested with version 0.9.5a and 0.9.6) for signing,
  32 ;; encryption and decryption.
  33 ;;
  34 ;; Some general knowledge of S/MIME, X.509, PKCS#12, PEM etc is
  35 ;; probably required to use this library in any useful way.
  36 ;; Especially, don't expect this library to buy security for you.  If
  37 ;; you don't understand what you are doing, you're as likely to lose
  38 ;; security than gain any by using this library.
  39 ;;
  40 ;; This library is not intended to provide a "raw" API for S/MIME,
  41 ;; PKCSx or similar, it's intended to perform common operations
  42 ;; done on messages encoded in these formats.  The terminology chosen
  43 ;; reflect this.
  44
  45 ;;; Quick introduction:
  46
  47 ;; Get your S/MIME certificate from VeriSign or someplace.  I used
  48 ;; Netscape to generate the key and certificate request and stuff, and
  49 ;; Netscape can export the key into PKCS#12 format.
  50 ;;
  51 ;; Enter OpenSSL.  To be able to use this library, it need to have the
  52 ;; SMIME key readable in PEM format.  OpenSSL is used to convert the
  53 ;; key:
  54 ;;
  55 ;; $ openssl pkcs12 -in mykey.p12 -clcerts -nodes > mykey.pem
  56 ;; ...
  57 ;;
  58 ;; Now, use M-x customize-variable smime-keys and add mykey.pem as
  59 ;; a key.
  60 ;;
  61 ;; Now you should be able to sign messages!  Create a buffer and write
  62 ;; something and run M-x smime-sign-buffer RET RET and you should see
  63 ;; your message MIME armoured and a signature.  Encryption, M-x
  64 ;; smime-encrypt-buffer, should also work.
  65 ;;
  66 ;; To be able to verify messages you need to build up trust with
  67 ;; someone.  Perhaps you trust the CA that issued your certificate, at
  68 ;; least I did, so I export it's certificates from my PKCS#12
  69 ;; certificate with:
  70 ;;
  71 ;; $ openssl pkcs12 -in mykey.p12 -cacerts -nodes > cacert.pem
  72 ;; ...
  73 ;;
  74 ;; Now, use M-x customize-variable smime-CAs and add cacert.pem as a
  75 ;; CA certificate.
  76 ;;
  77 ;; You should now be able to sign messages, and even verify messages
  78 ;; sent by others that use the same CA as you.
  79
  80 ;; Bugs:
  81 ;;
  82 ;; Don't complain that this package doesn't do encrypted PEM files,
  83 ;; submit a patch instead.  I store my keys in a safe place, so I
  84 ;; didn't need the encryption.  Also, programming was made easier by
  85 ;; that decision.  One might think that this even influenced were I
  86 ;; store my keys, and one would probably be right. :-)
  87 ;;
  88 ;; Suggestions and comments are appreciated, mail me at simon@josefsson.org.
  89
  90 ;; <rant>
  91 ;;
  92 ;; I would include pointers to introductory text on concepts used in
  93 ;; this library here, but the material I've read are so horrible I
  94 ;; don't want to recomend them.
  95 ;;
  96 ;; Why can't someone write a simple introduction to all this stuff?
  97 ;; Until then, much of this resemble security by obscurity.
  98 ;;
  99 ;; Also, I'm not going to mention anything about the wonders of
 100 ;; cryptopolitics.  Oops, I just did.
 101 ;;
 102 ;; </rant>
 103
 104 ;;; Revision history:
 105
 106 ;; version 0 not released
 107
 108 ;;; Code:
 109
 110 (require 'dig)
 111 (eval-when-compile (require 'cl))
 112
 113 (defgroup smime nil
 114   "S/MIME configuration.")
 115
 116 (defcustom smime-keys nil
 117   "Map mail addresses to a file containing Certificate (and private key).
 118 The file is assumed to be in PEM format and not encrypted."
 119   :type '(repeat (list (string :tag "Mail address")
 120                        (file :tag "File name")))
 121   :group 'smime)
 122
 123 (defcustom smime-CA-directory ""
 124   "Directory containing certificates for CAs you trust.
 125 Directory should contain files (in PEM format) named to the X.509
 126 hash of the certificate."
 127   :type '(choice (const :tag "none" nil)
 128                  directory)
 129   :group 'smime)
 130
 131 (defcustom smime-CA-file ""
 132   "Files containing certificates for CAs you trust.
 133 File should be in PEM format."
 134   :type '(choice (const :tag "none" nil)
 135                  file)
 136   :group 'smime)
 137
 138 (defcustom smime-certificate-directory "~/Mail/certs/"
 139   "Directory containing other people's certificates.
 140 It should contain files named to the X.509 hash of the certificate,
 141 and the files themself should be in PEM format.
 142 The S/MIME library provide simple functionality for fetching
 143 certificates into this directory, so there is no need to populate it
 144 manually."
 145   :type 'directory
 146   :group 'smime)
 147
 148 (defcustom smime-openssl-program
 149   (and (condition-case ()
 150            (eq 0 (call-process "openssl" nil nil nil "version"))
 151          (error nil))
 152        "openssl")
 153   "Name of OpenSSL binary."
 154   :type 'string
 155   :group 'smime)
 156
 157 (defcustom smime-dns-server nil
 158   "DNS server to query certificates from.
 159 If nil, use system defaults."
 160   :type '(choice (const :tag "System defaults")
 161                  string)
 162   :group 'dig)
 163
 164 (defvar smime-details-buffer "*OpenSSL output*")
 165
 166 ;; OpenSSL wrappers.
 167
 168 (defun smime-call-openssl-region (b e buf &rest args)
 169   (case (apply 'call-process-region b e smime-openssl-program nil buf nil args)
 170     (0 t)
 171     (1 (message "OpenSSL: An error occurred parsing the command options.") nil)
 172     (2 (message "OpenSSL: One of the input files could not be read.") nil)
 173     (3 (message "OpenSSL: An error occurred creating the PKCS#7 file or when reading the MIME message.") nil)
 174     (4 (message "OpenSSL: An error occurred decrypting or verifying the message.") nil)
 175     (t (error "Unknown OpenSSL exitcode") nil)))
 176
 177 ;; Sign+encrypt region
 178
 179 (defun smime-sign-region (b e keyfile)
 180   "Sign region with certified key in KEYFILE.
 181 If signing fails, the buffer is not modified.  Region is assumed to
 182 have proper MIME tags.  KEYFILE is expected to contain a PEM encoded
 183 private key and certificate."
 184   (let ((buffer (generate-new-buffer (generate-new-buffer-name " *smime*"))))
 185     (prog1
 186         (when (smime-call-openssl-region b e buffer "smime" "-sign"
 187                                          "-signer" (expand-file-name keyfile))
 188           (delete-region b e)
 189           (insert-buffer buffer)
 190           (when (looking-at "^MIME-Version: 1.0$")
 191             (delete-region (point) (progn (forward-line 1) (point))))
 192           t)
 193       (with-current-buffer (get-buffer-create smime-details-buffer)
 194         (goto-char (point-max))
 195         (insert-buffer buffer))
 196       (kill-buffer buffer))))
 197
 198 (defun smime-encrypt-region (b e certfiles)
 199   "Encrypt region for recipients specified in CERTFILES.
 200 If encryption fails, the buffer is not modified.  Region is assumed to
 201 have proper MIME tags.  CERTFILES is a list of filenames, each file
 202 is expected to contain of a PEM encoded certificate."
 203   (let ((buffer (generate-new-buffer (generate-new-buffer-name " *smime*"))))
 204     (prog1
 205         (when (apply 'smime-call-openssl-region b e buffer "smime" "-encrypt"
 206                      (mapcar 'expand-file-name certfiles))
 207           (delete-region b e)
 208           (insert-buffer buffer)
 209           (when (looking-at "^MIME-Version: 1.0$")
 210             (delete-region (point) (progn (forward-line 1) (point))))
 211           t)
 212       (with-current-buffer (get-buffer-create smime-details-buffer)
 213         (goto-char (point-max))
 214         (insert-buffer buffer))
 215       (kill-buffer buffer))))
 216
 217 ;; Sign+encrypt buffer
 218
 219 (defun smime-sign-buffer (&optional keyfile buffer)
 220   "S/MIME sign BUFFER with key in KEYFILE.
 221 KEYFILE should contain a PEM encoded key and certificate."
 222   (interactive)
 223   (with-current-buffer (or buffer (current-buffer))
 224     (smime-sign-region
 225      (point-min) (point-max)
 226      (or keyfile
 227          (smime-get-key-by-email
 228           (completing-read "Sign using which signature? " smime-keys nil nil
 229                            (and (listp (car-safe smime-keys))
 230                                 (caar smime-keys))))))))
 231
 232 (defun smime-encrypt-buffer (&optional certfiles buffer)
 233   "S/MIME encrypt BUFFER for recipients specified in CERTFILES.
 234 CERTFILES is a list of filenames, each file is expected to consist of
 235 a PEM encoded key and certificate.  Uses current buffer if BUFFER is
 236 nil."
 237   (interactive)
 238   (with-current-buffer (or buffer (current-buffer))
 239     (smime-encrypt-region
 240      (point-min) (point-max)
 241      (or certfiles
 242          (list (read-file-name "Recipient's S/MIME certificate: "
 243                                smime-certificate-directory nil))))))
 244
 245 ;; Verify+decrypt region
 246
 247 (defun smime-verify-region (b e)
 248   (let ((buffer (get-buffer-create smime-details-buffer))
 249         (CAs (cond (smime-CA-file
 250                     (list "-CAfile" (expand-file-name smime-CA-file)))
 251                    (smime-CA-directory
 252                     (list "-CApath" (expand-file-name smime-CA-directory)))
 253                    (t
 254                     (error "No CA configured.")))))
 255     (with-current-buffer buffer
 256       (erase-buffer))
 257     (if (apply 'smime-call-openssl-region b e buffer "smime" "-verify"
 258                "-out" "/dev/null" CAs)
 259         (message "S/MIME message verified succesfully.")
 260       (message "S/MIME message NOT verified successfully.")
 261       nil)))
 262
 263 (defun smime-decrypt-region (b e keyfile)
 264   (let ((buffer (generate-new-buffer (generate-new-buffer-name "*smime*")))
 265         CAs)
 266     (when (apply 'smime-call-openssl-region b e buffer "smime" "-decrypt"
 267                  "-recip" (list keyfile))
 268
 269       )
 270     (with-current-buffer (get-buffer-create smime-details-buffer)
 271       (goto-char (point-max))
 272       (insert-buffer buffer))
 273     (kill-buffer buffer)))
 274
 275 ;; Verify+Decrypt buffer
 276
 277 (defun smime-verify-buffer (&optional buffer)
 278   "Verify integrity of S/MIME message in BUFFER.
 279 Uses current buffer if BUFFER is nil."
 280   (interactive)
 281   (with-current-buffer (or buffer (current-buffer))
 282     (smime-verify-region (point-min) (point-max))))
 283
 284 (defun smime-decrypt-buffer (&optional buffer keyfile)
 285   "Decrypt S/MIME message in BUFFER using KEYFILE.
 286 Uses current buffer if BUFFER is nil, queries user of KEYFILE is nil."
 287   (interactive)
 288   (with-current-buffer (or buffer (current-buffer))
 289     (smime-decrypt-region
 290      (point-min) (point-max)
 291      (expand-file-name
 292       (or keyfile
 293           (smime-get-key-by-email
 294            (completing-read "Decrypt with which key? " smime-keys nil nil
 295                             (and (listp (car-safe smime-keys))
 296                                  (caar smime-keys)))))))))
 297
 298 ;; Various operations
 299
 300 (defun smime-pkcs7-region (b e)
 301   "Convert S/MIME message between points B and E into a PKCS7 message."
 302   (let ((buffer (get-buffer-create smime-details-buffer)))
 303     (with-current-buffer buffer
 304       (erase-buffer))
 305     (when (smime-call-openssl-region b e buffer "smime" "-pk7out")
 306       (delete-region b e)
 307       (insert-buffer-substring buffer)
 308       t)))
 309
 310 (defun smime-pkcs7-certificates-region (b e)
 311   "Extract any certificates enclosed in PKCS7 message between points B and E."
 312   (let ((buffer (get-buffer-create smime-details-buffer)))
 313     (with-current-buffer buffer
 314       (erase-buffer))
 315     (when (smime-call-openssl-region b e buffer "pkcs7" "-print_certs" "-text")
 316       (delete-region b e)
 317       (insert-buffer-substring buffer)
 318       t)))
 319
 320 (defun smime-pkcs7-email-region (b e)
 321   "Get email addresses contained in certificate between points B and E.
 322 A string or a list of strings is returned."
 323   (let ((buffer (get-buffer-create smime-details-buffer)))
 324     (with-current-buffer buffer
 325       (erase-buffer))
 326     (when (smime-call-openssl-region b e buffer "x509" "-email" "-noout")
 327       (delete-region b e)
 328       (insert-buffer-substring buffer)
 329       t)))
 330
 331 (defalias 'smime-point-at-eol
 332   (if (fboundp 'point-at-eol)
 333       'point-at-eol
 334     'line-end-position))
 335
 336 (defun smime-buffer-as-string-region (b e)
 337   "Return each line in region between B and E as a list of strings."
 338   (save-excursion
 339     (goto-char b)
 340     (let (res)
 341       (while (< (point) e)
 342         (let ((str (buffer-substring (point) (smime-point-at-eol))))
 343           (unless (string= "" str)
 344             (push str res)))
 345         (forward-line))
 346       res)))
 347
 348 ;; Find certificates
 349
 350 (defun smime-mail-to-domain (mailaddr)
 351   (if (string-match "@" mailaddr)
 352       (replace-match "." 'fixedcase 'literal mailaddr)
 353     mailaddr))
 354
 355 (defun smime-cert-by-dns (mail)
 356   (let* ((dig-dns-server smime-dns-server)
 357          (digbuf (dig-invoke (smime-mail-to-domain mail) "cert" nil nil "+vc"))
 358          (retbuf (generate-new-buffer (format "*certificate for %s*" mail)))
 359          (certrr (with-current-buffer digbuf
 360                    (dig-extract-rr (smime-mail-to-domain mail) "cert")))
 361          (cert (and certrr (dig-rr-get-pkix-cert certrr))))
 362       (if cert
 363           (with-current-buffer retbuf
 364             (insert "-----BEGIN CERTIFICATE-----\n")
 365             (let ((i 0) (len (length cert)))
 366               (while (> (- len 64) i)
 367                 (insert (substring cert i (+ i 64)) "\n")
 368                 (setq i (+ i 64)))
 369               (insert (substring cert i len) "\n"))
 370             (insert "-----END CERTIFICATE-----\n"))
 371         (kill-buffer retbuf)
 372         (setq retbuf nil))
 373       (kill-buffer digbuf)
 374       retbuf))
 375
 376 ;; User interface.
 377
 378 (defvar smime-buffer "*SMIME*")
 379
 380 (defvar smime-mode-map nil)
 381 (put 'smime-mode 'mode-class 'special)
 382
 383 (unless smime-mode-map
 384   (setq smime-mode-map (make-sparse-keymap))
 385   (suppress-keymap smime-mode-map)
 386
 387   (define-key smime-mode-map "q" 'smime-exit)
 388   (define-key smime-mode-map "f" 'smime-certificate-info))
 389
 390 (defun smime-mode ()
 391   "Major mode for browsing, viewing and fetching certificates.
 392
 393 All normal editing commands are switched off.
 394 \\<smime-mode-map>
 395
 396 The following commands are available:
 397
 398 \\{smime-mode-map}"
 399   (interactive)
 400   (kill-all-local-variables)
 401   (setq major-mode 'smime-mode)
 402   (setq mode-name "SMIME")
 403   (setq mode-line-process nil)
 404   (use-local-map smime-mode-map)
 405   (buffer-disable-undo)
 406   (setq truncate-lines t)
 407   (setq buffer-read-only t))
 408
 409 (defun smime-certificate-info (certfile)
 410   (interactive "fCertificate file: ")
 411   (let ((buffer (get-buffer-create (format "*certificate %s*" certfile))))
 412     (switch-to-buffer buffer)
 413     (erase-buffer)
 414     (call-process smime-openssl-program nil buffer 'display
 415                   "x509" "-in" (expand-file-name certfile) "-text")
 416     (fundamental-mode)
 417     (set-buffer-modified-p nil)
 418     (toggle-read-only t)
 419     (goto-char (point-min))))
 420
 421 (defun smime-draw-buffer ()
 422   (with-current-buffer smime-buffer
 423     (let (buffer-read-only)
 424       (erase-buffer)
 425       (insert "\nYour keys:\n")
 426       (dolist (key smime-keys)
 427         (insert
 428          (format "\t\t%s: %s\n" (car key) (cadr key))))
 429       (insert "\nTrusted Certificate Authoritys:\n")
 430       (insert "\nKnown Certificates:\n"))))
 431
 432 (defun smime ()
 433   "Go to the SMIME buffer."
 434   (interactive)
 435   (unless (get-buffer smime-buffer)
 436     (save-excursion
 437       (set-buffer (get-buffer-create smime-buffer))
 438       (smime-mode)))
 439   (smime-draw-buffer)
 440   (switch-to-buffer smime-buffer))
 441
 442 (defun smime-exit ()
 443   "Quit the S/MIME buffer."
 444   (interactive)
 445   (kill-buffer (current-buffer)))
 446
 447 ;; Other functions
 448
 449 (defun smime-get-key-by-email (email)
 450   (cadr (assoc email smime-keys)))
 451
 452 (provide 'smime)
 453
 454 ;;; smime.el ends here