cgit.sxemacs.org Git - gnus/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (require 'cl)
  37
  38 (nnoo-declare nnml)
  39
  40 (defvoo nnml-directory message-directory
  41   "Mail spool directory.")
  42
  43 (defvoo nnml-active-file
  44   (concat (file-name-as-directory nnml-directory) "active")
  45   "Mail active file.")
  46
  47 (defvoo nnml-newsgroups-file
  48   (concat (file-name-as-directory nnml-directory) "newsgroups")
  49   "Mail newsgroups description file.")
  50
  51 (defvoo nnml-get-new-mail t
  52   "If non-nil, nnml will check the incoming mail file and split the mail.")
  53
  54 (defvoo nnml-nov-is-evil nil
  55   "If non-nil, Gnus will never generate and use nov databases for mail groups.
  56 Using nov databases will speed up header fetching considerably.
  57 This variable shouldn't be flipped much.  If you have, for some reason,
  58 set this to t, and want to set it to nil again, you should always run
  59 the `nnml-generate-nov-databases' command.  The function will go
  60 through all nnml directories and generate nov databases for them
  61 all.  This may very well take some time.")
  62
  63 (defvoo nnml-prepare-save-mail-hook nil
  64   "Hook run narrowed to an article before saving.")
  65
  66 (defvoo nnml-inhibit-expiry nil
  67   "If non-nil, inhibit expiry.")
  68
  69
  70 \f
  71
  72 (defconst nnml-version "nnml 1.0"
  73   "nnml version.")
  74
  75 (defvoo nnml-nov-file-name ".overview")
  76
  77 (defvoo nnml-current-directory nil)
  78 (defvoo nnml-current-group nil)
  79 (defvoo nnml-status-string "")
  80 (defvoo nnml-nov-buffer-alist nil)
  81 (defvoo nnml-group-alist nil)
  82 (defvoo nnml-active-timestamp nil)
  83 (defvoo nnml-article-file-alist nil)
  84
  85 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
  86
  87 \f
  88
  89 ;;; Interface functions.
  90
  91 (nnoo-define-basics nnml)
  92
  93 (deffoo nnml-retrieve-headers (sequence &optional newsgroup server fetch-old)
  94   (save-excursion
  95     (set-buffer nntp-server-buffer)
  96     (erase-buffer)
  97     (let ((file nil)
  98           (number (length sequence))
  99           (count 0)
 100           beg article)
 101       (if (stringp (car sequence))
 102           'headers
 103         (nnml-possibly-change-directory newsgroup server)
 104         (unless nnml-article-file-alist
 105           (setq nnml-article-file-alist
 106                 (nnheader-article-to-file-alist nnml-current-directory)))
 107         (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 108             'nov
 109           (while sequence
 110             (setq article (car sequence))
 111             (setq file
 112                   (concat nnml-current-directory
 113                           (or (cdr (assq article nnml-article-file-alist))
 114                               "")))
 115             (if (and (file-exists-p file)
 116                      (not (file-directory-p file)))
 117                 (progn
 118                   (insert (format "221 %d Article retrieved.\n" article))
 119                   (setq beg (point))
 120                   (nnheader-insert-head file)
 121                   (goto-char beg)
 122                   (if (search-forward "\n\n" nil t)
 123                       (forward-char -1)
 124                     (goto-char (point-max))
 125                     (insert "\n\n"))
 126                   (insert ".\n")
 127                   (delete-region (point) (point-max))))
 128             (setq sequence (cdr sequence))
 129             (setq count (1+ count))
 130             (and (numberp nnmail-large-newsgroup)
 131                  (> number nnmail-large-newsgroup)
 132                  (zerop (% count 20))
 133                  (nnheader-message 6 "nnml: Receiving headers... %d%%"
 134                                    (/ (* count 100) number))))
 135
 136           (and (numberp nnmail-large-newsgroup)
 137                (> number nnmail-large-newsgroup)
 138                (nnheader-message 6 "nnml: Receiving headers...done"))
 139
 140           (nnheader-fold-continuation-lines)
 141           'headers)))))
 142
 143 (deffoo nnml-open-server (server &optional defs)
 144   (nnoo-change-server 'nnml server defs)
 145   (when (not (file-exists-p nnml-directory))
 146     (condition-case ()
 147         (make-directory nnml-directory t)
 148       (error t)))
 149   (cond
 150    ((not (file-exists-p nnml-directory))
 151     (nnml-close-server)
 152     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 153    ((not (file-directory-p (file-truename nnml-directory)))
 154     (nnml-close-server)
 155     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 156    (t
 157     (nnheader-report 'nnml "Opened server %s using directory %s"
 158                      server nnml-directory)
 159     t)))
 160
 161 (deffoo nnml-request-article (id &optional newsgroup server buffer)
 162   (nnml-possibly-change-directory newsgroup server)
 163   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 164          path gpath group-num)
 165     (if (stringp id)
 166         (when (and (setq group-num (nnml-find-group-number id))
 167                    (cdr
 168                     (assq (cdr group-num)
 169                           (nnheader-article-to-file-alist
 170                            (setq gpath
 171                                  (nnmail-group-pathname
 172                                   (car group-num)
 173                                   nnml-directory))))))
 174           (setq path (concat gpath (int-to-string (cdr group-num)))))
 175       (setq path (nnml-article-to-file id)))
 176     (cond
 177      ((not path)
 178       (nnheader-report 'nnml "No such article: %s" id))
 179      ((not (file-exists-p path))
 180       (nnheader-report 'nnml "No such file: %s" path))
 181      ((file-directory-p path)
 182       (nnheader-report 'nnml "File is a directory: %s" path))
 183      ((not (save-excursion (nnmail-find-file path)))
 184       (nnheader-report 'nnml "Couldn't read file: %s" path))
 185      (t
 186       (nnheader-report 'nnml "Article %s retrieved" id)
 187       ;; We return the article number.
 188       (cons newsgroup (string-to-int (file-name-nondirectory path)))))))
 189
 190 (deffoo nnml-request-group (group &optional server dont-check)
 191   (cond
 192    ((not (nnml-possibly-change-directory group server))
 193     (nnheader-report 'nnml "Invalid group (no such directory)"))
 194    ((not (file-exists-p nnml-current-directory))
 195     (nnheader-report 'nnml "Directory %s does not exist"
 196                      nnml-current-directory))
 197    ((not (file-directory-p nnml-current-directory))
 198     (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 199    (dont-check
 200     (nnheader-report 'nnml "Group %s selected" group)
 201     t)
 202    (t
 203     (nnmail-activate 'nnml)
 204     (let ((active (nth 1 (assoc group nnml-group-alist))))
 205       (if (not active)
 206           (nnheader-report 'nnml "No such group: %s" group)
 207         (nnheader-report 'nnml "Selected group %s" group)
 208         (nnheader-insert "211 %d %d %d %s\n"
 209                          (max (1+ (- (cdr active) (car active))) 0)
 210                          (car active) (cdr active) group))))))
 211
 212 (deffoo nnml-request-scan (&optional group server)
 213   (setq nnml-article-file-alist nil)
 214   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 215
 216 (deffoo nnml-close-group (group &optional server)
 217   (setq nnml-article-file-alist nil)
 218   t)
 219
 220 (deffoo nnml-request-create-group (group &optional server)
 221   (nnmail-activate 'nnml)
 222   (or (assoc group nnml-group-alist)
 223       (let (active)
 224         (setq nnml-group-alist (cons (list group (setq active (cons 1 0)))
 225                                      nnml-group-alist))
 226         (nnml-possibly-create-directory group)
 227         (nnml-possibly-change-directory group server)
 228         (let ((articles
 229                (nnheader-directory-articles nnml-current-directory )))
 230           (and articles
 231                (progn
 232                  (setcar active (apply 'min articles))
 233                  (setcdr active (apply 'max articles)))))
 234         (nnmail-save-active nnml-group-alist nnml-active-file)))
 235   t)
 236
 237 (deffoo nnml-request-list (&optional server)
 238   (save-excursion
 239     (nnmail-find-file nnml-active-file)
 240     (setq nnml-group-alist (nnmail-get-active))))
 241
 242 (deffoo nnml-request-newgroups (date &optional server)
 243   (nnml-request-list server))
 244
 245 (deffoo nnml-request-list-newsgroups (&optional server)
 246   (save-excursion
 247     (nnmail-find-file nnml-newsgroups-file)))
 248
 249 (deffoo nnml-request-expire-articles (articles newsgroup &optional server force)
 250   (nnml-possibly-change-directory newsgroup server)
 251   (let* ((active-articles
 252           (nnheader-directory-articles nnml-current-directory))
 253          (is-old t)
 254          article rest mod-time number)
 255     (nnmail-activate 'nnml)
 256
 257     (unless nnml-article-file-alist
 258       (setq nnml-article-file-alist
 259             (nnheader-article-to-file-alist nnml-current-directory)))
 260
 261     (while (and articles is-old)
 262       (setq article (concat nnml-current-directory
 263                             (int-to-string
 264                              (setq number (pop articles)))))
 265       (when (setq mod-time (nth 5 (file-attributes article)))
 266         (if (and (nnml-deletable-article-p newsgroup number)
 267                  (setq is-old
 268                        (nnmail-expired-article-p newsgroup mod-time force
 269                                                  nnml-inhibit-expiry)))
 270             (progn
 271               (nnheader-message 5 "Deleting article %s in %s..."
 272                                 article newsgroup)
 273               (condition-case ()
 274                   (funcall nnmail-delete-file-function article)
 275                 (file-error
 276                  (push number rest)))
 277               (setq active-articles (delq number active-articles))
 278               (nnml-nov-delete-article newsgroup number))
 279           (push number rest))))
 280     (let ((active (nth 1 (assoc newsgroup nnml-group-alist))))
 281       (when active
 282         (setcar active (or (and active-articles
 283                                 (apply 'min active-articles))
 284                            (1+ (cdr active)))))
 285       (nnmail-save-active nnml-group-alist nnml-active-file))
 286     (nnml-save-nov)
 287     (message "")
 288     (nconc rest articles)))
 289
 290 (deffoo nnml-request-move-article
 291   (article group server accept-form &optional last)
 292   (let ((buf (get-buffer-create " *nnml move*"))
 293         result)
 294     (nnml-possibly-change-directory group server)
 295     (unless nnml-article-file-alist
 296       (setq nnml-article-file-alist
 297             (nnheader-article-to-file-alist nnml-current-directory)))
 298     (and
 299      (nnml-deletable-article-p group article)
 300      (nnml-request-article article group server)
 301      (save-excursion
 302        (set-buffer buf)
 303        (insert-buffer-substring nntp-server-buffer)
 304        (setq result (eval accept-form))
 305        (kill-buffer (current-buffer))
 306        result)
 307      (progn
 308        (nnml-possibly-change-directory group server)
 309        (condition-case ()
 310            (funcall nnmail-delete-file-function
 311                     (concat nnml-current-directory
 312                             (int-to-string article)))
 313          (file-error nil))
 314        (nnml-nov-delete-article group article)
 315        (and last (nnml-save-nov))))
 316     result))
 317
 318 (deffoo nnml-request-accept-article (group &optional server last)
 319   (nnml-possibly-change-directory group server)
 320   (nnmail-check-syntax)
 321   (let (result)
 322     (if (stringp group)
 323         (and
 324          (nnmail-activate 'nnml)
 325          (setq result (car (nnml-save-mail
 326                             (list (cons group (nnml-active-number group))))))
 327          (progn
 328            (nnmail-save-active nnml-group-alist nnml-active-file)
 329            (and last (nnml-save-nov))))
 330       (and
 331        (nnmail-activate 'nnml)
 332        (setq result (car (nnml-save-mail
 333                           (nnmail-article-group 'nnml-active-number))))
 334        (progn
 335          (nnmail-save-active nnml-group-alist nnml-active-file)
 336          (and last (nnml-save-nov)))))
 337     result))
 338
 339 (deffoo nnml-request-replace-article (article group buffer)
 340   (nnml-possibly-change-directory group)
 341   (save-excursion
 342     (set-buffer buffer)
 343     (nnml-possibly-create-directory group)
 344     (let ((chars (nnmail-insert-lines))
 345           (art (concat (int-to-string article) "\t"))
 346           headers)
 347       (when (condition-case ()
 348                 (progn
 349                   (nnmail-write-region
 350                    (point-min) (point-max)
 351                    (concat nnml-current-directory
 352                            (int-to-string article))
 353                    nil (if (nnheader-be-verbose 5) nil 'nomesg))
 354                   t)
 355               (error nil))
 356         (setq headers (nnml-parse-head chars article))
 357         ;; Replace the NOV line in the NOV file.
 358         (save-excursion
 359           (set-buffer (nnml-open-nov group))
 360           (goto-char (point-min))
 361           (if (or (looking-at art)
 362                   (search-forward (concat "\n" art) nil t))
 363               ;; Delete the old NOV line.
 364               (delete-region (progn (beginning-of-line) (point))
 365                              (progn (forward-line 1) (point)))
 366             ;; The line isn't here, so we have to find out where
 367             ;; we should insert it.  (This situation should never
 368             ;; occur, but one likes to make sure...)
 369             (while (and (looking-at "[0-9]+\t")
 370                         (< (string-to-int
 371                             (buffer-substring
 372                              (match-beginning 0) (match-end 0)))
 373                            article)
 374                         (zerop (forward-line 1)))))
 375           (beginning-of-line)
 376           (nnheader-insert-nov headers)
 377           (nnml-save-nov)
 378           t)))))
 379
 380 (deffoo nnml-request-delete-group (group &optional force server)
 381   (nnml-possibly-change-directory group server)
 382   (when force
 383     ;; Delete all articles in GROUP.
 384     (let ((articles
 385            (directory-files
 386             nnml-current-directory t
 387             (concat nnheader-numerical-short-files
 388                     "\\|" (regexp-quote nnml-nov-file-name) "$")))
 389           article)
 390       (while articles
 391         (setq article (pop articles))
 392         (when (file-writable-p article)
 393           (nnheader-message 5 "Deleting article %s in %s..." article group)
 394           (funcall nnmail-delete-file-function article))))
 395     ;; Try to delete the directory itself.
 396     (condition-case ()
 397         (delete-directory nnml-current-directory)
 398       (error nil)))
 399   ;; Remove the group from all structures.
 400   (setq nnml-group-alist
 401         (delq (assoc group nnml-group-alist) nnml-group-alist)
 402         nnml-current-group nil
 403         nnml-current-directory nil)
 404   ;; Save the active file.
 405   (nnmail-save-active nnml-group-alist nnml-active-file)
 406   t)
 407
 408 (deffoo nnml-request-rename-group (group new-name &optional server)
 409   (nnml-possibly-change-directory group server)
 410   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 411         (old-dir (nnmail-group-pathname group nnml-directory)))
 412     (when (condition-case ()
 413               (progn
 414                 (make-directory new-dir t)
 415                 t)
 416             (error nil))
 417       ;; We move the articles file by file instead of renaming
 418       ;; the directory -- there may be subgroups in this group.
 419       ;; One might be more clever, I guess.
 420       (let ((files (nnheader-article-to-file-alist old-dir)))
 421         (while files
 422           (rename-file
 423            (concat old-dir (cdar files))
 424            (concat new-dir (cdar files)))
 425           (pop files)))
 426       ;; Move .overview file.
 427       (let ((overview (concat old-dir nnml-nov-file-name)))
 428         (when (file-exists-p overview)
 429           (rename-file overview (concat new-dir nnml-nov-file-name))))
 430       (when (<= (length (directory-files old-dir)) 2)
 431         (condition-case ()
 432             (delete-directory old-dir)
 433           (error nil)))
 434       ;; That went ok, so we change the internal structures.
 435       (let ((entry (assoc group nnml-group-alist)))
 436         (and entry (setcar entry new-name))
 437         (setq nnml-current-directory nil
 438               nnml-current-group nil)
 439         ;; Save the new group alist.
 440         (nnmail-save-active nnml-group-alist nnml-active-file)
 441         t))))
 442
 443 (deffoo nnml-set-status (article name value &optional group server)
 444   (nnml-possibly-change-directory group server)
 445   (let ((file (nnml-article-to-file article)))
 446     (cond
 447      ((not (file-exists-p file))
 448       (nnheader-report 'nnml "File %s does not exist" file))
 449      (t
 450       (nnheader-temp-write file
 451         (nnheader-insert-file-contents-literally file)
 452         (nnmail-replace-status name value))
 453       t))))
 454
 455 \f
 456 ;;; Internal functions.
 457
 458 (defun nnml-article-to-file (article)
 459   (unless nnml-article-file-alist
 460     (setq nnml-article-file-alist
 461           (nnheader-article-to-file-alist nnml-current-directory)))
 462   (let (file)
 463     (when (setq file (cdr (assq article nnml-article-file-alist)))
 464       (concat nnml-current-directory file))))
 465
 466 (defun nnml-deletable-article-p (group article)
 467   "Say whether ARTICLE in GROUP can be deleted."
 468   (let (file path)
 469     (when (setq file (cdr (assq article nnml-article-file-alist)))
 470       (setq path (concat nnml-current-directory file))
 471       (and (file-writable-p path)
 472            (or (not nnmail-keep-last-article)
 473                (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 474                         article)))))))
 475
 476 ;; Find an article number in the current group given the Message-ID.
 477 (defun nnml-find-group-number (id)
 478   (save-excursion
 479     (set-buffer (get-buffer-create " *nnml id*"))
 480     (buffer-disable-undo (current-buffer))
 481     (let ((alist nnml-group-alist)
 482           number)
 483       ;; We want to look through all .overview files, but we want to
 484       ;; start with the one in the current directory.  It seems most
 485       ;; likely that the article we are looking for is in that group.
 486       (if (setq number (nnml-find-id nnml-current-group id))
 487           (cons nnml-current-group number)
 488         ;; It wasn't there, so we look through the other groups as well.
 489         (while (and (not number)
 490                     alist)
 491           (or (string= (caar alist) nnml-current-group)
 492               (setq number (nnml-find-id (caar alist) id)))
 493           (or number
 494               (setq alist (cdr alist))))
 495         (and number
 496              (cons (caar alist) number))))))
 497
 498 (defun nnml-find-id (group id)
 499   (erase-buffer)
 500   (let ((nov (concat (nnmail-group-pathname group nnml-directory)
 501                      nnml-nov-file-name))
 502         number found)
 503     (when (file-exists-p nov)
 504       (insert-file-contents nov)
 505       (while (and (not found)
 506                   (search-forward id nil t)) ; We find the ID.
 507         ;; And the id is in the fourth field.
 508         (if (search-backward
 509              "\t" (save-excursion (beginning-of-line) (point)) t 4)
 510             (progn
 511               (beginning-of-line)
 512               (setq found t)
 513               ;; We return the article number.
 514               (setq number
 515                     (condition-case ()
 516                         (read (current-buffer))
 517                       (error nil))))))
 518       number)))
 519
 520 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 521   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 522       nil
 523     (let ((first (car articles))
 524           (last (progn (while (cdr articles) (setq articles (cdr articles)))
 525                        (car articles)))
 526           (nov (concat nnml-current-directory nnml-nov-file-name)))
 527       (when (file-exists-p nov)
 528         (save-excursion
 529           (set-buffer nntp-server-buffer)
 530           (erase-buffer)
 531           (insert-file-contents nov)
 532           (if (and fetch-old
 533                    (not (numberp fetch-old)))
 534               t                         ; Don't remove anything.
 535             (if fetch-old
 536                 (setq first (max 1 (- first fetch-old))))
 537             (goto-char (point-min))
 538             (while (and (not (eobp)) (> first (read (current-buffer))))
 539               (forward-line 1))
 540             (beginning-of-line)
 541             (if (not (eobp)) (delete-region 1 (point)))
 542             (while (and (not (eobp)) (>= last (read (current-buffer))))
 543               (forward-line 1))
 544             (beginning-of-line)
 545             (if (not (eobp)) (delete-region (point) (point-max)))
 546             t))))))
 547
 548 (defun nnml-possibly-change-directory (group &optional server)
 549   (when (and server
 550              (not (nnml-server-opened server)))
 551     (nnml-open-server server))
 552   (when group
 553     (let ((pathname (nnmail-group-pathname group nnml-directory)))
 554       (when (not (equal pathname nnml-current-directory))
 555         (setq nnml-current-directory pathname
 556               nnml-current-group group
 557               nnml-article-file-alist nil))))
 558   t)
 559
 560 (defun nnml-possibly-create-directory (group)
 561   (let (dir dirs)
 562     (setq dir (nnmail-group-pathname group nnml-directory))
 563     (while (not (file-directory-p dir))
 564       (setq dirs (cons dir dirs))
 565       (setq dir (file-name-directory (directory-file-name dir))))
 566     (while dirs
 567       (make-directory (directory-file-name (car dirs)))
 568       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 569       (setq dirs (cdr dirs)))))
 570
 571 (defun nnml-save-mail (group-art)
 572   "Called narrowed to an article."
 573   (let (chars headers)
 574     (setq chars (nnmail-insert-lines))
 575     (nnmail-insert-xref group-art)
 576     (run-hooks 'nnmail-prepare-save-mail-hook)
 577     (run-hooks 'nnml-prepare-save-mail-hook)
 578     (goto-char (point-min))
 579     (while (looking-at "From ")
 580       (replace-match "X-From-Line: ")
 581       (forward-line 1))
 582     ;; We save the article in all the newsgroups it belongs in.
 583     (let ((ga group-art)
 584           first)
 585       (while ga
 586         (nnml-possibly-create-directory (caar ga))
 587         (let ((file (concat (nnmail-group-pathname
 588                              (caar ga) nnml-directory)
 589                             (int-to-string (cdar ga)))))
 590           (if first
 591               ;; It was already saved, so we just make a hard link.
 592               (funcall nnmail-crosspost-link-function first file t)
 593             ;; Save the article.
 594             (nnmail-write-region (point-min) (point-max) file nil
 595                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 596             (setq first file)))
 597         (setq ga (cdr ga))))
 598     ;; Generate a nov line for this article.  We generate the nov
 599     ;; line after saving, because nov generation destroys the
 600     ;; header.
 601     (setq headers (nnml-parse-head chars))
 602     ;; Output the nov line to all nov databases that should have it.
 603     (let ((ga group-art))
 604       (while ga
 605         (nnml-add-nov (caar ga) (cdar ga) headers)
 606         (setq ga (cdr ga))))
 607     group-art))
 608
 609 (defun nnml-active-number (group)
 610   "Compute the next article number in GROUP."
 611   (let ((active (cadr (assoc group nnml-group-alist))))
 612     ;; The group wasn't known to nnml, so we just create an active
 613     ;; entry for it.
 614     (unless active
 615       ;; Perhaps the active file was corrupt?  See whether
 616       ;; there are any articles in this group.
 617       (nnml-possibly-create-directory group)
 618       (nnml-possibly-change-directory group)
 619       (unless nnml-article-file-alist
 620         (setq nnml-article-file-alist
 621               (sort
 622                (nnheader-article-to-file-alist nnml-current-directory)
 623                (lambda (a1 a2) (< (car a1) (car a2))))))
 624       (setq active
 625             (if nnml-article-file-alist
 626                 (cons (caar nnml-article-file-alist)
 627                       (caar (last nnml-article-file-alist)))
 628               (cons 1 0)))
 629       (setq nnml-group-alist (cons (list group active) nnml-group-alist)))
 630     (setcdr active (1+ (cdr active)))
 631     (while (file-exists-p
 632             (concat (nnmail-group-pathname group nnml-directory)
 633                     (int-to-string (cdr active))))
 634       (setcdr active (1+ (cdr active))))
 635     (cdr active)))
 636
 637 (defun nnml-add-nov (group article headers)
 638   "Add a nov line for the GROUP base."
 639   (save-excursion
 640     (set-buffer (nnml-open-nov group))
 641     (goto-char (point-max))
 642     (mail-header-set-number headers article)
 643     (nnheader-insert-nov headers)))
 644
 645 (defsubst nnml-header-value ()
 646   (buffer-substring (match-end 0) (progn (end-of-line) (point))))
 647
 648 (defun nnml-parse-head (chars &optional number)
 649   "Parse the head of the current buffer."
 650   (save-excursion
 651     (save-restriction
 652       (goto-char (point-min))
 653       (narrow-to-region
 654        (point)
 655        (1- (or (search-forward "\n\n" nil t) (point-max))))
 656       ;; Fold continuation lines.
 657       (goto-char (point-min))
 658       (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 659         (replace-match " " t t))
 660       ;; Remove any tabs; they are too confusing.
 661       (subst-char-in-region (point-min) (point-max) ?\t ? )
 662       (let ((headers (nnheader-parse-head t)))
 663         (mail-header-set-chars headers chars)
 664         (mail-header-set-number headers number)
 665         headers))))
 666
 667 (defun nnml-open-nov (group)
 668   (or (cdr (assoc group nnml-nov-buffer-alist))
 669       (let ((buffer (find-file-noselect
 670                      (concat (nnmail-group-pathname group nnml-directory)
 671                              nnml-nov-file-name))))
 672         (save-excursion
 673           (set-buffer buffer)
 674           (buffer-disable-undo (current-buffer)))
 675         (setq nnml-nov-buffer-alist
 676               (cons (cons group buffer) nnml-nov-buffer-alist))
 677         buffer)))
 678
 679 (defun nnml-save-nov ()
 680   (save-excursion
 681     (while nnml-nov-buffer-alist
 682       (when (buffer-name (cdar nnml-nov-buffer-alist))
 683         (set-buffer (cdar nnml-nov-buffer-alist))
 684         (when (buffer-modified-p)
 685           (nnmail-write-region 1 (point-max) (buffer-file-name) nil 'nomesg))
 686         (set-buffer-modified-p nil)
 687         (kill-buffer (current-buffer)))
 688       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 689
 690 ;;;###autoload
 691 (defun nnml-generate-nov-databases ()
 692   "Generate nov databases in all nnml directories."
 693   (interactive)
 694   ;; Read the active file to make sure we don't re-use articles
 695   ;; numbers in empty groups.
 696   (nnmail-activate 'nnml)
 697   (nnml-open-server (or (nnoo-current-server 'nnml) ""))
 698   (setq nnml-directory (expand-file-name nnml-directory))
 699   ;; Recurse down the directories.
 700   (nnml-generate-nov-databases-1 nnml-directory)
 701   ;; Save the active file.
 702   (nnmail-save-active nnml-group-alist nnml-active-file))
 703
 704 (defun nnml-generate-nov-databases-1 (dir)
 705   (setq dir (file-name-as-directory dir))
 706   ;; We descend recursively
 707   (let ((dirs (directory-files dir t nil t))
 708         dir)
 709     (while dirs
 710       (setq dir (pop dirs))
 711       (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 712                  (file-directory-p dir))
 713         (nnml-generate-nov-databases-1 dir))))
 714   ;; Do this directory.
 715   (let ((files (sort
 716                 (mapcar
 717                  (lambda (name) (string-to-int name))
 718                  (directory-files dir nil "^[0-9]+$" t))
 719                 '<)))
 720     (when files
 721       (funcall nnml-generate-active-function dir)
 722       ;; Generate the nov file.
 723       (nnml-generate-nov-file dir files))))
 724
 725 (defvar files)
 726 (defun nnml-generate-active-info (dir)
 727   ;; Update the active info for this group.
 728   (let ((group (nnheader-file-to-group
 729                 (directory-file-name dir) nnml-directory)))
 730     (setq nnml-group-alist
 731           (delq (assoc group nnml-group-alist) nnml-group-alist))
 732     (push (list group
 733                 (cons (car files)
 734                       (let ((f files))
 735                         (while (cdr f) (setq f (cdr f)))
 736                         (car f))))
 737           nnml-group-alist)))
 738
 739 (defun nnml-generate-nov-file (dir files)
 740   (let* ((dir (file-name-as-directory dir))
 741          (nov (concat dir nnml-nov-file-name))
 742          (nov-buffer (get-buffer-create " *nov*"))
 743          chars file headers)
 744     (save-excursion
 745       ;; Init the nov buffer.
 746       (set-buffer nov-buffer)
 747       (buffer-disable-undo (current-buffer))
 748       (erase-buffer)
 749       (set-buffer nntp-server-buffer)
 750       ;; Delete the old NOV file.
 751       (when (file-exists-p nov)
 752         (funcall nnmail-delete-file-function nov))
 753       (while files
 754         (unless (file-directory-p
 755                  (setq file (concat dir (int-to-string (car files)))))
 756           (erase-buffer)
 757           (insert-file-contents file)
 758           (narrow-to-region
 759            (goto-char (point-min))
 760            (progn
 761              (search-forward "\n\n" nil t)
 762              (setq chars (- (point-max) (point)))
 763              (max 1 (1- (point)))))
 764           (when (and (not (= 0 chars))  ; none of them empty files...
 765                      (not (= (point-min) (point-max))))
 766             (goto-char (point-min))
 767             (setq headers (nnml-parse-head chars (car files)))
 768             (save-excursion
 769               (set-buffer nov-buffer)
 770               (goto-char (point-max))
 771               (nnheader-insert-nov headers)))
 772           (widen))
 773         (setq files (cdr files)))
 774       (save-excursion
 775         (set-buffer nov-buffer)
 776         (nnmail-write-region 1 (point-max) nov nil 'nomesg)
 777         (kill-buffer (current-buffer))))))
 778
 779 (defun nnml-nov-delete-article (group article)
 780   (save-excursion
 781     (set-buffer (nnml-open-nov group))
 782     (goto-char (point-min))
 783     (if (re-search-forward (concat "^" (int-to-string article) "\t") nil t)
 784         (delete-region (match-beginning 0) (progn (forward-line 1) (point))))
 785     t))
 786
 787 (provide 'nnml)
 788
 789 ;;; nnml.el ends here