cgit.sxemacs.org Git - gnus/blob - lisp/proto-stream.el

   1 ;;; proto-stream.el --- negotiating TLS, STARTTLS and other connections
   2
   3 ;; Copyright (C) 2010-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library is meant to provide the glue between modules that want
  26 ;; to establish a network connection to a server for protocols such as
  27 ;; IMAP, NNTP, SMTP and POP3.
  28
  29 ;; The main problem is that there's more than a couple of interfaces
  30 ;; towards doing this.  You have normal, plain connections, which are
  31 ;; no trouble at all, but you also have TLS/SSL connections, and you
  32 ;; have STARTTLS.  Negotiating this for each protocol can be rather
  33 ;; tedious, so this library provides a single entry point, and hides
  34 ;; much of the ugliness.
  35
  36 ;; Usage example:
  37
  38 ;; (open-protocol-stream
  39 ;;  "*nnimap*" buffer address port
  40 ;;  :type 'network
  41 ;;  :capability-command "1 CAPABILITY\r\n"
  42 ;;  :success " OK "
  43 ;;  :starttls-function
  44 ;;  (lambda (capabilities)
  45 ;;    (if (not (string-match "STARTTLS" capabilities))
  46 ;;        nil
  47 ;;      "1 STARTTLS\r\n")))
  48
  49 ;;; Code:
  50
  51 (eval-when-compile
  52   (require 'cl))
  53 (require 'tls)
  54 (require 'starttls)
  55 (require 'format-spec)
  56
  57 (defcustom proto-stream-always-use-starttls (fboundp 'open-gnutls-stream)
  58   "If non-nil, always try to upgrade network connections with STARTTLS."
  59   :version "24.1"
  60   :type 'boolean
  61   :group 'comm)
  62
  63 (declare-function gnutls-negotiate "gnutls"
  64                   (proc type &optional priority-string trustfiles keyfiles))
  65
  66 ;;;###autoload
  67 (defun open-protocol-stream (name buffer host service &rest parameters)
  68   "Open a network stream to HOST, upgrading to STARTTLS if possible.
  69 The first four parameters have the same meaning as in
  70 `open-network-stream'.  The function returns a list where the
  71 first element is the stream, the second element is the greeting
  72 the server replied with after connecting, and the third element
  73 is a string representing the capabilities of the server (if any).
  74
  75 The PARAMETERS is a keyword list that can have the following
  76 values:
  77
  78 :type -- either `network', `network-only, `tls', `shell' or
  79 `starttls'.  If omitted, the default is `network'.  `network'
  80 will be opportunistically upgraded to STARTTLS if both the server
  81 and Emacs supports it.  If you don't want STARTTLS upgrades, use
  82 `network-only'.
  83
  84 :end-of-command -- a regexp saying what the end of a command is.
  85 This defaults to \"\\n\".
  86
  87 :success -- a regexp saying whether the STARTTLS command was
  88 successful or not.  For instance, for NNTP this is \"^3\".
  89
  90 :capability-command -- a string representing the command used to
  91 query server for capabilities.  For instance, for IMAP this is
  92 \"1 CAPABILITY\\r\\n\".
  93
  94 :starttls-function -- a function that takes one parameter, which
  95 is the response to the capaibility command.  It should return nil
  96 if it turns out that the server doesn't support STARTTLS, or the
  97 command to switch on STARTTLS otherwise."
  98   (let ((type (or (cadr (memq :type parameters)) 'network)))
  99     (cond
 100      ((eq type 'starttls)
 101       (setq type 'network))
 102      ((eq type 'ssl)
 103       (setq type 'tls)))
 104     (let ((open-result
 105            (funcall (intern (format "proto-stream-open-%s" type) obarray)
 106                     name buffer host service parameters)))
 107       (if (null open-result)
 108           (list nil nil nil type)
 109         (let ((stream (car open-result)))
 110           (list (and stream
 111                      (memq (process-status stream)
 112                            '(open run))
 113                      stream)
 114                 (nth 1 open-result)
 115                 (nth 2 open-result)
 116                 (nth 3 open-result)))))))
 117
 118 (defun proto-stream-open-network-only (name buffer host service parameters)
 119   (let ((start (with-current-buffer buffer (point)))
 120         (stream (open-network-stream name buffer host service)))
 121     (list stream
 122           (proto-stream-get-response
 123            stream start (proto-stream-eoc parameters))
 124           nil
 125           'network)))
 126
 127 (defun proto-stream-open-network (name buffer host service parameters)
 128   (let* ((start (with-current-buffer buffer (point)))
 129          (stream (open-network-stream name buffer host service))
 130          (capability-command (cadr (memq :capability-command parameters)))
 131          (eoc (proto-stream-eoc parameters))
 132          (type (cadr (memq :type parameters)))
 133          (greeting (proto-stream-get-response stream start eoc))
 134          success)
 135     (if (not capability-command)
 136         (list stream greeting nil 'network)
 137       (let* ((capabilities
 138               (proto-stream-command stream capability-command eoc))
 139              (starttls-command
 140               (funcall (cadr (memq :starttls-function parameters))
 141                        capabilities)))
 142         (cond
 143           ;; If this server doesn't support STARTTLS, but we have
 144           ;; requested it explicitly, then close the connection and
 145           ;; return nil.
 146          ((or (not starttls-command)
 147               (and (not (eq type 'starttls))
 148                    (not proto-stream-always-use-starttls)))
 149           (if (eq type 'starttls)
 150               (progn
 151                 (delete-process stream)
 152                 nil)
 153             ;; Otherwise, just return this plain network connection.
 154             (list stream greeting capabilities 'network)))
 155          ;; We have some kind of STARTTLS support, so we try to
 156          ;; upgrade the connection opportunistically.
 157          ((or (fboundp 'open-gnutls-stream)
 158               (executable-find "gnutls-cli"))
 159           (unless (fboundp 'open-gnutls-stream)
 160             (delete-process stream)
 161             (setq start (with-current-buffer buffer (point-max)))
 162             (let* ((starttls-use-gnutls t)
 163                    (starttls-extra-arguments
 164                     (if (not (eq type 'starttls))
 165                         ;; When doing opportunistic TLS upgrades we
 166                         ;; don't really care about the identity of the
 167                         ;; peer.
 168                         (cons "--insecure" starttls-extra-arguments)
 169                       starttls-extra-arguments)))
 170               (setq stream (starttls-open-stream name buffer host service)))
 171             (proto-stream-get-response stream start eoc))
 172           (if (not
 173                (string-match
 174                 (cadr (memq :success parameters))
 175                 (proto-stream-command stream starttls-command eoc)))
 176               ;; We got an error back from the STARTTLS command.
 177               (progn
 178                 (if (eq type 'starttls)
 179                     (progn
 180                       (delete-process stream)
 181                       nil)
 182                   (list stream greeting capabilities 'network)))
 183             ;; The server said it was OK to start doing STARTTLS negotiations.
 184             (if (fboundp 'open-gnutls-stream)
 185                 (gnutls-negotiate stream nil)
 186               (unless (starttls-negotiate stream)
 187                 (delete-process stream)
 188                 (setq stream nil)))
 189             (when (or (null stream)
 190                       (not (memq (process-status stream)
 191                                  '(open run))))
 192               ;; It didn't successfully negotiate STARTTLS, so we reopen
 193               ;; the connection.
 194               (setq stream (open-network-stream name buffer host service))
 195               (proto-stream-get-response stream start eoc))
 196             ;; Re-get the capabilities, since they may have changed
 197             ;; after switching to TLS.
 198             (list stream greeting
 199                   (proto-stream-command stream capability-command eoc) 'tls)))
 200          ;; We don't have STARTTLS support available, but the caller
 201          ;; requested a STARTTLS connection, so we give up.
 202          ((eq (cadr (memq :type parameters)) 'starttls)
 203           (delete-process stream)
 204           nil)
 205          ;; Fall back on using a plain network stream.
 206          (t
 207           (list stream greeting capabilities 'network)))))))
 208
 209 (defun proto-stream-command (stream command eoc)
 210   (let ((start (with-current-buffer (process-buffer stream) (point-max))))
 211     (process-send-string stream command)
 212     (proto-stream-get-response stream start eoc)))
 213
 214 (defun proto-stream-get-response (stream start end-of-command)
 215   (with-current-buffer (process-buffer stream)
 216     (save-excursion
 217       (goto-char start)
 218       (while (and (memq (process-status stream)
 219                         '(open run))
 220                   (not (re-search-forward end-of-command nil t)))
 221         (accept-process-output stream 0 50)
 222         (goto-char start))
 223       (if (= start (point))
 224           ;; The process died; return nil.
 225           nil
 226         ;; Return the data we got back.
 227         (buffer-substring start (point))))))
 228
 229 (defun proto-stream-open-tls (name buffer host service parameters)
 230   (with-current-buffer buffer
 231     (let ((start (point-max))
 232           (stream
 233            (funcall (if (fboundp 'open-gnutls-stream)
 234                         'open-gnutls-stream
 235                       'open-tls-stream)
 236                     name buffer host service)))
 237       (if (null stream)
 238           nil
 239         ;; If we're using tls.el, we have to delete the output from
 240         ;; openssl/gnutls-cli.
 241         (unless (fboundp 'open-gnutls-stream)
 242           (proto-stream-get-response
 243            stream start (proto-stream-eoc parameters))
 244           (goto-char (point-min))
 245           (when (re-search-forward (proto-stream-eoc parameters) nil t)
 246             (goto-char (match-beginning 0))
 247             (delete-region (point-min) (line-beginning-position))))
 248         (proto-stream-capability-open start stream parameters 'tls)))))
 249
 250 (defun proto-stream-open-shell (name buffer host service parameters)
 251   (proto-stream-capability-open
 252    (with-current-buffer buffer (point))
 253    (let ((process-connection-type nil))
 254      (start-process name buffer shell-file-name
 255                     shell-command-switch
 256                     (format-spec
 257                      (cadr (memq :shell-command parameters))
 258                      (format-spec-make
 259                       ?s host
 260                       ?p service))))
 261    parameters 'network))
 262
 263 (defun proto-stream-capability-open (start stream parameters stream-type)
 264   (let ((capability-command (cadr (memq :capability-command parameters)))
 265         (greeting (proto-stream-get-response
 266                    stream start (proto-stream-eoc parameters))))
 267     (list stream greeting
 268           (and capability-command
 269                (proto-stream-command
 270                 stream capability-command (proto-stream-eoc parameters)))
 271           stream-type)))
 272
 273 (defun proto-stream-eoc (parameters)
 274   (or (cadr (memq :end-of-command parameters))
 275       "\r\n"))
 276
 277 (provide 'proto-stream)
 278
 279 ;;; proto-stream.el ends here