cgit.sxemacs.org Git - gnus/blob - lisp/pgg-gpg.el

   1 ;;; pgg-gpg.el --- GnuPG support for PGG.
   2
   3 ;; Copyright (C) 1999, 2000, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Daiki Ueno <ueno@unixuser.org>
   6 ;; Created: 1999/10/28
   7 ;; Keywords: PGP, OpenPGP, GnuPG
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl)                         ; for gpg macros
  30   (require 'pgg))
  31
  32 (defgroup pgg-gpg ()
  33   "GnuPG interface"
  34   :group 'pgg)
  35
  36 (defcustom pgg-gpg-program "gpg"
  37   "The GnuPG executable."
  38   :group 'pgg-gpg
  39   :type 'string)
  40
  41 (defcustom pgg-gpg-extra-args nil
  42   "Extra arguments for every GnuPG invocation."
  43   :group 'pgg-gpg
  44   :type '(repeat (string :tag "Argument")))
  45
  46 (defvar pgg-gpg-user-id nil
  47   "GnuPG ID of your default identity.")
  48
  49 (defun pgg-gpg-process-region (start end passphrase program args)
  50   (let* ((output-file-name (pgg-make-temp-file "pgg-output"))
  51          (args
  52           `("--status-fd" "2"
  53             ,@(if passphrase '("--passphrase-fd" "0"))
  54             "--yes" ; overwrite
  55             "--output" ,output-file-name
  56             ,@pgg-gpg-extra-args ,@args))
  57          (output-buffer pgg-output-buffer)
  58          (errors-buffer pgg-errors-buffer)
  59          (orig-mode (default-file-modes))
  60          (process-connection-type nil)
  61          exit-status)
  62     (with-current-buffer (get-buffer-create errors-buffer)
  63       (buffer-disable-undo)
  64       (erase-buffer))
  65     (unwind-protect
  66         (progn
  67           (set-default-file-modes 448)
  68           (let ((coding-system-for-write 'binary)
  69                 (input (buffer-substring-no-properties start end))
  70                 (default-enable-multibyte-characters nil))
  71             (with-temp-buffer
  72               (when passphrase
  73                 (insert passphrase "\n"))
  74               (insert input)
  75               (setq exit-status
  76                     (apply #'call-process-region (point-min) (point-max) program
  77                            nil errors-buffer nil args))))
  78           (with-current-buffer (get-buffer-create output-buffer)
  79             (buffer-disable-undo)
  80             (erase-buffer)
  81             (if (file-exists-p output-file-name)
  82                 (let ((coding-system-for-read 'raw-text-dos))
  83                   (insert-file-contents output-file-name)))
  84             (set-buffer errors-buffer)
  85             (if (not (equal exit-status 0))
  86                 (insert (format "\n%s exited abnormally: '%s'\n"
  87                                 program exit-status)))))
  88       (if (file-exists-p output-file-name)
  89           (delete-file output-file-name))
  90       (set-default-file-modes orig-mode))))
  91
  92 (defun pgg-gpg-possibly-cache-passphrase (passphrase &optional key)
  93   (if (and pgg-cache-passphrase
  94            (progn
  95              (goto-char (point-min))
  96              (re-search-forward "^\\[GNUPG:] GOOD_PASSPHRASE\\>" nil t)))
  97       (pgg-add-passphrase-cache
  98        (or key
  99            (progn
 100              (goto-char (point-min))
 101              (if (re-search-forward
 102                   "^\\[GNUPG:] NEED_PASSPHRASE \\w+ ?\\w*" nil t)
 103                  (substring (match-string 0) -8))))
 104        passphrase)))
 105
 106 (defun pgg-gpg-lookup-key (string &optional type)
 107   "Search keys associated with STRING."
 108   (let ((args (list "--with-colons" "--no-greeting" "--batch"
 109                     (if type "--list-secret-keys" "--list-keys")
 110                     string)))
 111     (with-temp-buffer
 112       (apply #'call-process pgg-gpg-program nil t nil args)
 113       (goto-char (point-min))
 114       (if (re-search-forward "^\\(sec\\|pub\\):"  nil t)
 115           (substring
 116            (nth 3 (split-string
 117                    (buffer-substring (match-end 0)
 118                                      (progn (end-of-line)(point)))
 119                    ":")) 8)))))
 120
 121 (defun pgg-gpg-encrypt-region (start end recipients &optional sign)
 122   "Encrypt the current region between START and END.
 123 If optional argument SIGN is non-nil, do a combined sign and encrypt."
 124   (let* ((pgg-gpg-user-id (or pgg-gpg-user-id pgg-default-user-id))
 125          (passphrase
 126           (when sign
 127             (pgg-read-passphrase
 128              (format "GnuPG passphrase for %s: " pgg-gpg-user-id)
 129              pgg-gpg-user-id)))
 130          (args
 131           (append
 132            (list "--batch" "--armor" "--always-trust" "--encrypt")
 133            (if sign (list "--sign" "--local-user" pgg-gpg-user-id))
 134            (if recipients
 135                (apply #'nconc
 136                       (mapcar (lambda (rcpt)
 137                                 (list "--remote-user" rcpt))
 138                               (append recipients
 139                                       (if pgg-encrypt-for-me
 140                                           (list pgg-gpg-user-id)))))))))
 141     (pgg-as-lbt start end 'CRLF
 142       (pgg-gpg-process-region start end passphrase pgg-gpg-program args))
 143     (when sign
 144       (with-current-buffer pgg-errors-buffer
 145         (pgg-gpg-possibly-cache-passphrase passphrase pgg-gpg-user-id)))
 146     (pgg-process-when-success)))
 147
 148 (defun pgg-gpg-decrypt-region (start end)
 149   "Decrypt the current region between START and END."
 150   (let* ((pgg-gpg-user-id (or pgg-gpg-user-id pgg-default-user-id))
 151          (passphrase
 152           (pgg-read-passphrase
 153            (format "GnuPG passphrase for %s: " pgg-gpg-user-id)
 154            pgg-gpg-user-id))
 155          (args '("--batch" "--decrypt")))
 156     (pgg-gpg-process-region start end passphrase pgg-gpg-program args)
 157     (with-current-buffer pgg-errors-buffer
 158       (pgg-gpg-possibly-cache-passphrase passphrase pgg-gpg-user-id)
 159       (goto-char (point-min))
 160       (re-search-forward "^\\[GNUPG:] DECRYPTION_OKAY\\>" nil t))))
 161
 162 (defun pgg-gpg-sign-region (start end &optional cleartext)
 163   "Make detached signature from text between START and END."
 164   (let* ((pgg-gpg-user-id (or pgg-gpg-user-id pgg-default-user-id))
 165          (passphrase
 166           (pgg-read-passphrase
 167            (format "GnuPG passphrase for %s: " pgg-gpg-user-id)
 168            pgg-gpg-user-id))
 169          (args
 170           (list (if cleartext "--clearsign" "--detach-sign")
 171                 "--armor" "--batch" "--verbose"
 172                 "--local-user" pgg-gpg-user-id))
 173          (inhibit-read-only t)
 174          buffer-read-only)
 175     (pgg-as-lbt start end 'CRLF
 176       (pgg-gpg-process-region start end passphrase pgg-gpg-program args))
 177     (with-current-buffer pgg-errors-buffer
 178       (pgg-gpg-possibly-cache-passphrase passphrase pgg-gpg-user-id))
 179     (pgg-process-when-success)))
 180
 181 (defun pgg-gpg-verify-region (start end &optional signature)
 182   "Verify region between START and END as the detached signature SIGNATURE."
 183   (let ((args '("--batch" "--verify")))
 184     (when (stringp signature)
 185       (setq args (append args (list signature))))
 186     (setq args (append args '("-")))
 187     (pgg-gpg-process-region start end nil pgg-gpg-program args)
 188     (with-current-buffer pgg-errors-buffer
 189       (goto-char (point-min))
 190       (while (re-search-forward "^gpg: \\(.*\\)\n" nil t)
 191         (with-current-buffer pgg-output-buffer
 192           (insert-buffer-substring pgg-errors-buffer
 193                                    (match-beginning 1) (match-end 0)))
 194         (delete-region (match-beginning 0) (match-end 0)))
 195       (goto-char (point-min))
 196       (re-search-forward "^\\[GNUPG:] GOODSIG\\>" nil t))))
 197
 198 (defun pgg-gpg-insert-key ()
 199   "Insert public key at point."
 200   (let* ((pgg-gpg-user-id (or pgg-gpg-user-id pgg-default-user-id))
 201          (args (list "--batch" "--export" "--armor"
 202                      pgg-gpg-user-id)))
 203     (pgg-gpg-process-region (point)(point) nil pgg-gpg-program args)
 204     (insert-buffer-substring pgg-output-buffer)))
 205
 206 (defun pgg-gpg-snarf-keys-region (start end)
 207   "Add all public keys in region between START and END to the keyring."
 208   (let ((args '("--import" "--batch" "-")) status)
 209     (pgg-gpg-process-region start end nil pgg-gpg-program args)
 210     (set-buffer pgg-errors-buffer)
 211     (goto-char (point-min))
 212     (when (re-search-forward "^\\[GNUPG:] IMPORT_RES\\>" nil t)
 213       (setq status (buffer-substring (match-end 0)
 214                                      (progn (end-of-line)(point)))
 215             status (vconcat (mapcar #'string-to-int (split-string status))))
 216       (erase-buffer)
 217       (insert (format "Imported %d key(s).
 218 \tArmor contains %d key(s) [%d bad, %d old].\n"
 219                       (+ (aref status 2)
 220                          (aref status 10))
 221                       (aref status 0)
 222                       (aref status 1)
 223                       (+ (aref status 4)
 224                          (aref status 11)))
 225               (if (zerop (aref status 9))
 226                   ""
 227                 "\tSecret keys are imported.\n")))
 228     (append-to-buffer pgg-output-buffer (point-min)(point-max))
 229     (pgg-process-when-success)))
 230
 231 (provide 'pgg-gpg)
 232
 233 ;;; pgg-gpg.el ends here