cgit.sxemacs.org Git - gnus/blob - lisp/nnultimate.el

   1 ;;; nnultimate.el --- interfacing with the Ultimate Bulletin Board system
   2 ;; Copyright (C) 1999 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Note: You need to have `url' and `w3' installed for this
  27 ;; backend to work.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'nnoo)
  34 (require 'message)
  35 (require 'gnus-util)
  36 (require 'gnus)
  37 (require 'nnmail)
  38 (require 'mm-util)
  39 (require 'nnweb)
  40 (eval-when-compile
  41   (ignore-errors
  42     (require 'w3)
  43     (require 'url)
  44     (require 'w3-forms)))
  45 ;; Report failure to find w3 at load time if appropriate.
  46 (eval '(progn
  47          (require 'w3)
  48          (require 'url)
  49          (require 'w3-forms)))
  50
  51 (nnoo-declare nnultimate)
  52
  53 (defvoo nnultimate-directory (nnheader-concat gnus-directory "ultimate/")
  54   "Where nnultimate will save its files.")
  55
  56 (defvoo nnultimate-address ""
  57   "The address of the Ultimate bulletin board.")
  58
  59 ;;; Internal variables
  60
  61 (defvar nnultimate-groups-alist nil)
  62 (defvoo nnultimate-groups nil)
  63 (defvoo nnultimate-headers nil)
  64 (defvoo nnultimate-articles nil)
  65
  66 ;;; Interface functions
  67
  68 (nnoo-define-basics nnultimate)
  69
  70 (deffoo nnultimate-retrieve-headers (articles &optional group server fetch-old)
  71   (nnultimate-possibly-change-server group server)
  72   (unless gnus-nov-is-evil
  73     (let* ((last (car (last articles)))
  74            (did nil)
  75            (start 1)
  76            (entry (assoc group nnultimate-groups))
  77            (sid (nth 2 entry))
  78            (topics (nth 4 entry))
  79            (mapping (nth 5 entry))
  80            (old-total (or (nth 6 entry) 1))
  81            (furl "forumdisplay.cgi?action=topics&number=%d&DaysPrune=1000")
  82            (furls (list (concat nnultimate-address (format furl sid))))
  83            headers article subject score from date lines parent point
  84            contents tinfo fetchers map elem a href garticles topic old-max
  85            inc datel table string current-page total-contents pages
  86            farticles forum-contents parse furl-fetched mmap farticle)
  87       (setq map mapping)
  88       (while (and (setq article (car articles))
  89                   map)
  90         (while (and map
  91                     (> article (caar map)))
  92           (pop map))
  93         (when (setq mmap (car map))
  94           (setq farticle -1)
  95           (while (and article
  96                       (<= article (nth 1 mmap)))
  97             ;; Do we already have a fetcher for this topic?
  98             (if (setq elem (assq (nth 2 mmap) fetchers))
  99                 ;; Yes, so we just add the spec to the end.
 100                 (nconc elem (list (cons article
 101                                         (+ (nth 3 mmap) (incf farticle)))))
 102               ;; No, so we add a new one.
 103               (push (list (nth 2 mmap)
 104                           (cons article
 105                                 (+ (nth 3 mmap) (incf farticle))))
 106                     fetchers))
 107             (pop articles)
 108             (setq article (car articles)))))
 109       ;; Now we have the mapping from/to Gnus/nnultimate article numbers,
 110       ;; so we start fetching the topics that we need to satisfy the
 111       ;; request.
 112       (if (not fetchers)
 113           (save-excursion
 114             (set-buffer nntp-server-buffer)
 115             (erase-buffer))
 116         (setq nnultimate-articles nil)
 117         (with-temp-buffer
 118           (dolist (elem fetchers)
 119             (setq pages 1
 120                   current-page 1
 121                   total-contents nil)
 122             (while (<= current-page pages)
 123               (erase-buffer)
 124               (setq subject (nth 2 (assq (car elem) topics)))
 125               (setq href (nth 3 (assq (car elem) topics)))
 126               (if (= current-page 1)
 127                   (nnweb-insert href)
 128                 (string-match "\\.html$" href)
 129                 (nnweb-insert (concat (substring href 0 (match-beginning 0))
 130                                       "-" (number-to-string current-page)
 131                                       (match-string 0 href))))
 132               (goto-char (point-min))
 133               (setq contents (w3-parse-buffer (current-buffer)))
 134               (setq table (nnultimate-find-forum-table contents))
 135               (setq string (mapconcat 'identity (nnweb-text table) ""))
 136               (when (string-match "topic is \\([0-9]\\) pages" string)
 137                 (setq pages (string-to-number (match-string 1 string)))
 138                 (setcdr table nil)
 139                 (setq table (nnultimate-find-forum-table contents)))
 140               (setq contents (cdr (nth 2 (car (nth 2 table)))))
 141               (setq total-contents (nconc total-contents contents))
 142               (incf current-page))
 143             ;;(setq total-contents (nreverse total-contents))
 144             (dolist (art (cdr elem))
 145               (if (not (nth (1- (cdr art)) total-contents))
 146                   ();(debug)
 147                 (push (list (car art)
 148                             (nth (1- (cdr art)) total-contents)
 149                             subject)
 150                       nnultimate-articles)))))
 151         (setq nnultimate-articles
 152               (sort nnultimate-articles 'car-less-than-car))
 153         ;; Now we have all the articles, conveniently in an alist
 154         ;; where the key is the Gnus article number.
 155         (dolist (articlef nnultimate-articles)
 156           (setq article (nth 0 articlef)
 157                 contents (nth 1 articlef)
 158                 subject (nth 2 articlef))
 159           (setq from (mapconcat 'identity
 160                                 (nnweb-text (car (nth 2 contents)))
 161                                 " ")
 162                 datel (nnweb-text (nth 2 (car (cdr (nth 2 contents))))))
 163           (while datel
 164             (when (string-match "Posted" (car datel))
 165               (setq date (substring (car datel) (match-end 0))
 166                     datel nil))
 167             (pop datel))
 168           (setq date (delete "" (split-string date "[- \n\t\r    ]")))
 169           (if (or (member "AM" date)
 170                   (member "PM" date))
 171               (setq date (format "%s %s %s %s"
 172                                  (car (rassq (string-to-number (nth 0 date))
 173                                              parse-time-months))
 174                                  (nth 1 date) (nth 2 date) (nth 3 date)))
 175             (setq date (format "%s %s %s %s"
 176                                (car (rassq (string-to-number (nth 1 date))
 177                                            parse-time-months))
 178                                (nth 0 date) (nth 2 date) (nth 3 date))))
 179           (push
 180            (cons
 181             article
 182             (make-full-mail-header
 183              article subject
 184              from (or date "")
 185              (concat "<" (number-to-string sid) "%"
 186                      (number-to-string article)
 187                      "@ultimate>")
 188              "" 0
 189              (/ (length (mapconcat
 190                          'identity
 191                          (nnweb-text
 192                           (cdr (nth 2 (nth 1 (nth 2 contents)))))
 193                          ""))
 194                 70)
 195              nil nil))
 196            headers))
 197         (setq nnultimate-headers (sort headers 'car-less-than-car))
 198         (save-excursion
 199           (set-buffer nntp-server-buffer)
 200           (erase-buffer)
 201           (dolist (header nnultimate-headers)
 202             (nnheader-insert-nov (cdr header)))))
 203       'nov)))
 204
 205 (deffoo nnultimate-request-group (group &optional server dont-check)
 206   (nnultimate-possibly-change-server nil server)
 207   (when (not nnultimate-groups)
 208     (nnultimate-request-list))
 209   (unless dont-check
 210     (nnultimate-create-mapping group))
 211   (let ((elem (assoc group nnultimate-groups)))
 212     (cond
 213      ((not elem)
 214       (nnheader-report 'nnultimate "Group does not exist"))
 215      (t
 216       (nnheader-report 'nnultimate "Opened group %s" group)
 217       (nnheader-insert
 218        "211 %d %d %d %s\n" (cadr elem) 1 (cadr elem)
 219        (prin1-to-string group))))))
 220
 221 (deffoo nnultimate-request-article (article &optional group server buffer)
 222   (nnultimate-possibly-change-server group server)
 223   (let ((contents (cdr (assq article nnultimate-articles))))
 224     (setq contents (cddr (nth 2 (nth 1 (nth 2 (car contents))))))
 225     (when contents
 226       (save-excursion
 227         (set-buffer (or buffer nntp-server-buffer))
 228         (erase-buffer)
 229         (nnweb-insert-html (cons 'p (cons nil (list contents))))
 230         (goto-char (point-min))
 231         (insert "Content-Type: text/html\nMIME-Version: 1.0\n")
 232         (let ((header (cdr (assq article nnultimate-headers))))
 233           (nnheader-insert-header header))
 234         (nnheader-report 'nnultimate "Fetched article %s" article)
 235         (cons group article)))))
 236
 237 (deffoo nnultimate-request-list (&optional server)
 238   (nnultimate-possibly-change-server nil server)
 239   (with-temp-buffer
 240     (nnweb-insert
 241      (if (string-match "/$" nnultimate-address)
 242          (concat nnultimate-address "Ultimate.cgi")
 243        nnultimate-address))
 244     (let ((contents (nth 2 (car (nth 2
 245                                      (nnultimate-find-forum-table
 246                                       (w3-parse-buffer (current-buffer)))))))
 247           sid elem description articles a href group forum
 248           a1 a2)
 249       (dolist (row contents)
 250         (setq row (nth 2 row))
 251         (when (setq a (nnweb-parse-find 'a row))
 252           (setq group (car (last (nnweb-text a)))
 253                 href (cdr (assq 'href (nth 1 a))))
 254           (setq description (car (last (nnweb-text (nth 1 row)))))
 255           (setq a1 (car (last (nnweb-text (nth 2 row)))))
 256           (setq a2 (car (last (nnweb-text (nth 3 row)))))
 257           (when (string-match "^[0-9]+$" a1)
 258             (setq articles (string-to-number a1)))
 259           (when (and a2 (string-match "^[0-9]+$" a2))
 260             (setq articles (max articles (string-to-number a2))))
 261           (when href
 262             (string-match "number=\\([0-9]+\\)" href)
 263             (setq forum (string-to-number (match-string 1 href)))
 264             (if (setq elem (assoc group nnultimate-groups))
 265                 (setcar (cdr elem) articles)
 266               (push (list group articles forum description nil nil nil nil)
 267                     nnultimate-groups))))))
 268     (nnultimate-write-groups)
 269     (nnultimate-generate-active)
 270     t))
 271
 272 (deffoo nnultimate-request-newgroups (date &optional server)
 273   (nnultimate-possibly-change-server nil server)
 274   (nnultimate-generate-active)
 275   t)
 276
 277 (nnoo-define-skeleton nnultimate)
 278
 279 ;;; Internal functions
 280
 281 (defun nnultimate-prune-days (group time)
 282   "Compute the number of days to fetch info for."
 283   (let ((old-time (nth 7 (assoc group nnultimate-groups))))
 284     (if (null old-time)
 285         1000
 286       (- (time-to-days time) (time-to-days old-time)))))
 287
 288 (defun nnultimate-create-mapping (group)
 289   (let* ((entry (assoc group nnultimate-groups))
 290          (sid (nth 2 entry))
 291          (topics (nth 4 entry))
 292          (mapping (nth 5 entry))
 293          (old-total (or (nth 6 entry) 1))
 294          (current-time (current-time))
 295          (furl
 296           (concat "forumdisplay.cgi?action=topics&number=%d&DaysPrune="
 297                   (number-to-string
 298                    (nnultimate-prune-days group current-time))))
 299          (furls (list (concat nnultimate-address (format furl sid))))
 300          contents forum-contents furl-fetched a subject href
 301          garticles topic tinfo old-max inc parse)
 302     (with-temp-buffer
 303       (while furls
 304         (erase-buffer)
 305         (nnweb-insert (pop furls))
 306         (goto-char (point-min))
 307         (setq parse (w3-parse-buffer (current-buffer)))
 308         (setq contents
 309               (cdr (nth 2 (car (nth 2 (nnultimate-find-forum-table
 310                                        parse))))))
 311         (setq forum-contents (nconc contents forum-contents))
 312         (unless furl-fetched
 313           (setq furl-fetched t)
 314           ;; On the first time through this loop, we find all the
 315           ;; forum URLs.
 316           (dolist (a (nnweb-parse-find-all 'a parse))
 317             (let ((href (cdr (assq 'href (nth 1 a)))))
 318               (when (and href
 319                          (string-match "forumdisplay.*startpoint" href))
 320                 (push href furls))))
 321           (setq furls (nreverse furls))))
 322       ;; The main idea here is to map Gnus article numbers to
 323       ;; nnultimate article numbers.  Say there are three topics in
 324       ;; this forum, the first with 4 articles, the seconds with 2,
 325       ;; and the third with 1.  Then this will translate into 7 Gnus
 326       ;; article numbers, where 1-4 comes from the first topic, 5-6
 327       ;; from the second and 7 from the third.  Now, then next time
 328       ;; the group is entered, there's 2 new articles in topic one
 329       ;; and 1 in topic three.  Then Gnus article number 8-9 be 5-6
 330       ;; in topic one and 10 will be the 2 in topic three.
 331       (dolist (row (reverse forum-contents))
 332         (setq row (nth 2 row))
 333         (when (setq a (nnweb-parse-find 'a row))
 334           (setq subject (car (last (nnweb-text a)))
 335                 href (cdr (assq 'href (nth 1 a))))
 336           (let ((artlist (nreverse (nnweb-text row)))
 337                 art)
 338             (while (and (not art)
 339                         artlist)
 340               (when (string-match "^[0-9]+$" (car artlist))
 341                 (setq art (1+ (string-to-number (car artlist)))))
 342               (pop artlist))
 343             (setq garticles art))
 344           (string-match "/\\([0-9]+\\).html" href)
 345           (setq topic (string-to-number (match-string 1 href)))
 346           (if (setq tinfo (assq topic topics))
 347               (progn
 348                 (setq old-max (cadr tinfo))
 349                 (setcar (cdr tinfo) garticles))
 350             (setq old-max 0)
 351             (push (list topic garticles subject href) topics)
 352             (setcar (nthcdr 4 entry) topics))
 353           (when (not (= old-max garticles))
 354             (setq inc (- garticles old-max))
 355             (setq mapping (nconc mapping
 356                                  (list
 357                                   (list
 358                                    old-total (1- (incf old-total inc))
 359                                    topic (1+ old-max)))))
 360             (incf old-max inc)
 361             (setcar (nthcdr 5 entry) mapping)
 362             (setcar (nthcdr 6 entry) old-total)))))
 363     (setcar (nthcdr 7 entry) current-time)
 364     (setcar (nthcdr 1 entry) (1- old-total))
 365     (nnultimate-write-groups)
 366     mapping))
 367
 368 (defun nnultimate-possibly-change-server (&optional group server)
 369   (nnultimate-init server)
 370   (when (and server
 371              (not (nnultimate-server-opened server)))
 372     (nnultimate-open-server server))
 373   (unless nnultimate-groups-alist
 374     (nnultimate-read-groups)
 375   (setq nnultimate-groups (cdr (assoc nnultimate-address
 376                                       nnultimate-groups-alist)))))
 377
 378 (deffoo nnultimate-open-server (server &optional defs connectionless)
 379   (nnheader-init-server-buffer)
 380   (if (nnultimate-server-opened server)
 381       t
 382     (unless (assq 'nnultimate-address defs)
 383       (setq defs (append defs (list (list 'nnultimate-address server)))))
 384     (nnoo-change-server 'nnultimate server defs)))
 385
 386 (defun nnultimate-read-groups ()
 387   (setq nnultimate-groups-alist nil)
 388   (let ((file (expand-file-name "groups" nnultimate-directory)))
 389     (when (file-exists-p file)
 390       (with-temp-buffer
 391         (insert-file-contents file)
 392         (goto-char (point-min))
 393         (setq nnultimate-groups-alist (read (current-buffer)))))))
 394
 395 (defun nnultimate-write-groups ()
 396   (setq nnultimate-groups-alist
 397         (delq (assoc nnultimate-address nnultimate-groups-alist)
 398               nnultimate-groups-alist))
 399   (push (cons nnultimate-address nnultimate-groups)
 400         nnultimate-groups-alist)
 401   (with-temp-file (expand-file-name "groups" nnultimate-directory)
 402     (prin1 nnultimate-groups-alist (current-buffer))))
 403
 404 (defun nnultimate-init (server)
 405   "Initialize buffers and such."
 406   (unless (file-exists-p nnultimate-directory)
 407     (gnus-make-directory nnultimate-directory)))
 408
 409 (defun nnultimate-generate-active ()
 410   (save-excursion
 411     (set-buffer nntp-server-buffer)
 412     (erase-buffer)
 413     (dolist (elem nnultimate-groups)
 414       (insert (prin1-to-string (car elem))
 415               " " (number-to-string (cadr elem)) " 1 y\n"))))
 416
 417 (defun nnultimate-find-forum-table (contents)
 418   (catch 'found
 419     (nnultimate-find-forum-table-1 contents)))
 420
 421 (defun nnultimate-find-forum-table-1 (contents)
 422   (dolist (element contents)
 423     (unless (stringp element)
 424       (when (and (eq (car element) 'table)
 425                  (nnultimate-forum-table-p element))
 426         (throw 'found element))
 427       (when (nth 2 element)
 428         (nnultimate-find-forum-table-1 (nth 2 element))))))
 429
 430 (defun nnultimate-forum-table-p (parse)
 431   (when (not (apply 'gnus-or
 432                     (mapcar
 433                      (lambda (p)
 434                        (nnweb-parse-find 'table p))
 435                      (nth 2 parse))))
 436     (let ((href (cdr (assq 'href (nth 1 (nnweb-parse-find 'a parse 20)))))
 437           case-fold-search)
 438       (when (and href (string-match
 439                        "postings\\|forumdisplay\\|Forum[0-9]+/HTML\\|getbio"
 440                                     href))
 441         t))))
 442
 443 (provide 'nnultimate)
 444
 445 ;;; nnultimate.el ends here