cgit.sxemacs.org Git - gnus/blob - lisp/nnvirtual.el

   1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
   2 ;; Copyright (C) 1994,95,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: David Moore <dmoore@ucsd.edu>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The other access methods (nntp, nnspool, etc) are general news
  29 ;; access methods.  This module relies on Gnus and can not be used
  30 ;; separately.
  31
  32 ;;; Code:
  33
  34 (require 'nntp)
  35 (require 'nnheader)
  36 (require 'gnus)
  37 (require 'nnoo)
  38 (require 'gnus-util)
  39 (require 'gnus-start)
  40 (require 'gnus-sum)
  41 (require 'gnus-msg)
  42 (require 'cl)
  43
  44 (nnoo-declare nnvirtual)
  45
  46 (defvoo nnvirtual-always-rescan t
  47   "*If non-nil, always scan groups for unread articles when entering a group.
  48 If this variable is nil (which is the default) and you read articles
  49 in a component group after the virtual group has been activated, the
  50 read articles from the component group will show up when you enter the
  51 virtual group.")
  52
  53 (defvoo nnvirtual-component-regexp nil
  54   "*Regexp to match component groups.")
  55
  56 (defvoo nnvirtual-component-groups nil
  57   "Component group in this nnvirtual group.")
  58
  59 \f
  60
  61 (defconst nnvirtual-version "nnvirtual 1.1")
  62
  63 (defvoo nnvirtual-current-group nil)
  64
  65 (defvoo nnvirtual-mapping-table nil
  66   "Table of rules on how to map between component group and article number
  67 to virtual article number.")
  68
  69 (defvoo nnvirtual-mapping-offsets nil
  70   "Table indexed by component group to an offset to be applied to article numbers in that group.")
  71
  72 (defvoo nnvirtual-mapping-len 0
  73   "Number of articles in this virtual group.")
  74
  75 (defvoo nnvirtual-mapping-reads nil
  76   "Compressed sequence of read articles on the virtual group as computed from the unread status of individual component groups.")
  77
  78 (defvoo nnvirtual-mapping-marks nil
  79   "Compressed marks alist for the virtual group as computed from the marks of individual component groups.")
  80
  81 (defvoo nnvirtual-info-installed nil
  82   "T if we have already installed the group info for this group, and shouldn't blast over it again.")
  83
  84 (defvoo nnvirtual-status-string "")
  85
  86 (eval-and-compile
  87   (autoload 'gnus-cache-articles-in-group "gnus-cache"))
  88
  89 \f
  90
  91 ;;; Interface functions.
  92
  93 (nnoo-define-basics nnvirtual)
  94
  95
  96 (deffoo nnvirtual-retrieve-headers (articles &optional newsgroup
  97                                              server fetch-old)
  98   (when (nnvirtual-possibly-change-server server)
  99     (save-excursion
 100       (set-buffer nntp-server-buffer)
 101       (erase-buffer)
 102       (if (stringp (car articles))
 103           'headers
 104         (let ((vbuf (nnheader-set-temp-buffer
 105                      (get-buffer-create " *virtual headers*")))
 106               (carticles (nnvirtual-partition-sequence articles))
 107               (system-name (system-name))
 108               cgroup carticle article result prefix)
 109           (while carticles
 110             (setq cgroup (caar carticles))
 111             (setq articles (cdar carticles))
 112             (pop carticles)
 113             (when (and articles
 114                        (gnus-check-server
 115                         (gnus-find-method-for-group cgroup) t)
 116                        (gnus-request-group cgroup t)
 117                        (setq prefix (gnus-group-real-prefix cgroup))
 118                        ;; FIX FIX FIX we want to check the cache!
 119                        ;; This is probably evil if people have set
 120                        ;; gnus-use-cache to nil themselves, but I
 121                        ;; have no way of finding the true value of it.
 122                        (let ((gnus-use-cache t))
 123                          (setq result (gnus-retrieve-headers
 124                                        articles cgroup nil))))
 125             (set-buffer nntp-server-buffer)
 126             ;; If we got HEAD headers, we convert them into NOV
 127             ;; headers.  This is slow, inefficient and, come to think
 128             ;; of it, downright evil.  So sue me.  I couldn't be
 129             ;; bothered to write a header parse routine that could
 130             ;; parse a mixed HEAD/NOV buffer.
 131             (when (eq result 'headers)
 132               (nnvirtual-convert-headers))
 133             (goto-char (point-min))
 134             (while (not (eobp))
 135               (delete-region (point)
 136                              (progn
 137                                (setq carticle (read nntp-server-buffer))
 138                                (point)))
 139
 140               ;; We remove this article from the articles list, if
 141               ;; anything is left in the articles list after going through
 142               ;; the entire buffer, then those articles have been
 143               ;; expired or canceled, so we appropriately update the
 144               ;; component group below.  They should be coming up
 145               ;; generally in order, so this shouldn't be slow.
 146               (setq articles (delq carticle articles))
 147
 148               (setq article (nnvirtual-reverse-map-article cgroup carticle))
 149               (if (null article)
 150                   ;; This line has no reverse mapping, that means it
 151                   ;; was an extra article reference returned by nntp.
 152                   (progn
 153                     (beginning-of-line)
 154                     (delete-region (point) (progn (forward-line 1) (point))))
 155                 ;; Otherwise insert the virtual article number,
 156                 ;; and clean up the xrefs.
 157                 (princ article nntp-server-buffer)
 158                 (nnvirtual-update-xref-header cgroup carticle
 159                                               prefix system-name)
 160                 (forward-line 1))
 161               )
 162
 163             (set-buffer vbuf)
 164             (goto-char (point-max))
 165             (insert-buffer-substring nntp-server-buffer))
 166             ;; Anything left in articles is expired or canceled.
 167             ;; Could be smart and not tell it about articles already known?
 168             (when articles
 169               (gnus-group-make-articles-read cgroup articles))
 170             )
 171
 172           ;; The headers are ready for reading, so they are inserted into
 173           ;; the nntp-server-buffer, which is where Gnus expects to find
 174           ;; them.
 175           (prog1
 176               (save-excursion
 177                 (set-buffer nntp-server-buffer)
 178                 (erase-buffer)
 179                 (insert-buffer-substring vbuf)
 180                 ;; FIX FIX FIX, we should be able to sort faster than
 181                 ;; this if needed, since each cgroup is sorted, we just
 182                 ;; need to merge
 183                 (sort-numeric-fields 1 (point-min) (point-max))
 184                 'nov)
 185             (kill-buffer vbuf)))))))
 186
 187
 188 (defvoo nnvirtual-last-accessed-component-group nil)
 189
 190 (deffoo nnvirtual-request-article (article &optional group server buffer)
 191   (when (nnvirtual-possibly-change-server server)
 192     (if (stringp article)
 193         ;; This is a fetch by Message-ID.
 194         (cond
 195          ((not nnvirtual-last-accessed-component-group)
 196           (nnheader-report
 197            'nnvirtual "Don't know what server to request from"))
 198          (t
 199           (save-excursion
 200             (when buffer
 201               (set-buffer buffer))
 202             (let ((method (gnus-find-method-for-group
 203                            nnvirtual-last-accessed-component-group)))
 204               (funcall (gnus-get-function method 'request-article)
 205                        article nil (nth 1 method) buffer)))))
 206       ;; This is a fetch by number.
 207       (let* ((amap (nnvirtual-map-article article))
 208              (cgroup (car amap)))
 209         (cond
 210          ((not amap)
 211           (nnheader-report 'nnvirtual "No such article: %s" article))
 212          ((not (gnus-check-group cgroup))
 213           (nnheader-report
 214            'nnvirtual "Can't open server where %s exists" cgroup))
 215          ((not (gnus-request-group cgroup t))
 216           (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
 217          (t
 218           (setq nnvirtual-last-accessed-component-group cgroup)
 219           (if buffer
 220               (save-excursion
 221                 (set-buffer buffer)
 222                 (gnus-request-article-this-buffer (cdr amap) cgroup))
 223             (gnus-request-article (cdr amap) cgroup))))))))
 224
 225
 226 (deffoo nnvirtual-open-server (server &optional defs)
 227   (unless (assq 'nnvirtual-component-regexp defs)
 228     (push `(nnvirtual-component-regexp ,server)
 229           defs))
 230   (nnoo-change-server 'nnvirtual server defs)
 231   (if nnvirtual-component-groups
 232       t
 233     (setq nnvirtual-mapping-table nil
 234           nnvirtual-mapping-offsets nil
 235           nnvirtual-mapping-len 0
 236           nnvirtual-mapping-reads nil
 237           nnvirtual-mapping-marks nil
 238           nnvirtual-info-installed nil)
 239     (when nnvirtual-component-regexp
 240       ;; Go through the newsrc alist and find all component groups.
 241       (let ((newsrc (cdr gnus-newsrc-alist))
 242             group)
 243         (while (setq group (car (pop newsrc)))
 244           (when (string-match nnvirtual-component-regexp group) ; Match
 245             ;; Add this group to the list of component groups.
 246             (setq nnvirtual-component-groups
 247                   (cons group (delete group nnvirtual-component-groups)))))))
 248     (if (not nnvirtual-component-groups)
 249         (nnheader-report 'nnvirtual "No component groups: %s" server)
 250       t)))
 251
 252
 253 (deffoo nnvirtual-request-group (group &optional server dont-check)
 254   (nnvirtual-possibly-change-server server)
 255   (setq nnvirtual-component-groups
 256         (delete (nnvirtual-current-group) nnvirtual-component-groups))
 257   (cond
 258    ((null nnvirtual-component-groups)
 259     (setq nnvirtual-current-group nil)
 260     (nnheader-report 'nnvirtual "No component groups in %s" group))
 261    (t
 262     (setq nnvirtual-current-group group)
 263     (when (or (not dont-check)
 264               nnvirtual-always-rescan)
 265       (nnvirtual-create-mapping)
 266       (when nnvirtual-always-rescan
 267         (nnvirtual-request-update-info
 268          (nnvirtual-current-group)
 269          (gnus-get-info (nnvirtual-current-group)))))
 270     (nnheader-insert "211 %d 1 %d %s\n"
 271                      nnvirtual-mapping-len nnvirtual-mapping-len group))))
 272
 273
 274 (deffoo nnvirtual-request-type (group &optional article)
 275   (if (not article)
 276       'unknown
 277     (if (numberp article)
 278         (let ((mart (nnvirtual-map-article article)))
 279           (if mart
 280               (gnus-request-type (car mart) (cdr mart))))
 281       (gnus-request-type
 282        nnvirtual-last-accessed-component-group nil))))
 283
 284 (deffoo nnvirtual-request-update-mark (group article mark)
 285   (let* ((nart (nnvirtual-map-article article))
 286          (cgroup (car nart))
 287          ;; The component group might be a virtual group.
 288          (nmark (gnus-request-update-mark cgroup (cdr nart) mark)))
 289     (when (and nart
 290                (= mark nmark)
 291                (gnus-group-auto-expirable-p cgroup))
 292       (setq mark gnus-expirable-mark)))
 293   mark)
 294
 295
 296 (deffoo nnvirtual-close-group (group &optional server)
 297   (when (and (nnvirtual-possibly-change-server server)
 298              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 299     (nnvirtual-update-read-and-marked t t))
 300   t)
 301
 302
 303 (deffoo nnvirtual-request-list (&optional server)
 304   (nnheader-report 'nnvirtual "LIST is not implemented."))
 305
 306
 307 (deffoo nnvirtual-request-newgroups (date &optional server)
 308   (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
 309
 310
 311 (deffoo nnvirtual-request-list-newsgroups (&optional server)
 312   (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
 313
 314
 315 (deffoo nnvirtual-request-update-info (group info &optional server)
 316   (when (and (nnvirtual-possibly-change-server server)
 317              (not nnvirtual-info-installed))
 318     ;; Install the precomputed lists atomically, so the virtual group
 319     ;; is not left in a half-way state in case of C-g.
 320     (gnus-atomic-progn
 321       (setcar (cddr info) nnvirtual-mapping-reads)
 322       (if (nthcdr 3 info)
 323           (setcar (nthcdr 3 info) nnvirtual-mapping-marks)
 324         (when nnvirtual-mapping-marks
 325           (setcdr (nthcdr 2 info) (list nnvirtual-mapping-marks))))
 326       (setq nnvirtual-info-installed t))
 327     t))
 328
 329
 330 (deffoo nnvirtual-catchup-group (group &optional server all)
 331   (when (and (nnvirtual-possibly-change-server server)
 332              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 333     ;; copy over existing marks first, in case they set anything
 334     (nnvirtual-update-read-and-marked nil nil)
 335     ;; do a catchup on all component groups
 336     (let ((gnus-group-marked (copy-sequence nnvirtual-component-groups))
 337           (gnus-expert-user t))
 338       ;; Make sure all groups are activated.
 339       (mapcar
 340        (lambda (g)
 341          (when (not (numberp (car (gnus-gethash g gnus-newsrc-hashtb))))
 342            (gnus-activate-group g)))
 343        nnvirtual-component-groups)
 344       (save-excursion
 345         (set-buffer gnus-group-buffer)
 346         (gnus-group-catchup-current nil all)))))
 347
 348
 349 (deffoo nnvirtual-find-group-art (group article)
 350   "Return the real group and article for virtual GROUP and ARTICLE."
 351   (nnvirtual-map-article article))
 352
 353
 354 (deffoo nnvirtual-request-post (&optional server)
 355   (if (not gnus-message-group-art)
 356       (nnheader-report 'nnvirtual "Can't post to an nnvirtual group")
 357     (let ((group (car (nnvirtual-find-group-art
 358                        (car gnus-message-group-art)
 359                        (cdr gnus-message-group-art)))))
 360       (gnus-request-post (gnus-find-method-for-group group)))))
 361
 362 \f
 363 ;;; Internal functions.
 364
 365 (defun nnvirtual-convert-headers ()
 366   "Convert HEAD headers into NOV headers."
 367   (save-excursion
 368     (set-buffer nntp-server-buffer)
 369     (let* ((dependencies (make-vector 100 0))
 370            (headers (gnus-get-newsgroup-headers dependencies))
 371            header)
 372       (erase-buffer)
 373       (while (setq header (pop headers))
 374         (nnheader-insert-nov header)))))
 375
 376
 377 (defun nnvirtual-update-xref-header (group article prefix system-name)
 378   "Edit current NOV header in current buffer to have an xref to the component group, and also server prefix any existing xref lines."
 379   ;; Move to beginning of Xref field, creating a slot if needed.
 380   (beginning-of-line)
 381   (looking-at
 382    "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
 383   (goto-char (match-end 0))
 384   (unless (search-forward "\t" (gnus-point-at-eol) 'move)
 385     (insert "\t"))
 386
 387   ;; Remove any spaces at the beginning of the Xref field.
 388   (while (= (char-after (1- (point))) ? )
 389     (forward-char -1)
 390     (delete-char 1))
 391
 392   (insert "Xref: " system-name " " group ":")
 393   (princ article (current-buffer))
 394   (insert " ")
 395
 396   ;; If there were existing xref lines, clean them up to have the correct
 397   ;; component server prefix.
 398   (save-restriction
 399     (narrow-to-region (point)
 400                       (or (search-forward "\t" (gnus-point-at-eol) t)
 401                           (gnus-point-at-eol)))
 402     (goto-char (point-min))
 403     (when (re-search-forward "Xref: *[^\n:0-9 ]+ *" nil t)
 404       (replace-match "" t t))
 405     (goto-char (point-min))
 406     (when (re-search-forward
 407            (concat (regexp-quote (gnus-group-real-name group)) ":[0-9]+")
 408            nil t)
 409       (replace-match "" t t))
 410     (unless (= (point) (point-max))
 411       (insert " ")
 412       (when (not (string= "" prefix))
 413         (while (re-search-forward "[^ ]+:[0-9]+" nil t)
 414           (save-excursion
 415             (goto-char (match-beginning 0))
 416             (insert prefix))))))
 417
 418   ;; Ensure a trailing \t.
 419   (end-of-line)
 420   (or (= (char-after (1- (point))) ?\t)
 421       (insert ?\t)))
 422
 423
 424 (defun nnvirtual-possibly-change-server (server)
 425   (or (not server)
 426       (nnoo-current-server-p 'nnvirtual server)
 427       (nnvirtual-open-server server)))
 428
 429
 430 (defun nnvirtual-update-read-and-marked (read-p update-p)
 431   "Copy marks from the virtual group to the component groups.
 432 If READ-P is not nil, update the (un)read status of the components.
 433 If UPDATE-P is not nil, call gnus-group-update-group on the components."
 434   (when nnvirtual-current-group
 435     (let ((unreads (and read-p
 436                         (nnvirtual-partition-sequence
 437                          (gnus-list-of-unread-articles
 438                           (nnvirtual-current-group)))))
 439           (type-marks
 440            (delq nil
 441                  (mapcar (lambda (ml)
 442                            (if (eq (car ml) 'score)
 443                                nil
 444                              (cons (car ml)
 445                                    (nnvirtual-partition-sequence (cdr ml)))))
 446                          (gnus-info-marks (gnus-get-info
 447                                            (nnvirtual-current-group))))))
 448           mark type groups carticles info entry)
 449
 450       ;; Ok, atomically move all of the (un)read info, clear any old
 451       ;; marks, and move all of the current marks.  This way if someone
 452       ;; hits C-g, you won't leave the component groups in a half-way state.
 453       (progn
 454         ;; move (un)read
 455         (let ((gnus-newsgroup-active nil)) ;workaround guns-update-read-articles
 456           (while (setq entry (pop unreads))
 457             (gnus-update-read-articles (car entry) (cdr entry))))
 458
 459         ;; clear all existing marks on the component groups
 460         (setq groups nnvirtual-component-groups)
 461         (while groups
 462           (when (and (setq info (gnus-get-info (pop groups)))
 463                      (gnus-info-marks info))
 464             (gnus-info-set-marks
 465              info
 466              (if (assq 'score (gnus-info-marks info))
 467                  (list (assq 'score (gnus-info-marks info)))
 468                nil))))
 469
 470         ;; Ok, currently type-marks is an assq list with keys of a mark type,
 471         ;; with data of an assq list with keys of component group names
 472         ;; and the articles which correspond to that key/group pair.
 473         (while (setq mark (pop type-marks))
 474           (setq type (car mark))
 475           (setq groups (cdr mark))
 476           (while (setq carticles (pop groups))
 477             (gnus-add-marked-articles (car carticles) type (cdr carticles)
 478                                       nil t))))
 479
 480       ;; possibly update the display, it is really slow
 481       (when update-p
 482         (setq groups nnvirtual-component-groups)
 483         (while groups
 484           (gnus-group-update-group (pop groups) t))))))
 485
 486
 487 (defun nnvirtual-current-group ()
 488   "Return the prefixed name of the current nnvirtual group."
 489   (concat "nnvirtual:" nnvirtual-current-group))
 490
 491
 492
 493 ;;; This is currently O(kn^2) to merge n lists of length k.
 494 ;;; You could do it in O(knlogn), but we have a small n, and the
 495 ;;; overhead of the other approach is probably greater.
 496 (defun nnvirtual-merge-sorted-lists (&rest lists)
 497   "Merge many sorted lists of numbers."
 498   (if (null (cdr lists))
 499       (car lists)
 500     (sort (apply 'nconc lists) '<)))
 501
 502
 503 ;;; We map between virtual articles and real articles in a manner
 504 ;;; which keeps the size of the virtual active list the same as
 505 ;;; the sum of the component active lists.
 506 ;;; To achieve fair mixing of the groups, the last article in
 507 ;;; each of N component groups will be in the the last N articles
 508 ;;; in the virtual group.
 509
 510 ;;; If you have 3 components A, B and C, with articles 1-8, 1-5, and 6-7
 511 ;;; resprectively, then the virtual article numbers look like:
 512 ;;;
 513 ;;;  1  2  3  4  5  6  7  8  9  10 11 12 13 14 15
 514 ;;;  A1 A2 A3 A4 B1 A5 B2 A6 B3 A7 B4 C6 A8 B5 C7
 515
 516 ;;; To compute these mappings we generate a couple tables and then
 517 ;;; do some fast operations on them.  Tables for the example above:
 518 ;;;
 519 ;;; Offsets - [(A 0) (B -3) (C -1)]
 520 ;;;
 521 ;;;               a  b  c  d  e
 522 ;;; Mapping - ([  3  0  1  3  0 ]
 523 ;;;            [  6  3  2  9  3 ]
 524 ;;;            [  8  6  3 15  9 ])
 525 ;;;
 526 ;;; (note column 'e' is different in real algorithm, which is slightly
 527 ;;;  different than described here, but this gives you the methodology.)
 528 ;;;
 529 ;;; The basic idea is this, when going from component->virtual, apply
 530 ;;; the appropriate offset to the article number.  Then search the first
 531 ;;; column of the table for a row where 'a' is less than or equal to the
 532 ;;; modified number.  You can see that only group A can therefore go to
 533 ;;; the first row, groups A and B to the second, and all to the last.
 534 ;;; The third column of the table is telling us the number of groups
 535 ;;; which might be able to reach that row (it might increase by more than
 536 ;;; 1 if several groups have the same size).
 537 ;;; Then column 'b' provides an additional offset you apply when you have
 538 ;;; found the correct row.  You then multiply by 'c' and add on the groups
 539 ;;; _position_ in the offset table.  The basic idea here is that on
 540 ;;; any given row we are going to map back and forth using X'=X*c+Y and
 541 ;;; X=(X'/c), Y=(X' mod c).  Then once you've done this transformation,
 542 ;;; you apply a final offset from column 'e' to give the virtual article.
 543 ;;;
 544 ;;; Going the other direction, you instead search on column 'd' instead
 545 ;;; of 'a', and apply everything in reverse order.
 546
 547 ;;; Convert component -> virtual:
 548 ;;; set num = num - Offset(group)
 549 ;;; find first row in Mapping where num <= 'a'
 550 ;;; num = (num-'b')*c + Position(group) + 'e'
 551
 552 ;;; Convert virtual -> component:
 553 ;;; find first row in Mapping where num <= 'd'
 554 ;;; num = num - 'e'
 555 ;;; group_pos = num mod 'c'
 556 ;;; num = (num / 'c') + 'b' + Offset(group_pos)
 557
 558 ;;; Easy no? :)
 559 ;;;
 560 ;;; Well actually, you need to keep column e offset smaller by the 'c'
 561 ;;; column for that line, and always add 1 more when going from
 562 ;;; component -> virtual.  Otherwise you run into a problem with
 563 ;;; unique reverse mapping.
 564
 565 (defun nnvirtual-map-article (article)
 566   "Return a cons of the component group and article corresponding to the given virtual ARTICLE."
 567   (let ((table nnvirtual-mapping-table)
 568         entry group-pos)
 569     (while (and table
 570                 (> article (aref (car table) 3)))
 571       (setq table (cdr table)))
 572     (when (and table
 573                (> article 0))
 574       (setq entry (car table))
 575       (setq article (- article (aref entry 4) 1))
 576       (setq group-pos (mod article (aref entry 2)))
 577       (cons (car (aref nnvirtual-mapping-offsets group-pos))
 578             (+ (/ article (aref entry 2))
 579                (aref entry 1)
 580                (cdr (aref nnvirtual-mapping-offsets group-pos)))
 581             ))
 582       ))
 583
 584
 585
 586 (defun nnvirtual-reverse-map-article (group article)
 587   "Return the virtual article number corresponding to the given component GROUP and ARTICLE."
 588   (when (numberp article)
 589     (let ((table nnvirtual-mapping-table)
 590           (group-pos 0)
 591           entry)
 592       (while (not (string= group (car (aref nnvirtual-mapping-offsets
 593                                             group-pos))))
 594         (setq group-pos (1+ group-pos)))
 595       (setq article (- article (cdr (aref nnvirtual-mapping-offsets
 596                                           group-pos))))
 597       (while (and table
 598                   (> article (aref (car table) 0)))
 599         (setq table (cdr table)))
 600       (setq entry (car table))
 601       (when (and entry
 602                  (> article 0)
 603                  (< group-pos (aref entry 2))) ; article not out of range below
 604         (+ (aref entry 4)
 605            group-pos
 606            (* (- article (aref entry 1))
 607               (aref entry 2))
 608            1))
 609       )))
 610
 611
 612 (defsubst nnvirtual-reverse-map-sequence (group articles)
 613   "Return list of virtual article numbers for all ARTICLES in GROUP.
 614 The ARTICLES should be sorted, and can be a compressed sequence.
 615 If any of the article numbers has no corresponding virtual article,
 616 then it is left out of the result."
 617   (when (numberp (cdr-safe articles))
 618     (setq articles (list articles)))
 619   (let (result a i j new-a)
 620     (while (setq a (pop articles))
 621       (if (atom a)
 622           (setq i a
 623                 j a)
 624         (setq i (car a)
 625               j (cdr a)))
 626       (while (<= i j)
 627         ;; If this is slow, you can optimize by moving article checking
 628         ;; into here.  You don't have to recompute the group-pos,
 629         ;; nor scan the table every time.
 630         (when (setq new-a (nnvirtual-reverse-map-article group i))
 631           (push new-a result))
 632         (setq i (1+ i))))
 633     (nreverse result)))
 634
 635
 636 (defun nnvirtual-partition-sequence (articles)
 637   "Return an association list of component article numbers.
 638 These are indexed by elements of nnvirtual-component-groups, based on
 639 the sequence ARTICLES of virtual article numbers.  ARTICLES should be
 640 sorted, and can be a compressed sequence. If any of the article
 641 numbers has no corresponding component article, then it is left out of
 642 the result."
 643   (when (numberp (cdr-safe articles))
 644     (setq articles (list articles)))
 645   (let ((carticles (mapcar (lambda (g) (list g))
 646                            nnvirtual-component-groups))
 647         a i j article entry)
 648     (while (setq a (pop articles))
 649       (if (atom a)
 650           (setq i a
 651                 j a)
 652         (setq i (car a)
 653               j (cdr a)))
 654       (while (<= i j)
 655         (when (setq article (nnvirtual-map-article i))
 656           (setq entry (assoc (car article) carticles))
 657           (setcdr entry (cons (cdr article) (cdr entry))))
 658         (setq i (1+ i))))
 659     (mapcar (lambda (x) (setcdr x (nreverse (cdr x))))
 660             carticles)
 661     carticles))
 662
 663
 664 (defun nnvirtual-create-mapping ()
 665   "Build the tables necessary to map between component (group, article) to virtual article.
 666 Generate the set of read messages and marks for the virtual group
 667 based on the marks on the component groups."
 668   (let ((cnt 0)
 669         (tot 0)
 670         (M 0)
 671         (i 0)
 672         actives all-unreads all-marks
 673         active min max size unreads marks
 674         next-M next-tot
 675         reads beg)
 676     ;; Ok, we loop over all component groups and collect a lot of
 677     ;; information:
 678     ;; Into actives we place (g size max), where size is max-min+1.
 679     ;; Into all-unreads we put (g unreads).
 680     ;; Into all-marks we put (g marks).
 681     ;; We also increment cnt and tot here, and compute M (max of sizes).
 682     (mapc (lambda (g)
 683             (setq active (gnus-activate-group g)
 684                   min (car active)
 685                   max (cdr active))
 686             (when (and active (>= max min) (not (zerop max)))
 687               ;; store active information
 688               (push (list g (- max min -1) max) actives)
 689               ;; collect unread/mark info for later
 690               (setq unreads (gnus-list-of-unread-articles g))
 691               (setq marks (gnus-info-marks (gnus-get-info g)))
 692               (when gnus-use-cache
 693                 (push (cons 'cache
 694                             (gnus-cache-articles-in-group g))
 695                       marks))
 696               (push (cons g unreads) all-unreads)
 697               (push (cons g marks) all-marks)
 698               ;; count groups, total #articles, and max size
 699               (setq size (- max min -1))
 700               (setq cnt (1+ cnt)
 701                     tot (+ tot size)
 702                     M (max M size))))
 703           nnvirtual-component-groups)
 704
 705     ;; Number of articles in the virtual group.
 706     (setq nnvirtual-mapping-len tot)
 707
 708
 709     ;; We want the actives list sorted by size, to build the tables.
 710     (setq actives (sort actives (lambda (g1 g2) (< (nth 1 g1) (nth 1 g2)))))
 711
 712     ;; Build the offset table.  Largest sized groups are at the front.
 713     (setq nnvirtual-mapping-offsets
 714           (vconcat
 715            (nreverse
 716             (mapcar (lambda (entry)
 717                       (cons (nth 0 entry)
 718                             (- (nth 2 entry) M)))
 719                     actives))))
 720
 721     ;; Build the mapping table.
 722     (setq nnvirtual-mapping-table nil)
 723     (setq actives (mapcar (lambda (entry) (nth 1 entry)) actives))
 724     (while actives
 725       (setq size (car actives))
 726       (setq next-M (- M size))
 727       (setq next-tot (- tot (* cnt size)))
 728       ;; make current row in table
 729       (push (vector M next-M cnt tot (- next-tot cnt))
 730             nnvirtual-mapping-table)
 731       ;; update M and tot
 732       (setq M next-M)
 733       (setq tot next-tot)
 734       ;; subtract the current size from all entries.
 735       (setq actives (mapcar (lambda (x) (- x size)) actives))
 736       ;; remove anything that went to 0.
 737       (while (and actives
 738                   (= (car actives) 0))
 739         (pop actives)
 740         (setq cnt (- cnt 1))))
 741
 742
 743     ;; Now that the mapping tables are generated, we can convert
 744     ;; and combine the separate component unreads and marks lists
 745     ;; into single lists of virtual article numbers.
 746     (setq unreads (apply 'nnvirtual-merge-sorted-lists
 747                          (mapcar (lambda (x)
 748                                    (nnvirtual-reverse-map-sequence
 749                                     (car x) (cdr x)))
 750                                  all-unreads)))
 751     (setq marks (mapcar
 752                  (lambda (type)
 753                    (cons (cdr type)
 754                          (gnus-compress-sequence
 755                           (apply
 756                            'nnvirtual-merge-sorted-lists
 757                            (mapcar (lambda (x)
 758                                      (nnvirtual-reverse-map-sequence
 759                                       (car x)
 760                                       (cdr (assq (cdr type) (cdr x)))))
 761                                    all-marks)))))
 762                  gnus-article-mark-lists))
 763
 764     ;; Remove any empty marks lists, and store.
 765     (setq nnvirtual-mapping-marks nil)
 766     (while marks
 767       (if (cdr (car marks))
 768           (push (car marks) nnvirtual-mapping-marks))
 769       (setq marks (cdr marks)))
 770
 771     ;; We need to convert the unreads to reads.  We compress the
 772     ;; sequence as we go, otherwise it could be huge.
 773     (while (and (<= (incf i) nnvirtual-mapping-len)
 774                 unreads)
 775       (if (= i (car unreads))
 776           (setq unreads (cdr unreads))
 777         ;; try to get a range.
 778         (setq beg i)
 779         (while (and (<= (incf i) nnvirtual-mapping-len)
 780                     (not (= i (car unreads)))))
 781         (setq i (- i 1))
 782         (if (= i beg)
 783             (push i reads)
 784           (push (cons beg i) reads))
 785         ))
 786     (when (<= i nnvirtual-mapping-len)
 787       (if (= i nnvirtual-mapping-len)
 788           (push i reads)
 789         (push (cons i nnvirtual-mapping-len) reads)))
 790
 791     ;; Store the reads list for later use.
 792     (setq nnvirtual-mapping-reads (nreverse reads))
 793
 794     ;; Throw flag to show we changed the info.
 795     (setq nnvirtual-info-installed nil)
 796     ))
 797
 798 (provide 'nnvirtual)
 799
 800 ;;; nnvirtual.el ends here