cgit.sxemacs.org Git - gnus/blob - lisp/proto-stream.el

   1 ;;; proto-stream.el --- negotiating TLS, STARTTLS and other connections
   2 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 3, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This library is meant to provide the glue between modules that want
  27 ;; to establish a network connection to a server for protocols such as
  28 ;; IMAP, NNTP, SMTP and POP3.
  29
  30 ;; The main problem is that there's more than a couple of interfaces
  31 ;; towards doing this.  You have normal, plain connections, which are
  32 ;; no trouble at all, but you also have TLS/SSL connections, and you
  33 ;; have STARTTLS.  Negotiating this for each protocol can be rather
  34 ;; tedious, so this library provides a single entry point, and hides
  35 ;; much of the ugliness.
  36
  37 ;; Usage example:
  38
  39 ;; (open-protocol-stream
  40 ;;  "*nnimap*" buffer address port
  41 ;;  :type 'network
  42 ;;  :capability-command "1 CAPABILITY\r\n"
  43 ;;  :starttls-function
  44 ;;  (lambda (capabilities)
  45 ;;    (if (not (string-match "STARTTLS" capabilities))
  46 ;;        nil
  47 ;;      "1 STARTTLS\r\n")))
  48
  49 ;;; Code:
  50
  51 (eval-when-compile
  52   (require 'cl))
  53 (require 'tls)
  54 (require 'starttls)
  55 (require 'format-spec)
  56
  57 (defcustom proto-stream-always-use-starttls (fboundp 'open-gnutls-stream)
  58   "If non-nil, always try to upgrade network connections with STARTTLS."
  59   :version "24.1"
  60   :type 'boolean
  61   :group 'comm)
  62
  63 (declare-function gnutls-negotiate "gnutls"
  64                   (proc type &optional priority-string trustfiles keyfiles))
  65
  66 ;;;###autoload
  67 (defun open-protocol-stream (name buffer host service &rest parameters)
  68   "Open a network stream to HOST.
  69 The first four parameters have the same meaning as in
  70 `open-network-stream'.  The function returns a list where the
  71 first element is the stream, the second element is the greeting
  72 the server replied with after connecting, and the third element
  73 is a string representing the capabilities of the server (if any).
  74
  75 The PARAMETERS is a keyword list that can have the following
  76 values:
  77
  78 :type -- either `network', `tls', `shell' or `starttls'.  If
  79 omitted, the default is `network'.
  80
  81 :end-of-command -- a regexp saying what the end of a command is.
  82 This defaults to \"\\n\".
  83
  84 :capability-command -- a string representing the command used to
  85 query server for capabilities.  For instance, for IMAP this is
  86 \"1 CAPABILITY\\r\\n\".
  87
  88 :starttls-function -- a function that takes one parameter, which
  89 is the response to the capaibility command.  It should return nil
  90 if it turns out that the server doesn't support STARTTLS, or the
  91 command to switch on STARTTLS otherwise."
  92   (let ((type (or (cadr (memq :type parameters)) 'network)))
  93     (when (and (eq type 'starttls)
  94                (fboundp 'open-gnutls-stream))
  95       (setq type 'network))
  96     (when (eq type 'ssl)
  97       (setq type 'tls))
  98     (destructuring-bind (stream greeting capabilities)
  99         (funcall (intern (format "proto-stream-open-%s" type) obarray)
 100                  name buffer host service parameters)
 101       (list (and stream
 102                  (memq (process-status stream)
 103                        '(open run))
 104                  stream)
 105             greeting capabilities))))
 106
 107 (defun proto-stream-open-network (name buffer host service parameters)
 108   (let* ((start (with-current-buffer buffer (point)))
 109          (stream (open-network-stream name buffer host service))
 110          (capability-command (cadr (memq :capability-command parameters)))
 111          (eoc (proto-stream-eoc parameters))
 112          (type (cadr (memq :type parameters)))
 113          (greeting (proto-stream-get-response stream start eoc)))
 114     (if (not capability-command)
 115         (list stream greeting nil)
 116       (let* ((capabilities
 117               (proto-stream-command stream capability-command eoc))
 118              (starttls-command
 119               (funcall (cadr (memq :starttls-function parameters))
 120                        capabilities)))
 121         (cond
 122          ((or (not starttls-command)
 123               (and (not (eq type 'starttls))
 124                    (not proto-stream-always-use-starttls)))
 125           ;; If this server doesn't support STARTTLS, but we have
 126           ;; requested it explicitly, then close the connection and
 127           ;; return nil.
 128           (if (eq type 'starttls)
 129               (progn
 130                 (delete-process stream)
 131                 nil)
 132             ;; Otherwise, just return this plain network connection.
 133             (list stream greeting capabilities)))
 134          ((or (fboundp 'open-gnutls-stream)
 135               (executable-find "gnutls-cli"))
 136           (unless (fboundp 'open-gnutls-stream)
 137             (delete-process stream)
 138             (let* ((starttls-use-gnutls t)
 139                    (starttls-extra-arguments
 140                     (if (eq type 'starttls)
 141                         ;; When doing opportunistic TLS upgrades we
 142                         ;; don't really care about the identity of the
 143                         ;; peer.
 144                         (cons "--insecure" starttls-extra-arguments)
 145                       starttls-extra-arguments)))
 146               (setq stream (starttls-open-stream name buffer host service)))
 147             (proto-stream-get-response stream start eoc))
 148           (proto-stream-command stream starttls-command eoc)
 149           (if (fboundp 'open-gnutls-stream)
 150               (gnutls-negotiate stream nil)
 151             (starttls-negotiate stream))
 152           ;; Re-get the capabilities, since they may have changed
 153           ;; after switching to TLS.
 154           (list stream greeting
 155                 (proto-stream-command stream capability-command eoc)))
 156          ((eq (cadr (memq :type parameters)) 'starttls)
 157           (delete-process stream)
 158           nil)
 159          (t
 160           (list stream greeting capabilities)))))))
 161
 162 (defun proto-stream-command (stream command eoc)
 163   (let ((start (with-current-buffer (process-buffer stream) (point-max))))
 164     (process-send-string stream command)
 165     (proto-stream-get-response stream start eoc)))
 166
 167 (defun proto-stream-get-response (stream start end-of-command)
 168   (with-current-buffer (process-buffer stream)
 169     (save-excursion
 170       (goto-char start)
 171       (while (and (memq (process-status stream)
 172                         '(open run))
 173                   (not (re-search-forward end-of-command nil t)))
 174         (accept-process-output stream 0 50)
 175         (goto-char start))
 176       (if (= start (point))
 177           ;; The process died; return nil.
 178           nil
 179         ;; Return the data we got back.
 180         (buffer-substring start (point))))))
 181
 182 (defun proto-stream-open-tls (name buffer host service parameters)
 183   (with-current-buffer buffer
 184     (let ((start (point-max))
 185           (stream
 186            (funcall (if (fboundp 'open-gnutls-stream)
 187                         'open-gnutls-stream
 188                       'open-tls-stream)
 189                     name buffer host service)))
 190       ;; If we're using tls.el, we have to delete the output from
 191       ;; openssl/gnutls-cli.
 192       (unless (fboundp 'open-gnutls-stream)
 193         (proto-stream-get-response
 194          stream start (proto-stream-eoc parameters))
 195         (goto-char (point-min))
 196         (when (re-search-forward (proto-stream-eoc parameters) nil t)
 197           (goto-char (match-beginning 0))
 198           (delete-region (point-min) (line-beginning-position))))
 199       (proto-stream-capability-open start stream parameters))))
 200
 201 (defun proto-stream-open-shell (name buffer host service parameters)
 202   (proto-stream-capability-open
 203    (with-current-buffer buffer (point))
 204    (let ((process-connection-type nil))
 205      (start-process name buffer shell-file-name
 206                     shell-command-switch
 207                     (format-spec
 208                      (cadr (memq :shell-command parameters))
 209                      (format-spec-make
 210                       ?s host
 211                       ?p service))))
 212    parameters))
 213
 214 (defun proto-stream-capability-open (start stream parameters)
 215   (let ((capability-command (cadr (memq :capability-command parameters)))
 216         (greeting (proto-stream-get-response
 217                    stream start (proto-stream-eoc parameters))))
 218     (list stream greeting
 219           (and capability-command
 220                (proto-stream-command
 221                 stream capability-command (proto-stream-eoc parameters))))))
 222
 223 (defun proto-stream-eoc (parameters)
 224   (or (cadr (memq :end-of-command parameters))
 225       "\r\n"))
 226
 227 (provide 'proto-stream)
 228
 229 ;;; proto-stream.el ends here