cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35 (unless (aref (char-category-set (make-char 'japanese-jisx0208 33 35)) ?>)
  36   (load "kinsoku" nil t))
  37
  38 (defgroup shr nil
  39   "Simple HTML Renderer"
  40   :group 'mail)
  41
  42 (defcustom shr-max-image-proportion 0.9
  43   "How big pictures displayed are in relation to the window they're in.
  44 A value of 0.7 means that they are allowed to take up 70% of the
  45 width and height of the window.  If they are larger than this,
  46 and Emacs supports it, then the images will be rescaled down to
  47 fit these criteria."
  48   :version "24.1"
  49   :group 'shr
  50   :type 'float)
  51
  52 (defcustom shr-blocked-images nil
  53   "Images that have URLs matching this regexp will be blocked."
  54   :version "24.1"
  55   :group 'shr
  56   :type 'regexp)
  57
  58 (defcustom shr-table-line ?-
  59   "Character used to draw table line."
  60   :group 'shr
  61   :type 'character)
  62
  63 (defcustom shr-table-corner ?+
  64   "Character used to draw table corner."
  65   :group 'shr
  66   :type 'character)
  67
  68 (defcustom shr-hr-line ?-
  69   "Character used to draw hr line."
  70   :group 'shr
  71   :type 'character)
  72
  73 (defcustom shr-width fill-column
  74   "Frame width to use for rendering."
  75   :type 'integer
  76   :group 'shr)
  77
  78 (defvar shr-content-function nil
  79   "If bound, this should be a function that will return the content.
  80 This is used for cid: URLs, and the function is called with the
  81 cid: URL as the argument.")
  82
  83 ;;; Internal variables.
  84
  85 (defvar shr-folding-mode nil)
  86 (defvar shr-state nil)
  87 (defvar shr-start nil)
  88 (defvar shr-indentation 0)
  89 (defvar shr-inhibit-images nil)
  90 (defvar shr-list-mode nil)
  91 (defvar shr-content-cache nil)
  92 (defvar shr-kinsoku-shorten nil)
  93
  94 (defvar shr-map
  95   (let ((map (make-sparse-keymap)))
  96     (define-key map "a" 'shr-show-alt-text)
  97     (define-key map "i" 'shr-browse-image)
  98     (define-key map "I" 'shr-insert-image)
  99     (define-key map "u" 'shr-copy-url)
 100     (define-key map "v" 'shr-browse-url)
 101     (define-key map "o" 'shr-save-contents)
 102     (define-key map "\r" 'shr-browse-url)
 103     map))
 104
 105 ;; Public functions and commands.
 106
 107 ;;;###autoload
 108 (defun shr-insert-document (dom)
 109   (setq shr-content-cache nil)
 110   (let ((shr-state nil)
 111         (shr-start nil))
 112     (shr-descend (shr-transform-dom dom))))
 113
 114 (defun shr-copy-url ()
 115   "Copy the URL under point to the kill ring.
 116 If called twice, then try to fetch the URL and see whether it
 117 redirects somewhere else."
 118   (interactive)
 119   (let ((url (get-text-property (point) 'shr-url)))
 120     (cond
 121      ((not url)
 122       (message "No URL under point"))
 123      ;; Resolve redirected URLs.
 124      ((equal url (car kill-ring))
 125       (url-retrieve
 126        url
 127        (lambda (a)
 128          (when (and (consp a)
 129                     (eq (car a) :redirect))
 130            (with-temp-buffer
 131              (insert (cadr a))
 132              (goto-char (point-min))
 133              ;; Remove common tracking junk from the URL.
 134              (when (re-search-forward ".utm_.*" nil t)
 135                (replace-match "" t t))
 136              (message "Copied %s" (buffer-string))
 137              (copy-region-as-kill (point-min) (point-max)))))))
 138      ;; Copy the URL to the kill ring.
 139      (t
 140       (with-temp-buffer
 141         (insert url)
 142         (copy-region-as-kill (point-min) (point-max))
 143         (message "Copied %s" url))))))
 144
 145 (defun shr-show-alt-text ()
 146   "Show the ALT text of the image under point."
 147   (interactive)
 148   (let ((text (get-text-property (point) 'shr-alt)))
 149     (if (not text)
 150         (message "No image under point")
 151       (message "%s" text))))
 152
 153 (defun shr-browse-image ()
 154   "Browse the image under point."
 155   (interactive)
 156   (let ((url (get-text-property (point) 'shr-image)))
 157     (if (not url)
 158         (message "No image under point")
 159       (message "Browsing %s..." url)
 160       (browse-url url))))
 161
 162 (defun shr-insert-image ()
 163   "Insert the image under point into the buffer."
 164   (interactive)
 165   (let ((url (get-text-property (point) 'shr-image)))
 166     (if (not url)
 167         (message "No image under point")
 168       (message "Inserting %s..." url)
 169       (url-retrieve url 'shr-image-fetched
 170                     (list (current-buffer) (1- (point)) (point-marker))
 171                     t))))
 172
 173 ;;; Utility functions.
 174
 175 (defun shr-transform-dom (dom)
 176   (let ((result (list (pop dom))))
 177     (dolist (arg (pop dom))
 178       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 179                   (cdr arg))
 180             result))
 181     (dolist (sub dom)
 182       (if (stringp sub)
 183           (push (cons :text sub) result)
 184         (push (shr-transform-dom sub) result)))
 185     (nreverse result)))
 186
 187 (defun shr-descend (dom)
 188   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
 189     (if (fboundp function)
 190         (funcall function (cdr dom))
 191       (shr-generic (cdr dom)))))
 192
 193 (defun shr-generic (cont)
 194   (dolist (sub cont)
 195     (cond
 196      ((eq (car sub) :text)
 197       (shr-insert (cdr sub)))
 198      ((listp (cdr sub))
 199       (shr-descend sub)))))
 200
 201 (defun shr-insert (text)
 202   (when (and (eq shr-state 'image)
 203              (not (string-match "\\`[ \t\n]+\\'" text)))
 204     (insert "\n")
 205     (setq shr-state nil))
 206   (cond
 207    ((eq shr-folding-mode 'none)
 208     (insert text))
 209    (t
 210     (when (and (string-match "\\`[ \t\n]" text)
 211                (not (bolp))
 212                (not (eq (char-after (1- (point))) ? )))
 213       (insert " "))
 214     (dolist (elem (split-string text))
 215       (when (and (bolp)
 216                  (> shr-indentation 0))
 217         (shr-indent))
 218       ;; The shr-start is a special variable that is used to pass
 219       ;; upwards the first point in the buffer where the text really
 220       ;; starts.
 221       (unless shr-start
 222         (setq shr-start (point)))
 223       ;; No space is needed behind a wide character categorized as
 224       ;; kinsoku-bol, between characters both categorized as nospace,
 225       ;; or at the beginning of a line.
 226       (let (prev)
 227         (when (and (eq (preceding-char) ? )
 228                    (or (= (line-beginning-position) (1- (point)))
 229                        (and (aref fill-find-break-point-function-table
 230                                   (setq prev (char-after (- (point) 2))))
 231                             (aref (char-category-set prev) ?>))
 232                        (and (aref fill-nospace-between-words-table prev)
 233                             (aref fill-nospace-between-words-table
 234                                   (aref elem 0)))))
 235           (delete-char -1)))
 236       (insert elem)
 237       (while (> (current-column) shr-width)
 238         (unless (prog1
 239                     (shr-find-fill-point)
 240                   (when (eq (preceding-char) ? )
 241                     (delete-char -1))
 242                   (insert "\n"))
 243           (put-text-property (1- (point)) (point) 'shr-break t)
 244           ;; No space is needed at the beginning of a line.
 245           (when (eq (following-char) ? )
 246             (delete-char 1)))
 247         (when (> shr-indentation 0)
 248           (shr-indent))
 249         (end-of-line))
 250       (insert " "))
 251     (unless (string-match "[ \t\n]\\'" text)
 252       (delete-char -1)))))
 253
 254 (defun shr-find-fill-point ()
 255   (when (> (move-to-column shr-width) shr-width)
 256     (backward-char 1))
 257   (let (failed)
 258     (while (not
 259             (or (setq failed (= (current-column) shr-indentation))
 260                 (eq (preceding-char) ? )
 261                 (eq (following-char) ? )
 262                 (aref fill-find-break-point-function-table (preceding-char))))
 263       (backward-char 1))
 264     (if failed
 265         ;; There's no breakable point, so we give it up.
 266         (progn
 267           (end-of-line)
 268           (while (aref fill-find-break-point-function-table (preceding-char))
 269             (backward-char 1))
 270           nil)
 271       (or (eolp)
 272           ;; Don't put kinsoku-bol characters at the beginning of a line,
 273           ;; or kinsoku-eol characters at the end of a line,
 274           (let ((count 4))
 275             (if (or shr-kinsoku-shorten
 276                     (and (aref (char-category-set (preceding-char)) ?<)
 277                          (progn
 278                            (setq count (1- count))
 279                            (backward-char 1)
 280                            t)))
 281                 (while (and
 282                         (>= (setq count (1- count)) 0)
 283                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 284                         (or (aref (char-category-set (preceding-char)) ?<)
 285                             (aref (char-category-set (following-char)) ?>)))
 286                   (backward-char 1))
 287               (while (and (>= (setq count (1- count)) 0)
 288                           (aref (char-category-set (following-char)) ?>))
 289                 (forward-char 1)))
 290             (when (eq (following-char) ? )
 291               (forward-char 1))
 292             t)))))
 293
 294 (defun shr-ensure-newline ()
 295   (unless (zerop (current-column))
 296     (insert "\n")))
 297
 298 (defun shr-ensure-paragraph ()
 299   (unless (bobp)
 300     (if (<= (current-column) shr-indentation)
 301         (unless (save-excursion
 302                   (forward-line -1)
 303                   (looking-at " *$"))
 304           (insert "\n"))
 305       (if (save-excursion
 306             (beginning-of-line)
 307             (looking-at " *$"))
 308           (insert "\n")
 309         (insert "\n\n")))))
 310
 311 (defun shr-indent ()
 312   (when (> shr-indentation 0)
 313     (insert (make-string shr-indentation ? ))))
 314
 315 (defun shr-fontize-cont (cont &rest types)
 316   (let (shr-start)
 317     (shr-generic cont)
 318     (dolist (type types)
 319       (shr-add-font (or shr-start (point)) (point) type))))
 320
 321 ;; Add an overlay in the region, but avoid putting the font properties
 322 ;; on blank text at the start of the line, and the newline at the end,
 323 ;; to avoid ugliness.
 324 (defun shr-add-font (start end type)
 325   (save-excursion
 326     (goto-char start)
 327     (while (< (point) end)
 328       (when (bolp)
 329         (skip-chars-forward " "))
 330       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 331         (overlay-put overlay 'face type))
 332       (if (< (line-end-position) end)
 333           (forward-line 1)
 334         (goto-char end)))))
 335
 336 (defun shr-browse-url ()
 337   "Browse the URL under point."
 338   (interactive)
 339   (let ((url (get-text-property (point) 'shr-url)))
 340     (if (not url)
 341         (message "No link under point")
 342       (browse-url url))))
 343
 344 (defun shr-save-contents (directory)
 345   "Save the contents from URL in a file."
 346   (interactive "DSave contents of URL to directory: ")
 347   (let ((url (get-text-property (point) 'shr-url)))
 348     (if (not url)
 349         (message "No link under point")
 350       (url-retrieve (shr-encode-url url)
 351                     'shr-store-contents (list url directory)))))
 352
 353 (defun shr-store-contents (status url directory)
 354   (unless (plist-get status :error)
 355     (when (or (search-forward "\n\n" nil t)
 356               (search-forward "\r\n\r\n" nil t))
 357       (write-region (point) (point-max)
 358                     (expand-file-name (file-name-nondirectory url)
 359                                       directory)))))
 360
 361 (defun shr-image-fetched (status buffer start end)
 362   (when (and (buffer-name buffer)
 363              (not (plist-get status :error)))
 364     (url-store-in-cache (current-buffer))
 365     (when (or (search-forward "\n\n" nil t)
 366               (search-forward "\r\n\r\n" nil t))
 367       (let ((data (buffer-substring (point) (point-max))))
 368         (with-current-buffer buffer
 369           (let ((alt (buffer-substring start end))
 370                 (inhibit-read-only t))
 371             (delete-region start end)
 372             (shr-put-image data start alt))))))
 373   (kill-buffer (current-buffer)))
 374
 375 (defun shr-put-image (data point alt)
 376   (if (display-graphic-p)
 377       (let ((image (ignore-errors
 378                      (shr-rescale-image data))))
 379         (when image
 380           (put-image image point alt)))
 381     (save-excursion
 382       (goto-char point)
 383       (insert alt))))
 384
 385 (defun shr-rescale-image (data)
 386   (if (or (not (fboundp 'imagemagick-types))
 387           (not (get-buffer-window (current-buffer))))
 388       (create-image data nil t)
 389     (let* ((image (create-image data nil t))
 390            (size (image-size image t))
 391            (width (car size))
 392            (height (cdr size))
 393            (edges (window-inside-pixel-edges
 394                    (get-buffer-window (current-buffer))))
 395            (window-width (truncate (* shr-max-image-proportion
 396                                       (- (nth 2 edges) (nth 0 edges)))))
 397            (window-height (truncate (* shr-max-image-proportion
 398                                        (- (nth 3 edges) (nth 1 edges)))))
 399            scaled-image)
 400       (when (> height window-height)
 401         (setq image (or (create-image data 'imagemagick t
 402                                       :height window-height)
 403                         image))
 404         (setq size (image-size image t)))
 405       (when (> (car size) window-width)
 406         (setq image (or
 407                      (create-image data 'imagemagick t
 408                                    :width window-width)
 409                      image)))
 410       image)))
 411
 412 (defun shr-get-image-data (url)
 413   "Get image data for URL.
 414 Return a string with image data."
 415   (with-temp-buffer
 416     (mm-disable-multibyte)
 417     (when (ignore-errors
 418             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 419             t)
 420       (when (or (search-forward "\n\n" nil t)
 421                 (search-forward "\r\n\r\n" nil t))
 422         (buffer-substring (point) (point-max))))))
 423
 424 (defun shr-heading (cont &rest types)
 425   (shr-ensure-paragraph)
 426   (apply #'shr-fontize-cont cont types)
 427   (shr-ensure-paragraph))
 428
 429 (defun shr-urlify (start url)
 430   (widget-convert-button
 431    'url-link start (point)
 432    :help-echo url
 433    :keymap shr-map
 434    url)
 435   (put-text-property start (point) 'shr-url url))
 436
 437 (defun shr-encode-url (url)
 438   "Encode URL."
 439   (browse-url-url-encode-chars url "[)$ ]"))
 440
 441 ;;; Tag-specific rendering rules.
 442
 443 (defun shr-tag-p (cont)
 444   (shr-ensure-paragraph)
 445   (shr-indent)
 446   (shr-generic cont)
 447   (shr-ensure-paragraph))
 448
 449 (defun shr-tag-div (cont)
 450   (shr-ensure-newline)
 451   (shr-indent)
 452   (shr-generic cont)
 453   (shr-ensure-newline))
 454
 455 (defun shr-tag-b (cont)
 456   (shr-fontize-cont cont 'bold))
 457
 458 (defun shr-tag-i (cont)
 459   (shr-fontize-cont cont 'italic))
 460
 461 (defun shr-tag-em (cont)
 462   (shr-fontize-cont cont 'bold))
 463
 464 (defun shr-tag-strong (cont)
 465   (shr-fontize-cont cont 'bold))
 466
 467 (defun shr-tag-u (cont)
 468   (shr-fontize-cont cont 'underline))
 469
 470 (defun shr-tag-s (cont)
 471   (shr-fontize-cont cont 'strike-through))
 472
 473 (defun shr-tag-span (cont)
 474   (let ((start (point))
 475         (color (cdr (assq 'color (shr-parse-style (cdr (assq :style cont)))))))
 476     (shr-generic cont)
 477     (when color
 478       (let ((overlay (make-overlay start (point))))
 479         (overlay-put overlay 'face (cons 'foreground-color color))))))
 480
 481 (defun shr-parse-style (style)
 482   (when style
 483     (let ((plist nil))
 484       (dolist (elem (split-string style ";"))
 485         (when elem
 486           (setq elem (split-string elem ":"))
 487           (when (and (car elem)
 488                      (cadr elem))
 489             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 490                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 491               (push (cons (intern name obarray)
 492                           value)
 493                     plist)))))
 494       plist)))
 495
 496 (defun shr-tag-a (cont)
 497   (let ((url (cdr (assq :href cont)))
 498         (start (point))
 499         shr-start)
 500     (shr-generic cont)
 501     (shr-urlify (or shr-start start) url)))
 502
 503 (defun shr-tag-object (cont)
 504   (let ((url (cdr (assq :src (cdr (assq 'embed cont)))))
 505         (start (point)))
 506     (when url
 507       (shr-insert " [multimedia] ")
 508       (shr-urlify start url))))
 509
 510 (defun shr-tag-img (cont)
 511   (when (and cont
 512              (cdr (assq :src cont)))
 513     (when (and (> (current-column) 0)
 514                (not (eq shr-state 'image)))
 515       (insert "\n"))
 516     (let ((alt (cdr (assq :alt cont)))
 517           (url (cdr (assq :src cont))))
 518       (let ((start (point-marker)))
 519         (when (zerop (length alt))
 520           (setq alt "[img]"))
 521         (cond
 522          ((and (not shr-inhibit-images)
 523                (string-match "\\`cid:" url))
 524           (let ((url (substring url (match-end 0)))
 525                 image)
 526             (if (or (not shr-content-function)
 527                     (not (setq image (funcall shr-content-function url))))
 528                 (insert alt)
 529               (shr-put-image image (point) alt))))
 530          ((or shr-inhibit-images
 531               (and shr-blocked-images
 532                    (string-match shr-blocked-images url)))
 533           (setq shr-start (point))
 534           (let ((shr-state 'space))
 535             (if (> (length alt) 8)
 536                 (shr-insert (substring alt 0 8))
 537               (shr-insert alt))))
 538          ((url-is-cached (shr-encode-url url))
 539           (shr-put-image (shr-get-image-data url) (point) alt))
 540          (t
 541           (insert alt)
 542           (ignore-errors
 543             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 544                           (list (current-buffer) start (point-marker))
 545                           t))))
 546         (insert " ")
 547         (put-text-property start (point) 'keymap shr-map)
 548         (put-text-property start (point) 'shr-alt alt)
 549         (put-text-property start (point) 'shr-image url)
 550         (setq shr-state 'image)))))
 551
 552 (defun shr-tag-pre (cont)
 553   (let ((shr-folding-mode 'none))
 554     (shr-ensure-newline)
 555     (shr-indent)
 556     (shr-generic cont)
 557     (shr-ensure-newline)))
 558
 559 (defun shr-tag-blockquote (cont)
 560   (shr-ensure-paragraph)
 561   (shr-indent)
 562   (let ((shr-indentation (+ shr-indentation 4)))
 563     (shr-generic cont))
 564   (shr-ensure-paragraph))
 565
 566 (defun shr-tag-ul (cont)
 567   (shr-ensure-paragraph)
 568   (let ((shr-list-mode 'ul))
 569     (shr-generic cont))
 570   (shr-ensure-paragraph))
 571
 572 (defun shr-tag-ol (cont)
 573   (shr-ensure-paragraph)
 574   (let ((shr-list-mode 1))
 575     (shr-generic cont))
 576   (shr-ensure-paragraph))
 577
 578 (defun shr-tag-li (cont)
 579   (shr-ensure-paragraph)
 580   (shr-indent)
 581   (let* ((bullet
 582           (if (numberp shr-list-mode)
 583               (prog1
 584                   (format "%d " shr-list-mode)
 585                 (setq shr-list-mode (1+ shr-list-mode)))
 586             "* "))
 587          (shr-indentation (+ shr-indentation (length bullet))))
 588     (insert bullet)
 589     (shr-generic cont)))
 590
 591 (defun shr-tag-br (cont)
 592   (unless (bobp)
 593     (insert "\n")
 594     (shr-indent))
 595   (shr-generic cont))
 596
 597 (defun shr-tag-h1 (cont)
 598   (shr-heading cont 'bold 'underline))
 599
 600 (defun shr-tag-h2 (cont)
 601   (shr-heading cont 'bold))
 602
 603 (defun shr-tag-h3 (cont)
 604   (shr-heading cont 'italic))
 605
 606 (defun shr-tag-h4 (cont)
 607   (shr-heading cont))
 608
 609 (defun shr-tag-h5 (cont)
 610   (shr-heading cont))
 611
 612 (defun shr-tag-h6 (cont)
 613   (shr-heading cont))
 614
 615 (defun shr-tag-hr (cont)
 616   (shr-ensure-newline)
 617   (insert (make-string shr-width shr-hr-line) "\n"))
 618
 619 ;;; Table rendering algorithm.
 620
 621 ;; Table rendering is the only complicated thing here.  We do this by
 622 ;; first counting how many TDs there are in each TR, and registering
 623 ;; how wide they think they should be ("width=45%", etc).  Then we
 624 ;; render each TD separately (this is done in temporary buffers, so
 625 ;; that we can use all the rendering machinery as if we were in the
 626 ;; main buffer).  Now we know how much space each TD really takes, so
 627 ;; we then render everything again with the new widths, and finally
 628 ;; insert all these boxes into the main buffer.
 629 (defun shr-tag-table-1 (cont)
 630   (setq cont (or (cdr (assq 'tbody cont))
 631                  cont))
 632   (let* ((shr-inhibit-images t)
 633          (shr-kinsoku-shorten t)
 634          ;; Find all suggested widths.
 635          (columns (shr-column-specs cont))
 636          ;; Compute how many characters wide each TD should be.
 637          (suggested-widths (shr-pro-rate-columns columns))
 638          ;; Do a "test rendering" to see how big each TD is (this can
 639          ;; be smaller (if there's little text) or bigger (if there's
 640          ;; unbreakable text).
 641          (sketch (shr-make-table cont suggested-widths))
 642          (sketch-widths (shr-table-widths sketch suggested-widths)))
 643     ;; This probably won't work very well.
 644     (when (> (+ (loop for width across sketch-widths
 645                       summing (1+ width))
 646                 shr-indentation 1)
 647              (frame-width))
 648       (setq truncate-lines t))
 649     ;; Then render the table again with these new "hard" widths.
 650     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 651   ;; Finally, insert all the images after the table.  The Emacs buffer
 652   ;; model isn't strong enough to allow us to put the images actually
 653   ;; into the tables.
 654   (dolist (elem (shr-find-elements cont 'img))
 655     (shr-tag-img (cdr elem))))
 656
 657 (defun shr-tag-table (cont)
 658   (shr-ensure-paragraph)
 659   (let* ((caption (cdr (assq 'caption cont)))
 660          (header (cdr (assq 'thead cont)))
 661          (body (or (cdr (assq 'tbody cont)) cont))
 662          (footer (cdr (assq 'tfoot cont)))
 663          (nheader (if header (shr-max-columns header)))
 664          (nbody (if body (shr-max-columns body)))
 665          (nfooter (if footer (shr-max-columns footer))))
 666     (shr-tag-table-1
 667      (nconc
 668       (if caption `((tr (td ,@caption))))
 669       (if header
 670           (if footer
 671               ;; hader + body + footer
 672               (if (= nheader nbody)
 673                   (if (= nbody nfooter)
 674                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 675                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 676                            (if (= nfooter 1)
 677                                footer
 678                              `((tr (td (table (tbody ,@footer))))))))
 679                 (nconc `((tr (td (table (tbody ,@header)))))
 680                        (if (= nbody nfooter)
 681                            `((tr (td (table (tbody ,@body ,@footer)))))
 682                          (nconc `((tr (td (table (tbody ,@body)))))
 683                                 (if (= nfooter 1)
 684                                     footer
 685                                   `((tr (td (table (tbody ,@footer))))))))))
 686             ;; header + body
 687             (if (= nheader nbody)
 688                 `((tr (td (table (tbody ,@header ,@body)))))
 689               (if (= nheader 1)
 690                   `(,@header (tr (td (table (tbody ,@body)))))
 691                 `((tr (td (table (tbody ,@header))))
 692                   (tr (td (table (tbody ,@body))))))))
 693         (if footer
 694             ;; body + footer
 695             (if (= nbody nfooter)
 696                 `((tr (td (table (tbody ,@body ,@footer)))))
 697               (nconc `((tr (td (table (tbody ,@body)))))
 698                      (if (= nfooter 1)
 699                          footer
 700                        `((tr (td (table (tbody ,@footer))))))))
 701           (if caption
 702               `((tr (td (table (tbody ,@body)))))
 703             body)))))))
 704
 705 (defun shr-find-elements (cont type)
 706   (let (result)
 707     (dolist (elem cont)
 708       (cond ((eq (car elem) type)
 709              (push elem result))
 710             ((consp (cdr elem))
 711              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 712     (nreverse result)))
 713
 714 (defun shr-insert-table (table widths)
 715   (shr-insert-table-ruler widths)
 716   (dolist (row table)
 717     (let ((start (point))
 718           (height (let ((max 0))
 719                     (dolist (column row)
 720                       (setq max (max max (cadr column))))
 721                     max)))
 722       (dotimes (i height)
 723         (shr-indent)
 724         (insert "|\n"))
 725       (dolist (column row)
 726         (goto-char start)
 727         (let ((lines (nth 2 column))
 728               (overlay-lines (nth 3 column))
 729               overlay overlay-line)
 730           (dolist (line lines)
 731             (setq overlay-line (pop overlay-lines))
 732             (end-of-line)
 733             (insert line "|")
 734             (dolist (overlay overlay-line)
 735               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 736                                      (- (point) (nth 1 overlay) 1)))
 737                     (properties (nth 2 overlay)))
 738                 (while properties
 739                   (overlay-put o (pop properties) (pop properties)))))
 740             (forward-line 1))
 741           ;; Add blank lines at padding at the bottom of the TD,
 742           ;; possibly.
 743           (dotimes (i (- height (length lines)))
 744             (end-of-line)
 745             (insert (make-string (string-width (car lines)) ? ) "|")
 746             (forward-line 1)))))
 747     (shr-insert-table-ruler widths)))
 748
 749 (defun shr-insert-table-ruler (widths)
 750   (when (and (bolp)
 751              (> shr-indentation 0))
 752     (shr-indent))
 753   (insert shr-table-corner)
 754   (dotimes (i (length widths))
 755     (insert (make-string (aref widths i) shr-table-line) shr-table-corner))
 756   (insert "\n"))
 757
 758 (defun shr-table-widths (table suggested-widths)
 759   (let* ((length (length suggested-widths))
 760          (widths (make-vector length 0))
 761          (natural-widths (make-vector length 0)))
 762     (dolist (row table)
 763       (let ((i 0))
 764         (dolist (column row)
 765           (aset widths i (max (aref widths i)
 766                               (car column)))
 767           (aset natural-widths i (max (aref natural-widths i)
 768                                       (cadr column)))
 769           (setq i (1+ i)))))
 770     (let ((extra (- (apply '+ (append suggested-widths nil))
 771                     (apply '+ (append widths nil))))
 772           (expanded-columns 0))
 773       (when (> extra 0)
 774         (dotimes (i length)
 775           ;; If the natural width is wider than the rendered width, we
 776           ;; want to allow the column to expand.
 777           (when (> (aref natural-widths i) (aref widths i))
 778             (setq expanded-columns (1+ expanded-columns))))
 779         (dotimes (i length)
 780           (when (> (aref natural-widths i) (aref widths i))
 781             (aset widths i (min
 782                             (1+ (aref natural-widths i))
 783                             (+ (/ extra expanded-columns)
 784                                (aref widths i))))))))
 785     widths))
 786
 787 (defun shr-make-table (cont widths &optional fill)
 788   (let ((trs nil))
 789     (dolist (row cont)
 790       (when (eq (car row) 'tr)
 791         (let ((tds nil)
 792               (columns (cdr row))
 793               (i 0)
 794               column)
 795           (while (< i (length widths))
 796             (setq column (pop columns))
 797             (when (or (memq (car column) '(td th))
 798                       (null column))
 799               (push (shr-render-td (cdr column) (aref widths i) fill)
 800                     tds)
 801               (setq i (1+ i))))
 802           (push (nreverse tds) trs))))
 803     (nreverse trs)))
 804
 805 (defun shr-render-td (cont width fill)
 806   (with-temp-buffer
 807     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
 808       (if cache
 809           (insert cache)
 810         (let ((shr-width width)
 811               (shr-indentation 0))
 812           (shr-generic cont))
 813         (delete-region
 814          (point)
 815          (+ (point)
 816             (skip-chars-backward " \t\n")))
 817         (push (cons (cons width cont) (buffer-string))
 818               shr-content-cache)))
 819     (goto-char (point-min))
 820     (let ((max 0))
 821       (while (not (eobp))
 822         (end-of-line)
 823         (setq max (max max (current-column)))
 824         (forward-line 1))
 825       (when fill
 826         (goto-char (point-min))
 827         ;; If the buffer is totally empty, then put a single blank
 828         ;; line here.
 829         (if (zerop (buffer-size))
 830             (insert (make-string width ? ))
 831           ;; Otherwise, fill the buffer.
 832           (while (not (eobp))
 833             (end-of-line)
 834             (when (> (- width (current-column)) 0)
 835               (insert (make-string (- width (current-column)) ? )))
 836             (forward-line 1))))
 837       (if fill
 838           (list max
 839                 (count-lines (point-min) (point-max))
 840                 (split-string (buffer-string) "\n")
 841                 (shr-collect-overlays))
 842         (list max
 843               (shr-natural-width))))))
 844
 845 (defun shr-natural-width ()
 846   (goto-char (point-min))
 847   (let ((current 0)
 848         (max 0))
 849     (while (not (eobp))
 850       (end-of-line)
 851       (setq current (+ current (current-column)))
 852       (unless (get-text-property (point) 'shr-break)
 853         (setq max (max max current)
 854               current 0))
 855       (forward-line 1))
 856     max))
 857
 858 (defun shr-collect-overlays ()
 859   (save-excursion
 860     (goto-char (point-min))
 861     (let ((overlays nil))
 862       (while (not (eobp))
 863         (push (shr-overlays-in-region (point) (line-end-position))
 864               overlays)
 865         (forward-line 1))
 866       (nreverse overlays))))
 867
 868 (defun shr-overlays-in-region (start end)
 869   (let (result)
 870     (dolist (overlay (overlays-in start end))
 871       (push (list (if (> start (overlay-start overlay))
 872                       (- end start)
 873                     (- end (overlay-start overlay)))
 874                   (if (< end (overlay-end overlay))
 875                       0
 876                     (- end (overlay-end overlay)))
 877                   (overlay-properties overlay))
 878             result))
 879     (nreverse result)))
 880
 881 (defun shr-pro-rate-columns (columns)
 882   (let ((total-percentage 0)
 883         (widths (make-vector (length columns) 0)))
 884     (dotimes (i (length columns))
 885       (setq total-percentage (+ total-percentage (aref columns i))))
 886     (setq total-percentage (/ 1.0 total-percentage))
 887     (dotimes (i (length columns))
 888       (aset widths i (max (truncate (* (aref columns i)
 889                                        total-percentage
 890                                        (- shr-width (1+ (length columns)))))
 891                           10)))
 892     widths))
 893
 894 ;; Return a summary of the number and shape of the TDs in the table.
 895 (defun shr-column-specs (cont)
 896   (let ((columns (make-vector (shr-max-columns cont) 1)))
 897     (dolist (row cont)
 898       (when (eq (car row) 'tr)
 899         (let ((i 0))
 900           (dolist (column (cdr row))
 901             (when (memq (car column) '(td th))
 902               (let ((width (cdr (assq :width (cdr column)))))
 903                 (when (and width
 904                            (string-match "\\([0-9]+\\)%" width))
 905                   (aset columns i
 906                         (/ (string-to-number (match-string 1 width))
 907                            100.0))))
 908               (setq i (1+ i)))))))
 909     columns))
 910
 911 (defun shr-count (cont elem)
 912   (let ((i 0))
 913     (dolist (sub cont)
 914       (when (eq (car sub) elem)
 915         (setq i (1+ i))))
 916     i))
 917
 918 (defun shr-max-columns (cont)
 919   (let ((max 0))
 920     (dolist (row cont)
 921       (when (eq (car row) 'tr)
 922         (setq max (max max (+ (shr-count (cdr row) 'td)
 923                               (shr-count (cdr row) 'th))))))
 924     max))
 925
 926 (provide 'shr)
 927
 928 ;;; shr.el ends here