cgit.sxemacs.org Git - gnus/blob - lisp/nnir.el

   1 ;;; nnir.el --- search mail with various search engines -*- coding: iso-8859-1 -*-
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Kai Großjohann <grossjohann@ls6.cs.uni-dortmund.de>
   7 ;; Swish-e and Swish++ backends by:
   8 ;;   Christoph Conrad <christoph.conrad@gmx.de>.
   9 ;; IMAP backend by: Simon Josefsson <jas@pdc.kth.se>.
  10 ;; IMAP search by: Torsten Hilbrich <torsten.hilbrich <at> gmx.net>
  11 ;; IMAP search improved by Daniel Pittman  <daniel@rimspace.net>.
  12 ;; nnmaildir support for Swish++ and Namazu backends by:
  13 ;;   Justus Piater <Justus <at> Piater.name>
  14 ;; Keywords: news mail searching ir
  15
  16 ;; This file is part of GNU Emacs.
  17
  18 ;; GNU Emacs is free software: you can redistribute it and/or modify
  19 ;; it under the terms of the GNU General Public License as published by
  20 ;; the Free Software Foundation, either version 3 of the License, or
  21 ;; (at your option) any later version.
  22
  23 ;; GNU Emacs is distributed in the hope that it will be useful,
  24 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  25 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26 ;; GNU General Public License for more details.
  27
  28 ;; You should have received a copy of the GNU General Public License
  29 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  30
  31 ;;; Commentary:
  32
  33 ;; TODO: Documentation in the Gnus manual
  34
  35 ;; Where in the existing gnus manual would this fit best?
  36
  37 ;; What does it do?  Well, it allows you to search your mail using
  38 ;; some search engine (imap, namazu, swish-e, gmane and others -- see
  39 ;; later) by typing `G G' in the Group buffer.  You will then get a
  40 ;; buffer which shows all articles matching the query, sorted by
  41 ;; Retrieval Status Value (score).
  42
  43 ;; When looking at the retrieval result (in the Summary buffer) you
  44 ;; can type `A W' (aka M-x gnus-warp-to-article RET) on an article.  You
  45 ;; will be warped into the group this article came from. Typing `A T'
  46 ;; (aka M-x gnus-summary-refer-thread RET) will warp to the group and
  47 ;; also show the thread this article is part of.
  48
  49 ;; The Lisp setup may involve setting a few variables and setting up the
  50 ;; search engine. You can define the variables in the server definition
  51 ;; like this :
  52 ;;   (setq gnus-secondary-select-methods '(
  53 ;;       (nnimap "" (nnimap-address "localhost")
  54 ;;                  (nnir-search-engine namazu)
  55 ;;       )))
  56 ;; The main variable to set is `nnir-search-engine'.  Choose one of
  57 ;; the engines listed in `nnir-engines'.  (Actually `nnir-engines' is
  58 ;; an alist, type `C-h v nnir-engines RET' for more information; this
  59 ;; includes examples for setting `nnir-search-engine', too.)
  60
  61 ;; If you use one of the local indices (namazu, find-grep, swish) you
  62 ;; must also set up a search engine backend.
  63
  64 ;; 1. Namazu
  65 ;;
  66 ;; The Namazu backend requires you to have one directory containing all
  67 ;; index files, this is controlled by the `nnir-namazu-index-directory'
  68 ;; variable.  To function the `nnir-namazu-remove-prefix' variable must
  69 ;; also be correct, see the documentation for `nnir-namazu-remove-prefix'
  70 ;; above.
  71 ;;
  72 ;; It is particularly important not to pass any any switches to namazu
  73 ;; that will change the output format.  Good switches to use include
  74 ;; `--sort', `--ascending', `--early' and `--late'.  Refer to the Namazu
  75 ;; documentation for further information on valid switches.
  76 ;;
  77 ;; To index my mail with the `mknmz' program I use the following
  78 ;; configuration file:
  79 ;;
  80 ;; ,----
  81 ;; | package conf;  # Don't remove this line!
  82 ;; |
  83 ;; | # Paths which will not be indexed. Don't use `^' or `$' anchors.
  84 ;; | $EXCLUDE_PATH = "spam|sent";
  85 ;; |
  86 ;; | # Header fields which should be searchable. case-insensitive
  87 ;; | $REMAIN_HEADER = "from|date|message-id|subject";
  88 ;; |
  89 ;; | # Searchable fields. case-insensitive
  90 ;; | $SEARCH_FIELD = "from|date|message-id|subject";
  91 ;; |
  92 ;; | # The max length of a word.
  93 ;; | $WORD_LENG_MAX = 128;
  94 ;; |
  95 ;; | # The max length of a field.
  96 ;; | $MAX_FIELD_LENGTH = 256;
  97 ;; `----
  98 ;;
  99 ;; My mail is stored in the directories ~/Mail/mail/, ~/Mail/lists/ and
 100 ;; ~/Mail/archive/, so to index them I go to the directory set in
 101 ;; `nnir-namazu-index-directory' and issue the following command.
 102 ;;
 103 ;;      mknmz --mailnews ~/Mail/archive/ ~/Mail/mail/ ~/Mail/lists/
 104 ;;
 105 ;; For maximum searching efficiency I have a cron job set to run this
 106 ;; command every four hours.
 107
 108 ;; 2. find-grep
 109 ;;
 110 ;; The find-grep engine simply runs find(1) to locate eligible
 111 ;; articles and searches them with grep(1).  This, of course, is much
 112 ;; slower than using a proper search engine but OTOH doesn't require
 113 ;; maintenance of an index and is still faster than using any built-in
 114 ;; means for searching.  The method specification of the server to
 115 ;; search must include a directory for this engine to work (E.g.,
 116 ;; `nnml-directory').  The tools must be POSIX compliant.  GNU Find
 117 ;; prior to version 4.2.12 (4.2.26 on Linux due to incorrect ARG_MAX
 118 ;; handling) does not work.
 119 ;; ,----
 120 ;; |    ;; find-grep configuration for searching the Gnus Cache
 121 ;; |
 122 ;; |    (nnml "cache"
 123 ;; |          (nnml-get-new-mail nil)
 124 ;; |          (nnir-search-engine find-grep)
 125 ;; |          (nnml-directory "~/News/cache/")
 126 ;; |          (nnml-active-file "~/News/cache/active"))
 127 ;; `----
 128
 129 ;; Developer information:
 130
 131 ;; I have tried to make the code expandable.  Basically, it is divided
 132 ;; into two layers.  The upper layer is somewhat like the `nnvirtual'
 133 ;; backend: given a specification of what articles to show from
 134 ;; another backend, it creates a group containing exactly those
 135 ;; articles.  The lower layer issues a query to a search engine and
 136 ;; produces such a specification of what articles to show from the
 137 ;; other backend.
 138
 139 ;; The interface between the two layers consists of the single
 140 ;; function `nnir-run-query', which just selects the appropriate
 141 ;; function for the search engine one is using.  The input to
 142 ;; `nnir-run-query' is a string, representing the query as input by
 143 ;; the user.  The output of `nnir-run-query' is supposed to be a
 144 ;; vector, each element of which should in turn be a three-element
 145 ;; vector.  The first element should be full group name of the article,
 146 ;; the second element should be the article number, and the third
 147 ;; element should be the Retrieval Status Value (RSV) as returned from
 148 ;; the search engine.  An RSV is the score assigned to the document by
 149 ;; the search engine.  For Boolean search engines, the
 150 ;; RSV is always 1000 (or 1 or 100, or whatever you like).
 151
 152 ;; The sorting order of the articles in the summary buffer created by
 153 ;; nnir is based on the order of the articles in the above mentioned
 154 ;; vector, so that's where you can do the sorting you'd like.  Maybe
 155 ;; it would be nice to have a way of displaying the search result
 156 ;; sorted differently?
 157
 158 ;; So what do you need to do when you want to add another search
 159 ;; engine?  You write a function that executes the query.  Temporary
 160 ;; data from the search engine can be put in `nnir-tmp-buffer'.  This
 161 ;; function should return the list of articles as a vector, as
 162 ;; described above.  Then, you need to register this backend in
 163 ;; `nnir-engines'.  Then, users can choose the backend by setting
 164 ;; `nnir-search-engine' as a server variable.
 165
 166 ;;; Code:
 167
 168 ;;; Setup:
 169
 170 ;; For Emacs <22.2 and XEmacs.
 171 (eval-and-compile
 172   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
 173
 174 (require 'nnoo)
 175 (require 'gnus-group)
 176 (require 'message)
 177 (require 'gnus-util)
 178 (eval-when-compile
 179   (require 'cl))
 180
 181 ;;; Internal Variables:
 182
 183 (defvar nnir-current-query nil
 184   "Internal: stores current query (= group name).")
 185
 186 (defvar nnir-current-server nil
 187   "Internal: stores current server (does it ever change?).")
 188
 189 (defvar nnir-current-group-marked nil
 190   "Internal: stores current list of process-marked groups.")
 191
 192 (defvar nnir-artlist nil
 193   "Internal: stores search result.")
 194
 195 (defvar nnir-tmp-buffer " *nnir*"
 196   "Internal: temporary buffer.")
 197
 198 (defvar nnir-search-history ()
 199   "Internal: the history for querying search options in nnir")
 200
 201 (defvar nnir-extra-parms nil
 202   "Internal: stores request for extra search parms")
 203
 204 ;; Imap variables
 205
 206 (defvar nnir-imap-search-arguments
 207   '(("Whole message" . "TEXT")
 208     ("Subject" . "SUBJECT")
 209     ("To" . "TO")
 210     ("From" . "FROM")
 211     ("Imap" . ""))
 212   "Mapping from user readable keys to IMAP search items for use in nnir")
 213
 214 (defvar nnir-imap-search-other "HEADER %S"
 215   "The IMAP search item to use for anything other than
 216   `nnir-imap-search-arguments'. By default this is the name of an
 217   email header field")
 218
 219 (defvar nnir-imap-search-argument-history ()
 220   "The history for querying search options in nnir")
 221
 222 ;;; Helper macros
 223
 224 ;; Data type article list.
 225
 226 (defmacro nnir-artlist-length (artlist)
 227   "Returns number of articles in artlist."
 228   `(length ,artlist))
 229
 230 (defmacro nnir-artlist-article (artlist n)
 231   "Returns from ARTLIST the Nth artitem (counting starting at 1)."
 232   `(when (> ,n 0)
 233      (elt ,artlist (1- ,n))))
 234
 235 (defmacro nnir-artitem-group (artitem)
 236   "Returns the group from the ARTITEM."
 237   `(elt ,artitem 0))
 238
 239 (defmacro nnir-artitem-number (artitem)
 240   "Returns the number from the ARTITEM."
 241   `(elt ,artitem 1))
 242
 243 (defmacro nnir-artitem-rsv (artitem)
 244   "Returns the Retrieval Status Value (RSV, score) from the ARTITEM."
 245   `(elt ,artitem 2))
 246
 247 (defmacro nnir-article-group (article)
 248   "Returns the group for ARTICLE"
 249   `(nnir-artitem-group (nnir-artlist-article nnir-artlist ,article)))
 250
 251 (defmacro nnir-article-number (article)
 252   "Returns the number for ARTICLE"
 253   `(nnir-artitem-number (nnir-artlist-article nnir-artlist ,article)))
 254
 255 (defmacro nnir-article-rsv (article)
 256   "Returns the rsv for ARTICLE"
 257   `(nnir-artitem-rsv (nnir-artlist-article nnir-artlist ,article)))
 258
 259 (defsubst nnir-article-ids (article)
 260   "Returns the pair `(nnir id . real id)' of ARTICLE"
 261   (cons article (nnir-article-number article)))
 262
 263 (defmacro nnir-categorize (sequence keyfunc &optional valuefunc)
 264   "Sorts a sequence into categories and returns a list of the form
 265 `((key1 (element11 element12)) (key2 (element21 element22))'.
 266 The category key for a member of the sequence is obtained
 267 as `(keyfunc member)' and the corresponding element is just
 268 `member'. If `valuefunc' is non-nil, the element of the list
 269 is `(valuefunc member)'."
 270   `(unless (null ,sequence)
 271      (let (value)
 272        (mapc
 273         (lambda (member)
 274           (let ((y (,keyfunc member))
 275                 (x ,(if valuefunc
 276                         `(,valuefunc member)
 277                       'member)))
 278             (if (assoc y value)
 279                 (push x (cadr (assoc y value)))
 280               (push (list y (list x)) value))))
 281         ,sequence)
 282        value)))
 283
 284 ;;; Finish setup:
 285
 286 (require 'gnus-sum)
 287
 288 (eval-when-compile
 289   (autoload 'nnimap-buffer "nnimap")
 290   (autoload 'nnimap-command "nnimap")
 291   (autoload 'nnimap-possibly-change-group "nnimap")
 292   (autoload 'gnus-registry-action "gnus-registry"))
 293
 294 (nnoo-declare nnir)
 295 (nnoo-define-basics nnir)
 296
 297 (gnus-declare-backend "nnir" 'mail)
 298
 299
 300 ;;; User Customizable Variables:
 301
 302 (defgroup nnir nil
 303   "Search groups in Gnus with assorted seach engines."
 304   :group 'gnus)
 305
 306 (defcustom nnir-method-default-engines
 307   '((nnimap . imap)
 308     (nntp . gmane))
 309   "*Alist of default search engines keyed by server method."
 310   :type '(alist)
 311   :group 'nnir)
 312
 313 (defcustom nnir-ignored-newsgroups ""
 314   "*A regexp to match newsgroups in the active file that should
 315   be skipped when searching."
 316   :type '(regexp)
 317   :group 'nnir)
 318
 319 (defcustom nnir-summary-line-format nil
 320   "*The format specification of the lines in an nnir summary buffer.
 321
 322 All the items from `gnus-summary-line-format' are available, along
 323 with three items unique to nnir summary buffers:
 324
 325 %Z    Search retrieval score value (integer)
 326 %G    Article original full group name (string)
 327 %g    Article original short group name (string)
 328
 329 If nil this will use `gnus-summary-line-format'."
 330   :type '(regexp)
 331   :group 'nnir)
 332
 333 (defcustom nnir-retrieve-headers-override-function nil
 334   "*If non-nil, a function that accepts an article list and group
 335 and populates the `nntp-server-buffer' with the retrieved
 336 headers. Must return either 'nov or 'headers indicating the
 337 retrieved header format.
 338
 339 If this variable is nil, or if the provided function returns nil for a search
 340 result, `gnus-retrieve-headers' will be called instead."
 341   :type '(function)
 342   :group 'nnir)
 343
 344 (defcustom nnir-imap-default-search-key "Whole message"
 345   "*The default IMAP search key for an nnir search. Must be one of
 346   the keys in `nnir-imap-search-arguments'. To use raw imap queries
 347   by default set this to \"Imap\"."
 348   :type '(string)
 349   :group 'nnir)
 350
 351 (defcustom nnir-swish++-configuration-file
 352   (expand-file-name "~/Mail/swish++.conf")
 353   "*Configuration file for swish++."
 354   :type '(file)
 355   :group 'nnir)
 356
 357 (defcustom nnir-swish++-program "search"
 358   "*Name of swish++ search executable."
 359   :type '(string)
 360   :group 'nnir)
 361
 362 (defcustom nnir-swish++-additional-switches '()
 363   "*A list of strings, to be given as additional arguments to swish++.
 364
 365 Note that this should be a list.  Ie, do NOT use the following:
 366     (setq nnir-swish++-additional-switches \"-i -w\") ; wrong
 367 Instead, use this:
 368     (setq nnir-swish++-additional-switches '(\"-i\" \"-w\"))"
 369   :type '(repeat (string))
 370   :group 'nnir)
 371
 372 (defcustom nnir-swish++-remove-prefix (concat (getenv "HOME") "/Mail/")
 373   "*The prefix to remove from each file name returned by swish++
 374 in order to get a group name (albeit with / instead of .).  This is a
 375 regular expression.
 376
 377 This variable is very similar to `nnir-namazu-remove-prefix', except
 378 that it is for swish++, not Namazu."
 379   :type '(regexp)
 380   :group 'nnir)
 381
 382 ;; Swish-E.
 383 ;; URL: http://swish-e.org/
 384 ;; Variables `nnir-swish-e-index-file', `nnir-swish-e-program' and
 385 ;; `nnir-swish-e-additional-switches'
 386
 387 (make-obsolete-variable 'nnir-swish-e-index-file
 388                         'nnir-swish-e-index-files "Emacs 23.1")
 389 (defcustom nnir-swish-e-index-file
 390   (expand-file-name "~/Mail/index.swish-e")
 391   "*Index file for swish-e.
 392 This could be a server parameter.
 393 It is never consulted once `nnir-swish-e-index-files', which should be
 394 used instead, has been customized."
 395   :type '(file)
 396   :group 'nnir)
 397
 398 (defcustom nnir-swish-e-index-files
 399   (list nnir-swish-e-index-file)
 400   "*List of index files for swish-e.
 401 This could be a server parameter."
 402   :type '(repeat (file))
 403   :group 'nnir)
 404
 405 (defcustom nnir-swish-e-program "swish-e"
 406   "*Name of swish-e search executable.
 407 This cannot be a server parameter."
 408   :type '(string)
 409   :group 'nnir)
 410
 411 (defcustom nnir-swish-e-additional-switches '()
 412   "*A list of strings, to be given as additional arguments to swish-e.
 413
 414 Note that this should be a list.  Ie, do NOT use the following:
 415     (setq nnir-swish-e-additional-switches \"-i -w\") ; wrong
 416 Instead, use this:
 417     (setq nnir-swish-e-additional-switches '(\"-i\" \"-w\"))
 418
 419 This could be a server parameter."
 420   :type '(repeat (string))
 421   :group 'nnir)
 422
 423 (defcustom nnir-swish-e-remove-prefix (concat (getenv "HOME") "/Mail/")
 424   "*The prefix to remove from each file name returned by swish-e
 425 in order to get a group name (albeit with / instead of .).  This is a
 426 regular expression.
 427
 428 This variable is very similar to `nnir-namazu-remove-prefix', except
 429 that it is for swish-e, not Namazu.
 430
 431 This could be a server parameter."
 432   :type '(regexp)
 433   :group 'nnir)
 434
 435 ;; HyREX engine, see <URL:http://ls6-www.cs.uni-dortmund.de/>
 436
 437 (defcustom nnir-hyrex-program "nnir-search"
 438   "*Name of the nnir-search executable."
 439   :type '(string)
 440   :group 'nnir)
 441
 442 (defcustom nnir-hyrex-additional-switches '()
 443   "*A list of strings, to be given as additional arguments for nnir-search.
 444 Note that this should be a list. Ie, do NOT use the following:
 445     (setq nnir-hyrex-additional-switches \"-ddl ddl.xml -c nnir\") ; wrong !
 446 Instead, use this:
 447     (setq nnir-hyrex-additional-switches '(\"-ddl\" \"ddl.xml\" \"-c\" \"nnir\"))"
 448   :type '(repeat (string))
 449   :group 'nnir)
 450
 451 (defcustom nnir-hyrex-index-directory (getenv "HOME")
 452   "*Index directory for HyREX."
 453   :type '(directory)
 454   :group 'nnir)
 455
 456 (defcustom nnir-hyrex-remove-prefix (concat (getenv "HOME") "/Mail/")
 457   "*The prefix to remove from each file name returned by HyREX
 458 in order to get a group name (albeit with / instead of .).
 459
 460 For example, suppose that HyREX returns file names such as
 461 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 462 setting:  (setq nnir-hyrex-remove-prefix \"/home/john/Mail/\")
 463 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 464 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 465 arrive at the correct group name, \"mail.misc\"."
 466   :type '(directory)
 467   :group 'nnir)
 468
 469 ;; Namazu engine, see <URL:http://www.namazu.org/>
 470
 471 (defcustom nnir-namazu-program "namazu"
 472   "*Name of Namazu search executable."
 473   :type '(string)
 474   :group 'nnir)
 475
 476 (defcustom nnir-namazu-index-directory (expand-file-name "~/Mail/namazu/")
 477   "*Index directory for Namazu."
 478   :type '(directory)
 479   :group 'nnir)
 480
 481 (defcustom nnir-namazu-additional-switches '()
 482   "*A list of strings, to be given as additional arguments to namazu.
 483 The switches `-q', `-a', and `-s' are always used, very few other switches
 484 make any sense in this context.
 485
 486 Note that this should be a list.  Ie, do NOT use the following:
 487     (setq nnir-namazu-additional-switches \"-i -w\") ; wrong
 488 Instead, use this:
 489     (setq nnir-namazu-additional-switches '(\"-i\" \"-w\"))"
 490   :type '(repeat (string))
 491   :group 'nnir)
 492
 493 (defcustom nnir-namazu-remove-prefix (concat (getenv "HOME") "/Mail/")
 494   "*The prefix to remove from each file name returned by Namazu
 495 in order to get a group name (albeit with / instead of .).
 496
 497 For example, suppose that Namazu returns file names such as
 498 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 499 setting:  (setq nnir-namazu-remove-prefix \"/home/john/Mail/\")
 500 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 501 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 502 arrive at the correct group name, \"mail.misc\"."
 503   :type '(directory)
 504   :group 'nnir)
 505
 506 ;;; Developer Extension Variable:
 507
 508 (defvar nnir-engines
 509   `((imap    nnir-run-imap
 510              ((criteria
 511                "Imap Search in"                   ; Prompt
 512                ,(mapcar 'car nnir-imap-search-arguments) ; alist for completing
 513                nil                                ; allow any user input
 514                nil                                ; initial value
 515                nnir-imap-search-argument-history  ; the history to use
 516                ,nnir-imap-default-search-key      ; default
 517                )))
 518     (gmane   nnir-run-gmane
 519              ((author . "Gmane Author: ")))
 520     (swish++ nnir-run-swish++
 521              ((group . "Swish++ Group spec: ")))
 522     (swish-e nnir-run-swish-e
 523              ((group . "Swish-e Group spec: ")))
 524     (namazu  nnir-run-namazu
 525              ())
 526     (hyrex   nnir-run-hyrex
 527              ((group . "Hyrex Group spec: ")))
 528     (find-grep nnir-run-find-grep
 529                ((grep-options . "Grep options: "))))
 530   "Alist of supported search engines.
 531 Each element in the alist is a three-element list (ENGINE FUNCTION ARGS).
 532 ENGINE is a symbol designating the searching engine.  FUNCTION is also
 533 a symbol, giving the function that does the search.  The third element
 534 ARGS is a list of cons pairs (PARAM . PROMPT).  When issuing a query,
 535 the FUNCTION will issue a query for each of the PARAMs, using PROMPT.
 536
 537 The value of `nnir-search-engine' must be one of the ENGINE symbols.
 538 For example, for searching a server using namazu include
 539     (nnir-search-engine namazu)
 540 in the server definition.  Note that you have to set additional
 541 variables for most backends.  For example, the `namazu' backend
 542 needs the variables `nnir-namazu-program',
 543 `nnir-namazu-index-directory' and `nnir-namazu-remove-prefix'.
 544
 545 Add an entry here when adding a new search engine.")
 546
 547
 548 ;; Gnus glue.
 549
 550 (defun gnus-group-make-nnir-group (nnir-extra-parms)
 551   "Create an nnir group.  Asks for query."
 552   (interactive "P")
 553   (setq nnir-current-query nil
 554         nnir-current-server nil
 555         nnir-current-group-marked nil
 556         nnir-artlist nil)
 557   (let* ((query (read-string "Query: " nil 'nnir-search-history))
 558          (parms (list (cons 'query query)))
 559          (srv (if (gnus-server-server-name)
 560                   "all" "")))
 561     (add-to-list 'parms (cons 'unique-id (message-unique-id)) t)
 562     (gnus-group-read-ephemeral-group
 563      (concat "nnir:" (prin1-to-string parms)) (list 'nnir srv) t
 564      (cons (current-buffer) gnus-current-window-configuration)
 565      nil)))
 566
 567
 568 ;; Gnus backend interface functions.
 569
 570 (deffoo nnir-open-server (server &optional definitions)
 571   ;; Just set the server variables appropriately.
 572   (add-hook 'gnus-summary-mode-hook 'nnir-mode)
 573   (nnoo-change-server 'nnir server definitions))
 574
 575 (deffoo nnir-request-group (group &optional server fast info)
 576   "GROUP is the query string."
 577   (nnir-possibly-change-server server)
 578   ;; Check for cache and return that if appropriate.
 579   (if (and (equal group nnir-current-query)
 580            (equal gnus-group-marked nnir-current-group-marked)
 581            (or (null server)
 582                (equal server nnir-current-server)))
 583       nnir-artlist
 584     ;; Cache miss.
 585     (setq nnir-artlist (nnir-run-query group server)))
 586   (with-current-buffer nntp-server-buffer
 587     (setq nnir-current-query group)
 588     (when server (setq nnir-current-server server))
 589     (setq nnir-current-group-marked gnus-group-marked)
 590     (if (zerop (length nnir-artlist))
 591         (nnheader-report 'nnir "Search produced empty results.")
 592       ;; Remember data for cache.
 593       (nnheader-insert "211 %d %d %d %s\n"
 594                        (nnir-artlist-length nnir-artlist) ; total #
 595                        1              ; first #
 596                        (nnir-artlist-length nnir-artlist) ; last #
 597                        group))))      ; group name
 598
 599 (deffoo nnir-retrieve-headers (articles &optional group server fetch-old)
 600   (with-current-buffer nntp-server-buffer
 601     (let ((gnus-inhibit-demon t)
 602           (articles-by-group (nnir-categorize
 603                               articles nnir-article-group nnir-article-ids))
 604           headers)
 605       (while (not (null articles-by-group))
 606         (let* ((group-articles (pop articles-by-group))
 607                (artgroup (car group-articles))
 608                (articleids (cadr group-articles))
 609                (artlist (sort (mapcar 'cdr articleids) '<))
 610                (server (gnus-group-server artgroup))
 611                (gnus-override-method (gnus-server-to-method server))
 612                parsefunc)
 613           ;; (or (numberp art)
 614           ;;     (nnheader-report
 615           ;;      'nnir
 616           ;;      "nnir-retrieve-headers doesn't grok message ids: %s"
 617           ;;      art))
 618           (nnir-possibly-change-server server)
 619           ;; is this needed?
 620           (erase-buffer)
 621           (case (setq gnus-headers-retrieved-by
 622                       (or
 623                        (and
 624                         nnir-retrieve-headers-override-function
 625                         (funcall nnir-retrieve-headers-override-function
 626                                  artlist artgroup))
 627                        (gnus-retrieve-headers artlist artgroup nil)))
 628             (nov
 629              (setq parsefunc 'nnheader-parse-nov))
 630             (headers
 631              (setq parsefunc 'nnheader-parse-head))
 632             (t (error "Unknown header type %s while requesting articles \
 633                     of group %s" gnus-headers-retrieved-by artgroup)))
 634           (goto-char (point-min))
 635           (while (not (eobp))
 636             (let* ((novitem (funcall parsefunc))
 637                    (artno (mail-header-number novitem))
 638                    (art (car (rassoc artno articleids))))
 639               (when art
 640                 (mail-header-set-number novitem art)
 641                 (push novitem headers))
 642               (forward-line 1)))))
 643       (setq headers
 644             (sort headers
 645                   (lambda (x y)
 646                     (< (mail-header-number x) (mail-header-number y)))))
 647       (erase-buffer)
 648       (mapc 'nnheader-insert-nov headers)
 649       'nov)))
 650
 651 (deffoo nnir-request-article (article &optional group server to-buffer)
 652   (if (stringp article)
 653       (nnheader-report
 654        'nnir
 655        "nnir-retrieve-headers doesn't grok message ids: %s"
 656        article)
 657     (save-excursion
 658       (let ((artfullgroup (nnir-article-group article))
 659             (artno (nnir-article-number article))
 660             ;; Bug?
 661             ;; Why must we bind nntp-server-buffer here?  It won't
 662             ;; work if `buf' is used, say.  (Of course, the set-buffer
 663             ;; line below must then be updated, too.)
 664             (nntp-server-buffer (or to-buffer nntp-server-buffer)))
 665         (set-buffer nntp-server-buffer)
 666         (erase-buffer)
 667         (message "Requesting article %d from group %s"
 668                  artno artfullgroup)
 669         (gnus-request-article artno artfullgroup nntp-server-buffer)
 670         (cons artfullgroup artno)))))
 671
 672 (deffoo nnir-request-move-article (article group server accept-form
 673                                            &optional last internal-move-group)
 674   (let* ((artfullgroup (nnir-article-group article))
 675          (artno (nnir-article-number article))
 676          (to-newsgroup (nth 1 accept-form))
 677          (to-method (gnus-find-method-for-group to-newsgroup))
 678          (from-method (gnus-find-method-for-group artfullgroup))
 679          (move-is-internal (gnus-server-equal from-method to-method))
 680          (artsubject (mail-header-subject
 681                       (gnus-data-header
 682                        (assoc article (gnus-data-list nil))))))
 683     (unless (gnus-check-backend-function
 684              'request-move-article artfullgroup)
 685       (error "The group %s does not support article moving" artfullgroup))
 686     (gnus-request-move-article
 687      artno
 688      artfullgroup
 689      (nth 1 from-method)
 690      accept-form
 691      last
 692      (and move-is-internal
 693           to-newsgroup          ; Not respooling
 694           (gnus-group-real-name to-newsgroup)))))
 695
 696 (deffoo nnir-warp-to-article ()
 697   (let* ((cur (if (> (gnus-summary-article-number) 0)
 698                   (gnus-summary-article-number)
 699                 (error "This is not a real article.")))
 700          (gnus-newsgroup-name (nnir-article-group cur))
 701          (backend-number (nnir-article-number cur)))
 702     (gnus-summary-read-group-1 gnus-newsgroup-name t t gnus-summary-buffer
 703                                nil (list backend-number))))
 704
 705 (nnoo-define-skeleton nnir)
 706
 707
 708 (defmacro nnir-add-result (dirnam artno score prefix server artlist)
 709   "Ask `nnir-compose-result' to construct a result vector,
 710 and if it is non-nil, add it to artlist."
 711   `(let ((result (nnir-compose-result ,dirnam ,artno ,score ,prefix ,server)))
 712      (when (not (null result))
 713        (push result ,artlist))))
 714
 715 (autoload 'nnmaildir-base-name-to-article-number "nnmaildir")
 716
 717 ;; Helper function currently used by the Swish++ and Namazu backends;
 718 ;; perhaps useful for other backends as well
 719 (defun nnir-compose-result (dirnam article score prefix server)
 720   "Extract the group from dirnam, and create a result vector
 721 ready to be added to the list of search results."
 722
 723   ;; remove nnir-*-remove-prefix from beginning of dirnam filename
 724   (when (string-match (concat "^" prefix) dirnam)
 725     (setq dirnam (replace-match "" t t dirnam)))
 726
 727   (when (file-readable-p (concat prefix dirnam article))
 728     ;; remove trailing slash and, for nnmaildir, cur/new/tmp
 729     (setq dirnam
 730           (substring dirnam 0
 731                      (if (string= (gnus-group-server server) "nnmaildir")
 732                          -5 -1)))
 733
 734     ;; Set group to dirnam without any leading dots or slashes,
 735     ;; and with all subsequent slashes replaced by dots
 736     (let ((group (gnus-replace-in-string
 737                  (gnus-replace-in-string dirnam "^[./\\]" "" t)
 738                  "[/\\]" "." t)))
 739
 740     (vector (gnus-group-full-name group server)
 741             (if (string= (gnus-group-server server) "nnmaildir")
 742                 (nnmaildir-base-name-to-article-number
 743                  (substring article 0 (string-match ":" article))
 744                  group nil)
 745               (string-to-number article))
 746             (string-to-number score)))))
 747
 748 ;;; Search Engine Interfaces:
 749
 750 ;; imap interface
 751 (defun nnir-run-imap (query srv &optional groups)
 752   "Run a search against an IMAP back-end server.
 753 This uses a custom query language parser; see `nnir-imap-make-query' for
 754 details on the language and supported extensions"
 755   (save-excursion
 756     (let ((qstring (cdr (assq 'query query)))
 757           (server (cadr (gnus-server-to-method srv)))
 758           (defs (caddr (gnus-server-to-method srv)))
 759           (criteria (or (cdr (assq 'criteria query))
 760                         (cdr (assoc nnir-imap-default-search-key
 761                                     nnir-imap-search-arguments))))
 762           (gnus-inhibit-demon t)
 763           (groups (or groups (nnir-get-active srv))))
 764       (message "Opening server %s" server)
 765       (apply
 766        'vconcat
 767        (mapcar
 768         (lambda (group)
 769           (let (artlist)
 770             (condition-case ()
 771                 (when (nnimap-possibly-change-group
 772                        (gnus-group-short-name group) server)
 773                   (with-current-buffer (nnimap-buffer)
 774                     (message "Searching %s..." group)
 775                     (let ((arts 0)
 776                           (result (nnimap-command "UID SEARCH %s"
 777                                                   (if (string= criteria "")
 778                                                       qstring
 779                                                     (nnir-imap-make-query
 780                                                      criteria qstring)))))
 781                       (mapc
 782                        (lambda (artnum) (push (vector group artnum 100) artlist)
 783                          (setq arts (1+ arts)))
 784                        (and (car result)
 785                             (delete 0 (mapcar #'string-to-number
 786                                               (cdr (assoc "SEARCH"
 787                                                           (cdr result)))))))
 788                       (message "Searching %s... %d matches" group arts)))
 789                   (message "Searching %s...done" group))
 790               (quit nil))
 791             artlist))
 792         groups)))))
 793
 794 (defun nnir-imap-make-query (criteria qstring)
 795   "Parse the query string and criteria into an appropriate IMAP search
 796 expression, returning the string query to make.
 797
 798 This implements a little language designed to return the expected results
 799 to an arbitrary query string to the end user.
 800
 801 The search is always case-insensitive, as defined by RFC2060, and supports
 802 the following features (inspired by the Google search input language):
 803
 804 Automatic \"and\" queries
 805     If you specify multiple words then they will be treated as an \"and\"
 806     expression intended to match all components.
 807
 808 Phrase searches
 809     If you wrap your query in double-quotes then it will be treated as a
 810     literal string.
 811
 812 Negative terms
 813     If you precede a term with \"-\" then it will negate that.
 814
 815 \"OR\" queries
 816     If you include an upper-case \"OR\" in your search it will cause the
 817     term before it and the term after it to be treated as alternatives.
 818
 819 In future the following will be added to the language:
 820  * support for date matches
 821  * support for location of text matching within the query
 822  * from/to/etc headers
 823  * additional search terms
 824  * flag based searching
 825  * anything else that the RFC supports, basically."
 826   ;; Walk through the query and turn it into an IMAP query string.
 827   (nnir-imap-query-to-imap criteria (nnir-imap-parse-query qstring)))
 828
 829
 830 (defun nnir-imap-query-to-imap (criteria query)
 831   "Turn a s-expression format query into IMAP."
 832   (mapconcat
 833    ;; Turn the expressions into IMAP text
 834    (lambda (item)
 835      (nnir-imap-expr-to-imap criteria item))
 836    ;; The query, already in s-expr format.
 837    query
 838    ;; Append a space between each expression
 839    " "))
 840
 841
 842 (defun nnir-imap-expr-to-imap (criteria expr)
 843   "Convert EXPR into an IMAP search expression on CRITERIA"
 844   ;; What sort of expression is this, eh?
 845   (cond
 846    ;; Simple string term
 847    ((stringp expr)
 848     (format "%s %S" criteria expr))
 849    ;; Trivial term: and
 850    ((eq expr 'and) nil)
 851    ;; Composite term: or expression
 852    ((eq (car-safe expr) 'or)
 853     (format "OR %s %s"
 854             (nnir-imap-expr-to-imap criteria (second expr))
 855             (nnir-imap-expr-to-imap criteria (third expr))))
 856    ;; Composite term: just the fax, mam
 857    ((eq (car-safe expr) 'not)
 858     (format "NOT (%s)" (nnir-imap-query-to-imap criteria (rest expr))))
 859    ;; Composite term: just expand it all.
 860    ((and (not (null expr)) (listp expr))
 861     (format "(%s)" (nnir-imap-query-to-imap criteria expr)))
 862    ;; Complex value, give up for now.
 863    (t (error "Unhandled input: %S" expr))))
 864
 865
 866 (defun nnir-imap-parse-query (string)
 867   "Turn STRING into an s-expression based query based on the IMAP
 868 query language as defined in `nnir-imap-make-query'.
 869
 870 This involves turning individual tokens into higher level terms
 871 that the search language can then understand and use."
 872   (with-temp-buffer
 873     ;; Set up the parsing environment.
 874     (insert string)
 875     (goto-char (point-min))
 876     ;; Now, collect the output terms and return them.
 877     (let (out)
 878       (while (not (nnir-imap-end-of-input))
 879         (push (nnir-imap-next-expr) out))
 880       (reverse out))))
 881
 882
 883 (defun nnir-imap-next-expr (&optional count)
 884   "Return the next expression from the current buffer."
 885   (let ((term (nnir-imap-next-term count))
 886         (next (nnir-imap-peek-symbol)))
 887     ;; Are we looking at an 'or' expression?
 888     (cond
 889      ;; Handle 'expr or expr'
 890      ((eq next 'or)
 891       (list 'or term (nnir-imap-next-expr 2)))
 892      ;; Anything else
 893      (t term))))
 894
 895
 896 (defun nnir-imap-next-term (&optional count)
 897   "Return the next TERM from the current buffer."
 898   (let ((term (nnir-imap-next-symbol count)))
 899     ;; What sort of term is this?
 900     (cond
 901      ;; and -- just ignore it
 902      ((eq term 'and) 'and)
 903      ;; negated term
 904      ((eq term 'not) (list 'not (nnir-imap-next-expr)))
 905      ;; generic term
 906      (t term))))
 907
 908
 909 (defun nnir-imap-peek-symbol ()
 910   "Return the next symbol from the current buffer, but don't consume it."
 911   (save-excursion
 912     (nnir-imap-next-symbol)))
 913
 914 (defun nnir-imap-next-symbol (&optional count)
 915   "Return the next symbol from the current buffer, or nil if we are
 916 at the end of the buffer.  If supplied COUNT skips some symbols before
 917 returning the one at the supplied position."
 918   (when (and (numberp count) (> count 1))
 919     (nnir-imap-next-symbol (1- count)))
 920   (let ((case-fold-search t))
 921     ;; end of input stream?
 922     (unless (nnir-imap-end-of-input)
 923       ;; No, return the next symbol from the stream.
 924       (cond
 925        ;; negated expression -- return it and advance one char.
 926        ((looking-at "-") (forward-char 1) 'not)
 927        ;; quoted string
 928        ((looking-at "\"") (nnir-imap-delimited-string "\""))
 929        ;; list expression -- we parse the content and return this as a list.
 930        ((looking-at "(")
 931         (nnir-imap-parse-query (nnir-imap-delimited-string ")")))
 932        ;; keyword input -- return a symbol version
 933        ((looking-at "\\band\\b") (forward-char 3) 'and)
 934        ((looking-at "\\bor\\b")  (forward-char 2) 'or)
 935        ((looking-at "\\bnot\\b") (forward-char 3) 'not)
 936        ;; Simple, boring keyword
 937        (t (let ((start (point))
 938                 (end (if (search-forward-regexp "[[:blank:]]" nil t)
 939                          (prog1
 940                              (match-beginning 0)
 941                            ;; unskip if we hit a non-blank terminal character.
 942                            (when (string-match "[^[:blank:]]" (match-string 0))
 943                              (backward-char 1)))
 944                        (goto-char (point-max)))))
 945             (buffer-substring start end)))))))
 946
 947 (defun nnir-imap-delimited-string (delimiter)
 948   "Return a delimited string from the current buffer."
 949   (let ((start (point)) end)
 950     (forward-char 1)                    ; skip the first delimiter.
 951     (while (not end)
 952       (unless (search-forward delimiter nil t)
 953         (error "Unmatched delimited input with %s in query" delimiter))
 954       (let ((here (point)))
 955         (unless (equal (buffer-substring (- here 2) (- here 1)) "\\")
 956           (setq end (point)))))
 957     (buffer-substring (1+ start) (1- end))))
 958
 959 (defun nnir-imap-end-of-input ()
 960   "Are we at the end of input?"
 961   (skip-chars-forward "[[:blank:]]")
 962   (looking-at "$"))
 963
 964
 965 ;; Swish++ interface.
 966 ;; -cc- Todo
 967 ;; Search by
 968 ;; - group
 969 ;; Sort by
 970 ;; - rank (default)
 971 ;; - article number
 972 ;; - file size
 973 ;; - group
 974 (defun nnir-run-swish++ (query server &optional group)
 975   "Run QUERY against swish++.
 976 Returns a vector of (group name, file name) pairs (also vectors,
 977 actually).
 978
 979 Tested with swish++ 4.7 on GNU/Linux and with swish++ 5.0b2 on
 980 Windows NT 4.0."
 981
 982   ;; (when group
 983   ;;   (error "The swish++ backend cannot search specific groups"))
 984
 985   (save-excursion
 986     (let ( (qstring (cdr (assq 'query query)))
 987            (groupspec (cdr (assq 'group query)))
 988            (prefix (nnir-read-server-parm 'nnir-swish++-remove-prefix server))
 989            artlist
 990            ;; nnml-use-compressed-files might be any string, but probably this
 991            ;; is sufficient.  Note that we can't only use the value of
 992            ;; nnml-use-compressed-files because old articles might have been
 993            ;; saved with a different value.
 994            (article-pattern (if (string= (gnus-group-server server) "nnmaildir")
 995                                 ":[0-9]+"
 996                               "^[0-9]+\\(\\.[a-z0-9]+\\)?$"))
 997            score artno dirnam filenam)
 998
 999       (when (equal "" qstring)
1000         (error "swish++: You didn't enter anything"))
1001
1002       (set-buffer (get-buffer-create nnir-tmp-buffer))
1003       (erase-buffer)
1004
1005       (if groupspec
1006           (message "Doing swish++ query %s on %s..." qstring groupspec)
1007         (message "Doing swish++ query %s..." qstring))
1008
1009       (let* ((cp-list `( ,nnir-swish++-program
1010                          nil            ; input from /dev/null
1011                          t              ; output
1012                          nil            ; don't redisplay
1013                          "--config-file" ,(nnir-read-server-parm 'nnir-swish++-configuration-file server)
1014                          ,@(nnir-read-server-parm 'nnir-swish++-additional-switches server)
1015                          ,qstring       ; the query, in swish++ format
1016                          ))
1017              (exitstatus
1018               (progn
1019                 (message "%s args: %s" nnir-swish++-program
1020                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1021                 (apply 'call-process cp-list))))
1022         (unless (or (null exitstatus)
1023                     (zerop exitstatus))
1024           (nnheader-report 'nnir "Couldn't run swish++: %s" exitstatus)
1025           ;; swish++ failure reason is in this buffer, show it if
1026           ;; the user wants it.
1027           (when (> gnus-verbose 6)
1028             (display-buffer nnir-tmp-buffer))))
1029
1030       ;; The results are output in the format of:
1031       ;; V 4.7 Linux
1032       ;; rank relative-path-name file-size file-title
1033       ;; V 5.0b2:
1034       ;; rank relative-path-name file-size topic??
1035       ;; where rank is an integer from 1 to 100.
1036       (goto-char (point-min))
1037       (while (re-search-forward
1038               "\\(^[0-9]+\\) \\([^ ]+\\) [0-9]+ \\(.*\\)$" nil t)
1039         (setq score (match-string 1)
1040               filenam (match-string 2)
1041               artno (file-name-nondirectory filenam)
1042               dirnam (file-name-directory filenam))
1043
1044         ;; don't match directories
1045         (when (string-match article-pattern artno)
1046           (when (not (null dirnam))
1047
1048             ;; maybe limit results to matching groups.
1049             (when (or (not groupspec)
1050                       (string-match groupspec dirnam))
1051               (nnir-add-result dirnam artno score prefix server artlist)))))
1052
1053       (message "Massaging swish++ output...done")
1054
1055       ;; Sort by score
1056       (apply 'vector
1057              (sort artlist
1058                    (function (lambda (x y)
1059                                (> (nnir-artitem-rsv x)
1060                                   (nnir-artitem-rsv y)))))))))
1061
1062 ;; Swish-E interface.
1063 (defun nnir-run-swish-e (query server &optional group)
1064   "Run given query against swish-e.
1065 Returns a vector of (group name, file name) pairs (also vectors,
1066 actually).
1067
1068 Tested with swish-e-2.0.1 on Windows NT 4.0."
1069
1070   ;; swish-e crashes with empty parameter to "-w" on commandline...
1071   ;; (when group
1072   ;;   (error "The swish-e backend cannot search specific groups"))
1073
1074   (save-excursion
1075     (let ((qstring (cdr (assq 'query query)))
1076           (prefix
1077            (or (nnir-read-server-parm 'nnir-swish-e-remove-prefix server)
1078                (error "Missing parameter `nnir-swish-e-remove-prefix'")))
1079           artlist score artno dirnam group )
1080
1081       (when (equal "" qstring)
1082         (error "swish-e: You didn't enter anything"))
1083
1084       (set-buffer (get-buffer-create nnir-tmp-buffer))
1085       (erase-buffer)
1086
1087       (message "Doing swish-e query %s..." query)
1088       (let* ((index-files
1089               (or (nnir-read-server-parm
1090                    'nnir-swish-e-index-files server)
1091                   (error "Missing parameter `nnir-swish-e-index-files'")))
1092              (additional-switches
1093               (nnir-read-server-parm
1094                'nnir-swish-e-additional-switches server))
1095              (cp-list `(,nnir-swish-e-program
1096                         nil             ; input from /dev/null
1097                         t               ; output
1098                         nil             ; don't redisplay
1099                         "-f" ,@index-files
1100                         ,@additional-switches
1101                         "-w"
1102                         ,qstring        ; the query, in swish-e format
1103                         ))
1104              (exitstatus
1105               (progn
1106                 (message "%s args: %s" nnir-swish-e-program
1107                          (mapconcat 'identity (cddddr cp-list) " "))
1108                 (apply 'call-process cp-list))))
1109         (unless (or (null exitstatus)
1110                     (zerop exitstatus))
1111           (nnheader-report 'nnir "Couldn't run swish-e: %s" exitstatus)
1112           ;; swish-e failure reason is in this buffer, show it if
1113           ;; the user wants it.
1114           (when (> gnus-verbose 6)
1115             (display-buffer nnir-tmp-buffer))))
1116
1117       ;; The results are output in the format of:
1118       ;; rank path-name file-title file-size
1119       (goto-char (point-min))
1120       (while (re-search-forward
1121               "\\(^[0-9]+\\) \\([^ ]+\\) \"\\([^\"]+\\)\" [0-9]+$" nil t)
1122         (setq score (match-string 1)
1123               artno (match-string 3)
1124               dirnam (file-name-directory (match-string 2)))
1125
1126         ;; don't match directories
1127         (when (string-match "^[0-9]+$" artno)
1128           (when (not (null dirnam))
1129
1130             ;; remove nnir-swish-e-remove-prefix from beginning of dirname
1131             (when (string-match (concat "^" prefix) dirnam)
1132               (setq dirnam (replace-match "" t t dirnam)))
1133
1134             (setq dirnam (substring dirnam 0 -1))
1135             ;; eliminate all ".", "/", "\" from beginning. Always matches.
1136             (string-match "^[./\\]*\\(.*\\)$" dirnam)
1137             ;; "/" -> "."
1138             (setq group (gnus-replace-in-string (match-string 1 dirnam) "/" "."))
1139             ;; Windows "\\" -> "."
1140             (setq group (gnus-replace-in-string group "\\\\" "."))
1141
1142             (push (vector (gnus-group-full-name group server)
1143                           (string-to-number artno)
1144                           (string-to-number score))
1145                   artlist))))
1146
1147       (message "Massaging swish-e output...done")
1148
1149       ;; Sort by score
1150       (apply 'vector
1151              (sort artlist
1152                    (function (lambda (x y)
1153                                (> (nnir-artitem-rsv x)
1154                                   (nnir-artitem-rsv y)))))))))
1155
1156 ;; HyREX interface
1157 (defun nnir-run-hyrex (query server &optional group)
1158   (save-excursion
1159     (let ((artlist nil)
1160           (groupspec (cdr (assq 'group query)))
1161           (qstring (cdr (assq 'query query)))
1162           (prefix (nnir-read-server-parm 'nnir-hyrex-remove-prefix server))
1163           score artno dirnam)
1164       (when (and (not groupspec) group)
1165         (setq groupspec
1166               (regexp-opt
1167                (mapcar (lambda (x) (gnus-group-real-name x)) group))))
1168       (set-buffer (get-buffer-create nnir-tmp-buffer))
1169       (erase-buffer)
1170       (message "Doing hyrex-search query %s..." query)
1171       (let* ((cp-list
1172               `( ,nnir-hyrex-program
1173                  nil                    ; input from /dev/null
1174                  t                      ; output
1175                  nil                    ; don't redisplay
1176                  "-i",(nnir-read-server-parm 'nnir-hyrex-index-directory server) ; index directory
1177                  ,@(nnir-read-server-parm 'nnir-hyrex-additional-switches server)
1178                  ,qstring          ; the query, in hyrex-search format
1179                  ))
1180              (exitstatus
1181               (progn
1182                 (message "%s args: %s" nnir-hyrex-program
1183                          (mapconcat 'identity (cddddr cp-list) " "))
1184                 (apply 'call-process cp-list))))
1185         (unless (or (null exitstatus)
1186                     (zerop exitstatus))
1187           (nnheader-report 'nnir "Couldn't run hyrex-search: %s" exitstatus)
1188           ;; nnir-search failure reason is in this buffer, show it if
1189           ;; the user wants it.
1190           (when (> gnus-verbose 6)
1191             (display-buffer nnir-tmp-buffer)))) ;; FIXME: Dont clear buffer !
1192       (message "Doing hyrex-search query \"%s\"...done" qstring)
1193       (sit-for 0)
1194       ;; nnir-search returns:
1195       ;;   for nnml/nnfolder: "filename mailid weigth"
1196       ;;   for nnimap:        "group mailid weigth"
1197       (goto-char (point-min))
1198       (delete-non-matching-lines "^\\S + [0-9]+ [0-9]+$")
1199       ;; HyREX doesn't search directly in groups -- so filter out here.
1200       (when groupspec
1201         (keep-lines groupspec))
1202       ;; extract data from result lines
1203       (goto-char (point-min))
1204       (while (re-search-forward
1205               "\\(\\S +\\) \\([0-9]+\\) \\([0-9]+\\)" nil t)
1206         (setq dirnam (match-string 1)
1207               artno (match-string 2)
1208               score (match-string 3))
1209         (when (string-match prefix dirnam)
1210           (setq dirnam (replace-match "" t t dirnam)))
1211         (push (vector (gnus-group-full-name
1212                        (gnus-replace-in-string dirnam "/" ".") server)
1213                       (string-to-number artno)
1214                       (string-to-number score))
1215               artlist))
1216       (message "Massaging hyrex-search output...done.")
1217       (apply 'vector
1218              (sort artlist
1219                    (function (lambda (x y)
1220                                (if (string-lessp (nnir-artitem-group x)
1221                                                  (nnir-artitem-group y))
1222                                    t
1223                                  (< (nnir-artitem-number x)
1224                                     (nnir-artitem-number y)))))))
1225       )))
1226
1227 ;; Namazu interface
1228 (defun nnir-run-namazu (query server &optional group)
1229   "Run given query against Namazu.  Returns a vector of (group name, file name)
1230 pairs (also vectors, actually).
1231
1232 Tested with Namazu 2.0.6 on a GNU/Linux system."
1233   ;; (when group
1234   ;;   (error "The Namazu backend cannot search specific groups"))
1235   (save-excursion
1236     (let ((article-pattern (if (string= (gnus-group-server server) "nnmaildir")
1237                                ":[0-9]+"
1238                              "^[0-9]+$"))
1239           artlist
1240           (qstring (cdr (assq 'query query)))
1241           (prefix (nnir-read-server-parm 'nnir-namazu-remove-prefix server))
1242           score group article
1243           (process-environment (copy-sequence process-environment)))
1244       (setenv "LC_MESSAGES" "C")
1245       (set-buffer (get-buffer-create nnir-tmp-buffer))
1246       (erase-buffer)
1247       (let* ((cp-list
1248               `( ,nnir-namazu-program
1249                  nil                    ; input from /dev/null
1250                  t                      ; output
1251                  nil                    ; don't redisplay
1252                  "-q"                   ; don't be verbose
1253                  "-a"                   ; show all matches
1254                  "-s"                   ; use short format
1255                  ,@(nnir-read-server-parm 'nnir-namazu-additional-switches server)
1256                  ,qstring               ; the query, in namazu format
1257                  ,(nnir-read-server-parm 'nnir-namazu-index-directory server) ; index directory
1258                  ))
1259              (exitstatus
1260               (progn
1261                 (message "%s args: %s" nnir-namazu-program
1262                          (mapconcat 'identity (cddddr cp-list) " "))
1263                 (apply 'call-process cp-list))))
1264         (unless (or (null exitstatus)
1265                     (zerop exitstatus))
1266           (nnheader-report 'nnir "Couldn't run namazu: %s" exitstatus)
1267           ;; Namazu failure reason is in this buffer, show it if
1268           ;; the user wants it.
1269           (when (> gnus-verbose 6)
1270             (display-buffer nnir-tmp-buffer))))
1271
1272       ;; Namazu output looks something like this:
1273       ;; 2. Re: Gnus agent expire broken (score: 55)
1274       ;; /home/henrik/Mail/mail/sent/1310 (4,138 bytes)
1275
1276       (goto-char (point-min))
1277       (while (re-search-forward
1278               "^\\([0-9]+\\.\\).*\\((score: \\([0-9]+\\)\\))\n\\([^ ]+\\)"
1279               nil t)
1280         (setq score (match-string 3)
1281               group (file-name-directory (match-string 4))
1282               article (file-name-nondirectory (match-string 4)))
1283
1284         ;; make sure article and group is sane
1285         (when (and (string-match article-pattern article)
1286                    (not (null group)))
1287           (nnir-add-result group article score prefix server artlist)))
1288
1289       ;; sort artlist by score
1290       (apply 'vector
1291              (sort artlist
1292                    (function (lambda (x y)
1293                                (> (nnir-artitem-rsv x)
1294                                   (nnir-artitem-rsv y)))))))))
1295
1296 (defun nnir-run-find-grep (query server &optional grouplist)
1297   "Run find and grep to obtain matching articles."
1298   (let* ((method (gnus-server-to-method server))
1299          (sym (intern
1300                (concat (symbol-name (car method)) "-directory")))
1301          (directory (cadr (assoc sym (cddr method))))
1302          (regexp (cdr (assoc 'query query)))
1303          (grep-options (cdr (assoc 'grep-options query)))
1304          (grouplist (or grouplist (nnir-get-active server)))
1305          artlist)
1306     (unless directory
1307       (error "No directory found in method specification of server %s"
1308              server))
1309     (apply
1310      'vconcat
1311      (mapcar (lambda (x)
1312                (let ((group x))
1313                  (message "Searching %s using find-grep..."
1314                           (or group server))
1315                  (save-window-excursion
1316                    (set-buffer (get-buffer-create nnir-tmp-buffer))
1317                    (erase-buffer)
1318                    (if (> gnus-verbose 6)
1319                        (pop-to-buffer (current-buffer)))
1320                    (cd directory) ; Using relative paths simplifies
1321                                   ; postprocessing.
1322                    (let ((group
1323                           (if (not group)
1324                               "."
1325                             ;; Try accessing the group literally as
1326                             ;; well as interpreting dots as directory
1327                             ;; separators so the engine works with
1328                             ;; plain nnml as well as the Gnus Cache.
1329                             (let ((group (gnus-group-real-name group)))
1330                               ;; Replace cl-func find-if.
1331                               (if (file-directory-p group)
1332                                   group
1333                                 (if (file-directory-p
1334                                      (setq group
1335                                            (gnus-replace-in-string
1336                                             group
1337                                             "\\." "/" t)))
1338                                     group))))))
1339                      (unless group
1340                        (error "Cannot locate directory for group"))
1341                      (save-excursion
1342                        (apply
1343                         'call-process "find" nil t
1344                         "find" group "-type" "f" "-name" "[0-9]*" "-exec"
1345                         "grep"
1346                         `("-l" ,@(and grep-options
1347                                       (split-string grep-options "\\s-" t))
1348                           "-e" ,regexp "{}" "+"))))
1349
1350                    ;; Translate relative paths to group names.
1351                    (while (not (eobp))
1352                      (let* ((path (split-string
1353                                    (buffer-substring
1354                                     (point)
1355                                     (line-end-position)) "/" t))
1356                             (art (string-to-number (car (last path)))))
1357                        (while (string= "." (car path))
1358                          (setq path (cdr path)))
1359                        (let ((group (mapconcat 'identity
1360                                                ;; Replace cl-func:
1361                                                ;; (subseq path 0 -1)
1362                                                (let ((end (1- (length path)))
1363                                                      res)
1364                                                  (while
1365                                                      (>= (setq end (1- end)) 0)
1366                                                    (push (pop path) res))
1367                                                  (nreverse res))
1368                                                ".")))
1369                          (push
1370                           (vector (gnus-group-full-name group server) art 0)
1371                           artlist))
1372                        (forward-line 1)))
1373                    (message "Searching %s using find-grep...done"
1374                             (or group server))
1375                    artlist)))
1376      grouplist))))
1377
1378 (declare-function mm-url-insert "mm-url" (url &optional follow-refresh))
1379 (declare-function mm-url-encode-www-form-urlencoded "mm-url" (pairs))
1380
1381 ;; gmane interface
1382 (defun nnir-run-gmane (query srv &optional groups)
1383   "Run a search against a gmane back-end server."
1384   (if (gnus-string-match-p
1385        "gmane.org$"
1386        (or (cadr (assoc 'nntp-address  (cddr (gnus-server-to-method srv))))
1387            ""))
1388       (let* ((case-fold-search t)
1389              (qstring (cdr (assq 'query query)))
1390              (server (cadr (gnus-server-to-method srv)))
1391              (groupspec (if groups
1392                             (mapconcat
1393                              (lambda (x)
1394                                (format "group:%s" (gnus-group-short-name x)))
1395                              groups " ") ""))
1396              (authorspec
1397               (if (assq 'author query)
1398                   (format "author:%s" (cdr (assq 'author query))) ""))
1399              (search (format "%s %s %s"
1400                              qstring groupspec authorspec))
1401              (gnus-inhibit-demon t)
1402              artlist)
1403         (require 'mm-url)
1404         (with-current-buffer (get-buffer-create nnir-tmp-buffer)
1405           (erase-buffer)
1406           (mm-url-insert
1407            (concat
1408             "http://search.gmane.org/nov.php"
1409             "?"
1410             (mm-url-encode-www-form-urlencoded
1411              `(("query" . ,search)
1412                ("HITSPERPAGE" . "999")))))
1413           (unless (featurep 'xemacs) (set-buffer-multibyte t))
1414           (mm-decode-coding-region (point-min) (point-max) 'utf-8)
1415           (goto-char (point-min))
1416           (forward-line 1)
1417           (while (not (eobp))
1418             (unless (or (eolp) (looking-at "\x0d"))
1419               (let ((header (nnheader-parse-nov)))
1420                 (let ((xref (mail-header-xref header))
1421                       (xscore (string-to-number (cdr (assoc 'X-Score
1422                                (mail-header-extra header))))))
1423                   (when (string-match " \\([^:]+\\)[:/]\\([0-9]+\\)" xref)
1424                     (push
1425                      (vector
1426                       (gnus-group-prefixed-name (match-string 1 xref) srv)
1427                       (string-to-number (match-string 2 xref)) xscore)
1428                      artlist)))))
1429             (forward-line 1)))
1430         (apply 'vector (nreverse (mm-delete-duplicates artlist))))
1431     (message "Can't search non-gmane nntp groups")
1432     nil))
1433
1434 ;;; Util Code:
1435
1436 (defun nnir-read-parms (query nnir-search-engine)
1437   "Reads additional search parameters according to `nnir-engines'."
1438   (let ((parmspec (caddr (assoc nnir-search-engine nnir-engines))))
1439     (append query
1440            (mapcar 'nnir-read-parm parmspec))))
1441
1442 (defun nnir-read-parm (parmspec)
1443   "Reads a single search parameter.
1444 `parmspec' is a cons cell, the car is a symbol, the cdr is a prompt."
1445   (let ((sym (car parmspec))
1446         (prompt (cdr parmspec)))
1447     (if (listp prompt)
1448         (let* ((result (apply 'gnus-completing-read prompt))
1449                (mapping (or (assoc result nnir-imap-search-arguments)
1450                             (cons nil nnir-imap-search-other))))
1451           (cons sym (format (cdr mapping) result)))
1452       (cons sym (read-string prompt)))))
1453
1454 (autoload 'gnus-group-topic-name "gnus-topic")
1455
1456 (defun nnir-run-query (query nserver)
1457   "Invoke appropriate search engine function (see `nnir-engines').
1458   If some groups were process-marked, run the query for each of the groups
1459   and concat the results."
1460   (let ((q (car (read-from-string query)))
1461         (groups (if (string= "all-ephemeral" nserver)
1462                     (with-current-buffer gnus-server-buffer
1463                       (list (list (gnus-server-server-name))))
1464                   (nnir-categorize
1465                    (or gnus-group-marked
1466                        (if (gnus-group-group-name)
1467                            (list (gnus-group-group-name))
1468                          (cdr (assoc (gnus-group-topic-name)
1469                                      gnus-topic-alist))))
1470                    gnus-group-server))))
1471     (apply 'vconcat
1472            (mapcar
1473             (lambda (x)
1474               (let* ((server (car x))
1475                      (nnir-search-engine
1476                       (or (nnir-read-server-parm 'nnir-search-engine
1477                                                  server)
1478                           (cdr (assoc (car
1479                                        (gnus-server-to-method server))
1480                                       nnir-method-default-engines))))
1481                      search-func)
1482                 (setq search-func (cadr (assoc nnir-search-engine
1483                                                nnir-engines)))
1484                 (if search-func
1485                     (funcall search-func
1486                              (if nnir-extra-parms
1487                                  (nnir-read-parms q nnir-search-engine)
1488                                q)
1489                              server (cadr x))
1490                   nil)))
1491             groups))))
1492
1493 (defun nnir-read-server-parm (key server)
1494   "Returns the parameter value of key for the given server, where
1495 server is of form 'backend:name'."
1496   (let ((method (gnus-server-to-method server)))
1497     (cond ((and method (assq key (cddr method)))
1498            (nth 1 (assq key (cddr method))))
1499           (t nil))))
1500
1501 (defun nnir-possibly-change-server (server)
1502   (unless (and server (nnir-server-opened server))
1503     (nnir-open-server server)))
1504
1505
1506
1507 ;; unused?
1508 (defun nnir-artlist-groups (artlist)
1509   "Returns a list of all groups in the given ARTLIST."
1510   (let ((res nil)
1511         (with-dups nil))
1512     ;; from each artitem, extract group component
1513     (setq with-dups (mapcar 'nnir-artitem-group artlist))
1514     ;; remove duplicates from above
1515     (mapc (function (lambda (x) (add-to-list 'res x)))
1516             with-dups)
1517     res))
1518
1519 (defun nnir-get-active (srv)
1520   (let ((method (gnus-server-to-method srv))
1521         groups)
1522     (gnus-request-list method)
1523     (with-current-buffer nntp-server-buffer
1524       (let ((cur (current-buffer))
1525             name)
1526         (goto-char (point-min))
1527         (unless (string= nnir-ignored-newsgroups "")
1528           (delete-matching-lines nnir-ignored-newsgroups))
1529         (if (eq (car method) 'nntp)
1530             (while (not (eobp))
1531               (ignore-errors
1532                 (push (mm-string-as-unibyte
1533                        (gnus-group-full-name
1534                         (buffer-substring
1535                          (point)
1536                          (progn
1537                            (skip-chars-forward "^ \t")
1538                            (point))) method))
1539                       groups))
1540               (forward-line))
1541           (while (not (eobp))
1542             (ignore-errors
1543               (push (mm-string-as-unibyte
1544                      (if (eq (char-after) ?\")
1545                          (gnus-group-full-name (read cur) method)
1546                        (let ((p (point)) (name ""))
1547                          (skip-chars-forward "^ \t\\\\")
1548                          (setq name (buffer-substring p (point)))
1549                          (while (eq (char-after) ?\\)
1550                            (setq p (1+ (point)))
1551                            (forward-char 2)
1552                            (skip-chars-forward "^ \t\\\\")
1553                            (setq name (concat name (buffer-substring
1554                                                     p (point)))))
1555                          (gnus-group-full-name name method))))
1556                     groups))
1557             (forward-line)))))
1558     groups))
1559
1560 (defun nnir-registry-action (action data-header from &optional to method)
1561   "Call `gnus-registry-action' with the original article group."
1562   (gnus-registry-action
1563    action
1564    data-header
1565    (nnir-article-group (mail-header-number data-header))
1566    to
1567    method))
1568
1569 (defun nnir-mode ()
1570   (when (eq (car (gnus-find-method-for-group gnus-newsgroup-name)) 'nnir)
1571     (setq gnus-summary-line-format
1572           (or nnir-summary-line-format gnus-summary-line-format))
1573     (remove-hook 'gnus-summary-article-delete-hook 'gnus-registry-action t)
1574     (remove-hook 'gnus-summary-article-move-hook 'gnus-registry-action t)
1575     (add-hook 'gnus-summary-article-delete-hook 'nnir-registry-action t t)
1576     (add-hook 'gnus-summary-article-move-hook 'nnir-registry-action t t)))
1577
1578
1579
1580 ;; The end.
1581 (provide 'nnir)
1582
1583 ;;; nnir.el ends here