cgit.sxemacs.org Git - gnus/blob - lisp/nnultimate.el

   1 ;;; nnultimate.el --- interfacing with the Ultimate Bulletin Board system -*- coding: iso-latin-1 -*-
   2 ;; Copyright (C) 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Note: You need to have `url' and `w3' installed for this
  27 ;; backend to work.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'nnoo)
  34 (require 'message)
  35 (require 'gnus-util)
  36 (require 'gnus)
  37 (require 'nnmail)
  38 (require 'mm-util)
  39 (eval-when-compile
  40   (ignore-errors
  41     (require 'nnweb)))
  42 ;; Report failure to find w3 at load time if appropriate.
  43 (eval '(require 'nnweb))
  44
  45 (nnoo-declare nnultimate)
  46
  47 (defvoo nnultimate-directory (nnheader-concat gnus-directory "ultimate/")
  48   "Where nnultimate will save its files.")
  49
  50 (defvoo nnultimate-address ""
  51   "The address of the Ultimate bulletin board.")
  52
  53 ;;; Internal variables
  54
  55 (defvar nnultimate-groups-alist nil)
  56 (defvoo nnultimate-groups nil)
  57 (defvoo nnultimate-headers nil)
  58 (defvoo nnultimate-articles nil)
  59 (defvar nnultimate-table-regexp
  60   "postings.*editpost\\|forumdisplay\\|Forum[0-9]+/HTML\\|getbio")
  61
  62 ;;; Interface functions
  63
  64 (nnoo-define-basics nnultimate)
  65
  66 (deffoo nnultimate-retrieve-headers (articles &optional group server fetch-old)
  67   (nnultimate-possibly-change-server group server)
  68   (unless gnus-nov-is-evil
  69     (let* ((last (car (last articles)))
  70            (did nil)
  71            (start 1)
  72            (entry (assoc group nnultimate-groups))
  73            (sid (nth 2 entry))
  74            (topics (nth 4 entry))
  75            (mapping (nth 5 entry))
  76            (old-total (or (nth 6 entry) 1))
  77            (furl "forumdisplay.cgi?action=topics&number=%d&DaysPrune=1000")
  78            (furls (list (concat nnultimate-address (format furl sid))))
  79            (nnultimate-table-regexp
  80             "postings.*editpost\\|forumdisplay\\|getbio")
  81            headers article subject score from date lines parent point
  82            contents tinfo fetchers map elem a href garticles topic old-max
  83            inc datel table string current-page total-contents pages
  84            farticles forum-contents parse furl-fetched mmap farticle)
  85       (setq map mapping)
  86       (while (and (setq article (car articles))
  87                   map)
  88         (while (and map
  89                     (or (> article (caar map))
  90                         (< (cadar map) (caar map))))
  91           (pop map))
  92         (when (setq mmap (car map))
  93           (setq farticle -1)
  94           (while (and article
  95                       (<= article (nth 1 mmap)))
  96             ;; Do we already have a fetcher for this topic?
  97             (if (setq elem (assq (nth 2 mmap) fetchers))
  98                 ;; Yes, so we just add the spec to the end.
  99                 (nconc elem (list (cons article
 100                                         (+ (nth 3 mmap) (incf farticle)))))
 101               ;; No, so we add a new one.
 102               (push (list (nth 2 mmap)
 103                           (cons article
 104                                 (+ (nth 3 mmap) (incf farticle))))
 105                     fetchers))
 106             (pop articles)
 107             (setq article (car articles)))))
 108       ;; Now we have the mapping from/to Gnus/nnultimate article numbers,
 109       ;; so we start fetching the topics that we need to satisfy the
 110       ;; request.
 111       (if (not fetchers)
 112           (save-excursion
 113             (set-buffer nntp-server-buffer)
 114             (erase-buffer))
 115         (setq nnultimate-articles nil)
 116         (mm-with-unibyte-buffer
 117           (dolist (elem fetchers)
 118             (setq pages 1
 119                   current-page 1
 120                   total-contents nil)
 121             (while (<= current-page pages)
 122               (erase-buffer)
 123               (setq subject (nth 2 (assq (car elem) topics)))
 124               (setq href (nth 3 (assq (car elem) topics)))
 125               (if (= current-page 1)
 126                   (nnweb-insert href)
 127                 (string-match "\\.html$" href)
 128                 (nnweb-insert (concat (substring href 0 (match-beginning 0))
 129                                       "-" (number-to-string current-page)
 130                                       (match-string 0 href))))
 131               (goto-char (point-min))
 132               (setq contents
 133                     (ignore-errors (w3-parse-buffer (current-buffer))))
 134               (setq table (nnultimate-find-forum-table contents))
 135               (setq string (mapconcat 'identity (nnweb-text table) ""))
 136               (when (string-match "topic is \\([0-9]\\) pages" string)
 137                 (setq pages (string-to-number (match-string 1 string)))
 138                 (setcdr table nil)
 139                 (setq table (nnultimate-find-forum-table contents)))
 140               (setq contents (cdr (nth 2 (car (nth 2 table)))))
 141               (setq total-contents (nconc total-contents contents))
 142               (incf current-page))
 143             ;;(setq total-contents (nreverse total-contents))
 144             (dolist (art (cdr elem))
 145               (if (not (nth (1- (cdr art)) total-contents))
 146                   ()                    ;(debug)
 147                 (push (list (car art)
 148                             (nth (1- (cdr art)) total-contents)
 149                             subject)
 150                       nnultimate-articles)))))
 151         (setq nnultimate-articles
 152               (sort nnultimate-articles 'car-less-than-car))
 153         ;; Now we have all the articles, conveniently in an alist
 154         ;; where the key is the Gnus article number.
 155         (dolist (articlef nnultimate-articles)
 156           (setq article (nth 0 articlef)
 157                 contents (nth 1 articlef)
 158                 subject (nth 2 articlef))
 159           (setq from (mapconcat 'identity
 160                                 (nnweb-text (car (nth 2 contents)))
 161                                 " ")
 162                 datel (nnweb-text (nth 2 (car (cdr (nth 2 contents))))))
 163           (while datel
 164             (when (string-match "Posted" (car datel))
 165               (setq date (substring (car datel) (match-end 0))
 166                     datel nil))
 167             (pop datel))
 168           (setq date (delete "" (split-string date "[- \n\t\r \81 \81 \81 ]")))
 169           (if (or (member "AM" date)
 170                   (member "PM" date))
 171               (setq date (format "%s %s %s %s"
 172                                  (car (rassq (string-to-number (nth 0 date))
 173                                              parse-time-months))
 174                                  (nth 1 date) (nth 2 date) (nth 3 date)))
 175             (setq date (format "%s %s %s %s"
 176                                (car (rassq (string-to-number (nth 1 date))
 177                                            parse-time-months))
 178                                (nth 0 date) (nth 2 date) (nth 3 date))))
 179           (push
 180            (cons
 181             article
 182             (make-full-mail-header
 183              article subject
 184              from (or date "")
 185              (concat "<" (number-to-string sid) "%"
 186                      (number-to-string article)
 187                      "@ultimate>")
 188              "" 0
 189              (/ (length (mapconcat
 190                          'identity
 191                          (nnweb-text
 192                           (cdr (nth 2 (nth 1 (nth 2 contents)))))
 193                          ""))
 194                 70)
 195              nil nil))
 196            headers))
 197         (setq nnultimate-headers (sort headers 'car-less-than-car))
 198         (save-excursion
 199           (set-buffer nntp-server-buffer)
 200           (mm-with-unibyte-current-buffer
 201             (erase-buffer)
 202             (dolist (header nnultimate-headers)
 203               (nnheader-insert-nov (cdr header))))))
 204       'nov)))
 205
 206 (deffoo nnultimate-request-group (group &optional server dont-check)
 207   (nnultimate-possibly-change-server nil server)
 208   (when (not nnultimate-groups)
 209     (nnultimate-request-list))
 210   (unless dont-check
 211     (nnultimate-create-mapping group))
 212   (let ((elem (assoc group nnultimate-groups)))
 213     (cond
 214      ((not elem)
 215       (nnheader-report 'nnultimate "Group does not exist"))
 216      (t
 217       (nnheader-report 'nnultimate "Opened group %s" group)
 218       (nnheader-insert
 219        "211 %d %d %d %s\n" (cadr elem) 1 (cadr elem)
 220        (prin1-to-string group))))))
 221
 222 (deffoo nnultimate-request-close ()
 223   (setq nnultimate-groups-alist nil
 224         nnultimate-groups nil))
 225
 226 (deffoo nnultimate-request-article (article &optional group server buffer)
 227   (nnultimate-possibly-change-server group server)
 228   (let ((contents (cdr (assq article nnultimate-articles))))
 229     (setq contents (cddr (nth 2 (nth 1 (nth 2 (car contents))))))
 230     (when contents
 231       (save-excursion
 232         (set-buffer (or buffer nntp-server-buffer))
 233         (erase-buffer)
 234         (nnweb-insert-html (cons 'p (cons nil (list contents))))
 235         (goto-char (point-min))
 236         (insert "Content-Type: text/html\nMIME-Version: 1.0\n")
 237         (let ((header (cdr (assq article nnultimate-headers))))
 238           (mm-with-unibyte-current-buffer
 239             (nnheader-insert-header header)))
 240         (nnheader-report 'nnultimate "Fetched article %s" article)
 241         (cons group article)))))
 242
 243 (deffoo nnultimate-request-list (&optional server)
 244   (nnultimate-possibly-change-server nil server)
 245   (mm-with-unibyte-buffer
 246     (nnweb-insert
 247      (if (string-match "/$" nnultimate-address)
 248          (concat nnultimate-address "Ultimate.cgi")
 249        nnultimate-address))
 250     (let ((contents (nth 2 (car (nth 2
 251                                      (nnultimate-find-forum-table
 252                                       (w3-parse-buffer (current-buffer)))))))
 253           sid elem description articles a href group forum
 254           a1 a2)
 255       (dolist (row contents)
 256         (setq row (nth 2 row))
 257         (when (setq a (nnweb-parse-find 'a row))
 258           (setq group (car (last (nnweb-text a)))
 259                 href (cdr (assq 'href (nth 1 a))))
 260           (setq description (car (last (nnweb-text (nth 1 row)))))
 261           (setq a1 (car (last (nnweb-text (nth 2 row)))))
 262           (setq a2 (car (last (nnweb-text (nth 3 row)))))
 263           (when (string-match "^[0-9]+$" a1)
 264             (setq articles (string-to-number a1)))
 265           (when (and a2 (string-match "^[0-9]+$" a2))
 266             (setq articles (max articles (string-to-number a2))))
 267           (when href
 268             (string-match "number=\\([0-9]+\\)" href)
 269             (setq forum (string-to-number (match-string 1 href)))
 270             (if (setq elem (assoc group nnultimate-groups))
 271                 (setcar (cdr elem) articles)
 272               (push (list group articles forum description nil nil nil nil)
 273                     nnultimate-groups))))))
 274     (nnultimate-write-groups)
 275     (nnultimate-generate-active)
 276     t))
 277
 278 (deffoo nnultimate-request-newgroups (date &optional server)
 279   (nnultimate-possibly-change-server nil server)
 280   (nnultimate-generate-active)
 281   t)
 282
 283 (nnoo-define-skeleton nnultimate)
 284
 285 ;;; Internal functions
 286
 287 (defun nnultimate-prune-days (group time)
 288   "Compute the number of days to fetch info for."
 289   (let ((old-time (nth 7 (assoc group nnultimate-groups))))
 290     (if (null old-time)
 291         1000
 292       (- (time-to-days time) (time-to-days old-time)))))
 293
 294 (defun nnultimate-create-mapping (group)
 295   (let* ((entry (assoc group nnultimate-groups))
 296          (sid (nth 2 entry))
 297          (topics (nth 4 entry))
 298          (mapping (nth 5 entry))
 299          (old-total (or (nth 6 entry) 1))
 300          (current-time (current-time))
 301          (furl
 302           (concat "forumdisplay.cgi?action=topics&number=%d&DaysPrune="
 303                   (number-to-string
 304                    (nnultimate-prune-days group current-time))))
 305          (furls (list (concat nnultimate-address (format furl sid))))
 306          contents forum-contents furl-fetched a subject href
 307          garticles topic tinfo old-max inc parse)
 308     (mm-with-unibyte-buffer
 309       (while furls
 310         (erase-buffer)
 311         (nnweb-insert (pop furls))
 312         (goto-char (point-min))
 313         (setq parse (w3-parse-buffer (current-buffer)))
 314         (setq contents
 315               (cdr (nth 2 (car (nth 2 (nnultimate-find-forum-table
 316                                        parse))))))
 317         (setq forum-contents (nconc contents forum-contents))
 318         (unless furl-fetched
 319           (setq furl-fetched t)
 320           ;; On the first time through this loop, we find all the
 321           ;; forum URLs.
 322           (dolist (a (nnweb-parse-find-all 'a parse))
 323             (let ((href (cdr (assq 'href (nth 1 a)))))
 324               (when (and href
 325                          (string-match "forumdisplay.*startpoint" href))
 326                 (push href furls))))
 327           (setq furls (nreverse furls))))
 328       ;; The main idea here is to map Gnus article numbers to
 329       ;; nnultimate article numbers.  Say there are three topics in
 330       ;; this forum, the first with 4 articles, the seconds with 2,
 331       ;; and the third with 1.  Then this will translate into 7 Gnus
 332       ;; article numbers, where 1-4 comes from the first topic, 5-6
 333       ;; from the second and 7 from the third.  Now, then next time
 334       ;; the group is entered, there's 2 new articles in topic one
 335       ;; and 1 in topic three.  Then Gnus article number 8-9 be 5-6
 336       ;; in topic one and 10 will be the 2 in topic three.
 337       (dolist (row (nreverse forum-contents))
 338         (setq row (nth 2 row))
 339         (when (setq a (nnweb-parse-find 'a row))
 340           (setq subject (car (last (nnweb-text a)))
 341                 href (cdr (assq 'href (nth 1 a))))
 342           (let ((artlist (nreverse (nnweb-text row)))
 343                 art)
 344             (while (and (not art)
 345                         artlist)
 346               (when (string-match "^[0-9]+$" (car artlist))
 347                 (setq art (1+ (string-to-number (car artlist)))))
 348               (pop artlist))
 349             (setq garticles art))
 350           (when garticles
 351             (string-match "/\\([0-9]+\\).html" href)
 352             (setq topic (string-to-number (match-string 1 href)))
 353             (if (setq tinfo (assq topic topics))
 354                 (progn
 355                   (setq old-max (cadr tinfo))
 356                   (setcar (cdr tinfo) garticles))
 357               (setq old-max 0)
 358               (push (list topic garticles subject href) topics)
 359               (setcar (nthcdr 4 entry) topics))
 360             (when (not (= old-max garticles))
 361               (setq inc (- garticles old-max))
 362               (setq mapping (nconc mapping
 363                                    (list
 364                                     (list
 365                                      old-total (1- (incf old-total inc))
 366                                      topic (1+ old-max)))))
 367               (incf old-max inc)
 368               (setcar (nthcdr 5 entry) mapping)
 369               (setcar (nthcdr 6 entry) old-total))))))
 370     (setcar (nthcdr 7 entry) current-time)
 371     (setcar (nthcdr 1 entry) (1- old-total))
 372     (nnultimate-write-groups)
 373     mapping))
 374
 375 (defun nnultimate-possibly-change-server (&optional group server)
 376   (nnultimate-init server)
 377   (when (and server
 378              (not (nnultimate-server-opened server)))
 379     (nnultimate-open-server server))
 380   (unless nnultimate-groups-alist
 381     (nnultimate-read-groups)
 382     (setq nnultimate-groups (cdr (assoc nnultimate-address
 383                                         nnultimate-groups-alist)))))
 384
 385 (deffoo nnultimate-open-server (server &optional defs connectionless)
 386   (nnheader-init-server-buffer)
 387   (if (nnultimate-server-opened server)
 388       t
 389     (unless (assq 'nnultimate-address defs)
 390       (setq defs (append defs (list (list 'nnultimate-address server)))))
 391     (nnoo-change-server 'nnultimate server defs)))
 392
 393 (defun nnultimate-read-groups ()
 394   (setq nnultimate-groups-alist nil)
 395   (let ((file (expand-file-name "groups" nnultimate-directory)))
 396     (when (file-exists-p file)
 397       (mm-with-unibyte-buffer
 398         (insert-file-contents file)
 399         (goto-char (point-min))
 400         (setq nnultimate-groups-alist (read (current-buffer)))))))
 401
 402 (defun nnultimate-write-groups ()
 403   (setq nnultimate-groups-alist
 404         (delq (assoc nnultimate-address nnultimate-groups-alist)
 405               nnultimate-groups-alist))
 406   (push (cons nnultimate-address nnultimate-groups)
 407         nnultimate-groups-alist)
 408   (with-temp-file (expand-file-name "groups" nnultimate-directory)
 409     (prin1 nnultimate-groups-alist (current-buffer))))
 410
 411 (defun nnultimate-init (server)
 412   "Initialize buffers and such."
 413   (unless (file-exists-p nnultimate-directory)
 414     (gnus-make-directory nnultimate-directory)))
 415
 416 (defun nnultimate-generate-active ()
 417   (save-excursion
 418     (set-buffer nntp-server-buffer)
 419     (erase-buffer)
 420     (dolist (elem nnultimate-groups)
 421       (insert (prin1-to-string (car elem))
 422               " " (number-to-string (cadr elem)) " 1 y\n"))))
 423
 424 (defun nnultimate-find-forum-table (contents)
 425   (catch 'found
 426     (nnultimate-find-forum-table-1 contents)))
 427
 428 (defun nnultimate-find-forum-table-1 (contents)
 429   (dolist (element contents)
 430     (unless (stringp element)
 431       (when (and (eq (car element) 'table)
 432                  (nnultimate-forum-table-p element))
 433         (throw 'found element))
 434       (when (nth 2 element)
 435         (nnultimate-find-forum-table-1 (nth 2 element))))))
 436
 437 (defun nnultimate-forum-table-p (parse)
 438   (when (not (apply 'gnus-or
 439                     (mapcar
 440                      (lambda (p)
 441                        (nnweb-parse-find 'table p))
 442                      (nth 2 parse))))
 443     (let ((href (cdr (assq 'href (nth 1 (nnweb-parse-find 'a parse 20)))))
 444           case-fold-search)
 445       (when (and href (string-match nnultimate-table-regexp href))
 446         t))))
 447
 448 (provide 'nnultimate)
 449
 450 ;; Local Variables:
 451 ;; coding: iso-8859-1
 452 ;; End:
 453
 454 ;;; nnultimate.el ends here