cgit.sxemacs.org Git - gnus/blob - lisp/nnir.el

   1 ;;; nnir.el --- search mail with various search engines -*- coding: iso-8859-1 -*-
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Kai Großjohann <grossjohann@ls6.cs.uni-dortmund.de>
   7 ;; Swish-e and Swish++ backends by:
   8 ;;   Christoph Conrad <christoph.conrad@gmx.de>.
   9 ;; IMAP backend by: Simon Josefsson <jas@pdc.kth.se>.
  10 ;; IMAP search by: Torsten Hilbrich <torsten.hilbrich <at> gmx.net>
  11 ;; IMAP search improved by Daniel Pittman  <daniel@rimspace.net>.
  12 ;; nnmaildir support for Swish++ and Namazu backends by:
  13 ;;   Justus Piater <Justus <at> Piater.name>
  14 ;; Keywords: news mail searching ir
  15
  16 ;; This file is part of GNU Emacs.
  17
  18 ;; GNU Emacs is free software: you can redistribute it and/or modify
  19 ;; it under the terms of the GNU General Public License as published by
  20 ;; the Free Software Foundation, either version 3 of the License, or
  21 ;; (at your option) any later version.
  22
  23 ;; GNU Emacs is distributed in the hope that it will be useful,
  24 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  25 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26 ;; GNU General Public License for more details.
  27
  28 ;; You should have received a copy of the GNU General Public License
  29 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  30
  31 ;;; Commentary:
  32
  33 ;; TODO: Documentation in the Gnus manual
  34
  35 ;; Where in the existing gnus manual would this fit best?
  36
  37 ;; What does it do?  Well, it allows you to search your mail using
  38 ;; some search engine (imap, namazu, swish-e, gmane and others -- see
  39 ;; later) by typing `G G' in the Group buffer.  You will then get a
  40 ;; buffer which shows all articles matching the query, sorted by
  41 ;; Retrieval Status Value (score).
  42
  43 ;; When looking at the retrieval result (in the Summary buffer) you
  44 ;; can type `A W' (aka M-x gnus-warp-to-article RET) on an article.  You
  45 ;; will be warped into the group this article came from. Typing `A T'
  46 ;; (aka M-x gnus-summary-refer-thread RET) will warp to the group and
  47 ;; also show the thread this article is part of.
  48
  49 ;; The Lisp setup may involve setting a few variables and setting up the
  50 ;; search engine. You can define the variables in the server definition
  51 ;; like this :
  52 ;;   (setq gnus-secondary-select-methods '(
  53 ;;       (nnimap "" (nnimap-address "localhost")
  54 ;;                  (nnir-search-engine namazu)
  55 ;;       )))
  56 ;; The main variable to set is `nnir-search-engine'.  Choose one of
  57 ;; the engines listed in `nnir-engines'.  (Actually `nnir-engines' is
  58 ;; an alist, type `C-h v nnir-engines RET' for more information; this
  59 ;; includes examples for setting `nnir-search-engine', too.)
  60
  61 ;; If you use one of the local indices (namazu, find-grep, swish) you
  62 ;; must also set up a search engine backend.
  63
  64 ;; 1. Namazu
  65 ;;
  66 ;; The Namazu backend requires you to have one directory containing all
  67 ;; index files, this is controlled by the `nnir-namazu-index-directory'
  68 ;; variable.  To function the `nnir-namazu-remove-prefix' variable must
  69 ;; also be correct, see the documentation for `nnir-namazu-remove-prefix'
  70 ;; above.
  71 ;;
  72 ;; It is particularly important not to pass any any switches to namazu
  73 ;; that will change the output format.  Good switches to use include
  74 ;; `--sort', `--ascending', `--early' and `--late'.  Refer to the Namazu
  75 ;; documentation for further information on valid switches.
  76 ;;
  77 ;; To index my mail with the `mknmz' program I use the following
  78 ;; configuration file:
  79 ;;
  80 ;; ,----
  81 ;; | package conf;  # Don't remove this line!
  82 ;; |
  83 ;; | # Paths which will not be indexed. Don't use `^' or `$' anchors.
  84 ;; | $EXCLUDE_PATH = "spam|sent";
  85 ;; |
  86 ;; | # Header fields which should be searchable. case-insensitive
  87 ;; | $REMAIN_HEADER = "from|date|message-id|subject";
  88 ;; |
  89 ;; | # Searchable fields. case-insensitive
  90 ;; | $SEARCH_FIELD = "from|date|message-id|subject";
  91 ;; |
  92 ;; | # The max length of a word.
  93 ;; | $WORD_LENG_MAX = 128;
  94 ;; |
  95 ;; | # The max length of a field.
  96 ;; | $MAX_FIELD_LENGTH = 256;
  97 ;; `----
  98 ;;
  99 ;; My mail is stored in the directories ~/Mail/mail/, ~/Mail/lists/ and
 100 ;; ~/Mail/archive/, so to index them I go to the directory set in
 101 ;; `nnir-namazu-index-directory' and issue the following command.
 102 ;;
 103 ;;      mknmz --mailnews ~/Mail/archive/ ~/Mail/mail/ ~/Mail/lists/
 104 ;;
 105 ;; For maximum searching efficiency I have a cron job set to run this
 106 ;; command every four hours.
 107
 108 ;; 2. find-grep
 109 ;;
 110 ;; The find-grep engine simply runs find(1) to locate eligible
 111 ;; articles and searches them with grep(1).  This, of course, is much
 112 ;; slower than using a proper search engine but OTOH doesn't require
 113 ;; maintenance of an index and is still faster than using any built-in
 114 ;; means for searching.  The method specification of the server to
 115 ;; search must include a directory for this engine to work (E.g.,
 116 ;; `nnml-directory').  The tools must be POSIX compliant.  GNU Find
 117 ;; prior to version 4.2.12 (4.2.26 on Linux due to incorrect ARG_MAX
 118 ;; handling) does not work.
 119 ;; ,----
 120 ;; |    ;; find-grep configuration for searching the Gnus Cache
 121 ;; |
 122 ;; |    (nnml "cache"
 123 ;; |          (nnml-get-new-mail nil)
 124 ;; |          (nnir-search-engine find-grep)
 125 ;; |          (nnml-directory "~/News/cache/")
 126 ;; |          (nnml-active-file "~/News/cache/active"))
 127 ;; `----
 128
 129 ;; Developer information:
 130
 131 ;; I have tried to make the code expandable.  Basically, it is divided
 132 ;; into two layers.  The upper layer is somewhat like the `nnvirtual'
 133 ;; backend: given a specification of what articles to show from
 134 ;; another backend, it creates a group containing exactly those
 135 ;; articles.  The lower layer issues a query to a search engine and
 136 ;; produces such a specification of what articles to show from the
 137 ;; other backend.
 138
 139 ;; The interface between the two layers consists of the single
 140 ;; function `nnir-run-query', which just selects the appropriate
 141 ;; function for the search engine one is using.  The input to
 142 ;; `nnir-run-query' is a string, representing the query as input by
 143 ;; the user.  The output of `nnir-run-query' is supposed to be a
 144 ;; vector, each element of which should in turn be a three-element
 145 ;; vector.  The first element should be full group name of the article,
 146 ;; the second element should be the article number, and the third
 147 ;; element should be the Retrieval Status Value (RSV) as returned from
 148 ;; the search engine.  An RSV is the score assigned to the document by
 149 ;; the search engine.  For Boolean search engines, the
 150 ;; RSV is always 1000 (or 1 or 100, or whatever you like).
 151
 152 ;; The sorting order of the articles in the summary buffer created by
 153 ;; nnir is based on the order of the articles in the above mentioned
 154 ;; vector, so that's where you can do the sorting you'd like.  Maybe
 155 ;; it would be nice to have a way of displaying the search result
 156 ;; sorted differently?
 157
 158 ;; So what do you need to do when you want to add another search
 159 ;; engine?  You write a function that executes the query.  Temporary
 160 ;; data from the search engine can be put in `nnir-tmp-buffer'.  This
 161 ;; function should return the list of articles as a vector, as
 162 ;; described above.  Then, you need to register this backend in
 163 ;; `nnir-engines'.  Then, users can choose the backend by setting
 164 ;; `nnir-search-engine' as a server variable.
 165
 166 ;;; Code:
 167
 168 ;;; Setup:
 169
 170 ;; For Emacs <22.2 and XEmacs.
 171 (eval-and-compile
 172   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
 173
 174 (require 'nnoo)
 175 (require 'gnus-group)
 176 (require 'message)
 177 (require 'gnus-util)
 178 (eval-when-compile
 179   (require 'cl))
 180
 181 ;;; Internal Variables:
 182
 183 (defvar nnir-current-query nil
 184   "Internal: stores current query (= group name).")
 185
 186 (defvar nnir-current-server nil
 187   "Internal: stores current server (does it ever change?).")
 188
 189 (defvar nnir-current-group-marked nil
 190   "Internal: stores current list of process-marked groups.")
 191
 192 (defvar nnir-artlist nil
 193   "Internal: stores search result.")
 194
 195 (defvar nnir-tmp-buffer " *nnir*"
 196   "Internal: temporary buffer.")
 197
 198 (defvar nnir-search-history ()
 199   "Internal: the history for querying search options in nnir")
 200
 201 (defvar nnir-extra-parms nil
 202   "Internal: stores request for extra search parms")
 203
 204 ;; Imap variables
 205
 206 (defvar nnir-imap-search-arguments
 207   '(("Whole message" . "TEXT")
 208     ("Subject" . "SUBJECT")
 209     ("To" . "TO")
 210     ("From" . "FROM")
 211     ("Imap" . ""))
 212   "Mapping from user readable keys to IMAP search items for use in nnir")
 213
 214 (defvar nnir-imap-search-other "HEADER %S"
 215   "The IMAP search item to use for anything other than
 216   `nnir-imap-search-arguments'. By default this is the name of an
 217   email header field")
 218
 219 (defvar nnir-imap-search-argument-history ()
 220   "The history for querying search options in nnir")
 221
 222 ;;; Helper macros
 223
 224 ;; Data type article list.
 225
 226 (defmacro nnir-artlist-length (artlist)
 227   "Returns number of articles in artlist."
 228   `(length ,artlist))
 229
 230 (defmacro nnir-artlist-article (artlist n)
 231   "Returns from ARTLIST the Nth artitem (counting starting at 1)."
 232   `(when (> ,n 0)
 233      (elt ,artlist (1- ,n))))
 234
 235 (defmacro nnir-artitem-group (artitem)
 236   "Returns the group from the ARTITEM."
 237   `(elt ,artitem 0))
 238
 239 (defmacro nnir-artitem-number (artitem)
 240   "Returns the number from the ARTITEM."
 241   `(elt ,artitem 1))
 242
 243 (defmacro nnir-artitem-rsv (artitem)
 244   "Returns the Retrieval Status Value (RSV, score) from the ARTITEM."
 245   `(elt ,artitem 2))
 246
 247 (defmacro nnir-article-group (article)
 248   "Returns the group for ARTICLE"
 249   `(nnir-artitem-group (nnir-artlist-article nnir-artlist ,article)))
 250
 251 (defmacro nnir-article-number (article)
 252   "Returns the number for ARTICLE"
 253   `(nnir-artitem-number (nnir-artlist-article nnir-artlist ,article)))
 254
 255 (defmacro nnir-article-rsv (article)
 256   "Returns the rsv for ARTICLE"
 257   `(nnir-artitem-rsv (nnir-artlist-article nnir-artlist ,article)))
 258
 259 (defsubst nnir-article-ids (article)
 260   "Returns the pair `(nnir id . real id)' of ARTICLE"
 261   (cons article (nnir-article-number article)))
 262
 263 (defmacro nnir-categorize (sequence keyfunc &optional valuefunc)
 264   "Sorts a sequence into categories and returns a list of the form
 265 `((key1 (element11 element12)) (key2 (element21 element22))'.
 266 The category key for a member of the sequence is obtained
 267 as `(keyfunc member)' and the corresponding element is just
 268 `member'. If `valuefunc' is non-nil, the element of the list
 269 is `(valuefunc member)'."
 270   `(unless (null ,sequence)
 271      (let (value)
 272        (mapc
 273         (lambda (member)
 274           (let ((y (,keyfunc member))
 275                 (x ,(if valuefunc
 276                         `(,valuefunc member)
 277                       'member)))
 278             (if (assoc y value)
 279                 (push x (cadr (assoc y value)))
 280               (push (list y (list x)) value))))
 281         ,sequence)
 282        value)))
 283
 284 ;;; Finish setup:
 285
 286 (require 'gnus-sum)
 287
 288 (eval-when-compile
 289   (autoload 'nnimap-buffer "nnimap")
 290   (autoload 'nnimap-command "nnimap")
 291   (autoload 'nnimap-possibly-change-group "nnimap")
 292   (autoload 'gnus-registry-action "gnus-registry"))
 293
 294 (nnoo-declare nnir)
 295 (nnoo-define-basics nnir)
 296
 297 (gnus-declare-backend "nnir" 'mail)
 298
 299
 300 ;;; User Customizable Variables:
 301
 302 (defgroup nnir nil
 303   "Search groups in Gnus with assorted seach engines."
 304   :group 'gnus)
 305
 306 (defcustom nnir-method-default-engines
 307   '((nnimap . imap)
 308     (nntp . gmane))
 309   "*Alist of default search engines keyed by server method."
 310   :type '(alist)
 311   :group 'nnir)
 312
 313 (defcustom nnir-ignored-newsgroups ""
 314   "*A regexp to match newsgroups in the active file that should
 315   be skipped when searching."
 316   :type '(regexp)
 317   :group 'nnir)
 318
 319 (defcustom nnir-summary-line-format nil
 320   "*The format specification of the lines in an nnir summary buffer.
 321
 322 All the items from `gnus-summary-line-format' are available, along
 323 with three items unique to nnir summary buffers:
 324
 325 %Z    Search retrieval score value (integer)
 326 %G    Article original full group name (string)
 327 %g    Article original short group name (string)
 328
 329 If nil this will use `gnus-summary-line-format'."
 330   :type '(regexp)
 331   :group 'nnir)
 332
 333 (defcustom nnir-retrieve-headers-override-function nil
 334   "*If non-nil, a function that accepts an article list and group
 335 and populates the `nntp-server-buffer' with the retrieved
 336 headers. Must return either 'nov or 'headers indicating the
 337 retrieved header format.
 338
 339 If this variable is nil, or if the provided function returns nil for a search
 340 result, `gnus-retrieve-headers' will be called instead."
 341   :type '(function)
 342   :group 'nnir)
 343
 344 (defcustom nnir-imap-default-search-key "Whole message"
 345   "*The default IMAP search key for an nnir search. Must be one of
 346   the keys in `nnir-imap-search-arguments'. To use raw imap queries
 347   by default set this to \"Imap\"."
 348   :type '(string)
 349   :group 'nnir)
 350
 351 (defcustom nnir-swish++-configuration-file
 352   (expand-file-name "~/Mail/swish++.conf")
 353   "*Configuration file for swish++."
 354   :type '(file)
 355   :group 'nnir)
 356
 357 (defcustom nnir-swish++-program "search"
 358   "*Name of swish++ search executable."
 359   :type '(string)
 360   :group 'nnir)
 361
 362 (defcustom nnir-swish++-additional-switches '()
 363   "*A list of strings, to be given as additional arguments to swish++.
 364
 365 Note that this should be a list.  Ie, do NOT use the following:
 366     (setq nnir-swish++-additional-switches \"-i -w\") ; wrong
 367 Instead, use this:
 368     (setq nnir-swish++-additional-switches '(\"-i\" \"-w\"))"
 369   :type '(repeat (string))
 370   :group 'nnir)
 371
 372 (defcustom nnir-swish++-remove-prefix (concat (getenv "HOME") "/Mail/")
 373   "*The prefix to remove from each file name returned by swish++
 374 in order to get a group name (albeit with / instead of .).  This is a
 375 regular expression.
 376
 377 This variable is very similar to `nnir-namazu-remove-prefix', except
 378 that it is for swish++, not Namazu."
 379   :type '(regexp)
 380   :group 'nnir)
 381
 382 ;; Swish-E.
 383 ;; URL: http://swish-e.org/
 384 ;; Variables `nnir-swish-e-index-file', `nnir-swish-e-program' and
 385 ;; `nnir-swish-e-additional-switches'
 386
 387 (make-obsolete-variable 'nnir-swish-e-index-file
 388                         'nnir-swish-e-index-files "Emacs 23.1")
 389 (defcustom nnir-swish-e-index-file
 390   (expand-file-name "~/Mail/index.swish-e")
 391   "*Index file for swish-e.
 392 This could be a server parameter.
 393 It is never consulted once `nnir-swish-e-index-files', which should be
 394 used instead, has been customized."
 395   :type '(file)
 396   :group 'nnir)
 397
 398 (defcustom nnir-swish-e-index-files
 399   (list nnir-swish-e-index-file)
 400   "*List of index files for swish-e.
 401 This could be a server parameter."
 402   :type '(repeat (file))
 403   :group 'nnir)
 404
 405 (defcustom nnir-swish-e-program "swish-e"
 406   "*Name of swish-e search executable.
 407 This cannot be a server parameter."
 408   :type '(string)
 409   :group 'nnir)
 410
 411 (defcustom nnir-swish-e-additional-switches '()
 412   "*A list of strings, to be given as additional arguments to swish-e.
 413
 414 Note that this should be a list.  Ie, do NOT use the following:
 415     (setq nnir-swish-e-additional-switches \"-i -w\") ; wrong
 416 Instead, use this:
 417     (setq nnir-swish-e-additional-switches '(\"-i\" \"-w\"))
 418
 419 This could be a server parameter."
 420   :type '(repeat (string))
 421   :group 'nnir)
 422
 423 (defcustom nnir-swish-e-remove-prefix (concat (getenv "HOME") "/Mail/")
 424   "*The prefix to remove from each file name returned by swish-e
 425 in order to get a group name (albeit with / instead of .).  This is a
 426 regular expression.
 427
 428 This variable is very similar to `nnir-namazu-remove-prefix', except
 429 that it is for swish-e, not Namazu.
 430
 431 This could be a server parameter."
 432   :type '(regexp)
 433   :group 'nnir)
 434
 435 ;; HyREX engine, see <URL:http://ls6-www.cs.uni-dortmund.de/>
 436
 437 (defcustom nnir-hyrex-program "nnir-search"
 438   "*Name of the nnir-search executable."
 439   :type '(string)
 440   :group 'nnir)
 441
 442 (defcustom nnir-hyrex-additional-switches '()
 443   "*A list of strings, to be given as additional arguments for nnir-search.
 444 Note that this should be a list. Ie, do NOT use the following:
 445     (setq nnir-hyrex-additional-switches \"-ddl ddl.xml -c nnir\") ; wrong !
 446 Instead, use this:
 447     (setq nnir-hyrex-additional-switches '(\"-ddl\" \"ddl.xml\" \"-c\" \"nnir\"))"
 448   :type '(repeat (string))
 449   :group 'nnir)
 450
 451 (defcustom nnir-hyrex-index-directory (getenv "HOME")
 452   "*Index directory for HyREX."
 453   :type '(directory)
 454   :group 'nnir)
 455
 456 (defcustom nnir-hyrex-remove-prefix (concat (getenv "HOME") "/Mail/")
 457   "*The prefix to remove from each file name returned by HyREX
 458 in order to get a group name (albeit with / instead of .).
 459
 460 For example, suppose that HyREX returns file names such as
 461 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 462 setting:  (setq nnir-hyrex-remove-prefix \"/home/john/Mail/\")
 463 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 464 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 465 arrive at the correct group name, \"mail.misc\"."
 466   :type '(directory)
 467   :group 'nnir)
 468
 469 ;; Namazu engine, see <URL:http://www.namazu.org/>
 470
 471 (defcustom nnir-namazu-program "namazu"
 472   "*Name of Namazu search executable."
 473   :type '(string)
 474   :group 'nnir)
 475
 476 (defcustom nnir-namazu-index-directory (expand-file-name "~/Mail/namazu/")
 477   "*Index directory for Namazu."
 478   :type '(directory)
 479   :group 'nnir)
 480
 481 (defcustom nnir-namazu-additional-switches '()
 482   "*A list of strings, to be given as additional arguments to namazu.
 483 The switches `-q', `-a', and `-s' are always used, very few other switches
 484 make any sense in this context.
 485
 486 Note that this should be a list.  Ie, do NOT use the following:
 487     (setq nnir-namazu-additional-switches \"-i -w\") ; wrong
 488 Instead, use this:
 489     (setq nnir-namazu-additional-switches '(\"-i\" \"-w\"))"
 490   :type '(repeat (string))
 491   :group 'nnir)
 492
 493 (defcustom nnir-namazu-remove-prefix (concat (getenv "HOME") "/Mail/")
 494   "*The prefix to remove from each file name returned by Namazu
 495 in order to get a group name (albeit with / instead of .).
 496
 497 For example, suppose that Namazu returns file names such as
 498 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 499 setting:  (setq nnir-namazu-remove-prefix \"/home/john/Mail/\")
 500 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 501 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 502 arrive at the correct group name, \"mail.misc\"."
 503   :type '(directory)
 504   :group 'nnir)
 505
 506 ;;; Developer Extension Variable:
 507
 508 (defvar nnir-engines
 509   `((imap    nnir-run-imap
 510              ((criteria
 511                "Imap Search in"                   ; Prompt
 512                ,(mapcar 'car nnir-imap-search-arguments) ; alist for completing
 513                nil                                ; allow any user input
 514                nil                                ; initial value
 515                nnir-imap-search-argument-history  ; the history to use
 516                ,nnir-imap-default-search-key      ; default
 517                )))
 518     (gmane   nnir-run-gmane
 519              ((author . "Gmane Author: ")))
 520     (swish++ nnir-run-swish++
 521              ((group . "Swish++ Group spec: ")))
 522     (swish-e nnir-run-swish-e
 523              ((group . "Swish-e Group spec: ")))
 524     (namazu  nnir-run-namazu
 525              ())
 526     (hyrex   nnir-run-hyrex
 527              ((group . "Hyrex Group spec: ")))
 528     (find-grep nnir-run-find-grep
 529                ((grep-options . "Grep options: "))))
 530   "Alist of supported search engines.
 531 Each element in the alist is a three-element list (ENGINE FUNCTION ARGS).
 532 ENGINE is a symbol designating the searching engine.  FUNCTION is also
 533 a symbol, giving the function that does the search.  The third element
 534 ARGS is a list of cons pairs (PARAM . PROMPT).  When issuing a query,
 535 the FUNCTION will issue a query for each of the PARAMs, using PROMPT.
 536
 537 The value of `nnir-search-engine' must be one of the ENGINE symbols.
 538 For example, for searching a server using namazu include
 539     (nnir-search-engine namazu)
 540 in the server definition.  Note that you have to set additional
 541 variables for most backends.  For example, the `namazu' backend
 542 needs the variables `nnir-namazu-program',
 543 `nnir-namazu-index-directory' and `nnir-namazu-remove-prefix'.
 544
 545 Add an entry here when adding a new search engine.")
 546
 547
 548 ;; Gnus glue.
 549
 550 (defun gnus-group-make-nnir-group (nnir-extra-parms)
 551   "Create an nnir group.  Asks for query."
 552   (interactive "P")
 553   (setq nnir-current-query nil
 554         nnir-current-server nil
 555         nnir-current-group-marked nil
 556         nnir-artlist nil)
 557   (let* ((query (read-string "Query: " nil 'nnir-search-history))
 558          (parms (list (cons 'query query)))
 559          (srv (if (gnus-server-server-name)
 560                   "all" "")))
 561     (add-to-list 'parms (cons 'unique-id (message-unique-id)) t)
 562     (gnus-group-read-ephemeral-group
 563      (concat "nnir:" (prin1-to-string parms)) (list 'nnir srv) t
 564      (cons (current-buffer) gnus-current-window-configuration)
 565      nil)))
 566
 567
 568 ;; Gnus backend interface functions.
 569
 570 (deffoo nnir-open-server (server &optional definitions)
 571   ;; Just set the server variables appropriately.
 572   (add-hook 'gnus-summary-mode-hook 'nnir-mode)
 573   (nnoo-change-server 'nnir server definitions))
 574
 575 (deffoo nnir-request-group (group &optional server fast info)
 576   "GROUP is the query string."
 577   (nnir-possibly-change-server server)
 578   ;; Check for cache and return that if appropriate.
 579   (if (and (equal group nnir-current-query)
 580            (equal gnus-group-marked nnir-current-group-marked)
 581            (or (null server)
 582                (equal server nnir-current-server)))
 583       nnir-artlist
 584     ;; Cache miss.
 585     (setq nnir-artlist (nnir-run-query group server)))
 586   (with-current-buffer nntp-server-buffer
 587     (setq nnir-current-query group)
 588     (when server (setq nnir-current-server server))
 589     (setq nnir-current-group-marked gnus-group-marked)
 590     (if (zerop (length nnir-artlist))
 591         (nnheader-report 'nnir "Search produced empty results.")
 592       ;; Remember data for cache.
 593       (nnheader-insert "211 %d %d %d %s\n"
 594                        (nnir-artlist-length nnir-artlist) ; total #
 595                        1              ; first #
 596                        (nnir-artlist-length nnir-artlist) ; last #
 597                        group))))      ; group name
 598
 599 (deffoo nnir-retrieve-headers (articles &optional group server fetch-old)
 600   (with-current-buffer nntp-server-buffer
 601     (let ((gnus-inhibit-demon t)
 602           (articles-by-group (nnir-categorize
 603                               articles nnir-article-group nnir-article-ids))
 604           headers)
 605       (while (not (null articles-by-group))
 606         (let* ((group-articles (pop articles-by-group))
 607                (artgroup (car group-articles))
 608                (articleids (cadr group-articles))
 609                (artlist (sort (mapcar 'cdr articleids) '<))
 610                (server (gnus-group-server artgroup))
 611                (gnus-override-method (gnus-server-to-method server))
 612                parsefunc)
 613           ;; (or (numberp art)
 614           ;;     (nnheader-report
 615           ;;      'nnir
 616           ;;      "nnir-retrieve-headers doesn't grok message ids: %s"
 617           ;;      art))
 618           (nnir-possibly-change-server server)
 619           ;; is this needed?
 620           (erase-buffer)
 621           (case (setq gnus-headers-retrieved-by
 622                       (or
 623                        (and
 624                         nnir-retrieve-headers-override-function
 625                         (funcall nnir-retrieve-headers-override-function
 626                                  artlist artgroup))
 627                        (gnus-retrieve-headers artlist artgroup nil)))
 628             (nov
 629              (setq parsefunc 'nnheader-parse-nov))
 630             (headers
 631              (setq parsefunc 'nnheader-parse-head))
 632             (t (error "Unknown header type %s while requesting articles \
 633                     of group %s" gnus-headers-retrieved-by artgroup)))
 634           (goto-char (point-min))
 635           (while (not (eobp))
 636             (let* ((novitem (funcall parsefunc))
 637                    (artno (mail-header-number novitem))
 638                    (art (car (rassoc artno articleids))))
 639               (when art
 640                 (mail-header-set-number novitem art)
 641                 (push novitem headers))
 642               (forward-line 1)))))
 643       (setq headers
 644             (sort headers
 645                   (lambda (x y)
 646                     (< (mail-header-number x) (mail-header-number y)))))
 647       (erase-buffer)
 648       (mapc 'nnheader-insert-nov headers)
 649       'nov)))
 650
 651 (deffoo nnir-request-article (article &optional group server to-buffer)
 652   (if (stringp article)
 653       (nnheader-report
 654        'nnir
 655        "nnir-retrieve-headers doesn't grok message ids: %s"
 656        article)
 657     (save-excursion
 658       (let ((artfullgroup (nnir-article-group article))
 659             (artno (nnir-article-number article))
 660             ;; Bug?
 661             ;; Why must we bind nntp-server-buffer here?  It won't
 662             ;; work if `buf' is used, say.  (Of course, the set-buffer
 663             ;; line below must then be updated, too.)
 664             (nntp-server-buffer (or to-buffer nntp-server-buffer)))
 665         (set-buffer nntp-server-buffer)
 666         (erase-buffer)
 667         (message "Requesting article %d from group %s"
 668                  artno artfullgroup)
 669         (gnus-request-article artno artfullgroup nntp-server-buffer)
 670         (cons artfullgroup artno)))))
 671
 672 (deffoo nnir-request-move-article (article group server accept-form
 673                                            &optional last internal-move-group)
 674   (let* ((artfullgroup (nnir-article-group article))
 675          (artno (nnir-article-number article))
 676          (to-newsgroup (nth 1 accept-form))
 677          (to-method (gnus-find-method-for-group to-newsgroup))
 678          (from-method (gnus-find-method-for-group artfullgroup))
 679          (move-is-internal (gnus-server-equal from-method to-method)))
 680     (unless (gnus-check-backend-function
 681              'request-move-article artfullgroup)
 682       (error "The group %s does not support article moving" artfullgroup))
 683     (gnus-request-move-article
 684      artno
 685      artfullgroup
 686      (nth 1 from-method)
 687      accept-form
 688      last
 689      (and move-is-internal
 690           to-newsgroup          ; Not respooling
 691           (gnus-group-real-name to-newsgroup)))))
 692
 693 (deffoo nnir-warp-to-article ()
 694   (let* ((cur (if (> (gnus-summary-article-number) 0)
 695                   (gnus-summary-article-number)
 696                 (error "This is not a real article.")))
 697          (gnus-newsgroup-name (nnir-article-group cur))
 698          (backend-number (nnir-article-number cur)))
 699     (gnus-summary-read-group-1 gnus-newsgroup-name t t gnus-summary-buffer
 700                                nil (list backend-number))))
 701
 702 (nnoo-define-skeleton nnir)
 703
 704
 705 (defmacro nnir-add-result (dirnam artno score prefix server artlist)
 706   "Ask `nnir-compose-result' to construct a result vector,
 707 and if it is non-nil, add it to artlist."
 708   `(let ((result (nnir-compose-result ,dirnam ,artno ,score ,prefix ,server)))
 709      (when (not (null result))
 710        (push result ,artlist))))
 711
 712 (autoload 'nnmaildir-base-name-to-article-number "nnmaildir")
 713
 714 ;; Helper function currently used by the Swish++ and Namazu backends;
 715 ;; perhaps useful for other backends as well
 716 (defun nnir-compose-result (dirnam article score prefix server)
 717   "Extract the group from dirnam, and create a result vector
 718 ready to be added to the list of search results."
 719
 720   ;; remove nnir-*-remove-prefix from beginning of dirnam filename
 721   (when (string-match (concat "^" prefix) dirnam)
 722     (setq dirnam (replace-match "" t t dirnam)))
 723
 724   (when (file-readable-p (concat prefix dirnam article))
 725     ;; remove trailing slash and, for nnmaildir, cur/new/tmp
 726     (setq dirnam
 727           (substring dirnam 0
 728                      (if (string= (gnus-group-server server) "nnmaildir")
 729                          -5 -1)))
 730
 731     ;; Set group to dirnam without any leading dots or slashes,
 732     ;; and with all subsequent slashes replaced by dots
 733     (let ((group (gnus-replace-in-string
 734                  (gnus-replace-in-string dirnam "^[./\\]" "" t)
 735                  "[/\\]" "." t)))
 736
 737     (vector (gnus-group-full-name group server)
 738             (if (string= (gnus-group-server server) "nnmaildir")
 739                 (nnmaildir-base-name-to-article-number
 740                  (substring article 0 (string-match ":" article))
 741                  group nil)
 742               (string-to-number article))
 743             (string-to-number score)))))
 744
 745 ;;; Search Engine Interfaces:
 746
 747 ;; imap interface
 748 (defun nnir-run-imap (query srv &optional groups)
 749   "Run a search against an IMAP back-end server.
 750 This uses a custom query language parser; see `nnir-imap-make-query' for
 751 details on the language and supported extensions"
 752   (save-excursion
 753     (let ((qstring (cdr (assq 'query query)))
 754           (server (cadr (gnus-server-to-method srv)))
 755           (defs (caddr (gnus-server-to-method srv)))
 756           (criteria (or (cdr (assq 'criteria query))
 757                         (cdr (assoc nnir-imap-default-search-key
 758                                     nnir-imap-search-arguments))))
 759           (gnus-inhibit-demon t)
 760           (groups (or groups (nnir-get-active srv))))
 761       (message "Opening server %s" server)
 762       (apply
 763        'vconcat
 764        (mapcar
 765         (lambda (group)
 766           (let (artlist)
 767             (condition-case ()
 768                 (when (nnimap-possibly-change-group
 769                        (gnus-group-short-name group) server)
 770                   (with-current-buffer (nnimap-buffer)
 771                     (message "Searching %s..." group)
 772                     (let ((arts 0)
 773                           (result (nnimap-command "UID SEARCH %s"
 774                                                   (if (string= criteria "")
 775                                                       qstring
 776                                                     (nnir-imap-make-query
 777                                                      criteria qstring)))))
 778                       (mapc
 779                        (lambda (artnum) (push (vector group artnum 100) artlist)
 780                          (setq arts (1+ arts)))
 781                        (and (car result)
 782                             (delete 0 (mapcar #'string-to-number
 783                                               (cdr (assoc "SEARCH"
 784                                                           (cdr result)))))))
 785                       (message "Searching %s... %d matches" group arts)))
 786                   (message "Searching %s...done" group))
 787               (quit nil))
 788             artlist))
 789         groups)))))
 790
 791 (defun nnir-imap-make-query (criteria qstring)
 792   "Parse the query string and criteria into an appropriate IMAP search
 793 expression, returning the string query to make.
 794
 795 This implements a little language designed to return the expected results
 796 to an arbitrary query string to the end user.
 797
 798 The search is always case-insensitive, as defined by RFC2060, and supports
 799 the following features (inspired by the Google search input language):
 800
 801 Automatic \"and\" queries
 802     If you specify multiple words then they will be treated as an \"and\"
 803     expression intended to match all components.
 804
 805 Phrase searches
 806     If you wrap your query in double-quotes then it will be treated as a
 807     literal string.
 808
 809 Negative terms
 810     If you precede a term with \"-\" then it will negate that.
 811
 812 \"OR\" queries
 813     If you include an upper-case \"OR\" in your search it will cause the
 814     term before it and the term after it to be treated as alternatives.
 815
 816 In future the following will be added to the language:
 817  * support for date matches
 818  * support for location of text matching within the query
 819  * from/to/etc headers
 820  * additional search terms
 821  * flag based searching
 822  * anything else that the RFC supports, basically."
 823   ;; Walk through the query and turn it into an IMAP query string.
 824   (nnir-imap-query-to-imap criteria (nnir-imap-parse-query qstring)))
 825
 826
 827 (defun nnir-imap-query-to-imap (criteria query)
 828   "Turn a s-expression format query into IMAP."
 829   (mapconcat
 830    ;; Turn the expressions into IMAP text
 831    (lambda (item)
 832      (nnir-imap-expr-to-imap criteria item))
 833    ;; The query, already in s-expr format.
 834    query
 835    ;; Append a space between each expression
 836    " "))
 837
 838
 839 (defun nnir-imap-expr-to-imap (criteria expr)
 840   "Convert EXPR into an IMAP search expression on CRITERIA"
 841   ;; What sort of expression is this, eh?
 842   (cond
 843    ;; Simple string term
 844    ((stringp expr)
 845     (format "%s %S" criteria expr))
 846    ;; Trivial term: and
 847    ((eq expr 'and) nil)
 848    ;; Composite term: or expression
 849    ((eq (car-safe expr) 'or)
 850     (format "OR %s %s"
 851             (nnir-imap-expr-to-imap criteria (second expr))
 852             (nnir-imap-expr-to-imap criteria (third expr))))
 853    ;; Composite term: just the fax, mam
 854    ((eq (car-safe expr) 'not)
 855     (format "NOT (%s)" (nnir-imap-query-to-imap criteria (rest expr))))
 856    ;; Composite term: just expand it all.
 857    ((and (not (null expr)) (listp expr))
 858     (format "(%s)" (nnir-imap-query-to-imap criteria expr)))
 859    ;; Complex value, give up for now.
 860    (t (error "Unhandled input: %S" expr))))
 861
 862
 863 (defun nnir-imap-parse-query (string)
 864   "Turn STRING into an s-expression based query based on the IMAP
 865 query language as defined in `nnir-imap-make-query'.
 866
 867 This involves turning individual tokens into higher level terms
 868 that the search language can then understand and use."
 869   (with-temp-buffer
 870     ;; Set up the parsing environment.
 871     (insert string)
 872     (goto-char (point-min))
 873     ;; Now, collect the output terms and return them.
 874     (let (out)
 875       (while (not (nnir-imap-end-of-input))
 876         (push (nnir-imap-next-expr) out))
 877       (reverse out))))
 878
 879
 880 (defun nnir-imap-next-expr (&optional count)
 881   "Return the next expression from the current buffer."
 882   (let ((term (nnir-imap-next-term count))
 883         (next (nnir-imap-peek-symbol)))
 884     ;; Are we looking at an 'or' expression?
 885     (cond
 886      ;; Handle 'expr or expr'
 887      ((eq next 'or)
 888       (list 'or term (nnir-imap-next-expr 2)))
 889      ;; Anything else
 890      (t term))))
 891
 892
 893 (defun nnir-imap-next-term (&optional count)
 894   "Return the next TERM from the current buffer."
 895   (let ((term (nnir-imap-next-symbol count)))
 896     ;; What sort of term is this?
 897     (cond
 898      ;; and -- just ignore it
 899      ((eq term 'and) 'and)
 900      ;; negated term
 901      ((eq term 'not) (list 'not (nnir-imap-next-expr)))
 902      ;; generic term
 903      (t term))))
 904
 905
 906 (defun nnir-imap-peek-symbol ()
 907   "Return the next symbol from the current buffer, but don't consume it."
 908   (save-excursion
 909     (nnir-imap-next-symbol)))
 910
 911 (defun nnir-imap-next-symbol (&optional count)
 912   "Return the next symbol from the current buffer, or nil if we are
 913 at the end of the buffer.  If supplied COUNT skips some symbols before
 914 returning the one at the supplied position."
 915   (when (and (numberp count) (> count 1))
 916     (nnir-imap-next-symbol (1- count)))
 917   (let ((case-fold-search t))
 918     ;; end of input stream?
 919     (unless (nnir-imap-end-of-input)
 920       ;; No, return the next symbol from the stream.
 921       (cond
 922        ;; negated expression -- return it and advance one char.
 923        ((looking-at "-") (forward-char 1) 'not)
 924        ;; quoted string
 925        ((looking-at "\"") (nnir-imap-delimited-string "\""))
 926        ;; list expression -- we parse the content and return this as a list.
 927        ((looking-at "(")
 928         (nnir-imap-parse-query (nnir-imap-delimited-string ")")))
 929        ;; keyword input -- return a symbol version
 930        ((looking-at "\\band\\b") (forward-char 3) 'and)
 931        ((looking-at "\\bor\\b")  (forward-char 2) 'or)
 932        ((looking-at "\\bnot\\b") (forward-char 3) 'not)
 933        ;; Simple, boring keyword
 934        (t (let ((start (point))
 935                 (end (if (search-forward-regexp "[[:blank:]]" nil t)
 936                          (prog1
 937                              (match-beginning 0)
 938                            ;; unskip if we hit a non-blank terminal character.
 939                            (when (string-match "[^[:blank:]]" (match-string 0))
 940                              (backward-char 1)))
 941                        (goto-char (point-max)))))
 942             (buffer-substring start end)))))))
 943
 944 (defun nnir-imap-delimited-string (delimiter)
 945   "Return a delimited string from the current buffer."
 946   (let ((start (point)) end)
 947     (forward-char 1)                    ; skip the first delimiter.
 948     (while (not end)
 949       (unless (search-forward delimiter nil t)
 950         (error "Unmatched delimited input with %s in query" delimiter))
 951       (let ((here (point)))
 952         (unless (equal (buffer-substring (- here 2) (- here 1)) "\\")
 953           (setq end (point)))))
 954     (buffer-substring (1+ start) (1- end))))
 955
 956 (defun nnir-imap-end-of-input ()
 957   "Are we at the end of input?"
 958   (skip-chars-forward "[[:blank:]]")
 959   (looking-at "$"))
 960
 961
 962 ;; Swish++ interface.
 963 ;; -cc- Todo
 964 ;; Search by
 965 ;; - group
 966 ;; Sort by
 967 ;; - rank (default)
 968 ;; - article number
 969 ;; - file size
 970 ;; - group
 971 (defun nnir-run-swish++ (query server &optional group)
 972   "Run QUERY against swish++.
 973 Returns a vector of (group name, file name) pairs (also vectors,
 974 actually).
 975
 976 Tested with swish++ 4.7 on GNU/Linux and with swish++ 5.0b2 on
 977 Windows NT 4.0."
 978
 979   ;; (when group
 980   ;;   (error "The swish++ backend cannot search specific groups"))
 981
 982   (save-excursion
 983     (let ( (qstring (cdr (assq 'query query)))
 984            (groupspec (cdr (assq 'group query)))
 985            (prefix (nnir-read-server-parm 'nnir-swish++-remove-prefix server))
 986            artlist
 987            ;; nnml-use-compressed-files might be any string, but probably this
 988            ;; is sufficient.  Note that we can't only use the value of
 989            ;; nnml-use-compressed-files because old articles might have been
 990            ;; saved with a different value.
 991            (article-pattern (if (string= (gnus-group-server server) "nnmaildir")
 992                                 ":[0-9]+"
 993                               "^[0-9]+\\(\\.[a-z0-9]+\\)?$"))
 994            score artno dirnam filenam)
 995
 996       (when (equal "" qstring)
 997         (error "swish++: You didn't enter anything"))
 998
 999       (set-buffer (get-buffer-create nnir-tmp-buffer))
1000       (erase-buffer)
1001
1002       (if groupspec
1003           (message "Doing swish++ query %s on %s..." qstring groupspec)
1004         (message "Doing swish++ query %s..." qstring))
1005
1006       (let* ((cp-list `( ,nnir-swish++-program
1007                          nil            ; input from /dev/null
1008                          t              ; output
1009                          nil            ; don't redisplay
1010                          "--config-file" ,(nnir-read-server-parm 'nnir-swish++-configuration-file server)
1011                          ,@(nnir-read-server-parm 'nnir-swish++-additional-switches server)
1012                          ,qstring       ; the query, in swish++ format
1013                          ))
1014              (exitstatus
1015               (progn
1016                 (message "%s args: %s" nnir-swish++-program
1017                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1018                 (apply 'call-process cp-list))))
1019         (unless (or (null exitstatus)
1020                     (zerop exitstatus))
1021           (nnheader-report 'nnir "Couldn't run swish++: %s" exitstatus)
1022           ;; swish++ failure reason is in this buffer, show it if
1023           ;; the user wants it.
1024           (when (> gnus-verbose 6)
1025             (display-buffer nnir-tmp-buffer))))
1026
1027       ;; The results are output in the format of:
1028       ;; V 4.7 Linux
1029       ;; rank relative-path-name file-size file-title
1030       ;; V 5.0b2:
1031       ;; rank relative-path-name file-size topic??
1032       ;; where rank is an integer from 1 to 100.
1033       (goto-char (point-min))
1034       (while (re-search-forward
1035               "\\(^[0-9]+\\) \\([^ ]+\\) [0-9]+ \\(.*\\)$" nil t)
1036         (setq score (match-string 1)
1037               filenam (match-string 2)
1038               artno (file-name-nondirectory filenam)
1039               dirnam (file-name-directory filenam))
1040
1041         ;; don't match directories
1042         (when (string-match article-pattern artno)
1043           (when (not (null dirnam))
1044
1045             ;; maybe limit results to matching groups.
1046             (when (or (not groupspec)
1047                       (string-match groupspec dirnam))
1048               (nnir-add-result dirnam artno score prefix server artlist)))))
1049
1050       (message "Massaging swish++ output...done")
1051
1052       ;; Sort by score
1053       (apply 'vector
1054              (sort artlist
1055                    (function (lambda (x y)
1056                                (> (nnir-artitem-rsv x)
1057                                   (nnir-artitem-rsv y)))))))))
1058
1059 ;; Swish-E interface.
1060 (defun nnir-run-swish-e (query server &optional group)
1061   "Run given query against swish-e.
1062 Returns a vector of (group name, file name) pairs (also vectors,
1063 actually).
1064
1065 Tested with swish-e-2.0.1 on Windows NT 4.0."
1066
1067   ;; swish-e crashes with empty parameter to "-w" on commandline...
1068   ;; (when group
1069   ;;   (error "The swish-e backend cannot search specific groups"))
1070
1071   (save-excursion
1072     (let ((qstring (cdr (assq 'query query)))
1073           (prefix
1074            (or (nnir-read-server-parm 'nnir-swish-e-remove-prefix server)
1075                (error "Missing parameter `nnir-swish-e-remove-prefix'")))
1076           artlist score artno dirnam group )
1077
1078       (when (equal "" qstring)
1079         (error "swish-e: You didn't enter anything"))
1080
1081       (set-buffer (get-buffer-create nnir-tmp-buffer))
1082       (erase-buffer)
1083
1084       (message "Doing swish-e query %s..." query)
1085       (let* ((index-files
1086               (or (nnir-read-server-parm
1087                    'nnir-swish-e-index-files server)
1088                   (error "Missing parameter `nnir-swish-e-index-files'")))
1089              (additional-switches
1090               (nnir-read-server-parm
1091                'nnir-swish-e-additional-switches server))
1092              (cp-list `(,nnir-swish-e-program
1093                         nil             ; input from /dev/null
1094                         t               ; output
1095                         nil             ; don't redisplay
1096                         "-f" ,@index-files
1097                         ,@additional-switches
1098                         "-w"
1099                         ,qstring        ; the query, in swish-e format
1100                         ))
1101              (exitstatus
1102               (progn
1103                 (message "%s args: %s" nnir-swish-e-program
1104                          (mapconcat 'identity (cddddr cp-list) " "))
1105                 (apply 'call-process cp-list))))
1106         (unless (or (null exitstatus)
1107                     (zerop exitstatus))
1108           (nnheader-report 'nnir "Couldn't run swish-e: %s" exitstatus)
1109           ;; swish-e failure reason is in this buffer, show it if
1110           ;; the user wants it.
1111           (when (> gnus-verbose 6)
1112             (display-buffer nnir-tmp-buffer))))
1113
1114       ;; The results are output in the format of:
1115       ;; rank path-name file-title file-size
1116       (goto-char (point-min))
1117       (while (re-search-forward
1118               "\\(^[0-9]+\\) \\([^ ]+\\) \"\\([^\"]+\\)\" [0-9]+$" nil t)
1119         (setq score (match-string 1)
1120               artno (match-string 3)
1121               dirnam (file-name-directory (match-string 2)))
1122
1123         ;; don't match directories
1124         (when (string-match "^[0-9]+$" artno)
1125           (when (not (null dirnam))
1126
1127             ;; remove nnir-swish-e-remove-prefix from beginning of dirname
1128             (when (string-match (concat "^" prefix) dirnam)
1129               (setq dirnam (replace-match "" t t dirnam)))
1130
1131             (setq dirnam (substring dirnam 0 -1))
1132             ;; eliminate all ".", "/", "\" from beginning. Always matches.
1133             (string-match "^[./\\]*\\(.*\\)$" dirnam)
1134             ;; "/" -> "."
1135             (setq group (gnus-replace-in-string (match-string 1 dirnam) "/" "."))
1136             ;; Windows "\\" -> "."
1137             (setq group (gnus-replace-in-string group "\\\\" "."))
1138
1139             (push (vector (gnus-group-full-name group server)
1140                           (string-to-number artno)
1141                           (string-to-number score))
1142                   artlist))))
1143
1144       (message "Massaging swish-e output...done")
1145
1146       ;; Sort by score
1147       (apply 'vector
1148              (sort artlist
1149                    (function (lambda (x y)
1150                                (> (nnir-artitem-rsv x)
1151                                   (nnir-artitem-rsv y)))))))))
1152
1153 ;; HyREX interface
1154 (defun nnir-run-hyrex (query server &optional group)
1155   (save-excursion
1156     (let ((artlist nil)
1157           (groupspec (cdr (assq 'group query)))
1158           (qstring (cdr (assq 'query query)))
1159           (prefix (nnir-read-server-parm 'nnir-hyrex-remove-prefix server))
1160           score artno dirnam)
1161       (when (and (not groupspec) group)
1162         (setq groupspec
1163               (regexp-opt
1164                (mapcar (lambda (x) (gnus-group-real-name x)) group))))
1165       (set-buffer (get-buffer-create nnir-tmp-buffer))
1166       (erase-buffer)
1167       (message "Doing hyrex-search query %s..." query)
1168       (let* ((cp-list
1169               `( ,nnir-hyrex-program
1170                  nil                    ; input from /dev/null
1171                  t                      ; output
1172                  nil                    ; don't redisplay
1173                  "-i",(nnir-read-server-parm 'nnir-hyrex-index-directory server) ; index directory
1174                  ,@(nnir-read-server-parm 'nnir-hyrex-additional-switches server)
1175                  ,qstring          ; the query, in hyrex-search format
1176                  ))
1177              (exitstatus
1178               (progn
1179                 (message "%s args: %s" nnir-hyrex-program
1180                          (mapconcat 'identity (cddddr cp-list) " "))
1181                 (apply 'call-process cp-list))))
1182         (unless (or (null exitstatus)
1183                     (zerop exitstatus))
1184           (nnheader-report 'nnir "Couldn't run hyrex-search: %s" exitstatus)
1185           ;; nnir-search failure reason is in this buffer, show it if
1186           ;; the user wants it.
1187           (when (> gnus-verbose 6)
1188             (display-buffer nnir-tmp-buffer)))) ;; FIXME: Dont clear buffer !
1189       (message "Doing hyrex-search query \"%s\"...done" qstring)
1190       (sit-for 0)
1191       ;; nnir-search returns:
1192       ;;   for nnml/nnfolder: "filename mailid weigth"
1193       ;;   for nnimap:        "group mailid weigth"
1194       (goto-char (point-min))
1195       (delete-non-matching-lines "^\\S + [0-9]+ [0-9]+$")
1196       ;; HyREX doesn't search directly in groups -- so filter out here.
1197       (when groupspec
1198         (keep-lines groupspec))
1199       ;; extract data from result lines
1200       (goto-char (point-min))
1201       (while (re-search-forward
1202               "\\(\\S +\\) \\([0-9]+\\) \\([0-9]+\\)" nil t)
1203         (setq dirnam (match-string 1)
1204               artno (match-string 2)
1205               score (match-string 3))
1206         (when (string-match prefix dirnam)
1207           (setq dirnam (replace-match "" t t dirnam)))
1208         (push (vector (gnus-group-full-name
1209                        (gnus-replace-in-string dirnam "/" ".") server)
1210                       (string-to-number artno)
1211                       (string-to-number score))
1212               artlist))
1213       (message "Massaging hyrex-search output...done.")
1214       (apply 'vector
1215              (sort artlist
1216                    (function (lambda (x y)
1217                                (if (string-lessp (nnir-artitem-group x)
1218                                                  (nnir-artitem-group y))
1219                                    t
1220                                  (< (nnir-artitem-number x)
1221                                     (nnir-artitem-number y)))))))
1222       )))
1223
1224 ;; Namazu interface
1225 (defun nnir-run-namazu (query server &optional group)
1226   "Run given query against Namazu.  Returns a vector of (group name, file name)
1227 pairs (also vectors, actually).
1228
1229 Tested with Namazu 2.0.6 on a GNU/Linux system."
1230   ;; (when group
1231   ;;   (error "The Namazu backend cannot search specific groups"))
1232   (save-excursion
1233     (let ((article-pattern (if (string= (gnus-group-server server) "nnmaildir")
1234                                ":[0-9]+"
1235                              "^[0-9]+$"))
1236           artlist
1237           (qstring (cdr (assq 'query query)))
1238           (prefix (nnir-read-server-parm 'nnir-namazu-remove-prefix server))
1239           score group article
1240           (process-environment (copy-sequence process-environment)))
1241       (setenv "LC_MESSAGES" "C")
1242       (set-buffer (get-buffer-create nnir-tmp-buffer))
1243       (erase-buffer)
1244       (let* ((cp-list
1245               `( ,nnir-namazu-program
1246                  nil                    ; input from /dev/null
1247                  t                      ; output
1248                  nil                    ; don't redisplay
1249                  "-q"                   ; don't be verbose
1250                  "-a"                   ; show all matches
1251                  "-s"                   ; use short format
1252                  ,@(nnir-read-server-parm 'nnir-namazu-additional-switches server)
1253                  ,qstring               ; the query, in namazu format
1254                  ,(nnir-read-server-parm 'nnir-namazu-index-directory server) ; index directory
1255                  ))
1256              (exitstatus
1257               (progn
1258                 (message "%s args: %s" nnir-namazu-program
1259                          (mapconcat 'identity (cddddr cp-list) " "))
1260                 (apply 'call-process cp-list))))
1261         (unless (or (null exitstatus)
1262                     (zerop exitstatus))
1263           (nnheader-report 'nnir "Couldn't run namazu: %s" exitstatus)
1264           ;; Namazu failure reason is in this buffer, show it if
1265           ;; the user wants it.
1266           (when (> gnus-verbose 6)
1267             (display-buffer nnir-tmp-buffer))))
1268
1269       ;; Namazu output looks something like this:
1270       ;; 2. Re: Gnus agent expire broken (score: 55)
1271       ;; /home/henrik/Mail/mail/sent/1310 (4,138 bytes)
1272
1273       (goto-char (point-min))
1274       (while (re-search-forward
1275               "^\\([0-9]+\\.\\).*\\((score: \\([0-9]+\\)\\))\n\\([^ ]+\\)"
1276               nil t)
1277         (setq score (match-string 3)
1278               group (file-name-directory (match-string 4))
1279               article (file-name-nondirectory (match-string 4)))
1280
1281         ;; make sure article and group is sane
1282         (when (and (string-match article-pattern article)
1283                    (not (null group)))
1284           (nnir-add-result group article score prefix server artlist)))
1285
1286       ;; sort artlist by score
1287       (apply 'vector
1288              (sort artlist
1289                    (function (lambda (x y)
1290                                (> (nnir-artitem-rsv x)
1291                                   (nnir-artitem-rsv y)))))))))
1292
1293 (defun nnir-run-find-grep (query server &optional grouplist)
1294   "Run find and grep to obtain matching articles."
1295   (let* ((method (gnus-server-to-method server))
1296          (sym (intern
1297                (concat (symbol-name (car method)) "-directory")))
1298          (directory (cadr (assoc sym (cddr method))))
1299          (regexp (cdr (assoc 'query query)))
1300          (grep-options (cdr (assoc 'grep-options query)))
1301          (grouplist (or grouplist (nnir-get-active server)))
1302          artlist)
1303     (unless directory
1304       (error "No directory found in method specification of server %s"
1305              server))
1306     (apply
1307      'vconcat
1308      (mapcar (lambda (x)
1309                (let ((group x))
1310                  (message "Searching %s using find-grep..."
1311                           (or group server))
1312                  (save-window-excursion
1313                    (set-buffer (get-buffer-create nnir-tmp-buffer))
1314                    (erase-buffer)
1315                    (if (> gnus-verbose 6)
1316                        (pop-to-buffer (current-buffer)))
1317                    (cd directory) ; Using relative paths simplifies
1318                                   ; postprocessing.
1319                    (let ((group
1320                           (if (not group)
1321                               "."
1322                             ;; Try accessing the group literally as
1323                             ;; well as interpreting dots as directory
1324                             ;; separators so the engine works with
1325                             ;; plain nnml as well as the Gnus Cache.
1326                             (let ((group (gnus-group-real-name group)))
1327                               ;; Replace cl-func find-if.
1328                               (if (file-directory-p group)
1329                                   group
1330                                 (if (file-directory-p
1331                                      (setq group
1332                                            (gnus-replace-in-string
1333                                             group
1334                                             "\\." "/" t)))
1335                                     group))))))
1336                      (unless group
1337                        (error "Cannot locate directory for group"))
1338                      (save-excursion
1339                        (apply
1340                         'call-process "find" nil t
1341                         "find" group "-type" "f" "-name" "[0-9]*" "-exec"
1342                         "grep"
1343                         `("-l" ,@(and grep-options
1344                                       (split-string grep-options "\\s-" t))
1345                           "-e" ,regexp "{}" "+"))))
1346
1347                    ;; Translate relative paths to group names.
1348                    (while (not (eobp))
1349                      (let* ((path (split-string
1350                                    (buffer-substring
1351                                     (point)
1352                                     (line-end-position)) "/" t))
1353                             (art (string-to-number (car (last path)))))
1354                        (while (string= "." (car path))
1355                          (setq path (cdr path)))
1356                        (let ((group (mapconcat 'identity
1357                                                ;; Replace cl-func:
1358                                                ;; (subseq path 0 -1)
1359                                                (let ((end (1- (length path)))
1360                                                      res)
1361                                                  (while
1362                                                      (>= (setq end (1- end)) 0)
1363                                                    (push (pop path) res))
1364                                                  (nreverse res))
1365                                                ".")))
1366                          (push
1367                           (vector (gnus-group-full-name group server) art 0)
1368                           artlist))
1369                        (forward-line 1)))
1370                    (message "Searching %s using find-grep...done"
1371                             (or group server))
1372                    artlist)))
1373      grouplist))))
1374
1375 (declare-function mm-url-insert "mm-url" (url &optional follow-refresh))
1376 (declare-function mm-url-encode-www-form-urlencoded "mm-url" (pairs))
1377
1378 ;; gmane interface
1379 (defun nnir-run-gmane (query srv &optional groups)
1380   "Run a search against a gmane back-end server."
1381   (if (gnus-string-match-p
1382        "gmane.org$"
1383        (or (cadr (assoc 'nntp-address  (cddr (gnus-server-to-method srv))))
1384            ""))
1385       (let* ((case-fold-search t)
1386              (qstring (cdr (assq 'query query)))
1387              (server (cadr (gnus-server-to-method srv)))
1388              (groupspec (if groups
1389                             (mapconcat
1390                              (lambda (x)
1391                                (format "group:%s" (gnus-group-short-name x)))
1392                              groups " ") ""))
1393              (authorspec
1394               (if (assq 'author query)
1395                   (format "author:%s" (cdr (assq 'author query))) ""))
1396              (search (format "%s %s %s"
1397                              qstring groupspec authorspec))
1398              (gnus-inhibit-demon t)
1399              artlist)
1400         (require 'mm-url)
1401         (with-current-buffer (get-buffer-create nnir-tmp-buffer)
1402           (erase-buffer)
1403           (mm-url-insert
1404            (concat
1405             "http://search.gmane.org/nov.php"
1406             "?"
1407             (mm-url-encode-www-form-urlencoded
1408              `(("query" . ,search)
1409                ("HITSPERPAGE" . "999")))))
1410           (unless (featurep 'xemacs) (set-buffer-multibyte t))
1411           (mm-decode-coding-region (point-min) (point-max) 'utf-8)
1412           (goto-char (point-min))
1413           (forward-line 1)
1414           (while (not (eobp))
1415             (unless (or (eolp) (looking-at "\x0d"))
1416               (let ((header (nnheader-parse-nov)))
1417                 (let ((xref (mail-header-xref header))
1418                       (xscore (string-to-number (cdr (assoc 'X-Score
1419                                (mail-header-extra header))))))
1420                   (when (string-match " \\([^:]+\\)[:/]\\([0-9]+\\)" xref)
1421                     (push
1422                      (vector
1423                       (gnus-group-prefixed-name (match-string 1 xref) srv)
1424                       (string-to-number (match-string 2 xref)) xscore)
1425                      artlist)))))
1426             (forward-line 1)))
1427         (apply 'vector (nreverse (mm-delete-duplicates artlist))))
1428     (message "Can't search non-gmane nntp groups")
1429     nil))
1430
1431 ;;; Util Code:
1432
1433 (defun nnir-read-parms (query nnir-search-engine)
1434   "Reads additional search parameters according to `nnir-engines'."
1435   (let ((parmspec (caddr (assoc nnir-search-engine nnir-engines))))
1436     (append query
1437            (mapcar 'nnir-read-parm parmspec))))
1438
1439 (defun nnir-read-parm (parmspec)
1440   "Reads a single search parameter.
1441 `parmspec' is a cons cell, the car is a symbol, the cdr is a prompt."
1442   (let ((sym (car parmspec))
1443         (prompt (cdr parmspec)))
1444     (if (listp prompt)
1445         (let* ((result (apply 'gnus-completing-read prompt))
1446                (mapping (or (assoc result nnir-imap-search-arguments)
1447                             (cons nil nnir-imap-search-other))))
1448           (cons sym (format (cdr mapping) result)))
1449       (cons sym (read-string prompt)))))
1450
1451 (autoload 'gnus-group-topic-name "gnus-topic")
1452
1453 (defun nnir-run-query (query nserver)
1454   "Invoke appropriate search engine function (see `nnir-engines').
1455   If some groups were process-marked, run the query for each of the groups
1456   and concat the results."
1457   (let ((q (car (read-from-string query)))
1458         (groups (if (string= "all-ephemeral" nserver)
1459                     (with-current-buffer gnus-server-buffer
1460                       (list (list (gnus-server-server-name))))
1461                   (nnir-categorize
1462                    (or gnus-group-marked
1463                        (if (gnus-group-group-name)
1464                            (list (gnus-group-group-name))
1465                          (cdr (assoc (gnus-group-topic-name)
1466                                      gnus-topic-alist))))
1467                    gnus-group-server))))
1468     (apply 'vconcat
1469            (mapcar
1470             (lambda (x)
1471               (let* ((server (car x))
1472                      (nnir-search-engine
1473                       (or (nnir-read-server-parm 'nnir-search-engine
1474                                                  server)
1475                           (cdr (assoc (car
1476                                        (gnus-server-to-method server))
1477                                       nnir-method-default-engines))))
1478                      search-func)
1479                 (setq search-func (cadr (assoc nnir-search-engine
1480                                                nnir-engines)))
1481                 (if search-func
1482                     (funcall search-func
1483                              (if nnir-extra-parms
1484                                  (nnir-read-parms q nnir-search-engine)
1485                                q)
1486                              server (cadr x))
1487                   nil)))
1488             groups))))
1489
1490 (defun nnir-read-server-parm (key server)
1491   "Returns the parameter value of key for the given server, where
1492 server is of form 'backend:name'."
1493   (let ((method (gnus-server-to-method server)))
1494     (cond ((and method (assq key (cddr method)))
1495            (nth 1 (assq key (cddr method))))
1496           (t nil))))
1497
1498 (defun nnir-possibly-change-server (server)
1499   (unless (and server (nnir-server-opened server))
1500     (nnir-open-server server)))
1501
1502
1503
1504 ;; unused?
1505 (defun nnir-artlist-groups (artlist)
1506   "Returns a list of all groups in the given ARTLIST."
1507   (let ((res nil)
1508         (with-dups nil))
1509     ;; from each artitem, extract group component
1510     (setq with-dups (mapcar 'nnir-artitem-group artlist))
1511     ;; remove duplicates from above
1512     (mapc (function (lambda (x) (add-to-list 'res x)))
1513             with-dups)
1514     res))
1515
1516 (defun nnir-get-active (srv)
1517   (let ((method (gnus-server-to-method srv))
1518         groups)
1519     (gnus-request-list method)
1520     (with-current-buffer nntp-server-buffer
1521       (let ((cur (current-buffer))
1522             name)
1523         (goto-char (point-min))
1524         (unless (string= nnir-ignored-newsgroups "")
1525           (delete-matching-lines nnir-ignored-newsgroups))
1526         (if (eq (car method) 'nntp)
1527             (while (not (eobp))
1528               (ignore-errors
1529                 (push (mm-string-as-unibyte
1530                        (gnus-group-full-name
1531                         (buffer-substring
1532                          (point)
1533                          (progn
1534                            (skip-chars-forward "^ \t")
1535                            (point))) method))
1536                       groups))
1537               (forward-line))
1538           (while (not (eobp))
1539             (ignore-errors
1540               (push (mm-string-as-unibyte
1541                      (if (eq (char-after) ?\")
1542                          (gnus-group-full-name (read cur) method)
1543                        (let ((p (point)) (name ""))
1544                          (skip-chars-forward "^ \t\\\\")
1545                          (setq name (buffer-substring p (point)))
1546                          (while (eq (char-after) ?\\)
1547                            (setq p (1+ (point)))
1548                            (forward-char 2)
1549                            (skip-chars-forward "^ \t\\\\")
1550                            (setq name (concat name (buffer-substring
1551                                                     p (point)))))
1552                          (gnus-group-full-name name method))))
1553                     groups))
1554             (forward-line)))))
1555     groups))
1556
1557 (defun nnir-registry-action (action data-header from &optional to method)
1558   "Call `gnus-registry-action' with the original article group."
1559   (gnus-registry-action
1560    action
1561    data-header
1562    (nnir-article-group (mail-header-number data-header))
1563    to
1564    method))
1565
1566 (defun nnir-mode ()
1567   (when (eq (car (gnus-find-method-for-group gnus-newsgroup-name)) 'nnir)
1568     (setq gnus-summary-line-format
1569           (or nnir-summary-line-format gnus-summary-line-format))
1570     (remove-hook 'gnus-summary-article-delete-hook 'gnus-registry-action t)
1571     (remove-hook 'gnus-summary-article-move-hook 'gnus-registry-action t)
1572     (add-hook 'gnus-summary-article-delete-hook 'nnir-registry-action t t)
1573     (add-hook 'gnus-summary-article-move-hook 'nnir-registry-action t t)))
1574
1575
1576
1577 ;; The end.
1578 (provide 'nnir)
1579
1580 ;;; nnir.el ends here