cgit.sxemacs.org Git - gnus/blob - lisp/proto-stream.el

   1 ;;; proto-stream.el --- negotiating TLS, STARTTLS and other connections
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library is meant to provide the glue between modules that want
  26 ;; to establish a network connection to a server for protocols such as
  27 ;; IMAP, NNTP, SMTP and POP3.
  28
  29 ;; The main problem is that there's more than a couple of interfaces
  30 ;; towards doing this.  You have normal, plain connections, which are
  31 ;; no trouble at all, but you also have TLS/SSL connections, and you
  32 ;; have STARTTLS.  Negotiating this for each protocol can be rather
  33 ;; tedious, so this library provides a single entry point, and hides
  34 ;; much of the ugliness.
  35
  36 ;; Usage example:
  37
  38 ;; (open-protocol-stream
  39 ;;  "*nnimap*" buffer address port
  40 ;;  :type 'network
  41 ;;  :capability-command "1 CAPABILITY\r\n"
  42 ;;  :success " OK "
  43 ;;  :starttls-function
  44 ;;  (lambda (capabilities)
  45 ;;    (if (not (string-match "STARTTLS" capabilities))
  46 ;;        nil
  47 ;;      "1 STARTTLS\r\n")))
  48
  49 ;;; Code:
  50
  51 (eval-when-compile
  52   (require 'cl))
  53 (require 'tls)
  54 (require 'starttls)
  55 (require 'format-spec)
  56
  57 (defcustom proto-stream-always-use-starttls (fboundp 'open-gnutls-stream)
  58   "If non-nil, always try to upgrade network connections with STARTTLS."
  59   :version "24.1"
  60   :type 'boolean
  61   :group 'comm)
  62
  63 (declare-function gnutls-negotiate "gnutls"
  64                   (proc type &optional priority-string trustfiles keyfiles))
  65
  66 ;;;###autoload
  67 (defun open-protocol-stream (name buffer host service &rest parameters)
  68   "Open a network stream to HOST, upgrading to STARTTLS if possible.
  69 The first four parameters have the same meaning as in
  70 `open-network-stream'.  The function returns a list where the
  71 first element is the stream, the second element is the greeting
  72 the server replied with after connecting, and the third element
  73 is a string representing the capabilities of the server (if any).
  74
  75 The PARAMETERS is a keyword list that can have the following
  76 values:
  77
  78 :type -- either `network', `network-only, `tls', `shell' or
  79 `starttls'.  If omitted, the default is `network'.  `network'
  80 will be opportunistically upgraded to STARTTLS if both the server
  81 and Emacs supports it.  If you don't want STARTTLS upgrades, use
  82 `network-only'.
  83
  84 :end-of-command -- a regexp saying what the end of a command is.
  85 This defaults to \"\\n\".
  86
  87 :success -- a regexp saying whether the STARTTLS command was
  88 successful or not.  For instance, for NNTP this is \"^3\".
  89
  90 :capability-command -- a string representing the command used to
  91 query server for capabilities.  For instance, for IMAP this is
  92 \"1 CAPABILITY\\r\\n\".
  93
  94 :starttls-function -- a function that takes one parameter, which
  95 is the response to the capaibility command.  It should return nil
  96 if it turns out that the server doesn't support STARTTLS, or the
  97 command to switch on STARTTLS otherwise."
  98   (let ((type (or (cadr (memq :type parameters)) 'network)))
  99     (cond
 100      ((eq type 'starttls)
 101       (setq type 'network))
 102      ((eq type 'ssl)
 103       (setq type 'tls)))
 104     (destructuring-bind (stream greeting capabilities)
 105         (funcall (intern (format "proto-stream-open-%s" type) obarray)
 106                  name buffer host service parameters)
 107       (list (and stream
 108                  (memq (process-status stream)
 109                        '(open run))
 110                  stream)
 111             greeting capabilities))))
 112
 113 (defun proto-stream-open-network-only (name buffer host service parameters)
 114   (let ((start (with-current-buffer buffer (point)))
 115         (stream (open-network-stream name buffer host service)))
 116     (list stream
 117           (proto-stream-get-response
 118            stream start (proto-stream-eoc parameters))
 119           nil)))
 120
 121 (defun proto-stream-open-network (name buffer host service parameters)
 122   (let* ((start (with-current-buffer buffer (point)))
 123          (stream (open-network-stream name buffer host service))
 124          (capability-command (cadr (memq :capability-command parameters)))
 125          (eoc (proto-stream-eoc parameters))
 126          (type (cadr (memq :type parameters)))
 127          (greeting (proto-stream-get-response stream start eoc))
 128          success)
 129     (if (not capability-command)
 130         (list stream greeting nil)
 131       (let* ((capabilities
 132               (proto-stream-command stream capability-command eoc))
 133              (starttls-command
 134               (funcall (cadr (memq :starttls-function parameters))
 135                        capabilities)))
 136         (cond
 137           ;; If this server doesn't support STARTTLS, but we have
 138           ;; requested it explicitly, then close the connection and
 139           ;; return nil.
 140          ((or (not starttls-command)
 141               (and (not (eq type 'starttls))
 142                    (not proto-stream-always-use-starttls)))
 143           (if (eq type 'starttls)
 144               (progn
 145                 (delete-process stream)
 146                 nil)
 147             ;; Otherwise, just return this plain network connection.
 148             (list stream greeting capabilities)))
 149          ;; We have some kind of STARTTLS support, so we try to
 150          ;; upgrade the connection opportunistically.
 151          ((or (fboundp 'open-gnutls-stream)
 152               (executable-find "gnutls-cli"))
 153           (unless (fboundp 'open-gnutls-stream)
 154             (delete-process stream)
 155             (setq start (with-current-buffer buffer (point-max)))
 156             (let* ((starttls-use-gnutls t)
 157                    (starttls-extra-arguments
 158                     (if (not (eq type 'starttls))
 159                         ;; When doing opportunistic TLS upgrades we
 160                         ;; don't really care about the identity of the
 161                         ;; peer.
 162                         (cons "--insecure" starttls-extra-arguments)
 163                       starttls-extra-arguments)))
 164               (setq stream (starttls-open-stream name buffer host service)))
 165             (proto-stream-get-response stream start eoc))
 166           (if (not
 167                (string-match
 168                 (cadr (memq :success parameters))
 169                 (proto-stream-command stream starttls-command eoc)))
 170               ;; We got an error back from the STARTTLS command.
 171               (progn
 172                 (if (eq type 'starttls)
 173                     (progn
 174                       (delete-process stream)
 175                       nil)
 176                   (list stream greeting capabilities)))
 177             ;; The server said it was OK to start doing STARTTLS negotiations.
 178             (if (fboundp 'open-gnutls-stream)
 179                 (gnutls-negotiate stream nil)
 180               (unless (starttls-negotiate stream)
 181                 (delete-process stream)
 182                 (setq stream nil)))
 183             (when (or (null stream)
 184                       (not (memq (process-status stream)
 185                                  '(open run))))
 186               ;; It didn't successfully negotiate STARTTLS, so we reopen
 187               ;; the connection.
 188               (setq stream (open-network-stream name buffer host service))
 189               (proto-stream-get-response stream start eoc))
 190             ;; Re-get the capabilities, since they may have changed
 191             ;; after switching to TLS.
 192             (list stream greeting
 193                   (proto-stream-command stream capability-command eoc))))
 194          ;; We don't have STARTTLS support available, but the caller
 195          ;; requested a STARTTLS connection, so we give up.
 196          ((eq (cadr (memq :type parameters)) 'starttls)
 197           (delete-process stream)
 198           nil)
 199          ;; Fall back on using a plain network stream.
 200          (t
 201           (list stream greeting capabilities)))))))
 202
 203 (defun proto-stream-command (stream command eoc)
 204   (let ((start (with-current-buffer (process-buffer stream) (point-max))))
 205     (process-send-string stream command)
 206     (proto-stream-get-response stream start eoc)))
 207
 208 (defun proto-stream-get-response (stream start end-of-command)
 209   (with-current-buffer (process-buffer stream)
 210     (save-excursion
 211       (goto-char start)
 212       (while (and (memq (process-status stream)
 213                         '(open run))
 214                   (not (re-search-forward end-of-command nil t)))
 215         (accept-process-output stream 0 50)
 216         (goto-char start))
 217       (if (= start (point))
 218           ;; The process died; return nil.
 219           nil
 220         ;; Return the data we got back.
 221         (buffer-substring start (point))))))
 222
 223 (defun proto-stream-open-tls (name buffer host service parameters)
 224   (with-current-buffer buffer
 225     (let ((start (point-max))
 226           (stream
 227            (funcall (if (fboundp 'open-gnutls-stream)
 228                         'open-gnutls-stream
 229                       'open-tls-stream)
 230                     name buffer host service)))
 231       (if (null stream)
 232           nil
 233         ;; If we're using tls.el, we have to delete the output from
 234         ;; openssl/gnutls-cli.
 235         (unless (fboundp 'open-gnutls-stream)
 236           (proto-stream-get-response
 237            stream start (proto-stream-eoc parameters))
 238           (goto-char (point-min))
 239           (when (re-search-forward (proto-stream-eoc parameters) nil t)
 240             (goto-char (match-beginning 0))
 241             (delete-region (point-min) (line-beginning-position))))
 242         (proto-stream-capability-open start stream parameters)))))
 243
 244 (defun proto-stream-open-shell (name buffer host service parameters)
 245   (proto-stream-capability-open
 246    (with-current-buffer buffer (point))
 247    (let ((process-connection-type nil))
 248      (start-process name buffer shell-file-name
 249                     shell-command-switch
 250                     (format-spec
 251                      (cadr (memq :shell-command parameters))
 252                      (format-spec-make
 253                       ?s host
 254                       ?p service))))
 255    parameters))
 256
 257 (defun proto-stream-capability-open (start stream parameters)
 258   (let ((capability-command (cadr (memq :capability-command parameters)))
 259         (greeting (proto-stream-get-response
 260                    stream start (proto-stream-eoc parameters))))
 261     (list stream greeting
 262           (and capability-command
 263                (proto-stream-command
 264                 stream capability-command (proto-stream-eoc parameters))))))
 265
 266 (defun proto-stream-eoc (parameters)
 267   (or (cadr (memq :end-of-command parameters))
 268       "\r\n"))
 269
 270 (provide 'proto-stream)
 271
 272 ;;; proto-stream.el ends here