cgit.sxemacs.org Git - gnus/blob - lisp/nntp.el

   1 ;;; Copyright (C) 1987,88,89,90,92,93,94,95,96 Free Software Foundation, Inc.
   2
   3 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   4 ;; Keywords: news
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'nnheader)
  27 (require 'nnoo)
  28 (require 'gnus-util)
  29
  30 (nnoo-declare nntp)
  31
  32 (eval-and-compile
  33   (unless (fboundp 'open-network-stream)
  34     (require 'tcp)))
  35
  36 (eval-when-compile (require 'cl))
  37
  38 (defvoo nntp-address nil
  39   "Address of the physical nntp server.")
  40
  41 (defvoo nntp-port-number "nntp"
  42   "Port number on the physical nntp server.")
  43
  44 (defvoo nntp-server-opened-hook '(nntp-send-mode-reader)
  45   "*Hook used for sending commands to the server at startup.
  46 The default value is `nntp-send-mode-reader', which makes an innd
  47 server spawn an nnrpd server.  Another useful function to put in this
  48 hook might be `nntp-send-authinfo', which will prompt for a password
  49 to allow posting from the server.  Note that this is only necessary to
  50 do on servers that use strict access control.")
  51
  52 (defvoo nntp-authinfo-function 'nntp-send-authinfo
  53   "Function used to send AUTHINFO to the server.")
  54
  55 (defvoo nntp-server-action-alist
  56   '(("nntpd 1\\.5\\.11t"
  57      (remove-hook 'nntp-server-opened-hook 'nntp-send-mode-reader))
  58     ("NNRP server Netscape"
  59      (setq nntp-server-list-active-group nil)))
  60   "Alist of regexps to match on server types and actions to be taken.
  61 For instance, if you want Gnus to beep every time you connect
  62 to innd, you could say something like:
  63
  64 \(setq nntp-server-action-alist
  65        '((\"innd\" (ding))))
  66
  67 You probably don't want to do that, though.")
  68
  69 (defvoo nntp-open-connection-function 'nntp-open-network-stream
  70   "*Function used for connecting to a remote system.
  71 It will be called with the buffer to output in.
  72
  73 Two pre-made functions are `nntp-open-network-stream', which is the
  74 default, and simply connects to some port or other on the remote
  75 system (see nntp-port-number).  The other are `nntp-open-rlogin', which
  76 does an rlogin on the remote system, and then does a telnet to the
  77 NNTP server available there (see nntp-rlogin-parameters) and `nntp-open-telnet' which
  78 telnets to a remote system, logs in and does the same")
  79
  80 (defvoo nntp-rlogin-parameters '("telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  81   "*Parameters to `nntp-open-login'.
  82 That function may be used as `nntp-open-server-function'.  In that
  83 case, this list will be used as the parameter list given to rsh.")
  84
  85 (defvoo nntp-rlogin-user-name nil
  86   "*User name on remote system when using the rlogin connect method.")
  87
  88 (defvoo nntp-telnet-parameters '("exec" "telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  89   "*Parameters to `nntp-open-telnet'.
  90 That function may be used as `nntp-open-server-function'.  In that
  91 case, this list will be executed as a command after logging in
  92 via telnet.")
  93
  94 (defvoo nntp-telnet-user-name nil
  95   "User name to log in via telnet with.")
  96
  97 (defvoo nntp-telnet-passwd nil
  98   "Password to use to log in via telnet with.")
  99
 100 (defvoo nntp-end-of-line "\r\n"
 101   "String to use on the end of lines when talking to the NNTP server.
 102 This is \"\\r\\n\" by default, but should be \"\\n\" when
 103 using rlogin or telnet to communicate with the server.")
 104
 105 (defvoo nntp-large-newsgroup 50
 106   "*The number of the articles which indicates a large newsgroup.
 107 If the number of the articles is greater than the value, verbose
 108 messages will be shown to indicate the current status.")
 109
 110 (defvoo nntp-maximum-request 400
 111   "*The maximum number of the requests sent to the NNTP server at one time.
 112 If Emacs hangs up while retrieving headers, set the variable to a
 113 lower value.")
 114
 115 (defvoo nntp-nov-is-evil nil
 116   "*If non-nil, nntp will never attempt to use XOVER when talking to the server.")
 117
 118 (defvoo nntp-xover-commands '("XOVER" "XOVERVIEW")
 119   "*List of strings that are used as commands to fetch NOV lines from a server.
 120 The strings are tried in turn until a positive response is gotten.  If
 121 none of the commands are successful, nntp will just grab headers one
 122 by one.")
 123
 124 (defvoo nntp-nov-gap 20
 125   "*Maximum allowed gap between two articles.
 126 If the gap between two consecutive articles is bigger than this
 127 variable, split the XOVER request into two requests.")
 128
 129 (defvoo nntp-connection-timeout nil
 130   "*Number of seconds to wait before an nntp connection times out.
 131 If this variable is nil, which is the default, no timers are set.")
 132
 133 (defvoo nntp-prepare-server-hook nil
 134   "*Hook run before a server is opened.
 135 If can be used to set up a server remotely, for instance.  Say you
 136 have an account at the machine \"other.machine\".  This machine has
 137 access to an NNTP server that you can't access locally.  You could
 138 then use this hook to rsh to the remote machine and start a proxy NNTP
 139 server there that you can connect to.  See also `nntp-open-connection-function'")
 140
 141 (defvoo nntp-warn-about-losing-connection t
 142   "*If non-nil, beep when a server closes connection.")
 143
 144 \f
 145
 146 ;;; Internal variables.
 147
 148 (defvar nntp-process-wait-for nil)
 149 (defvar nntp-process-to-buffer nil)
 150 (defvar nntp-process-callback nil)
 151 (defvar nntp-process-decode nil)
 152 (defvar nntp-process-start-point nil)
 153 (defvar nntp-inside-change-function nil)
 154
 155 (defvar nntp-connection-list nil)
 156
 157 (defvoo nntp-server-type nil)
 158 (defvoo nntp-connection-alist nil)
 159 (defvoo nntp-status-string "")
 160 (defconst nntp-version "nntp 5.0")
 161 (defvoo nntp-inhibit-erase nil)
 162
 163 (defvoo nntp-server-xover 'try)
 164 (defvoo nntp-server-list-active-group 'try)
 165
 166 (eval-and-compile
 167   (autoload 'nnmail-read-passwd "nnmail"))
 168
 169 \f
 170
 171 ;;; Interface functions.
 172
 173 (nnoo-define-basics nntp)
 174
 175 (deffoo nntp-retrieve-headers (articles &optional group server fetch-old)
 176   "Retrieve the headers of ARTICLES."
 177   (nntp-possibly-change-group group server)
 178   (save-excursion
 179     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 180     (erase-buffer)
 181     (if (and (not gnus-nov-is-evil)
 182              (not nntp-nov-is-evil)
 183              (nntp-retrieve-headers-with-xover articles fetch-old))
 184         ;; We successfully retrieved the headers via XOVER.
 185         'nov
 186       ;; XOVER didn't work, so we do it the hard, slow and inefficient
 187       ;; way.
 188       (let ((number (length articles))
 189             (count 0)
 190             (received 0)
 191             (last-point (point-min))
 192             (buf (nntp-find-connection-buffer nntp-server-buffer))
 193             (nntp-inhibit-erase t))
 194         ;; Send HEAD command.
 195         (while articles
 196           (nntp-send-command
 197            nil
 198            "HEAD" (if (numberp (car articles))
 199                       (int-to-string (car articles))
 200                     ;; `articles' is either a list of article numbers
 201                     ;; or a list of article IDs.
 202                     (car articles)))
 203           (setq articles (cdr articles)
 204                 count (1+ count))
 205           ;; Every 400 header requests we have to read the stream in
 206           ;; order to avoid deadlocks.
 207           (when (or (null articles)     ;All requests have been sent.
 208                     (zerop (% count nntp-maximum-request)))
 209             (nntp-accept-response)
 210             (while (progn
 211                      (progn
 212                        (set-buffer buf)
 213                        (goto-char last-point))
 214                      ;; Count replies.
 215                      (while (re-search-forward "^[0-9]" nil t)
 216                        (incf received))
 217                      (setq last-point (point))
 218                      (< received count))
 219               ;; If number of headers is greater than 100, give
 220               ;;  informative messages.
 221               (and (numberp nntp-large-newsgroup)
 222                    (> number nntp-large-newsgroup)
 223                    (zerop (% received 20))
 224                    (message "NNTP: Receiving headers... %d%%"
 225                             (/ (* received 100) number)))
 226               (nntp-accept-response))))
 227         ;; Wait for text of last command.
 228         (goto-char (point-max))
 229         (re-search-backward "^[0-9]" nil t)
 230         (when (looking-at "^[23]")
 231           (while (progn
 232                    (goto-char (- (point-max) 3))
 233                    (not (looking-at "^\\.\r?\n")))
 234             (nntp-accept-response)))
 235         (and (numberp nntp-large-newsgroup)
 236              (> number nntp-large-newsgroup)
 237              (message "NNTP: Receiving headers...done"))
 238
 239         ;; Now all of replies are received.  Fold continuation lines.
 240         (nnheader-fold-continuation-lines)
 241         ;; Remove all "\r"'s.
 242         (nnheader-strip-cr)
 243         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 244         'headers))))
 245
 246 (deffoo nntp-retrieve-groups (groups &optional server)
 247   "Retrieve group info on GROUPS."
 248   (nntp-possibly-change-group nil server)
 249   (save-excursion
 250     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 251     ;; The first time this is run, this variable is `try'.  So we
 252     ;; try.
 253     (when (eq nntp-server-list-active-group 'try)
 254       (nntp-try-list-active (car groups)))
 255     (erase-buffer)
 256     (let ((count 0)
 257           (received 0)
 258           (last-point (point-min))
 259           (nntp-inhibit-erase t)
 260           (command (if nntp-server-list-active-group "LIST ACTIVE" "GROUP")))
 261       (while groups
 262         ;; Send the command to the server.
 263         (nntp-send-command nil command (pop groups))
 264         (incf count)
 265         ;; Every 400 requests we have to read the stream in
 266         ;; order to avoid deadlocks.
 267         (when (or (null groups)         ;All requests have been sent.
 268                   (zerop (% count nntp-maximum-request)))
 269           (nntp-accept-response)
 270           (while (progn
 271                    (goto-char last-point)
 272                    ;; Count replies.
 273                    (while (re-search-forward "^[0-9]" nil t)
 274                      (incf received))
 275                    (setq last-point (point))
 276                    (< received count))
 277             (nntp-accept-response))))
 278
 279       ;; Wait for the reply from the final command.
 280       (goto-char (point-max))
 281       (re-search-backward "^[0-9]" nil t)
 282       (when (looking-at "^[23]")
 283         (while (progn
 284                  (goto-char (point-max))
 285                  (if (not nntp-server-list-active-group)
 286                      (not (re-search-backward "\r?\n" (- (point) 3) t))
 287                    (not (re-search-backward "^\\.\r?\n" (- (point) 4) t))))
 288           (nntp-accept-response)))
 289
 290       ;; Now all replies are received.  We remove CRs.
 291       (goto-char (point-min))
 292       (while (search-forward "\r" nil t)
 293         (replace-match "" t t))
 294
 295       (if (not nntp-server-list-active-group)
 296           (progn
 297             (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 298             'group)
 299         ;; We have read active entries, so we just delete the
 300         ;; superfluous gunk.
 301         (goto-char (point-min))
 302         (while (re-search-forward "^[.2-5]" nil t)
 303           (delete-region (match-beginning 0)
 304                          (progn (forward-line 1) (point))))
 305         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 306         'active))))
 307
 308 (defun nntp-try-list-active (group)
 309   (nntp-list-active-group group)
 310   (save-excursion
 311     (set-buffer nntp-server-buffer)
 312     (goto-char (point-min))
 313     (cond ((or (eobp)
 314                (looking-at "5[0-9]+"))
 315            (setq nntp-server-list-active-group nil))
 316           (t
 317            (setq nntp-server-list-active-group t)))))
 318
 319 (deffoo nntp-list-active-group (group &optional server)
 320   "Return the active info on GROUP (which can be a regexp."
 321   (nntp-possibly-change-group nil server)
 322   (nntp-send-command "^.*\r?\n" "LIST ACTIVE" group))
 323
 324 (deffoo nntp-request-article (article &optional group server buffer command)
 325   (nntp-possibly-change-group group server)
 326   (when (nntp-send-command-and-decode
 327          "\r?\n\\.\r?\n" "ARTICLE"
 328          (if (numberp article) (int-to-string article) article))
 329     (when (and buffer
 330                (not (equal buffer nntp-server-buffer)))
 331       (save-excursion
 332         (set-buffer nntp-server-buffer)
 333         (copy-to-buffer buffer (point-min) (point-max))
 334         (nntp-find-group-and-number)))
 335     (nntp-find-group-and-number)))
 336
 337 (deffoo nntp-request-head (article &optional group server)
 338   (nntp-possibly-change-group group server)
 339   (when (nntp-send-command-and-decode
 340          "\r\n\\.\r\n" "HEAD"
 341          (if (numberp article) (int-to-string article) article))
 342     (nntp-find-group-and-number)))
 343
 344 (deffoo nntp-request-body (article &optional group server)
 345   (nntp-possibly-change-group group server)
 346   (nntp-send-command-and-decode
 347    "\r?\n\\.\r?\n" "BODY"
 348    (if (numberp article) (int-to-string article) article)))
 349
 350 (deffoo nntp-request-group (group &optional server dont-check)
 351   (nntp-possibly-change-group nil server)
 352   (when (nntp-send-command "^2.*\n" "GROUP" group)
 353     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 354       (setcar (cddr entry) group))))
 355
 356 (deffoo nntp-close-group (group &optional server)
 357   t)
 358
 359 (deffoo nntp-server-opened (&optional server)
 360   "Say whether a connection to SERVER has been opened."
 361   (and (nnoo-current-server-p 'nntp server)
 362        nntp-server-buffer
 363        (gnus-buffer-live-p nntp-server-buffer)
 364        (nntp-find-connection nntp-server-buffer)))
 365
 366 (deffoo nntp-open-server (server &optional defs connectionless)
 367   (nnheader-init-server-buffer)
 368   (if (nntp-server-opened server)
 369       t
 370     (when (or (stringp (car defs))
 371               (numberp (car defs)))
 372       (setq defs (cons (list 'nntp-port-number (car defs)) (cdr defs))))
 373     (unless (assq 'nntp-address defs)
 374       (setq defs (append defs (list (list 'nntp-address server)))))
 375     (nnoo-change-server 'nntp server defs)
 376     (unless connectionless
 377       (or (nntp-find-connection nntp-server-buffer)
 378           (nntp-open-connection nntp-server-buffer)))))
 379
 380 (deffoo nntp-close-server (&optional server)
 381   (nntp-possibly-change-group nil server t)
 382   (let (process)
 383     (while (setq process (car (pop nntp-connection-alist)))
 384       (when (memq (process-status process) '(open run))
 385         (set-process-sentinel process nil)
 386         (nntp-send-string process "QUIT"))
 387       (when (buffer-name (process-buffer process))
 388         (kill-buffer (process-buffer process))))
 389     (nnoo-close-server 'nntp)))
 390
 391 (deffoo nntp-request-close ()
 392   (let (process)
 393     (while (setq process (pop nntp-connection-list))
 394       (when (memq (process-status process) '(open run))
 395         (set-process-sentinel process nil)
 396         (ignore-errors
 397           (nntp-send-string process "QUIT")))
 398       (when (buffer-name (process-buffer process))
 399         (kill-buffer (process-buffer process))))))
 400
 401 (deffoo nntp-request-list (&optional server)
 402   (nntp-possibly-change-group nil server)
 403   (nntp-send-command-and-decode "\r?\n\\.\r?\n" "LIST"))
 404
 405 (deffoo nntp-request-list-newsgroups (&optional server)
 406   (nntp-possibly-change-group nil server)
 407   (nntp-send-command "\r?\n\\.\r?\n" "LIST NEWSGROUPS"))
 408
 409 (deffoo nntp-request-newgroups (date &optional server)
 410   (nntp-possibly-change-group nil server)
 411   (save-excursion
 412     (set-buffer nntp-server-buffer)
 413     (let* ((date (timezone-parse-date date))
 414            (time-string
 415             (format "%s%02d%02d %s%s%s"
 416                     (substring (aref date 0) 2) (string-to-int (aref date 1))
 417                     (string-to-int (aref date 2)) (substring (aref date 3) 0 2)
 418                     (substring
 419                      (aref date 3) 3 5) (substring (aref date 3) 6 8))))
 420       (prog1
 421           (nntp-send-command "^\\.\r?\n" "NEWGROUPS" time-string)
 422         (nntp-decode-text)))))
 423
 424 (deffoo nntp-request-post (&optional server)
 425   (nntp-possibly-change-group nil server)
 426   (when (nntp-send-command "^[23].*\r?\n" "POST")
 427     (nntp-send-buffer "^[23].*\n")))
 428
 429 (deffoo nntp-request-type (group article)
 430   'news)
 431
 432 (deffoo nntp-asynchronous-p ()
 433   t)
 434
 435 ;;; Hooky functions.
 436
 437 (defun nntp-send-mode-reader ()
 438   "Send the MODE READER command to the nntp server.
 439 This function is supposed to be called from `nntp-server-opened-hook'.
 440 It will make innd servers spawn an nnrpd process to allow actual article
 441 reading."
 442   (nntp-send-command "^.*\r?\n" "MODE READER"))
 443
 444 (defun nntp-send-nosy-authinfo ()
 445   "Send the AUTHINFO to the nntp server.
 446 This function is supposed to be called from `nntp-server-opened-hook'.
 447 It will prompt for a password."
 448   (nntp-send-command
 449    "^.*\r?\n" "AUTHINFO USER"
 450    (read-string (format "NNTP (%s) user name: " nntp-address)))
 451   (nntp-send-command
 452    "^.*\r?\n" "AUTHINFO PASS"
 453    (nnmail-read-passwd "NNTP (%s) password: " nntp-address)))
 454
 455 (defun nntp-send-authinfo ()
 456   "Send the AUTHINFO to the nntp server.
 457 This function is supposed to be called from `nntp-server-opened-hook'.
 458 It will prompt for a password."
 459   (nntp-send-command "^.*\r?\n" "AUTHINFO USER" (user-login-name))
 460   (nntp-send-command
 461    "^.*\r?\n" "AUTHINFO PASS"
 462    (nnmail-read-passwd (format "NNTP (%s) password: " nntp-address))))
 463
 464 (defun nntp-send-authinfo-from-file ()
 465   "Send the AUTHINFO to the nntp server.
 466 This function is supposed to be called from `nntp-server-opened-hook'.
 467 It will prompt for a password."
 468   (when (file-exists-p "~/.nntp-authinfo")
 469     (nnheader-temp-write nil
 470       (insert-file-contents "~/.nntp-authinfo")
 471       (goto-char (point-min))
 472       (nntp-send-command "^.*\r?\n" "AUTHINFO USER" (user-login-name))
 473       (nntp-send-command
 474        "^.*\r?\n" "AUTHINFO PASS"
 475        (buffer-substring (point) (progn (end-of-line) (point)))))))
 476
 477 ;;; Internal functions.
 478
 479 (defun nntp-send-command (wait-for &rest strings)
 480   "Send STRINGS to server and wait until WAIT-FOR returns."
 481   (unless nnheader-callback-function
 482     (save-excursion
 483       (set-buffer nntp-server-buffer)
 484       (erase-buffer)))
 485   (nntp-retrieve-data
 486    (mapconcat 'identity strings " ")
 487    nntp-address nntp-port-number nntp-server-buffer
 488    wait-for nnheader-callback-function))
 489
 490 (defun nntp-send-command-nodelete (wait-for &rest strings)
 491   "Send STRINGS to server and wait until WAIT-FOR returns."
 492   (nntp-retrieve-data
 493    (mapconcat 'identity strings " ")
 494    nntp-address nntp-port-number nntp-server-buffer
 495    wait-for nnheader-callback-function))
 496
 497 (defun nntp-send-command-and-decode (wait-for &rest strings)
 498   "Send STRINGS to server and wait until WAIT-FOR returns."
 499   (unless nnheader-callback-function
 500     (save-excursion
 501       (set-buffer nntp-server-buffer)
 502       (erase-buffer)))
 503   (nntp-retrieve-data
 504    (mapconcat 'identity strings " ")
 505    nntp-address nntp-port-number nntp-server-buffer
 506    wait-for nnheader-callback-function t))
 507
 508 (defun nntp-send-buffer (wait-for)
 509   "Send the current buffer to server and wait until WAIT-FOR returns."
 510   (unless nnheader-callback-function
 511     (save-excursion
 512       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 513       (erase-buffer)))
 514   (nntp-encode-text)
 515   (process-send-region (nntp-find-connection nntp-server-buffer)
 516                        (point-min) (point-max))
 517   (nntp-retrieve-data
 518    nil nntp-address nntp-port-number nntp-server-buffer
 519    wait-for nnheader-callback-function))
 520
 521 (defun nntp-find-connection (buffer)
 522   "Find the connection delivering to BUFFER."
 523   (let ((alist nntp-connection-alist)
 524         (buffer (if (stringp buffer) (get-buffer buffer) buffer))
 525         process entry)
 526     (while (setq entry (pop alist))
 527       (when (eq buffer (cadr entry))
 528         (setq process (car entry)
 529               alist nil)))
 530     (when process
 531       (if (memq (process-status process) '(open run))
 532           process
 533         (when (buffer-name (process-buffer process))
 534           (kill-buffer (process-buffer process)))
 535         (setq nntp-connection-alist (delq entry nntp-connection-alist))
 536         nil))))
 537
 538 (defun nntp-find-connection-entry (buffer)
 539   "Return the entry for the connection to BUFFER."
 540   (assq (nntp-find-connection buffer) nntp-connection-alist))
 541
 542 (defun nntp-find-connection-buffer (buffer)
 543   "Return the process connection buffer tied to BUFFER."
 544   (let ((process (nntp-find-connection buffer)))
 545     (when process
 546       (process-buffer process))))
 547
 548 (defun nntp-make-process-buffer (buffer)
 549   "Create a new, fresh buffer usable for nntp process connections."
 550   (save-excursion
 551     (set-buffer
 552      (generate-new-buffer
 553       (format " *server %s %s %s*"
 554               nntp-address nntp-port-number
 555               (buffer-name (get-buffer buffer)))))
 556     (buffer-disable-undo (current-buffer))
 557     (set (make-local-variable 'after-change-functions) nil)
 558     (set (make-local-variable 'nntp-process-wait-for) nil)
 559     (set (make-local-variable 'nntp-process-callback) nil)
 560     (set (make-local-variable 'nntp-process-to-buffer) nil)
 561     (set (make-local-variable 'nntp-process-start-point) nil)
 562     (set (make-local-variable 'nntp-process-decode) nil)
 563     (current-buffer)))
 564
 565 (defun nntp-open-connection (buffer)
 566   "Open a connection to PORT on ADDRESS delivering output to BUFFER."
 567   (run-hooks 'nntp-prepare-server-hook)
 568   (let* ((pbuffer (nntp-make-process-buffer buffer))
 569          (process
 570           (ignore-errors
 571             (funcall nntp-open-connection-function pbuffer))))
 572     (when process
 573       (process-kill-without-query process)
 574       (nntp-wait-for process "^.*\n" buffer nil t)
 575       (if (memq (process-status process) '(open run))
 576           (prog1
 577               (caar (push (list process buffer nil) nntp-connection-alist))
 578             (push process nntp-connection-list)
 579             (save-excursion
 580               (set-buffer pbuffer)
 581               (nntp-read-server-type)
 582               (erase-buffer)
 583               (set-buffer nntp-server-buffer)
 584               (let ((nnheader-callback-function nil))
 585                 (run-hooks 'nntp-server-opened-hook))))
 586         (when (buffer-name (process-buffer process))
 587           (kill-buffer (process-buffer process)))
 588         nil))))
 589
 590 (defun nntp-open-network-stream (buffer)
 591   (open-network-stream "nntpd" buffer nntp-address nntp-port-number))
 592
 593 (defun nntp-read-server-type ()
 594   "Find out what the name of the server we have connected to is."
 595   ;; Wait for the status string to arrive.
 596   (setq nntp-server-type (buffer-string))
 597   (let ((alist nntp-server-action-alist)
 598         (case-fold-search t)
 599         entry)
 600     ;; Run server-specific commands.
 601     (while alist
 602       (setq entry (pop alist))
 603       (when (string-match (car entry) nntp-server-type)
 604         (if (and (listp (cadr entry))
 605                  (not (eq 'lambda (caadr entry))))
 606             (eval (cadr entry))
 607           (funcall (cadr entry)))))))
 608
 609 (defun nntp-after-change-function-callback (beg end len)
 610   (when nntp-process-callback
 611     (save-match-data
 612       (if (and (= beg (point-min))
 613                (memq (char-after beg) '(?4 ?5)))
 614           ;; Report back error messages.
 615           (save-excursion
 616             (goto-char beg)
 617             (if (looking-at "480")
 618                 (funcall nntp-authinfo-function)
 619               (nntp-snarf-error-message)
 620               (funcall nntp-process-callback nil)))
 621         (goto-char end)
 622         (when (and (> (point) nntp-process-start-point)
 623                    (re-search-backward nntp-process-wait-for
 624                                        nntp-process-start-point t))
 625           (when (buffer-name (get-buffer nntp-process-to-buffer))
 626             (let ((cur (current-buffer))
 627                   (start nntp-process-start-point))
 628               (save-excursion
 629                 (set-buffer (get-buffer nntp-process-to-buffer))
 630                 (goto-char (point-max))
 631                 (let ((b (point)))
 632                   (insert-buffer-substring cur start)
 633                   (narrow-to-region b (point-max))
 634                   (nntp-decode-text)
 635                   (widen)))))
 636           (goto-char end)
 637           (let ((callback nntp-process-callback)
 638                 (nntp-inside-change-function t))
 639             (setq nntp-process-callback nil)
 640             (save-excursion
 641               (funcall callback (buffer-name
 642                                  (get-buffer nntp-process-to-buffer))))))))))
 643
 644 (defun nntp-retrieve-data (command address port buffer
 645                                    &optional wait-for callback decode)
 646   "Use COMMAND to retrieve data into BUFFER from PORT on ADDRESS."
 647   (let ((process (or (nntp-find-connection buffer)
 648                      (nntp-open-connection buffer))))
 649     (if (not process)
 650         (nnheader-report 'nntp "Couldn't open connection to %s" address)
 651       (unless (or nntp-inhibit-erase nnheader-callback-function)
 652         (save-excursion
 653           (set-buffer (process-buffer process))
 654           (erase-buffer)))
 655       (when command
 656         (nntp-send-string process command))
 657       (cond
 658        ((eq callback 'ignore)
 659         t)
 660        ((and callback wait-for)
 661         (save-excursion
 662           (set-buffer (process-buffer process))
 663           (unless nntp-inside-change-function
 664             (erase-buffer))
 665           (setq nntp-process-decode decode
 666                 nntp-process-to-buffer buffer
 667                 nntp-process-wait-for wait-for
 668                 nntp-process-callback callback
 669                 nntp-process-start-point (point-max)
 670                 after-change-functions
 671                 (list 'nntp-after-change-function-callback)))
 672         t)
 673        (wait-for
 674         (nntp-wait-for process wait-for buffer decode))
 675        (t t)))))
 676
 677 (defun nntp-send-string (process string)
 678   "Send STRING to PROCESS."
 679   (process-send-string process (concat string nntp-end-of-line)))
 680
 681 (defun nntp-wait-for (process wait-for buffer &optional decode discard)
 682   "Wait for WAIT-FOR to arrive from PROCESS."
 683   (save-excursion
 684     (set-buffer (process-buffer process))
 685     (goto-char (point-min))
 686     (while (or (not (memq (following-char) '(?2 ?3 ?4 ?5)))
 687                (looking-at "480"))
 688       (when (looking-at "480")
 689         (erase-buffer)
 690         (funcall nntp-authinfo-function))
 691       (nntp-accept-process-output process)
 692       (goto-char (point-min)))
 693     (prog1
 694         (if (looking-at "[45]")
 695             (progn
 696               (nntp-snarf-error-message)
 697               nil)
 698           (goto-char (point-max))
 699           (while (not (re-search-backward wait-for nil t))
 700             (nntp-accept-process-output process)
 701             (goto-char (point-max)))
 702           (nntp-decode-text (not decode))
 703           (unless discard
 704             (save-excursion
 705               (set-buffer buffer)
 706               (goto-char (point-max))
 707               (insert-buffer-substring (process-buffer process))
 708               ;; Nix out "nntp reading...." message.
 709               (message "")
 710               t)))
 711       (unless discard
 712         (erase-buffer)))))
 713
 714 (defun nntp-snarf-error-message ()
 715   "Save the error message in the current buffer."
 716   (let ((message (buffer-string)))
 717     (while (string-match "[\r\n]+" message)
 718       (setq message (replace-match " " t t message)))
 719     (nnheader-report 'nntp message)
 720     message))
 721
 722 (defun nntp-accept-process-output (process)
 723   "Wait for output from PROCESS and message some dots."
 724   (save-excursion
 725     (set-buffer (or (nntp-find-connection-buffer nntp-server-buffer)
 726                     nntp-server-buffer))
 727     (let ((len (/ (point-max) 10000)))
 728       (unless (zerop len)
 729         (message "nntp reading%s" (make-string len ?.))))
 730     (accept-process-output process 1)))
 731
 732 (defun nntp-accept-response ()
 733   "Wait for output from the process that outputs to BUFFER."
 734   (nntp-accept-process-output (nntp-find-connection nntp-server-buffer)))
 735
 736 (defun nntp-possibly-change-group (group server &optional connectionless)
 737   (let ((nnheader-callback-function nil))
 738     (when server
 739       (or (nntp-server-opened server)
 740           (nntp-open-server server nil connectionless)))
 741
 742     (unless connectionless
 743       (or (nntp-find-connection nntp-server-buffer)
 744           (nntp-open-connection nntp-server-buffer))))
 745
 746   (when group
 747     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 748       (when (not (equal group (caddr entry)))
 749         (nntp-request-group group)
 750         (save-excursion
 751           (set-buffer nntp-server-buffer)
 752           (if nnheader-callback-function
 753               (progn
 754                 (goto-char (point-max))
 755                 (forward-line -1)
 756                 (gnus-delete-line))
 757             (erase-buffer)))))))
 758
 759 (defun nntp-decode-text (&optional cr-only)
 760   "Decode the text in the current buffer."
 761   (goto-char (point-min))
 762   (while (search-forward "\r" nil t)
 763     (delete-char -1))
 764   (unless cr-only
 765     ;; Remove trailing ".\n" end-of-transfer marker.
 766     (goto-char (point-max))
 767     (forward-line -1)
 768     (when (looking-at ".\n")
 769       (delete-char 2))
 770     ;; Delete status line.
 771     (goto-char (point-min))
 772     (delete-region (point) (progn (forward-line 1) (point)))
 773     ;; Remove "." -> ".." encoding.
 774     (while (search-forward "\n.." nil t)
 775       (delete-char -1))))
 776
 777 (defun nntp-encode-text ()
 778   "Encode the text in the current buffer."
 779   (save-excursion
 780     ;; Replace "." at beginning of line with "..".
 781     (goto-char (point-min))
 782     (while (re-search-forward "^\\." nil t)
 783       (insert "."))
 784     (goto-char (point-max))
 785     ;; Insert newline at the end of the buffer.
 786     (unless (bolp)
 787       (insert "\n"))
 788     ;; Insert `.' at end of buffer (end of text mark).
 789     (goto-char (point-max))
 790     (insert "." nntp-end-of-line)))
 791
 792 (defun nntp-retrieve-headers-with-xover (articles &optional fetch-old)
 793   (set-buffer nntp-server-buffer)
 794   (erase-buffer)
 795   (cond
 796
 797    ;; This server does not talk NOV.
 798    ((not nntp-server-xover)
 799     nil)
 800
 801    ;; We don't care about gaps.
 802    ((or (not nntp-nov-gap)
 803         fetch-old)
 804     (nntp-send-xover-command
 805      (if fetch-old
 806          (if (numberp fetch-old)
 807              (max 1 (- (car articles) fetch-old))
 808            1)
 809        (car articles))
 810      (car (last articles)) 'wait)
 811
 812     (goto-char (point-min))
 813     (when (looking-at "[1-5][0-9][0-9] ")
 814       (delete-region (point) (progn (forward-line 1) (point))))
 815     (while (search-forward "\r" nil t)
 816       (replace-match "" t t))
 817     (goto-char (point-max))
 818     (forward-line -1)
 819     (when (looking-at "\\.")
 820       (delete-region (point) (progn (forward-line 1) (point)))))
 821
 822    ;; We do it the hard way.  For each gap, an XOVER command is sent
 823    ;; to the server.  We do not wait for a reply from the server, we
 824    ;; just send them off as fast as we can.  That means that we have
 825    ;; to count the number of responses we get back to find out when we
 826    ;; have gotten all we asked for.
 827    ((numberp nntp-nov-gap)
 828     (let ((count 0)
 829           (received 0)
 830           (last-point (point-min))
 831           (buf nntp-server-buffer)
 832           ;;(process-buffer (nntp-find-connection (current-buffer))))
 833           first)
 834       ;; We have to check `nntp-server-xover'.  If it gets set to nil,
 835       ;; that means that the server does not understand XOVER, but we
 836       ;; won't know that until we try.
 837       (while (and nntp-server-xover articles)
 838         (setq first (car articles))
 839         ;; Search forward until we find a gap, or until we run out of
 840         ;; articles.
 841         (while (and (cdr articles)
 842                     (< (- (nth 1 articles) (car articles)) nntp-nov-gap))
 843           (setq articles (cdr articles)))
 844
 845         (when (nntp-send-xover-command first (car articles))
 846           (setq articles (cdr articles)
 847                 count (1+ count))
 848
 849           ;; Every 400 requests we have to read the stream in
 850           ;; order to avoid deadlocks.
 851           (when (or (null articles)     ;All requests have been sent.
 852                     (zerop (% count nntp-maximum-request)))
 853             (accept-process-output)
 854             ;; On some Emacs versions the preceding function has
 855             ;; a tendency to change the buffer.  Perhaps.  It's
 856             ;; quite difficult to reproduce, because it only
 857             ;; seems to happen once in a blue moon.
 858             (set-buffer buf)
 859             (while (progn
 860                      (goto-char last-point)
 861                      ;; Count replies.
 862                      (while (re-search-forward "^[0-9][0-9][0-9] " nil t)
 863                        (setq received (1+ received)))
 864                      (setq last-point (point))
 865                      (< received count))
 866               (accept-process-output)
 867               (set-buffer buf)))))
 868
 869       (when nntp-server-xover
 870         ;; Wait for the reply from the final command.
 871         (goto-char (point-max))
 872         (re-search-backward "^[0-9][0-9][0-9] " nil t)
 873         (when (looking-at "^[23]")
 874           (while (progn
 875                    (goto-char (point-max))
 876                    (forward-line -1)
 877                    (not (looking-at "^\\.\r?\n")))
 878             (nntp-accept-response)))
 879
 880         ;; We remove any "." lines and status lines.
 881         (goto-char (point-min))
 882         (while (search-forward "\r" nil t)
 883           (delete-char -1))
 884         (goto-char (point-min))
 885         (delete-matching-lines "^\\.$\\|^[1-5][0-9][0-9] ")
 886         ;;(copy-to-buffer nntp-server-buffer (point-min) (point-max))
 887         t))))
 888
 889   nntp-server-xover)
 890
 891 (defun nntp-send-xover-command (beg end &optional wait-for-reply)
 892   "Send the XOVER command to the server."
 893   (let ((range (format "%d-%d" beg end))
 894         (nntp-inhibit-erase t))
 895     (if (stringp nntp-server-xover)
 896         ;; If `nntp-server-xover' is a string, then we just send this
 897         ;; command.
 898         (if wait-for-reply
 899             (nntp-send-command-nodelete "\r?\n\\.\r?\n" nntp-server-xover range)
 900           ;; We do not wait for the reply.
 901           (nntp-send-command-nodelete "\r?\n\\.\r?\n" nntp-server-xover range))
 902       (let ((commands nntp-xover-commands))
 903         ;; `nntp-xover-commands' is a list of possible XOVER commands.
 904         ;; We try them all until we get at positive response.
 905         (while (and commands (eq nntp-server-xover 'try))
 906           (nntp-send-command-nodelete "\r?\n\\.\r?\n" (car commands) range)
 907           (save-excursion
 908             (set-buffer nntp-server-buffer)
 909             (goto-char (point-min))
 910             (and (looking-at "[23]")    ; No error message.
 911                  ;; We also have to look at the lines.  Some buggy
 912                  ;; servers give back simple lines with just the
 913                  ;; article number.  How... helpful.
 914                  (progn
 915                    (forward-line 1)
 916                    (looking-at "[0-9]+\t...")) ; More text after number.
 917                  (setq nntp-server-xover (car commands))))
 918           (setq commands (cdr commands)))
 919         ;; If none of the commands worked, we disable XOVER.
 920         (when (eq nntp-server-xover 'try)
 921           (save-excursion
 922             (set-buffer nntp-server-buffer)
 923             (erase-buffer)
 924             (setq nntp-server-xover nil)))
 925         nntp-server-xover))))
 926
 927 ;;; Alternative connection methods.
 928
 929 (defun nntp-wait-for-string (regexp)
 930   "Wait until string arrives in the buffer."
 931   (let ((buf (current-buffer)))
 932     (goto-char (point-min))
 933     (while (not (re-search-forward regexp nil t))
 934       (accept-process-output (nntp-find-connection nntp-server-buffer))
 935       (set-buffer buf)
 936       (goto-char (point-min)))))
 937
 938 (defun nntp-open-telnet (buffer)
 939   (save-excursion
 940     (set-buffer buffer)
 941     (erase-buffer)
 942     (let ((proc (start-process
 943                  "nntpd" buffer "telnet" "-8"))
 944           (case-fold-search t))
 945       (when (memq (process-status proc) '(open run))
 946         (process-send-string proc "set escape \^X\n")
 947         (process-send-string proc (concat "open " nntp-address "\n"))
 948         (nntp-wait-for-string "^\r*.?login:")
 949         (process-send-string
 950          proc (concat
 951                (or nntp-telnet-user-name
 952                    (setq nntp-telnet-user-name (read-string "login: ")))
 953                "\n"))
 954         (nntp-wait-for-string "^\r*.?password:")
 955         (process-send-string
 956          proc (concat
 957                (or nntp-telnet-passwd
 958                    (setq nntp-telnet-passwd
 959                          (nnmail-read-passwd "Password: ")))
 960                "\n"))
 961         (erase-buffer)
 962         (nntp-wait-for-string "bash\\|\$ *\r?$\\|> *\r?")
 963         (process-send-string
 964          proc (concat (mapconcat 'identity nntp-telnet-parameters " ") "\n"))
 965         (nntp-wait-for-string "^\r*200")
 966         (beginning-of-line)
 967         (delete-region (point-min) (point))
 968         (process-send-string proc "\^]")
 969         (nntp-wait-for-string "^telnet")
 970         (process-send-string proc "mode character\n")
 971         (accept-process-output proc 1)
 972         (sit-for 1)
 973         (goto-char (point-min))
 974         (forward-line 1)
 975         (delete-region (point) (point-max)))
 976       proc)))
 977
 978 (defun nntp-open-rlogin (buffer)
 979   "Open a connection to SERVER using rsh."
 980   (let ((proc (if nntp-rlogin-user-name
 981                   (start-process
 982                    "nntpd" buffer "rsh"
 983                    nntp-address "-l" nntp-rlogin-user-name
 984                    (mapconcat 'identity
 985                               nntp-rlogin-parameters " "))
 986                 (start-process
 987                  "nntpd" buffer "rsh" nntp-address
 988                  (mapconcat 'identity
 989                             nntp-rlogin-parameters " ")))))
 990     (set-buffer buffer)
 991     (nntp-wait-for-string "^\r*200")
 992     (beginning-of-line)
 993     (delete-region (point-min) (point))
 994     proc)
 995   )
 996
 997 (defun nntp-find-group-and-number ()
 998   (save-excursion
 999     (save-restriction
1000       (set-buffer nntp-server-buffer)
1001       (narrow-to-region (goto-char (point-min))
1002                         (or (search-forward "\n\n" nil t) (point-max)))
1003       (goto-char (point-min))
1004       ;; We first find the number by looking at the status line.
1005       (let ((number (and (looking-at "2[0-9][0-9] +\\([0-9]+\\) ")
1006                          (string-to-int
1007                           (buffer-substring (match-beginning 1)
1008                                             (match-end 1)))))
1009             group newsgroups xref)
1010         (and number (zerop number) (setq number nil))
1011         ;; Then we find the group name.
1012         (setq group
1013               (cond
1014                ;; If there is only one group in the Newsgroups header,
1015                ;; then it seems quite likely that this article comes
1016                ;; from that group, I'd say.
1017                ((and (setq newsgroups (mail-fetch-field "newsgroups"))
1018                      (not (string-match "," newsgroups)))
1019                 newsgroups)
1020                ;; If there is more than one group in the Newsgroups
1021                ;; header, then the Xref header should be filled out.
1022                ;; We hazard a guess that the group that has this
1023                ;; article number in the Xref header is the one we are
1024                ;; looking for.  This might very well be wrong if this
1025                ;; article happens to have the same number in several
1026                ;; groups, but that's life.
1027                ((and (setq xref (mail-fetch-field "xref"))
1028                      number
1029                      (string-match (format "\\([^ :]+\\):%d" number) xref))
1030                 (substring xref (match-beginning 1) (match-end 1)))
1031                (t "")))
1032         (when (string-match "\r" group)
1033           (setq group (substring group 0 (match-beginning 0))))
1034         (cons group number)))))
1035
1036 (provide 'nntp)
1037
1038 ;;; nntp.el ends here