cgit.sxemacs.org Git - gnus/blob - lisp/nnir.el

   1 ;;; nnir.el --- search mail with various search engines -*- coding: utf-8 -*-
   2
   3 ;; Copyright (C) 1998-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Kai Großjohann <grossjohann@ls6.cs.uni-dortmund.de>
   6 ;; Swish-e and Swish++ backends by:
   7 ;;   Christoph Conrad <christoph.conrad@gmx.de>.
   8 ;; IMAP backend by: Simon Josefsson <jas@pdc.kth.se>.
   9 ;; IMAP search by: Torsten Hilbrich <torsten.hilbrich <at> gmx.net>
  10 ;; IMAP search improved by Daniel Pittman  <daniel@rimspace.net>.
  11 ;; nnmaildir support for Swish++ and Namazu backends by:
  12 ;;   Justus Piater <Justus <at> Piater.name>
  13 ;; Keywords: news mail searching ir
  14
  15 ;; This file is part of GNU Emacs.
  16
  17 ;; GNU Emacs is free software: you can redistribute it and/or modify
  18 ;; it under the terms of the GNU General Public License as published by
  19 ;; the Free Software Foundation, either version 3 of the License, or
  20 ;; (at your option) any later version.
  21
  22 ;; GNU Emacs is distributed in the hope that it will be useful,
  23 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 ;; GNU General Public License for more details.
  26
  27 ;; You should have received a copy of the GNU General Public License
  28 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  29
  30 ;;; Commentary:
  31
  32 ;; What does it do?  Well, it allows you to search your mail using
  33 ;; some search engine (imap, namazu, swish-e, gmane and others -- see
  34 ;; later) by typing `G G' in the Group buffer.  You will then get a
  35 ;; buffer which shows all articles matching the query, sorted by
  36 ;; Retrieval Status Value (score).
  37
  38 ;; When looking at the retrieval result (in the Summary buffer) you
  39 ;; can type `A W' (aka M-x gnus-warp-to-article RET) on an article.  You
  40 ;; will be warped into the group this article came from. Typing `A T'
  41 ;; (aka M-x gnus-summary-refer-thread RET) will warp to the group and
  42 ;; also show the thread this article is part of.
  43
  44 ;; The Lisp setup may involve setting a few variables and setting up the
  45 ;; search engine. You can define the variables in the server definition
  46 ;; like this :
  47 ;;   (setq gnus-secondary-select-methods '(
  48 ;;       (nnimap "" (nnimap-address "localhost")
  49 ;;                  (nnir-search-engine namazu)
  50 ;;       )))
  51 ;; The main variable to set is `nnir-search-engine'.  Choose one of
  52 ;; the engines listed in `nnir-engines'.  (Actually `nnir-engines' is
  53 ;; an alist, type `C-h v nnir-engines RET' for more information; this
  54 ;; includes examples for setting `nnir-search-engine', too.)
  55
  56 ;; If you use one of the local indices (namazu, find-grep, swish) you
  57 ;; must also set up a search engine backend.
  58
  59 ;; 1. Namazu
  60 ;;
  61 ;; The Namazu backend requires you to have one directory containing all
  62 ;; index files, this is controlled by the `nnir-namazu-index-directory'
  63 ;; variable.  To function the `nnir-namazu-remove-prefix' variable must
  64 ;; also be correct, see the documentation for `nnir-namazu-remove-prefix'
  65 ;; above.
  66 ;;
  67 ;; It is particularly important not to pass any any switches to namazu
  68 ;; that will change the output format.  Good switches to use include
  69 ;; `--sort', `--ascending', `--early' and `--late'.  Refer to the Namazu
  70 ;; documentation for further information on valid switches.
  71 ;;
  72 ;; To index my mail with the `mknmz' program I use the following
  73 ;; configuration file:
  74 ;;
  75 ;; ,----
  76 ;; | package conf;  # Don't remove this line!
  77 ;; |
  78 ;; | # Paths which will not be indexed. Don't use `^' or `$' anchors.
  79 ;; | $EXCLUDE_PATH = "spam|sent";
  80 ;; |
  81 ;; | # Header fields which should be searchable. case-insensitive
  82 ;; | $REMAIN_HEADER = "from|date|message-id|subject";
  83 ;; |
  84 ;; | # Searchable fields. case-insensitive
  85 ;; | $SEARCH_FIELD = "from|date|message-id|subject";
  86 ;; |
  87 ;; | # The max length of a word.
  88 ;; | $WORD_LENG_MAX = 128;
  89 ;; |
  90 ;; | # The max length of a field.
  91 ;; | $MAX_FIELD_LENGTH = 256;
  92 ;; `----
  93 ;;
  94 ;; My mail is stored in the directories ~/Mail/mail/, ~/Mail/lists/ and
  95 ;; ~/Mail/archive/, so to index them I go to the directory set in
  96 ;; `nnir-namazu-index-directory' and issue the following command.
  97 ;;
  98 ;;      mknmz --mailnews ~/Mail/archive/ ~/Mail/mail/ ~/Mail/lists/
  99 ;;
 100 ;; For maximum searching efficiency I have a cron job set to run this
 101 ;; command every four hours.
 102
 103 ;; 2. find-grep
 104 ;;
 105 ;; The find-grep engine simply runs find(1) to locate eligible
 106 ;; articles and searches them with grep(1).  This, of course, is much
 107 ;; slower than using a proper search engine but OTOH doesn't require
 108 ;; maintenance of an index and is still faster than using any built-in
 109 ;; means for searching.  The method specification of the server to
 110 ;; search must include a directory for this engine to work (E.g.,
 111 ;; `nnml-directory').  The tools must be POSIX compliant.  GNU Find
 112 ;; prior to version 4.2.12 (4.2.26 on Linux due to incorrect ARG_MAX
 113 ;; handling) does not work.
 114 ;; ,----
 115 ;; |    ;; find-grep configuration for searching the Gnus Cache
 116 ;; |
 117 ;; |    (nnml "cache"
 118 ;; |          (nnml-get-new-mail nil)
 119 ;; |          (nnir-search-engine find-grep)
 120 ;; |          (nnml-directory "~/News/cache/")
 121 ;; |          (nnml-active-file "~/News/cache/active"))
 122 ;; `----
 123
 124 ;; Developer information:
 125
 126 ;; I have tried to make the code expandable.  Basically, it is divided
 127 ;; into two layers.  The upper layer is somewhat like the `nnvirtual'
 128 ;; backend: given a specification of what articles to show from
 129 ;; another backend, it creates a group containing exactly those
 130 ;; articles.  The lower layer issues a query to a search engine and
 131 ;; produces such a specification of what articles to show from the
 132 ;; other backend.
 133
 134 ;; The interface between the two layers consists of the single
 135 ;; function `nnir-run-query', which dispatches the search to the
 136 ;; proper search function.  The argument of `nnir-run-query' is an
 137 ;; alist with two keys: 'nnir-query-spec and 'nnir-group-spec. The
 138 ;; value for 'nnir-query-spec is an alist. The only required key/value
 139 ;; pair is (query . "query") specifying the search string to pass to
 140 ;; the query engine. Individual engines may have other elements. The
 141 ;; value of 'nnir-group-spec is a list with the specification of the
 142 ;; groups/servers to search.  The format of the 'nnir-group-spec is
 143 ;; (("server1" ("group11" "group12")) ("server2" ("group21"
 144 ;; "group22"))). If any of the group lists is absent then all groups
 145 ;; on that server are searched.
 146
 147 ;; The output of `nnir-run-query' is supposed to be a vector, each
 148 ;; element of which should in turn be a three-element vector.  The
 149 ;; first element should be full group name of the article, the second
 150 ;; element should be the article number, and the third element should
 151 ;; be the Retrieval Status Value (RSV) as returned from the search
 152 ;; engine.  An RSV is the score assigned to the document by the search
 153 ;; engine.  For Boolean search engines, the RSV is always 1000 (or 1
 154 ;; or 100, or whatever you like).
 155
 156 ;; The sorting order of the articles in the summary buffer created by
 157 ;; nnir is based on the order of the articles in the above mentioned
 158 ;; vector, so that's where you can do the sorting you'd like.  Maybe
 159 ;; it would be nice to have a way of displaying the search result
 160 ;; sorted differently?
 161
 162 ;; So what do you need to do when you want to add another search
 163 ;; engine?  You write a function that executes the query.  Temporary
 164 ;; data from the search engine can be put in `nnir-tmp-buffer'.  This
 165 ;; function should return the list of articles as a vector, as
 166 ;; described above.  Then, you need to register this backend in
 167 ;; `nnir-engines'.  Then, users can choose the backend by setting
 168 ;; `nnir-search-engine' as a server variable.
 169
 170 ;;; Code:
 171
 172 ;;; Setup:
 173
 174 ;; For Emacs <22.2 and XEmacs.
 175 (eval-and-compile
 176   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
 177
 178 (require 'nnoo)
 179 (require 'gnus-group)
 180 (require 'message)
 181 (require 'gnus-util)
 182 (eval-when-compile
 183   (require 'cl))
 184
 185 ;;; Internal Variables:
 186
 187 (defvar nnir-memo-query nil
 188   "Internal: stores current query.")
 189
 190 (defvar nnir-memo-server nil
 191   "Internal: stores current server.")
 192
 193 (defvar nnir-artlist nil
 194   "Internal: stores search result.")
 195
 196 (defvar nnir-search-history ()
 197   "Internal: the history for querying search options in nnir")
 198
 199 (defconst nnir-tmp-buffer " *nnir*"
 200   "Internal: temporary buffer.")
 201
 202
 203 ;; Imap variables
 204
 205 (defvar nnir-imap-search-arguments
 206   '(("whole message" . "TEXT")
 207     ("subject" . "SUBJECT")
 208     ("to" . "TO")
 209     ("from" . "FROM")
 210     ("body" . "BODY")
 211     ("imap" . ""))
 212   "Mapping from user readable keys to IMAP search items for use in nnir")
 213
 214 (defvar nnir-imap-search-other "HEADER %S"
 215   "The IMAP search item to use for anything other than
 216   `nnir-imap-search-arguments'. By default this is the name of an
 217   email header field")
 218
 219 (defvar nnir-imap-search-argument-history ()
 220   "The history for querying search options in nnir")
 221
 222 ;;; Helper macros
 223
 224 ;; Data type article list.
 225
 226 (defmacro nnir-artlist-length (artlist)
 227   "Returns number of articles in artlist."
 228   `(length ,artlist))
 229
 230 (defmacro nnir-artlist-article (artlist n)
 231   "Returns from ARTLIST the Nth artitem (counting starting at 1)."
 232   `(when (> ,n 0)
 233      (elt ,artlist (1- ,n))))
 234
 235 (defmacro nnir-artitem-group (artitem)
 236   "Returns the group from the ARTITEM."
 237   `(elt ,artitem 0))
 238
 239 (defmacro nnir-artitem-number (artitem)
 240   "Returns the number from the ARTITEM."
 241   `(elt ,artitem 1))
 242
 243 (defmacro nnir-artitem-rsv (artitem)
 244   "Returns the Retrieval Status Value (RSV, score) from the ARTITEM."
 245   `(elt ,artitem 2))
 246
 247 (defmacro nnir-article-group (article)
 248   "Returns the group for ARTICLE"
 249   `(nnir-artitem-group (nnir-artlist-article nnir-artlist ,article)))
 250
 251 (defmacro nnir-article-number (article)
 252   "Returns the number for ARTICLE"
 253   `(nnir-artitem-number (nnir-artlist-article nnir-artlist ,article)))
 254
 255 (defmacro nnir-article-rsv (article)
 256   "Returns the rsv for ARTICLE"
 257   `(nnir-artitem-rsv (nnir-artlist-article nnir-artlist ,article)))
 258
 259 (defsubst nnir-article-ids (article)
 260   "Returns the pair `(nnir id . real id)' of ARTICLE"
 261   (cons article (nnir-article-number article)))
 262
 263 (defmacro nnir-categorize (sequence keyfunc &optional valuefunc)
 264   "Sorts a sequence into categories and returns a list of the form
 265 `((key1 (element11 element12)) (key2 (element21 element22))'.
 266 The category key for a member of the sequence is obtained
 267 as `(keyfunc member)' and the corresponding element is just
 268 `member'. If `valuefunc' is non-nil, the element of the list
 269 is `(valuefunc member)'."
 270   `(unless (null ,sequence)
 271      (let (value)
 272        (mapc
 273         (lambda (member)
 274           (let ((y (,keyfunc member))
 275                 (x ,(if valuefunc
 276                         `(,valuefunc member)
 277                       'member)))
 278             (if (assoc y value)
 279                 (push x (cadr (assoc y value)))
 280               (push (list y (list x)) value))))
 281         ,sequence)
 282        value)))
 283
 284 ;;; Finish setup:
 285
 286 (require 'gnus-sum)
 287
 288 (eval-when-compile
 289   (autoload 'nnimap-buffer "nnimap")
 290   (autoload 'nnimap-command "nnimap")
 291   (autoload 'nnimap-change-group "nnimap")
 292   (autoload 'nnimap-make-thread-query "nnimap")
 293   (autoload 'gnus-registry-action "gnus-registry")
 294   (autoload 'gnus-registry-get-id-key "gnus-registry")
 295   (autoload 'gnus-group-topic-name "gnus-topic"))
 296
 297
 298 (nnoo-declare nnir)
 299 (nnoo-define-basics nnir)
 300
 301 (gnus-declare-backend "nnir" 'mail 'virtual)
 302
 303
 304 ;;; User Customizable Variables:
 305
 306 (defgroup nnir nil
 307   "Search groups in Gnus with assorted search engines."
 308   :group 'gnus)
 309
 310 (defcustom nnir-ignored-newsgroups ""
 311   "*A regexp to match newsgroups in the active file that should
 312   be skipped when searching."
 313   :version "24.1"
 314   :type '(regexp)
 315   :group 'nnir)
 316
 317 (defcustom nnir-summary-line-format nil
 318   "*The format specification of the lines in an nnir summary buffer.
 319
 320 All the items from `gnus-summary-line-format' are available, along
 321 with three items unique to nnir summary buffers:
 322
 323 %Z    Search retrieval score value (integer)
 324 %G    Article original full group name (string)
 325 %g    Article original short group name (string)
 326
 327 If nil this will use `gnus-summary-line-format'."
 328   :version "24.1"
 329   :type '(string)
 330   :group 'nnir)
 331
 332 (defcustom nnir-retrieve-headers-override-function nil
 333   "*If non-nil, a function that accepts an article list and group
 334 and populates the `nntp-server-buffer' with the retrieved
 335 headers. Must return either 'nov or 'headers indicating the
 336 retrieved header format.
 337
 338 If this variable is nil, or if the provided function returns nil for a search
 339 result, `gnus-retrieve-headers' will be called instead."
 340   :version "24.1"
 341   :type '(function)
 342   :group 'nnir)
 343
 344 (defcustom nnir-imap-default-search-key "whole message"
 345   "*The default IMAP search key for an nnir search. Must be one of
 346   the keys in `nnir-imap-search-arguments'. To use raw imap queries
 347   by default set this to \"imap\"."
 348   :version "24.1"
 349   :type `(choice ,@(mapcar (lambda (elem) (list 'const (car elem)))
 350                            nnir-imap-search-arguments))
 351   :group 'nnir)
 352
 353 (defcustom nnir-swish++-configuration-file
 354   (expand-file-name "~/Mail/swish++.conf")
 355   "*Configuration file for swish++."
 356   :type '(file)
 357   :group 'nnir)
 358
 359 (defcustom nnir-swish++-program "search"
 360   "*Name of swish++ search executable."
 361   :type '(string)
 362   :group 'nnir)
 363
 364 (defcustom nnir-swish++-additional-switches '()
 365   "*A list of strings, to be given as additional arguments to swish++.
 366
 367 Note that this should be a list.  Ie, do NOT use the following:
 368     (setq nnir-swish++-additional-switches \"-i -w\") ; wrong
 369 Instead, use this:
 370     (setq nnir-swish++-additional-switches '(\"-i\" \"-w\"))"
 371   :type '(repeat (string))
 372   :group 'nnir)
 373
 374 (defcustom nnir-swish++-remove-prefix (concat (getenv "HOME") "/Mail/")
 375   "*The prefix to remove from each file name returned by swish++
 376 in order to get a group name (albeit with / instead of .).  This is a
 377 regular expression.
 378
 379 This variable is very similar to `nnir-namazu-remove-prefix', except
 380 that it is for swish++, not Namazu."
 381   :type '(regexp)
 382   :group 'nnir)
 383
 384 ;; Swish-E.
 385 ;; URL: http://swish-e.org/
 386 ;; Variables `nnir-swish-e-index-file', `nnir-swish-e-program' and
 387 ;; `nnir-swish-e-additional-switches'
 388
 389 (make-obsolete-variable 'nnir-swish-e-index-file
 390                         'nnir-swish-e-index-files "Emacs 23.1")
 391 (defcustom nnir-swish-e-index-file
 392   (expand-file-name "~/Mail/index.swish-e")
 393   "*Index file for swish-e.
 394 This could be a server parameter.
 395 It is never consulted once `nnir-swish-e-index-files', which should be
 396 used instead, has been customized."
 397   :type '(file)
 398   :group 'nnir)
 399
 400 (defcustom nnir-swish-e-index-files
 401   (list nnir-swish-e-index-file)
 402   "*List of index files for swish-e.
 403 This could be a server parameter."
 404   :type '(repeat (file))
 405   :group 'nnir)
 406
 407 (defcustom nnir-swish-e-program "swish-e"
 408   "*Name of swish-e search executable.
 409 This cannot be a server parameter."
 410   :type '(string)
 411   :group 'nnir)
 412
 413 (defcustom nnir-swish-e-additional-switches '()
 414   "*A list of strings, to be given as additional arguments to swish-e.
 415
 416 Note that this should be a list.  Ie, do NOT use the following:
 417     (setq nnir-swish-e-additional-switches \"-i -w\") ; wrong
 418 Instead, use this:
 419     (setq nnir-swish-e-additional-switches '(\"-i\" \"-w\"))
 420
 421 This could be a server parameter."
 422   :type '(repeat (string))
 423   :group 'nnir)
 424
 425 (defcustom nnir-swish-e-remove-prefix (concat (getenv "HOME") "/Mail/")
 426   "*The prefix to remove from each file name returned by swish-e
 427 in order to get a group name (albeit with / instead of .).  This is a
 428 regular expression.
 429
 430 This variable is very similar to `nnir-namazu-remove-prefix', except
 431 that it is for swish-e, not Namazu.
 432
 433 This could be a server parameter."
 434   :type '(regexp)
 435   :group 'nnir)
 436
 437 ;; HyREX engine, see <URL:http://ls6-www.cs.uni-dortmund.de/>
 438
 439 (defcustom nnir-hyrex-program "nnir-search"
 440   "*Name of the nnir-search executable."
 441   :type '(string)
 442   :group 'nnir)
 443
 444 (defcustom nnir-hyrex-additional-switches '()
 445   "*A list of strings, to be given as additional arguments for nnir-search.
 446 Note that this should be a list. Ie, do NOT use the following:
 447     (setq nnir-hyrex-additional-switches \"-ddl ddl.xml -c nnir\") ; wrong !
 448 Instead, use this:
 449     (setq nnir-hyrex-additional-switches '(\"-ddl\" \"ddl.xml\" \"-c\" \"nnir\"))"
 450   :type '(repeat (string))
 451   :group 'nnir)
 452
 453 (defcustom nnir-hyrex-index-directory (getenv "HOME")
 454   "*Index directory for HyREX."
 455   :type '(directory)
 456   :group 'nnir)
 457
 458 (defcustom nnir-hyrex-remove-prefix (concat (getenv "HOME") "/Mail/")
 459   "*The prefix to remove from each file name returned by HyREX
 460 in order to get a group name (albeit with / instead of .).
 461
 462 For example, suppose that HyREX returns file names such as
 463 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 464 setting:  (setq nnir-hyrex-remove-prefix \"/home/john/Mail/\")
 465 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 466 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 467 arrive at the correct group name, \"mail.misc\"."
 468   :type '(directory)
 469   :group 'nnir)
 470
 471 ;; Namazu engine, see <URL:http://www.namazu.org/>
 472
 473 (defcustom nnir-namazu-program "namazu"
 474   "*Name of Namazu search executable."
 475   :type '(string)
 476   :group 'nnir)
 477
 478 (defcustom nnir-namazu-index-directory (expand-file-name "~/Mail/namazu/")
 479   "*Index directory for Namazu."
 480   :type '(directory)
 481   :group 'nnir)
 482
 483 (defcustom nnir-namazu-additional-switches '()
 484   "*A list of strings, to be given as additional arguments to namazu.
 485 The switches `-q', `-a', and `-s' are always used, very few other switches
 486 make any sense in this context.
 487
 488 Note that this should be a list.  Ie, do NOT use the following:
 489     (setq nnir-namazu-additional-switches \"-i -w\") ; wrong
 490 Instead, use this:
 491     (setq nnir-namazu-additional-switches '(\"-i\" \"-w\"))"
 492   :type '(repeat (string))
 493   :group 'nnir)
 494
 495 (defcustom nnir-namazu-remove-prefix (concat (getenv "HOME") "/Mail/")
 496   "*The prefix to remove from each file name returned by Namazu
 497 in order to get a group name (albeit with / instead of .).
 498
 499 For example, suppose that Namazu returns file names such as
 500 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 501 setting:  (setq nnir-namazu-remove-prefix \"/home/john/Mail/\")
 502 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 503 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 504 arrive at the correct group name, \"mail.misc\"."
 505   :type '(directory)
 506   :group 'nnir)
 507
 508 (defcustom nnir-notmuch-program "notmuch"
 509   "*Name of notmuch search executable."
 510   :version "24.1"
 511   :type '(string)
 512   :group 'nnir)
 513
 514 (defcustom nnir-notmuch-additional-switches '()
 515   "*A list of strings, to be given as additional arguments to notmuch.
 516
 517 Note that this should be a list.  Ie, do NOT use the following:
 518     (setq nnir-notmuch-additional-switches \"-i -w\") ; wrong
 519 Instead, use this:
 520     (setq nnir-notmuch-additional-switches '(\"-i\" \"-w\"))"
 521   :version "24.1"
 522   :type '(repeat (string))
 523   :group 'nnir)
 524
 525 (defcustom nnir-notmuch-remove-prefix (concat (getenv "HOME") "/Mail/")
 526   "*The prefix to remove from each file name returned by notmuch
 527 in order to get a group name (albeit with / instead of .).  This is a
 528 regular expression.
 529
 530 This variable is very similar to `nnir-namazu-remove-prefix', except
 531 that it is for notmuch, not Namazu."
 532   :version "24.1"
 533   :type '(regexp)
 534   :group 'nnir)
 535
 536 ;;; Developer Extension Variable:
 537
 538 (defvar nnir-engines
 539   `((imap    nnir-run-imap
 540              ((criteria
 541                "Imap Search in"                   ; Prompt
 542                ,(mapcar 'car nnir-imap-search-arguments) ; alist for completing
 543                nil                                ; allow any user input
 544                nil                                ; initial value
 545                nnir-imap-search-argument-history  ; the history to use
 546                ,nnir-imap-default-search-key      ; default
 547                )))
 548     (gmane   nnir-run-gmane
 549              ((gmane-author . "Gmane Author: ")))
 550     (swish++ nnir-run-swish++
 551              ((swish++-group . "Swish++ Group spec: ")))
 552     (swish-e nnir-run-swish-e
 553              ((swish-e-group . "Swish-e Group spec: ")))
 554     (namazu  nnir-run-namazu
 555              ())
 556     (notmuch nnir-run-notmuch
 557              ())
 558     (hyrex   nnir-run-hyrex
 559              ((hyrex-group . "Hyrex Group spec: ")))
 560     (find-grep nnir-run-find-grep
 561                ((grep-options . "Grep options: "))))
 562   "Alist of supported search engines.
 563 Each element in the alist is a three-element list (ENGINE FUNCTION ARGS).
 564 ENGINE is a symbol designating the searching engine.  FUNCTION is also
 565 a symbol, giving the function that does the search.  The third element
 566 ARGS is a list of cons pairs (PARAM . PROMPT).  When issuing a query,
 567 the FUNCTION will issue a query for each of the PARAMs, using PROMPT.
 568
 569 The value of `nnir-search-engine' must be one of the ENGINE symbols.
 570 For example, for searching a server using namazu include
 571     (nnir-search-engine namazu)
 572 in the server definition.  Note that you have to set additional
 573 variables for most backends.  For example, the `namazu' backend
 574 needs the variables `nnir-namazu-program',
 575 `nnir-namazu-index-directory' and `nnir-namazu-remove-prefix'.
 576
 577 Add an entry here when adding a new search engine.")
 578
 579 (defcustom nnir-method-default-engines  '((nnimap . imap) (nntp . gmane))
 580   "*Alist of default search engines keyed by server method."
 581   :version "24.1"
 582   :group 'nnir
 583   :type `(repeat (cons (choice (const nnimap) (const nntp) (const nnspool)
 584                                (const nneething) (const nndir) (const nnmbox)
 585                                (const nnml) (const nnmh) (const nndraft)
 586                                (const nnfolder) (const nnmaildir))
 587                        (choice
 588                         ,@(mapcar (lambda (elem) (list 'const (car elem)))
 589                                   nnir-engines)))))
 590
 591 ;; Gnus glue.
 592
 593 (defun gnus-group-make-nnir-group (nnir-extra-parms &optional specs)
 594   "Create an nnir group.  Prompt for a search query and determine
 595 the groups to search as follows: if called from the *Server*
 596 buffer search all groups belonging to the server on the current
 597 line; if called from the *Group* buffer search any marked groups,
 598 or the group on the current line, or all the groups under the
 599 current topic. Calling with a prefix-arg prompts for additional
 600 search-engine specific constraints. A non-nil `specs' arg must be
 601 an alist with `nnir-query-spec' and `nnir-group-spec' keys, and
 602 skips all prompting."
 603   (interactive "P")
 604   (let* ((group-spec
 605           (or (cdr (assoc 'nnir-group-spec specs))
 606             (if (gnus-server-server-name)
 607                 (list (list (gnus-server-server-name)))
 608               (nnir-categorize
 609                (or gnus-group-marked
 610                    (if (gnus-group-group-name)
 611                        (list (gnus-group-group-name))
 612                      (cdr (assoc (gnus-group-topic-name) gnus-topic-alist))))
 613                gnus-group-server))))
 614          (query-spec
 615           (or (cdr (assoc 'nnir-query-spec specs))
 616             (apply
 617              'append
 618              (list (cons 'query
 619                          (read-string "Query: " nil 'nnir-search-history)))
 620              (when nnir-extra-parms
 621                (mapcar
 622                 (lambda (x)
 623                   (nnir-read-parms (nnir-server-to-search-engine (car x))))
 624                 group-spec))))))
 625     (gnus-group-read-ephemeral-group
 626      (concat "nnir-" (message-unique-id))
 627      (list 'nnir "nnir")
 628      nil
 629 ;     (cons (current-buffer) gnus-current-window-configuration)
 630      nil
 631      nil nil
 632      (list
 633       (cons 'nnir-specs (list (cons 'nnir-query-spec query-spec)
 634                               (cons 'nnir-group-spec group-spec)))
 635       (cons 'nnir-artlist nil)))))
 636
 637 (defun gnus-summary-make-nnir-group (nnir-extra-parms)
 638   "Search a group from the summary buffer."
 639   (interactive "P")
 640   (gnus-warp-to-article)
 641   (let ((spec
 642          (list
 643           (cons 'nnir-group-spec
 644                 (list (list
 645                        (gnus-group-server gnus-newsgroup-name)
 646                        (list gnus-newsgroup-name)))))))
 647     (gnus-group-make-nnir-group nnir-extra-parms spec)))
 648
 649
 650 ;; Gnus backend interface functions.
 651
 652 (deffoo nnir-open-server (server &optional definitions)
 653   ;; Just set the server variables appropriately.
 654   (let ((backend (car (gnus-server-to-method server))))
 655     (if backend
 656         (nnoo-change-server backend server definitions)
 657       (add-hook 'gnus-summary-mode-hook 'nnir-mode)
 658       (nnoo-change-server 'nnir server definitions))))
 659
 660 (deffoo nnir-request-group (group &optional server dont-check info)
 661   (nnir-possibly-change-group group server)
 662   (let ((pgroup (if (gnus-group-prefixed-p group)
 663                     group
 664                   (gnus-group-prefixed-name  group '(nnir "nnir"))))
 665         length)
 666     ;; Check for cached search result or run the query and cache the
 667     ;; result.
 668     (unless (and nnir-artlist dont-check)
 669       (gnus-group-set-parameter
 670        pgroup 'nnir-artlist
 671        (setq nnir-artlist
 672              (nnir-run-query
 673               (gnus-group-get-parameter pgroup 'nnir-specs t))))
 674       (nnir-request-update-info pgroup (gnus-get-info pgroup)))
 675     (with-current-buffer nntp-server-buffer
 676       (if (zerop (setq length (nnir-artlist-length nnir-artlist)))
 677           (progn
 678             (nnir-close-group group)
 679             (nnheader-report 'nnir "Search produced empty results."))
 680         (nnheader-insert "211 %d %d %d %s\n"
 681                          length    ; total #
 682                          1         ; first #
 683                          length    ; last #
 684                          group)))) ; group name
 685   nnir-artlist)
 686
 687 (deffoo nnir-retrieve-headers (articles &optional group server fetch-old)
 688   (with-current-buffer nntp-server-buffer
 689     (let ((gnus-inhibit-demon t)
 690           (articles-by-group (nnir-categorize
 691                               articles nnir-article-group nnir-article-ids))
 692           headers)
 693       (while (not (null articles-by-group))
 694         (let* ((group-articles (pop articles-by-group))
 695                (artgroup (car group-articles))
 696                (articleids (cadr group-articles))
 697                (artlist (sort (mapcar 'cdr articleids) '<))
 698                (server (gnus-group-server artgroup))
 699                (gnus-override-method (gnus-server-to-method server))
 700                parsefunc)
 701           ;; (nnir-possibly-change-group nil server)
 702           (erase-buffer)
 703           (case (setq gnus-headers-retrieved-by
 704                       (or
 705                        (and
 706                         nnir-retrieve-headers-override-function
 707                         (funcall nnir-retrieve-headers-override-function
 708                                  artlist artgroup))
 709                        (gnus-retrieve-headers artlist artgroup nil)))
 710             (nov
 711              (setq parsefunc 'nnheader-parse-nov))
 712             (headers
 713              (setq parsefunc 'nnheader-parse-head))
 714             (t (error "Unknown header type %s while requesting articles \
 715                     of group %s" gnus-headers-retrieved-by artgroup)))
 716           (goto-char (point-min))
 717           (while (not (eobp))
 718             (let* ((novitem (funcall parsefunc))
 719                    (artno (and novitem
 720                                (mail-header-number novitem)))
 721                    (art (car (rassq artno articleids))))
 722               (when art
 723                 (mail-header-set-number novitem art)
 724                 (push novitem headers))
 725               (forward-line 1)))))
 726       (setq headers
 727             (sort headers
 728                   (lambda (x y)
 729                     (< (mail-header-number x) (mail-header-number y)))))
 730       (erase-buffer)
 731       (mapc 'nnheader-insert-nov headers)
 732       'nov)))
 733
 734 (deffoo nnir-request-article (article &optional group server to-buffer)
 735   (nnir-possibly-change-group group server)
 736   (if (and (stringp article)
 737            (not (eq 'nnimap (car (gnus-server-to-method server)))))
 738       (nnheader-report
 739        'nnir
 740        "nnir-request-article only groks message ids for nnimap servers: %s"
 741        server)
 742     (save-excursion
 743       (let ((article article)
 744             query)
 745         (when (stringp article)
 746           (setq gnus-override-method (gnus-server-to-method server))
 747           (setq query
 748                 (list
 749                  (cons 'query (format "HEADER Message-ID %s" article))
 750                  (cons 'criteria "")
 751                  (cons 'shortcut t)))
 752           (unless (and nnir-artlist (equal query nnir-memo-query)
 753                        (equal server nnir-memo-server))
 754             (setq nnir-artlist (nnir-run-imap query server)
 755                   nnir-memo-query query
 756                   nnir-memo-server server))
 757           (setq article 1))
 758         (unless (zerop (nnir-artlist-length nnir-artlist))
 759           (let ((artfullgroup (nnir-article-group article))
 760                 (artno (nnir-article-number article)))
 761             (message "Requesting article %d from group %s"
 762                      artno artfullgroup)
 763             (if to-buffer
 764                 (with-current-buffer to-buffer
 765                   (let ((gnus-article-decode-hook nil))
 766                     (gnus-request-article-this-buffer artno artfullgroup)))
 767               (gnus-request-article artno artfullgroup))
 768             (cons artfullgroup artno)))))))
 769
 770 (deffoo nnir-request-move-article (article group server accept-form
 771                                            &optional last internal-move-group)
 772   (nnir-possibly-change-group group server)
 773   (let* ((artfullgroup (nnir-article-group article))
 774          (artno (nnir-article-number article))
 775          (to-newsgroup (nth 1 accept-form))
 776          (to-method (gnus-find-method-for-group to-newsgroup))
 777          (from-method (gnus-find-method-for-group artfullgroup))
 778          (move-is-internal (gnus-server-equal from-method to-method)))
 779     (unless (gnus-check-backend-function
 780              'request-move-article artfullgroup)
 781       (error "The group %s does not support article moving" artfullgroup))
 782     (gnus-request-move-article
 783      artno
 784      artfullgroup
 785      (nth 1 from-method)
 786      accept-form
 787      last
 788      (and move-is-internal
 789           to-newsgroup          ; Not respooling
 790           (gnus-group-real-name to-newsgroup)))))
 791
 792 (deffoo nnir-request-expire-articles (articles group &optional server force)
 793   (nnir-possibly-change-group group server)
 794   (if force
 795     (let ((articles-by-group (nnir-categorize
 796                               articles nnir-article-group nnir-article-ids))
 797           not-deleted)
 798       (while (not (null articles-by-group))
 799         (let* ((group-articles (pop articles-by-group))
 800                (artgroup (car group-articles))
 801                (articleids (cadr group-articles))
 802                (artlist (sort (mapcar 'cdr articleids) '<)))
 803           (unless (gnus-check-backend-function 'request-expire-articles
 804                                                artgroup)
 805             (error "The group %s does not support article deletion" artgroup))
 806           (unless (gnus-check-server (gnus-find-method-for-group artgroup))
 807             (error "Couldn't open server for group %s" artgroup))
 808           (push (gnus-request-expire-articles
 809                  artlist artgroup force)
 810                 not-deleted)))
 811       (sort (delq nil not-deleted) '<))
 812     articles))
 813
 814 (deffoo nnir-warp-to-article ()
 815   (nnir-possibly-change-group gnus-newsgroup-name)
 816   (let* ((cur (if (> (gnus-summary-article-number) 0)
 817                   (gnus-summary-article-number)
 818                 (error "Can't warp to a pseudo-article")))
 819          (backend-article-group (nnir-article-group cur))
 820          (backend-article-number (nnir-article-number cur))
 821          (quit-config (gnus-ephemeral-group-p gnus-newsgroup-name)))
 822
 823     ;; what should we do here? we could leave all the buffers around
 824     ;; and assume that we have to exit from them one by one. or we can
 825     ;; try to clean up directly
 826
 827     ;;first exit from the nnir summary buffer.
 828 ;    (gnus-summary-exit)
 829     ;; and if the nnir summary buffer in turn came from another
 830     ;; summary buffer we have to clean that summary up too.
 831  ;   (when (not (eq (cdr quit-config) 'group))
 832 ;      (gnus-summary-exit))
 833     (gnus-summary-read-group-1 backend-article-group t t  nil
 834                                nil (list backend-article-number))))
 835
 836 (deffoo nnir-request-update-mark (group article mark)
 837   (let ((artgroup (nnir-article-group article))
 838         (artnumber (nnir-article-number article)))
 839     (gnus-request-update-mark artgroup artnumber mark)))
 840
 841 (deffoo nnir-request-set-mark (group actions &optional server)
 842   (let (mlist)
 843     (dolist (action actions)
 844       (destructuring-bind (range action marks) action
 845         (let ((articles-by-group (nnir-categorize
 846                                   (gnus-uncompress-range range)
 847                                   nnir-article-group nnir-article-number)))
 848           (dolist (artgroup articles-by-group)
 849             (push (list
 850                    (car artgroup)
 851                    (list (gnus-compress-sequence
 852                           (sort (cadr artgroup) '<)) action marks)) mlist)))))
 853     (dolist (request (nnir-categorize  mlist car cadr))
 854       (gnus-request-set-mark (car request) (cadr request)))))
 855
 856
 857 (deffoo nnir-request-update-info (group info &optional server)
 858   (nnir-possibly-change-group group)
 859   ;; clear out all existing marks.
 860   (gnus-info-set-marks info nil)
 861   (gnus-info-set-read info nil)
 862   (let ((group (gnus-group-guess-full-name-from-command-method group))
 863         (articles-by-group
 864          (nnir-categorize
 865           (gnus-uncompress-range (cons 1 (nnir-artlist-length nnir-artlist)))
 866           nnir-article-group nnir-article-ids)))
 867     (gnus-set-active group
 868                      (cons 1 (nnir-artlist-length nnir-artlist)))
 869     (while (not (null articles-by-group))
 870       (let* ((group-articles (pop articles-by-group))
 871              (articleids (reverse (cadr group-articles)))
 872              (group-info (gnus-get-info (car group-articles)))
 873              (marks (gnus-info-marks group-info))
 874              (read (gnus-info-read group-info)))
 875         (gnus-info-set-read
 876          info
 877          (gnus-add-to-range
 878           (gnus-info-read info)
 879           (delq nil
 880                   (mapcar
 881                    #'(lambda (art)
 882                      (when (gnus-member-of-range (cdr art) read) (car art)))
 883                    articleids))))
 884         (dolist (mark marks)
 885           (destructuring-bind (type . range) mark
 886             (gnus-add-marked-articles
 887              group type
 888              (delq nil
 889                      (mapcar
 890                       #'(lambda (art)
 891                         (when (gnus-member-of-range (cdr art) range) (car art)))
 892                       articleids)))))))))
 893
 894
 895 (deffoo nnir-close-group (group &optional server)
 896   (let ((pgroup (if (gnus-group-prefixed-p group)
 897                     group
 898                   (gnus-group-prefixed-name  group '(nnir "nnir")))))
 899     (when (and nnir-artlist (not (gnus-ephemeral-group-p pgroup)))
 900       (gnus-group-set-parameter  pgroup 'nnir-artlist nnir-artlist))
 901     (setq nnir-artlist nil)
 902     (when (gnus-ephemeral-group-p pgroup)
 903       (gnus-kill-ephemeral-group pgroup)
 904       (setq gnus-ephemeral-servers
 905             (delq (assq 'nnir gnus-ephemeral-servers)
 906                   gnus-ephemeral-servers)))))
 907 ;; (gnus-opened-servers-remove
 908 ;;  (car (assoc  '(nnir "nnir-ephemeral" (nnir-address "nnir"))
 909 ;;              gnus-opened-servers))))
 910
 911
 912
 913
 914 (defmacro nnir-add-result (dirnam artno score prefix server artlist)
 915   "Ask `nnir-compose-result' to construct a result vector,
 916 and if it is non-nil, add it to artlist."
 917   `(let ((result (nnir-compose-result ,dirnam ,artno ,score ,prefix ,server)))
 918      (when (not (null result))
 919        (push result ,artlist))))
 920
 921 (autoload 'nnmaildir-base-name-to-article-number "nnmaildir")
 922
 923 ;; Helper function currently used by the Swish++ and Namazu backends;
 924 ;; perhaps useful for other backends as well
 925 (defun nnir-compose-result (dirnam article score prefix server)
 926   "Extract the group from dirnam, and create a result vector
 927 ready to be added to the list of search results."
 928
 929   ;; remove nnir-*-remove-prefix from beginning of dirnam filename
 930   (when (string-match (concat "^" prefix) dirnam)
 931     (setq dirnam (replace-match "" t t dirnam)))
 932
 933   (when (file-readable-p (concat prefix dirnam article))
 934     ;; remove trailing slash and, for nnmaildir, cur/new/tmp
 935     (setq dirnam
 936           (substring dirnam 0
 937                      (if (string-match "\\`nnmaildir:" (gnus-group-server server))
 938                          -5 -1)))
 939
 940     ;; Set group to dirnam without any leading dots or slashes,
 941     ;; and with all subsequent slashes replaced by dots
 942     (let ((group (gnus-replace-in-string
 943                  (gnus-replace-in-string dirnam "^[./\\]" "" t)
 944                  "[/\\]" "." t)))
 945
 946     (vector (gnus-group-full-name group server)
 947             (if (string-match "\\`nnmaildir:" (gnus-group-server server))
 948                 (nnmaildir-base-name-to-article-number
 949                  (substring article 0 (string-match ":" article))
 950                  group nil)
 951               (string-to-number article))
 952             (string-to-number score)))))
 953
 954 ;;; Search Engine Interfaces:
 955
 956 ;; imap interface
 957 (defun nnir-run-imap (query srv &optional groups)
 958   "Run a search against an IMAP back-end server.
 959 This uses a custom query language parser; see `nnir-imap-make-query' for
 960 details on the language and supported extensions."
 961   (save-excursion
 962     (let ((qstring (cdr (assq 'query query)))
 963           (server (cadr (gnus-server-to-method srv)))
 964           (defs (caddr (gnus-server-to-method srv)))
 965           (criteria (or (cdr (assq 'criteria query))
 966                         (cdr (assoc nnir-imap-default-search-key
 967                                     nnir-imap-search-arguments))))
 968           (gnus-inhibit-demon t)
 969           (groups (or groups (nnir-get-active srv))))
 970       (message "Opening server %s" server)
 971       (apply
 972        'vconcat
 973        (catch 'found
 974          (mapcar
 975           (lambda (group)
 976             (let (artlist)
 977               (condition-case ()
 978                   (when (nnimap-change-group
 979                          (gnus-group-short-name group) server)
 980                     (with-current-buffer (nnimap-buffer)
 981                       (message "Searching %s..." group)
 982                       (let ((arts 0)
 983                             (result (nnimap-command "UID SEARCH %s"
 984                                                     (if (string= criteria "")
 985                                                         qstring
 986                                                       (nnir-imap-make-query
 987                                                        criteria qstring)))))
 988                         (mapc
 989                          (lambda (artnum)
 990                            (let ((artn (string-to-number artnum)))
 991                              (when (> artn 0)
 992                                (push (vector group artn 100)
 993                                      artlist)
 994                                (when (assq 'shortcut query)
 995                                  (throw 'found (list artlist)))
 996                                (setq arts (1+ arts)))))
 997                          (and (car result)
 998                               (cdr (assoc "SEARCH" (cdr result)))))
 999                         (message "Searching %s... %d matches" group arts)))
1000                     (message "Searching %s...done" group))
1001                 (quit nil))
1002               (nreverse artlist)))
1003           groups))))))
1004
1005 (defun nnir-imap-make-query (criteria qstring)
1006   "Parse the query string and criteria into an appropriate IMAP search
1007 expression, returning the string query to make.
1008
1009 This implements a little language designed to return the expected results
1010 to an arbitrary query string to the end user.
1011
1012 The search is always case-insensitive, as defined by RFC2060, and supports
1013 the following features (inspired by the Google search input language):
1014
1015 Automatic \"and\" queries
1016     If you specify multiple words then they will be treated as an \"and\"
1017     expression intended to match all components.
1018
1019 Phrase searches
1020     If you wrap your query in double-quotes then it will be treated as a
1021     literal string.
1022
1023 Negative terms
1024     If you precede a term with \"-\" then it will negate that.
1025
1026 \"OR\" queries
1027     If you include an upper-case \"OR\" in your search it will cause the
1028     term before it and the term after it to be treated as alternatives.
1029
1030 In future the following will be added to the language:
1031  * support for date matches
1032  * support for location of text matching within the query
1033  * from/to/etc headers
1034  * additional search terms
1035  * flag based searching
1036  * anything else that the RFC supports, basically."
1037   ;; Walk through the query and turn it into an IMAP query string.
1038   (nnir-imap-query-to-imap criteria (nnir-imap-parse-query qstring)))
1039
1040
1041 (defun nnir-imap-query-to-imap (criteria query)
1042   "Turn a s-expression format query into IMAP."
1043   (mapconcat
1044    ;; Turn the expressions into IMAP text
1045    (lambda (item)
1046      (nnir-imap-expr-to-imap criteria item))
1047    ;; The query, already in s-expr format.
1048    query
1049    ;; Append a space between each expression
1050    " "))
1051
1052
1053 (defun nnir-imap-expr-to-imap (criteria expr)
1054   "Convert EXPR into an IMAP search expression on CRITERIA"
1055   ;; What sort of expression is this, eh?
1056   (cond
1057    ;; Simple string term
1058    ((stringp expr)
1059     (format "%s %S" criteria expr))
1060    ;; Trivial term: and
1061    ((eq expr 'and) nil)
1062    ;; Composite term: or expression
1063    ((eq (car-safe expr) 'or)
1064     (format "OR %s %s"
1065             (nnir-imap-expr-to-imap criteria (second expr))
1066             (nnir-imap-expr-to-imap criteria (third expr))))
1067    ;; Composite term: just the fax, mam
1068    ((eq (car-safe expr) 'not)
1069     (format "NOT (%s)" (nnir-imap-query-to-imap criteria (rest expr))))
1070    ;; Composite term: just expand it all.
1071    ((and (not (null expr)) (listp expr))
1072     (format "(%s)" (nnir-imap-query-to-imap criteria expr)))
1073    ;; Complex value, give up for now.
1074    (t (error "Unhandled input: %S" expr))))
1075
1076
1077 (defun nnir-imap-parse-query (string)
1078   "Turn STRING into an s-expression based query based on the IMAP
1079 query language as defined in `nnir-imap-make-query'.
1080
1081 This involves turning individual tokens into higher level terms
1082 that the search language can then understand and use."
1083   (with-temp-buffer
1084     ;; Set up the parsing environment.
1085     (insert string)
1086     (goto-char (point-min))
1087     ;; Now, collect the output terms and return them.
1088     (let (out)
1089       (while (not (nnir-imap-end-of-input))
1090         (push (nnir-imap-next-expr) out))
1091       (reverse out))))
1092
1093
1094 (defun nnir-imap-next-expr (&optional count)
1095   "Return the next expression from the current buffer."
1096   (let ((term (nnir-imap-next-term count))
1097         (next (nnir-imap-peek-symbol)))
1098     ;; Are we looking at an 'or' expression?
1099     (cond
1100      ;; Handle 'expr or expr'
1101      ((eq next 'or)
1102       (list 'or term (nnir-imap-next-expr 2)))
1103      ;; Anything else
1104      (t term))))
1105
1106
1107 (defun nnir-imap-next-term (&optional count)
1108   "Return the next TERM from the current buffer."
1109   (let ((term (nnir-imap-next-symbol count)))
1110     ;; What sort of term is this?
1111     (cond
1112      ;; and -- just ignore it
1113      ((eq term 'and) 'and)
1114      ;; negated term
1115      ((eq term 'not) (list 'not (nnir-imap-next-expr)))
1116      ;; generic term
1117      (t term))))
1118
1119
1120 (defun nnir-imap-peek-symbol ()
1121   "Return the next symbol from the current buffer, but don't consume it."
1122   (save-excursion
1123     (nnir-imap-next-symbol)))
1124
1125 (defun nnir-imap-next-symbol (&optional count)
1126   "Return the next symbol from the current buffer, or nil if we are
1127 at the end of the buffer.  If supplied COUNT skips some symbols before
1128 returning the one at the supplied position."
1129   (when (and (numberp count) (> count 1))
1130     (nnir-imap-next-symbol (1- count)))
1131   (let ((case-fold-search t))
1132     ;; end of input stream?
1133     (unless (nnir-imap-end-of-input)
1134       ;; No, return the next symbol from the stream.
1135       (cond
1136        ;; negated expression -- return it and advance one char.
1137        ((looking-at "-") (forward-char 1) 'not)
1138        ;; quoted string
1139        ((looking-at "\"") (nnir-imap-delimited-string "\""))
1140        ;; list expression -- we parse the content and return this as a list.
1141        ((looking-at "(")
1142         (nnir-imap-parse-query (nnir-imap-delimited-string ")")))
1143        ;; keyword input -- return a symbol version
1144        ((looking-at "\\band\\b") (forward-char 3) 'and)
1145        ((looking-at "\\bor\\b")  (forward-char 2) 'or)
1146        ((looking-at "\\bnot\\b") (forward-char 3) 'not)
1147        ;; Simple, boring keyword
1148        (t (let ((start (point))
1149                 (end (if (search-forward-regexp "[[:blank:]]" nil t)
1150                          (prog1
1151                              (match-beginning 0)
1152                            ;; unskip if we hit a non-blank terminal character.
1153                            (when (string-match "[^[:blank:]]" (match-string 0))
1154                              (backward-char 1)))
1155                        (goto-char (point-max)))))
1156             (buffer-substring start end)))))))
1157
1158 (defun nnir-imap-delimited-string (delimiter)
1159   "Return a delimited string from the current buffer."
1160   (let ((start (point)) end)
1161     (forward-char 1)                    ; skip the first delimiter.
1162     (while (not end)
1163       (unless (search-forward delimiter nil t)
1164         (error "Unmatched delimited input with %s in query" delimiter))
1165       (let ((here (point)))
1166         (unless (equal (buffer-substring (- here 2) (- here 1)) "\\")
1167           (setq end (point)))))
1168     (buffer-substring (1+ start) (1- end))))
1169
1170 (defun nnir-imap-end-of-input ()
1171   "Are we at the end of input?"
1172   (skip-chars-forward "[[:blank:]]")
1173   (looking-at "$"))
1174
1175
1176 ;; Swish++ interface.
1177 ;; -cc- Todo
1178 ;; Search by
1179 ;; - group
1180 ;; Sort by
1181 ;; - rank (default)
1182 ;; - article number
1183 ;; - file size
1184 ;; - group
1185 (defun nnir-run-swish++ (query server &optional group)
1186   "Run QUERY against swish++.
1187 Returns a vector of (group name, file name) pairs (also vectors,
1188 actually).
1189
1190 Tested with swish++ 4.7 on GNU/Linux and with swish++ 5.0b2 on
1191 Windows NT 4.0."
1192
1193   ;; (when group
1194   ;;   (error "The swish++ backend cannot search specific groups"))
1195
1196   (save-excursion
1197     (let ( (qstring (cdr (assq 'query query)))
1198            (groupspec (cdr (assq 'swish++-group query)))
1199            (prefix (nnir-read-server-parm 'nnir-swish++-remove-prefix server))
1200            artlist
1201            ;; nnml-use-compressed-files might be any string, but probably this
1202            ;; is sufficient.  Note that we can't only use the value of
1203            ;; nnml-use-compressed-files because old articles might have been
1204            ;; saved with a different value.
1205            (article-pattern (if (string-match "\\`nnmaildir:"
1206                                               (gnus-group-server server))
1207                                 ":[0-9]+"
1208                               "^[0-9]+\\(\\.[a-z0-9]+\\)?$"))
1209            score artno dirnam filenam)
1210
1211       (when (equal "" qstring)
1212         (error "swish++: You didn't enter anything"))
1213
1214       (set-buffer (get-buffer-create nnir-tmp-buffer))
1215       (erase-buffer)
1216
1217       (if groupspec
1218           (message "Doing swish++ query %s on %s..." qstring groupspec)
1219         (message "Doing swish++ query %s..." qstring))
1220
1221       (let* ((cp-list `( ,nnir-swish++-program
1222                          nil            ; input from /dev/null
1223                          t              ; output
1224                          nil            ; don't redisplay
1225                          "--config-file" ,(nnir-read-server-parm 'nnir-swish++-configuration-file server)
1226                          ,@(nnir-read-server-parm 'nnir-swish++-additional-switches server)
1227                          ,qstring       ; the query, in swish++ format
1228                          ))
1229              (exitstatus
1230               (progn
1231                 (message "%s args: %s" nnir-swish++-program
1232                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1233                 (apply 'call-process cp-list))))
1234         (unless (or (null exitstatus)
1235                     (zerop exitstatus))
1236           (nnheader-report 'nnir "Couldn't run swish++: %s" exitstatus)
1237           ;; swish++ failure reason is in this buffer, show it if
1238           ;; the user wants it.
1239           (when (> gnus-verbose 6)
1240             (display-buffer nnir-tmp-buffer))))
1241
1242       ;; The results are output in the format of:
1243       ;; V 4.7 Linux
1244       ;; rank relative-path-name file-size file-title
1245       ;; V 5.0b2:
1246       ;; rank relative-path-name file-size topic??
1247       ;; where rank is an integer from 1 to 100.
1248       (goto-char (point-min))
1249       (while (re-search-forward
1250               "\\(^[0-9]+\\) \\([^ ]+\\) [0-9]+ \\(.*\\)$" nil t)
1251         (setq score (match-string 1)
1252               filenam (match-string 2)
1253               artno (file-name-nondirectory filenam)
1254               dirnam (file-name-directory filenam))
1255
1256         ;; don't match directories
1257         (when (string-match article-pattern artno)
1258           (when (not (null dirnam))
1259
1260             ;; maybe limit results to matching groups.
1261             (when (or (not groupspec)
1262                       (string-match groupspec dirnam))
1263               (nnir-add-result dirnam artno score prefix server artlist)))))
1264
1265       (message "Massaging swish++ output...done")
1266
1267       ;; Sort by score
1268       (apply 'vector
1269              (sort artlist
1270                    (function (lambda (x y)
1271                                (> (nnir-artitem-rsv x)
1272                                   (nnir-artitem-rsv y)))))))))
1273
1274 ;; Swish-E interface.
1275 (defun nnir-run-swish-e (query server &optional group)
1276   "Run given query against swish-e.
1277 Returns a vector of (group name, file name) pairs (also vectors,
1278 actually).
1279
1280 Tested with swish-e-2.0.1 on Windows NT 4.0."
1281
1282   ;; swish-e crashes with empty parameter to "-w" on commandline...
1283   ;; (when group
1284   ;;   (error "The swish-e backend cannot search specific groups"))
1285
1286   (save-excursion
1287     (let ((qstring (cdr (assq 'query query)))
1288           (prefix
1289            (or (nnir-read-server-parm 'nnir-swish-e-remove-prefix server)
1290                (error "Missing parameter `nnir-swish-e-remove-prefix'")))
1291           artlist score artno dirnam group )
1292
1293       (when (equal "" qstring)
1294         (error "swish-e: You didn't enter anything"))
1295
1296       (set-buffer (get-buffer-create nnir-tmp-buffer))
1297       (erase-buffer)
1298
1299       (message "Doing swish-e query %s..." query)
1300       (let* ((index-files
1301               (or (nnir-read-server-parm
1302                    'nnir-swish-e-index-files server)
1303                   (error "Missing parameter `nnir-swish-e-index-files'")))
1304              (additional-switches
1305               (nnir-read-server-parm
1306                'nnir-swish-e-additional-switches server))
1307              (cp-list `(,nnir-swish-e-program
1308                         nil             ; input from /dev/null
1309                         t               ; output
1310                         nil             ; don't redisplay
1311                         "-f" ,@index-files
1312                         ,@additional-switches
1313                         "-w"
1314                         ,qstring        ; the query, in swish-e format
1315                         ))
1316              (exitstatus
1317               (progn
1318                 (message "%s args: %s" nnir-swish-e-program
1319                          (mapconcat 'identity (cddddr cp-list) " "))
1320                 (apply 'call-process cp-list))))
1321         (unless (or (null exitstatus)
1322                     (zerop exitstatus))
1323           (nnheader-report 'nnir "Couldn't run swish-e: %s" exitstatus)
1324           ;; swish-e failure reason is in this buffer, show it if
1325           ;; the user wants it.
1326           (when (> gnus-verbose 6)
1327             (display-buffer nnir-tmp-buffer))))
1328
1329       ;; The results are output in the format of:
1330       ;; rank path-name file-title file-size
1331       (goto-char (point-min))
1332       (while (re-search-forward
1333               "\\(^[0-9]+\\) \\([^ ]+\\) \"\\([^\"]+\\)\" [0-9]+$" nil t)
1334         (setq score (match-string 1)
1335               artno (match-string 3)
1336               dirnam (file-name-directory (match-string 2)))
1337
1338         ;; don't match directories
1339         (when (string-match "^[0-9]+$" artno)
1340           (when (not (null dirnam))
1341
1342             ;; remove nnir-swish-e-remove-prefix from beginning of dirname
1343             (when (string-match (concat "^" prefix) dirnam)
1344               (setq dirnam (replace-match "" t t dirnam)))
1345
1346             (setq dirnam (substring dirnam 0 -1))
1347             ;; eliminate all ".", "/", "\" from beginning. Always matches.
1348             (string-match "^[./\\]*\\(.*\\)$" dirnam)
1349             ;; "/" -> "."
1350             (setq group (gnus-replace-in-string (match-string 1 dirnam) "/" "."))
1351             ;; Windows "\\" -> "."
1352             (setq group (gnus-replace-in-string group "\\\\" "."))
1353
1354             (push (vector (gnus-group-full-name group server)
1355                           (string-to-number artno)
1356                           (string-to-number score))
1357                   artlist))))
1358
1359       (message "Massaging swish-e output...done")
1360
1361       ;; Sort by score
1362       (apply 'vector
1363              (sort artlist
1364                    (function (lambda (x y)
1365                                (> (nnir-artitem-rsv x)
1366                                   (nnir-artitem-rsv y)))))))))
1367
1368 ;; HyREX interface
1369 (defun nnir-run-hyrex (query server &optional group)
1370   (save-excursion
1371     (let ((artlist nil)
1372           (groupspec (cdr (assq 'hyrex-group query)))
1373           (qstring (cdr (assq 'query query)))
1374           (prefix (nnir-read-server-parm 'nnir-hyrex-remove-prefix server))
1375           score artno dirnam)
1376       (when (and (not groupspec) group)
1377         (setq groupspec
1378               (regexp-opt
1379                (mapcar (lambda (x) (gnus-group-real-name x)) group))))
1380       (set-buffer (get-buffer-create nnir-tmp-buffer))
1381       (erase-buffer)
1382       (message "Doing hyrex-search query %s..." query)
1383       (let* ((cp-list
1384               `( ,nnir-hyrex-program
1385                  nil                    ; input from /dev/null
1386                  t                      ; output
1387                  nil                    ; don't redisplay
1388                  "-i",(nnir-read-server-parm 'nnir-hyrex-index-directory server) ; index directory
1389                  ,@(nnir-read-server-parm 'nnir-hyrex-additional-switches server)
1390                  ,qstring          ; the query, in hyrex-search format
1391                  ))
1392              (exitstatus
1393               (progn
1394                 (message "%s args: %s" nnir-hyrex-program
1395                          (mapconcat 'identity (cddddr cp-list) " "))
1396                 (apply 'call-process cp-list))))
1397         (unless (or (null exitstatus)
1398                     (zerop exitstatus))
1399           (nnheader-report 'nnir "Couldn't run hyrex-search: %s" exitstatus)
1400           ;; nnir-search failure reason is in this buffer, show it if
1401           ;; the user wants it.
1402           (when (> gnus-verbose 6)
1403             (display-buffer nnir-tmp-buffer)))) ;; FIXME: Don't clear buffer !
1404       (message "Doing hyrex-search query \"%s\"...done" qstring)
1405       (sit-for 0)
1406       ;; nnir-search returns:
1407       ;;   for nnml/nnfolder: "filename mailid weight"
1408       ;;   for nnimap:        "group mailid weight"
1409       (goto-char (point-min))
1410       (delete-non-matching-lines "^\\S + [0-9]+ [0-9]+$")
1411       ;; HyREX doesn't search directly in groups -- so filter out here.
1412       (when groupspec
1413         (keep-lines groupspec))
1414       ;; extract data from result lines
1415       (goto-char (point-min))
1416       (while (re-search-forward
1417               "\\(\\S +\\) \\([0-9]+\\) \\([0-9]+\\)" nil t)
1418         (setq dirnam (match-string 1)
1419               artno (match-string 2)
1420               score (match-string 3))
1421         (when (string-match prefix dirnam)
1422           (setq dirnam (replace-match "" t t dirnam)))
1423         (push (vector (gnus-group-full-name
1424                        (gnus-replace-in-string dirnam "/" ".") server)
1425                       (string-to-number artno)
1426                       (string-to-number score))
1427               artlist))
1428       (message "Massaging hyrex-search output...done.")
1429       (apply 'vector
1430              (sort artlist
1431                    (function (lambda (x y)
1432                                (if (string-lessp (nnir-artitem-group x)
1433                                                  (nnir-artitem-group y))
1434                                    t
1435                                  (< (nnir-artitem-number x)
1436                                     (nnir-artitem-number y)))))))
1437       )))
1438
1439 ;; Namazu interface
1440 (defun nnir-run-namazu (query server &optional group)
1441   "Run given query against Namazu.  Returns a vector of (group name, file name)
1442 pairs (also vectors, actually).
1443
1444 Tested with Namazu 2.0.6 on a GNU/Linux system."
1445   ;; (when group
1446   ;;   (error "The Namazu backend cannot search specific groups"))
1447   (save-excursion
1448     (let ((article-pattern (if (string-match "\\`nnmaildir:"
1449                                              (gnus-group-server server))
1450                                ":[0-9]+"
1451                              "^[0-9]+$"))
1452           artlist
1453           (qstring (cdr (assq 'query query)))
1454           (prefix (nnir-read-server-parm 'nnir-namazu-remove-prefix server))
1455           score group article
1456           (process-environment (copy-sequence process-environment)))
1457       (setenv "LC_MESSAGES" "C")
1458       (set-buffer (get-buffer-create nnir-tmp-buffer))
1459       (erase-buffer)
1460       (let* ((cp-list
1461               `( ,nnir-namazu-program
1462                  nil                    ; input from /dev/null
1463                  t                      ; output
1464                  nil                    ; don't redisplay
1465                  "-q"                   ; don't be verbose
1466                  "-a"                   ; show all matches
1467                  "-s"                   ; use short format
1468                  ,@(nnir-read-server-parm 'nnir-namazu-additional-switches server)
1469                  ,qstring               ; the query, in namazu format
1470                  ,(nnir-read-server-parm 'nnir-namazu-index-directory server) ; index directory
1471                  ))
1472              (exitstatus
1473               (progn
1474                 (message "%s args: %s" nnir-namazu-program
1475                          (mapconcat 'identity (cddddr cp-list) " "))
1476                 (apply 'call-process cp-list))))
1477         (unless (or (null exitstatus)
1478                     (zerop exitstatus))
1479           (nnheader-report 'nnir "Couldn't run namazu: %s" exitstatus)
1480           ;; Namazu failure reason is in this buffer, show it if
1481           ;; the user wants it.
1482           (when (> gnus-verbose 6)
1483             (display-buffer nnir-tmp-buffer))))
1484
1485       ;; Namazu output looks something like this:
1486       ;; 2. Re: Gnus agent expire broken (score: 55)
1487       ;; /home/henrik/Mail/mail/sent/1310 (4,138 bytes)
1488
1489       (goto-char (point-min))
1490       (while (re-search-forward
1491               "^\\([0-9]+\\.\\).*\\((score: \\([0-9]+\\)\\))\n\\([^ ]+\\)"
1492               nil t)
1493         (setq score (match-string 3)
1494               group (file-name-directory (match-string 4))
1495               article (file-name-nondirectory (match-string 4)))
1496
1497         ;; make sure article and group is sane
1498         (when (and (string-match article-pattern article)
1499                    (not (null group)))
1500           (nnir-add-result group article score prefix server artlist)))
1501
1502       ;; sort artlist by score
1503       (apply 'vector
1504              (sort artlist
1505                    (function (lambda (x y)
1506                                (> (nnir-artitem-rsv x)
1507                                   (nnir-artitem-rsv y)))))))))
1508
1509 (defun nnir-run-notmuch (query server &optional group)
1510   "Run QUERY against notmuch.
1511 Returns a vector of (group name, file name) pairs (also vectors,
1512 actually)."
1513
1514   ;; (when group
1515   ;;   (error "The notmuch backend cannot search specific groups"))
1516
1517   (save-excursion
1518     (let ( (qstring (cdr (assq 'query query)))
1519            (groupspec (cdr (assq 'notmuch-group query)))
1520            (prefix (nnir-read-server-parm 'nnir-notmuch-remove-prefix server))
1521            artlist
1522            (article-pattern (if (string-match "\\`nnmaildir:"
1523                                               (gnus-group-server server))
1524                                ":[0-9]+"
1525                              "^[0-9]+$"))
1526            artno dirnam filenam)
1527
1528       (when (equal "" qstring)
1529         (error "notmuch: You didn't enter anything"))
1530
1531       (set-buffer (get-buffer-create nnir-tmp-buffer))
1532       (erase-buffer)
1533
1534       (if groupspec
1535           (message "Doing notmuch query %s on %s..." qstring groupspec)
1536         (message "Doing notmuch query %s..." qstring))
1537
1538       (let* ((cp-list `( ,nnir-notmuch-program
1539                          nil            ; input from /dev/null
1540                          t              ; output
1541                          nil            ; don't redisplay
1542                          "search"
1543                          "--format=text"
1544                          "--output=files"
1545                          ,@(nnir-read-server-parm 'nnir-notmuch-additional-switches server)
1546                          ,qstring       ; the query, in notmuch format
1547                          ))
1548              (exitstatus
1549               (progn
1550                 (message "%s args: %s" nnir-notmuch-program
1551                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1552                 (apply 'call-process cp-list))))
1553         (unless (or (null exitstatus)
1554                     (zerop exitstatus))
1555           (nnheader-report 'nnir "Couldn't run notmuch: %s" exitstatus)
1556           ;; notmuch failure reason is in this buffer, show it if
1557           ;; the user wants it.
1558           (when (> gnus-verbose 6)
1559             (display-buffer nnir-tmp-buffer))))
1560
1561       ;; The results are output in the format of:
1562       ;; absolute-path-name
1563       (goto-char (point-min))
1564       (while (not (eobp))
1565         (setq filenam (buffer-substring-no-properties (line-beginning-position)
1566                                                       (line-end-position))
1567               artno (file-name-nondirectory filenam)
1568               dirnam (file-name-directory filenam))
1569         (forward-line 1)
1570
1571         ;; don't match directories
1572         (when (string-match article-pattern artno)
1573           (when (not (null dirnam))
1574
1575             ;; maybe limit results to matching groups.
1576             (when (or (not groupspec)
1577                       (string-match groupspec dirnam))
1578               (nnir-add-result dirnam artno "" prefix server artlist)))))
1579
1580       (message "Massaging notmuch output...done")
1581
1582       artlist)))
1583
1584 (defun nnir-run-find-grep (query server &optional grouplist)
1585   "Run find and grep to obtain matching articles."
1586   (let* ((method (gnus-server-to-method server))
1587          (sym (intern
1588                (concat (symbol-name (car method)) "-directory")))
1589          (directory (cadr (assoc sym (cddr method))))
1590          (regexp (cdr (assoc 'query query)))
1591          (grep-options (cdr (assoc 'grep-options query)))
1592          (grouplist (or grouplist (nnir-get-active server))))
1593     (unless directory
1594       (error "No directory found in method specification of server %s"
1595              server))
1596     (apply
1597      'vconcat
1598      (mapcar (lambda (x)
1599                (let ((group x)
1600                      artlist)
1601                  (message "Searching %s using find-grep..."
1602                           (or group server))
1603                  (save-window-excursion
1604                    (set-buffer (get-buffer-create nnir-tmp-buffer))
1605                    (if (> gnus-verbose 6)
1606                        (pop-to-buffer (current-buffer)))
1607                    (cd directory) ; Using relative paths simplifies
1608                                         ; postprocessing.
1609                    (let ((group
1610                           (if (not group)
1611                               "."
1612                             ;; Try accessing the group literally as
1613                             ;; well as interpreting dots as directory
1614                             ;; separators so the engine works with
1615                             ;; plain nnml as well as the Gnus Cache.
1616                             (let ((group (gnus-group-real-name group)))
1617                               ;; Replace cl-func find-if.
1618                               (if (file-directory-p group)
1619                                   group
1620                                 (if (file-directory-p
1621                                      (setq group
1622                                            (gnus-replace-in-string
1623                                             group
1624                                             "\\." "/" t)))
1625                                     group))))))
1626                      (unless group
1627                        (error "Cannot locate directory for group"))
1628                      (save-excursion
1629                        (apply
1630                         'call-process "find" nil t
1631                         "find" group "-maxdepth" "1" "-type" "f"
1632                         "-name" "[0-9]*" "-exec"
1633                         "grep"
1634                         `("-l" ,@(and grep-options
1635                                       (split-string grep-options "\\s-" t))
1636                           "-e" ,regexp "{}" "+"))))
1637
1638                    ;; Translate relative paths to group names.
1639                    (while (not (eobp))
1640                      (let* ((path (split-string
1641                                    (buffer-substring
1642                                     (point)
1643                                     (line-end-position)) "/" t))
1644                             (art (string-to-number (car (last path)))))
1645                        (while (string= "." (car path))
1646                          (setq path (cdr path)))
1647                        (let ((group (mapconcat 'identity
1648                                                ;; Replace cl-func:
1649                                                ;; (subseq path 0 -1)
1650                                                (let ((end (1- (length path)))
1651                                                      res)
1652                                                  (while
1653                                                      (>= (setq end (1- end)) 0)
1654                                                    (push (pop path) res))
1655                                                  (nreverse res))
1656                                                ".")))
1657                          (push
1658                           (vector (gnus-group-full-name group server) art 0)
1659                           artlist))
1660                        (forward-line 1)))
1661                    (message "Searching %s using find-grep...done"
1662                             (or group server))
1663                    artlist)))
1664      grouplist))))
1665
1666 (declare-function mm-url-insert "mm-url" (url &optional follow-refresh))
1667 (declare-function mm-url-encode-www-form-urlencoded "mm-url" (pairs))
1668
1669 ;; gmane interface
1670 (defun nnir-run-gmane (query srv &optional groups)
1671   "Run a search against a gmane back-end server."
1672       (let* ((case-fold-search t)
1673              (qstring (cdr (assq 'query query)))
1674              (server (cadr (gnus-server-to-method srv)))
1675              (groupspec (mapconcat
1676                          (lambda (x)
1677                            (if (gnus-string-match-p "gmane" x)
1678                                (format "group:%s" (gnus-group-short-name x))
1679                              (error "Can't search non-gmane groups: %s" x)))
1680                            groups " "))
1681              (authorspec
1682               (if (assq 'gmane-author query)
1683                   (format "author:%s" (cdr (assq 'gmane-author query))) ""))
1684              (search (format "%s %s %s"
1685                              qstring groupspec authorspec))
1686              (gnus-inhibit-demon t)
1687              artlist)
1688         (require 'mm-url)
1689         (with-current-buffer (get-buffer-create nnir-tmp-buffer)
1690           (erase-buffer)
1691           (mm-url-insert
1692            (concat
1693             "http://search.gmane.org/nov.php"
1694             "?"
1695             (mm-url-encode-www-form-urlencoded
1696              `(("query" . ,search)
1697                ("HITSPERPAGE" . "999")))))
1698           (unless (featurep 'xemacs) (set-buffer-multibyte t))
1699           (mm-decode-coding-region (point-min) (point-max) 'utf-8)
1700           (goto-char (point-min))
1701           (forward-line 1)
1702           (while (not (eobp))
1703             (unless (or (eolp) (looking-at "\x0d"))
1704               (let ((header (nnheader-parse-nov)))
1705                 (let ((xref (mail-header-xref header))
1706                       (xscore (string-to-number (cdr (assoc 'X-Score
1707                                (mail-header-extra header))))))
1708                   (when (string-match " \\([^:]+\\)[:/]\\([0-9]+\\)" xref)
1709                     (push
1710                      (vector
1711                       (gnus-group-prefixed-name (match-string 1 xref) srv)
1712                       (string-to-number (match-string 2 xref)) xscore)
1713                      artlist)))))
1714             (forward-line 1)))
1715         (apply 'vector (nreverse (mm-delete-duplicates artlist)))))
1716
1717 ;;; Util Code:
1718
1719 (defun gnus-nnir-group-p (group)
1720   "Say whether GROUP is nnir or not."
1721   (if (gnus-group-prefixed-p group)
1722       (eq 'nnir (car (gnus-find-method-for-group group)))
1723     (and group (string-match "^nnir" group))))
1724
1725 (defun nnir-read-parms (nnir-search-engine)
1726   "Reads additional search parameters according to `nnir-engines'."
1727   (let ((parmspec (caddr (assoc nnir-search-engine nnir-engines))))
1728     (mapcar 'nnir-read-parm parmspec)))
1729
1730 (defun nnir-read-parm (parmspec)
1731   "Reads a single search parameter.
1732 `parmspec' is a cons cell, the car is a symbol, the cdr is a prompt."
1733   (let ((sym (car parmspec))
1734         (prompt (cdr parmspec)))
1735     (if (listp prompt)
1736         (let* ((result (apply 'gnus-completing-read prompt))
1737                (mapping (or (assoc result nnir-imap-search-arguments)
1738                             (cons nil nnir-imap-search-other))))
1739           (cons sym (format (cdr mapping) result)))
1740       (cons sym (read-string prompt)))))
1741
1742 (defun nnir-run-query (specs)
1743   "Invoke appropriate search engine function (see `nnir-engines')."
1744   (apply 'vconcat
1745          (mapcar
1746           (lambda (x)
1747             (let* ((server (car x))
1748                    (search-engine (nnir-server-to-search-engine server))
1749                    (search-func (cadr (assoc search-engine nnir-engines))))
1750               (and search-func
1751                    (funcall search-func (cdr (assq 'nnir-query-spec specs))
1752                             server (cadr x)))))
1753           (cdr (assq 'nnir-group-spec specs)))))
1754
1755 (defun nnir-server-to-search-engine (server)
1756   (or (nnir-read-server-parm 'nnir-search-engine server t)
1757       (cdr (assoc (car (gnus-server-to-method server))
1758                   nnir-method-default-engines))))
1759
1760 (defun nnir-read-server-parm (key server &optional not-global)
1761   "Returns the parameter value corresponding to `key' for
1762 `server'. If no server-specific value is found consult the global
1763 environment unless `not-global' is non-nil."
1764   (let ((method (gnus-server-to-method server)))
1765     (cond ((and method (assq key (cddr method)))
1766            (nth 1 (assq key (cddr method))))
1767           ((and (not not-global) (boundp key)) (symbol-value key))
1768           (t nil))))
1769
1770 (defun nnir-possibly-change-group (group &optional server)
1771   (or (not server) (nnir-server-opened server) (nnir-open-server server))
1772   (when (gnus-nnir-group-p group)
1773     (setq nnir-artlist (gnus-group-get-parameter
1774                         (gnus-group-prefixed-name
1775                          (gnus-group-short-name group) '(nnir "nnir"))
1776                         'nnir-artlist t))))
1777
1778 (defun nnir-server-opened (&optional server)
1779   (let ((backend (car (gnus-server-to-method server))))
1780     (nnoo-current-server-p (or backend 'nnir) server)))
1781
1782 (defun nnir-search-thread (header)
1783   "Make an nnir group based on the thread containing the article
1784 header. The current server will be searched. If the registry is
1785 installed, the server that the registry reports the current
1786 article came from is also searched."
1787   (let* ((query
1788           (list (cons 'query (nnimap-make-thread-query header))
1789                 (cons 'criteria "")))
1790          (server
1791           (list (list (gnus-method-to-server
1792            (gnus-find-method-for-group gnus-newsgroup-name)))))
1793          (registry-group (and
1794                           (gnus-bound-and-true-p 'gnus-registry-enabled)
1795                           (car (gnus-registry-get-id-key
1796                                 (mail-header-id header) 'group))))
1797          (registry-server
1798           (and registry-group
1799                (gnus-method-to-server
1800                 (gnus-find-method-for-group registry-group)))))
1801     (when registry-server (add-to-list 'server (list registry-server)))
1802     (gnus-group-make-nnir-group nil (list
1803                                      (cons 'nnir-query-spec query)
1804                                      (cons 'nnir-group-spec server)))
1805     (gnus-summary-goto-subject (gnus-id-to-article (mail-header-id header)))))
1806
1807 (defun nnir-get-active (srv)
1808   (let ((method (gnus-server-to-method srv))
1809         groups)
1810     (gnus-request-list method)
1811     (with-current-buffer nntp-server-buffer
1812       (let ((cur (current-buffer))
1813             name)
1814         (goto-char (point-min))
1815         (unless (or (null nnir-ignored-newsgroups)
1816                     (string= nnir-ignored-newsgroups ""))
1817           (delete-matching-lines nnir-ignored-newsgroups))
1818         (if (eq (car method) 'nntp)
1819             (while (not (eobp))
1820               (ignore-errors
1821                 (push (mm-string-as-unibyte
1822                        (gnus-group-full-name
1823                         (buffer-substring
1824                          (point)
1825                          (progn
1826                            (skip-chars-forward "^ \t")
1827                            (point))) method))
1828                       groups))
1829               (forward-line))
1830           (while (not (eobp))
1831             (ignore-errors
1832               (push (mm-string-as-unibyte
1833                      (if (eq (char-after) ?\")
1834                          (gnus-group-full-name (read cur) method)
1835                        (let ((p (point)) (name ""))
1836                          (skip-chars-forward "^ \t\\\\")
1837                          (setq name (buffer-substring p (point)))
1838                          (while (eq (char-after) ?\\)
1839                            (setq p (1+ (point)))
1840                            (forward-char 2)
1841                            (skip-chars-forward "^ \t\\\\")
1842                            (setq name (concat name (buffer-substring
1843                                                     p (point)))))
1844                          (gnus-group-full-name name method))))
1845                     groups))
1846             (forward-line)))))
1847     groups))
1848
1849 (defun nnir-registry-action (action data-header from &optional to method)
1850   "Call `gnus-registry-action' with the original article group."
1851   (gnus-registry-action
1852    action
1853    data-header
1854    (nnir-article-group (mail-header-number data-header))
1855    to
1856    method))
1857
1858 (defun nnir-mode ()
1859   (when (eq (car (gnus-find-method-for-group gnus-newsgroup-name)) 'nnir)
1860     (setq gnus-summary-line-format
1861           (or nnir-summary-line-format gnus-summary-line-format))
1862     (when (gnus-bound-and-true-p 'gnus-registry-enabled)
1863       (remove-hook 'gnus-summary-article-delete-hook 'gnus-registry-action t)
1864       (remove-hook 'gnus-summary-article-move-hook 'gnus-registry-action t)
1865       (remove-hook 'gnus-summary-article-expire-hook 'gnus-registry-action t)
1866       (add-hook 'gnus-summary-article-delete-hook 'nnir-registry-action t t)
1867       (add-hook 'gnus-summary-article-move-hook 'nnir-registry-action t t)
1868       (add-hook 'gnus-summary-article-expire-hook 'nnir-registry-action t t))))
1869
1870
1871 (defun gnus-summary-create-nnir-group ()
1872   (interactive)
1873   (let ((name (gnus-read-group "Group name: "))
1874         (method "nnir")
1875         (pgroup (if (gnus-group-prefixed-p gnus-newsgroup-name)
1876                     gnus-newsgroup-name
1877                   (gnus-group-prefixed-name
1878                    gnus-newsgroup-name '(nnir "nnir")))))
1879     (with-current-buffer gnus-group-buffer
1880       (gnus-group-make-group
1881        name method nil
1882        (gnus-group-find-parameter pgroup)))))
1883
1884
1885 (deffoo nnir-request-create-group (group &optional server args)
1886   (message "Creating nnir group %s" group)
1887   (let* ((group (gnus-group-prefixed-name  group '(nnir "nnir")))
1888          (specs (assoc 'nnir-specs args))
1889          (query-spec
1890           (or (cdr (assoc 'nnir-query-spec specs))
1891               (list (cons 'query
1892                           (read-string "Query: " nil 'nnir-search-history)))))
1893          (group-spec
1894           (or (cdr (assoc 'nnir-group-spec specs))
1895               (list (list (read-string "Server: " nil nil)))))
1896          (nnir-specs (list (cons 'nnir-query-spec query-spec)
1897                            (cons 'nnir-group-spec group-spec))))
1898     (gnus-group-set-parameter group 'nnir-specs nnir-specs)
1899     (gnus-group-set-parameter
1900      group 'nnir-artlist
1901      (or (cdr (assoc 'nnir-artlist args))
1902          (nnir-run-query nnir-specs)))
1903     (nnir-request-update-info group (gnus-get-info group)))
1904   t)
1905
1906 (deffoo nnir-request-delete-group (group &optional force server)
1907   t)
1908
1909 (deffoo nnir-request-list (&optional server)
1910   t)
1911
1912 (deffoo nnir-request-scan (group method)
1913   t)
1914
1915 (deffoo nnir-request-close ()
1916   t)
1917
1918 (nnoo-define-skeleton nnir)
1919
1920 ;; The end.
1921 (provide 'nnir)
1922
1923 ;;; nnir.el ends here