cgit.sxemacs.org Git - gnus/blob - lisp/nnvirtual.el

   1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
   2 ;; Copyright (C) 1994,95,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; The other access methods (nntp, nnspool, etc) are general news
  28 ;; access methods. This module relies on Gnus and can not be used
  29 ;; separately.
  30
  31 ;;; Code:
  32
  33 (require 'nntp)
  34 (require 'nnheader)
  35 (require 'gnus)
  36 (eval-when-compile (require 'cl))
  37
  38 (defvar nnvirtual-always-rescan nil
  39   "*If non-nil, always scan groups for unread articles when entering a group.
  40 If this variable is nil (which is the default) and you read articles
  41 in a component group after the virtual group has been activated, the
  42 read articles from the component group will show up when you enter the
  43 virtual group.")
  44
  45 \f
  46
  47 (defconst nnvirtual-version "nnvirtual 1.0"
  48   "Version number of this version of nnvirtual.")
  49
  50 (defvar nnvirtual-group-alist nil)
  51 (defvar nnvirtual-current-group nil)
  52 (defvar nnvirtual-component-groups nil)
  53 (defvar nnvirtual-mapping nil)
  54
  55 (defvar nnvirtual-status-string "")
  56
  57 (eval-and-compile
  58   (autoload 'gnus-cache-articles-in-group "gnus-cache"))
  59
  60 \f
  61
  62 ;;; Interface functions.
  63
  64 (defun nnvirtual-retrieve-headers (articles &optional newsgroup server fetch-old)
  65   (when (nnvirtual-possibly-change-group newsgroup server t)
  66     (save-excursion
  67       (if (stringp (car articles))
  68           'headers
  69         (let ((vbuf (nnheader-set-temp-buffer
  70                      (get-buffer-create " *virtual headers*")))
  71               (unfetched (mapcar (lambda (g) (list g))
  72                                  nnvirtual-component-groups))
  73               (system-name (system-name))
  74               cgroup article result prefix)
  75           (while articles
  76             (setq article (assq (pop articles) nnvirtual-mapping))
  77             (when (and (setq cgroup (cadr article))
  78                        (gnus-check-server
  79                         (gnus-find-method-for-group cgroup) t)
  80                        (gnus-request-group cgroup t))
  81               (setq prefix (gnus-group-real-prefix cgroup))
  82               (when (setq result (gnus-retrieve-headers
  83                                   (list (caddr article)) cgroup fetch-old))
  84                 (set-buffer nntp-server-buffer)
  85                 (if (zerop (buffer-size))
  86                     (nconc (assq cgroup unfetched) (list (caddr article)))
  87                   ;; If we got HEAD headers, we convert them into NOV
  88                   ;; headers.  This is slow, inefficient and, come to think
  89                   ;; of it, downright evil.  So sue me.  I couldn't be
  90                   ;; bothered to write a header parse routine that could
  91                   ;; parse a mixed HEAD/NOV buffer.
  92                   (when (eq result 'headers)
  93                     (nnvirtual-convert-headers))
  94                   (goto-char (point-min))
  95                   (while (not (eobp))
  96                     (delete-region
  97                      (point) (progn (read nntp-server-buffer) (point)))
  98                     (princ (car article) (current-buffer))
  99                     (beginning-of-line)
 100                     (looking-at
 101                      "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
 102                     (goto-char (match-end 0))
 103                     (or (search-forward
 104                          "\t" (save-excursion (end-of-line) (point)) t)
 105                         (end-of-line))
 106                     (while (= (char-after (1- (point))) ? )
 107                       (forward-char -1)
 108                       (delete-char 1))
 109                     (if (eolp)
 110                         (progn
 111                           (end-of-line)
 112                           (or (= (char-after (1- (point))) ?\t)
 113                               (insert ?\t))
 114                           (insert "Xref: " system-name " " cgroup ":")
 115                           (princ (caddr article) (current-buffer))
 116                           (insert "\t"))
 117                       (insert "Xref: " system-name " " cgroup ":")
 118                       (princ (caddr article) (current-buffer))
 119                       (insert " ")
 120                       (if (not (string= "" prefix))
 121                           (while (re-search-forward
 122                                   "[^ ]+:[0-9]+"
 123                                   (save-excursion (end-of-line) (point)) t)
 124                             (save-excursion
 125                               (goto-char (match-beginning 0))
 126                               (insert prefix))))
 127                       (end-of-line)
 128                       (or (= (char-after (1- (point))) ?\t)
 129                           (insert ?\t)))
 130                     (forward-line 1))
 131                   (set-buffer vbuf)
 132                   (goto-char (point-max))
 133                   (insert-buffer-substring nntp-server-buffer)))))
 134
 135           ;; In case some of the articles have expired or been
 136           ;; cancelled, we have to mark them as read in the
 137           ;; component group.
 138           (while unfetched
 139             (when (cdar unfetched)
 140               (gnus-group-make-articles-read
 141                (caar unfetched) (sort (cdar unfetched) '<)))
 142             (setq unfetched (cdr unfetched)))
 143
 144           ;; The headers are ready for reading, so they are inserted into
 145           ;; the nntp-server-buffer, which is where Gnus expects to find
 146           ;; them.
 147           (prog1
 148               (save-excursion
 149                 (set-buffer nntp-server-buffer)
 150                 (erase-buffer)
 151                 (insert-buffer-substring vbuf)
 152                 'nov)
 153             (kill-buffer vbuf)))))))
 154
 155 (defun nnvirtual-open-server (server &optional something)
 156   (nnheader-init-server-buffer))
 157
 158 (defun nnvirtual-close-server (&rest dum)
 159   t)
 160
 161 (defun nnvirtual-request-close ()
 162   (setq nnvirtual-current-group nil
 163         nnvirtual-component-groups nil
 164         nnvirtual-mapping nil
 165         nnvirtual-group-alist nil)
 166   t)
 167
 168 (defun nnvirtual-server-opened (&optional server)
 169   (and nntp-server-buffer
 170        (get-buffer nntp-server-buffer)))
 171
 172 (defun nnvirtual-status-message (&optional server)
 173   nnvirtual-status-string)
 174
 175 (defun nnvirtual-request-article (article &optional group server buffer)
 176   (when (and (nnvirtual-possibly-change-group group server t)
 177              (numberp article))
 178     (let* ((amap (assq article nnvirtual-mapping))
 179            (cgroup (cadr amap)))
 180       (cond
 181        ((not amap)
 182         (nnheader-report 'nnvirtual "No such article: %s" article))
 183        ((not (gnus-check-group cgroup))
 184         (nnheader-report
 185          'nnvirtual "Can't open server where %s exists" cgroup))
 186        ((not (gnus-request-group cgroup t))
 187         (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
 188        (t
 189         (if buffer
 190             (save-excursion
 191               (set-buffer buffer)
 192               (gnus-request-article-this-buffer (caddr amap) cgroup))
 193           (gnus-request-article (caddr amap) cgroup)))))))
 194
 195 (defun nnvirtual-request-group (group &optional server dont-check)
 196   (cond
 197    ((null (nnvirtual-possibly-change-group
 198            group server
 199            (if nnvirtual-always-rescan nil (not dont-check))))
 200     (setq nnvirtual-current-group nil)
 201     (nnheader-report 'nnvirtual "No component groups in %s" group))
 202    (t
 203     (let ((len (length nnvirtual-mapping)))
 204       (nnheader-insert "211 %d 1 %d %s\n" len len group)))))
 205
 206 (defun nnvirtual-request-type (group &optional article)
 207   (when (nnvirtual-possibly-change-group group nil t)
 208     (if (not article)
 209         'unknown
 210       (let ((mart (assq article nnvirtual-mapping)))
 211         (when mart
 212           (gnus-request-type (cadr mart) (car mart)))))))
 213
 214 (defun nnvirtual-request-update-mark (group article mark)
 215   (when (nnvirtual-possibly-change-group group nil t)
 216     (let* ((nart (assq article nnvirtual-mapping))
 217            (cgroup (cadr nart))
 218            ;; The component group might be a virtual group.
 219            (nmark (gnus-request-update-mark cgroup (caddr nart) mark)))
 220       (when (and (= mark nmark)
 221                  (gnus-group-auto-expirable-p cgroup))
 222         (setq mark gnus-expirable-mark))))
 223   mark)
 224
 225 (defun nnvirtual-close-group (group &optional server)
 226   (when (nnvirtual-possibly-change-group group server t)
 227     ;; We copy the marks from this group to the component
 228     ;; groups here.
 229     (nnvirtual-update-marked)
 230     ;; Reset all relevant variables.
 231     (setq nnvirtual-current-group nil
 232           nnvirtual-component-groups nil
 233           nnvirtual-mapping nil)
 234     (setq nnvirtual-group-alist
 235           (delq (assoc group nnvirtual-group-alist) nnvirtual-group-alist)))
 236   t)
 237
 238 (defun nnvirtual-request-list (&optional server)
 239   (nnheader-report 'nnvirtual "LIST is not implemented."))
 240
 241 (defun nnvirtual-request-newgroups (date &optional server)
 242   (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
 243
 244 (defun nnvirtual-request-list-newsgroups (&optional server)
 245   (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
 246
 247 (defun nnvirtual-request-update-info (group info &optional server)
 248   (when (nnvirtual-possibly-change-group group server)
 249     (let ((map nnvirtual-mapping)
 250           (marks (mapcar (lambda (m) (list (cdr m))) gnus-article-mark-lists))
 251           reads mr m op)
 252       (while map
 253         (setq m (pop map))
 254         (unless (nth 3 m)
 255           (push (car m) reads))
 256         (when (setq mr (nth 4 m))
 257           (while mr
 258             (setcdr (setq op (assq (pop mr) marks)) (cons (car m) (cdr op))))))
 259       (setq mr marks)
 260       (while mr
 261         (setcdr (car mr) (gnus-compress-sequence (sort (cdar mr) '<)))
 262         (setq mr (cdr mr)))
 263       (setcar (cddr info) (gnus-compress-sequence (nreverse reads)))
 264
 265       ;; Enter these new marks into the info of the group.
 266       (if (nthcdr 3 info)
 267           (setcar (nthcdr 3 info) marks)
 268         ;; Add the marks lists to the end of the info.
 269         (when marks
 270           (setcdr (nthcdr 2 info) (list marks))))
 271       t)))
 272
 273 (defun nnvirtual-catchup-group (group &optional server all)
 274   (nnvirtual-possibly-change-group group server t)
 275   (let ((gnus-group-marked nnvirtual-component-groups)
 276         (gnus-expert-user t))
 277     (save-excursion
 278       (set-buffer gnus-group-buffer)
 279       (gnus-group-catchup-current nil all))))
 280
 281 (defun nnvirtual-find-group-art (group article)
 282   "Return the real group and article for virtual GROUP and ARTICLE."
 283   (nnvirtual-possibly-change-group group nil t)
 284   (let ((mart (assq article nnvirtual-mapping)))
 285     (when mart
 286       (cons (cadr mart) (caddr mart)))))
 287
 288 \f
 289 ;;; Internal functions.
 290
 291 (defun nnvirtual-convert-headers ()
 292   "Convert HEAD headers into NOV headers."
 293   (save-excursion
 294     (set-buffer nntp-server-buffer)
 295     (let* ((dependencies (make-vector 100 0))
 296            (headers (gnus-get-newsgroup-headers dependencies))
 297            header)
 298       (erase-buffer)
 299       (while (setq header (pop headers))
 300         (insert (int-to-string (mail-header-number header)) "\t"
 301                 (or (mail-header-subject header) "") "\t"
 302                 (or (mail-header-from header) "") "\t"
 303                 (or (mail-header-date header) "") "\t"
 304                 (or (mail-header-id header) "") "\t"
 305                 (or (mail-header-references header) "") "\t"
 306                 (int-to-string (or (mail-header-chars header) 0)) "\t"
 307                 (int-to-string (or (mail-header-lines header) 0)) "\t"
 308                 (if (mail-header-xref header)
 309                     (concat "Xref: " (mail-header-xref header) "\t")
 310                   "") "\n")))))
 311
 312 (defun nnvirtual-possibly-change-group (group regexp &optional check)
 313   (let ((inf t))
 314     (when (or (not (equal group nnvirtual-current-group))
 315               check)
 316       (and (setq inf (assoc group nnvirtual-group-alist))
 317            regexp
 318            (string= (nth 3 inf) regexp)
 319            (progn
 320              (setq nnvirtual-current-group (car inf))
 321              (setq nnvirtual-component-groups (nth 1 inf))
 322              (setq nnvirtual-mapping (nth 2 inf))))
 323       (when (and regexp (not inf))
 324         (and inf (setq nnvirtual-group-alist
 325                        (delq inf nnvirtual-group-alist)))
 326         (setq nnvirtual-mapping nil)
 327         (setq nnvirtual-current-group group)
 328         (let ((newsrc gnus-newsrc-alist)
 329               (virt-group (gnus-group-prefixed-name
 330                            nnvirtual-current-group '(nnvirtual ""))))
 331           (setq nnvirtual-component-groups nil)
 332           (while newsrc
 333             (and (string-match regexp (caar newsrc))
 334                  (not (string= (caar newsrc) virt-group))
 335                  (setq nnvirtual-component-groups
 336                        (cons (caar newsrc) nnvirtual-component-groups)))
 337             (setq newsrc (cdr newsrc))))
 338         (if nnvirtual-component-groups
 339             (progn
 340               (nnvirtual-create-mapping)
 341               (setq nnvirtual-group-alist
 342                     (cons (list group nnvirtual-component-groups
 343                                 nnvirtual-mapping regexp)
 344                           nnvirtual-group-alist)))
 345           (nnheader-report 'nnvirtual "No component groups: %s" group)))))
 346   nnvirtual-component-groups)
 347
 348 (defun nnvirtual-update-marked ()
 349   "Copy marks from the virtual group to the component groups."
 350   (let ((mark-lists gnus-article-mark-lists)
 351         type list mart cgroups)
 352     (when (and gnus-summary-buffer
 353                (get-buffer gnus-summary-buffer)
 354                (buffer-name (get-buffer gnus-summary-buffer)))
 355       (set-buffer gnus-summary-buffer))
 356     (while mark-lists
 357       (setq type (cdar mark-lists))
 358       (setq list (symbol-value (intern (format "gnus-newsgroup-%s"
 359                                                (car (pop mark-lists))))))
 360       (setq cgroups
 361             (mapcar (lambda (g) (list g)) nnvirtual-component-groups))
 362       (while list
 363         (nconc (assoc (cadr (setq mart (assq (pop list) nnvirtual-mapping)))
 364                       cgroups)
 365                (list (caddr mart))))
 366       (while cgroups
 367         (gnus-add-marked-articles
 368          (caar cgroups) type (cdar cgroups) nil t)
 369         (gnus-group-update-group (car (pop cgroups)) t)))))
 370
 371 (defsubst nnvirtual-marks (article marks)
 372   "Return a list of mark types for ARTICLE."
 373   (let (out)
 374     (while marks
 375       (when (memq article (cdar marks))
 376         (push (caar marks) out))
 377       (setq marks (cdr marks)))
 378     out))
 379
 380 (defun nnvirtual-create-mapping ()
 381   "Create an article mapping for the current group."
 382   (let* (div m marks list article
 383          (map (sort
 384                (apply
 385                 'nconc
 386                 (mapcar
 387                  (lambda (g)
 388                    (let* ((active (or (gnus-active g) (gnus-activate-group g)))
 389                           (unreads (and active (gnus-list-of-unread-articles
 390                                                 g)))
 391                           (marks (gnus-uncompress-marks
 392                                   (gnus-info-marks (gnus-get-info g)))))
 393                      (when active
 394                        (when gnus-use-cache
 395                          (push (cons 'cache (gnus-cache-articles-in-group g))
 396                                marks))
 397                        (when active
 398                          (setq div (/ (float (car active))
 399                                       (if (zerop (cdr active))
 400                                           1 (cdr active)) ))
 401                          (mapcar (lambda (n)
 402                                    (list (* div (- n (car active)))
 403                                          g n (and (memq n unreads) t)
 404                                          (nnvirtual-marks n marks)))
 405                                  (gnus-uncompress-range active))))))
 406          nnvirtual-component-groups))
 407                (lambda (m1 m2)
 408                  (< (car m1) (car m2)))))
 409          (i 0))
 410     (setq nnvirtual-mapping map)
 411     ;; Nix out any old marks.
 412     (let ((marks gnus-article-mark-lists))
 413       (set (intern (format "gnus-newsgroup-%s" (car (pop marks)))) nil))
 414     ;; Copy in all marks from the component groups.
 415     (while (setq m (pop map))
 416       (setcar m (setq article (incf i)))
 417       (when (setq marks (nth 4 m))
 418         (while marks
 419           (set (setq list
 420                      (intern (concat "gnus-newsgroup-"
 421                                      (symbol-name
 422                                       (car (rassq (pop marks)
 423                                                   gnus-article-mark-lists))))))
 424                (cons article (symbol-value list))))))))
 425
 426 (provide 'nnvirtual)
 427
 428 ;;; nnvirtual.el ends here