cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :group 'mail)
  39
  40 (defcustom shr-max-image-proportion 0.9
  41   "How big pictures displayed are in relation to the window they're in.
  42 A value of 0.7 means that they are allowed to take up 70% of the
  43 width and height of the window.  If they are larger than this,
  44 and Emacs supports it, then the images will be rescaled down to
  45 fit these criteria."
  46   :version "24.1"
  47   :group 'shr
  48   :type 'float)
  49
  50 (defcustom shr-blocked-images nil
  51   "Images that have URLs matching this regexp will be blocked."
  52   :version "24.1"
  53   :group 'shr
  54   :type 'regexp)
  55
  56 (defcustom shr-table-horizontal-line ?-
  57   "Character used to draw horizontal table lines."
  58   :group 'shr
  59   :type 'character)
  60
  61 (defcustom shr-table-vertical-line ?|
  62   "Character used to draw vertical table lines."
  63   :group 'shr
  64   :type 'character)
  65
  66 (defcustom shr-table-corner ?+
  67   "Character used to draw table corners."
  68   :group 'shr
  69   :type 'character)
  70
  71 (defcustom shr-hr-line ?-
  72   "Character used to draw hr lines."
  73   :group 'shr
  74   :type 'character)
  75
  76 (defcustom shr-width fill-column
  77   "Frame width to use for rendering."
  78   :type 'integer
  79   :group 'shr)
  80
  81 (defvar shr-content-function nil
  82   "If bound, this should be a function that will return the content.
  83 This is used for cid: URLs, and the function is called with the
  84 cid: URL as the argument.")
  85
  86 ;;; Internal variables.
  87
  88 (defvar shr-folding-mode nil)
  89 (defvar shr-state nil)
  90 (defvar shr-start nil)
  91 (defvar shr-indentation 0)
  92 (defvar shr-inhibit-images nil)
  93 (defvar shr-list-mode nil)
  94 (defvar shr-content-cache nil)
  95 (defvar shr-kinsoku-shorten nil)
  96 (defvar shr-table-depth 0)
  97 (defvar shr-stylesheet nil)
  98
  99 (defvar shr-map
 100   (let ((map (make-sparse-keymap)))
 101     (define-key map "a" 'shr-show-alt-text)
 102     (define-key map "i" 'shr-browse-image)
 103     (define-key map "I" 'shr-insert-image)
 104     (define-key map "u" 'shr-copy-url)
 105     (define-key map "v" 'shr-browse-url)
 106     (define-key map "o" 'shr-save-contents)
 107     (define-key map "\r" 'shr-browse-url)
 108     map))
 109
 110 ;; Public functions and commands.
 111
 112 ;;;###autoload
 113 (defun shr-insert-document (dom)
 114   (setq shr-content-cache nil)
 115   (let ((shr-state nil)
 116         (shr-start nil))
 117     (shr-descend (shr-transform-dom dom))))
 118
 119 (defun shr-copy-url ()
 120   "Copy the URL under point to the kill ring.
 121 If called twice, then try to fetch the URL and see whether it
 122 redirects somewhere else."
 123   (interactive)
 124   (let ((url (get-text-property (point) 'shr-url)))
 125     (cond
 126      ((not url)
 127       (message "No URL under point"))
 128      ;; Resolve redirected URLs.
 129      ((equal url (car kill-ring))
 130       (url-retrieve
 131        url
 132        (lambda (a)
 133          (when (and (consp a)
 134                     (eq (car a) :redirect))
 135            (with-temp-buffer
 136              (insert (cadr a))
 137              (goto-char (point-min))
 138              ;; Remove common tracking junk from the URL.
 139              (when (re-search-forward ".utm_.*" nil t)
 140                (replace-match "" t t))
 141              (message "Copied %s" (buffer-string))
 142              (copy-region-as-kill (point-min) (point-max)))))))
 143      ;; Copy the URL to the kill ring.
 144      (t
 145       (with-temp-buffer
 146         (insert url)
 147         (copy-region-as-kill (point-min) (point-max))
 148         (message "Copied %s" url))))))
 149
 150 (defun shr-show-alt-text ()
 151   "Show the ALT text of the image under point."
 152   (interactive)
 153   (let ((text (get-text-property (point) 'shr-alt)))
 154     (if (not text)
 155         (message "No image under point")
 156       (message "%s" text))))
 157
 158 (defun shr-browse-image ()
 159   "Browse the image under point."
 160   (interactive)
 161   (let ((url (get-text-property (point) 'image-url)))
 162     (if (not url)
 163         (message "No image under point")
 164       (message "Browsing %s..." url)
 165       (browse-url url))))
 166
 167 (defun shr-insert-image ()
 168   "Insert the image under point into the buffer."
 169   (interactive)
 170   (let ((url (get-text-property (point) 'image-url)))
 171     (if (not url)
 172         (message "No image under point")
 173       (message "Inserting %s..." url)
 174       (url-retrieve url 'shr-image-fetched
 175                     (list (current-buffer) (1- (point)) (point-marker))
 176                     t))))
 177
 178 ;;; Utility functions.
 179
 180 (defun shr-transform-dom (dom)
 181   (let ((result (list (pop dom))))
 182     (dolist (arg (pop dom))
 183       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 184                   (cdr arg))
 185             result))
 186     (dolist (sub dom)
 187       (if (stringp sub)
 188           (push (cons 'text sub) result)
 189         (push (shr-transform-dom sub) result)))
 190     (nreverse result)))
 191
 192 (defun shr-descend (dom)
 193   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 194         (style (cdr (assq :style (cdr dom))))
 195         (shr-stylesheet shr-stylesheet)
 196         (start (point)))
 197     (when style
 198       (if (string-match "color" style)
 199           (setq shr-stylesheet (nconc (shr-parse-style style)
 200                                       shr-stylesheet))
 201         (setq style nil)))
 202     (if (fboundp function)
 203         (funcall function (cdr dom))
 204       (shr-generic (cdr dom)))
 205     ;; If style is set, then this node has set the color.
 206     (when style
 207       (shr-colorize-region start (point)
 208                            (cdr (assq 'color shr-stylesheet))
 209                            (cdr (assq 'background-color shr-stylesheet))))))
 210
 211 (defun shr-generic (cont)
 212   (dolist (sub cont)
 213     (cond
 214      ((eq (car sub) 'text)
 215       (shr-insert (cdr sub)))
 216      ((listp (cdr sub))
 217       (shr-descend sub)))))
 218
 219 (defmacro shr-char-breakable-p (char)
 220   "Return non-nil if a line can be broken before and after CHAR."
 221   `(aref fill-find-break-point-function-table ,char))
 222 (defmacro shr-char-nospace-p (char)
 223   "Return non-nil if no space is required before and after CHAR."
 224   `(aref fill-nospace-between-words-table ,char))
 225
 226 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 227 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 228 ;; parentheses, and so on, that should not be placed in the beginning
 229 ;; of a line or the end of a line.
 230 (defmacro shr-char-kinsoku-bol-p (char)
 231   "Return non-nil if a line ought not to begin with CHAR."
 232   `(aref (char-category-set ,char) ?>))
 233 (defmacro shr-char-kinsoku-eol-p (char)
 234   "Return non-nil if a line ought not to end with CHAR."
 235   `(aref (char-category-set ,char) ?<))
 236 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 237   (load "kinsoku" nil t))
 238
 239 (defun shr-insert (text)
 240   (when (and (eq shr-state 'image)
 241              (not (string-match "\\`[ \t\n]+\\'" text)))
 242     (insert "\n")
 243     (setq shr-state nil))
 244   (cond
 245    ((eq shr-folding-mode 'none)
 246     (insert text))
 247    (t
 248     (when (and (string-match "\\`[ \t\n]" text)
 249                (not (bolp))
 250                (not (eq (char-after (1- (point))) ? )))
 251       (insert " "))
 252     (dolist (elem (split-string text))
 253       (when (and (bolp)
 254                  (> shr-indentation 0))
 255         (shr-indent))
 256       ;; The shr-start is a special variable that is used to pass
 257       ;; upwards the first point in the buffer where the text really
 258       ;; starts.
 259       (unless shr-start
 260         (setq shr-start (point)))
 261       ;; No space is needed behind a wide character categorized as
 262       ;; kinsoku-bol, between characters both categorized as nospace,
 263       ;; or at the beginning of a line.
 264       (let (prev)
 265         (when (and (eq (preceding-char) ? )
 266                    (or (= (line-beginning-position) (1- (point)))
 267                        (and (shr-char-breakable-p
 268                              (setq prev (char-after (- (point) 2))))
 269                             (shr-char-kinsoku-bol-p prev))
 270                        (and (shr-char-nospace-p prev)
 271                             (shr-char-nospace-p (aref elem 0)))))
 272           (delete-char -1)))
 273       (insert elem)
 274       (let (found)
 275         (while (and (> (current-column) shr-width)
 276                     (progn
 277                       (setq found (shr-find-fill-point))
 278                       (not (eolp))))
 279           (when (eq (preceding-char) ? )
 280             (delete-char -1))
 281           (insert "\n")
 282           (unless found
 283             (put-text-property (1- (point)) (point) 'shr-break t)
 284             ;; No space is needed at the beginning of a line.
 285             (when (eq (following-char) ? )
 286               (delete-char 1)))
 287           (when (> shr-indentation 0)
 288             (shr-indent))
 289           (end-of-line))
 290         (insert " ")))
 291     (unless (string-match "[ \t\n]\\'" text)
 292       (delete-char -1)))))
 293
 294 (defun shr-find-fill-point ()
 295   (when (> (move-to-column shr-width) shr-width)
 296     (backward-char 1))
 297   (let ((bp (point))
 298         failed)
 299     (while (not (or (setq failed (= (current-column) shr-indentation))
 300                     (eq (preceding-char) ? )
 301                     (eq (following-char) ? )
 302                     (shr-char-breakable-p (preceding-char))
 303                     (shr-char-breakable-p (following-char))
 304                     (if (eq (preceding-char) ?')
 305                         (not (memq (char-after (- (point) 2))
 306                                    (list nil ?\n ? )))
 307                       (and (shr-char-kinsoku-bol-p (preceding-char))
 308                            (shr-char-breakable-p (following-char))
 309                            (not (shr-char-kinsoku-bol-p (following-char)))))
 310                     (shr-char-kinsoku-eol-p (following-char))))
 311       (backward-char 1))
 312     (if (and (not (or failed (eolp)))
 313              (eq (preceding-char) ?'))
 314         (while (not (or (setq failed (eolp))
 315                         (eq (following-char) ? )
 316                         (shr-char-breakable-p (following-char))
 317                         (shr-char-kinsoku-eol-p (following-char))))
 318           (forward-char 1)))
 319     (if failed
 320         ;; There's no breakable point, so we give it up.
 321         (let (found)
 322           (goto-char bp)
 323           (unless shr-kinsoku-shorten
 324             (while (and (setq found (re-search-forward
 325                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 326                                      (line-end-position) 'move))
 327                         (eq (preceding-char) ?')))
 328             (if (and found (not (match-beginning 1)))
 329                 (goto-char (match-beginning 0)))))
 330       (or
 331        (eolp)
 332        ;; Don't put kinsoku-bol characters at the beginning of a line,
 333        ;; or kinsoku-eol characters at the end of a line.
 334        (cond
 335         (shr-kinsoku-shorten
 336          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 337                      (shr-char-kinsoku-eol-p (preceding-char)))
 338            (backward-char 1))
 339          (when (setq failed (= (current-column) shr-indentation))
 340            ;; There's no breakable point that doesn't violate kinsoku,
 341            ;; so we look for the second best position.
 342            (while (and (progn
 343                          (forward-char 1)
 344                          (<= (current-column) shr-width))
 345                        (progn
 346                          (setq bp (point))
 347                          (shr-char-kinsoku-eol-p (following-char)))))
 348            (goto-char bp)))
 349         ((shr-char-kinsoku-eol-p (preceding-char))
 350          (if (shr-char-kinsoku-eol-p (following-char))
 351              ;; There are consecutive kinsoku-eol characters.
 352              (setq failed t)
 353            (let ((count 4))
 354              (while
 355                  (progn
 356                    (backward-char 1)
 357                    (and (> (setq count (1- count)) 0)
 358                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 359                         (or (shr-char-kinsoku-eol-p (preceding-char))
 360                             (shr-char-kinsoku-bol-p (following-char)))))))
 361            (if (setq failed (= (current-column) shr-indentation))
 362                ;; There's no breakable point that doesn't violate kinsoku,
 363                ;; so we go to the second best position.
 364                (if (looking-at "\\(\\c<+\\)\\c<")
 365                    (goto-char (match-end 1))
 366                  (forward-char 1)))))
 367         (t
 368          (if (shr-char-kinsoku-bol-p (preceding-char))
 369              ;; There are consecutive kinsoku-bol characters.
 370              (setq failed t)
 371            (let ((count 4))
 372              (while (and (>= (setq count (1- count)) 0)
 373                          (shr-char-kinsoku-bol-p (following-char))
 374                          (shr-char-breakable-p (following-char)))
 375                (forward-char 1))))))
 376        (when (eq (following-char) ? )
 377          (forward-char 1))))
 378     (not failed)))
 379
 380 (defun shr-ensure-newline ()
 381   (unless (zerop (current-column))
 382     (insert "\n")))
 383
 384 (defun shr-ensure-paragraph ()
 385   (unless (bobp)
 386     (if (<= (current-column) shr-indentation)
 387         (unless (save-excursion
 388                   (forward-line -1)
 389                   (looking-at " *$"))
 390           (insert "\n"))
 391       (if (save-excursion
 392             (beginning-of-line)
 393             (looking-at " *$"))
 394           (insert "\n")
 395         (insert "\n\n")))))
 396
 397 (defun shr-indent ()
 398   (when (> shr-indentation 0)
 399     (insert (make-string shr-indentation ? ))))
 400
 401 (defun shr-fontize-cont (cont &rest types)
 402   (let (shr-start)
 403     (shr-generic cont)
 404     (dolist (type types)
 405       (shr-add-font (or shr-start (point)) (point) type))))
 406
 407 ;; Add an overlay in the region, but avoid putting the font properties
 408 ;; on blank text at the start of the line, and the newline at the end,
 409 ;; to avoid ugliness.
 410 (defun shr-add-font (start end type)
 411   (save-excursion
 412     (goto-char start)
 413     (while (< (point) end)
 414       (when (bolp)
 415         (skip-chars-forward " "))
 416       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 417         (overlay-put overlay 'face type))
 418       (if (< (line-end-position) end)
 419           (forward-line 1)
 420         (goto-char end)))))
 421
 422 (defun shr-browse-url ()
 423   "Browse the URL under point."
 424   (interactive)
 425   (let ((url (get-text-property (point) 'shr-url)))
 426     (cond
 427      ((not url)
 428       (message "No link under point"))
 429      ((string-match "^mailto:" url)
 430       (browse-url-mailto url))
 431      (t
 432       (browse-url url)))))
 433
 434 (defun shr-save-contents (directory)
 435   "Save the contents from URL in a file."
 436   (interactive "DSave contents of URL to directory: ")
 437   (let ((url (get-text-property (point) 'shr-url)))
 438     (if (not url)
 439         (message "No link under point")
 440       (url-retrieve (shr-encode-url url)
 441                     'shr-store-contents (list url directory)))))
 442
 443 (defun shr-store-contents (status url directory)
 444   (unless (plist-get status :error)
 445     (when (or (search-forward "\n\n" nil t)
 446               (search-forward "\r\n\r\n" nil t))
 447       (write-region (point) (point-max)
 448                     (expand-file-name (file-name-nondirectory url)
 449                                       directory)))))
 450
 451 (defun shr-image-fetched (status buffer start end)
 452   (when (and (buffer-name buffer)
 453              (not (plist-get status :error)))
 454     (url-store-in-cache (current-buffer))
 455     (when (or (search-forward "\n\n" nil t)
 456               (search-forward "\r\n\r\n" nil t))
 457       (let ((data (buffer-substring (point) (point-max))))
 458         (with-current-buffer buffer
 459           (let ((alt (buffer-substring start end))
 460                 (inhibit-read-only t))
 461             (delete-region start end)
 462             (goto-char start)
 463             (shr-put-image data alt))))))
 464   (kill-buffer (current-buffer)))
 465
 466 (defun shr-put-image (data alt)
 467   (if (display-graphic-p)
 468       (let ((image (ignore-errors
 469                      (shr-rescale-image data))))
 470         (when image
 471           ;; When inserting big-ish pictures, put them at the
 472           ;; beginning of the line.
 473           (when (and (> (current-column) 0)
 474                      (> (car (image-size image t)) 400))
 475             (insert "\n"))
 476           (insert-image image (or alt "*"))))
 477     (insert alt)))
 478
 479 (defun shr-rescale-image (data)
 480   (if (or (not (fboundp 'imagemagick-types))
 481           (not (get-buffer-window (current-buffer))))
 482       (create-image data nil t)
 483     (let* ((image (create-image data nil t))
 484            (size (image-size image t))
 485            (width (car size))
 486            (height (cdr size))
 487            (edges (window-inside-pixel-edges
 488                    (get-buffer-window (current-buffer))))
 489            (window-width (truncate (* shr-max-image-proportion
 490                                       (- (nth 2 edges) (nth 0 edges)))))
 491            (window-height (truncate (* shr-max-image-proportion
 492                                        (- (nth 3 edges) (nth 1 edges)))))
 493            scaled-image)
 494       (when (> height window-height)
 495         (setq image (or (create-image data 'imagemagick t
 496                                       :height window-height)
 497                         image))
 498         (setq size (image-size image t)))
 499       (when (> (car size) window-width)
 500         (setq image (or
 501                      (create-image data 'imagemagick t
 502                                    :width window-width)
 503                      image)))
 504       image)))
 505
 506 ;; url-cache-extract autoloads url-cache.
 507 (declare-function url-cache-create-filename "url-cache" (url))
 508 (autoload 'mm-disable-multibyte "mm-util")
 509 (autoload 'browse-url-mailto "browse-url")
 510
 511 (defun shr-get-image-data (url)
 512   "Get image data for URL.
 513 Return a string with image data."
 514   (with-temp-buffer
 515     (mm-disable-multibyte)
 516     (when (ignore-errors
 517             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 518             t)
 519       (when (or (search-forward "\n\n" nil t)
 520                 (search-forward "\r\n\r\n" nil t))
 521         (buffer-substring (point) (point-max))))))
 522
 523 (defun shr-image-displayer (content-function)
 524   "Return a function to display an image.
 525 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 526 is an argument.  The function to be returned takes three arguments URL,
 527 START, and END.  Note that START and END should be merkers."
 528   `(lambda (url start end)
 529      (when url
 530        (if (string-match "\\`cid:" url)
 531            ,(when content-function
 532               `(let ((image (funcall ,content-function
 533                                      (substring url (match-end 0)))))
 534                  (when image
 535                    (goto-char start)
 536                    (shr-put-image image
 537                                   (buffer-substring-no-properties start end))
 538                    (delete-region (point) end))))
 539          (url-retrieve url 'shr-image-fetched
 540                        (list (current-buffer) start end)
 541                        t)))))
 542
 543 (defun shr-heading (cont &rest types)
 544   (shr-ensure-paragraph)
 545   (apply #'shr-fontize-cont cont types)
 546   (shr-ensure-paragraph))
 547
 548 (autoload 'widget-convert-button "wid-edit")
 549
 550 (defun shr-urlify (start url &optional title)
 551   (widget-convert-button
 552    'url-link start (point)
 553    :help-echo (if title (format "%s (%s)" url title) url)
 554    :keymap shr-map
 555    url)
 556   (put-text-property start (point) 'shr-url url))
 557
 558 (defun shr-encode-url (url)
 559   "Encode URL."
 560   (browse-url-url-encode-chars url "[)$ ]"))
 561
 562 (autoload 'shr-color-visible "shr-color")
 563 (autoload 'shr-color->hexadecimal "shr-color")
 564
 565 (defun shr-color-check (fg bg)
 566   "Check that FG is visible on BG.
 567 Returns (fg bg) with corrected values.
 568 Returns nil if the colors that would be used are the default
 569 ones, in case fg and bg are nil."
 570   (when (or fg bg)
 571     (let ((fixed (cond ((null fg) 'fg)
 572                        ((null bg) 'bg))))
 573       ;; Convert colors to hexadecimal, or set them to default.
 574       (let ((fg (or (shr-color->hexadecimal fg)
 575                     (frame-parameter nil 'foreground-color)))
 576             (bg (or (shr-color->hexadecimal bg)
 577                     (frame-parameter nil 'background-color))))
 578         (cond ((eq fixed 'bg)
 579                ;; Only return the new fg
 580                (list nil (cadr (shr-color-visible bg fg t))))
 581               ((eq fixed 'fg)
 582                ;; Invert args and results and return only the new bg
 583                (list (cadr (shr-color-visible fg bg t)) nil))
 584               (t
 585                (shr-color-visible bg fg)))))))
 586
 587 (defun shr-colorize-region (start end fg &optional bg)
 588   (when (or fg bg)
 589     (let ((new-colors (shr-color-check fg bg)))
 590       (when new-colors
 591         (when fg
 592           (shr-put-color start end :foreground (cadr new-colors)))
 593         (when bg
 594           (shr-put-color start end :background (car new-colors)))))))
 595
 596 ;; Put a color in the region, but avoid putting colors on on blank
 597 ;; text at the start of the line, and the newline at the end, to avoid
 598 ;; ugliness.  Also, don't overwrite any existing color information,
 599 ;; since this can be called recursively, and we want the "inner" color
 600 ;; to win.
 601 (defun shr-put-color (start end type color)
 602   (save-excursion
 603     (goto-char start)
 604     (while (< (point) end)
 605       (when (bolp)
 606         (skip-chars-forward " "))
 607       (when (> (line-end-position) (point))
 608         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 609       (if (< (line-end-position) end)
 610           (forward-line 1)
 611         (goto-char end)))))
 612
 613 (defun shr-put-color-1 (start end type color)
 614   (let* ((old-props (get-text-property start 'face))
 615          (do-put (not (memq type old-props)))
 616          change)
 617     (while (< start end)
 618       (setq change (next-single-property-change start 'face nil end))
 619       (when do-put
 620         (put-text-property start change 'face
 621                            (nconc (list type color) old-props)))
 622       (setq old-props (get-text-property change 'face))
 623       (setq do-put (not (memq type old-props)))
 624       (setq start change))
 625     (when (and do-put
 626                (> end start))
 627       (put-text-property start end 'face
 628                          (nconc (list type color old-props))))))
 629
 630 ;;; Tag-specific rendering rules.
 631
 632 (defun shr-tag-body (cont)
 633   (let* ((start (point))
 634          (fgcolor (cdr (assq :fgcolor cont)))
 635          (bgcolor (cdr (assq :bgcolor cont)))
 636          (shr-stylesheet (list (cons 'color fgcolor)
 637                                (cons 'background-color bgcolor))))
 638     (shr-generic cont)
 639     (shr-colorize-region start (point) fgcolor bgcolor)))
 640
 641 (defun shr-tag-style (cont)
 642   )
 643
 644 (defun shr-tag-p (cont)
 645   (shr-ensure-paragraph)
 646   (shr-indent)
 647   (shr-generic cont)
 648   (shr-ensure-paragraph))
 649
 650 (defun shr-tag-div (cont)
 651   (shr-ensure-newline)
 652   (shr-indent)
 653   (shr-generic cont)
 654   (shr-ensure-newline))
 655
 656 (defun shr-tag-b (cont)
 657   (shr-fontize-cont cont 'bold))
 658
 659 (defun shr-tag-i (cont)
 660   (shr-fontize-cont cont 'italic))
 661
 662 (defun shr-tag-em (cont)
 663   (shr-fontize-cont cont 'bold))
 664
 665 (defun shr-tag-strong (cont)
 666   (shr-fontize-cont cont 'bold))
 667
 668 (defun shr-tag-u (cont)
 669   (shr-fontize-cont cont 'underline))
 670
 671 (defun shr-tag-s (cont)
 672   (shr-fontize-cont cont 'strike-through))
 673
 674 (defun shr-parse-style (style)
 675   (when style
 676     (save-match-data
 677       (when (string-match "\n" style)
 678         (setq style (replace-match " " t t style))))
 679     (let ((plist nil))
 680       (dolist (elem (split-string style ";"))
 681         (when elem
 682           (setq elem (split-string elem ":"))
 683           (when (and (car elem)
 684                      (cadr elem))
 685             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 686                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 687               (when (string-match " *!important\\'" value)
 688                 (setq value (substring value 0 (match-beginning 0))))
 689               (push (cons (intern name obarray)
 690                           value)
 691                     plist)))))
 692       plist)))
 693
 694 (defun shr-tag-a (cont)
 695   (let ((url (cdr (assq :href cont)))
 696         (title (cdr (assq :title cont)))
 697         (start (point))
 698         shr-start)
 699     (shr-generic cont)
 700     (shr-urlify (or shr-start start) url title)))
 701
 702 (defun shr-tag-object (cont)
 703   (let ((start (point))
 704         url)
 705     (dolist (elem cont)
 706       (when (eq (car elem) 'embed)
 707         (setq url (or url (cdr (assq :src (cdr elem))))))
 708       (when (and (eq (car elem) 'param)
 709                  (equal (cdr (assq :name (cdr elem))) "movie"))
 710         (setq url (or url (cdr (assq :value (cdr elem)))))))
 711     (when url
 712       (shr-insert " [multimedia] ")
 713       (shr-urlify start url))
 714     (shr-generic cont)))
 715
 716 (defun shr-tag-video (cont)
 717   (let ((image (cdr (assq :poster cont)))
 718         (url (cdr (assq :src cont)))
 719         (start (point)))
 720     (shr-tag-img nil image)
 721     (shr-urlify start url)))
 722
 723 (defun shr-tag-img (cont &optional url)
 724   (when (or url
 725             (and cont
 726                  (cdr (assq :src cont))))
 727     (when (and (> (current-column) 0)
 728                (not (eq shr-state 'image)))
 729       (insert "\n"))
 730     (let ((alt (cdr (assq :alt cont)))
 731           (url (or url (cdr (assq :src cont)))))
 732       (let ((start (point-marker)))
 733         (when (zerop (length alt))
 734           (setq alt "*"))
 735         (cond
 736          ((or (member (cdr (assq :height cont)) '("0" "1"))
 737               (member (cdr (assq :width cont)) '("0" "1")))
 738           ;; Ignore zero-sized or single-pixel images.
 739           )
 740          ((and (not shr-inhibit-images)
 741                (string-match "\\`cid:" url))
 742           (let ((url (substring url (match-end 0)))
 743                 image)
 744             (if (or (not shr-content-function)
 745                     (not (setq image (funcall shr-content-function url))))
 746                 (insert alt)
 747               (shr-put-image image alt))))
 748          ((or shr-inhibit-images
 749               (and shr-blocked-images
 750                    (string-match shr-blocked-images url)))
 751           (setq shr-start (point))
 752           (let ((shr-state 'space))
 753             (if (> (string-width alt) 8)
 754                 (shr-insert (truncate-string-to-width alt 8))
 755               (shr-insert alt))))
 756          ((url-is-cached (shr-encode-url url))
 757           (shr-put-image (shr-get-image-data url) alt))
 758          (t
 759           (insert alt)
 760           (ignore-errors
 761             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 762                           (list (current-buffer) start (point-marker))
 763                           t))))
 764         (put-text-property start (point) 'keymap shr-map)
 765         (put-text-property start (point) 'shr-alt alt)
 766         (put-text-property start (point) 'image-url url)
 767         (put-text-property start (point) 'image-displayer
 768                            (shr-image-displayer shr-content-function))
 769         (put-text-property start (point) 'help-echo alt)
 770         (setq shr-state 'image)))))
 771
 772 (defun shr-tag-pre (cont)
 773   (let ((shr-folding-mode 'none))
 774     (shr-ensure-newline)
 775     (shr-indent)
 776     (shr-generic cont)
 777     (shr-ensure-newline)))
 778
 779 (defun shr-tag-blockquote (cont)
 780   (shr-ensure-paragraph)
 781   (shr-indent)
 782   (let ((shr-indentation (+ shr-indentation 4)))
 783     (shr-generic cont))
 784   (shr-ensure-paragraph))
 785
 786 (defun shr-tag-ul (cont)
 787   (shr-ensure-paragraph)
 788   (let ((shr-list-mode 'ul))
 789     (shr-generic cont))
 790   (shr-ensure-paragraph))
 791
 792 (defun shr-tag-ol (cont)
 793   (shr-ensure-paragraph)
 794   (let ((shr-list-mode 1))
 795     (shr-generic cont))
 796   (shr-ensure-paragraph))
 797
 798 (defun shr-tag-li (cont)
 799   (shr-ensure-paragraph)
 800   (shr-indent)
 801   (let* ((bullet
 802           (if (numberp shr-list-mode)
 803               (prog1
 804                   (format "%d " shr-list-mode)
 805                 (setq shr-list-mode (1+ shr-list-mode)))
 806             "* "))
 807          (shr-indentation (+ shr-indentation (length bullet))))
 808     (insert bullet)
 809     (shr-generic cont)))
 810
 811 (defun shr-tag-br (cont)
 812   (unless (bobp)
 813     (insert "\n")
 814     (shr-indent))
 815   (shr-generic cont))
 816
 817 (defun shr-tag-h1 (cont)
 818   (shr-heading cont 'bold 'underline))
 819
 820 (defun shr-tag-h2 (cont)
 821   (shr-heading cont 'bold))
 822
 823 (defun shr-tag-h3 (cont)
 824   (shr-heading cont 'italic))
 825
 826 (defun shr-tag-h4 (cont)
 827   (shr-heading cont))
 828
 829 (defun shr-tag-h5 (cont)
 830   (shr-heading cont))
 831
 832 (defun shr-tag-h6 (cont)
 833   (shr-heading cont))
 834
 835 (defun shr-tag-hr (cont)
 836   (shr-ensure-newline)
 837   (insert (make-string shr-width shr-hr-line) "\n"))
 838
 839 (defun shr-tag-title (cont)
 840   (shr-heading cont 'bold 'underline))
 841
 842 (defun shr-tag-font (cont)
 843   (let* ((start (point))
 844          (color (cdr (assq :color cont)))
 845          (shr-stylesheet (nconc (list (cons 'color color))
 846                                 shr-stylesheet)))
 847     (shr-generic cont)
 848     (when color
 849       (shr-colorize-region start (point) color
 850                            (cdr (assq 'background-color shr-stylesheet))))))
 851
 852 ;;; Table rendering algorithm.
 853
 854 ;; Table rendering is the only complicated thing here.  We do this by
 855 ;; first counting how many TDs there are in each TR, and registering
 856 ;; how wide they think they should be ("width=45%", etc).  Then we
 857 ;; render each TD separately (this is done in temporary buffers, so
 858 ;; that we can use all the rendering machinery as if we were in the
 859 ;; main buffer).  Now we know how much space each TD really takes, so
 860 ;; we then render everything again with the new widths, and finally
 861 ;; insert all these boxes into the main buffer.
 862 (defun shr-tag-table-1 (cont)
 863   (setq cont (or (cdr (assq 'tbody cont))
 864                  cont))
 865   (let* ((shr-inhibit-images t)
 866          (shr-table-depth (1+ shr-table-depth))
 867          (shr-kinsoku-shorten t)
 868          ;; Find all suggested widths.
 869          (columns (shr-column-specs cont))
 870          ;; Compute how many characters wide each TD should be.
 871          (suggested-widths (shr-pro-rate-columns columns))
 872          ;; Do a "test rendering" to see how big each TD is (this can
 873          ;; be smaller (if there's little text) or bigger (if there's
 874          ;; unbreakable text).
 875          (sketch (shr-make-table cont suggested-widths))
 876          (sketch-widths (shr-table-widths sketch suggested-widths)))
 877     ;; This probably won't work very well.
 878     (when (> (+ (loop for width across sketch-widths
 879                       summing (1+ width))
 880                 shr-indentation 1)
 881              (frame-width))
 882       (setq truncate-lines t))
 883     ;; Then render the table again with these new "hard" widths.
 884     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 885   ;; Finally, insert all the images after the table.  The Emacs buffer
 886   ;; model isn't strong enough to allow us to put the images actually
 887   ;; into the tables.
 888   (when (zerop shr-table-depth)
 889     (dolist (elem (shr-find-elements cont 'img))
 890       (shr-tag-img (cdr elem)))))
 891
 892 (defun shr-tag-table (cont)
 893   (shr-ensure-paragraph)
 894   (let* ((caption (cdr (assq 'caption cont)))
 895          (header (cdr (assq 'thead cont)))
 896          (body (or (cdr (assq 'tbody cont)) cont))
 897          (footer (cdr (assq 'tfoot cont)))
 898          (bgcolor (cdr (assq :bgcolor cont)))
 899          (start (point))
 900          (shr-stylesheet (nconc (list (cons 'background-color bgcolor))
 901                                 shr-stylesheet))
 902          (nheader (if header (shr-max-columns header)))
 903          (nbody (if body (shr-max-columns body)))
 904          (nfooter (if footer (shr-max-columns footer))))
 905     (shr-tag-table-1
 906      (nconc
 907       (if caption `((tr (td ,@caption))))
 908       (if header
 909           (if footer
 910               ;; hader + body + footer
 911               (if (= nheader nbody)
 912                   (if (= nbody nfooter)
 913                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 914                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 915                            (if (= nfooter 1)
 916                                footer
 917                              `((tr (td (table (tbody ,@footer))))))))
 918                 (nconc `((tr (td (table (tbody ,@header)))))
 919                        (if (= nbody nfooter)
 920                            `((tr (td (table (tbody ,@body ,@footer)))))
 921                          (nconc `((tr (td (table (tbody ,@body)))))
 922                                 (if (= nfooter 1)
 923                                     footer
 924                                   `((tr (td (table (tbody ,@footer))))))))))
 925             ;; header + body
 926             (if (= nheader nbody)
 927                 `((tr (td (table (tbody ,@header ,@body)))))
 928               (if (= nheader 1)
 929                   `(,@header (tr (td (table (tbody ,@body)))))
 930                 `((tr (td (table (tbody ,@header))))
 931                   (tr (td (table (tbody ,@body))))))))
 932         (if footer
 933             ;; body + footer
 934             (if (= nbody nfooter)
 935                 `((tr (td (table (tbody ,@body ,@footer)))))
 936               (nconc `((tr (td (table (tbody ,@body)))))
 937                      (if (= nfooter 1)
 938                          footer
 939                        `((tr (td (table (tbody ,@footer))))))))
 940           (if caption
 941               `((tr (td (table (tbody ,@body)))))
 942             body)))))
 943     (when bgcolor
 944       (shr-colorize-region start (point) (cdr (assq 'color shr-stylesheet))
 945                            bgcolor))))
 946
 947 (defun shr-find-elements (cont type)
 948   (let (result)
 949     (dolist (elem cont)
 950       (cond ((eq (car elem) type)
 951              (push elem result))
 952             ((consp (cdr elem))
 953              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 954     (nreverse result)))
 955
 956 (defun shr-insert-table (table widths)
 957   (shr-insert-table-ruler widths)
 958   (dolist (row table)
 959     (let ((start (point))
 960           (height (let ((max 0))
 961                     (dolist (column row)
 962                       (setq max (max max (cadr column))))
 963                     max)))
 964       (dotimes (i height)
 965         (shr-indent)
 966         (insert shr-table-vertical-line "\n"))
 967       (dolist (column row)
 968         (goto-char start)
 969         (let ((lines (nth 2 column))
 970               (overlay-lines (nth 3 column))
 971               overlay overlay-line)
 972           (dolist (line lines)
 973             (setq overlay-line (pop overlay-lines))
 974             (end-of-line)
 975             (insert line shr-table-vertical-line)
 976             (dolist (overlay overlay-line)
 977               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 978                                      (- (point) (nth 1 overlay) 1)))
 979                     (properties (nth 2 overlay)))
 980                 (while properties
 981                   (overlay-put o (pop properties) (pop properties)))))
 982             (forward-line 1))
 983           ;; Add blank lines at padding at the bottom of the TD,
 984           ;; possibly.
 985           (dotimes (i (- height (length lines)))
 986             (end-of-line)
 987             (insert (make-string (string-width (car lines)) ? )
 988                     shr-table-vertical-line)
 989             (forward-line 1)))))
 990     (shr-insert-table-ruler widths)))
 991
 992 (defun shr-insert-table-ruler (widths)
 993   (when (and (bolp)
 994              (> shr-indentation 0))
 995     (shr-indent))
 996   (insert shr-table-corner)
 997   (dotimes (i (length widths))
 998     (insert (make-string (aref widths i) shr-table-horizontal-line)
 999             shr-table-corner))
1000   (insert "\n"))
1001
1002 (defun shr-table-widths (table suggested-widths)
1003   (let* ((length (length suggested-widths))
1004          (widths (make-vector length 0))
1005          (natural-widths (make-vector length 0)))
1006     (dolist (row table)
1007       (let ((i 0))
1008         (dolist (column row)
1009           (aset widths i (max (aref widths i)
1010                               (car column)))
1011           (aset natural-widths i (max (aref natural-widths i)
1012                                       (cadr column)))
1013           (setq i (1+ i)))))
1014     (let ((extra (- (apply '+ (append suggested-widths nil))
1015                     (apply '+ (append widths nil))))
1016           (expanded-columns 0))
1017       (when (> extra 0)
1018         (dotimes (i length)
1019           ;; If the natural width is wider than the rendered width, we
1020           ;; want to allow the column to expand.
1021           (when (> (aref natural-widths i) (aref widths i))
1022             (setq expanded-columns (1+ expanded-columns))))
1023         (dotimes (i length)
1024           (when (> (aref natural-widths i) (aref widths i))
1025             (aset widths i (min
1026                             (1+ (aref natural-widths i))
1027                             (+ (/ extra expanded-columns)
1028                                (aref widths i))))))))
1029     widths))
1030
1031 (defun shr-make-table (cont widths &optional fill)
1032   (let ((trs nil))
1033     (dolist (row cont)
1034       (when (eq (car row) 'tr)
1035         (let ((tds nil)
1036               (columns (cdr row))
1037               (i 0)
1038               column)
1039           (while (< i (length widths))
1040             (setq column (pop columns))
1041             (when (or (memq (car column) '(td th))
1042                       (null column))
1043               (push (shr-render-td (cdr column) (aref widths i) fill)
1044                     tds)
1045               (setq i (1+ i))))
1046           (push (nreverse tds) trs))))
1047     (nreverse trs)))
1048
1049 (defun shr-render-td (cont width fill)
1050   (with-temp-buffer
1051     (let ((bgcolor (cdr (assq :bgcolor cont)))
1052           (fgcolor (cdr (assq :fgcolor cont)))
1053           (style (cdr (assq :style cont)))
1054           (shr-stylesheet shr-stylesheet)
1055           overlays)
1056       (when style
1057         (setq style (and (string-match "color" style)
1058                          (shr-parse-style style))))
1059       (when bgcolor
1060         (setq style (nconc (list (cons 'background-color bgcolor)) style)))
1061       (when fgcolor
1062         (setq style (nconc (list (cons 'color fgcolor)) style)))
1063       (when style
1064         (setq shr-stylesheet (append style shr-stylesheet)))
1065       (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1066         (if cache
1067             (progn
1068               (insert (car cache))
1069               (let ((end (length (car cache))))
1070                 (dolist (overlay (cadr cache))
1071                   (let ((new-overlay
1072                          (make-overlay (1+ (- end (nth 0 overlay)))
1073                                        (1+ (- end (nth 1 overlay)))))
1074                         (properties (nth 2 overlay)))
1075                     (while properties
1076                       (overlay-put new-overlay
1077                                    (pop properties) (pop properties)))))))
1078           (let ((shr-width width)
1079                 (shr-indentation 0))
1080             (shr-descend (cons 'td cont)))
1081           (delete-region
1082            (point)
1083            (+ (point)
1084               (skip-chars-backward " \t\n")))
1085           (push (list (cons width cont) (buffer-string)
1086                       (shr-overlays-in-region (point-min) (point-max)))
1087                 shr-content-cache)))
1088       (goto-char (point-min))
1089       (let ((max 0))
1090         (while (not (eobp))
1091           (end-of-line)
1092           (setq max (max max (current-column)))
1093           (forward-line 1))
1094         (when fill
1095           (goto-char (point-min))
1096           ;; If the buffer is totally empty, then put a single blank
1097           ;; line here.
1098           (if (zerop (buffer-size))
1099               (insert (make-string width ? ))
1100             ;; Otherwise, fill the buffer.
1101             (while (not (eobp))
1102               (end-of-line)
1103               (when (> (- width (current-column)) 0)
1104                 (insert (make-string (- width (current-column)) ? )))
1105               (forward-line 1))))
1106         (when style
1107           (shr-colorize-region
1108            (point-min) (point-max)
1109            (cdr (assq 'color shr-stylesheet))
1110            (cdr (assq 'background-color shr-stylesheet))))
1111         (if fill
1112             (list max
1113                   (count-lines (point-min) (point-max))
1114                   (split-string (buffer-string) "\n")
1115                   (shr-collect-overlays))
1116           (list max
1117                 (shr-natural-width)))))))
1118
1119 (defun shr-natural-width ()
1120   (goto-char (point-min))
1121   (let ((current 0)
1122         (max 0))
1123     (while (not (eobp))
1124       (end-of-line)
1125       (setq current (+ current (current-column)))
1126       (unless (get-text-property (point) 'shr-break)
1127         (setq max (max max current)
1128               current 0))
1129       (forward-line 1))
1130     max))
1131
1132 (defun shr-collect-overlays ()
1133   (save-excursion
1134     (goto-char (point-min))
1135     (let ((overlays nil))
1136       (while (not (eobp))
1137         (push (shr-overlays-in-region (point) (line-end-position))
1138               overlays)
1139         (forward-line 1))
1140       (nreverse overlays))))
1141
1142 (defun shr-overlays-in-region (start end)
1143   (let (result)
1144     (dolist (overlay (overlays-in start end))
1145       (push (list (if (> start (overlay-start overlay))
1146                       (- end start)
1147                     (- end (overlay-start overlay)))
1148                   (if (< end (overlay-end overlay))
1149                       0
1150                     (- end (overlay-end overlay)))
1151                   (overlay-properties overlay))
1152             result))
1153     (nreverse result)))
1154
1155 (defun shr-pro-rate-columns (columns)
1156   (let ((total-percentage 0)
1157         (widths (make-vector (length columns) 0)))
1158     (dotimes (i (length columns))
1159       (setq total-percentage (+ total-percentage (aref columns i))))
1160     (setq total-percentage (/ 1.0 total-percentage))
1161     (dotimes (i (length columns))
1162       (aset widths i (max (truncate (* (aref columns i)
1163                                        total-percentage
1164                                        (- shr-width (1+ (length columns)))))
1165                           10)))
1166     widths))
1167
1168 ;; Return a summary of the number and shape of the TDs in the table.
1169 (defun shr-column-specs (cont)
1170   (let ((columns (make-vector (shr-max-columns cont) 1)))
1171     (dolist (row cont)
1172       (when (eq (car row) 'tr)
1173         (let ((i 0))
1174           (dolist (column (cdr row))
1175             (when (memq (car column) '(td th))
1176               (let ((width (cdr (assq :width (cdr column)))))
1177                 (when (and width
1178                            (string-match "\\([0-9]+\\)%" width))
1179                   (aset columns i
1180                         (/ (string-to-number (match-string 1 width))
1181                            100.0))))
1182               (setq i (1+ i)))))))
1183     columns))
1184
1185 (defun shr-count (cont elem)
1186   (let ((i 0))
1187     (dolist (sub cont)
1188       (when (eq (car sub) elem)
1189         (setq i (1+ i))))
1190     i))
1191
1192 (defun shr-max-columns (cont)
1193   (let ((max 0))
1194     (dolist (row cont)
1195       (when (eq (car row) 'tr)
1196         (setq max (max max (+ (shr-count (cdr row) 'td)
1197                               (shr-count (cdr row) 'th))))))
1198     max))
1199
1200 (provide 'shr)
1201
1202 ;;; shr.el ends here