cgit.sxemacs.org Git - gnus/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2 ;; Copyright (C) 1988,89,90,93,94,95,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nntp)
  31 (require 'timezone)
  32 (require 'nnoo)
  33 (eval-when-compile (require 'cl))
  34
  35 (nnoo-declare nnspool)
  36
  37 (defvoo nnspool-inews-program news-inews-program
  38   "Program to post news.
  39 This is most commonly `inews' or `injnews'.")
  40
  41 (defvoo nnspool-inews-switches '("-h" "-S")
  42   "Switches for nnspool-request-post to pass to `inews' for posting news.
  43 If you are using Cnews, you probably should set this variable to nil.")
  44
  45 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  46   "Local news spool directory.")
  47
  48 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  49   "Local news nov directory.")
  50
  51 (defvoo nnspool-lib-dir "/usr/lib/news/"
  52   "Where the local news library files are stored.")
  53
  54 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  55   "Local news active file.")
  56
  57 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  58   "Local news newsgroups file.")
  59
  60 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distributions")
  61   "Local news distributions file.")
  62
  63 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  64   "Local news history file.")
  65
  66 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  67   "Local news active date file.")
  68
  69 (defvoo nnspool-large-newsgroup 50
  70   "The number of the articles which indicates a large newsgroup.
  71 If the number of the articles is greater than the value, verbose
  72 messages will be shown to indicate the current status.")
  73
  74 (defvoo nnspool-nov-is-evil nil
  75   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  76
  77 (defconst nnspool-sift-nov-with-sed nil
  78   "If non-nil, use sed to get the relevant portion from the overview file.
  79 If nil, nnspool will load the entire file into a buffer and process it
  80 there.")
  81
  82 (defvoo nnspool-rejected-article-hook nil
  83   "*A hook that will be run when an article has been rejected by the server.")
  84
  85 \f
  86
  87 (defconst nnspool-version "nnspool 2.0"
  88   "Version numbers of this version of NNSPOOL.")
  89
  90 (defvoo nnspool-current-directory nil
  91   "Current news group directory.")
  92
  93 (defvoo nnspool-current-group nil)
  94 (defvoo nnspool-status-string "")
  95
  96 \f
  97 ;;; Interface functions.
  98
  99 (nnoo-define-basics nnspool)
 100
 101 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 102   "Retrieve the headers of ARTICLES."
 103   (save-excursion
 104     (set-buffer nntp-server-buffer)
 105     (erase-buffer)
 106     (when (nnspool-possibly-change-directory group)
 107       (let* ((number (length articles))
 108              (count 0)
 109              (default-directory nnspool-current-directory)
 110              (do-message (and (numberp nnspool-large-newsgroup)
 111                               (> number nnspool-large-newsgroup)))
 112              file beg article ag)
 113         (if (and (numberp (car articles))
 114                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 115             ;; We successfully retrieved the NOV headers.
 116             'nov
 117           ;; No NOV headers here, so we do it the hard way.
 118           (while (setq article (pop articles))
 119             (if (stringp article)
 120                 ;; This is a Message-ID.
 121                 (setq ag (nnspool-find-id article)
 122                       file (and ag (nnspool-article-pathname
 123                                     (car ag) (cdr ag)))
 124                       article (cdr ag))
 125               ;; This is an article in the current group.
 126               (setq file (int-to-string article)))
 127             ;; Insert the head of the article.
 128             (when (and file
 129                        (file-exists-p file))
 130               (insert "221 ")
 131               (princ article (current-buffer))
 132               (insert " Article retrieved.\n")
 133               (setq beg (point))
 134               (inline (nnheader-insert-head file))
 135               (goto-char beg)
 136               (search-forward "\n\n" nil t)
 137               (forward-char -1)
 138               (insert ".\n")
 139               (delete-region (point) (point-max)))
 140
 141             (and do-message
 142                  (zerop (% (incf count) 20))
 143                  (message "nnspool: Receiving headers... %d%%"
 144                           (/ (* count 100) number))))
 145
 146           (and do-message
 147                (message "nnspool: Receiving headers...done"))
 148
 149           ;; Fold continuation lines.
 150           (nnheader-fold-continuation-lines)
 151           'headers)))))
 152
 153 (deffoo nnspool-open-server (server &optional defs)
 154   (nnoo-change-server 'nnspool server defs)
 155   (cond
 156    ((not (file-exists-p nnspool-spool-directory))
 157     (nnspool-close-server)
 158     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 159                      nnspool-spool-directory))
 160    ((not (file-directory-p
 161           (directory-file-name
 162            (file-truename nnspool-spool-directory))))
 163     (nnspool-close-server)
 164     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 165    (t
 166     (nnheader-report 'nnspool "Opened server %s using directory %s"
 167                      server nnspool-spool-directory)
 168     t)))
 169
 170 (deffoo nnspool-request-article (id &optional group server buffer)
 171   "Select article by message ID (or number)."
 172   (nnspool-possibly-change-directory group)
 173   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 174         file ag)
 175     (if (stringp id)
 176         ;; This is a Message-ID.
 177         (when (setq ag (nnspool-find-id id))
 178           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 179       (setq file (nnspool-article-pathname nnspool-current-group id)))
 180     (and file
 181          (file-exists-p file)
 182          (not (file-directory-p file))
 183          (save-excursion (nnspool-find-file file))
 184          ;; We return the article number and group name.
 185          (if (numberp id)
 186              (cons nnspool-current-group id)
 187            ag))))
 188
 189 (deffoo nnspool-request-body (id &optional group server)
 190   "Select article body by message ID (or number)."
 191   (nnspool-possibly-change-directory group)
 192   (let ((res (nnspool-request-article id)))
 193     (when res
 194       (save-excursion
 195         (set-buffer nntp-server-buffer)
 196         (goto-char (point-min))
 197         (when (search-forward "\n\n" nil t)
 198           (delete-region (point-min) (point)))
 199         res))))
 200
 201 (deffoo nnspool-request-head (id &optional group server)
 202   "Select article head by message ID (or number)."
 203   (nnspool-possibly-change-directory group)
 204   (let ((res (nnspool-request-article id)))
 205     (when res
 206       (save-excursion
 207         (set-buffer nntp-server-buffer)
 208         (goto-char (point-min))
 209         (when (search-forward "\n\n" nil t)
 210           (delete-region (1- (point)) (point-max)))))
 211     res))
 212
 213 (deffoo nnspool-request-group (group &optional server dont-check)
 214   "Select news GROUP."
 215   (let ((pathname (nnspool-article-pathname group))
 216         dir)
 217     (if (not (file-directory-p pathname))
 218         (nnheader-report
 219          'nnspool "Invalid group name (no such directory): %s" group)
 220       (setq nnspool-current-directory pathname)
 221       (nnheader-report 'nnspool "Selected group %s" group)
 222       (if dont-check
 223           (progn
 224             (nnheader-report 'nnspool "Selected group %s" group)
 225             t)
 226         ;; Yes, completely empty spool directories *are* possible.
 227         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 228         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 229           (setq dir
 230                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 231         (if dir
 232             (nnheader-insert
 233              "211 %d %d %d %s\n" (length dir) (car dir)
 234              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 235              group)
 236           (nnheader-report 'nnspool "Empty group %s" group)
 237           (nnheader-insert "211 0 0 0 %s\n" group))))))
 238
 239 (deffoo nnspool-request-type (group &optional article)
 240   'news)
 241
 242 (deffoo nnspool-close-group (group &optional server)
 243   t)
 244
 245 (deffoo nnspool-request-list (&optional server)
 246   "List active newsgroups."
 247   (save-excursion
 248     (or (nnspool-find-file nnspool-active-file)
 249         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 250
 251 (deffoo nnspool-request-list-newsgroups (&optional server)
 252   "List newsgroups (defined in NNTP2)."
 253   (save-excursion
 254     (or (nnspool-find-file nnspool-newsgroups-file)
 255         (nnheader-report 'nnspool (nnheader-file-error
 256                                    nnspool-newsgroups-file)))))
 257
 258 (deffoo nnspool-request-list-distributions (&optional server)
 259   "List distributions (defined in NNTP2)."
 260   (save-excursion
 261     (or (nnspool-find-file nnspool-distributions-file)
 262         (nnheader-report 'nnspool (nnheader-file-error
 263                                    nnspool-distributions-file)))))
 264
 265 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 266 (deffoo nnspool-request-newgroups (date &optional server)
 267   "List groups created after DATE."
 268   (if (nnspool-find-file nnspool-active-times-file)
 269       (save-excursion
 270         ;; Find the last valid line.
 271         (goto-char (point-max))
 272         (while (and (not (looking-at
 273                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 274                     (zerop (forward-line -1))))
 275         (let ((seconds (nnspool-seconds-since-epoch date))
 276               groups)
 277           ;; Go through lines and add the latest groups to a list.
 278           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 279                       (progn
 280                         ;; We insert a .0 to make the list reader
 281                         ;; interpret the number as a float. It is far
 282                         ;; too big to be stored in a lisp integer.
 283                         (goto-char (1- (match-end 0)))
 284                         (insert ".0")
 285                         (> (progn
 286                              (goto-char (match-end 1))
 287                              (read (current-buffer)))
 288                            seconds))
 289                       (setq groups (cons (buffer-substring
 290                                           (match-beginning 1) (match-end 1))
 291                                          groups))
 292                       (zerop (forward-line -1))))
 293           (erase-buffer)
 294           (while groups
 295             (insert (car groups) " 0 0 y\n")
 296             (setq groups (cdr groups))))
 297         t)
 298     nil))
 299
 300 (deffoo nnspool-request-post (&optional server)
 301   "Post a new news in current buffer."
 302   (save-excursion
 303     (let* ((process-connection-type nil) ; t bugs out on Solaris
 304            (inews-buffer (generate-new-buffer " *nnspool post*"))
 305            (proc
 306             (condition-case err
 307                 (apply 'start-process "*nnspool inews*" inews-buffer
 308                        nnspool-inews-program nnspool-inews-switches)
 309               (error
 310                (nnheader-report 'nnspool "inews error: %S" err)))))
 311       (if (not proc)
 312           ;; The inews program failed.
 313           ()
 314         (nnheader-report 'nnspool "")
 315         (set-process-sentinel proc 'nnspool-inews-sentinel)
 316         (process-send-region proc (point-min) (point-max))
 317         ;; We slap a condition-case around this, because the process may
 318         ;; have exited already...
 319         (condition-case nil
 320             (process-send-eof proc)
 321           (error nil))
 322         t))))
 323
 324
 325 \f
 326 ;;; Internal functions.
 327
 328 (defun nnspool-inews-sentinel (proc status)
 329   (save-excursion
 330     (set-buffer (process-buffer proc))
 331     (goto-char (point-min))
 332     (if (or (zerop (buffer-size))
 333             (search-forward "spooled" nil t))
 334         (kill-buffer (current-buffer))
 335       ;; Make status message by folding lines.
 336       (while (re-search-forward "[ \t\n]+" nil t)
 337         (replace-match " " t t))
 338       (nnheader-report 'nnspool "%s" (buffer-string))
 339       (message "nnspool: %s" nnspool-status-string)
 340       (ding)
 341       (run-hooks 'nnspool-rejected-article-hook))))
 342
 343 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 344   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 345       nil
 346     (let ((nov (nnheader-group-pathname
 347                 nnspool-current-group nnspool-nov-directory ".overview"))
 348           (arts articles)
 349           last)
 350       (if (not (file-exists-p nov))
 351           ()
 352         (save-excursion
 353           (set-buffer nntp-server-buffer)
 354           (erase-buffer)
 355           (if nnspool-sift-nov-with-sed
 356               (nnspool-sift-nov-with-sed articles nov)
 357             (insert-file-contents nov)
 358             (if (and fetch-old
 359                      (not (numberp fetch-old)))
 360                 t                       ; We want all the headers.
 361               ;; First we find the first wanted line.
 362               (nnspool-find-nov-line
 363                (if fetch-old (max 1 (- (car articles) fetch-old))
 364                  (car articles)))
 365               (delete-region (point-min) (point))
 366               ;; Then we find the last wanted line.
 367               (if (nnspool-find-nov-line
 368                    (progn (while (cdr articles) (setq articles (cdr articles)))
 369                           (car articles)))
 370                   (forward-line 1))
 371               (delete-region (point) (point-max))
 372               ;; If the buffer is empty, this wasn't very successful.
 373               (unless (zerop (buffer-size))
 374                 ;; We check what the last article number was.  The NOV file
 375                 ;; may be out of sync with the articles in the group.
 376                 (forward-line -1)
 377                 (setq last (read (current-buffer)))
 378                 (if (= last (car articles))
 379                     ;; Yup, it's all there.
 380                     t
 381                   ;; Perhaps not.  We try to find the missing articles.
 382                   (while (and arts
 383                               (<= last (car arts)))
 384                     (pop arts))
 385                   ;; The articles in `arts' are missing from the buffer.
 386                   (while arts
 387                     (nnspool-insert-nov-head (pop arts)))
 388                   t)))))))))
 389
 390 (defun nnspool-insert-nov-head (article)
 391   "Read the head of ARTICLE, convert to NOV headers, and insert."
 392   (save-excursion
 393     (let ((cur (current-buffer))
 394           buf)
 395       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 396       (when (nnheader-insert-head
 397              (nnspool-article-pathname nnspool-current-group article))
 398         (nnheader-insert-article-line article)
 399         (let ((headers (nnheader-parse-head)))
 400           (set-buffer cur)
 401           (goto-char (point-max))
 402           (nnheader-insert-nov headers)))
 403       (kill-buffer buf))))
 404
 405 (defun nnspool-find-nov-line (article)
 406   (let ((max (point-max))
 407         (min (goto-char (point-min)))
 408         (cur (current-buffer))
 409         (prev (point-min))
 410         num found)
 411     (while (not found)
 412       (goto-char (/ (+ max min) 2))
 413       (beginning-of-line)
 414       (if (or (= (point) prev)
 415               (eobp))
 416           (setq found t)
 417         (setq prev (point))
 418         (cond ((> (setq num (read cur)) article)
 419                (setq max (point)))
 420               ((< num article)
 421                (setq min (point)))
 422               (t
 423                (setq found 'yes)))))
 424     ;; Now we may have found the article we're looking for, or we
 425     ;; may be somewhere near it.
 426     (when (and (not (eq found 'yes))
 427                (not (eq num article)))
 428       (setq found (point))
 429       (while (and (< (point) max)
 430                   (or (not (numberp num))
 431                       (< num article)))
 432         (forward-line 1)
 433         (setq found (point))
 434         (or (eobp)
 435             (= (setq num (read cur)) article)))
 436       (unless (eq num article)
 437         (goto-char found)))
 438     (beginning-of-line)
 439     (eq num article)))
 440
 441 (defun nnspool-sift-nov-with-sed (articles file)
 442   (let ((first (car articles))
 443         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 444                      (car articles))))
 445     (call-process "awk" nil t nil
 446                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 447                           (1- first) (1+ last))
 448                   file)))
 449
 450 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 451 ;; Find out what group an article identified by a Message-ID is in.
 452 (defun nnspool-find-id (id)
 453   (save-excursion
 454     (set-buffer (get-buffer-create " *nnspool work*"))
 455     (buffer-disable-undo (current-buffer))
 456     (erase-buffer)
 457     (condition-case ()
 458         (call-process "grep" nil t nil id nnspool-history-file)
 459       (error nil))
 460     (goto-char (point-min))
 461     (prog1
 462         (if (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 463             (cons (match-string 1) (string-to-int (match-string 2))))
 464       (kill-buffer (current-buffer)))))
 465
 466 (defun nnspool-find-file (file)
 467   "Insert FILE in server buffer safely."
 468   (set-buffer nntp-server-buffer)
 469   (erase-buffer)
 470   (condition-case ()
 471       (progn (nnheader-insert-raw-file-contents file) t)
 472     (file-error nil)))
 473
 474 (defun nnspool-possibly-change-directory (group)
 475   (if (not group)
 476       t
 477     (let ((pathname (nnspool-article-pathname group)))
 478       (if (file-directory-p pathname)
 479           (setq nnspool-current-directory pathname
 480                 nnspool-current-group group)
 481         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 482
 483 (defun nnspool-article-pathname (group &optional article)
 484   "Find the path for GROUP."
 485   (nnheader-group-pathname group nnspool-spool-directory article))
 486
 487 (defun nnspool-seconds-since-epoch (date)
 488   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 489                         (timezone-parse-date date)))
 490          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 491                         (timezone-parse-time
 492                          (aref (timezone-parse-date date) 3))))
 493          (unix (encode-time (nth 2 ttime) (nth 1 ttime) (nth 0 ttime)
 494                             (nth 2 tdate) (nth 1 tdate) (nth 0 tdate)
 495                             (nth 4 tdate))))
 496     (+ (* (car unix) 65536.0)
 497        (cadr unix))))
 498
 499 (provide 'nnspool)
 500
 501 ;;; nnspool.el ends here