cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010, 2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :group 'mail)
  39
  40 (defcustom shr-max-image-proportion 0.9
  41   "How big pictures displayed are in relation to the window they're in.
  42 A value of 0.7 means that they are allowed to take up 70% of the
  43 width and height of the window.  If they are larger than this,
  44 and Emacs supports it, then the images will be rescaled down to
  45 fit these criteria."
  46   :version "24.1"
  47   :group 'shr
  48   :type 'float)
  49
  50 (defcustom shr-blocked-images nil
  51   "Images that have URLs matching this regexp will be blocked."
  52   :version "24.1"
  53   :group 'shr
  54   :type 'regexp)
  55
  56 (defcustom shr-table-horizontal-line ?-
  57   "Character used to draw horizontal table lines."
  58   :group 'shr
  59   :type 'character)
  60
  61 (defcustom shr-table-vertical-line ?|
  62   "Character used to draw vertical table lines."
  63   :group 'shr
  64   :type 'character)
  65
  66 (defcustom shr-table-corner ?+
  67   "Character used to draw table corners."
  68   :group 'shr
  69   :type 'character)
  70
  71 (defcustom shr-hr-line ?-
  72   "Character used to draw hr lines."
  73   :group 'shr
  74   :type 'character)
  75
  76 (defcustom shr-width fill-column
  77   "Frame width to use for rendering.
  78 May either be an integer specifying a fixed width in characters,
  79 or nil, meaning that the full width of the window should be
  80 used."
  81   :type '(choice (integer :tag "Fixed width in characters")
  82                  (const   :tag "Use the width of the window" nil))
  83   :group 'shr)
  84
  85 (defvar shr-content-function nil
  86   "If bound, this should be a function that will return the content.
  87 This is used for cid: URLs, and the function is called with the
  88 cid: URL as the argument.")
  89
  90 ;;; Internal variables.
  91
  92 (defvar shr-folding-mode nil)
  93 (defvar shr-state nil)
  94 (defvar shr-start nil)
  95 (defvar shr-indentation 0)
  96 (defvar shr-inhibit-images nil)
  97 (defvar shr-list-mode nil)
  98 (defvar shr-content-cache nil)
  99 (defvar shr-kinsoku-shorten nil)
 100 (defvar shr-table-depth 0)
 101 (defvar shr-stylesheet nil)
 102
 103 (defvar shr-map
 104   (let ((map (make-sparse-keymap)))
 105     (define-key map "a" 'shr-show-alt-text)
 106     (define-key map "i" 'shr-browse-image)
 107     (define-key map "I" 'shr-insert-image)
 108     (define-key map "u" 'shr-copy-url)
 109     (define-key map "v" 'shr-browse-url)
 110     (define-key map "o" 'shr-save-contents)
 111     (define-key map "\r" 'shr-browse-url)
 112     map))
 113
 114 ;; Public functions and commands.
 115
 116 ;;;###autoload
 117 (defun shr-insert-document (dom)
 118   (setq shr-content-cache nil)
 119   (let ((shr-state nil)
 120         (shr-start nil)
 121         (shr-width (or shr-width (window-width))))
 122     (shr-descend (shr-transform-dom dom))))
 123
 124 (defun shr-copy-url ()
 125   "Copy the URL under point to the kill ring.
 126 If called twice, then try to fetch the URL and see whether it
 127 redirects somewhere else."
 128   (interactive)
 129   (let ((url (get-text-property (point) 'shr-url)))
 130     (cond
 131      ((not url)
 132       (message "No URL under point"))
 133      ;; Resolve redirected URLs.
 134      ((equal url (car kill-ring))
 135       (url-retrieve
 136        url
 137        (lambda (a)
 138          (when (and (consp a)
 139                     (eq (car a) :redirect))
 140            (with-temp-buffer
 141              (insert (cadr a))
 142              (goto-char (point-min))
 143              ;; Remove common tracking junk from the URL.
 144              (when (re-search-forward ".utm_.*" nil t)
 145                (replace-match "" t t))
 146              (message "Copied %s" (buffer-string))
 147              (copy-region-as-kill (point-min) (point-max)))))))
 148      ;; Copy the URL to the kill ring.
 149      (t
 150       (with-temp-buffer
 151         (insert url)
 152         (copy-region-as-kill (point-min) (point-max))
 153         (message "Copied %s" url))))))
 154
 155 (defun shr-show-alt-text ()
 156   "Show the ALT text of the image under point."
 157   (interactive)
 158   (let ((text (get-text-property (point) 'shr-alt)))
 159     (if (not text)
 160         (message "No image under point")
 161       (message "%s" text))))
 162
 163 (defun shr-browse-image ()
 164   "Browse the image under point."
 165   (interactive)
 166   (let ((url (get-text-property (point) 'image-url)))
 167     (if (not url)
 168         (message "No image under point")
 169       (message "Browsing %s..." url)
 170       (browse-url url))))
 171
 172 (defun shr-insert-image ()
 173   "Insert the image under point into the buffer."
 174   (interactive)
 175   (let ((url (get-text-property (point) 'image-url)))
 176     (if (not url)
 177         (message "No image under point")
 178       (message "Inserting %s..." url)
 179       (url-retrieve url 'shr-image-fetched
 180                     (list (current-buffer) (1- (point)) (point-marker))
 181                     t))))
 182
 183 ;;; Utility functions.
 184
 185 (defun shr-transform-dom (dom)
 186   (let ((result (list (pop dom))))
 187     (dolist (arg (pop dom))
 188       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 189                   (cdr arg))
 190             result))
 191     (dolist (sub dom)
 192       (if (stringp sub)
 193           (push (cons 'text sub) result)
 194         (push (shr-transform-dom sub) result)))
 195     (nreverse result)))
 196
 197 (defun shr-descend (dom)
 198   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 199         (style (cdr (assq :style (cdr dom))))
 200         (shr-stylesheet shr-stylesheet)
 201         (start (point)))
 202     (when style
 203       (if (string-match "color" style)
 204           (setq shr-stylesheet (nconc (shr-parse-style style)
 205                                       shr-stylesheet))
 206         (setq style nil)))
 207     (if (fboundp function)
 208         (funcall function (cdr dom))
 209       (shr-generic (cdr dom)))
 210     ;; If style is set, then this node has set the color.
 211     (when style
 212       (shr-colorize-region start (point)
 213                            (cdr (assq 'color shr-stylesheet))
 214                            (cdr (assq 'background-color shr-stylesheet))))))
 215
 216 (defun shr-generic (cont)
 217   (dolist (sub cont)
 218     (cond
 219      ((eq (car sub) 'text)
 220       (shr-insert (cdr sub)))
 221      ((listp (cdr sub))
 222       (shr-descend sub)))))
 223
 224 (defmacro shr-char-breakable-p (char)
 225   "Return non-nil if a line can be broken before and after CHAR."
 226   `(aref fill-find-break-point-function-table ,char))
 227 (defmacro shr-char-nospace-p (char)
 228   "Return non-nil if no space is required before and after CHAR."
 229   `(aref fill-nospace-between-words-table ,char))
 230
 231 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 232 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 233 ;; parentheses, and so on, that should not be placed in the beginning
 234 ;; of a line or the end of a line.
 235 (defmacro shr-char-kinsoku-bol-p (char)
 236   "Return non-nil if a line ought not to begin with CHAR."
 237   `(aref (char-category-set ,char) ?>))
 238 (defmacro shr-char-kinsoku-eol-p (char)
 239   "Return non-nil if a line ought not to end with CHAR."
 240   `(aref (char-category-set ,char) ?<))
 241 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 242   (load "kinsoku" nil t))
 243
 244 (defun shr-insert (text)
 245   (when (and (eq shr-state 'image)
 246              (not (string-match "\\`[ \t\n]+\\'" text)))
 247     (insert "\n")
 248     (setq shr-state nil))
 249   (cond
 250    ((eq shr-folding-mode 'none)
 251     (insert text))
 252    (t
 253     (when (and (string-match "\\`[ \t\n]" text)
 254                (not (bolp))
 255                (not (eq (char-after (1- (point))) ? )))
 256       (insert " "))
 257     (dolist (elem (split-string text))
 258       (when (and (bolp)
 259                  (> shr-indentation 0))
 260         (shr-indent))
 261       ;; No space is needed behind a wide character categorized as
 262       ;; kinsoku-bol, between characters both categorized as nospace,
 263       ;; or at the beginning of a line.
 264       (let (prev)
 265         (when (and (> (current-column) shr-indentation)
 266                    (eq (preceding-char) ? )
 267                    (or (= (line-beginning-position) (1- (point)))
 268                        (and (shr-char-breakable-p
 269                              (setq prev (char-after (- (point) 2))))
 270                             (shr-char-kinsoku-bol-p prev))
 271                        (and (shr-char-nospace-p prev)
 272                             (shr-char-nospace-p (aref elem 0)))))
 273           (delete-char -1)))
 274       ;; The shr-start is a special variable that is used to pass
 275       ;; upwards the first point in the buffer where the text really
 276       ;; starts.
 277       (unless shr-start
 278         (setq shr-start (point)))
 279       (insert elem)
 280       (let (found)
 281         (while (and (> (current-column) shr-width)
 282                     (progn
 283                       (setq found (shr-find-fill-point))
 284                       (not (eolp))))
 285           (when (eq (preceding-char) ? )
 286             (delete-char -1))
 287           (insert "\n")
 288           (unless found
 289             (put-text-property (1- (point)) (point) 'shr-break t)
 290             ;; No space is needed at the beginning of a line.
 291             (when (eq (following-char) ? )
 292               (delete-char 1)))
 293           (when (> shr-indentation 0)
 294             (shr-indent))
 295           (end-of-line))
 296         (insert " ")))
 297     (unless (string-match "[ \t\n]\\'" text)
 298       (delete-char -1)))))
 299
 300 (defun shr-find-fill-point ()
 301   (when (> (move-to-column shr-width) shr-width)
 302     (backward-char 1))
 303   (let ((bp (point))
 304         failed)
 305     (while (not (or (setq failed (= (current-column) shr-indentation))
 306                     (eq (preceding-char) ? )
 307                     (eq (following-char) ? )
 308                     (shr-char-breakable-p (preceding-char))
 309                     (shr-char-breakable-p (following-char))
 310                     (if (eq (preceding-char) ?')
 311                         (not (memq (char-after (- (point) 2))
 312                                    (list nil ?\n ? )))
 313                       (and (shr-char-kinsoku-bol-p (preceding-char))
 314                            (shr-char-breakable-p (following-char))
 315                            (not (shr-char-kinsoku-bol-p (following-char)))))
 316                     (shr-char-kinsoku-eol-p (following-char))))
 317       (backward-char 1))
 318     (if (and (not (or failed (eolp)))
 319              (eq (preceding-char) ?'))
 320         (while (not (or (setq failed (eolp))
 321                         (eq (following-char) ? )
 322                         (shr-char-breakable-p (following-char))
 323                         (shr-char-kinsoku-eol-p (following-char))))
 324           (forward-char 1)))
 325     (if failed
 326         ;; There's no breakable point, so we give it up.
 327         (let (found)
 328           (goto-char bp)
 329           (unless shr-kinsoku-shorten
 330             (while (and (setq found (re-search-forward
 331                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 332                                      (line-end-position) 'move))
 333                         (eq (preceding-char) ?')))
 334             (if (and found (not (match-beginning 1)))
 335                 (goto-char (match-beginning 0)))))
 336       (or
 337        (eolp)
 338        ;; Don't put kinsoku-bol characters at the beginning of a line,
 339        ;; or kinsoku-eol characters at the end of a line.
 340        (cond
 341         (shr-kinsoku-shorten
 342          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 343                      (shr-char-kinsoku-eol-p (preceding-char)))
 344            (backward-char 1))
 345          (when (setq failed (= (current-column) shr-indentation))
 346            ;; There's no breakable point that doesn't violate kinsoku,
 347            ;; so we look for the second best position.
 348            (while (and (progn
 349                          (forward-char 1)
 350                          (<= (current-column) shr-width))
 351                        (progn
 352                          (setq bp (point))
 353                          (shr-char-kinsoku-eol-p (following-char)))))
 354            (goto-char bp)))
 355         ((shr-char-kinsoku-eol-p (preceding-char))
 356          (if (shr-char-kinsoku-eol-p (following-char))
 357              ;; There are consecutive kinsoku-eol characters.
 358              (setq failed t)
 359            (let ((count 4))
 360              (while
 361                  (progn
 362                    (backward-char 1)
 363                    (and (> (setq count (1- count)) 0)
 364                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 365                         (or (shr-char-kinsoku-eol-p (preceding-char))
 366                             (shr-char-kinsoku-bol-p (following-char)))))))
 367            (if (setq failed (= (current-column) shr-indentation))
 368                ;; There's no breakable point that doesn't violate kinsoku,
 369                ;; so we go to the second best position.
 370                (if (looking-at "\\(\\c<+\\)\\c<")
 371                    (goto-char (match-end 1))
 372                  (forward-char 1)))))
 373         (t
 374          (if (shr-char-kinsoku-bol-p (preceding-char))
 375              ;; There are consecutive kinsoku-bol characters.
 376              (setq failed t)
 377            (let ((count 4))
 378              (while (and (>= (setq count (1- count)) 0)
 379                          (shr-char-kinsoku-bol-p (following-char))
 380                          (shr-char-breakable-p (following-char)))
 381                (forward-char 1))))))
 382        (when (eq (following-char) ? )
 383          (forward-char 1))))
 384     (not failed)))
 385
 386 (defun shr-ensure-newline ()
 387   (unless (zerop (current-column))
 388     (insert "\n")))
 389
 390 (defun shr-ensure-paragraph ()
 391   (unless (bobp)
 392     (if (<= (current-column) shr-indentation)
 393         (unless (save-excursion
 394                   (forward-line -1)
 395                   (looking-at " *$"))
 396           (insert "\n"))
 397       (if (save-excursion
 398             (beginning-of-line)
 399             (looking-at " *$"))
 400           (insert "\n")
 401         (insert "\n\n")))))
 402
 403 (defun shr-indent ()
 404   (when (> shr-indentation 0)
 405     (insert (make-string shr-indentation ? ))))
 406
 407 (defun shr-fontize-cont (cont &rest types)
 408   (let (shr-start)
 409     (shr-generic cont)
 410     (dolist (type types)
 411       (shr-add-font (or shr-start (point)) (point) type))))
 412
 413 ;; Add an overlay in the region, but avoid putting the font properties
 414 ;; on blank text at the start of the line, and the newline at the end,
 415 ;; to avoid ugliness.
 416 (defun shr-add-font (start end type)
 417   (save-excursion
 418     (goto-char start)
 419     (while (< (point) end)
 420       (when (bolp)
 421         (skip-chars-forward " "))
 422       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 423         (overlay-put overlay 'face type))
 424       (if (< (line-end-position) end)
 425           (forward-line 1)
 426         (goto-char end)))))
 427
 428 (defun shr-browse-url ()
 429   "Browse the URL under point."
 430   (interactive)
 431   (let ((url (get-text-property (point) 'shr-url)))
 432     (cond
 433      ((not url)
 434       (message "No link under point"))
 435      ((string-match "^mailto:" url)
 436       (browse-url-mailto url))
 437      (t
 438       (browse-url url)))))
 439
 440 (defun shr-save-contents (directory)
 441   "Save the contents from URL in a file."
 442   (interactive "DSave contents of URL to directory: ")
 443   (let ((url (get-text-property (point) 'shr-url)))
 444     (if (not url)
 445         (message "No link under point")
 446       (url-retrieve (shr-encode-url url)
 447                     'shr-store-contents (list url directory)))))
 448
 449 (defun shr-store-contents (status url directory)
 450   (unless (plist-get status :error)
 451     (when (or (search-forward "\n\n" nil t)
 452               (search-forward "\r\n\r\n" nil t))
 453       (write-region (point) (point-max)
 454                     (expand-file-name (file-name-nondirectory url)
 455                                       directory)))))
 456
 457 (defun shr-image-fetched (status buffer start end)
 458   (when (and (buffer-name buffer)
 459              (not (plist-get status :error)))
 460     (url-store-in-cache (current-buffer))
 461     (when (or (search-forward "\n\n" nil t)
 462               (search-forward "\r\n\r\n" nil t))
 463       (let ((data (buffer-substring (point) (point-max))))
 464         (with-current-buffer buffer
 465           (save-excursion
 466             (let ((alt (buffer-substring start end))
 467                   (inhibit-read-only t))
 468               (delete-region start end)
 469               (goto-char start)
 470               (shr-put-image data alt))))))))
 471
 472 (defun shr-put-image (data alt)
 473   (if (display-graphic-p)
 474       (let ((image (ignore-errors
 475                      (shr-rescale-image data))))
 476         (when image
 477           ;; When inserting big-ish pictures, put them at the
 478           ;; beginning of the line.
 479           (when (and (> (current-column) 0)
 480                      (> (car (image-size image t)) 400))
 481             (insert "\n"))
 482           (insert-image image (or alt "*"))))
 483     (insert alt)))
 484
 485 (defun shr-rescale-image (data)
 486   (if (or (not (fboundp 'imagemagick-types))
 487           (not (get-buffer-window (current-buffer))))
 488       (create-image data nil t)
 489     (let* ((image (create-image data nil t))
 490            (size (image-size image t))
 491            (width (car size))
 492            (height (cdr size))
 493            (edges (window-inside-pixel-edges
 494                    (get-buffer-window (current-buffer))))
 495            (window-width (truncate (* shr-max-image-proportion
 496                                       (- (nth 2 edges) (nth 0 edges)))))
 497            (window-height (truncate (* shr-max-image-proportion
 498                                        (- (nth 3 edges) (nth 1 edges)))))
 499            scaled-image)
 500       (when (> height window-height)
 501         (setq image (or (create-image data 'imagemagick t
 502                                       :height window-height)
 503                         image))
 504         (setq size (image-size image t)))
 505       (when (> (car size) window-width)
 506         (setq image (or
 507                      (create-image data 'imagemagick t
 508                                    :width window-width)
 509                      image)))
 510       (when (and (fboundp 'create-animated-image)
 511                  (eq (image-type data nil t) 'gif))
 512         (setq image (create-animated-image data 'gif t)))
 513       image)))
 514
 515 ;; url-cache-extract autoloads url-cache.
 516 (declare-function url-cache-create-filename "url-cache" (url))
 517 (autoload 'mm-disable-multibyte "mm-util")
 518 (autoload 'browse-url-mailto "browse-url")
 519
 520 (defun shr-get-image-data (url)
 521   "Get image data for URL.
 522 Return a string with image data."
 523   (with-temp-buffer
 524     (mm-disable-multibyte)
 525     (when (ignore-errors
 526             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 527             t)
 528       (when (or (search-forward "\n\n" nil t)
 529                 (search-forward "\r\n\r\n" nil t))
 530         (buffer-substring (point) (point-max))))))
 531
 532 (defun shr-image-displayer (content-function)
 533   "Return a function to display an image.
 534 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 535 is an argument.  The function to be returned takes three arguments URL,
 536 START, and END.  Note that START and END should be merkers."
 537   `(lambda (url start end)
 538      (when url
 539        (if (string-match "\\`cid:" url)
 540            ,(when content-function
 541               `(let ((image (funcall ,content-function
 542                                      (substring url (match-end 0)))))
 543                  (when image
 544                    (goto-char start)
 545                    (shr-put-image image
 546                                   (buffer-substring-no-properties start end))
 547                    (delete-region (point) end))))
 548          (url-retrieve url 'shr-image-fetched
 549                        (list (current-buffer) start end)
 550                        t)))))
 551
 552 (defun shr-heading (cont &rest types)
 553   (shr-ensure-paragraph)
 554   (apply #'shr-fontize-cont cont types)
 555   (shr-ensure-paragraph))
 556
 557 (autoload 'widget-convert-button "wid-edit")
 558
 559 (defun shr-urlify (start url &optional title)
 560   (widget-convert-button
 561    'url-link start (point)
 562    :help-echo (if title (format "%s (%s)" url title) url)
 563    :keymap shr-map
 564    url)
 565   (put-text-property start (point) 'shr-url url))
 566
 567 (defun shr-encode-url (url)
 568   "Encode URL."
 569   (browse-url-url-encode-chars url "[)$ ]"))
 570
 571 (autoload 'shr-color-visible "shr-color")
 572 (autoload 'shr-color->hexadecimal "shr-color")
 573
 574 (defun shr-color-check (fg bg)
 575   "Check that FG is visible on BG.
 576 Returns (fg bg) with corrected values.
 577 Returns nil if the colors that would be used are the default
 578 ones, in case fg and bg are nil."
 579   (when (or fg bg)
 580     (let ((fixed (cond ((null fg) 'fg)
 581                        ((null bg) 'bg))))
 582       ;; Convert colors to hexadecimal, or set them to default.
 583       (let ((fg (or (shr-color->hexadecimal fg)
 584                     (frame-parameter nil 'foreground-color)))
 585             (bg (or (shr-color->hexadecimal bg)
 586                     (frame-parameter nil 'background-color))))
 587         (cond ((eq fixed 'bg)
 588                ;; Only return the new fg
 589                (list nil (cadr (shr-color-visible bg fg t))))
 590               ((eq fixed 'fg)
 591                ;; Invert args and results and return only the new bg
 592                (list (cadr (shr-color-visible fg bg t)) nil))
 593               (t
 594                (shr-color-visible bg fg)))))))
 595
 596 (defun shr-colorize-region (start end fg &optional bg)
 597   (when (or fg bg)
 598     (let ((new-colors (shr-color-check fg bg)))
 599       (when new-colors
 600         (when fg
 601           (shr-put-color start end :foreground (cadr new-colors)))
 602         (when bg
 603           (shr-put-color start end :background (car new-colors)))))))
 604
 605 ;; Put a color in the region, but avoid putting colors on on blank
 606 ;; text at the start of the line, and the newline at the end, to avoid
 607 ;; ugliness.  Also, don't overwrite any existing color information,
 608 ;; since this can be called recursively, and we want the "inner" color
 609 ;; to win.
 610 (defun shr-put-color (start end type color)
 611   (save-excursion
 612     (goto-char start)
 613     (while (< (point) end)
 614       (when (bolp)
 615         (skip-chars-forward " "))
 616       (when (> (line-end-position) (point))
 617         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 618       (if (< (line-end-position) end)
 619           (forward-line 1)
 620         (goto-char end)))))
 621
 622 (defun shr-put-color-1 (start end type color)
 623   (let* ((old-props (get-text-property start 'face))
 624          (do-put (not (memq type old-props)))
 625          change)
 626     (while (< start end)
 627       (setq change (next-single-property-change start 'face nil end))
 628       (when do-put
 629         (put-text-property start change 'face
 630                            (nconc (list type color) old-props)))
 631       (setq old-props (get-text-property change 'face))
 632       (setq do-put (not (memq type old-props)))
 633       (setq start change))
 634     (when (and do-put
 635                (> end start))
 636       (put-text-property start end 'face
 637                          (nconc (list type color old-props))))))
 638
 639 ;;; Tag-specific rendering rules.
 640
 641 (defun shr-tag-body (cont)
 642   (let* ((start (point))
 643          (fgcolor (cdr (assq :fgcolor cont)))
 644          (bgcolor (cdr (assq :bgcolor cont)))
 645          (shr-stylesheet (list (cons 'color fgcolor)
 646                                (cons 'background-color bgcolor))))
 647     (shr-generic cont)
 648     (shr-colorize-region start (point) fgcolor bgcolor)))
 649
 650 (defun shr-tag-style (cont)
 651   )
 652
 653 (defun shr-tag-script (cont)
 654   )
 655
 656 (defun shr-tag-label (cont)
 657   (shr-generic cont)
 658   (shr-ensure-paragraph))
 659
 660 (defun shr-tag-p (cont)
 661   (shr-ensure-paragraph)
 662   (shr-indent)
 663   (shr-generic cont)
 664   (shr-ensure-paragraph))
 665
 666 (defun shr-tag-div (cont)
 667   (shr-ensure-newline)
 668   (shr-indent)
 669   (shr-generic cont)
 670   (shr-ensure-newline))
 671
 672 (defun shr-tag-b (cont)
 673   (shr-fontize-cont cont 'bold))
 674
 675 (defun shr-tag-i (cont)
 676   (shr-fontize-cont cont 'italic))
 677
 678 (defun shr-tag-em (cont)
 679   (shr-fontize-cont cont 'bold))
 680
 681 (defun shr-tag-strong (cont)
 682   (shr-fontize-cont cont 'bold))
 683
 684 (defun shr-tag-u (cont)
 685   (shr-fontize-cont cont 'underline))
 686
 687 (defun shr-tag-s (cont)
 688   (shr-fontize-cont cont 'strike-through))
 689
 690 (defun shr-parse-style (style)
 691   (when style
 692     (save-match-data
 693       (when (string-match "\n" style)
 694         (setq style (replace-match " " t t style))))
 695     (let ((plist nil))
 696       (dolist (elem (split-string style ";"))
 697         (when elem
 698           (setq elem (split-string elem ":"))
 699           (when (and (car elem)
 700                      (cadr elem))
 701             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 702                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 703               (when (string-match " *!important\\'" value)
 704                 (setq value (substring value 0 (match-beginning 0))))
 705               (push (cons (intern name obarray)
 706                           value)
 707                     plist)))))
 708       plist)))
 709
 710 (defun shr-tag-a (cont)
 711   (let ((url (cdr (assq :href cont)))
 712         (title (cdr (assq :title cont)))
 713         (start (point))
 714         shr-start)
 715     (shr-generic cont)
 716     (shr-urlify (or shr-start start) url title)))
 717
 718 (defun shr-tag-object (cont)
 719   (let ((start (point))
 720         url)
 721     (dolist (elem cont)
 722       (when (eq (car elem) 'embed)
 723         (setq url (or url (cdr (assq :src (cdr elem))))))
 724       (when (and (eq (car elem) 'param)
 725                  (equal (cdr (assq :name (cdr elem))) "movie"))
 726         (setq url (or url (cdr (assq :value (cdr elem)))))))
 727     (when url
 728       (shr-insert " [multimedia] ")
 729       (shr-urlify start url))
 730     (shr-generic cont)))
 731
 732 (defun shr-tag-video (cont)
 733   (let ((image (cdr (assq :poster cont)))
 734         (url (cdr (assq :src cont)))
 735         (start (point)))
 736     (shr-tag-img nil image)
 737     (shr-urlify start url)))
 738
 739 (defun shr-tag-img (cont &optional url)
 740   (when (or url
 741             (and cont
 742                  (cdr (assq :src cont))))
 743     (when (and (> (current-column) 0)
 744                (not (eq shr-state 'image)))
 745       (insert "\n"))
 746     (let ((alt (cdr (assq :alt cont)))
 747           (url (or url (cdr (assq :src cont)))))
 748       (let ((start (point-marker)))
 749         (when (zerop (length alt))
 750           (setq alt "*"))
 751         (cond
 752          ((or (member (cdr (assq :height cont)) '("0" "1"))
 753               (member (cdr (assq :width cont)) '("0" "1")))
 754           ;; Ignore zero-sized or single-pixel images.
 755           )
 756          ((and (not shr-inhibit-images)
 757                (string-match "\\`cid:" url))
 758           (let ((url (substring url (match-end 0)))
 759                 image)
 760             (if (or (not shr-content-function)
 761                     (not (setq image (funcall shr-content-function url))))
 762                 (insert alt)
 763               (shr-put-image image alt))))
 764          ((or shr-inhibit-images
 765               (and shr-blocked-images
 766                    (string-match shr-blocked-images url)))
 767           (setq shr-start (point))
 768           (let ((shr-state 'space))
 769             (if (> (string-width alt) 8)
 770                 (shr-insert (truncate-string-to-width alt 8))
 771               (shr-insert alt))))
 772          ((url-is-cached (shr-encode-url url))
 773           (shr-put-image (shr-get-image-data url) alt))
 774          (t
 775           (insert alt)
 776           (ignore-errors
 777             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 778                           (list (current-buffer) start (point-marker))
 779                           t))))
 780         (put-text-property start (point) 'keymap shr-map)
 781         (put-text-property start (point) 'shr-alt alt)
 782         (put-text-property start (point) 'image-url url)
 783         (put-text-property start (point) 'image-displayer
 784                            (shr-image-displayer shr-content-function))
 785         (put-text-property start (point) 'help-echo alt)
 786         (setq shr-state 'image)))))
 787
 788 (defun shr-tag-pre (cont)
 789   (let ((shr-folding-mode 'none))
 790     (shr-ensure-newline)
 791     (shr-indent)
 792     (shr-generic cont)
 793     (shr-ensure-newline)))
 794
 795 (defun shr-tag-blockquote (cont)
 796   (shr-ensure-paragraph)
 797   (shr-indent)
 798   (let ((shr-indentation (+ shr-indentation 4)))
 799     (shr-generic cont))
 800   (shr-ensure-paragraph))
 801
 802 (defun shr-tag-ul (cont)
 803   (shr-ensure-paragraph)
 804   (let ((shr-list-mode 'ul))
 805     (shr-generic cont))
 806   (shr-ensure-paragraph))
 807
 808 (defun shr-tag-ol (cont)
 809   (shr-ensure-paragraph)
 810   (let ((shr-list-mode 1))
 811     (shr-generic cont))
 812   (shr-ensure-paragraph))
 813
 814 (defun shr-tag-li (cont)
 815   (shr-ensure-paragraph)
 816   (shr-indent)
 817   (let* ((bullet
 818           (if (numberp shr-list-mode)
 819               (prog1
 820                   (format "%d " shr-list-mode)
 821                 (setq shr-list-mode (1+ shr-list-mode)))
 822             "* "))
 823          (shr-indentation (+ shr-indentation (length bullet))))
 824     (insert bullet)
 825     (shr-generic cont)))
 826
 827 (defun shr-tag-br (cont)
 828   (unless (bobp)
 829     (insert "\n")
 830     (shr-indent))
 831   (shr-generic cont))
 832
 833 (defun shr-tag-h1 (cont)
 834   (shr-heading cont 'bold 'underline))
 835
 836 (defun shr-tag-h2 (cont)
 837   (shr-heading cont 'bold))
 838
 839 (defun shr-tag-h3 (cont)
 840   (shr-heading cont 'italic))
 841
 842 (defun shr-tag-h4 (cont)
 843   (shr-heading cont))
 844
 845 (defun shr-tag-h5 (cont)
 846   (shr-heading cont))
 847
 848 (defun shr-tag-h6 (cont)
 849   (shr-heading cont))
 850
 851 (defun shr-tag-hr (cont)
 852   (shr-ensure-newline)
 853   (insert (make-string shr-width shr-hr-line) "\n"))
 854
 855 (defun shr-tag-title (cont)
 856   (shr-heading cont 'bold 'underline))
 857
 858 (defun shr-tag-font (cont)
 859   (let* ((start (point))
 860          (color (cdr (assq :color cont)))
 861          (shr-stylesheet (nconc (list (cons 'color color))
 862                                 shr-stylesheet)))
 863     (shr-generic cont)
 864     (when color
 865       (shr-colorize-region start (point) color
 866                            (cdr (assq 'background-color shr-stylesheet))))))
 867
 868 ;;; Table rendering algorithm.
 869
 870 ;; Table rendering is the only complicated thing here.  We do this by
 871 ;; first counting how many TDs there are in each TR, and registering
 872 ;; how wide they think they should be ("width=45%", etc).  Then we
 873 ;; render each TD separately (this is done in temporary buffers, so
 874 ;; that we can use all the rendering machinery as if we were in the
 875 ;; main buffer).  Now we know how much space each TD really takes, so
 876 ;; we then render everything again with the new widths, and finally
 877 ;; insert all these boxes into the main buffer.
 878 (defun shr-tag-table-1 (cont)
 879   (setq cont (or (cdr (assq 'tbody cont))
 880                  cont))
 881   (let* ((shr-inhibit-images t)
 882          (shr-table-depth (1+ shr-table-depth))
 883          (shr-kinsoku-shorten t)
 884          ;; Find all suggested widths.
 885          (columns (shr-column-specs cont))
 886          ;; Compute how many characters wide each TD should be.
 887          (suggested-widths (shr-pro-rate-columns columns))
 888          ;; Do a "test rendering" to see how big each TD is (this can
 889          ;; be smaller (if there's little text) or bigger (if there's
 890          ;; unbreakable text).
 891          (sketch (shr-make-table cont suggested-widths))
 892          (sketch-widths (shr-table-widths sketch suggested-widths)))
 893     ;; This probably won't work very well.
 894     (when (> (+ (loop for width across sketch-widths
 895                       summing (1+ width))
 896                 shr-indentation 1)
 897              (frame-width))
 898       (setq truncate-lines t))
 899     ;; Then render the table again with these new "hard" widths.
 900     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 901   ;; Finally, insert all the images after the table.  The Emacs buffer
 902   ;; model isn't strong enough to allow us to put the images actually
 903   ;; into the tables.
 904   (when (zerop shr-table-depth)
 905     (dolist (elem (shr-find-elements cont 'img))
 906       (shr-tag-img (cdr elem)))))
 907
 908 (defun shr-tag-table (cont)
 909   (shr-ensure-paragraph)
 910   (let* ((caption (cdr (assq 'caption cont)))
 911          (header (cdr (assq 'thead cont)))
 912          (body (or (cdr (assq 'tbody cont)) cont))
 913          (footer (cdr (assq 'tfoot cont)))
 914          (bgcolor (cdr (assq :bgcolor cont)))
 915          (start (point))
 916          (shr-stylesheet (nconc (list (cons 'background-color bgcolor))
 917                                 shr-stylesheet))
 918          (nheader (if header (shr-max-columns header)))
 919          (nbody (if body (shr-max-columns body)))
 920          (nfooter (if footer (shr-max-columns footer))))
 921     (shr-tag-table-1
 922      (nconc
 923       (if caption `((tr (td ,@caption))))
 924       (if header
 925           (if footer
 926               ;; hader + body + footer
 927               (if (= nheader nbody)
 928                   (if (= nbody nfooter)
 929                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 930                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 931                            (if (= nfooter 1)
 932                                footer
 933                              `((tr (td (table (tbody ,@footer))))))))
 934                 (nconc `((tr (td (table (tbody ,@header)))))
 935                        (if (= nbody nfooter)
 936                            `((tr (td (table (tbody ,@body ,@footer)))))
 937                          (nconc `((tr (td (table (tbody ,@body)))))
 938                                 (if (= nfooter 1)
 939                                     footer
 940                                   `((tr (td (table (tbody ,@footer))))))))))
 941             ;; header + body
 942             (if (= nheader nbody)
 943                 `((tr (td (table (tbody ,@header ,@body)))))
 944               (if (= nheader 1)
 945                   `(,@header (tr (td (table (tbody ,@body)))))
 946                 `((tr (td (table (tbody ,@header))))
 947                   (tr (td (table (tbody ,@body))))))))
 948         (if footer
 949             ;; body + footer
 950             (if (= nbody nfooter)
 951                 `((tr (td (table (tbody ,@body ,@footer)))))
 952               (nconc `((tr (td (table (tbody ,@body)))))
 953                      (if (= nfooter 1)
 954                          footer
 955                        `((tr (td (table (tbody ,@footer))))))))
 956           (if caption
 957               `((tr (td (table (tbody ,@body)))))
 958             body)))))
 959     (when bgcolor
 960       (shr-colorize-region start (point) (cdr (assq 'color shr-stylesheet))
 961                            bgcolor))))
 962
 963 (defun shr-find-elements (cont type)
 964   (let (result)
 965     (dolist (elem cont)
 966       (cond ((eq (car elem) type)
 967              (push elem result))
 968             ((consp (cdr elem))
 969              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 970     (nreverse result)))
 971
 972 (defun shr-insert-table (table widths)
 973   (shr-insert-table-ruler widths)
 974   (dolist (row table)
 975     (let ((start (point))
 976           (height (let ((max 0))
 977                     (dolist (column row)
 978                       (setq max (max max (cadr column))))
 979                     max)))
 980       (dotimes (i height)
 981         (shr-indent)
 982         (insert shr-table-vertical-line "\n"))
 983       (dolist (column row)
 984         (goto-char start)
 985         (let ((lines (nth 2 column))
 986               (overlay-lines (nth 3 column))
 987               overlay overlay-line)
 988           (dolist (line lines)
 989             (setq overlay-line (pop overlay-lines))
 990             (end-of-line)
 991             (insert line shr-table-vertical-line)
 992             (dolist (overlay overlay-line)
 993               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 994                                      (- (point) (nth 1 overlay) 1)))
 995                     (properties (nth 2 overlay)))
 996                 (while properties
 997                   (overlay-put o (pop properties) (pop properties)))))
 998             (forward-line 1))
 999           ;; Add blank lines at padding at the bottom of the TD,
1000           ;; possibly.
1001           (dotimes (i (- height (length lines)))
1002             (end-of-line)
1003             (insert (make-string (string-width (car lines)) ? )
1004                     shr-table-vertical-line)
1005             (forward-line 1)))))
1006     (shr-insert-table-ruler widths)))
1007
1008 (defun shr-insert-table-ruler (widths)
1009   (when (and (bolp)
1010              (> shr-indentation 0))
1011     (shr-indent))
1012   (insert shr-table-corner)
1013   (dotimes (i (length widths))
1014     (insert (make-string (aref widths i) shr-table-horizontal-line)
1015             shr-table-corner))
1016   (insert "\n"))
1017
1018 (defun shr-table-widths (table suggested-widths)
1019   (let* ((length (length suggested-widths))
1020          (widths (make-vector length 0))
1021          (natural-widths (make-vector length 0)))
1022     (dolist (row table)
1023       (let ((i 0))
1024         (dolist (column row)
1025           (aset widths i (max (aref widths i)
1026                               (car column)))
1027           (aset natural-widths i (max (aref natural-widths i)
1028                                       (cadr column)))
1029           (setq i (1+ i)))))
1030     (let ((extra (- (apply '+ (append suggested-widths nil))
1031                     (apply '+ (append widths nil))))
1032           (expanded-columns 0))
1033       (when (> extra 0)
1034         (dotimes (i length)
1035           ;; If the natural width is wider than the rendered width, we
1036           ;; want to allow the column to expand.
1037           (when (> (aref natural-widths i) (aref widths i))
1038             (setq expanded-columns (1+ expanded-columns))))
1039         (dotimes (i length)
1040           (when (> (aref natural-widths i) (aref widths i))
1041             (aset widths i (min
1042                             (1+ (aref natural-widths i))
1043                             (+ (/ extra expanded-columns)
1044                                (aref widths i))))))))
1045     widths))
1046
1047 (defun shr-make-table (cont widths &optional fill)
1048   (let ((trs nil))
1049     (dolist (row cont)
1050       (when (eq (car row) 'tr)
1051         (let ((tds nil)
1052               (columns (cdr row))
1053               (i 0)
1054               column)
1055           (while (< i (length widths))
1056             (setq column (pop columns))
1057             (when (or (memq (car column) '(td th))
1058                       (null column))
1059               (push (shr-render-td (cdr column) (aref widths i) fill)
1060                     tds)
1061               (setq i (1+ i))))
1062           (push (nreverse tds) trs))))
1063     (nreverse trs)))
1064
1065 (defun shr-render-td (cont width fill)
1066   (with-temp-buffer
1067     (let ((bgcolor (cdr (assq :bgcolor cont)))
1068           (fgcolor (cdr (assq :fgcolor cont)))
1069           (style (cdr (assq :style cont)))
1070           (shr-stylesheet shr-stylesheet)
1071           overlays)
1072       (when style
1073         (setq style (and (string-match "color" style)
1074                          (shr-parse-style style))))
1075       (when bgcolor
1076         (setq style (nconc (list (cons 'background-color bgcolor)) style)))
1077       (when fgcolor
1078         (setq style (nconc (list (cons 'color fgcolor)) style)))
1079       (when style
1080         (setq shr-stylesheet (append style shr-stylesheet)))
1081       (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1082         (if cache
1083             (progn
1084               (insert (car cache))
1085               (let ((end (length (car cache))))
1086                 (dolist (overlay (cadr cache))
1087                   (let ((new-overlay
1088                          (make-overlay (1+ (- end (nth 0 overlay)))
1089                                        (1+ (- end (nth 1 overlay)))))
1090                         (properties (nth 2 overlay)))
1091                     (while properties
1092                       (overlay-put new-overlay
1093                                    (pop properties) (pop properties)))))))
1094           (let ((shr-width width)
1095                 (shr-indentation 0))
1096             (shr-descend (cons 'td cont)))
1097           (delete-region
1098            (point)
1099            (+ (point)
1100               (skip-chars-backward " \t\n")))
1101           (push (list (cons width cont) (buffer-string)
1102                       (shr-overlays-in-region (point-min) (point-max)))
1103                 shr-content-cache)))
1104       (goto-char (point-min))
1105       (let ((max 0))
1106         (while (not (eobp))
1107           (end-of-line)
1108           (setq max (max max (current-column)))
1109           (forward-line 1))
1110         (when fill
1111           (goto-char (point-min))
1112           ;; If the buffer is totally empty, then put a single blank
1113           ;; line here.
1114           (if (zerop (buffer-size))
1115               (insert (make-string width ? ))
1116             ;; Otherwise, fill the buffer.
1117             (while (not (eobp))
1118               (end-of-line)
1119               (when (> (- width (current-column)) 0)
1120                 (insert (make-string (- width (current-column)) ? )))
1121               (forward-line 1))))
1122         (when style
1123           (shr-colorize-region
1124            (point-min) (point-max)
1125            (cdr (assq 'color shr-stylesheet))
1126            (cdr (assq 'background-color shr-stylesheet))))
1127         (if fill
1128             (list max
1129                   (count-lines (point-min) (point-max))
1130                   (split-string (buffer-string) "\n")
1131                   (shr-collect-overlays))
1132           (list max
1133                 (shr-natural-width)))))))
1134
1135 (defun shr-natural-width ()
1136   (goto-char (point-min))
1137   (let ((current 0)
1138         (max 0))
1139     (while (not (eobp))
1140       (end-of-line)
1141       (setq current (+ current (current-column)))
1142       (unless (get-text-property (point) 'shr-break)
1143         (setq max (max max current)
1144               current 0))
1145       (forward-line 1))
1146     max))
1147
1148 (defun shr-collect-overlays ()
1149   (save-excursion
1150     (goto-char (point-min))
1151     (let ((overlays nil))
1152       (while (not (eobp))
1153         (push (shr-overlays-in-region (point) (line-end-position))
1154               overlays)
1155         (forward-line 1))
1156       (nreverse overlays))))
1157
1158 (defun shr-overlays-in-region (start end)
1159   (let (result)
1160     (dolist (overlay (overlays-in start end))
1161       (push (list (if (> start (overlay-start overlay))
1162                       (- end start)
1163                     (- end (overlay-start overlay)))
1164                   (if (< end (overlay-end overlay))
1165                       0
1166                     (- end (overlay-end overlay)))
1167                   (overlay-properties overlay))
1168             result))
1169     (nreverse result)))
1170
1171 (defun shr-pro-rate-columns (columns)
1172   (let ((total-percentage 0)
1173         (widths (make-vector (length columns) 0)))
1174     (dotimes (i (length columns))
1175       (setq total-percentage (+ total-percentage (aref columns i))))
1176     (setq total-percentage (/ 1.0 total-percentage))
1177     (dotimes (i (length columns))
1178       (aset widths i (max (truncate (* (aref columns i)
1179                                        total-percentage
1180                                        (- shr-width (1+ (length columns)))))
1181                           10)))
1182     widths))
1183
1184 ;; Return a summary of the number and shape of the TDs in the table.
1185 (defun shr-column-specs (cont)
1186   (let ((columns (make-vector (shr-max-columns cont) 1)))
1187     (dolist (row cont)
1188       (when (eq (car row) 'tr)
1189         (let ((i 0))
1190           (dolist (column (cdr row))
1191             (when (memq (car column) '(td th))
1192               (let ((width (cdr (assq :width (cdr column)))))
1193                 (when (and width
1194                            (string-match "\\([0-9]+\\)%" width))
1195                   (aset columns i
1196                         (/ (string-to-number (match-string 1 width))
1197                            100.0))))
1198               (setq i (1+ i)))))))
1199     columns))
1200
1201 (defun shr-count (cont elem)
1202   (let ((i 0))
1203     (dolist (sub cont)
1204       (when (eq (car sub) elem)
1205         (setq i (1+ i))))
1206     i))
1207
1208 (defun shr-max-columns (cont)
1209   (let ((max 0))
1210     (dolist (row cont)
1211       (when (eq (car row) 'tr)
1212         (setq max (max max (+ (shr-count (cdr row) 'td)
1213                               (shr-count (cdr row) 'th))))))
1214     max))
1215
1216 (provide 'shr)
1217
1218 ;;; shr.el ends here