cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :group 'mail)
  39
  40 (defcustom shr-max-image-proportion 0.9
  41   "How big pictures displayed are in relation to the window they're in.
  42 A value of 0.7 means that they are allowed to take up 70% of the
  43 width and height of the window.  If they are larger than this,
  44 and Emacs supports it, then the images will be rescaled down to
  45 fit these criteria."
  46   :version "24.1"
  47   :group 'shr
  48   :type 'float)
  49
  50 (defcustom shr-blocked-images nil
  51   "Images that have URLs matching this regexp will be blocked."
  52   :version "24.1"
  53   :group 'shr
  54   :type 'regexp)
  55
  56 (defcustom shr-table-horizontal-line ?-
  57   "Character used to draw horizontal table lines."
  58   :group 'shr
  59   :type 'character)
  60
  61 (defcustom shr-table-vertical-line ?|
  62   "Character used to draw vertical table lines."
  63   :group 'shr
  64   :type 'character)
  65
  66 (defcustom shr-table-corner ?+
  67   "Character used to draw table corners."
  68   :group 'shr
  69   :type 'character)
  70
  71 (defcustom shr-hr-line ?-
  72   "Character used to draw hr lines."
  73   :group 'shr
  74   :type 'character)
  75
  76 (defcustom shr-width fill-column
  77   "Frame width to use for rendering."
  78   :type 'integer
  79   :group 'shr)
  80
  81 (defvar shr-content-function nil
  82   "If bound, this should be a function that will return the content.
  83 This is used for cid: URLs, and the function is called with the
  84 cid: URL as the argument.")
  85
  86 ;;; Internal variables.
  87
  88 (defvar shr-folding-mode nil)
  89 (defvar shr-state nil)
  90 (defvar shr-start nil)
  91 (defvar shr-indentation 0)
  92 (defvar shr-inhibit-images nil)
  93 (defvar shr-list-mode nil)
  94 (defvar shr-content-cache nil)
  95 (defvar shr-kinsoku-shorten nil)
  96 (defvar shr-table-depth 0)
  97 (defvar shr-stylesheet nil)
  98
  99 (defvar shr-map
 100   (let ((map (make-sparse-keymap)))
 101     (define-key map "a" 'shr-show-alt-text)
 102     (define-key map "i" 'shr-browse-image)
 103     (define-key map "I" 'shr-insert-image)
 104     (define-key map "u" 'shr-copy-url)
 105     (define-key map "v" 'shr-browse-url)
 106     (define-key map "o" 'shr-save-contents)
 107     (define-key map "\r" 'shr-browse-url)
 108     map))
 109
 110 ;; Public functions and commands.
 111
 112 ;;;###autoload
 113 (defun shr-insert-document (dom)
 114   (setq shr-content-cache nil)
 115   (let ((shr-state nil)
 116         (shr-start nil))
 117     (shr-descend (shr-transform-dom dom))))
 118
 119 (defun shr-copy-url ()
 120   "Copy the URL under point to the kill ring.
 121 If called twice, then try to fetch the URL and see whether it
 122 redirects somewhere else."
 123   (interactive)
 124   (let ((url (get-text-property (point) 'shr-url)))
 125     (cond
 126      ((not url)
 127       (message "No URL under point"))
 128      ;; Resolve redirected URLs.
 129      ((equal url (car kill-ring))
 130       (url-retrieve
 131        url
 132        (lambda (a)
 133          (when (and (consp a)
 134                     (eq (car a) :redirect))
 135            (with-temp-buffer
 136              (insert (cadr a))
 137              (goto-char (point-min))
 138              ;; Remove common tracking junk from the URL.
 139              (when (re-search-forward ".utm_.*" nil t)
 140                (replace-match "" t t))
 141              (message "Copied %s" (buffer-string))
 142              (copy-region-as-kill (point-min) (point-max)))))))
 143      ;; Copy the URL to the kill ring.
 144      (t
 145       (with-temp-buffer
 146         (insert url)
 147         (copy-region-as-kill (point-min) (point-max))
 148         (message "Copied %s" url))))))
 149
 150 (defun shr-show-alt-text ()
 151   "Show the ALT text of the image under point."
 152   (interactive)
 153   (let ((text (get-text-property (point) 'shr-alt)))
 154     (if (not text)
 155         (message "No image under point")
 156       (message "%s" text))))
 157
 158 (defun shr-browse-image ()
 159   "Browse the image under point."
 160   (interactive)
 161   (let ((url (get-text-property (point) 'image-url)))
 162     (if (not url)
 163         (message "No image under point")
 164       (message "Browsing %s..." url)
 165       (browse-url url))))
 166
 167 (defun shr-insert-image ()
 168   "Insert the image under point into the buffer."
 169   (interactive)
 170   (let ((url (get-text-property (point) 'image-url)))
 171     (if (not url)
 172         (message "No image under point")
 173       (message "Inserting %s..." url)
 174       (url-retrieve url 'shr-image-fetched
 175                     (list (current-buffer) (1- (point)) (point-marker))
 176                     t))))
 177
 178 ;;; Utility functions.
 179
 180 (defun shr-transform-dom (dom)
 181   (let ((result (list (pop dom))))
 182     (dolist (arg (pop dom))
 183       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 184                   (cdr arg))
 185             result))
 186     (dolist (sub dom)
 187       (if (stringp sub)
 188           (push (cons 'text sub) result)
 189         (push (shr-transform-dom sub) result)))
 190     (nreverse result)))
 191
 192 (defun shr-descend (dom)
 193   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 194         (style (cdr (assq :style (cdr dom))))
 195         (shr-stylesheet shr-stylesheet)
 196         (start (point)))
 197     (when style
 198       (if (string-match "color" style)
 199           (setq shr-stylesheet (nconc (shr-parse-style style)
 200                                       shr-stylesheet))
 201         (setq style nil)))
 202     (if (fboundp function)
 203         (funcall function (cdr dom))
 204       (shr-generic (cdr dom)))
 205     ;; If style is set, then this node has set the color.
 206     (when style
 207       (shr-colorize-region start (point)
 208                            (cdr (assq 'color shr-stylesheet))
 209                            (cdr (assq 'background-color shr-stylesheet))))))
 210
 211 (defun shr-generic (cont)
 212   (dolist (sub cont)
 213     (cond
 214      ((eq (car sub) 'text)
 215       (shr-insert (cdr sub)))
 216      ((listp (cdr sub))
 217       (shr-descend sub)))))
 218
 219 (defmacro shr-char-breakable-p (char)
 220   "Return non-nil if a line can be broken before and after CHAR."
 221   `(aref fill-find-break-point-function-table ,char))
 222 (defmacro shr-char-nospace-p (char)
 223   "Return non-nil if no space is required before and after CHAR."
 224   `(aref fill-nospace-between-words-table ,char))
 225
 226 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 227 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 228 ;; parentheses, and so on, that should not be placed in the beginning
 229 ;; of a line or the end of a line.
 230 (defmacro shr-char-kinsoku-bol-p (char)
 231   "Return non-nil if a line ought not to begin with CHAR."
 232   `(aref (char-category-set ,char) ?>))
 233 (defmacro shr-char-kinsoku-eol-p (char)
 234   "Return non-nil if a line ought not to end with CHAR."
 235   `(aref (char-category-set ,char) ?<))
 236 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 237   (load "kinsoku" nil t))
 238
 239 (defun shr-insert (text)
 240   (when (and (eq shr-state 'image)
 241              (not (string-match "\\`[ \t\n]+\\'" text)))
 242     (insert "\n")
 243     (setq shr-state nil))
 244   (cond
 245    ((eq shr-folding-mode 'none)
 246     (insert text))
 247    (t
 248     (when (and (string-match "\\`[ \t\n]" text)
 249                (not (bolp))
 250                (not (eq (char-after (1- (point))) ? )))
 251       (insert " "))
 252     (dolist (elem (split-string text))
 253       (when (and (bolp)
 254                  (> shr-indentation 0))
 255         (shr-indent))
 256       ;; The shr-start is a special variable that is used to pass
 257       ;; upwards the first point in the buffer where the text really
 258       ;; starts.
 259       (unless shr-start
 260         (setq shr-start (point)))
 261       ;; No space is needed behind a wide character categorized as
 262       ;; kinsoku-bol, between characters both categorized as nospace,
 263       ;; or at the beginning of a line.
 264       (let (prev)
 265         (when (and (eq (preceding-char) ? )
 266                    (or (= (line-beginning-position) (1- (point)))
 267                        (and (shr-char-breakable-p
 268                              (setq prev (char-after (- (point) 2))))
 269                             (shr-char-kinsoku-bol-p prev))
 270                        (and (shr-char-nospace-p prev)
 271                             (shr-char-nospace-p (aref elem 0)))))
 272           (delete-char -1)))
 273       (insert elem)
 274       (let (found)
 275         (while (and (> (current-column) shr-width)
 276                     (progn
 277                       (setq found (shr-find-fill-point))
 278                       (not (eolp))))
 279           (when (eq (preceding-char) ? )
 280             (delete-char -1))
 281           (insert "\n")
 282           (unless found
 283             (put-text-property (1- (point)) (point) 'shr-break t)
 284             ;; No space is needed at the beginning of a line.
 285             (when (eq (following-char) ? )
 286               (delete-char 1)))
 287           (when (> shr-indentation 0)
 288             (shr-indent))
 289           (end-of-line))
 290         (insert " ")))
 291     (unless (string-match "[ \t\n]\\'" text)
 292       (delete-char -1)))))
 293
 294 (defun shr-find-fill-point ()
 295   (when (> (move-to-column shr-width) shr-width)
 296     (backward-char 1))
 297   (let ((bp (point))
 298         failed)
 299     (while (not (or (setq failed (= (current-column) shr-indentation))
 300                     (eq (preceding-char) ? )
 301                     (eq (following-char) ? )
 302                     (shr-char-breakable-p (preceding-char))
 303                     (shr-char-breakable-p (following-char))
 304                     (if (eq (preceding-char) ?')
 305                         (not (memq (char-after (- (point) 2))
 306                                    (list nil ?\n ? )))
 307                       (and (shr-char-kinsoku-bol-p (preceding-char))
 308                            (shr-char-breakable-p (following-char))
 309                            (not (shr-char-kinsoku-bol-p (following-char)))))
 310                     (shr-char-kinsoku-eol-p (following-char))))
 311       (backward-char 1))
 312     (if (and (not (or failed (eolp)))
 313              (eq (preceding-char) ?'))
 314         (while (not (or (setq failed (eolp))
 315                         (eq (following-char) ? )
 316                         (shr-char-breakable-p (following-char))
 317                         (shr-char-kinsoku-eol-p (following-char))))
 318           (forward-char 1)))
 319     (if failed
 320         ;; There's no breakable point, so we give it up.
 321         (let (found)
 322           (goto-char bp)
 323           (unless shr-kinsoku-shorten
 324             (while (and (setq found (re-search-forward
 325                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 326                                      (line-end-position) 'move))
 327                         (eq (preceding-char) ?')))
 328             (if (and found (not (match-beginning 1)))
 329                 (goto-char (match-beginning 0)))))
 330       (or
 331        (eolp)
 332        ;; Don't put kinsoku-bol characters at the beginning of a line,
 333        ;; or kinsoku-eol characters at the end of a line.
 334        (cond
 335         (shr-kinsoku-shorten
 336          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 337                      (shr-char-kinsoku-eol-p (preceding-char)))
 338            (backward-char 1))
 339          (when (setq failed (= (current-column) shr-indentation))
 340            ;; There's no breakable point that doesn't violate kinsoku,
 341            ;; so we look for the second best position.
 342            (while (and (progn
 343                          (forward-char 1)
 344                          (<= (current-column) shr-width))
 345                        (progn
 346                          (setq bp (point))
 347                          (shr-char-kinsoku-eol-p (following-char)))))
 348            (goto-char bp)))
 349         ((shr-char-kinsoku-eol-p (preceding-char))
 350          (if (shr-char-kinsoku-eol-p (following-char))
 351              ;; There are consecutive kinsoku-eol characters.
 352              (setq failed t)
 353            (let ((count 4))
 354              (while
 355                  (progn
 356                    (backward-char 1)
 357                    (and (> (setq count (1- count)) 0)
 358                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 359                         (or (shr-char-kinsoku-eol-p (preceding-char))
 360                             (shr-char-kinsoku-bol-p (following-char)))))))
 361            (if (setq failed (= (current-column) shr-indentation))
 362                ;; There's no breakable point that doesn't violate kinsoku,
 363                ;; so we go to the second best position.
 364                (if (looking-at "\\(\\c<+\\)\\c<")
 365                    (goto-char (match-end 1))
 366                  (forward-char 1)))))
 367         (t
 368          (if (shr-char-kinsoku-bol-p (preceding-char))
 369              ;; There are consecutive kinsoku-bol characters.
 370              (setq failed t)
 371            (let ((count 4))
 372              (while (and (>= (setq count (1- count)) 0)
 373                          (shr-char-kinsoku-bol-p (following-char))
 374                          (shr-char-breakable-p (following-char)))
 375                (forward-char 1))))))
 376        (when (eq (following-char) ? )
 377          (forward-char 1))))
 378     (not failed)))
 379
 380 (defun shr-ensure-newline ()
 381   (unless (zerop (current-column))
 382     (insert "\n")))
 383
 384 (defun shr-ensure-paragraph ()
 385   (unless (bobp)
 386     (if (<= (current-column) shr-indentation)
 387         (unless (save-excursion
 388                   (forward-line -1)
 389                   (looking-at " *$"))
 390           (insert "\n"))
 391       (if (save-excursion
 392             (beginning-of-line)
 393             (looking-at " *$"))
 394           (insert "\n")
 395         (insert "\n\n")))))
 396
 397 (defun shr-indent ()
 398   (when (> shr-indentation 0)
 399     (insert (make-string shr-indentation ? ))))
 400
 401 (defun shr-fontize-cont (cont &rest types)
 402   (let (shr-start)
 403     (shr-generic cont)
 404     (dolist (type types)
 405       (shr-add-font (or shr-start (point)) (point) type))))
 406
 407 ;; Add an overlay in the region, but avoid putting the font properties
 408 ;; on blank text at the start of the line, and the newline at the end,
 409 ;; to avoid ugliness.
 410 (defun shr-add-font (start end type)
 411   (save-excursion
 412     (goto-char start)
 413     (while (< (point) end)
 414       (when (bolp)
 415         (skip-chars-forward " "))
 416       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 417         (overlay-put overlay 'face type))
 418       (if (< (line-end-position) end)
 419           (forward-line 1)
 420         (goto-char end)))))
 421
 422 (defun shr-browse-url ()
 423   "Browse the URL under point."
 424   (interactive)
 425   (let ((url (get-text-property (point) 'shr-url)))
 426     (cond
 427      ((not url)
 428       (message "No link under point"))
 429      ((string-match "^mailto:" url)
 430       (browse-url-mailto url))
 431      (t
 432       (browse-url url)))))
 433
 434 (defun shr-save-contents (directory)
 435   "Save the contents from URL in a file."
 436   (interactive "DSave contents of URL to directory: ")
 437   (let ((url (get-text-property (point) 'shr-url)))
 438     (if (not url)
 439         (message "No link under point")
 440       (url-retrieve (shr-encode-url url)
 441                     'shr-store-contents (list url directory)))))
 442
 443 (defun shr-store-contents (status url directory)
 444   (unless (plist-get status :error)
 445     (when (or (search-forward "\n\n" nil t)
 446               (search-forward "\r\n\r\n" nil t))
 447       (write-region (point) (point-max)
 448                     (expand-file-name (file-name-nondirectory url)
 449                                       directory)))))
 450
 451 (defun shr-image-fetched (status buffer start end)
 452   (when (and (buffer-name buffer)
 453              (not (plist-get status :error)))
 454     (url-store-in-cache (current-buffer))
 455     (when (or (search-forward "\n\n" nil t)
 456               (search-forward "\r\n\r\n" nil t))
 457       (let ((data (buffer-substring (point) (point-max))))
 458         (with-current-buffer buffer
 459           (let ((alt (buffer-substring start end))
 460                 (inhibit-read-only t))
 461             (delete-region start end)
 462             (goto-char start)
 463             (shr-put-image data alt))))))
 464   (kill-buffer (current-buffer)))
 465
 466 (defun shr-put-image (data alt)
 467   (if (display-graphic-p)
 468       (let ((image (ignore-errors
 469                      (shr-rescale-image data))))
 470         (when image
 471           ;; When inserting big-ish pictures, put them at the
 472           ;; beginning of the line.
 473           (when (and (> (current-column) 0)
 474                      (> (car (image-size image t)) 400))
 475             (insert "\n"))
 476           (insert-image image (or alt "*"))))
 477     (insert alt)))
 478
 479 (defun shr-rescale-image (data)
 480   (if (or (not (fboundp 'imagemagick-types))
 481           (not (get-buffer-window (current-buffer))))
 482       (create-image data nil t)
 483     (let* ((image (create-image data nil t))
 484            (size (image-size image t))
 485            (width (car size))
 486            (height (cdr size))
 487            (edges (window-inside-pixel-edges
 488                    (get-buffer-window (current-buffer))))
 489            (window-width (truncate (* shr-max-image-proportion
 490                                       (- (nth 2 edges) (nth 0 edges)))))
 491            (window-height (truncate (* shr-max-image-proportion
 492                                        (- (nth 3 edges) (nth 1 edges)))))
 493            scaled-image)
 494       (when (> height window-height)
 495         (setq image (or (create-image data 'imagemagick t
 496                                       :height window-height)
 497                         image))
 498         (setq size (image-size image t)))
 499       (when (> (car size) window-width)
 500         (setq image (or
 501                      (create-image data 'imagemagick t
 502                                    :width window-width)
 503                      image)))
 504       image)))
 505
 506 ;; url-cache-extract autoloads url-cache.
 507 (declare-function url-cache-create-filename "url-cache" (url))
 508 (autoload 'mm-disable-multibyte "mm-util")
 509 (autoload 'browse-url-mailto "browse-url")
 510
 511 (defun shr-get-image-data (url)
 512   "Get image data for URL.
 513 Return a string with image data."
 514   (with-temp-buffer
 515     (mm-disable-multibyte)
 516     (when (ignore-errors
 517             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 518             t)
 519       (when (or (search-forward "\n\n" nil t)
 520                 (search-forward "\r\n\r\n" nil t))
 521         (buffer-substring (point) (point-max))))))
 522
 523 (defun shr-image-displayer (content-function)
 524   "Return a function to display an image.
 525 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 526 is an argument.  The function to be returned takes three arguments URL,
 527 START, and END."
 528   `(lambda (url start end)
 529      (when url
 530        (if (string-match "\\`cid:" url)
 531            ,(when content-function
 532               `(let ((image (funcall ,content-function
 533                                      (substring url (match-end 0)))))
 534                  (when image
 535                    (goto-char start)
 536                    (shr-put-image image
 537                                   (prog1
 538                                       (buffer-substring-no-properties start end)
 539                                     (delete-region start end))))))
 540          (url-retrieve url 'shr-image-fetched
 541                        (list (current-buffer) start end)
 542                        t)))))
 543
 544 (defun shr-heading (cont &rest types)
 545   (shr-ensure-paragraph)
 546   (apply #'shr-fontize-cont cont types)
 547   (shr-ensure-paragraph))
 548
 549 (autoload 'widget-convert-button "wid-edit")
 550
 551 (defun shr-urlify (start url &optional title)
 552   (widget-convert-button
 553    'url-link start (point)
 554    :help-echo (if title (format "%s (%s)" url title) url)
 555    :keymap shr-map
 556    url)
 557   (put-text-property start (point) 'shr-url url))
 558
 559 (defun shr-encode-url (url)
 560   "Encode URL."
 561   (browse-url-url-encode-chars url "[)$ ]"))
 562
 563 (autoload 'shr-color-visible "shr-color")
 564 (autoload 'shr-color->hexadecimal "shr-color")
 565
 566 (defun shr-color-check (fg bg)
 567   "Check that FG is visible on BG.
 568 Returns (fg bg) with corrected values.
 569 Returns nil if the colors that would be used are the default
 570 ones, in case fg and bg are nil."
 571   (when (or fg bg)
 572     (let ((fixed (cond ((null fg) 'fg)
 573                        ((null bg) 'bg))))
 574       ;; Convert colors to hexadecimal, or set them to default.
 575       (let ((fg (or (shr-color->hexadecimal fg)
 576                     (frame-parameter nil 'foreground-color)))
 577             (bg (or (shr-color->hexadecimal bg)
 578                     (frame-parameter nil 'background-color))))
 579         (cond ((eq fixed 'bg)
 580                ;; Only return the new fg
 581                (list nil (cadr (shr-color-visible bg fg t))))
 582               ((eq fixed 'fg)
 583                ;; Invert args and results and return only the new bg
 584                (list (cadr (shr-color-visible fg bg t)) nil))
 585               (t
 586                (shr-color-visible bg fg)))))))
 587
 588 (defun shr-colorize-region (start end fg &optional bg)
 589   (when (or fg bg)
 590     (let ((new-colors (shr-color-check fg bg)))
 591       (when new-colors
 592         (when fg
 593           (shr-put-color start end :foreground (cadr new-colors)))
 594         (when bg
 595           (shr-put-color start end :background (car new-colors)))))))
 596
 597 ;; Put a color in the region, but avoid putting colors on on blank
 598 ;; text at the start of the line, and the newline at the end, to avoid
 599 ;; ugliness.  Also, don't overwrite any existing color information,
 600 ;; since this can be called recursively, and we want the "inner" color
 601 ;; to win.
 602 (defun shr-put-color (start end type color)
 603   (save-excursion
 604     (goto-char start)
 605     (while (< (point) end)
 606       (when (bolp)
 607         (skip-chars-forward " "))
 608       (when (> (line-end-position) (point))
 609         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 610       (if (< (line-end-position) end)
 611           (forward-line 1)
 612         (goto-char end)))))
 613
 614 (defun shr-put-color-1 (start end type color)
 615   (let* ((old-props (get-text-property start 'face))
 616          (do-put (not (memq type old-props)))
 617          change)
 618     (while (< start end)
 619       (setq change (next-single-property-change start 'face nil end))
 620       (when do-put
 621         (put-text-property start change 'face
 622                            (nconc (list type color) old-props)))
 623       (setq old-props (get-text-property change 'face))
 624       (setq do-put (not (memq type old-props)))
 625       (setq start change))
 626     (when (and do-put
 627                (> end start))
 628       (put-text-property start end 'face
 629                          (nconc (list type color old-props))))))
 630
 631 ;;; Tag-specific rendering rules.
 632
 633 (defun shr-tag-body (cont)
 634   (let* ((start (point))
 635          (fgcolor (cdr (assq :fgcolor cont)))
 636          (bgcolor (cdr (assq :bgcolor cont)))
 637          (shr-stylesheet (list (cons 'color fgcolor)
 638                                (cons 'background-color bgcolor))))
 639     (shr-generic cont)
 640     (shr-colorize-region start (point) fgcolor bgcolor)))
 641
 642 (defun shr-tag-style (cont)
 643   )
 644
 645 (defun shr-tag-p (cont)
 646   (shr-ensure-paragraph)
 647   (shr-indent)
 648   (shr-generic cont)
 649   (shr-ensure-paragraph))
 650
 651 (defun shr-tag-div (cont)
 652   (shr-ensure-newline)
 653   (shr-indent)
 654   (shr-generic cont)
 655   (shr-ensure-newline))
 656
 657 (defun shr-tag-b (cont)
 658   (shr-fontize-cont cont 'bold))
 659
 660 (defun shr-tag-i (cont)
 661   (shr-fontize-cont cont 'italic))
 662
 663 (defun shr-tag-em (cont)
 664   (shr-fontize-cont cont 'bold))
 665
 666 (defun shr-tag-strong (cont)
 667   (shr-fontize-cont cont 'bold))
 668
 669 (defun shr-tag-u (cont)
 670   (shr-fontize-cont cont 'underline))
 671
 672 (defun shr-tag-s (cont)
 673   (shr-fontize-cont cont 'strike-through))
 674
 675 (defun shr-parse-style (style)
 676   (when style
 677     (save-match-data
 678       (when (string-match "\n" style)
 679         (setq style (replace-match " " t t style))))
 680     (let ((plist nil))
 681       (dolist (elem (split-string style ";"))
 682         (when elem
 683           (setq elem (split-string elem ":"))
 684           (when (and (car elem)
 685                      (cadr elem))
 686             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 687                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 688               (when (string-match " *!important\\'" value)
 689                 (setq value (substring value 0 (match-beginning 0))))
 690               (push (cons (intern name obarray)
 691                           value)
 692                     plist)))))
 693       plist)))
 694
 695 (defun shr-tag-a (cont)
 696   (let ((url (cdr (assq :href cont)))
 697         (title (cdr (assq :title cont)))
 698         (start (point))
 699         shr-start)
 700     (shr-generic cont)
 701     (shr-urlify (or shr-start start) url title)))
 702
 703 (defun shr-tag-object (cont)
 704   (let ((start (point))
 705         url)
 706     (dolist (elem cont)
 707       (when (eq (car elem) 'embed)
 708         (setq url (or url (cdr (assq :src (cdr elem))))))
 709       (when (and (eq (car elem) 'param)
 710                  (equal (cdr (assq :name (cdr elem))) "movie"))
 711         (setq url (or url (cdr (assq :value (cdr elem)))))))
 712     (when url
 713       (shr-insert " [multimedia] ")
 714       (shr-urlify start url))
 715     (shr-generic cont)))
 716
 717 (defun shr-tag-video (cont)
 718   (let ((image (cdr (assq :poster cont)))
 719         (url (cdr (assq :src cont)))
 720         (start (point)))
 721     (shr-tag-img nil image)
 722     (shr-urlify start url)))
 723
 724 (defun shr-tag-img (cont &optional url)
 725   (when (or url
 726             (and cont
 727                  (cdr (assq :src cont))))
 728     (when (and (> (current-column) 0)
 729                (not (eq shr-state 'image)))
 730       (insert "\n"))
 731     (let ((alt (cdr (assq :alt cont)))
 732           (url (or url (cdr (assq :src cont)))))
 733       (let ((start (point-marker)))
 734         (when (zerop (length alt))
 735           (setq alt "*"))
 736         (cond
 737          ((or (member (cdr (assq :height cont)) '("0" "1"))
 738               (member (cdr (assq :width cont)) '("0" "1")))
 739           ;; Ignore zero-sized or single-pixel images.
 740           )
 741          ((and (not shr-inhibit-images)
 742                (string-match "\\`cid:" url))
 743           (let ((url (substring url (match-end 0)))
 744                 image)
 745             (if (or (not shr-content-function)
 746                     (not (setq image (funcall shr-content-function url))))
 747                 (insert alt)
 748               (shr-put-image image alt))))
 749          ((or shr-inhibit-images
 750               (and shr-blocked-images
 751                    (string-match shr-blocked-images url)))
 752           (setq shr-start (point))
 753           (let ((shr-state 'space))
 754             (if (> (string-width alt) 8)
 755                 (shr-insert (truncate-string-to-width alt 8))
 756               (shr-insert alt))))
 757          ((url-is-cached (shr-encode-url url))
 758           (shr-put-image (shr-get-image-data url) alt))
 759          (t
 760           (insert alt)
 761           (ignore-errors
 762             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 763                           (list (current-buffer) start (point-marker))
 764                           t))))
 765         (put-text-property start (point) 'keymap shr-map)
 766         (put-text-property start (point) 'shr-alt alt)
 767         (put-text-property start (point) 'image-url url)
 768         (put-text-property start (point) 'image-displayer
 769                            (shr-image-displayer shr-content-function))
 770         (put-text-property start (point) 'help-echo alt)
 771         (setq shr-state 'image)))))
 772
 773 (defun shr-tag-pre (cont)
 774   (let ((shr-folding-mode 'none))
 775     (shr-ensure-newline)
 776     (shr-indent)
 777     (shr-generic cont)
 778     (shr-ensure-newline)))
 779
 780 (defun shr-tag-blockquote (cont)
 781   (shr-ensure-paragraph)
 782   (shr-indent)
 783   (let ((shr-indentation (+ shr-indentation 4)))
 784     (shr-generic cont))
 785   (shr-ensure-paragraph))
 786
 787 (defun shr-tag-ul (cont)
 788   (shr-ensure-paragraph)
 789   (let ((shr-list-mode 'ul))
 790     (shr-generic cont))
 791   (shr-ensure-paragraph))
 792
 793 (defun shr-tag-ol (cont)
 794   (shr-ensure-paragraph)
 795   (let ((shr-list-mode 1))
 796     (shr-generic cont))
 797   (shr-ensure-paragraph))
 798
 799 (defun shr-tag-li (cont)
 800   (shr-ensure-paragraph)
 801   (shr-indent)
 802   (let* ((bullet
 803           (if (numberp shr-list-mode)
 804               (prog1
 805                   (format "%d " shr-list-mode)
 806                 (setq shr-list-mode (1+ shr-list-mode)))
 807             "* "))
 808          (shr-indentation (+ shr-indentation (length bullet))))
 809     (insert bullet)
 810     (shr-generic cont)))
 811
 812 (defun shr-tag-br (cont)
 813   (unless (bobp)
 814     (insert "\n")
 815     (shr-indent))
 816   (shr-generic cont))
 817
 818 (defun shr-tag-h1 (cont)
 819   (shr-heading cont 'bold 'underline))
 820
 821 (defun shr-tag-h2 (cont)
 822   (shr-heading cont 'bold))
 823
 824 (defun shr-tag-h3 (cont)
 825   (shr-heading cont 'italic))
 826
 827 (defun shr-tag-h4 (cont)
 828   (shr-heading cont))
 829
 830 (defun shr-tag-h5 (cont)
 831   (shr-heading cont))
 832
 833 (defun shr-tag-h6 (cont)
 834   (shr-heading cont))
 835
 836 (defun shr-tag-hr (cont)
 837   (shr-ensure-newline)
 838   (insert (make-string shr-width shr-hr-line) "\n"))
 839
 840 (defun shr-tag-title (cont)
 841   (shr-heading cont 'bold 'underline))
 842
 843 (defun shr-tag-font (cont)
 844   (let* ((start (point))
 845          (color (cdr (assq :color cont)))
 846          (shr-stylesheet (nconc (list (cons 'color color))
 847                                 shr-stylesheet)))
 848     (shr-generic cont)
 849     (when color
 850       (shr-colorize-region start (point) color
 851                            (cdr (assq 'background-color shr-stylesheet))))))
 852
 853 ;;; Table rendering algorithm.
 854
 855 ;; Table rendering is the only complicated thing here.  We do this by
 856 ;; first counting how many TDs there are in each TR, and registering
 857 ;; how wide they think they should be ("width=45%", etc).  Then we
 858 ;; render each TD separately (this is done in temporary buffers, so
 859 ;; that we can use all the rendering machinery as if we were in the
 860 ;; main buffer).  Now we know how much space each TD really takes, so
 861 ;; we then render everything again with the new widths, and finally
 862 ;; insert all these boxes into the main buffer.
 863 (defun shr-tag-table-1 (cont)
 864   (setq cont (or (cdr (assq 'tbody cont))
 865                  cont))
 866   (let* ((shr-inhibit-images t)
 867          (shr-table-depth (1+ shr-table-depth))
 868          (shr-kinsoku-shorten t)
 869          ;; Find all suggested widths.
 870          (columns (shr-column-specs cont))
 871          ;; Compute how many characters wide each TD should be.
 872          (suggested-widths (shr-pro-rate-columns columns))
 873          ;; Do a "test rendering" to see how big each TD is (this can
 874          ;; be smaller (if there's little text) or bigger (if there's
 875          ;; unbreakable text).
 876          (sketch (shr-make-table cont suggested-widths))
 877          (sketch-widths (shr-table-widths sketch suggested-widths)))
 878     ;; This probably won't work very well.
 879     (when (> (+ (loop for width across sketch-widths
 880                       summing (1+ width))
 881                 shr-indentation 1)
 882              (frame-width))
 883       (setq truncate-lines t))
 884     ;; Then render the table again with these new "hard" widths.
 885     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 886   ;; Finally, insert all the images after the table.  The Emacs buffer
 887   ;; model isn't strong enough to allow us to put the images actually
 888   ;; into the tables.
 889   (when (zerop shr-table-depth)
 890     (dolist (elem (shr-find-elements cont 'img))
 891       (shr-tag-img (cdr elem)))))
 892
 893 (defun shr-tag-table (cont)
 894   (shr-ensure-paragraph)
 895   (let* ((caption (cdr (assq 'caption cont)))
 896          (header (cdr (assq 'thead cont)))
 897          (body (or (cdr (assq 'tbody cont)) cont))
 898          (footer (cdr (assq 'tfoot cont)))
 899          (bgcolor (cdr (assq :bgcolor cont)))
 900          (start (point))
 901          (shr-stylesheet (nconc (list (cons 'background-color bgcolor))
 902                                 shr-stylesheet))
 903          (nheader (if header (shr-max-columns header)))
 904          (nbody (if body (shr-max-columns body)))
 905          (nfooter (if footer (shr-max-columns footer))))
 906     (shr-tag-table-1
 907      (nconc
 908       (if caption `((tr (td ,@caption))))
 909       (if header
 910           (if footer
 911               ;; hader + body + footer
 912               (if (= nheader nbody)
 913                   (if (= nbody nfooter)
 914                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 915                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 916                            (if (= nfooter 1)
 917                                footer
 918                              `((tr (td (table (tbody ,@footer))))))))
 919                 (nconc `((tr (td (table (tbody ,@header)))))
 920                        (if (= nbody nfooter)
 921                            `((tr (td (table (tbody ,@body ,@footer)))))
 922                          (nconc `((tr (td (table (tbody ,@body)))))
 923                                 (if (= nfooter 1)
 924                                     footer
 925                                   `((tr (td (table (tbody ,@footer))))))))))
 926             ;; header + body
 927             (if (= nheader nbody)
 928                 `((tr (td (table (tbody ,@header ,@body)))))
 929               (if (= nheader 1)
 930                   `(,@header (tr (td (table (tbody ,@body)))))
 931                 `((tr (td (table (tbody ,@header))))
 932                   (tr (td (table (tbody ,@body))))))))
 933         (if footer
 934             ;; body + footer
 935             (if (= nbody nfooter)
 936                 `((tr (td (table (tbody ,@body ,@footer)))))
 937               (nconc `((tr (td (table (tbody ,@body)))))
 938                      (if (= nfooter 1)
 939                          footer
 940                        `((tr (td (table (tbody ,@footer))))))))
 941           (if caption
 942               `((tr (td (table (tbody ,@body)))))
 943             body)))))
 944     (when bgcolor
 945       (shr-colorize-region start (point) (cdr (assq 'color shr-stylesheet))
 946                            bgcolor))))
 947
 948 (defun shr-find-elements (cont type)
 949   (let (result)
 950     (dolist (elem cont)
 951       (cond ((eq (car elem) type)
 952              (push elem result))
 953             ((consp (cdr elem))
 954              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 955     (nreverse result)))
 956
 957 (defun shr-insert-table (table widths)
 958   (shr-insert-table-ruler widths)
 959   (dolist (row table)
 960     (let ((start (point))
 961           (height (let ((max 0))
 962                     (dolist (column row)
 963                       (setq max (max max (cadr column))))
 964                     max)))
 965       (dotimes (i height)
 966         (shr-indent)
 967         (insert shr-table-vertical-line "\n"))
 968       (dolist (column row)
 969         (goto-char start)
 970         (let ((lines (nth 2 column))
 971               (overlay-lines (nth 3 column))
 972               overlay overlay-line)
 973           (dolist (line lines)
 974             (setq overlay-line (pop overlay-lines))
 975             (end-of-line)
 976             (insert line shr-table-vertical-line)
 977             (dolist (overlay overlay-line)
 978               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 979                                      (- (point) (nth 1 overlay) 1)))
 980                     (properties (nth 2 overlay)))
 981                 (while properties
 982                   (overlay-put o (pop properties) (pop properties)))))
 983             (forward-line 1))
 984           ;; Add blank lines at padding at the bottom of the TD,
 985           ;; possibly.
 986           (dotimes (i (- height (length lines)))
 987             (end-of-line)
 988             (insert (make-string (string-width (car lines)) ? )
 989                     shr-table-vertical-line)
 990             (forward-line 1)))))
 991     (shr-insert-table-ruler widths)))
 992
 993 (defun shr-insert-table-ruler (widths)
 994   (when (and (bolp)
 995              (> shr-indentation 0))
 996     (shr-indent))
 997   (insert shr-table-corner)
 998   (dotimes (i (length widths))
 999     (insert (make-string (aref widths i) shr-table-horizontal-line)
1000             shr-table-corner))
1001   (insert "\n"))
1002
1003 (defun shr-table-widths (table suggested-widths)
1004   (let* ((length (length suggested-widths))
1005          (widths (make-vector length 0))
1006          (natural-widths (make-vector length 0)))
1007     (dolist (row table)
1008       (let ((i 0))
1009         (dolist (column row)
1010           (aset widths i (max (aref widths i)
1011                               (car column)))
1012           (aset natural-widths i (max (aref natural-widths i)
1013                                       (cadr column)))
1014           (setq i (1+ i)))))
1015     (let ((extra (- (apply '+ (append suggested-widths nil))
1016                     (apply '+ (append widths nil))))
1017           (expanded-columns 0))
1018       (when (> extra 0)
1019         (dotimes (i length)
1020           ;; If the natural width is wider than the rendered width, we
1021           ;; want to allow the column to expand.
1022           (when (> (aref natural-widths i) (aref widths i))
1023             (setq expanded-columns (1+ expanded-columns))))
1024         (dotimes (i length)
1025           (when (> (aref natural-widths i) (aref widths i))
1026             (aset widths i (min
1027                             (1+ (aref natural-widths i))
1028                             (+ (/ extra expanded-columns)
1029                                (aref widths i))))))))
1030     widths))
1031
1032 (defun shr-make-table (cont widths &optional fill)
1033   (let ((trs nil))
1034     (dolist (row cont)
1035       (when (eq (car row) 'tr)
1036         (let ((tds nil)
1037               (columns (cdr row))
1038               (i 0)
1039               column)
1040           (while (< i (length widths))
1041             (setq column (pop columns))
1042             (when (or (memq (car column) '(td th))
1043                       (null column))
1044               (push (shr-render-td (cdr column) (aref widths i) fill)
1045                     tds)
1046               (setq i (1+ i))))
1047           (push (nreverse tds) trs))))
1048     (nreverse trs)))
1049
1050 (defun shr-render-td (cont width fill)
1051   (with-temp-buffer
1052     (let ((bgcolor (cdr (assq :bgcolor cont)))
1053           (fgcolor (cdr (assq :fgcolor cont)))
1054           (style (cdr (assq :style cont)))
1055           (shr-stylesheet shr-stylesheet))
1056       (when style
1057         (setq style (and (string-match "color" style)
1058                          (shr-parse-style style))))
1059       (when bgcolor
1060         (setq style (nconc (list (cons 'background-color bgcolor)) style)))
1061       (when fgcolor
1062         (setq style (nconc (list (cons 'color fgcolor)) style)))
1063       (when style
1064         (setq shr-stylesheet (append style shr-stylesheet)))
1065       (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1066         (if cache
1067             (insert cache)
1068           (let ((shr-width width)
1069                 (shr-indentation 0))
1070             (shr-descend (cons 'td cont)))
1071           (delete-region
1072            (point)
1073            (+ (point)
1074               (skip-chars-backward " \t\n")))
1075           (push (cons (cons width cont) (buffer-string))
1076                 shr-content-cache)))
1077       (goto-char (point-min))
1078       (let ((max 0))
1079         (while (not (eobp))
1080           (end-of-line)
1081           (setq max (max max (current-column)))
1082           (forward-line 1))
1083         (when fill
1084           (goto-char (point-min))
1085           ;; If the buffer is totally empty, then put a single blank
1086           ;; line here.
1087           (if (zerop (buffer-size))
1088               (insert (make-string width ? ))
1089             ;; Otherwise, fill the buffer.
1090             (while (not (eobp))
1091               (end-of-line)
1092               (when (> (- width (current-column)) 0)
1093                 (insert (make-string (- width (current-column)) ? )))
1094               (forward-line 1))))
1095         (when style
1096           (shr-colorize-region
1097            (point-min) (point-max)
1098            (cdr (assq 'color shr-stylesheet))
1099            (cdr (assq 'background-color shr-stylesheet))))
1100         (if fill
1101             (list max
1102                   (count-lines (point-min) (point-max))
1103                   (split-string (buffer-string) "\n")
1104                   (shr-collect-overlays))
1105           (list max
1106                 (shr-natural-width)))))))
1107
1108 (defun shr-natural-width ()
1109   (goto-char (point-min))
1110   (let ((current 0)
1111         (max 0))
1112     (while (not (eobp))
1113       (end-of-line)
1114       (setq current (+ current (current-column)))
1115       (unless (get-text-property (point) 'shr-break)
1116         (setq max (max max current)
1117               current 0))
1118       (forward-line 1))
1119     max))
1120
1121 (defun shr-collect-overlays ()
1122   (save-excursion
1123     (goto-char (point-min))
1124     (let ((overlays nil))
1125       (while (not (eobp))
1126         (push (shr-overlays-in-region (point) (line-end-position))
1127               overlays)
1128         (forward-line 1))
1129       (nreverse overlays))))
1130
1131 (defun shr-overlays-in-region (start end)
1132   (let (result)
1133     (dolist (overlay (overlays-in start end))
1134       (push (list (if (> start (overlay-start overlay))
1135                       (- end start)
1136                     (- end (overlay-start overlay)))
1137                   (if (< end (overlay-end overlay))
1138                       0
1139                     (- end (overlay-end overlay)))
1140                   (overlay-properties overlay))
1141             result))
1142     (nreverse result)))
1143
1144 (defun shr-pro-rate-columns (columns)
1145   (let ((total-percentage 0)
1146         (widths (make-vector (length columns) 0)))
1147     (dotimes (i (length columns))
1148       (setq total-percentage (+ total-percentage (aref columns i))))
1149     (setq total-percentage (/ 1.0 total-percentage))
1150     (dotimes (i (length columns))
1151       (aset widths i (max (truncate (* (aref columns i)
1152                                        total-percentage
1153                                        (- shr-width (1+ (length columns)))))
1154                           10)))
1155     widths))
1156
1157 ;; Return a summary of the number and shape of the TDs in the table.
1158 (defun shr-column-specs (cont)
1159   (let ((columns (make-vector (shr-max-columns cont) 1)))
1160     (dolist (row cont)
1161       (when (eq (car row) 'tr)
1162         (let ((i 0))
1163           (dolist (column (cdr row))
1164             (when (memq (car column) '(td th))
1165               (let ((width (cdr (assq :width (cdr column)))))
1166                 (when (and width
1167                            (string-match "\\([0-9]+\\)%" width))
1168                   (aset columns i
1169                         (/ (string-to-number (match-string 1 width))
1170                            100.0))))
1171               (setq i (1+ i)))))))
1172     columns))
1173
1174 (defun shr-count (cont elem)
1175   (let ((i 0))
1176     (dolist (sub cont)
1177       (when (eq (car sub) elem)
1178         (setq i (1+ i))))
1179     i))
1180
1181 (defun shr-max-columns (cont)
1182   (let ((max 0))
1183     (dolist (row cont)
1184       (when (eq (car row) 'tr)
1185         (setq max (max max (+ (shr-count (cdr row) 'td)
1186                               (shr-count (cdr row) 'th))))))
1187     max))
1188
1189 (provide 'shr)
1190
1191 ;;; shr.el ends here