cgit.sxemacs.org Git - gnus/blob - lisp/nnmbox.el

   1 ;;; nnmbox.el --- mail mbox access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'message)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (eval-when-compile (require 'cl))
  37
  38 (nnoo-declare nnmbox)
  39
  40 (defvoo nnmbox-mbox-file (expand-file-name "~/mbox")
  41   "The name of the mail box file in the user's home directory.")
  42
  43 (defvoo nnmbox-active-file (expand-file-name "~/.mbox-active")
  44   "The name of the active file for the mail box.")
  45
  46 (defvoo nnmbox-get-new-mail t
  47   "If non-nil, nnmbox will check the incoming mail file and split the mail.")
  48
  49 (defvoo nnmbox-prepare-save-mail-hook nil
  50   "Hook run narrowed to an article before saving.")
  51
  52 \f
  53
  54 (defconst nnmbox-version "nnmbox 1.0"
  55   "nnmbox version.")
  56
  57 (defvoo nnmbox-current-group nil
  58   "Current nnmbox news group directory.")
  59
  60 (defconst nnmbox-mbox-buffer nil)
  61
  62 (defvoo nnmbox-status-string "")
  63
  64 (defvoo nnmbox-group-alist nil)
  65 (defvoo nnmbox-active-timestamp nil)
  66
  67 \f
  68
  69 ;;; Interface functions
  70
  71 (nnoo-define-basics nnmbox)
  72
  73 (deffoo nnmbox-retrieve-headers (sequence &optional newsgroup server fetch-old)
  74   (save-excursion
  75     (set-buffer nntp-server-buffer)
  76     (erase-buffer)
  77     (let ((number (length sequence))
  78           (count 0)
  79           article art-string start stop)
  80       (nnmbox-possibly-change-newsgroup newsgroup server)
  81       (while sequence
  82         (setq article (car sequence))
  83         (setq art-string (nnmbox-article-string article))
  84         (set-buffer nnmbox-mbox-buffer)
  85         (when (or (search-forward art-string nil t)
  86                   (progn (goto-char (point-min))
  87                          (search-forward art-string nil t)))
  88           (setq start
  89                 (save-excursion
  90                   (re-search-backward
  91                    (concat "^" message-unix-mail-delimiter) nil t)
  92                   (point)))
  93           (search-forward "\n\n" nil t)
  94           (setq stop (1- (point)))
  95           (set-buffer nntp-server-buffer)
  96           (insert (format "221 %d Article retrieved.\n" article))
  97           (insert-buffer-substring nnmbox-mbox-buffer start stop)
  98           (goto-char (point-max))
  99           (insert ".\n"))
 100         (setq sequence (cdr sequence))
 101         (setq count (1+ count))
 102         (and (numberp nnmail-large-newsgroup)
 103              (> number nnmail-large-newsgroup)
 104              (zerop (% count 20))
 105              (nnheader-message 5 "nnmbox: Receiving headers... %d%%"
 106                                (/ (* count 100) number))))
 107
 108       (and (numberp nnmail-large-newsgroup)
 109            (> number nnmail-large-newsgroup)
 110            (nnheader-message 5 "nnmbox: Receiving headers...done"))
 111
 112       (set-buffer nntp-server-buffer)
 113       (nnheader-fold-continuation-lines)
 114       'headers)))
 115
 116 (deffoo nnmbox-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmbox server defs)
 118   (nnmbox-create-mbox)
 119   (cond
 120    ((not (file-exists-p nnmbox-mbox-file))
 121     (nnmbox-close-server)
 122     (nnheader-report 'nnmbox "No such file: %s" nnmbox-mbox-file))
 123    ((file-directory-p nnmbox-mbox-file)
 124     (nnmbox-close-server)
 125     (nnheader-report 'nnmbox "Not a regular file: %s" nnmbox-mbox-file))
 126    (t
 127     (nnheader-report 'nnmbox "Opened server %s using mbox %s" server
 128                      nnmbox-mbox-file)
 129     t)))
 130
 131 (deffoo nnmbox-close-server (&optional server)
 132   (when (and nnmbox-mbox-buffer
 133              (buffer-name nnmbox-mbox-buffer))
 134     (kill-buffer nnmbox-mbox-buffer))
 135   (nnoo-close-server 'nnmbox server)
 136   t)
 137
 138 (deffoo nnmbox-server-opened (&optional server)
 139   (and (nnoo-current-server-p 'nnmbox server)
 140        nnmbox-mbox-buffer
 141        (buffer-name nnmbox-mbox-buffer)
 142        nntp-server-buffer
 143        (buffer-name nntp-server-buffer)))
 144
 145 (deffoo nnmbox-request-article (article &optional newsgroup server buffer)
 146   (nnmbox-possibly-change-newsgroup newsgroup server)
 147   (save-excursion
 148     (set-buffer nnmbox-mbox-buffer)
 149     (goto-char (point-min))
 150     (when (search-forward (nnmbox-article-string article) nil t)
 151       (let (start stop)
 152         (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 153         (setq start (point))
 154         (forward-line 1)
 155         (or (and (re-search-forward
 156                   (concat "^" message-unix-mail-delimiter) nil t)
 157                  (forward-line -1))
 158             (goto-char (point-max)))
 159         (setq stop (point))
 160         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 161           (set-buffer nntp-server-buffer)
 162           (erase-buffer)
 163           (insert-buffer-substring nnmbox-mbox-buffer start stop)
 164           (goto-char (point-min))
 165           (while (looking-at "From ")
 166             (delete-char 5)
 167             (insert "X-From-Line: ")
 168             (forward-line 1))
 169           (if (numberp article)
 170               (cons nnmbox-current-group article)
 171             (nnmbox-article-group-number)))))))
 172
 173 (deffoo nnmbox-request-group (group &optional server dont-check)
 174   (let ((active (cadr (assoc group nnmbox-group-alist))))
 175     (cond
 176      ((or (null active)
 177           (null (nnmbox-possibly-change-newsgroup group server)))
 178       (nnheader-report 'nnmbox "No such group: %s" group))
 179      (dont-check
 180       (nnheader-report 'nnmbox "Selected group %s" group)
 181       (nnheader-insert ""))
 182      (t
 183       (nnheader-report 'nnmbox "Selected group %s" group)
 184       (nnheader-insert "211 %d %d %d %s\n"
 185                        (1+ (- (cdr active) (car active)))
 186                        (car active) (cdr active) group)))))
 187
 188 (deffoo nnmbox-request-scan (&optional group server)
 189   (nnmbox-possibly-change-newsgroup group server)
 190   (nnmbox-read-mbox)
 191   (nnmail-get-new-mail
 192    'nnmbox
 193    (lambda ()
 194      (save-excursion
 195        (set-buffer nnmbox-mbox-buffer)
 196        (save-buffer)))
 197    (file-name-directory nnmbox-mbox-file)
 198    group
 199    (lambda ()
 200      (save-excursion
 201        (let ((in-buf (current-buffer)))
 202          (set-buffer nnmbox-mbox-buffer)
 203          (goto-char (point-max))
 204          (insert-buffer-substring in-buf)))
 205      (nnmail-save-active nnmbox-group-alist nnmbox-active-file))))
 206
 207 (deffoo nnmbox-close-group (group &optional server)
 208   t)
 209
 210 (deffoo nnmbox-request-list (&optional server)
 211   (save-excursion
 212     (nnmail-find-file nnmbox-active-file)
 213     (setq nnmbox-group-alist (nnmail-get-active))
 214     t))
 215
 216 (deffoo nnmbox-request-newgroups (date &optional server)
 217   (nnmbox-request-list server))
 218
 219 (deffoo nnmbox-request-list-newsgroups (&optional server)
 220   (nnheader-report 'nnmbox "LIST NEWSGROUPS is not implemented."))
 221
 222 (deffoo nnmbox-request-expire-articles
 223   (articles newsgroup &optional server force)
 224   (nnmbox-possibly-change-newsgroup newsgroup server)
 225   (let* ((is-old t)
 226          rest)
 227     (nnmail-activate 'nnmbox)
 228
 229     (save-excursion
 230       (set-buffer nnmbox-mbox-buffer)
 231       (while (and articles is-old)
 232         (goto-char (point-min))
 233         (when (search-forward (nnmbox-article-string (car articles)) nil t)
 234           (if (setq is-old
 235                     (nnmail-expired-article-p
 236                      newsgroup
 237                      (buffer-substring
 238                       (point) (progn (end-of-line) (point))) force))
 239               (progn
 240                 (nnheader-message 5 "Deleting article %d in %s..."
 241                                   (car articles) newsgroup)
 242                 (nnmbox-delete-mail))
 243             (push (car articles) rest)))
 244         (setq articles (cdr articles)))
 245       (save-buffer)
 246       ;; Find the lowest active article in this group.
 247       (let ((active (nth 1 (assoc newsgroup nnmbox-group-alist))))
 248         (goto-char (point-min))
 249         (while (and (not (search-forward
 250                           (nnmbox-article-string (car active)) nil t))
 251                     (<= (car active) (cdr active)))
 252           (setcar active (1+ (car active)))
 253           (goto-char (point-min))))
 254       (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 255       (nconc rest articles))))
 256
 257 (deffoo nnmbox-request-move-article
 258   (article group server accept-form &optional last)
 259   (let ((buf (get-buffer-create " *nnmbox move*"))
 260         result)
 261     (and
 262      (nnmbox-request-article article group server)
 263      (save-excursion
 264        (set-buffer buf)
 265        (buffer-disable-undo (current-buffer))
 266        (erase-buffer)
 267        (insert-buffer-substring nntp-server-buffer)
 268        (goto-char (point-min))
 269        (while (re-search-forward
 270                "^X-Gnus-Newsgroup:"
 271                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 272          (delete-region (progn (beginning-of-line) (point))
 273                         (progn (forward-line 1) (point))))
 274        (setq result (eval accept-form))
 275        (kill-buffer buf)
 276        result)
 277      (save-excursion
 278        (nnmbox-possibly-change-newsgroup group server)
 279        (set-buffer nnmbox-mbox-buffer)
 280        (goto-char (point-min))
 281        (when (search-forward (nnmbox-article-string article) nil t)
 282          (nnmbox-delete-mail))
 283        (and last (save-buffer))))
 284     result))
 285
 286 (deffoo nnmbox-request-accept-article (group &optional server last)
 287   (nnmbox-possibly-change-newsgroup group server)
 288   (nnmail-check-syntax)
 289   (let ((buf (current-buffer))
 290         result)
 291     (goto-char (point-min))
 292     ;; The From line may have been quoted by movemail.
 293     (when (looking-at (concat ">" message-unix-mail-delimiter))
 294       (delete-char 1))
 295     (if (looking-at "X-From-Line: ")
 296         (replace-match "From ")
 297       (insert "From nobody " (current-time-string) "\n"))
 298     (and
 299      (nnmail-activate 'nnmbox)
 300      (progn
 301        (set-buffer buf)
 302        (goto-char (point-min))
 303        (search-forward "\n\n" nil t)
 304        (forward-line -1)
 305        (while (re-search-backward "^X-Gnus-Newsgroup: " nil t)
 306          (delete-region (point) (progn (forward-line 1) (point))))
 307        (setq result (nnmbox-save-mail
 308                      (if (stringp group)
 309                          (list (cons group (nnmbox-active-number group)))
 310                        (nnmail-article-group 'nnmbox-active-number)))))
 311      (save-excursion
 312        (set-buffer nnmbox-mbox-buffer)
 313        (goto-char (point-max))
 314        (insert-buffer-substring buf)
 315        (when last
 316          (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 317          (save-buffer))))
 318     (car result)))
 319
 320 (deffoo nnmbox-request-replace-article (article group buffer)
 321   (nnmbox-possibly-change-newsgroup group)
 322   (save-excursion
 323     (set-buffer nnmbox-mbox-buffer)
 324     (goto-char (point-min))
 325     (if (not (search-forward (nnmbox-article-string article) nil t))
 326         nil
 327       (nnmbox-delete-mail t t)
 328       (insert-buffer-substring buffer)
 329       (save-buffer)
 330       t)))
 331
 332 (deffoo nnmbox-request-delete-group (group &optional force server)
 333   (nnmbox-possibly-change-newsgroup group server)
 334   ;; Delete all articles in GROUP.
 335   (if (not force)
 336       ()                                ; Don't delete the articles.
 337     (save-excursion
 338       (set-buffer nnmbox-mbox-buffer)
 339       (goto-char (point-min))
 340       ;; Delete all articles in this group.
 341       (let ((ident (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"))
 342             found)
 343         (while (search-forward ident nil t)
 344           (setq found t)
 345           (nnmbox-delete-mail))
 346         (when found
 347           (save-buffer)))))
 348   ;; Remove the group from all structures.
 349   (setq nnmbox-group-alist
 350         (delq (assoc group nnmbox-group-alist) nnmbox-group-alist)
 351         nnmbox-current-group nil)
 352   ;; Save the active file.
 353   (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 354   t)
 355
 356 (deffoo nnmbox-request-rename-group (group new-name &optional server)
 357   (nnmbox-possibly-change-newsgroup group server)
 358   (save-excursion
 359     (set-buffer nnmbox-mbox-buffer)
 360     (goto-char (point-min))
 361     (let ((ident (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"))
 362           (new-ident (concat "\nX-Gnus-Newsgroup: " new-name ":"))
 363           found)
 364       (while (search-forward ident nil t)
 365         (replace-match new-ident t t)
 366         (setq found t))
 367       (when found
 368         (save-buffer))))
 369   (let ((entry (assoc group nnmbox-group-alist)))
 370     (when entry
 371       (setcar entry new-name))
 372     (setq nnmbox-current-group nil)
 373     ;; Save the new group alist.
 374     (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 375     t))
 376
 377 \f
 378 ;;; Internal functions.
 379
 380 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 381 ;; headers there are.  If LEAVE-DELIM, don't delete the Unix mbox
 382 ;; delimiter line.
 383 (defun nnmbox-delete-mail (&optional force leave-delim)
 384   ;; Delete the current X-Gnus-Newsgroup line.
 385   (or force
 386       (delete-region
 387        (progn (beginning-of-line) (point))
 388        (progn (forward-line 1) (point))))
 389   ;; Beginning of the article.
 390   (save-excursion
 391     (save-restriction
 392       (narrow-to-region
 393        (save-excursion
 394          (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 395          (if leave-delim (progn (forward-line 1) (point))
 396            (match-beginning 0)))
 397        (progn
 398          (forward-line 1)
 399          (or (and (re-search-forward (concat "^" message-unix-mail-delimiter)
 400                                      nil t)
 401                   (if (and (not (bobp)) leave-delim)
 402                       (progn (forward-line -2) (point))
 403                     (match-beginning 0)))
 404              (point-max))))
 405       (goto-char (point-min))
 406       ;; Only delete the article if no other groups owns it as well.
 407       (when (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 408         (delete-region (point-min) (point-max))))))
 409
 410 (defun nnmbox-possibly-change-newsgroup (newsgroup &optional server)
 411   (when (and server
 412              (not (nnmbox-server-opened server)))
 413     (nnmbox-open-server server))
 414   (when (or (not nnmbox-mbox-buffer)
 415             (not (buffer-name nnmbox-mbox-buffer)))
 416     (save-excursion
 417       (set-buffer (setq nnmbox-mbox-buffer
 418                         (nnheader-find-file-noselect
 419                          nnmbox-mbox-file nil 'raw)))
 420       (buffer-disable-undo (current-buffer))))
 421   (when (not nnmbox-group-alist)
 422     (nnmail-activate 'nnmbox))
 423   (if newsgroup
 424       (when (assoc newsgroup nnmbox-group-alist)
 425         (setq nnmbox-current-group newsgroup))
 426     t))
 427
 428 (defun nnmbox-article-string (article)
 429   (if (numberp article)
 430       (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"
 431               (int-to-string article) " ")
 432     (concat "\nMessage-ID: " article)))
 433
 434 (defun nnmbox-article-group-number ()
 435   (save-excursion
 436     (goto-char (point-min))
 437     (when (re-search-forward "^X-Gnus-Newsgroup: +\\([^:]+\\):\\([0-9]+\\) "
 438                              nil t)
 439       (cons (buffer-substring (match-beginning 1) (match-end 1))
 440             (string-to-int
 441              (buffer-substring (match-beginning 2) (match-end 2)))))))
 442
 443 (defun nnmbox-save-mail (group-art)
 444   "Called narrowed to an article."
 445   (let ((delim (concat "^" message-unix-mail-delimiter)))
 446     (goto-char (point-min))
 447     ;; This might come from somewhere else.
 448     (unless (looking-at delim)
 449       (insert "From nobody " (current-time-string) "\n")
 450       (goto-char (point-min)))
 451     ;; Quote all "From " lines in the article.
 452     (forward-line 1)
 453     (while (re-search-forward delim nil t)
 454       (beginning-of-line)
 455       (insert "> "))
 456     (nnmail-insert-lines)
 457     (nnmail-insert-xref group-art)
 458     (nnmbox-insert-newsgroup-line group-art)
 459     (run-hooks 'nnmail-prepare-save-mail-hook)
 460     (run-hooks 'nnmbox-prepare-save-mail-hook)
 461     group-art))
 462
 463 (defun nnmbox-insert-newsgroup-line (group-art)
 464   (save-excursion
 465     (goto-char (point-min))
 466     (when (search-forward "\n\n" nil t)
 467       (forward-char -1)
 468       (while group-art
 469         (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 470                         (caar group-art) (cdar group-art)
 471                         (current-time-string)))
 472         (setq group-art (cdr group-art))))
 473     t))
 474
 475 (defun nnmbox-active-number (group)
 476   ;; Find the next article number in GROUP.
 477   (let ((active (cadr (assoc group nnmbox-group-alist))))
 478     (if active
 479         (setcdr active (1+ (cdr active)))
 480       ;; This group is new, so we create a new entry for it.
 481       ;; This might be a bit naughty... creating groups on the drop of
 482       ;; a hat, but I don't know...
 483       (push (list group (setq active (cons 1 1)))
 484             nnmbox-group-alist))
 485     (cdr active)))
 486
 487 (defun nnmbox-create-mbox ()
 488   (when (not (file-exists-p nnmbox-mbox-file))
 489     (nnmail-write-region 1 1 nnmbox-mbox-file t 'nomesg)))
 490
 491 (defun nnmbox-read-mbox ()
 492   (nnmail-activate 'nnmbox)
 493   (nnmbox-create-mbox)
 494   (if (and nnmbox-mbox-buffer
 495            (buffer-name nnmbox-mbox-buffer)
 496            (save-excursion
 497              (set-buffer nnmbox-mbox-buffer)
 498              (= (buffer-size) (nnheader-file-size nnmbox-mbox-file))))
 499       ()
 500     (save-excursion
 501       (let ((delim (concat "^" message-unix-mail-delimiter))
 502             (alist nnmbox-group-alist)
 503             start end number)
 504         (set-buffer (setq nnmbox-mbox-buffer
 505                           (nnheader-find-file-noselect
 506                            nnmbox-mbox-file nil 'raw)))
 507         (buffer-disable-undo (current-buffer))
 508
 509         ;; Go through the group alist and compare against
 510         ;; the mbox file.
 511         (while alist
 512           (goto-char (point-max))
 513           (when (and (re-search-backward
 514                       (format "^X-Gnus-Newsgroup: %s:\\([0-9]+\\) "
 515                               (caar alist)) nil t)
 516                      (>= (setq number
 517                                (string-to-number
 518                                 (buffer-substring
 519                                  (match-beginning 1) (match-end 1))))
 520                          (cdadar alist)))
 521             (setcdr (cadar alist) (1+ number)))
 522           (setq alist (cdr alist)))
 523
 524         (goto-char (point-min))
 525         (while (re-search-forward delim nil t)
 526           (setq start (match-beginning 0))
 527           (when (not (search-forward "\nX-Gnus-Newsgroup: "
 528                                      (save-excursion
 529                                        (setq end
 530                                              (or
 531                                               (and
 532                                                (re-search-forward delim nil t)
 533                                                (match-beginning 0))
 534                                               (point-max))))
 535                                      t))
 536             (save-excursion
 537               (save-restriction
 538                 (narrow-to-region start end)
 539                 (nnmbox-save-mail
 540                  (nnmail-article-group 'nnmbox-active-number)))))
 541           (goto-char end))))))
 542
 543 (provide 'nnmbox)
 544
 545 ;;; nnmbox.el ends here