cgit.sxemacs.org Git - gnus/blob - lisp/nnvirtual.el

   1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
   2 ;; Copyright (C) 1994,95,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; The other access methods (nntp, nnspool, etc) are general news
  28 ;; access methods. This module relies on Gnus and can not be used
  29 ;; separately.
  30
  31 ;;; Code:
  32
  33 (require 'nntp)
  34 (require 'nnheader)
  35 (require 'gnus)
  36 (eval-when-compile (require 'cl))
  37
  38 (defvar nnvirtual-always-rescan nil
  39   "*If non-nil, always scan groups for unread articles when entering a group.
  40 If this variable is nil (which is the default) and you read articles
  41 in a component group after the virtual group has been activated, the
  42 read articles from the component group will show up when you enter the
  43 virtual group.")
  44
  45 \f
  46
  47 (defconst nnvirtual-version "nnvirtual 1.0"
  48   "Version number of this version of nnvirtual.")
  49
  50 (defvar nnvirtual-group-alist nil)
  51 (defvar nnvirtual-current-group nil)
  52 (defvar nnvirtual-component-groups nil)
  53 (defvar nnvirtual-mapping nil)
  54
  55 (defvar nnvirtual-status-string "")
  56
  57 (eval-and-compile
  58   (autoload 'gnus-cache-articles-in-group "gnus-cache"))
  59
  60 \f
  61
  62 ;;; Interface functions.
  63
  64 (defun nnvirtual-retrieve-headers (articles &optional newsgroup server fetch-old)
  65   (when (nnvirtual-possibly-change-group newsgroup server t)
  66     (save-excursion
  67       (if (stringp (car articles))
  68           'headers
  69         (let ((vbuf (nnheader-set-temp-buffer
  70                      (get-buffer-create " *virtual headers*")))
  71               (unfetched (mapcar (lambda (g) (list g))
  72                                  nnvirtual-component-groups))
  73               (system-name (system-name))
  74               cgroup article result prefix)
  75           (while articles
  76             (setq article (assq (pop articles) nnvirtual-mapping))
  77             (when (and (setq cgroup (cadr article))
  78                        (gnus-check-server
  79                         (gnus-find-method-for-group cgroup) t)
  80                        (gnus-request-group cgroup t))
  81               (setq prefix (gnus-group-real-prefix cgroup))
  82               (when (setq result (gnus-retrieve-headers
  83                                   (list (caddr article)) cgroup nil))
  84                 (set-buffer nntp-server-buffer)
  85                 (if (zerop (buffer-size))
  86                     (nconc (assq cgroup unfetched) (list (caddr article)))
  87                   ;; If we got HEAD headers, we convert them into NOV
  88                   ;; headers.  This is slow, inefficient and, come to think
  89                   ;; of it, downright evil.  So sue me.  I couldn't be
  90                   ;; bothered to write a header parse routine that could
  91                   ;; parse a mixed HEAD/NOV buffer.
  92                   (when (eq result 'headers)
  93                     (nnvirtual-convert-headers))
  94                   (goto-char (point-min))
  95                   (while (not (eobp))
  96                     (delete-region
  97                      (point) (progn (read nntp-server-buffer) (point)))
  98                     (princ (car article) (current-buffer))
  99                     (beginning-of-line)
 100                     (looking-at
 101                      "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
 102                     (goto-char (match-end 0))
 103                     (or (search-forward
 104                          "\t" (save-excursion (end-of-line) (point)) t)
 105                         (end-of-line))
 106                     (while (= (char-after (1- (point))) ? )
 107                       (forward-char -1)
 108                       (delete-char 1))
 109                     (if (eolp)
 110                         (progn
 111                           (end-of-line)
 112                           (or (= (char-after (1- (point))) ?\t)
 113                               (insert ?\t))
 114                           (insert "Xref: " system-name " " cgroup ":")
 115                           (princ (caddr article) (current-buffer))
 116                           (insert "\t"))
 117                       (insert "Xref: " system-name " " cgroup ":")
 118                       (princ (caddr article) (current-buffer))
 119                       (insert " ")
 120                       (if (not (string= "" prefix))
 121                           (while (re-search-forward
 122                                   "[^ ]+:[0-9]+"
 123                                   (save-excursion (end-of-line) (point)) t)
 124                             (save-excursion
 125                               (goto-char (match-beginning 0))
 126                               (insert prefix))))
 127                       (end-of-line)
 128                       (or (= (char-after (1- (point))) ?\t)
 129                           (insert ?\t)))
 130                     (forward-line 1))
 131                   (set-buffer vbuf)
 132                   (goto-char (point-max))
 133                   (insert-buffer-substring nntp-server-buffer)))))
 134
 135           ;; In case some of the articles have expired or been
 136           ;; cancelled, we have to mark them as read in the
 137           ;; component group.
 138           (while unfetched
 139             (when (cdar unfetched)
 140               (gnus-group-make-articles-read
 141                (caar unfetched) (sort (cdar unfetched) '<)))
 142             (setq unfetched (cdr unfetched)))
 143
 144           ;; The headers are ready for reading, so they are inserted into
 145           ;; the nntp-server-buffer, which is where Gnus expects to find
 146           ;; them.
 147           (prog1
 148               (save-excursion
 149                 (set-buffer nntp-server-buffer)
 150                 (erase-buffer)
 151                 (insert-buffer-substring vbuf)
 152                 'nov)
 153             (kill-buffer vbuf)))))))
 154
 155 (defun nnvirtual-open-server (server &optional something)
 156   (nnheader-init-server-buffer))
 157
 158 (defun nnvirtual-close-server (&rest dum)
 159   t)
 160
 161 (defun nnvirtual-request-close ()
 162   (setq nnvirtual-current-group nil
 163         nnvirtual-component-groups nil
 164         nnvirtual-mapping nil
 165         nnvirtual-group-alist nil)
 166   t)
 167
 168 (defun nnvirtual-server-opened (&optional server)
 169   (and nntp-server-buffer
 170        (get-buffer nntp-server-buffer)))
 171
 172 (defun nnvirtual-status-message (&optional server)
 173   nnvirtual-status-string)
 174
 175 (defun nnvirtual-request-article (article &optional group server buffer)
 176   (when (and (nnvirtual-possibly-change-group group server t)
 177              (numberp article))
 178     (let* ((amap (assq article nnvirtual-mapping))
 179            (cgroup (cadr amap)))
 180       (cond
 181        ((not amap)
 182         (nnheader-report 'nnvirtual "No such article: %s" article))
 183        ((not (gnus-check-group cgroup))
 184         (nnheader-report
 185          'nnvirtual "Can't open server where %s exists" cgroup))
 186        ((not (gnus-request-group cgroup t))
 187         (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
 188        (t
 189         (if buffer
 190             (save-excursion
 191               (set-buffer buffer)
 192               (gnus-request-article-this-buffer (caddr amap) cgroup))
 193           (gnus-request-article (caddr amap) cgroup)))))))
 194
 195 (defun nnvirtual-request-group (group &optional server dont-check)
 196   (cond
 197    ((null (nnvirtual-possibly-change-group
 198            group server
 199            (if nnvirtual-always-rescan nil (not dont-check))))
 200     (setq nnvirtual-current-group nil)
 201     (nnheader-report 'nnvirtual "No component groups in %s" group))
 202    (t
 203     (let ((len (length nnvirtual-mapping)))
 204       (nnheader-insert "211 %d 1 %d %s\n" len len group)))))
 205
 206 (defun nnvirtual-request-type (group &optional article)
 207   (when (nnvirtual-possibly-change-group group nil t)
 208     (if (not article)
 209         'unknown
 210       (let ((mart (assq article nnvirtual-mapping)))
 211         (when mart
 212           (gnus-request-type (cadr mart) (car mart)))))))
 213
 214 (defun nnvirtual-request-update-mark (group article mark)
 215   (when (nnvirtual-possibly-change-group group nil t)
 216     (let* ((nart (assq article nnvirtual-mapping))
 217            (cgroup (cadr nart))
 218            ;; The component group might be a virtual group.
 219            (nmark (gnus-request-update-mark cgroup (caddr nart) mark)))
 220       (when (and (= mark nmark)
 221                  (gnus-group-auto-expirable-p cgroup))
 222         (setq mark gnus-expirable-mark))))
 223   mark)
 224
 225 (defun nnvirtual-close-group (group &optional server)
 226   (when (nnvirtual-possibly-change-group group server t)
 227     ;; Copy (un)read articles.
 228     (nnvirtual-update-reads)
 229     ;; We copy the marks from this group to the component
 230     ;; groups here.
 231     (nnvirtual-update-marked)
 232     ;; Reset all relevant variables.
 233     (setq nnvirtual-current-group nil
 234           nnvirtual-component-groups nil
 235           nnvirtual-mapping nil)
 236     (setq nnvirtual-group-alist
 237           (delq (assoc group nnvirtual-group-alist) nnvirtual-group-alist)))
 238   t)
 239
 240 (defun nnvirtual-request-list (&optional server)
 241   (nnheader-report 'nnvirtual "LIST is not implemented."))
 242
 243 (defun nnvirtual-request-newgroups (date &optional server)
 244   (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
 245
 246 (defun nnvirtual-request-list-newsgroups (&optional server)
 247   (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
 248
 249 (defun nnvirtual-request-update-info (group info &optional server)
 250   (when (nnvirtual-possibly-change-group group server)
 251     (let ((map nnvirtual-mapping)
 252           (marks (mapcar (lambda (m) (list (cdr m))) gnus-article-mark-lists))
 253           reads mr m op)
 254       ;; Go through the mapping.
 255       (while map
 256         (unless (nth 3 (setq m (pop map)))
 257           ;; Read article.
 258           (push (car m) reads))
 259         ;; Copy marks.
 260         (when (setq mr (nth 4 m))
 261           (while mr
 262             (setcdr (setq op (assq (pop mr) marks)) (cons (car m) (cdr op))))))
 263       ;; Compress the marks and the reads.
 264       (setq mr marks)
 265       (while mr
 266         (setcdr (car mr) (gnus-compress-sequence (sort (cdr (pop mr)) '<))))
 267       (setcar (cddr info) (gnus-compress-sequence (nreverse reads)))
 268       ;; Remove empty marks lists.
 269       (while (and marks (not (cdar marks)))
 270         (setq marks (cdr marks)))
 271       (setq mr marks)
 272       (while (cdr mr)
 273         (if (cdadr mr)
 274             (setq mr (cdr mr))
 275           (setcdr mr (cddr mr))))
 276
 277       ;; Enter these new marks into the info of the group.
 278       (if (nthcdr 3 info)
 279           (setcar (nthcdr 3 info) marks)
 280         ;; Add the marks lists to the end of the info.
 281         (when marks
 282           (setcdr (nthcdr 2 info) (list marks))))
 283       t)))
 284
 285 (defun nnvirtual-catchup-group (group &optional server all)
 286   (nnvirtual-possibly-change-group group server t)
 287   (let ((gnus-group-marked nnvirtual-component-groups)
 288         (gnus-expert-user t))
 289     ;; Make sure all groups are activated.
 290     (mapcar
 291      (lambda (g)
 292        (when (not (numberp (car (gnus-gethash g gnus-newsrc-hashtb))))
 293          (gnus-activate-group g)))
 294      nnvirtual-component-groups)
 295     (save-excursion
 296       (set-buffer gnus-group-buffer)
 297       (gnus-group-catchup-current nil all))))
 298
 299 (defun nnvirtual-find-group-art (group article)
 300   "Return the real group and article for virtual GROUP and ARTICLE."
 301   (nnvirtual-possibly-change-group group nil t)
 302   (let ((mart (assq article nnvirtual-mapping)))
 303     (when mart
 304       (cons (cadr mart) (caddr mart)))))
 305
 306 \f
 307 ;;; Internal functions.
 308
 309 (defun nnvirtual-convert-headers ()
 310   "Convert HEAD headers into NOV headers."
 311   (save-excursion
 312     (set-buffer nntp-server-buffer)
 313     (let* ((dependencies (make-vector 100 0))
 314            (headers (gnus-get-newsgroup-headers dependencies))
 315            header)
 316       (erase-buffer)
 317       (while (setq header (pop headers))
 318         (insert (int-to-string (mail-header-number header)) "\t"
 319                 (or (mail-header-subject header) "") "\t"
 320                 (or (mail-header-from header) "") "\t"
 321                 (or (mail-header-date header) "") "\t"
 322                 (or (mail-header-id header) "") "\t"
 323                 (or (mail-header-references header) "") "\t"
 324                 (int-to-string (or (mail-header-chars header) 0)) "\t"
 325                 (int-to-string (or (mail-header-lines header) 0)) "\t"
 326                 (if (mail-header-xref header)
 327                     (concat "Xref: " (mail-header-xref header) "\t")
 328                   "") "\n")))))
 329
 330 (defun nnvirtual-possibly-change-group (group regexp &optional check)
 331   (let ((inf t))
 332     (when (or (not (equal group nnvirtual-current-group))
 333               check)
 334       (and (setq inf (assoc group nnvirtual-group-alist))
 335            regexp
 336            (string= (nth 3 inf) regexp)
 337            (progn
 338              (setq nnvirtual-current-group (car inf))
 339              (setq nnvirtual-component-groups (nth 1 inf))
 340              (setq nnvirtual-mapping (nth 2 inf))))
 341       (when (and regexp (not inf))
 342         (and inf (setq nnvirtual-group-alist
 343                        (delq inf nnvirtual-group-alist)))
 344         (setq nnvirtual-mapping nil)
 345         (setq nnvirtual-current-group group)
 346         (let ((newsrc gnus-newsrc-alist)
 347               (virt-group (gnus-group-prefixed-name
 348                            nnvirtual-current-group '(nnvirtual ""))))
 349           (setq nnvirtual-component-groups nil)
 350           (while newsrc
 351             (and (string-match regexp (caar newsrc))
 352                  (not (string= (caar newsrc) virt-group))
 353                  (setq nnvirtual-component-groups
 354                        (cons (caar newsrc)
 355                              (delete (caar newsrc)
 356                                      nnvirtual-component-groups))))
 357             (setq newsrc (cdr newsrc))))
 358         (if nnvirtual-component-groups
 359             (progn
 360               (nnvirtual-create-mapping)
 361               (setq nnvirtual-group-alist
 362                     (cons (list group nnvirtual-component-groups
 363                                 nnvirtual-mapping regexp)
 364                           nnvirtual-group-alist)))
 365           (nnheader-report 'nnvirtual "No component groups: %s" group)))))
 366   nnvirtual-component-groups)
 367
 368 (defun nnvirtual-update-marked ()
 369   "Copy marks from the virtual group to the component groups."
 370   (let ((mark-lists gnus-article-mark-lists)
 371         (marks (gnus-info-marks (gnus-get-info
 372                                  (concat "nnvirtual:"
 373                                          nnvirtual-current-group))))
 374         type list mart cgroups)
 375     (while (setq type (cdr (pop mark-lists)))
 376       (setq list (gnus-uncompress-range (cdr (assq type marks))))
 377       (setq cgroups
 378             (mapcar (lambda (g) (list g)) nnvirtual-component-groups))
 379       (while list
 380         (nconc (assoc (cadr (setq mart (assq (pop list) nnvirtual-mapping)))
 381                       cgroups)
 382                (list (caddr mart))))
 383       (while cgroups
 384         (gnus-add-marked-articles
 385          (caar cgroups) type (cdar cgroups) nil t)
 386         (gnus-group-update-group (car (pop cgroups)) t)))))
 387
 388 (defun nnvirtual-update-reads ()
 389   "Copy (un)reads from the current group to the component groups."
 390   (let ((groups (mapcar (lambda (g) (list g)) nnvirtual-component-groups))
 391         (articles (gnus-list-of-unread-articles
 392                    (concat "nnvirtual:" nnvirtual-current-group)))
 393         m)
 394     (while articles
 395       (setq m (assq (pop articles) nnvirtual-mapping))
 396       (nconc (assoc (nth 1 m) groups) (list (nth 2 m))))
 397     (while groups
 398       (gnus-update-read-articles (caar groups) (cdr (pop groups))))))
 399
 400 (defsubst nnvirtual-marks (article marks)
 401   "Return a list of mark types for ARTICLE."
 402   (let (out)
 403     (while marks
 404       (when (memq article (cdar marks))
 405         (push (caar marks) out))
 406       (setq marks (cdr marks)))
 407     out))
 408
 409 (defun nnvirtual-create-mapping ()
 410   "Create an article mapping for the current group."
 411   (let* ((div nil)
 412          m marks list article unreads marks active
 413          (map (sort
 414                (apply
 415                 'nconc
 416                 (mapcar
 417                  (lambda (g)
 418                    (when (setq active (gnus-activate-group g))
 419                      (setq unreads (gnus-list-of-unread-articles g)
 420                            marks (gnus-uncompress-marks
 421                                   (gnus-info-marks (gnus-get-info g))))
 422                      (when gnus-use-cache
 423                        (push (cons 'cache (gnus-cache-articles-in-group g))
 424                              marks))
 425                      (setq div (/ (float (car active))
 426                                   (if (zerop (cdr active))
 427                                       1 (cdr active))))
 428                      (mapcar (lambda (n)
 429                                (list (* div (- n (car active)))
 430                                      g n (and (memq n unreads) t)
 431                                      (inline (nnvirtual-marks n marks))))
 432                              (gnus-uncompress-range active))))
 433                  nnvirtual-component-groups))
 434                (lambda (m1 m2)
 435                  (< (car m1) (car m2)))))
 436     (i 0))
 437     (setq nnvirtual-mapping map)
 438     ;; Set the virtual article numbers.
 439     (while (setq m (pop map))
 440       (setcar m (setq article (incf i))))))
 441
 442 (provide 'nnvirtual)
 443
 444 ;;; nnvirtual.el ends here