cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :group 'mail)
  39
  40 (defcustom shr-max-image-proportion 0.9
  41   "How big pictures displayed are in relation to the window they're in.
  42 A value of 0.7 means that they are allowed to take up 70% of the
  43 width and height of the window.  If they are larger than this,
  44 and Emacs supports it, then the images will be rescaled down to
  45 fit these criteria."
  46   :version "24.1"
  47   :group 'shr
  48   :type 'float)
  49
  50 (defcustom shr-blocked-images nil
  51   "Images that have URLs matching this regexp will be blocked."
  52   :version "24.1"
  53   :group 'shr
  54   :type 'regexp)
  55
  56 (defcustom shr-table-horizontal-line ?-
  57   "Character used to draw horizontal table lines."
  58   :group 'shr
  59   :type 'character)
  60
  61 (defcustom shr-table-vertical-line ?|
  62   "Character used to draw vertical table lines."
  63   :group 'shr
  64   :type 'character)
  65
  66 (defcustom shr-table-corner ?+
  67   "Character used to draw table corners."
  68   :group 'shr
  69   :type 'character)
  70
  71 (defcustom shr-hr-line ?-
  72   "Character used to draw hr lines."
  73   :group 'shr
  74   :type 'character)
  75
  76 (defcustom shr-width fill-column
  77   "Frame width to use for rendering.
  78 May either be an integer specifying a fixed width in characters,
  79 or nil, meaning that the full width of the window should be
  80 used."
  81   :type '(choice (integer :tag "Fixed width in characters")
  82                  (const   :tag "Use the width of the window" nil))
  83   :group 'shr)
  84
  85 (defvar shr-content-function nil
  86   "If bound, this should be a function that will return the content.
  87 This is used for cid: URLs, and the function is called with the
  88 cid: URL as the argument.")
  89
  90 ;;; Internal variables.
  91
  92 (defvar shr-folding-mode nil)
  93 (defvar shr-state nil)
  94 (defvar shr-start nil)
  95 (defvar shr-indentation 0)
  96 (defvar shr-inhibit-images nil)
  97 (defvar shr-list-mode nil)
  98 (defvar shr-content-cache nil)
  99 (defvar shr-kinsoku-shorten nil)
 100 (defvar shr-table-depth 0)
 101 (defvar shr-stylesheet nil)
 102
 103 (defvar shr-map
 104   (let ((map (make-sparse-keymap)))
 105     (define-key map "a" 'shr-show-alt-text)
 106     (define-key map "i" 'shr-browse-image)
 107     (define-key map "I" 'shr-insert-image)
 108     (define-key map "u" 'shr-copy-url)
 109     (define-key map "v" 'shr-browse-url)
 110     (define-key map "o" 'shr-save-contents)
 111     (define-key map "\r" 'shr-browse-url)
 112     map))
 113
 114 ;; Public functions and commands.
 115
 116 ;;;###autoload
 117 (defun shr-insert-document (dom)
 118   (setq shr-content-cache nil)
 119   (let ((shr-state nil)
 120         (shr-start nil)
 121         (shr-width (or shr-width (window-width))))
 122     (shr-descend (shr-transform-dom dom))))
 123
 124 (defun shr-copy-url ()
 125   "Copy the URL under point to the kill ring.
 126 If called twice, then try to fetch the URL and see whether it
 127 redirects somewhere else."
 128   (interactive)
 129   (let ((url (get-text-property (point) 'shr-url)))
 130     (cond
 131      ((not url)
 132       (message "No URL under point"))
 133      ;; Resolve redirected URLs.
 134      ((equal url (car kill-ring))
 135       (url-retrieve
 136        url
 137        (lambda (a)
 138          (when (and (consp a)
 139                     (eq (car a) :redirect))
 140            (with-temp-buffer
 141              (insert (cadr a))
 142              (goto-char (point-min))
 143              ;; Remove common tracking junk from the URL.
 144              (when (re-search-forward ".utm_.*" nil t)
 145                (replace-match "" t t))
 146              (message "Copied %s" (buffer-string))
 147              (copy-region-as-kill (point-min) (point-max)))))))
 148      ;; Copy the URL to the kill ring.
 149      (t
 150       (with-temp-buffer
 151         (insert url)
 152         (copy-region-as-kill (point-min) (point-max))
 153         (message "Copied %s" url))))))
 154
 155 (defun shr-show-alt-text ()
 156   "Show the ALT text of the image under point."
 157   (interactive)
 158   (let ((text (get-text-property (point) 'shr-alt)))
 159     (if (not text)
 160         (message "No image under point")
 161       (message "%s" text))))
 162
 163 (defun shr-browse-image ()
 164   "Browse the image under point."
 165   (interactive)
 166   (let ((url (get-text-property (point) 'image-url)))
 167     (if (not url)
 168         (message "No image under point")
 169       (message "Browsing %s..." url)
 170       (browse-url url))))
 171
 172 (defun shr-insert-image ()
 173   "Insert the image under point into the buffer."
 174   (interactive)
 175   (let ((url (get-text-property (point) 'image-url)))
 176     (if (not url)
 177         (message "No image under point")
 178       (message "Inserting %s..." url)
 179       (url-retrieve url 'shr-image-fetched
 180                     (list (current-buffer) (1- (point)) (point-marker))
 181                     t))))
 182
 183 ;;; Utility functions.
 184
 185 (defun shr-transform-dom (dom)
 186   (let ((result (list (pop dom))))
 187     (dolist (arg (pop dom))
 188       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 189                   (cdr arg))
 190             result))
 191     (dolist (sub dom)
 192       (if (stringp sub)
 193           (push (cons 'text sub) result)
 194         (push (shr-transform-dom sub) result)))
 195     (nreverse result)))
 196
 197 (defun shr-descend (dom)
 198   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 199         (style (cdr (assq :style (cdr dom))))
 200         (shr-stylesheet shr-stylesheet)
 201         (start (point)))
 202     (when style
 203       (if (string-match "color" style)
 204           (setq shr-stylesheet (nconc (shr-parse-style style)
 205                                       shr-stylesheet))
 206         (setq style nil)))
 207     (if (fboundp function)
 208         (funcall function (cdr dom))
 209       (shr-generic (cdr dom)))
 210     ;; If style is set, then this node has set the color.
 211     (when style
 212       (shr-colorize-region start (point)
 213                            (cdr (assq 'color shr-stylesheet))
 214                            (cdr (assq 'background-color shr-stylesheet))))))
 215
 216 (defun shr-generic (cont)
 217   (dolist (sub cont)
 218     (cond
 219      ((eq (car sub) 'text)
 220       (shr-insert (cdr sub)))
 221      ((listp (cdr sub))
 222       (shr-descend sub)))))
 223
 224 (defmacro shr-char-breakable-p (char)
 225   "Return non-nil if a line can be broken before and after CHAR."
 226   `(aref fill-find-break-point-function-table ,char))
 227 (defmacro shr-char-nospace-p (char)
 228   "Return non-nil if no space is required before and after CHAR."
 229   `(aref fill-nospace-between-words-table ,char))
 230
 231 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 232 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 233 ;; parentheses, and so on, that should not be placed in the beginning
 234 ;; of a line or the end of a line.
 235 (defmacro shr-char-kinsoku-bol-p (char)
 236   "Return non-nil if a line ought not to begin with CHAR."
 237   `(aref (char-category-set ,char) ?>))
 238 (defmacro shr-char-kinsoku-eol-p (char)
 239   "Return non-nil if a line ought not to end with CHAR."
 240   `(aref (char-category-set ,char) ?<))
 241 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 242   (load "kinsoku" nil t))
 243
 244 (defun shr-insert (text)
 245   (when (and (eq shr-state 'image)
 246              (not (string-match "\\`[ \t\n]+\\'" text)))
 247     (insert "\n")
 248     (setq shr-state nil))
 249   (cond
 250    ((eq shr-folding-mode 'none)
 251     (insert text))
 252    (t
 253     (when (and (string-match "\\`[ \t\n]" text)
 254                (not (bolp))
 255                (not (eq (char-after (1- (point))) ? )))
 256       (insert " "))
 257     (dolist (elem (split-string text))
 258       (when (and (bolp)
 259                  (> shr-indentation 0))
 260         (shr-indent))
 261       ;; No space is needed behind a wide character categorized as
 262       ;; kinsoku-bol, between characters both categorized as nospace,
 263       ;; or at the beginning of a line.
 264       (let (prev)
 265         (when (and (> (current-column) shr-indentation)
 266                    (eq (preceding-char) ? )
 267                    (or (= (line-beginning-position) (1- (point)))
 268                        (and (shr-char-breakable-p
 269                              (setq prev (char-after (- (point) 2))))
 270                             (shr-char-kinsoku-bol-p prev))
 271                        (and (shr-char-nospace-p prev)
 272                             (shr-char-nospace-p (aref elem 0)))))
 273           (delete-char -1)))
 274       ;; The shr-start is a special variable that is used to pass
 275       ;; upwards the first point in the buffer where the text really
 276       ;; starts.
 277       (unless shr-start
 278         (setq shr-start (point)))
 279       (insert elem)
 280       (let (found)
 281         (while (and (> (current-column) shr-width)
 282                     (progn
 283                       (setq found (shr-find-fill-point))
 284                       (not (eolp))))
 285           (when (eq (preceding-char) ? )
 286             (delete-char -1))
 287           (insert "\n")
 288           (unless found
 289             (put-text-property (1- (point)) (point) 'shr-break t)
 290             ;; No space is needed at the beginning of a line.
 291             (when (eq (following-char) ? )
 292               (delete-char 1)))
 293           (when (> shr-indentation 0)
 294             (shr-indent))
 295           (end-of-line))
 296         (insert " ")))
 297     (unless (string-match "[ \t\n]\\'" text)
 298       (delete-char -1)))))
 299
 300 (defun shr-find-fill-point ()
 301   (when (> (move-to-column shr-width) shr-width)
 302     (backward-char 1))
 303   (let ((bp (point))
 304         failed)
 305     (while (not (or (setq failed (= (current-column) shr-indentation))
 306                     (eq (preceding-char) ? )
 307                     (eq (following-char) ? )
 308                     (shr-char-breakable-p (preceding-char))
 309                     (shr-char-breakable-p (following-char))
 310                     (if (eq (preceding-char) ?')
 311                         (not (memq (char-after (- (point) 2))
 312                                    (list nil ?\n ? )))
 313                       (and (shr-char-kinsoku-bol-p (preceding-char))
 314                            (shr-char-breakable-p (following-char))
 315                            (not (shr-char-kinsoku-bol-p (following-char)))))
 316                     (shr-char-kinsoku-eol-p (following-char))))
 317       (backward-char 1))
 318     (if (and (not (or failed (eolp)))
 319              (eq (preceding-char) ?'))
 320         (while (not (or (setq failed (eolp))
 321                         (eq (following-char) ? )
 322                         (shr-char-breakable-p (following-char))
 323                         (shr-char-kinsoku-eol-p (following-char))))
 324           (forward-char 1)))
 325     (if failed
 326         ;; There's no breakable point, so we give it up.
 327         (let (found)
 328           (goto-char bp)
 329           (unless shr-kinsoku-shorten
 330             (while (and (setq found (re-search-forward
 331                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 332                                      (line-end-position) 'move))
 333                         (eq (preceding-char) ?')))
 334             (if (and found (not (match-beginning 1)))
 335                 (goto-char (match-beginning 0)))))
 336       (or
 337        (eolp)
 338        ;; Don't put kinsoku-bol characters at the beginning of a line,
 339        ;; or kinsoku-eol characters at the end of a line.
 340        (cond
 341         (shr-kinsoku-shorten
 342          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 343                      (shr-char-kinsoku-eol-p (preceding-char)))
 344            (backward-char 1))
 345          (when (setq failed (= (current-column) shr-indentation))
 346            ;; There's no breakable point that doesn't violate kinsoku,
 347            ;; so we look for the second best position.
 348            (while (and (progn
 349                          (forward-char 1)
 350                          (<= (current-column) shr-width))
 351                        (progn
 352                          (setq bp (point))
 353                          (shr-char-kinsoku-eol-p (following-char)))))
 354            (goto-char bp)))
 355         ((shr-char-kinsoku-eol-p (preceding-char))
 356          (if (shr-char-kinsoku-eol-p (following-char))
 357              ;; There are consecutive kinsoku-eol characters.
 358              (setq failed t)
 359            (let ((count 4))
 360              (while
 361                  (progn
 362                    (backward-char 1)
 363                    (and (> (setq count (1- count)) 0)
 364                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 365                         (or (shr-char-kinsoku-eol-p (preceding-char))
 366                             (shr-char-kinsoku-bol-p (following-char)))))))
 367            (if (setq failed (= (current-column) shr-indentation))
 368                ;; There's no breakable point that doesn't violate kinsoku,
 369                ;; so we go to the second best position.
 370                (if (looking-at "\\(\\c<+\\)\\c<")
 371                    (goto-char (match-end 1))
 372                  (forward-char 1)))))
 373         (t
 374          (if (shr-char-kinsoku-bol-p (preceding-char))
 375              ;; There are consecutive kinsoku-bol characters.
 376              (setq failed t)
 377            (let ((count 4))
 378              (while (and (>= (setq count (1- count)) 0)
 379                          (shr-char-kinsoku-bol-p (following-char))
 380                          (shr-char-breakable-p (following-char)))
 381                (forward-char 1))))))
 382        (when (eq (following-char) ? )
 383          (forward-char 1))))
 384     (not failed)))
 385
 386 (defun shr-ensure-newline ()
 387   (unless (zerop (current-column))
 388     (insert "\n")))
 389
 390 (defun shr-ensure-paragraph ()
 391   (unless (bobp)
 392     (if (<= (current-column) shr-indentation)
 393         (unless (save-excursion
 394                   (forward-line -1)
 395                   (looking-at " *$"))
 396           (insert "\n"))
 397       (if (save-excursion
 398             (beginning-of-line)
 399             (looking-at " *$"))
 400           (insert "\n")
 401         (insert "\n\n")))))
 402
 403 (defun shr-indent ()
 404   (when (> shr-indentation 0)
 405     (insert (make-string shr-indentation ? ))))
 406
 407 (defun shr-fontize-cont (cont &rest types)
 408   (let (shr-start)
 409     (shr-generic cont)
 410     (dolist (type types)
 411       (shr-add-font (or shr-start (point)) (point) type))))
 412
 413 ;; Add an overlay in the region, but avoid putting the font properties
 414 ;; on blank text at the start of the line, and the newline at the end,
 415 ;; to avoid ugliness.
 416 (defun shr-add-font (start end type)
 417   (save-excursion
 418     (goto-char start)
 419     (while (< (point) end)
 420       (when (bolp)
 421         (skip-chars-forward " "))
 422       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 423         (overlay-put overlay 'face type))
 424       (if (< (line-end-position) end)
 425           (forward-line 1)
 426         (goto-char end)))))
 427
 428 (defun shr-browse-url ()
 429   "Browse the URL under point."
 430   (interactive)
 431   (let ((url (get-text-property (point) 'shr-url)))
 432     (cond
 433      ((not url)
 434       (message "No link under point"))
 435      ((string-match "^mailto:" url)
 436       (browse-url-mailto url))
 437      (t
 438       (browse-url url)))))
 439
 440 (defun shr-save-contents (directory)
 441   "Save the contents from URL in a file."
 442   (interactive "DSave contents of URL to directory: ")
 443   (let ((url (get-text-property (point) 'shr-url)))
 444     (if (not url)
 445         (message "No link under point")
 446       (url-retrieve (shr-encode-url url)
 447                     'shr-store-contents (list url directory)))))
 448
 449 (defun shr-store-contents (status url directory)
 450   (unless (plist-get status :error)
 451     (when (or (search-forward "\n\n" nil t)
 452               (search-forward "\r\n\r\n" nil t))
 453       (write-region (point) (point-max)
 454                     (expand-file-name (file-name-nondirectory url)
 455                                       directory)))))
 456
 457 (defun shr-image-fetched (status buffer start end)
 458   (when (and (buffer-name buffer)
 459              (not (plist-get status :error)))
 460     (url-store-in-cache (current-buffer))
 461     (when (or (search-forward "\n\n" nil t)
 462               (search-forward "\r\n\r\n" nil t))
 463       (let ((data (buffer-substring (point) (point-max))))
 464         (with-current-buffer buffer
 465           (save-excursion
 466             (let ((alt (buffer-substring start end))
 467                   (inhibit-read-only t))
 468               (delete-region start end)
 469               (goto-char start)
 470               (shr-put-image data alt)))))))
 471   (kill-buffer (current-buffer)))
 472
 473 (defun shr-put-image (data alt)
 474   (if (display-graphic-p)
 475       (let ((image (ignore-errors
 476                      (shr-rescale-image data))))
 477         (when image
 478           ;; When inserting big-ish pictures, put them at the
 479           ;; beginning of the line.
 480           (when (and (> (current-column) 0)
 481                      (> (car (image-size image t)) 400))
 482             (insert "\n"))
 483           (insert-image image (or alt "*"))))
 484     (insert alt)))
 485
 486 (defun shr-rescale-image (data)
 487   (if (or (not (fboundp 'imagemagick-types))
 488           (not (get-buffer-window (current-buffer))))
 489       (create-image data nil t)
 490     (let* ((image (create-image data nil t))
 491            (size (image-size image t))
 492            (width (car size))
 493            (height (cdr size))
 494            (edges (window-inside-pixel-edges
 495                    (get-buffer-window (current-buffer))))
 496            (window-width (truncate (* shr-max-image-proportion
 497                                       (- (nth 2 edges) (nth 0 edges)))))
 498            (window-height (truncate (* shr-max-image-proportion
 499                                        (- (nth 3 edges) (nth 1 edges)))))
 500            scaled-image)
 501       (when (> height window-height)
 502         (setq image (or (create-image data 'imagemagick t
 503                                       :height window-height)
 504                         image))
 505         (setq size (image-size image t)))
 506       (when (> (car size) window-width)
 507         (setq image (or
 508                      (create-image data 'imagemagick t
 509                                    :width window-width)
 510                      image)))
 511       (when (and (fboundp 'create-animated-image)
 512                  (eq (image-type data nil t) 'gif))
 513         (setq image (create-animated-image data 'gif t)))
 514       image)))
 515
 516 ;; url-cache-extract autoloads url-cache.
 517 (declare-function url-cache-create-filename "url-cache" (url))
 518 (autoload 'mm-disable-multibyte "mm-util")
 519 (autoload 'browse-url-mailto "browse-url")
 520
 521 (defun shr-get-image-data (url)
 522   "Get image data for URL.
 523 Return a string with image data."
 524   (with-temp-buffer
 525     (mm-disable-multibyte)
 526     (when (ignore-errors
 527             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 528             t)
 529       (when (or (search-forward "\n\n" nil t)
 530                 (search-forward "\r\n\r\n" nil t))
 531         (buffer-substring (point) (point-max))))))
 532
 533 (defun shr-image-displayer (content-function)
 534   "Return a function to display an image.
 535 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 536 is an argument.  The function to be returned takes three arguments URL,
 537 START, and END.  Note that START and END should be merkers."
 538   `(lambda (url start end)
 539      (when url
 540        (if (string-match "\\`cid:" url)
 541            ,(when content-function
 542               `(let ((image (funcall ,content-function
 543                                      (substring url (match-end 0)))))
 544                  (when image
 545                    (goto-char start)
 546                    (shr-put-image image
 547                                   (buffer-substring-no-properties start end))
 548                    (delete-region (point) end))))
 549          (url-retrieve url 'shr-image-fetched
 550                        (list (current-buffer) start end)
 551                        t)))))
 552
 553 (defun shr-heading (cont &rest types)
 554   (shr-ensure-paragraph)
 555   (apply #'shr-fontize-cont cont types)
 556   (shr-ensure-paragraph))
 557
 558 (autoload 'widget-convert-button "wid-edit")
 559
 560 (defun shr-urlify (start url &optional title)
 561   (widget-convert-button
 562    'url-link start (point)
 563    :help-echo (if title (format "%s (%s)" url title) url)
 564    :keymap shr-map
 565    url)
 566   (put-text-property start (point) 'shr-url url))
 567
 568 (defun shr-encode-url (url)
 569   "Encode URL."
 570   (browse-url-url-encode-chars url "[)$ ]"))
 571
 572 (autoload 'shr-color-visible "shr-color")
 573 (autoload 'shr-color->hexadecimal "shr-color")
 574
 575 (defun shr-color-check (fg bg)
 576   "Check that FG is visible on BG.
 577 Returns (fg bg) with corrected values.
 578 Returns nil if the colors that would be used are the default
 579 ones, in case fg and bg are nil."
 580   (when (or fg bg)
 581     (let ((fixed (cond ((null fg) 'fg)
 582                        ((null bg) 'bg))))
 583       ;; Convert colors to hexadecimal, or set them to default.
 584       (let ((fg (or (shr-color->hexadecimal fg)
 585                     (frame-parameter nil 'foreground-color)))
 586             (bg (or (shr-color->hexadecimal bg)
 587                     (frame-parameter nil 'background-color))))
 588         (cond ((eq fixed 'bg)
 589                ;; Only return the new fg
 590                (list nil (cadr (shr-color-visible bg fg t))))
 591               ((eq fixed 'fg)
 592                ;; Invert args and results and return only the new bg
 593                (list (cadr (shr-color-visible fg bg t)) nil))
 594               (t
 595                (shr-color-visible bg fg)))))))
 596
 597 (defun shr-colorize-region (start end fg &optional bg)
 598   (when (or fg bg)
 599     (let ((new-colors (shr-color-check fg bg)))
 600       (when new-colors
 601         (when fg
 602           (shr-put-color start end :foreground (cadr new-colors)))
 603         (when bg
 604           (shr-put-color start end :background (car new-colors))))
 605       new-colors)))
 606
 607 ;; Put a color in the region, but avoid putting colors on on blank
 608 ;; text at the start of the line, and the newline at the end, to avoid
 609 ;; ugliness.  Also, don't overwrite any existing color information,
 610 ;; since this can be called recursively, and we want the "inner" color
 611 ;; to win.
 612 (defun shr-put-color (start end type color)
 613   (save-excursion
 614     (goto-char start)
 615     (while (< (point) end)
 616       (when (and (bolp)
 617                  (not (eq type :background)))
 618         (skip-chars-forward " "))
 619       (when (> (line-end-position) (point))
 620         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 621       (if (< (line-end-position) end)
 622           (forward-line 1)
 623         (goto-char end)))
 624     (when (and (eq type :background)
 625                (= shr-table-depth 0))
 626       (shr-expand-newlines start end color))))
 627
 628 (defun shr-expand-newlines (start end color)
 629   (save-restriction
 630     ;; Skip past all white space at the start and ends.
 631     (goto-char start)
 632     (skip-chars-forward " \t\n")
 633     (beginning-of-line)
 634     (setq start (point))
 635     (goto-char end)
 636     (skip-chars-backward " \t\n")
 637     (forward-line 1)
 638     (setq end (point))
 639     (narrow-to-region start end)
 640     (let ((width (shr-natural-width))
 641           column)
 642       (goto-char (point-min))
 643       (while (not (eobp))
 644         (end-of-line)
 645         (when (and (< (setq column (current-column)) width)
 646                    (< (setq column (shr-previous-newline-padding-width column))
 647                       width))
 648           (let ((overlay (make-overlay (point) (1+ (point)))))
 649             (overlay-put overlay 'before-string
 650                          (concat
 651                           (mapconcat
 652                            (lambda (overlay)
 653                              (let ((string (plist-get
 654                                             (overlay-properties overlay)
 655                                             'before-string)))
 656                                (if (not string)
 657                                    ""
 658                                  (overlay-put overlay 'before-string "")
 659                                  string)))
 660                            (overlays-at (point))
 661                            "")
 662                           (propertize (make-string (- width column) ? )
 663                                       'face (list :background color))))))
 664         (forward-line 1)))))
 665
 666 (defun shr-previous-newline-padding-width (width)
 667   (let ((overlays (overlays-at (point)))
 668         (previous-width 0))
 669     (if (null overlays)
 670         width
 671       (dolist (overlay overlays)
 672         (setq previous-width
 673               (+ previous-width
 674                  (length (plist-get (overlay-properties overlay)
 675                                     'before-string)))))
 676       (+ width previous-width))))
 677
 678 (defun shr-put-color-1 (start end type color)
 679   (let* ((old-props (get-text-property start 'face))
 680          (do-put (not (memq type old-props)))
 681          change)
 682     (while (< start end)
 683       (setq change (next-single-property-change start 'face nil end))
 684       (when do-put
 685         (put-text-property start change 'face
 686                            (nconc (list type color) old-props)))
 687       (setq old-props (get-text-property change 'face))
 688       (setq do-put (not (memq type old-props)))
 689       (setq start change))
 690     (when (and do-put
 691                (> end start))
 692       (put-text-property start end 'face
 693                          (nconc (list type color old-props))))))
 694
 695 ;;; Tag-specific rendering rules.
 696
 697 (defun shr-tag-body (cont)
 698   (let* ((start (point))
 699          (fgcolor (cdr (assq :fgcolor cont)))
 700          (bgcolor (cdr (assq :bgcolor cont)))
 701          (shr-stylesheet (list (cons 'color fgcolor)
 702                                (cons 'background-color bgcolor))))
 703     (shr-generic cont)
 704     (shr-colorize-region start (point) fgcolor bgcolor)))
 705
 706 (defun shr-tag-style (cont)
 707   )
 708
 709 (defun shr-tag-script (cont)
 710   )
 711
 712 (defun shr-tag-label (cont)
 713   (shr-generic cont)
 714   (shr-ensure-paragraph))
 715
 716 (defun shr-tag-p (cont)
 717   (shr-ensure-paragraph)
 718   (shr-indent)
 719   (shr-generic cont)
 720   (shr-ensure-paragraph))
 721
 722 (defun shr-tag-div (cont)
 723   (shr-ensure-newline)
 724   (shr-indent)
 725   (shr-generic cont)
 726   (shr-ensure-newline))
 727
 728 (defun shr-tag-b (cont)
 729   (shr-fontize-cont cont 'bold))
 730
 731 (defun shr-tag-i (cont)
 732   (shr-fontize-cont cont 'italic))
 733
 734 (defun shr-tag-em (cont)
 735   (shr-fontize-cont cont 'bold))
 736
 737 (defun shr-tag-strong (cont)
 738   (shr-fontize-cont cont 'bold))
 739
 740 (defun shr-tag-u (cont)
 741   (shr-fontize-cont cont 'underline))
 742
 743 (defun shr-tag-s (cont)
 744   (shr-fontize-cont cont 'strike-through))
 745
 746 (defun shr-parse-style (style)
 747   (when style
 748     (save-match-data
 749       (when (string-match "\n" style)
 750         (setq style (replace-match " " t t style))))
 751     (let ((plist nil))
 752       (dolist (elem (split-string style ";"))
 753         (when elem
 754           (setq elem (split-string elem ":"))
 755           (when (and (car elem)
 756                      (cadr elem))
 757             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 758                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 759               (when (string-match " *!important\\'" value)
 760                 (setq value (substring value 0 (match-beginning 0))))
 761               (push (cons (intern name obarray)
 762                           value)
 763                     plist)))))
 764       plist)))
 765
 766 (defun shr-tag-a (cont)
 767   (let ((url (cdr (assq :href cont)))
 768         (title (cdr (assq :title cont)))
 769         (start (point))
 770         shr-start)
 771     (shr-generic cont)
 772     (shr-urlify (or shr-start start) url title)))
 773
 774 (defun shr-tag-object (cont)
 775   (let ((start (point))
 776         url)
 777     (dolist (elem cont)
 778       (when (eq (car elem) 'embed)
 779         (setq url (or url (cdr (assq :src (cdr elem))))))
 780       (when (and (eq (car elem) 'param)
 781                  (equal (cdr (assq :name (cdr elem))) "movie"))
 782         (setq url (or url (cdr (assq :value (cdr elem)))))))
 783     (when url
 784       (shr-insert " [multimedia] ")
 785       (shr-urlify start url))
 786     (shr-generic cont)))
 787
 788 (defun shr-tag-video (cont)
 789   (let ((image (cdr (assq :poster cont)))
 790         (url (cdr (assq :src cont)))
 791         (start (point)))
 792     (shr-tag-img nil image)
 793     (shr-urlify start url)))
 794
 795 (defun shr-tag-img (cont &optional url)
 796   (when (or url
 797             (and cont
 798                  (cdr (assq :src cont))))
 799     (when (and (> (current-column) 0)
 800                (not (eq shr-state 'image)))
 801       (insert "\n"))
 802     (let ((alt (cdr (assq :alt cont)))
 803           (url (or url (cdr (assq :src cont)))))
 804       (let ((start (point-marker)))
 805         (when (zerop (length alt))
 806           (setq alt "*"))
 807         (cond
 808          ((or (member (cdr (assq :height cont)) '("0" "1"))
 809               (member (cdr (assq :width cont)) '("0" "1")))
 810           ;; Ignore zero-sized or single-pixel images.
 811           )
 812          ((and (not shr-inhibit-images)
 813                (string-match "\\`cid:" url))
 814           (let ((url (substring url (match-end 0)))
 815                 image)
 816             (if (or (not shr-content-function)
 817                     (not (setq image (funcall shr-content-function url))))
 818                 (insert alt)
 819               (shr-put-image image alt))))
 820          ((or shr-inhibit-images
 821               (and shr-blocked-images
 822                    (string-match shr-blocked-images url)))
 823           (setq shr-start (point))
 824           (let ((shr-state 'space))
 825             (if (> (string-width alt) 8)
 826                 (shr-insert (truncate-string-to-width alt 8))
 827               (shr-insert alt))))
 828          ((url-is-cached (shr-encode-url url))
 829           (shr-put-image (shr-get-image-data url) alt))
 830          (t
 831           (insert alt)
 832           (ignore-errors
 833             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 834                           (list (current-buffer) start (point-marker))
 835                           t))))
 836         (put-text-property start (point) 'keymap shr-map)
 837         (put-text-property start (point) 'shr-alt alt)
 838         (put-text-property start (point) 'image-url url)
 839         (put-text-property start (point) 'image-displayer
 840                            (shr-image-displayer shr-content-function))
 841         (put-text-property start (point) 'help-echo alt)
 842         (setq shr-state 'image)))))
 843
 844 (defun shr-tag-pre (cont)
 845   (let ((shr-folding-mode 'none))
 846     (shr-ensure-newline)
 847     (shr-indent)
 848     (shr-generic cont)
 849     (shr-ensure-newline)))
 850
 851 (defun shr-tag-blockquote (cont)
 852   (shr-ensure-paragraph)
 853   (shr-indent)
 854   (let ((shr-indentation (+ shr-indentation 4)))
 855     (shr-generic cont))
 856   (shr-ensure-paragraph))
 857
 858 (defun shr-tag-ul (cont)
 859   (shr-ensure-paragraph)
 860   (let ((shr-list-mode 'ul))
 861     (shr-generic cont))
 862   (shr-ensure-paragraph))
 863
 864 (defun shr-tag-ol (cont)
 865   (shr-ensure-paragraph)
 866   (let ((shr-list-mode 1))
 867     (shr-generic cont))
 868   (shr-ensure-paragraph))
 869
 870 (defun shr-tag-li (cont)
 871   (shr-ensure-paragraph)
 872   (shr-indent)
 873   (let* ((bullet
 874           (if (numberp shr-list-mode)
 875               (prog1
 876                   (format "%d " shr-list-mode)
 877                 (setq shr-list-mode (1+ shr-list-mode)))
 878             "* "))
 879          (shr-indentation (+ shr-indentation (length bullet))))
 880     (insert bullet)
 881     (shr-generic cont)))
 882
 883 (defun shr-tag-br (cont)
 884   (unless (bobp)
 885     (insert "\n")
 886     (shr-indent))
 887   (shr-generic cont))
 888
 889 (defun shr-tag-h1 (cont)
 890   (shr-heading cont 'bold 'underline))
 891
 892 (defun shr-tag-h2 (cont)
 893   (shr-heading cont 'bold))
 894
 895 (defun shr-tag-h3 (cont)
 896   (shr-heading cont 'italic))
 897
 898 (defun shr-tag-h4 (cont)
 899   (shr-heading cont))
 900
 901 (defun shr-tag-h5 (cont)
 902   (shr-heading cont))
 903
 904 (defun shr-tag-h6 (cont)
 905   (shr-heading cont))
 906
 907 (defun shr-tag-hr (cont)
 908   (shr-ensure-newline)
 909   (insert (make-string shr-width shr-hr-line) "\n"))
 910
 911 (defun shr-tag-title (cont)
 912   (shr-heading cont 'bold 'underline))
 913
 914 (defun shr-tag-font (cont)
 915   (let* ((start (point))
 916          (color (cdr (assq :color cont)))
 917          (shr-stylesheet (nconc (list (cons 'color color))
 918                                 shr-stylesheet)))
 919     (shr-generic cont)
 920     (when color
 921       (shr-colorize-region start (point) color
 922                            (cdr (assq 'background-color shr-stylesheet))))))
 923
 924 ;;; Table rendering algorithm.
 925
 926 ;; Table rendering is the only complicated thing here.  We do this by
 927 ;; first counting how many TDs there are in each TR, and registering
 928 ;; how wide they think they should be ("width=45%", etc).  Then we
 929 ;; render each TD separately (this is done in temporary buffers, so
 930 ;; that we can use all the rendering machinery as if we were in the
 931 ;; main buffer).  Now we know how much space each TD really takes, so
 932 ;; we then render everything again with the new widths, and finally
 933 ;; insert all these boxes into the main buffer.
 934 (defun shr-tag-table-1 (cont)
 935   (setq cont (or (cdr (assq 'tbody cont))
 936                  cont))
 937   (let* ((shr-inhibit-images t)
 938          (shr-table-depth (1+ shr-table-depth))
 939          (shr-kinsoku-shorten t)
 940          ;; Find all suggested widths.
 941          (columns (shr-column-specs cont))
 942          ;; Compute how many characters wide each TD should be.
 943          (suggested-widths (shr-pro-rate-columns columns))
 944          ;; Do a "test rendering" to see how big each TD is (this can
 945          ;; be smaller (if there's little text) or bigger (if there's
 946          ;; unbreakable text).
 947          (sketch (shr-make-table cont suggested-widths))
 948          (sketch-widths (shr-table-widths sketch suggested-widths)))
 949     ;; This probably won't work very well.
 950     (when (> (+ (loop for width across sketch-widths
 951                       summing (1+ width))
 952                 shr-indentation 1)
 953              (frame-width))
 954       (setq truncate-lines t))
 955     ;; Then render the table again with these new "hard" widths.
 956     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 957   ;; Finally, insert all the images after the table.  The Emacs buffer
 958   ;; model isn't strong enough to allow us to put the images actually
 959   ;; into the tables.
 960   (when (zerop shr-table-depth)
 961     (dolist (elem (shr-find-elements cont 'img))
 962       (shr-tag-img (cdr elem)))))
 963
 964 (defun shr-tag-table (cont)
 965   (shr-ensure-paragraph)
 966   (let* ((caption (cdr (assq 'caption cont)))
 967          (header (cdr (assq 'thead cont)))
 968          (body (or (cdr (assq 'tbody cont)) cont))
 969          (footer (cdr (assq 'tfoot cont)))
 970          (bgcolor (cdr (assq :bgcolor cont)))
 971          (start (point))
 972          (shr-stylesheet (nconc (list (cons 'background-color bgcolor))
 973                                 shr-stylesheet))
 974          (nheader (if header (shr-max-columns header)))
 975          (nbody (if body (shr-max-columns body)))
 976          (nfooter (if footer (shr-max-columns footer))))
 977     (shr-tag-table-1
 978      (nconc
 979       (if caption `((tr (td ,@caption))))
 980       (if header
 981           (if footer
 982               ;; hader + body + footer
 983               (if (= nheader nbody)
 984                   (if (= nbody nfooter)
 985                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 986                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 987                            (if (= nfooter 1)
 988                                footer
 989                              `((tr (td (table (tbody ,@footer))))))))
 990                 (nconc `((tr (td (table (tbody ,@header)))))
 991                        (if (= nbody nfooter)
 992                            `((tr (td (table (tbody ,@body ,@footer)))))
 993                          (nconc `((tr (td (table (tbody ,@body)))))
 994                                 (if (= nfooter 1)
 995                                     footer
 996                                   `((tr (td (table (tbody ,@footer))))))))))
 997             ;; header + body
 998             (if (= nheader nbody)
 999                 `((tr (td (table (tbody ,@header ,@body)))))
1000               (if (= nheader 1)
1001                   `(,@header (tr (td (table (tbody ,@body)))))
1002                 `((tr (td (table (tbody ,@header))))
1003                   (tr (td (table (tbody ,@body))))))))
1004         (if footer
1005             ;; body + footer
1006             (if (= nbody nfooter)
1007                 `((tr (td (table (tbody ,@body ,@footer)))))
1008               (nconc `((tr (td (table (tbody ,@body)))))
1009                      (if (= nfooter 1)
1010                          footer
1011                        `((tr (td (table (tbody ,@footer))))))))
1012           (if caption
1013               `((tr (td (table (tbody ,@body)))))
1014             body)))))
1015     (when bgcolor
1016       (shr-colorize-region start (point) (cdr (assq 'color shr-stylesheet))
1017                            bgcolor))))
1018
1019 (defun shr-find-elements (cont type)
1020   (let (result)
1021     (dolist (elem cont)
1022       (cond ((eq (car elem) type)
1023              (push elem result))
1024             ((consp (cdr elem))
1025              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
1026     (nreverse result)))
1027
1028 (defun shr-insert-table (table widths)
1029   (shr-insert-table-ruler widths)
1030   (dolist (row table)
1031     (let ((start (point))
1032           (height (let ((max 0))
1033                     (dolist (column row)
1034                       (setq max (max max (cadr column))))
1035                     max)))
1036       (dotimes (i height)
1037         (shr-indent)
1038         (insert shr-table-vertical-line "\n"))
1039       (dolist (column row)
1040         (goto-char start)
1041         (let ((lines (nth 2 column))
1042               (overlay-lines (nth 3 column))
1043               overlay overlay-line)
1044           (dolist (line lines)
1045             (setq overlay-line (pop overlay-lines))
1046             (end-of-line)
1047             (insert line shr-table-vertical-line)
1048             (dolist (overlay overlay-line)
1049               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
1050                                      (- (point) (nth 1 overlay) 1)))
1051                     (properties (nth 2 overlay)))
1052                 (while properties
1053                   (overlay-put o (pop properties) (pop properties)))))
1054             (forward-line 1))
1055           ;; Add blank lines at padding at the bottom of the TD,
1056           ;; possibly.
1057           (dotimes (i (- height (length lines)))
1058             (end-of-line)
1059             (let ((start (point)))
1060               (insert (make-string (string-width (car lines)) ? )
1061                       shr-table-vertical-line)
1062               (when (nth 4 column)
1063                 (shr-put-color start (1- (point)) :background (nth 4 column))))
1064             (forward-line 1)))))
1065     (shr-insert-table-ruler widths)))
1066
1067 (defun shr-insert-table-ruler (widths)
1068   (when (and (bolp)
1069              (> shr-indentation 0))
1070     (shr-indent))
1071   (insert shr-table-corner)
1072   (dotimes (i (length widths))
1073     (insert (make-string (aref widths i) shr-table-horizontal-line)
1074             shr-table-corner))
1075   (insert "\n"))
1076
1077 (defun shr-table-widths (table suggested-widths)
1078   (let* ((length (length suggested-widths))
1079          (widths (make-vector length 0))
1080          (natural-widths (make-vector length 0)))
1081     (dolist (row table)
1082       (let ((i 0))
1083         (dolist (column row)
1084           (aset widths i (max (aref widths i)
1085                               (car column)))
1086           (aset natural-widths i (max (aref natural-widths i)
1087                                       (cadr column)))
1088           (setq i (1+ i)))))
1089     (let ((extra (- (apply '+ (append suggested-widths nil))
1090                     (apply '+ (append widths nil))))
1091           (expanded-columns 0))
1092       (when (> extra 0)
1093         (dotimes (i length)
1094           ;; If the natural width is wider than the rendered width, we
1095           ;; want to allow the column to expand.
1096           (when (> (aref natural-widths i) (aref widths i))
1097             (setq expanded-columns (1+ expanded-columns))))
1098         (dotimes (i length)
1099           (when (> (aref natural-widths i) (aref widths i))
1100             (aset widths i (min
1101                             (1+ (aref natural-widths i))
1102                             (+ (/ extra expanded-columns)
1103                                (aref widths i))))))))
1104     widths))
1105
1106 (defun shr-make-table (cont widths &optional fill)
1107   (let ((trs nil))
1108     (dolist (row cont)
1109       (when (eq (car row) 'tr)
1110         (let ((tds nil)
1111               (columns (cdr row))
1112               (i 0)
1113               column)
1114           (while (< i (length widths))
1115             (setq column (pop columns))
1116             (when (or (memq (car column) '(td th))
1117                       (null column))
1118               (push (shr-render-td (cdr column) (aref widths i) fill)
1119                     tds)
1120               (setq i (1+ i))))
1121           (push (nreverse tds) trs))))
1122     (nreverse trs)))
1123
1124 (defun shr-render-td (cont width fill)
1125   (with-temp-buffer
1126     (let ((bgcolor (cdr (assq :bgcolor cont)))
1127           (fgcolor (cdr (assq :fgcolor cont)))
1128           (style (cdr (assq :style cont)))
1129           (shr-stylesheet shr-stylesheet)
1130           overlays actual-colors)
1131       (when style
1132         (setq style (and (string-match "color" style)
1133                          (shr-parse-style style))))
1134       (when bgcolor
1135         (setq style (nconc (list (cons 'background-color bgcolor)) style)))
1136       (when fgcolor
1137         (setq style (nconc (list (cons 'color fgcolor)) style)))
1138       (when style
1139         (setq shr-stylesheet (append style shr-stylesheet)))
1140       (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1141         (if cache
1142             (progn
1143               (insert (car cache))
1144               (let ((end (length (car cache))))
1145                 (dolist (overlay (cadr cache))
1146                   (let ((new-overlay
1147                          (make-overlay (1+ (- end (nth 0 overlay)))
1148                                        (1+ (- end (nth 1 overlay)))))
1149                         (properties (nth 2 overlay)))
1150                     (while properties
1151                       (overlay-put new-overlay
1152                                    (pop properties) (pop properties)))))))
1153           (let ((shr-width width)
1154                 (shr-indentation 0))
1155             (shr-descend (cons 'td cont)))
1156           (delete-region
1157            (point)
1158            (+ (point)
1159               (skip-chars-backward " \t\n")))
1160           (push (list (cons width cont) (buffer-string)
1161                       (shr-overlays-in-region (point-min) (point-max)))
1162                 shr-content-cache)))
1163       (goto-char (point-min))
1164       (let ((max 0))
1165         (while (not (eobp))
1166           (end-of-line)
1167           (setq max (max max (current-column)))
1168           (forward-line 1))
1169         (when fill
1170           (goto-char (point-min))
1171           ;; If the buffer is totally empty, then put a single blank
1172           ;; line here.
1173           (if (zerop (buffer-size))
1174               (insert (make-string width ? ))
1175             ;; Otherwise, fill the buffer.
1176             (while (not (eobp))
1177               (end-of-line)
1178               (when (> (- width (current-column)) 0)
1179                 (insert (make-string (- width (current-column)) ? )))
1180               (forward-line 1)))
1181           (when style
1182             (setq actual-colors
1183                   (shr-colorize-region
1184                    (point-min) (point-max)
1185                    (cdr (assq 'color shr-stylesheet))
1186                    (cdr (assq 'background-color shr-stylesheet))))))
1187         (if fill
1188             (list max
1189                   (count-lines (point-min) (point-max))
1190                   (split-string (buffer-string) "\n")
1191                   (shr-collect-overlays)
1192                   (car actual-colors))
1193           (list max
1194                 (shr-natural-width)))))))
1195
1196 (defun shr-natural-width ()
1197   (goto-char (point-min))
1198   (let ((current 0)
1199         (max 0))
1200     (while (not (eobp))
1201       (end-of-line)
1202       (setq current (+ current (current-column)))
1203       (unless (get-text-property (point) 'shr-break)
1204         (setq max (max max current)
1205               current 0))
1206       (forward-line 1))
1207     max))
1208
1209 (defun shr-collect-overlays ()
1210   (save-excursion
1211     (goto-char (point-min))
1212     (let ((overlays nil))
1213       (while (not (eobp))
1214         (push (shr-overlays-in-region (point) (line-end-position))
1215               overlays)
1216         (forward-line 1))
1217       (nreverse overlays))))
1218
1219 (defun shr-overlays-in-region (start end)
1220   (let (result)
1221     (dolist (overlay (overlays-in start end))
1222       (push (list (if (> start (overlay-start overlay))
1223                       (- end start)
1224                     (- end (overlay-start overlay)))
1225                   (if (< end (overlay-end overlay))
1226                       0
1227                     (- end (overlay-end overlay)))
1228                   (overlay-properties overlay))
1229             result))
1230     (nreverse result)))
1231
1232 (defun shr-pro-rate-columns (columns)
1233   (let ((total-percentage 0)
1234         (widths (make-vector (length columns) 0)))
1235     (dotimes (i (length columns))
1236       (setq total-percentage (+ total-percentage (aref columns i))))
1237     (setq total-percentage (/ 1.0 total-percentage))
1238     (dotimes (i (length columns))
1239       (aset widths i (max (truncate (* (aref columns i)
1240                                        total-percentage
1241                                        (- shr-width (1+ (length columns)))))
1242                           10)))
1243     widths))
1244
1245 ;; Return a summary of the number and shape of the TDs in the table.
1246 (defun shr-column-specs (cont)
1247   (let ((columns (make-vector (shr-max-columns cont) 1)))
1248     (dolist (row cont)
1249       (when (eq (car row) 'tr)
1250         (let ((i 0))
1251           (dolist (column (cdr row))
1252             (when (memq (car column) '(td th))
1253               (let ((width (cdr (assq :width (cdr column)))))
1254                 (when (and width
1255                            (string-match "\\([0-9]+\\)%" width))
1256                   (aset columns i
1257                         (/ (string-to-number (match-string 1 width))
1258                            100.0))))
1259               (setq i (1+ i)))))))
1260     columns))
1261
1262 (defun shr-count (cont elem)
1263   (let ((i 0))
1264     (dolist (sub cont)
1265       (when (eq (car sub) elem)
1266         (setq i (1+ i))))
1267     i))
1268
1269 (defun shr-max-columns (cont)
1270   (let ((max 0))
1271     (dolist (row cont)
1272       (when (eq (car row) 'tr)
1273         (setq max (max max (+ (shr-count (cdr row) 'td)
1274                               (shr-count (cdr row) 'th))))))
1275     max))
1276
1277 (provide 'shr)
1278
1279 ;;; shr.el ends here