cgit.sxemacs.org Git - gnus/blob - lisp/nnir.el

   1 ;;; nnir.el --- search mail with various search engines -*- coding: utf-8 -*-
   2
   3 ;; Copyright (C) 1998-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Kai Großjohann <grossjohann@ls6.cs.uni-dortmund.de>
   6 ;; Swish-e and Swish++ backends by:
   7 ;;   Christoph Conrad <christoph.conrad@gmx.de>.
   8 ;; IMAP backend by: Simon Josefsson <jas@pdc.kth.se>.
   9 ;; IMAP search by: Torsten Hilbrich <torsten.hilbrich <at> gmx.net>
  10 ;; IMAP search improved by Daniel Pittman  <daniel@rimspace.net>.
  11 ;; nnmaildir support for Swish++ and Namazu backends by:
  12 ;;   Justus Piater <Justus <at> Piater.name>
  13 ;; Keywords: news mail searching ir
  14
  15 ;; This file is part of GNU Emacs.
  16
  17 ;; GNU Emacs is free software: you can redistribute it and/or modify
  18 ;; it under the terms of the GNU General Public License as published by
  19 ;; the Free Software Foundation, either version 3 of the License, or
  20 ;; (at your option) any later version.
  21
  22 ;; GNU Emacs is distributed in the hope that it will be useful,
  23 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 ;; GNU General Public License for more details.
  26
  27 ;; You should have received a copy of the GNU General Public License
  28 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  29
  30 ;;; Commentary:
  31
  32 ;; What does it do?  Well, it allows you to search your mail using
  33 ;; some search engine (imap, namazu, swish-e, gmane and others -- see
  34 ;; later) by typing `G G' in the Group buffer.  You will then get a
  35 ;; buffer which shows all articles matching the query, sorted by
  36 ;; Retrieval Status Value (score).
  37
  38 ;; When looking at the retrieval result (in the Summary buffer) you
  39 ;; can type `A W' (aka M-x gnus-warp-to-article RET) on an article.  You
  40 ;; will be warped into the group this article came from. Typing `A T'
  41 ;; (aka M-x gnus-summary-refer-thread RET) will warp to the group and
  42 ;; also show the thread this article is part of.
  43
  44 ;; The Lisp setup may involve setting a few variables and setting up the
  45 ;; search engine. You can define the variables in the server definition
  46 ;; like this :
  47 ;;   (setq gnus-secondary-select-methods '(
  48 ;;       (nnimap "" (nnimap-address "localhost")
  49 ;;                  (nnir-search-engine namazu)
  50 ;;       )))
  51 ;; The main variable to set is `nnir-search-engine'.  Choose one of
  52 ;; the engines listed in `nnir-engines'.  (Actually `nnir-engines' is
  53 ;; an alist, type `C-h v nnir-engines RET' for more information; this
  54 ;; includes examples for setting `nnir-search-engine', too.)
  55
  56 ;; If you use one of the local indices (namazu, find-grep, swish) you
  57 ;; must also set up a search engine backend.
  58
  59 ;; 1. Namazu
  60 ;;
  61 ;; The Namazu backend requires you to have one directory containing all
  62 ;; index files, this is controlled by the `nnir-namazu-index-directory'
  63 ;; variable.  To function the `nnir-namazu-remove-prefix' variable must
  64 ;; also be correct, see the documentation for `nnir-namazu-remove-prefix'
  65 ;; above.
  66 ;;
  67 ;; It is particularly important not to pass any any switches to namazu
  68 ;; that will change the output format.  Good switches to use include
  69 ;; `--sort', `--ascending', `--early' and `--late'.  Refer to the Namazu
  70 ;; documentation for further information on valid switches.
  71 ;;
  72 ;; To index my mail with the `mknmz' program I use the following
  73 ;; configuration file:
  74 ;;
  75 ;; ,----
  76 ;; | package conf;  # Don't remove this line!
  77 ;; |
  78 ;; | # Paths which will not be indexed. Don't use `^' or `$' anchors.
  79 ;; | $EXCLUDE_PATH = "spam|sent";
  80 ;; |
  81 ;; | # Header fields which should be searchable. case-insensitive
  82 ;; | $REMAIN_HEADER = "from|date|message-id|subject";
  83 ;; |
  84 ;; | # Searchable fields. case-insensitive
  85 ;; | $SEARCH_FIELD = "from|date|message-id|subject";
  86 ;; |
  87 ;; | # The max length of a word.
  88 ;; | $WORD_LENG_MAX = 128;
  89 ;; |
  90 ;; | # The max length of a field.
  91 ;; | $MAX_FIELD_LENGTH = 256;
  92 ;; `----
  93 ;;
  94 ;; My mail is stored in the directories ~/Mail/mail/, ~/Mail/lists/ and
  95 ;; ~/Mail/archive/, so to index them I go to the directory set in
  96 ;; `nnir-namazu-index-directory' and issue the following command.
  97 ;;
  98 ;;      mknmz --mailnews ~/Mail/archive/ ~/Mail/mail/ ~/Mail/lists/
  99 ;;
 100 ;; For maximum searching efficiency I have a cron job set to run this
 101 ;; command every four hours.
 102
 103 ;; 2. find-grep
 104 ;;
 105 ;; The find-grep engine simply runs find(1) to locate eligible
 106 ;; articles and searches them with grep(1).  This, of course, is much
 107 ;; slower than using a proper search engine but OTOH doesn't require
 108 ;; maintenance of an index and is still faster than using any built-in
 109 ;; means for searching.  The method specification of the server to
 110 ;; search must include a directory for this engine to work (E.g.,
 111 ;; `nnml-directory').  The tools must be POSIX compliant.  GNU Find
 112 ;; prior to version 4.2.12 (4.2.26 on Linux due to incorrect ARG_MAX
 113 ;; handling) does not work.
 114 ;; ,----
 115 ;; |    ;; find-grep configuration for searching the Gnus Cache
 116 ;; |
 117 ;; |    (nnml "cache"
 118 ;; |          (nnml-get-new-mail nil)
 119 ;; |          (nnir-search-engine find-grep)
 120 ;; |          (nnml-directory "~/News/cache/")
 121 ;; |          (nnml-active-file "~/News/cache/active"))
 122 ;; `----
 123
 124 ;; Developer information:
 125
 126 ;; I have tried to make the code expandable.  Basically, it is divided
 127 ;; into two layers.  The upper layer is somewhat like the `nnvirtual'
 128 ;; backend: given a specification of what articles to show from
 129 ;; another backend, it creates a group containing exactly those
 130 ;; articles.  The lower layer issues a query to a search engine and
 131 ;; produces such a specification of what articles to show from the
 132 ;; other backend.
 133
 134 ;; The interface between the two layers consists of the single
 135 ;; function `nnir-run-query', which dispatches the search to the
 136 ;; proper search function.  The argument of `nnir-run-query' is an
 137 ;; alist with two keys: 'nnir-query-spec and 'nnir-group-spec. The
 138 ;; value for 'nnir-query-spec is an alist. The only required key/value
 139 ;; pair is (query . "query") specifying the search string to pass to
 140 ;; the query engine. Individual engines may have other elements. The
 141 ;; value of 'nnir-group-spec is a list with the specification of the
 142 ;; groups/servers to search.  The format of the 'nnir-group-spec is
 143 ;; (("server1" ("group11" "group12")) ("server2" ("group21"
 144 ;; "group22"))). If any of the group lists is absent then all groups
 145 ;; on that server are searched.
 146
 147 ;; The output of `nnir-run-query' is supposed to be a vector, each
 148 ;; element of which should in turn be a three-element vector.  The
 149 ;; first element should be full group name of the article, the second
 150 ;; element should be the article number, and the third element should
 151 ;; be the Retrieval Status Value (RSV) as returned from the search
 152 ;; engine.  An RSV is the score assigned to the document by the search
 153 ;; engine.  For Boolean search engines, the RSV is always 1000 (or 1
 154 ;; or 100, or whatever you like).
 155
 156 ;; The sorting order of the articles in the summary buffer created by
 157 ;; nnir is based on the order of the articles in the above mentioned
 158 ;; vector, so that's where you can do the sorting you'd like.  Maybe
 159 ;; it would be nice to have a way of displaying the search result
 160 ;; sorted differently?
 161
 162 ;; So what do you need to do when you want to add another search
 163 ;; engine?  You write a function that executes the query.  Temporary
 164 ;; data from the search engine can be put in `nnir-tmp-buffer'.  This
 165 ;; function should return the list of articles as a vector, as
 166 ;; described above.  Then, you need to register this backend in
 167 ;; `nnir-engines'.  Then, users can choose the backend by setting
 168 ;; `nnir-search-engine' as a server variable.
 169
 170 ;;; Code:
 171
 172 ;;; Setup:
 173
 174 (require 'nnoo)
 175 (require 'gnus-group)
 176 (require 'message)
 177 (require 'gnus-util)
 178 (eval-when-compile
 179   (require 'cl))
 180
 181 ;;; Internal Variables:
 182
 183 (defvar nnir-memo-query nil
 184   "Internal: stores current query.")
 185
 186 (defvar nnir-memo-server nil
 187   "Internal: stores current server.")
 188
 189 (defvar nnir-artlist nil
 190   "Internal: stores search result.")
 191
 192 (defvar nnir-search-history ()
 193   "Internal: the history for querying search options in nnir")
 194
 195 (defconst nnir-tmp-buffer " *nnir*"
 196   "Internal: temporary buffer.")
 197
 198
 199 ;; Imap variables
 200
 201 (defvar nnir-imap-search-arguments
 202   '(("whole message" . "TEXT")
 203     ("subject" . "SUBJECT")
 204     ("to" . "TO")
 205     ("from" . "FROM")
 206     ("body" . "BODY")
 207     ("imap" . ""))
 208   "Mapping from user readable keys to IMAP search items for use in nnir")
 209
 210 (defvar nnir-imap-search-other "HEADER %S"
 211   "The IMAP search item to use for anything other than
 212   `nnir-imap-search-arguments'. By default this is the name of an
 213   email header field")
 214
 215 (defvar nnir-imap-search-argument-history ()
 216   "The history for querying search options in nnir")
 217
 218 ;;; Helper macros
 219
 220 ;; Data type article list.
 221
 222 (defmacro nnir-artlist-length (artlist)
 223   "Returns number of articles in artlist."
 224   `(length ,artlist))
 225
 226 (defmacro nnir-artlist-article (artlist n)
 227   "Returns from ARTLIST the Nth artitem (counting starting at 1)."
 228   `(when (> ,n 0)
 229      (elt ,artlist (1- ,n))))
 230
 231 (defmacro nnir-artitem-group (artitem)
 232   "Returns the group from the ARTITEM."
 233   `(elt ,artitem 0))
 234
 235 (defmacro nnir-artitem-number (artitem)
 236   "Returns the number from the ARTITEM."
 237   `(elt ,artitem 1))
 238
 239 (defmacro nnir-artitem-rsv (artitem)
 240   "Returns the Retrieval Status Value (RSV, score) from the ARTITEM."
 241   `(elt ,artitem 2))
 242
 243 (defmacro nnir-article-group (article)
 244   "Returns the group for ARTICLE"
 245   `(nnir-artitem-group (nnir-artlist-article nnir-artlist ,article)))
 246
 247 (defmacro nnir-article-number (article)
 248   "Returns the number for ARTICLE"
 249   `(nnir-artitem-number (nnir-artlist-article nnir-artlist ,article)))
 250
 251 (defmacro nnir-article-rsv (article)
 252   "Returns the rsv for ARTICLE"
 253   `(nnir-artitem-rsv (nnir-artlist-article nnir-artlist ,article)))
 254
 255 (defsubst nnir-article-ids (article)
 256   "Returns the pair `(nnir id . real id)' of ARTICLE"
 257   (cons article (nnir-article-number article)))
 258
 259 (defmacro nnir-categorize (sequence keyfunc &optional valuefunc)
 260   "Sorts a sequence into categories and returns a list of the form
 261 `((key1 (element11 element12)) (key2 (element21 element22))'.
 262 The category key for a member of the sequence is obtained
 263 as `(keyfunc member)' and the corresponding element is just
 264 `member'. If `valuefunc' is non-nil, the element of the list
 265 is `(valuefunc member)'."
 266   `(unless (null ,sequence)
 267      (let (value)
 268        (mapc
 269         (lambda (member)
 270           (let ((y (,keyfunc member))
 271                 (x ,(if valuefunc
 272                         `(,valuefunc member)
 273                       'member)))
 274             (if (assoc y value)
 275                 (push x (cadr (assoc y value)))
 276               (push (list y (list x)) value))))
 277         ,sequence)
 278        value)))
 279
 280 ;;; Finish setup:
 281
 282 (require 'gnus-sum)
 283
 284 (eval-when-compile
 285   (autoload 'nnimap-buffer "nnimap")
 286   (autoload 'nnimap-command "nnimap")
 287   (autoload 'nnimap-change-group "nnimap")
 288   (autoload 'nnimap-make-thread-query "nnimap")
 289   (autoload 'gnus-registry-action "gnus-registry")
 290   (autoload 'gnus-registry-get-id-key "gnus-registry")
 291   (autoload 'gnus-group-topic-name "gnus-topic"))
 292
 293
 294 (nnoo-declare nnir)
 295 (nnoo-define-basics nnir)
 296
 297 (gnus-declare-backend "nnir" 'mail 'virtual)
 298
 299
 300 ;;; User Customizable Variables:
 301
 302 (defgroup nnir nil
 303   "Search groups in Gnus with assorted search engines."
 304   :group 'gnus)
 305
 306 (defcustom nnir-ignored-newsgroups ""
 307   "*A regexp to match newsgroups in the active file that should
 308   be skipped when searching."
 309   :version "24.1"
 310   :type '(regexp)
 311   :group 'nnir)
 312
 313 (defcustom nnir-summary-line-format nil
 314   "*The format specification of the lines in an nnir summary buffer.
 315
 316 All the items from `gnus-summary-line-format' are available, along
 317 with three items unique to nnir summary buffers:
 318
 319 %Z    Search retrieval score value (integer)
 320 %G    Article original full group name (string)
 321 %g    Article original short group name (string)
 322
 323 If nil this will use `gnus-summary-line-format'."
 324   :version "24.1"
 325   :type '(choice (const :tag "gnus-summary-line-format" nil) string)
 326   :group 'nnir)
 327
 328 (defcustom nnir-retrieve-headers-override-function nil
 329   "*If non-nil, a function that accepts an article list and group
 330 and populates the `nntp-server-buffer' with the retrieved
 331 headers. Must return either 'nov or 'headers indicating the
 332 retrieved header format.
 333
 334 If this variable is nil, or if the provided function returns nil for a search
 335 result, `gnus-retrieve-headers' will be called instead."
 336   :version "24.1"
 337   :type '(choice (const :tag "gnus-retrieve-headers" nil) function)
 338   :group 'nnir)
 339
 340 (defcustom nnir-imap-default-search-key "whole message"
 341   "*The default IMAP search key for an nnir search. Must be one of
 342   the keys in `nnir-imap-search-arguments'. To use raw imap queries
 343   by default set this to \"imap\"."
 344   :version "24.1"
 345   :type `(choice ,@(mapcar (lambda (elem) (list 'const (car elem)))
 346                            nnir-imap-search-arguments))
 347   :group 'nnir)
 348
 349 (defcustom nnir-swish++-configuration-file
 350   (expand-file-name "~/Mail/swish++.conf")
 351   "*Configuration file for swish++."
 352   :type '(file)
 353   :group 'nnir)
 354
 355 (defcustom nnir-swish++-program "search"
 356   "*Name of swish++ search executable."
 357   :type '(string)
 358   :group 'nnir)
 359
 360 (defcustom nnir-swish++-additional-switches '()
 361   "*A list of strings, to be given as additional arguments to swish++.
 362
 363 Note that this should be a list.  Ie, do NOT use the following:
 364     (setq nnir-swish++-additional-switches \"-i -w\") ; wrong
 365 Instead, use this:
 366     (setq nnir-swish++-additional-switches '(\"-i\" \"-w\"))"
 367   :type '(repeat (string))
 368   :group 'nnir)
 369
 370 (defcustom nnir-swish++-remove-prefix (concat (getenv "HOME") "/Mail/")
 371   "*The prefix to remove from each file name returned by swish++
 372 in order to get a group name (albeit with / instead of .).  This is a
 373 regular expression.
 374
 375 This variable is very similar to `nnir-namazu-remove-prefix', except
 376 that it is for swish++, not Namazu."
 377   :type '(regexp)
 378   :group 'nnir)
 379
 380 ;; Swish-E.
 381 ;; URL: http://swish-e.org/
 382 ;; Variables `nnir-swish-e-index-file', `nnir-swish-e-program' and
 383 ;; `nnir-swish-e-additional-switches'
 384
 385 (make-obsolete-variable 'nnir-swish-e-index-file
 386                         'nnir-swish-e-index-files "Emacs 23.1")
 387 (defcustom nnir-swish-e-index-file
 388   (expand-file-name "~/Mail/index.swish-e")
 389   "*Index file for swish-e.
 390 This could be a server parameter.
 391 It is never consulted once `nnir-swish-e-index-files', which should be
 392 used instead, has been customized."
 393   :type '(file)
 394   :group 'nnir)
 395
 396 (defcustom nnir-swish-e-index-files
 397   (list nnir-swish-e-index-file)
 398   "*List of index files for swish-e.
 399 This could be a server parameter."
 400   :type '(repeat (file))
 401   :group 'nnir)
 402
 403 (defcustom nnir-swish-e-program "swish-e"
 404   "*Name of swish-e search executable.
 405 This cannot be a server parameter."
 406   :type '(string)
 407   :group 'nnir)
 408
 409 (defcustom nnir-swish-e-additional-switches '()
 410   "*A list of strings, to be given as additional arguments to swish-e.
 411
 412 Note that this should be a list.  Ie, do NOT use the following:
 413     (setq nnir-swish-e-additional-switches \"-i -w\") ; wrong
 414 Instead, use this:
 415     (setq nnir-swish-e-additional-switches '(\"-i\" \"-w\"))
 416
 417 This could be a server parameter."
 418   :type '(repeat (string))
 419   :group 'nnir)
 420
 421 (defcustom nnir-swish-e-remove-prefix (concat (getenv "HOME") "/Mail/")
 422   "*The prefix to remove from each file name returned by swish-e
 423 in order to get a group name (albeit with / instead of .).  This is a
 424 regular expression.
 425
 426 This variable is very similar to `nnir-namazu-remove-prefix', except
 427 that it is for swish-e, not Namazu.
 428
 429 This could be a server parameter."
 430   :type '(regexp)
 431   :group 'nnir)
 432
 433 ;; HyREX engine, see <URL:http://ls6-www.cs.uni-dortmund.de/>
 434
 435 (defcustom nnir-hyrex-program "nnir-search"
 436   "*Name of the nnir-search executable."
 437   :type '(string)
 438   :group 'nnir)
 439
 440 (defcustom nnir-hyrex-additional-switches '()
 441   "*A list of strings, to be given as additional arguments for nnir-search.
 442 Note that this should be a list. Ie, do NOT use the following:
 443     (setq nnir-hyrex-additional-switches \"-ddl ddl.xml -c nnir\") ; wrong !
 444 Instead, use this:
 445     (setq nnir-hyrex-additional-switches '(\"-ddl\" \"ddl.xml\" \"-c\" \"nnir\"))"
 446   :type '(repeat (string))
 447   :group 'nnir)
 448
 449 (defcustom nnir-hyrex-index-directory (getenv "HOME")
 450   "*Index directory for HyREX."
 451   :type '(directory)
 452   :group 'nnir)
 453
 454 (defcustom nnir-hyrex-remove-prefix (concat (getenv "HOME") "/Mail/")
 455   "*The prefix to remove from each file name returned by HyREX
 456 in order to get a group name (albeit with / instead of .).
 457
 458 For example, suppose that HyREX returns file names such as
 459 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 460 setting:  (setq nnir-hyrex-remove-prefix \"/home/john/Mail/\")
 461 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 462 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 463 arrive at the correct group name, \"mail.misc\"."
 464   :type '(directory)
 465   :group 'nnir)
 466
 467 ;; Namazu engine, see <URL:http://www.namazu.org/>
 468
 469 (defcustom nnir-namazu-program "namazu"
 470   "*Name of Namazu search executable."
 471   :type '(string)
 472   :group 'nnir)
 473
 474 (defcustom nnir-namazu-index-directory (expand-file-name "~/Mail/namazu/")
 475   "*Index directory for Namazu."
 476   :type '(directory)
 477   :group 'nnir)
 478
 479 (defcustom nnir-namazu-additional-switches '()
 480   "*A list of strings, to be given as additional arguments to namazu.
 481 The switches `-q', `-a', and `-s' are always used, very few other switches
 482 make any sense in this context.
 483
 484 Note that this should be a list.  Ie, do NOT use the following:
 485     (setq nnir-namazu-additional-switches \"-i -w\") ; wrong
 486 Instead, use this:
 487     (setq nnir-namazu-additional-switches '(\"-i\" \"-w\"))"
 488   :type '(repeat (string))
 489   :group 'nnir)
 490
 491 (defcustom nnir-namazu-remove-prefix (concat (getenv "HOME") "/Mail/")
 492   "*The prefix to remove from each file name returned by Namazu
 493 in order to get a group name (albeit with / instead of .).
 494
 495 For example, suppose that Namazu returns file names such as
 496 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 497 setting:  (setq nnir-namazu-remove-prefix \"/home/john/Mail/\")
 498 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 499 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 500 arrive at the correct group name, \"mail.misc\"."
 501   :type '(directory)
 502   :group 'nnir)
 503
 504 (defcustom nnir-notmuch-program "notmuch"
 505   "*Name of notmuch search executable."
 506   :version "24.1"
 507   :type '(string)
 508   :group 'nnir)
 509
 510 (defcustom nnir-notmuch-additional-switches '()
 511   "*A list of strings, to be given as additional arguments to notmuch.
 512
 513 Note that this should be a list.  Ie, do NOT use the following:
 514     (setq nnir-notmuch-additional-switches \"-i -w\") ; wrong
 515 Instead, use this:
 516     (setq nnir-notmuch-additional-switches '(\"-i\" \"-w\"))"
 517   :version "24.1"
 518   :type '(repeat (string))
 519   :group 'nnir)
 520
 521 (defcustom nnir-notmuch-remove-prefix (concat (getenv "HOME") "/Mail/")
 522   "*The prefix to remove from each file name returned by notmuch
 523 in order to get a group name (albeit with / instead of .).  This is a
 524 regular expression.
 525
 526 This variable is very similar to `nnir-namazu-remove-prefix', except
 527 that it is for notmuch, not Namazu."
 528   :version "24.1"
 529   :type '(regexp)
 530   :group 'nnir)
 531
 532 ;;; Developer Extension Variable:
 533
 534 (defvar nnir-engines
 535   `((imap    nnir-run-imap
 536              ((criteria
 537                "Imap Search in"                   ; Prompt
 538                ,(mapcar 'car nnir-imap-search-arguments) ; alist for completing
 539                nil                                ; allow any user input
 540                nil                                ; initial value
 541                nnir-imap-search-argument-history  ; the history to use
 542                ,nnir-imap-default-search-key      ; default
 543                )))
 544     (gmane   nnir-run-gmane
 545              ((gmane-author . "Gmane Author: ")))
 546     (swish++ nnir-run-swish++
 547              ((swish++-group . "Swish++ Group spec (regexp): ")))
 548     (swish-e nnir-run-swish-e
 549              ((swish-e-group . "Swish-e Group spec (regexp): ")))
 550     (namazu  nnir-run-namazu
 551              ())
 552     (notmuch nnir-run-notmuch
 553              ())
 554     (hyrex   nnir-run-hyrex
 555              ((hyrex-group . "Hyrex Group spec (regexp): ")))
 556     (find-grep nnir-run-find-grep
 557                ((grep-options . "Grep options: "))))
 558   "Alist of supported search engines.
 559 Each element in the alist is a three-element list (ENGINE FUNCTION ARGS).
 560 ENGINE is a symbol designating the searching engine.  FUNCTION is also
 561 a symbol, giving the function that does the search.  The third element
 562 ARGS is a list of cons pairs (PARAM . PROMPT).  When issuing a query,
 563 the FUNCTION will issue a query for each of the PARAMs, using PROMPT.
 564
 565 The value of `nnir-search-engine' must be one of the ENGINE symbols.
 566 For example, for searching a server using namazu include
 567     (nnir-search-engine namazu)
 568 in the server definition.  Note that you have to set additional
 569 variables for most backends.  For example, the `namazu' backend
 570 needs the variables `nnir-namazu-program',
 571 `nnir-namazu-index-directory' and `nnir-namazu-remove-prefix'.
 572
 573 Add an entry here when adding a new search engine.")
 574
 575 (defcustom nnir-method-default-engines  '((nnimap . imap) (nntp . gmane))
 576   "*Alist of default search engines keyed by server method."
 577   :version "24.1"
 578   :group 'nnir
 579   :type `(repeat (cons (choice (const nnimap) (const nntp) (const nnspool)
 580                                (const nneething) (const nndir) (const nnmbox)
 581                                (const nnml) (const nnmh) (const nndraft)
 582                                (const nnfolder) (const nnmaildir))
 583                        (choice
 584                         ,@(mapcar (lambda (elem) (list 'const (car elem)))
 585                                   nnir-engines)))))
 586
 587 ;; Gnus glue.
 588
 589 (defun gnus-group-make-nnir-group (nnir-extra-parms &optional specs)
 590   "Create an nnir group.  Prompt for a search query and determine
 591 the groups to search as follows: if called from the *Server*
 592 buffer search all groups belonging to the server on the current
 593 line; if called from the *Group* buffer search any marked groups,
 594 or the group on the current line, or all the groups under the
 595 current topic. Calling with a prefix-arg prompts for additional
 596 search-engine specific constraints. A non-nil `specs' arg must be
 597 an alist with `nnir-query-spec' and `nnir-group-spec' keys, and
 598 skips all prompting."
 599   (interactive "P")
 600   (let* ((group-spec
 601           (or (cdr (assq 'nnir-group-spec specs))
 602             (if (gnus-server-server-name)
 603                 (list (list (gnus-server-server-name)))
 604               (nnir-categorize
 605                (or gnus-group-marked
 606                    (if (gnus-group-group-name)
 607                        (list (gnus-group-group-name))
 608                      (cdr (assoc (gnus-group-topic-name) gnus-topic-alist))))
 609                gnus-group-server))))
 610          (query-spec
 611           (or (cdr (assq 'nnir-query-spec specs))
 612             (apply
 613              'append
 614              (list (cons 'query
 615                          (read-string "Query: " nil 'nnir-search-history)))
 616              (when nnir-extra-parms
 617                (mapcar
 618                 (lambda (x)
 619                   (nnir-read-parms (nnir-server-to-search-engine (car x))))
 620                 group-spec))))))
 621     (gnus-group-read-ephemeral-group
 622      (concat "nnir-" (message-unique-id))
 623      (list 'nnir "nnir")
 624      nil
 625 ;     (cons (current-buffer) gnus-current-window-configuration)
 626      nil
 627      nil nil
 628      (list
 629       (cons 'nnir-specs (list (cons 'nnir-query-spec query-spec)
 630                               (cons 'nnir-group-spec group-spec)))
 631       (cons 'nnir-artlist nil)))))
 632
 633 (defun gnus-summary-make-nnir-group (nnir-extra-parms)
 634   "Search a group from the summary buffer."
 635   (interactive "P")
 636   (gnus-warp-to-article)
 637   (let ((spec
 638          (list
 639           (cons 'nnir-group-spec
 640                 (list (list
 641                        (gnus-group-server gnus-newsgroup-name)
 642                        (list gnus-newsgroup-name)))))))
 643     (gnus-group-make-nnir-group nnir-extra-parms spec)))
 644
 645
 646 ;; Gnus backend interface functions.
 647
 648 (deffoo nnir-open-server (server &optional definitions)
 649   ;; Just set the server variables appropriately.
 650   (let ((backend (car (gnus-server-to-method server))))
 651     (if backend
 652         (nnoo-change-server backend server definitions)
 653       (add-hook 'gnus-summary-mode-hook 'nnir-mode)
 654       (nnoo-change-server 'nnir server definitions))))
 655
 656 (deffoo nnir-request-group (group &optional server dont-check info)
 657   (nnir-possibly-change-group group server)
 658   (let ((pgroup (gnus-group-guess-full-name-from-command-method group))
 659         length)
 660     ;; Check for cached search result or run the query and cache the
 661     ;; result.
 662     (unless (and nnir-artlist dont-check)
 663       (gnus-group-set-parameter
 664        pgroup 'nnir-artlist
 665        (setq nnir-artlist
 666              (nnir-run-query
 667               (gnus-group-get-parameter pgroup 'nnir-specs t))))
 668       (nnir-request-update-info pgroup (gnus-get-info pgroup)))
 669     (with-current-buffer nntp-server-buffer
 670       (if (zerop (setq length (nnir-artlist-length nnir-artlist)))
 671           (progn
 672             (nnir-close-group group)
 673             (nnheader-report 'nnir "Search produced empty results."))
 674         (nnheader-insert "211 %d %d %d %s\n"
 675                          length    ; total #
 676                          1         ; first #
 677                          length    ; last #
 678                          group)))) ; group name
 679   nnir-artlist)
 680
 681 (deffoo nnir-retrieve-headers (articles &optional group server fetch-old)
 682   (with-current-buffer nntp-server-buffer
 683     (let ((gnus-inhibit-demon t)
 684           (articles-by-group (nnir-categorize
 685                               articles nnir-article-group nnir-article-ids))
 686           headers)
 687       (while (not (null articles-by-group))
 688         (let* ((group-articles (pop articles-by-group))
 689                (artgroup (car group-articles))
 690                (articleids (cadr group-articles))
 691                (artlist (sort (mapcar 'cdr articleids) '<))
 692                (server (gnus-group-server artgroup))
 693                (gnus-override-method (gnus-server-to-method server))
 694                parsefunc)
 695           ;; (nnir-possibly-change-group nil server)
 696           (erase-buffer)
 697           (case (setq gnus-headers-retrieved-by
 698                       (or
 699                        (and
 700                         nnir-retrieve-headers-override-function
 701                         (funcall nnir-retrieve-headers-override-function
 702                                  artlist artgroup))
 703                        (gnus-retrieve-headers artlist artgroup nil)))
 704             (nov
 705              (setq parsefunc 'nnheader-parse-nov))
 706             (headers
 707              (setq parsefunc 'nnheader-parse-head))
 708             (t (error "Unknown header type %s while requesting articles \
 709                     of group %s" gnus-headers-retrieved-by artgroup)))
 710           (goto-char (point-min))
 711           (while (not (eobp))
 712             (let* ((novitem (funcall parsefunc))
 713                    (artno (and novitem
 714                                (mail-header-number novitem)))
 715                    (art (car (rassq artno articleids))))
 716               (when art
 717                 (mail-header-set-number novitem art)
 718                 (push novitem headers))
 719               (forward-line 1)))))
 720       (setq headers
 721             (sort headers
 722                   (lambda (x y)
 723                     (< (mail-header-number x) (mail-header-number y)))))
 724       (erase-buffer)
 725       (mapc 'nnheader-insert-nov headers)
 726       'nov)))
 727
 728 (deffoo nnir-request-article (article &optional group server to-buffer)
 729   (nnir-possibly-change-group group server)
 730   (if (and (stringp article)
 731            (not (eq 'nnimap (car (gnus-server-to-method server)))))
 732       (nnheader-report
 733        'nnir
 734        "nnir-request-article only groks message ids for nnimap servers: %s"
 735        server)
 736     (save-excursion
 737       (let ((article article)
 738             query)
 739         (when (stringp article)
 740           (setq gnus-override-method (gnus-server-to-method server))
 741           (setq query
 742                 (list
 743                  (cons 'query (format "HEADER Message-ID %s" article))
 744                  (cons 'criteria "")
 745                  (cons 'shortcut t)))
 746           (unless (and nnir-artlist (equal query nnir-memo-query)
 747                        (equal server nnir-memo-server))
 748             (setq nnir-artlist (nnir-run-imap query server)
 749                   nnir-memo-query query
 750                   nnir-memo-server server))
 751           (setq article 1))
 752         (unless (zerop (nnir-artlist-length nnir-artlist))
 753           (let ((artfullgroup (nnir-article-group article))
 754                 (artno (nnir-article-number article)))
 755             (message "Requesting article %d from group %s"
 756                      artno artfullgroup)
 757             (if to-buffer
 758                 (with-current-buffer to-buffer
 759                   (let ((gnus-article-decode-hook nil))
 760                     (gnus-request-article-this-buffer artno artfullgroup)))
 761               (gnus-request-article artno artfullgroup))
 762             (cons artfullgroup artno)))))))
 763
 764 (deffoo nnir-request-move-article (article group server accept-form
 765                                            &optional last internal-move-group)
 766   (nnir-possibly-change-group group server)
 767   (let* ((artfullgroup (nnir-article-group article))
 768          (artno (nnir-article-number article))
 769          (to-newsgroup (nth 1 accept-form))
 770          (to-method (gnus-find-method-for-group to-newsgroup))
 771          (from-method (gnus-find-method-for-group artfullgroup))
 772          (move-is-internal (gnus-server-equal from-method to-method)))
 773     (unless (gnus-check-backend-function
 774              'request-move-article artfullgroup)
 775       (error "The group %s does not support article moving" artfullgroup))
 776     (gnus-request-move-article
 777      artno
 778      artfullgroup
 779      (nth 1 from-method)
 780      accept-form
 781      last
 782      (and move-is-internal
 783           to-newsgroup          ; Not respooling
 784           (gnus-group-real-name to-newsgroup)))))
 785
 786 (deffoo nnir-request-expire-articles (articles group &optional server force)
 787   (nnir-possibly-change-group group server)
 788   (if force
 789     (let ((articles-by-group (nnir-categorize
 790                               articles nnir-article-group nnir-article-ids))
 791           not-deleted)
 792       (while (not (null articles-by-group))
 793         (let* ((group-articles (pop articles-by-group))
 794                (artgroup (car group-articles))
 795                (articleids (cadr group-articles))
 796                (artlist (sort (mapcar 'cdr articleids) '<)))
 797           (unless (gnus-check-backend-function 'request-expire-articles
 798                                                artgroup)
 799             (error "The group %s does not support article deletion" artgroup))
 800           (unless (gnus-check-server (gnus-find-method-for-group artgroup))
 801             (error "Couldn't open server for group %s" artgroup))
 802           (push (gnus-request-expire-articles
 803                  artlist artgroup force)
 804                 not-deleted)))
 805       (sort (delq nil not-deleted) '<))
 806     articles))
 807
 808 (deffoo nnir-warp-to-article ()
 809   (nnir-possibly-change-group gnus-newsgroup-name)
 810   (let* ((cur (if (> (gnus-summary-article-number) 0)
 811                   (gnus-summary-article-number)
 812                 (error "Can't warp to a pseudo-article")))
 813          (backend-article-group (nnir-article-group cur))
 814          (backend-article-number (nnir-article-number cur))
 815          (quit-config (gnus-ephemeral-group-p gnus-newsgroup-name)))
 816
 817     ;; what should we do here? we could leave all the buffers around
 818     ;; and assume that we have to exit from them one by one. or we can
 819     ;; try to clean up directly
 820
 821     ;;first exit from the nnir summary buffer.
 822 ;    (gnus-summary-exit)
 823     ;; and if the nnir summary buffer in turn came from another
 824     ;; summary buffer we have to clean that summary up too.
 825  ;   (when (not (eq (cdr quit-config) 'group))
 826 ;      (gnus-summary-exit))
 827     (gnus-summary-read-group-1 backend-article-group t t  nil
 828                                nil (list backend-article-number))))
 829
 830 (deffoo nnir-request-update-mark (group article mark)
 831   (let ((artgroup (nnir-article-group article))
 832         (artnumber (nnir-article-number article)))
 833     (gnus-request-update-mark artgroup artnumber mark)))
 834
 835 (deffoo nnir-request-set-mark (group actions &optional server)
 836   (nnir-possibly-change-group group server)
 837   (let (mlist)
 838     (dolist (action actions)
 839       (destructuring-bind (range action marks) action
 840         (let ((articles-by-group (nnir-categorize
 841                                   (gnus-uncompress-range range)
 842                                   nnir-article-group nnir-article-number)))
 843           (dolist (artgroup articles-by-group)
 844             (push (list
 845                    (car artgroup)
 846                    (list (gnus-compress-sequence
 847                           (sort (cadr artgroup) '<)) action marks)) mlist)))))
 848     (dolist (request (nnir-categorize  mlist car cadr))
 849       (gnus-request-set-mark (car request) (cadr request)))))
 850
 851
 852 (deffoo nnir-request-update-info (group info &optional server)
 853   (nnir-possibly-change-group group server)
 854   ;; clear out all existing marks.
 855   (gnus-info-set-marks info nil)
 856   (gnus-info-set-read info nil)
 857   (let ((group (gnus-group-guess-full-name-from-command-method group))
 858         (articles-by-group
 859          (nnir-categorize
 860           (gnus-uncompress-range (cons 1 (nnir-artlist-length nnir-artlist)))
 861           nnir-article-group nnir-article-ids)))
 862     (gnus-set-active group
 863                      (cons 1 (nnir-artlist-length nnir-artlist)))
 864     (while (not (null articles-by-group))
 865       (let* ((group-articles (pop articles-by-group))
 866              (articleids (reverse (cadr group-articles)))
 867              (group-info (gnus-get-info (car group-articles)))
 868              (marks (gnus-info-marks group-info))
 869              (read (gnus-info-read group-info)))
 870         (gnus-info-set-read
 871          info
 872          (gnus-add-to-range
 873           (gnus-info-read info)
 874           (delq nil
 875                   (mapcar
 876                    #'(lambda (art)
 877                      (when (gnus-member-of-range (cdr art) read) (car art)))
 878                    articleids))))
 879         (dolist (mark marks)
 880           (destructuring-bind (type . range) mark
 881             (gnus-add-marked-articles
 882              group type
 883              (delq nil
 884                      (mapcar
 885                       #'(lambda (art)
 886                         (when (gnus-member-of-range (cdr art) range) (car art)))
 887                       articleids)))))))))
 888
 889
 890 (deffoo nnir-close-group (group &optional server)
 891   (nnir-possibly-change-group group server)
 892   (let ((pgroup (gnus-group-guess-full-name-from-command-method group)))
 893     (when (and nnir-artlist (not (gnus-ephemeral-group-p pgroup)))
 894       (gnus-group-set-parameter  pgroup 'nnir-artlist nnir-artlist))
 895     (setq nnir-artlist nil)
 896     (when (gnus-ephemeral-group-p pgroup)
 897       (gnus-kill-ephemeral-group pgroup)
 898       (setq gnus-ephemeral-servers
 899             (delq (assq 'nnir gnus-ephemeral-servers)
 900                   gnus-ephemeral-servers)))))
 901 ;; (gnus-opened-servers-remove
 902 ;;  (car (assoc  '(nnir "nnir-ephemeral" (nnir-address "nnir"))
 903 ;;              gnus-opened-servers))))
 904
 905
 906
 907
 908 (defmacro nnir-add-result (dirnam artno score prefix server artlist)
 909   "Ask `nnir-compose-result' to construct a result vector,
 910 and if it is non-nil, add it to artlist."
 911   `(let ((result (nnir-compose-result ,dirnam ,artno ,score ,prefix ,server)))
 912      (when (not (null result))
 913        (push result ,artlist))))
 914
 915 (autoload 'nnmaildir-base-name-to-article-number "nnmaildir")
 916
 917 ;; Helper function currently used by the Swish++ and Namazu backends;
 918 ;; perhaps useful for other backends as well
 919 (defun nnir-compose-result (dirnam article score prefix server)
 920   "Extract the group from dirnam, and create a result vector
 921 ready to be added to the list of search results."
 922
 923   ;; remove nnir-*-remove-prefix from beginning of dirnam filename
 924   (when (string-match (concat "^" prefix) dirnam)
 925     (setq dirnam (replace-match "" t t dirnam)))
 926
 927   (when (file-readable-p (concat prefix dirnam article))
 928     ;; remove trailing slash and, for nnmaildir, cur/new/tmp
 929     (setq dirnam
 930           (substring dirnam 0
 931                      (if (string-match "\\`nnmaildir:" (gnus-group-server server))
 932                          -5 -1)))
 933
 934     ;; Set group to dirnam without any leading dots or slashes,
 935     ;; and with all subsequent slashes replaced by dots
 936     (let ((group (gnus-replace-in-string
 937                  (gnus-replace-in-string dirnam "^[./\\]" "" t)
 938                  "[/\\]" "." t)))
 939
 940     (vector (gnus-group-full-name group server)
 941             (if (string-match "\\`nnmaildir:" (gnus-group-server server))
 942                 (nnmaildir-base-name-to-article-number
 943                  (substring article 0 (string-match ":" article))
 944                  group nil)
 945               (string-to-number article))
 946             (string-to-number score)))))
 947
 948 ;;; Search Engine Interfaces:
 949
 950 ;; imap interface
 951 (defun nnir-run-imap (query srv &optional groups)
 952   "Run a search against an IMAP back-end server.
 953 This uses a custom query language parser; see `nnir-imap-make-query' for
 954 details on the language and supported extensions."
 955   (save-excursion
 956     (let ((qstring (cdr (assq 'query query)))
 957           (server (cadr (gnus-server-to-method srv)))
 958           (defs (caddr (gnus-server-to-method srv)))
 959           (criteria (or (cdr (assq 'criteria query))
 960                         (cdr (assoc nnir-imap-default-search-key
 961                                     nnir-imap-search-arguments))))
 962           (gnus-inhibit-demon t)
 963           (groups (or groups (nnir-get-active srv))))
 964       (message "Opening server %s" server)
 965       (apply
 966        'vconcat
 967        (catch 'found
 968          (mapcar
 969           #'(lambda (group)
 970             (let (artlist)
 971               (condition-case ()
 972                   (when (nnimap-change-group
 973                          (gnus-group-short-name group) server)
 974                     (with-current-buffer (nnimap-buffer)
 975                       (message "Searching %s..." group)
 976                       (let ((arts 0)
 977                             (result (nnimap-command "UID SEARCH %s"
 978                                                     (if (string= criteria "")
 979                                                         qstring
 980                                                       (nnir-imap-make-query
 981                                                        criteria qstring)))))
 982                         (mapc
 983                          (lambda (artnum)
 984                            (let ((artn (string-to-number artnum)))
 985                              (when (> artn 0)
 986                                (push (vector group artn 100)
 987                                      artlist)
 988                                (when (assq 'shortcut query)
 989                                  (throw 'found (list artlist)))
 990                                (setq arts (1+ arts)))))
 991                          (and (car result)
 992                               (cdr (assoc "SEARCH" (cdr result)))))
 993                         (message "Searching %s... %d matches" group arts)))
 994                     (message "Searching %s...done" group))
 995                 (quit nil))
 996               (nreverse artlist)))
 997           groups))))))
 998
 999 (defun nnir-imap-make-query (criteria qstring)
1000   "Parse the query string and criteria into an appropriate IMAP search
1001 expression, returning the string query to make.
1002
1003 This implements a little language designed to return the expected results
1004 to an arbitrary query string to the end user.
1005
1006 The search is always case-insensitive, as defined by RFC2060, and supports
1007 the following features (inspired by the Google search input language):
1008
1009 Automatic \"and\" queries
1010     If you specify multiple words then they will be treated as an \"and\"
1011     expression intended to match all components.
1012
1013 Phrase searches
1014     If you wrap your query in double-quotes then it will be treated as a
1015     literal string.
1016
1017 Negative terms
1018     If you precede a term with \"-\" then it will negate that.
1019
1020 \"OR\" queries
1021     If you include an upper-case \"OR\" in your search it will cause the
1022     term before it and the term after it to be treated as alternatives.
1023
1024 In future the following will be added to the language:
1025  * support for date matches
1026  * support for location of text matching within the query
1027  * from/to/etc headers
1028  * additional search terms
1029  * flag based searching
1030  * anything else that the RFC supports, basically."
1031   ;; Walk through the query and turn it into an IMAP query string.
1032   (nnir-imap-query-to-imap criteria (nnir-imap-parse-query qstring)))
1033
1034
1035 (defun nnir-imap-query-to-imap (criteria query)
1036   "Turn a s-expression format query into IMAP."
1037   (mapconcat
1038    ;; Turn the expressions into IMAP text
1039    (lambda (item)
1040      (nnir-imap-expr-to-imap criteria item))
1041    ;; The query, already in s-expr format.
1042    query
1043    ;; Append a space between each expression
1044    " "))
1045
1046
1047 (defun nnir-imap-expr-to-imap (criteria expr)
1048   "Convert EXPR into an IMAP search expression on CRITERIA"
1049   ;; What sort of expression is this, eh?
1050   (cond
1051    ;; Simple string term
1052    ((stringp expr)
1053     (format "%s %S" criteria expr))
1054    ;; Trivial term: and
1055    ((eq expr 'and) nil)
1056    ;; Composite term: or expression
1057    ((eq (car-safe expr) 'or)
1058     (format "OR %s %s"
1059             (nnir-imap-expr-to-imap criteria (second expr))
1060             (nnir-imap-expr-to-imap criteria (third expr))))
1061    ;; Composite term: just the fax, mam
1062    ((eq (car-safe expr) 'not)
1063     (format "NOT (%s)" (nnir-imap-query-to-imap criteria (rest expr))))
1064    ;; Composite term: just expand it all.
1065    ((and (not (null expr)) (listp expr))
1066     (format "(%s)" (nnir-imap-query-to-imap criteria expr)))
1067    ;; Complex value, give up for now.
1068    (t (error "Unhandled input: %S" expr))))
1069
1070
1071 (defun nnir-imap-parse-query (string)
1072   "Turn STRING into an s-expression based query based on the IMAP
1073 query language as defined in `nnir-imap-make-query'.
1074
1075 This involves turning individual tokens into higher level terms
1076 that the search language can then understand and use."
1077   (with-temp-buffer
1078     ;; Set up the parsing environment.
1079     (insert string)
1080     (goto-char (point-min))
1081     ;; Now, collect the output terms and return them.
1082     (let (out)
1083       (while (not (nnir-imap-end-of-input))
1084         (push (nnir-imap-next-expr) out))
1085       (reverse out))))
1086
1087
1088 (defun nnir-imap-next-expr (&optional count)
1089   "Return the next expression from the current buffer."
1090   (let ((term (nnir-imap-next-term count))
1091         (next (nnir-imap-peek-symbol)))
1092     ;; Are we looking at an 'or' expression?
1093     (cond
1094      ;; Handle 'expr or expr'
1095      ((eq next 'or)
1096       (list 'or term (nnir-imap-next-expr 2)))
1097      ;; Anything else
1098      (t term))))
1099
1100
1101 (defun nnir-imap-next-term (&optional count)
1102   "Return the next TERM from the current buffer."
1103   (let ((term (nnir-imap-next-symbol count)))
1104     ;; What sort of term is this?
1105     (cond
1106      ;; and -- just ignore it
1107      ((eq term 'and) 'and)
1108      ;; negated term
1109      ((eq term 'not) (list 'not (nnir-imap-next-expr)))
1110      ;; generic term
1111      (t term))))
1112
1113
1114 (defun nnir-imap-peek-symbol ()
1115   "Return the next symbol from the current buffer, but don't consume it."
1116   (save-excursion
1117     (nnir-imap-next-symbol)))
1118
1119 (defun nnir-imap-next-symbol (&optional count)
1120   "Return the next symbol from the current buffer, or nil if we are
1121 at the end of the buffer.  If supplied COUNT skips some symbols before
1122 returning the one at the supplied position."
1123   (when (and (numberp count) (> count 1))
1124     (nnir-imap-next-symbol (1- count)))
1125   (let ((case-fold-search t))
1126     ;; end of input stream?
1127     (unless (nnir-imap-end-of-input)
1128       ;; No, return the next symbol from the stream.
1129       (cond
1130        ;; negated expression -- return it and advance one char.
1131        ((looking-at "-") (forward-char 1) 'not)
1132        ;; quoted string
1133        ((looking-at "\"") (nnir-imap-delimited-string "\""))
1134        ;; list expression -- we parse the content and return this as a list.
1135        ((looking-at "(")
1136         (nnir-imap-parse-query (nnir-imap-delimited-string ")")))
1137        ;; keyword input -- return a symbol version
1138        ((looking-at "\\band\\b") (forward-char 3) 'and)
1139        ((looking-at "\\bor\\b")  (forward-char 2) 'or)
1140        ((looking-at "\\bnot\\b") (forward-char 3) 'not)
1141        ;; Simple, boring keyword
1142        (t (let ((start (point))
1143                 (end (if (search-forward-regexp "[[:blank:]]" nil t)
1144                          (prog1
1145                              (match-beginning 0)
1146                            ;; unskip if we hit a non-blank terminal character.
1147                            (when (string-match "[^[:blank:]]" (match-string 0))
1148                              (backward-char 1)))
1149                        (goto-char (point-max)))))
1150             (buffer-substring start end)))))))
1151
1152 (defun nnir-imap-delimited-string (delimiter)
1153   "Return a delimited string from the current buffer."
1154   (let ((start (point)) end)
1155     (forward-char 1)                    ; skip the first delimiter.
1156     (while (not end)
1157       (unless (search-forward delimiter nil t)
1158         (error "Unmatched delimited input with %s in query" delimiter))
1159       (let ((here (point)))
1160         (unless (equal (buffer-substring (- here 2) (- here 1)) "\\")
1161           (setq end (point)))))
1162     (buffer-substring (1+ start) (1- end))))
1163
1164 (defun nnir-imap-end-of-input ()
1165   "Are we at the end of input?"
1166   (skip-chars-forward "[[:blank:]]")
1167   (looking-at "$"))
1168
1169
1170 ;; Swish++ interface.
1171 ;; -cc- Todo
1172 ;; Search by
1173 ;; - group
1174 ;; Sort by
1175 ;; - rank (default)
1176 ;; - article number
1177 ;; - file size
1178 ;; - group
1179 (defun nnir-run-swish++ (query server &optional group)
1180   "Run QUERY against swish++.
1181 Returns a vector of (group name, file name) pairs (also vectors,
1182 actually).
1183
1184 Tested with swish++ 4.7 on GNU/Linux and with swish++ 5.0b2 on
1185 Windows NT 4.0."
1186
1187   ;; (when group
1188   ;;   (error "The swish++ backend cannot search specific groups"))
1189
1190   (save-excursion
1191     (let ( (qstring (cdr (assq 'query query)))
1192            (groupspec (cdr (assq 'swish++-group query)))
1193            (prefix (nnir-read-server-parm 'nnir-swish++-remove-prefix server))
1194            artlist
1195            ;; nnml-use-compressed-files might be any string, but probably this
1196            ;; is sufficient.  Note that we can't only use the value of
1197            ;; nnml-use-compressed-files because old articles might have been
1198            ;; saved with a different value.
1199            (article-pattern (if (string-match "\\`nnmaildir:"
1200                                               (gnus-group-server server))
1201                                 ":[0-9]+"
1202                               "^[0-9]+\\(\\.[a-z0-9]+\\)?$"))
1203            score artno dirnam filenam)
1204
1205       (when (equal "" qstring)
1206         (error "swish++: You didn't enter anything"))
1207
1208       (set-buffer (get-buffer-create nnir-tmp-buffer))
1209       (erase-buffer)
1210
1211       (if groupspec
1212           (message "Doing swish++ query %s on %s..." qstring groupspec)
1213         (message "Doing swish++ query %s..." qstring))
1214
1215       (let* ((cp-list `( ,nnir-swish++-program
1216                          nil            ; input from /dev/null
1217                          t              ; output
1218                          nil            ; don't redisplay
1219                          "--config-file" ,(nnir-read-server-parm 'nnir-swish++-configuration-file server)
1220                          ,@(nnir-read-server-parm 'nnir-swish++-additional-switches server)
1221                          ,qstring       ; the query, in swish++ format
1222                          ))
1223              (exitstatus
1224               (progn
1225                 (message "%s args: %s" nnir-swish++-program
1226                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1227                 (apply 'call-process cp-list))))
1228         (unless (or (null exitstatus)
1229                     (zerop exitstatus))
1230           (nnheader-report 'nnir "Couldn't run swish++: %s" exitstatus)
1231           ;; swish++ failure reason is in this buffer, show it if
1232           ;; the user wants it.
1233           (when (> gnus-verbose 6)
1234             (display-buffer nnir-tmp-buffer))))
1235
1236       ;; The results are output in the format of:
1237       ;; V 4.7 Linux
1238       ;; rank relative-path-name file-size file-title
1239       ;; V 5.0b2:
1240       ;; rank relative-path-name file-size topic??
1241       ;; where rank is an integer from 1 to 100.
1242       (goto-char (point-min))
1243       (while (re-search-forward
1244               "\\(^[0-9]+\\) \\([^ ]+\\) [0-9]+ \\(.*\\)$" nil t)
1245         (setq score (match-string 1)
1246               filenam (match-string 2)
1247               artno (file-name-nondirectory filenam)
1248               dirnam (file-name-directory filenam))
1249
1250         ;; don't match directories
1251         (when (string-match article-pattern artno)
1252           (when (not (null dirnam))
1253
1254             ;; maybe limit results to matching groups.
1255             (when (or (not groupspec)
1256                       (string-match groupspec dirnam))
1257               (nnir-add-result dirnam artno score prefix server artlist)))))
1258
1259       (message "Massaging swish++ output...done")
1260
1261       ;; Sort by score
1262       (apply 'vector
1263              (sort artlist
1264                    (function (lambda (x y)
1265                                (> (nnir-artitem-rsv x)
1266                                   (nnir-artitem-rsv y)))))))))
1267
1268 ;; Swish-E interface.
1269 (defun nnir-run-swish-e (query server &optional group)
1270   "Run given query against swish-e.
1271 Returns a vector of (group name, file name) pairs (also vectors,
1272 actually).
1273
1274 Tested with swish-e-2.0.1 on Windows NT 4.0."
1275
1276   ;; swish-e crashes with empty parameter to "-w" on commandline...
1277   ;; (when group
1278   ;;   (error "The swish-e backend cannot search specific groups"))
1279
1280   (save-excursion
1281     (let ((qstring (cdr (assq 'query query)))
1282           (prefix
1283            (or (nnir-read-server-parm 'nnir-swish-e-remove-prefix server)
1284                (error "Missing parameter `nnir-swish-e-remove-prefix'")))
1285           artlist score artno dirnam group )
1286
1287       (when (equal "" qstring)
1288         (error "swish-e: You didn't enter anything"))
1289
1290       (set-buffer (get-buffer-create nnir-tmp-buffer))
1291       (erase-buffer)
1292
1293       (message "Doing swish-e query %s..." query)
1294       (let* ((index-files
1295               (or (nnir-read-server-parm
1296                    'nnir-swish-e-index-files server)
1297                   (error "Missing parameter `nnir-swish-e-index-files'")))
1298              (additional-switches
1299               (nnir-read-server-parm
1300                'nnir-swish-e-additional-switches server))
1301              (cp-list `(,nnir-swish-e-program
1302                         nil             ; input from /dev/null
1303                         t               ; output
1304                         nil             ; don't redisplay
1305                         "-f" ,@index-files
1306                         ,@additional-switches
1307                         "-w"
1308                         ,qstring        ; the query, in swish-e format
1309                         ))
1310              (exitstatus
1311               (progn
1312                 (message "%s args: %s" nnir-swish-e-program
1313                          (mapconcat 'identity (cddddr cp-list) " "))
1314                 (apply 'call-process cp-list))))
1315         (unless (or (null exitstatus)
1316                     (zerop exitstatus))
1317           (nnheader-report 'nnir "Couldn't run swish-e: %s" exitstatus)
1318           ;; swish-e failure reason is in this buffer, show it if
1319           ;; the user wants it.
1320           (when (> gnus-verbose 6)
1321             (display-buffer nnir-tmp-buffer))))
1322
1323       ;; The results are output in the format of:
1324       ;; rank path-name file-title file-size
1325       (goto-char (point-min))
1326       (while (re-search-forward
1327               "\\(^[0-9]+\\) \\([^ ]+\\) \"\\([^\"]+\\)\" [0-9]+$" nil t)
1328         (setq score (match-string 1)
1329               artno (match-string 3)
1330               dirnam (file-name-directory (match-string 2)))
1331
1332         ;; don't match directories
1333         (when (string-match "^[0-9]+$" artno)
1334           (when (not (null dirnam))
1335
1336             ;; remove nnir-swish-e-remove-prefix from beginning of dirname
1337             (when (string-match (concat "^" prefix) dirnam)
1338               (setq dirnam (replace-match "" t t dirnam)))
1339
1340             (setq dirnam (substring dirnam 0 -1))
1341             ;; eliminate all ".", "/", "\" from beginning. Always matches.
1342             (string-match "^[./\\]*\\(.*\\)$" dirnam)
1343             ;; "/" -> "."
1344             (setq group (gnus-replace-in-string (match-string 1 dirnam) "/" "."))
1345             ;; Windows "\\" -> "."
1346             (setq group (gnus-replace-in-string group "\\\\" "."))
1347
1348             (push (vector (gnus-group-full-name group server)
1349                           (string-to-number artno)
1350                           (string-to-number score))
1351                   artlist))))
1352
1353       (message "Massaging swish-e output...done")
1354
1355       ;; Sort by score
1356       (apply 'vector
1357              (sort artlist
1358                    (function (lambda (x y)
1359                                (> (nnir-artitem-rsv x)
1360                                   (nnir-artitem-rsv y)))))))))
1361
1362 ;; HyREX interface
1363 (defun nnir-run-hyrex (query server &optional group)
1364   (save-excursion
1365     (let ((artlist nil)
1366           (groupspec (cdr (assq 'hyrex-group query)))
1367           (qstring (cdr (assq 'query query)))
1368           (prefix (nnir-read-server-parm 'nnir-hyrex-remove-prefix server))
1369           score artno dirnam)
1370       (when (and (not groupspec) group)
1371         (setq groupspec
1372               (regexp-opt
1373                (mapcar (lambda (x) (gnus-group-real-name x)) group))))
1374       (set-buffer (get-buffer-create nnir-tmp-buffer))
1375       (erase-buffer)
1376       (message "Doing hyrex-search query %s..." query)
1377       (let* ((cp-list
1378               `( ,nnir-hyrex-program
1379                  nil                    ; input from /dev/null
1380                  t                      ; output
1381                  nil                    ; don't redisplay
1382                  "-i",(nnir-read-server-parm 'nnir-hyrex-index-directory server) ; index directory
1383                  ,@(nnir-read-server-parm 'nnir-hyrex-additional-switches server)
1384                  ,qstring          ; the query, in hyrex-search format
1385                  ))
1386              (exitstatus
1387               (progn
1388                 (message "%s args: %s" nnir-hyrex-program
1389                          (mapconcat 'identity (cddddr cp-list) " "))
1390                 (apply 'call-process cp-list))))
1391         (unless (or (null exitstatus)
1392                     (zerop exitstatus))
1393           (nnheader-report 'nnir "Couldn't run hyrex-search: %s" exitstatus)
1394           ;; nnir-search failure reason is in this buffer, show it if
1395           ;; the user wants it.
1396           (when (> gnus-verbose 6)
1397             (display-buffer nnir-tmp-buffer)))) ;; FIXME: Don't clear buffer !
1398       (message "Doing hyrex-search query \"%s\"...done" qstring)
1399       (sit-for 0)
1400       ;; nnir-search returns:
1401       ;;   for nnml/nnfolder: "filename mailid weight"
1402       ;;   for nnimap:        "group mailid weight"
1403       (goto-char (point-min))
1404       (delete-non-matching-lines "^\\S + [0-9]+ [0-9]+$")
1405       ;; HyREX doesn't search directly in groups -- so filter out here.
1406       (when groupspec
1407         (keep-lines groupspec))
1408       ;; extract data from result lines
1409       (goto-char (point-min))
1410       (while (re-search-forward
1411               "\\(\\S +\\) \\([0-9]+\\) \\([0-9]+\\)" nil t)
1412         (setq dirnam (match-string 1)
1413               artno (match-string 2)
1414               score (match-string 3))
1415         (when (string-match prefix dirnam)
1416           (setq dirnam (replace-match "" t t dirnam)))
1417         (push (vector (gnus-group-full-name
1418                        (gnus-replace-in-string dirnam "/" ".") server)
1419                       (string-to-number artno)
1420                       (string-to-number score))
1421               artlist))
1422       (message "Massaging hyrex-search output...done.")
1423       (apply 'vector
1424              (sort artlist
1425                    (function (lambda (x y)
1426                                (if (string-lessp (nnir-artitem-group x)
1427                                                  (nnir-artitem-group y))
1428                                    t
1429                                  (< (nnir-artitem-number x)
1430                                     (nnir-artitem-number y)))))))
1431       )))
1432
1433 ;; Namazu interface
1434 (defun nnir-run-namazu (query server &optional group)
1435   "Run given query against Namazu.  Returns a vector of (group name, file name)
1436 pairs (also vectors, actually).
1437
1438 Tested with Namazu 2.0.6 on a GNU/Linux system."
1439   ;; (when group
1440   ;;   (error "The Namazu backend cannot search specific groups"))
1441   (save-excursion
1442     (let ((article-pattern (if (string-match "\\`nnmaildir:"
1443                                              (gnus-group-server server))
1444                                ":[0-9]+"
1445                              "^[0-9]+$"))
1446           artlist
1447           (qstring (cdr (assq 'query query)))
1448           (prefix (nnir-read-server-parm 'nnir-namazu-remove-prefix server))
1449           score group article
1450           (process-environment (copy-sequence process-environment)))
1451       (setenv "LC_MESSAGES" "C")
1452       (set-buffer (get-buffer-create nnir-tmp-buffer))
1453       (erase-buffer)
1454       (let* ((cp-list
1455               `( ,nnir-namazu-program
1456                  nil                    ; input from /dev/null
1457                  t                      ; output
1458                  nil                    ; don't redisplay
1459                  "-q"                   ; don't be verbose
1460                  "-a"                   ; show all matches
1461                  "-s"                   ; use short format
1462                  ,@(nnir-read-server-parm 'nnir-namazu-additional-switches server)
1463                  ,qstring               ; the query, in namazu format
1464                  ,(nnir-read-server-parm 'nnir-namazu-index-directory server) ; index directory
1465                  ))
1466              (exitstatus
1467               (progn
1468                 (message "%s args: %s" nnir-namazu-program
1469                          (mapconcat 'identity (cddddr cp-list) " "))
1470                 (apply 'call-process cp-list))))
1471         (unless (or (null exitstatus)
1472                     (zerop exitstatus))
1473           (nnheader-report 'nnir "Couldn't run namazu: %s" exitstatus)
1474           ;; Namazu failure reason is in this buffer, show it if
1475           ;; the user wants it.
1476           (when (> gnus-verbose 6)
1477             (display-buffer nnir-tmp-buffer))))
1478
1479       ;; Namazu output looks something like this:
1480       ;; 2. Re: Gnus agent expire broken (score: 55)
1481       ;; /home/henrik/Mail/mail/sent/1310 (4,138 bytes)
1482
1483       (goto-char (point-min))
1484       (while (re-search-forward
1485               "^\\([0-9]+\\.\\).*\\((score: \\([0-9]+\\)\\))\n\\([^ ]+\\)"
1486               nil t)
1487         (setq score (match-string 3)
1488               group (file-name-directory (match-string 4))
1489               article (file-name-nondirectory (match-string 4)))
1490
1491         ;; make sure article and group is sane
1492         (when (and (string-match article-pattern article)
1493                    (not (null group)))
1494           (nnir-add-result group article score prefix server artlist)))
1495
1496       ;; sort artlist by score
1497       (apply 'vector
1498              (sort artlist
1499                    (function (lambda (x y)
1500                                (> (nnir-artitem-rsv x)
1501                                   (nnir-artitem-rsv y)))))))))
1502
1503 (defun nnir-run-notmuch (query server &optional group)
1504   "Run QUERY against notmuch.
1505 Returns a vector of (group name, file name) pairs (also vectors,
1506 actually)."
1507
1508   ;; (when group
1509   ;;   (error "The notmuch backend cannot search specific groups"))
1510
1511   (save-excursion
1512     (let ( (qstring (cdr (assq 'query query)))
1513            (groupspec (cdr (assq 'notmuch-group query)))
1514            (prefix (nnir-read-server-parm 'nnir-notmuch-remove-prefix server))
1515            artlist
1516            (article-pattern (if (string-match "\\`nnmaildir:"
1517                                               (gnus-group-server server))
1518                                ":[0-9]+"
1519                              "^[0-9]+$"))
1520            artno dirnam filenam)
1521
1522       (when (equal "" qstring)
1523         (error "notmuch: You didn't enter anything"))
1524
1525       (set-buffer (get-buffer-create nnir-tmp-buffer))
1526       (erase-buffer)
1527
1528       (if groupspec
1529           (message "Doing notmuch query %s on %s..." qstring groupspec)
1530         (message "Doing notmuch query %s..." qstring))
1531
1532       (let* ((cp-list `( ,nnir-notmuch-program
1533                          nil            ; input from /dev/null
1534                          t              ; output
1535                          nil            ; don't redisplay
1536                          "search"
1537                          "--format=text"
1538                          "--output=files"
1539                          ,@(nnir-read-server-parm 'nnir-notmuch-additional-switches server)
1540                          ,qstring       ; the query, in notmuch format
1541                          ))
1542              (exitstatus
1543               (progn
1544                 (message "%s args: %s" nnir-notmuch-program
1545                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1546                 (apply 'call-process cp-list))))
1547         (unless (or (null exitstatus)
1548                     (zerop exitstatus))
1549           (nnheader-report 'nnir "Couldn't run notmuch: %s" exitstatus)
1550           ;; notmuch failure reason is in this buffer, show it if
1551           ;; the user wants it.
1552           (when (> gnus-verbose 6)
1553             (display-buffer nnir-tmp-buffer))))
1554
1555       ;; The results are output in the format of:
1556       ;; absolute-path-name
1557       (goto-char (point-min))
1558       (while (not (eobp))
1559         (setq filenam (buffer-substring-no-properties (line-beginning-position)
1560                                                       (line-end-position))
1561               artno (file-name-nondirectory filenam)
1562               dirnam (file-name-directory filenam))
1563         (forward-line 1)
1564
1565         ;; don't match directories
1566         (when (string-match article-pattern artno)
1567           (when (not (null dirnam))
1568
1569             ;; maybe limit results to matching groups.
1570             (when (or (not groupspec)
1571                       (string-match groupspec dirnam))
1572               (nnir-add-result dirnam artno "" prefix server artlist)))))
1573
1574       (message "Massaging notmuch output...done")
1575
1576       artlist)))
1577
1578 (defun nnir-run-find-grep (query server &optional grouplist)
1579   "Run find and grep to obtain matching articles."
1580   (let* ((method (gnus-server-to-method server))
1581          (sym (intern
1582                (concat (symbol-name (car method)) "-directory")))
1583          (directory (cadr (assoc sym (cddr method))))
1584          (regexp (cdr (assoc 'query query)))
1585          (grep-options (cdr (assoc 'grep-options query)))
1586          (grouplist (or grouplist (nnir-get-active server))))
1587     (unless directory
1588       (error "No directory found in method specification of server %s"
1589              server))
1590     (apply
1591      'vconcat
1592      (mapcar (lambda (x)
1593                (let ((group x)
1594                      artlist)
1595                  (message "Searching %s using find-grep..."
1596                           (or group server))
1597                  (save-window-excursion
1598                    (set-buffer (get-buffer-create nnir-tmp-buffer))
1599                    (if (> gnus-verbose 6)
1600                        (pop-to-buffer (current-buffer)))
1601                    (cd directory) ; Using relative paths simplifies
1602                                         ; postprocessing.
1603                    (let ((group
1604                           (if (not group)
1605                               "."
1606                             ;; Try accessing the group literally as
1607                             ;; well as interpreting dots as directory
1608                             ;; separators so the engine works with
1609                             ;; plain nnml as well as the Gnus Cache.
1610                             (let ((group (gnus-group-real-name group)))
1611                               ;; Replace cl-func find-if.
1612                               (if (file-directory-p group)
1613                                   group
1614                                 (if (file-directory-p
1615                                      (setq group
1616                                            (gnus-replace-in-string
1617                                             group
1618                                             "\\." "/" t)))
1619                                     group))))))
1620                      (unless group
1621                        (error "Cannot locate directory for group"))
1622                      (save-excursion
1623                        (apply
1624                         'call-process "find" nil t
1625                         "find" group "-maxdepth" "1" "-type" "f"
1626                         "-name" "[0-9]*" "-exec"
1627                         "grep"
1628                         `("-l" ,@(and grep-options
1629                                       (split-string grep-options "\\s-" t))
1630                           "-e" ,regexp "{}" "+"))))
1631
1632                    ;; Translate relative paths to group names.
1633                    (while (not (eobp))
1634                      (let* ((path (split-string
1635                                    (buffer-substring
1636                                     (point)
1637                                     (line-end-position)) "/" t))
1638                             (art (string-to-number (car (last path)))))
1639                        (while (string= "." (car path))
1640                          (setq path (cdr path)))
1641                        (let ((group (mapconcat 'identity
1642                                                ;; Replace cl-func:
1643                                                ;; (subseq path 0 -1)
1644                                                (let ((end (1- (length path)))
1645                                                      res)
1646                                                  (while
1647                                                      (>= (setq end (1- end)) 0)
1648                                                    (push (pop path) res))
1649                                                  (nreverse res))
1650                                                ".")))
1651                          (push
1652                           (vector (gnus-group-full-name group server) art 0)
1653                           artlist))
1654                        (forward-line 1)))
1655                    (message "Searching %s using find-grep...done"
1656                             (or group server))
1657                    artlist)))
1658      grouplist))))
1659
1660 (declare-function mm-url-insert "mm-url" (url &optional follow-refresh))
1661 (declare-function mm-url-encode-www-form-urlencoded "mm-url" (pairs))
1662
1663 ;; gmane interface
1664 (defun nnir-run-gmane (query srv &optional groups)
1665   "Run a search against a gmane back-end server."
1666       (let* ((case-fold-search t)
1667              (qstring (cdr (assq 'query query)))
1668              (server (cadr (gnus-server-to-method srv)))
1669              (groupspec (mapconcat
1670                          (lambda (x)
1671                            (if (gnus-string-match-p "gmane" x)
1672                                (format "group:%s" (gnus-group-short-name x))
1673                              (error "Can't search non-gmane groups: %s" x)))
1674                            groups " "))
1675              (authorspec
1676               (if (assq 'gmane-author query)
1677                   (format "author:%s" (cdr (assq 'gmane-author query))) ""))
1678              (search (format "%s %s %s"
1679                              qstring groupspec authorspec))
1680              (gnus-inhibit-demon t)
1681              artlist)
1682         (require 'mm-url)
1683         (with-current-buffer (get-buffer-create nnir-tmp-buffer)
1684           (erase-buffer)
1685           (mm-url-insert
1686            (concat
1687             "http://search.gmane.org/nov.php"
1688             "?"
1689             (mm-url-encode-www-form-urlencoded
1690              `(("query" . ,search)
1691                ("HITSPERPAGE" . "999")))))
1692           (unless (featurep 'xemacs) (set-buffer-multibyte t))
1693           (mm-decode-coding-region (point-min) (point-max) 'utf-8)
1694           (goto-char (point-min))
1695           (forward-line 1)
1696           (while (not (eobp))
1697             (unless (or (eolp) (looking-at "\x0d"))
1698               (let ((header (nnheader-parse-nov)))
1699                 (let ((xref (mail-header-xref header))
1700                       (xscore (string-to-number (cdr (assoc 'X-Score
1701                                (mail-header-extra header))))))
1702                   (when (string-match " \\([^:]+\\)[:/]\\([0-9]+\\)" xref)
1703                     (push
1704                      (vector
1705                       (gnus-group-prefixed-name (match-string 1 xref) srv)
1706                       (string-to-number (match-string 2 xref)) xscore)
1707                      artlist)))))
1708             (forward-line 1)))
1709         (apply 'vector (nreverse (mm-delete-duplicates artlist)))))
1710
1711 ;;; Util Code:
1712
1713 (defun gnus-nnir-group-p (group)
1714   "Say whether GROUP is nnir or not."
1715   (if (gnus-group-prefixed-p group)
1716       (eq 'nnir (car (gnus-find-method-for-group group)))
1717     (and group (string-match "^nnir" group))))
1718
1719 (defun nnir-read-parms (nnir-search-engine)
1720   "Reads additional search parameters according to `nnir-engines'."
1721   (let ((parmspec (caddr (assoc nnir-search-engine nnir-engines))))
1722     (mapcar 'nnir-read-parm parmspec)))
1723
1724 (defun nnir-read-parm (parmspec)
1725   "Reads a single search parameter.
1726 `parmspec' is a cons cell, the car is a symbol, the cdr is a prompt."
1727   (let ((sym (car parmspec))
1728         (prompt (cdr parmspec)))
1729     (if (listp prompt)
1730         (let* ((result (apply 'gnus-completing-read prompt))
1731                (mapping (or (assoc result nnir-imap-search-arguments)
1732                             (cons nil nnir-imap-search-other))))
1733           (cons sym (format (cdr mapping) result)))
1734       (cons sym (read-string prompt)))))
1735
1736 (defun nnir-run-query (specs)
1737   "Invoke appropriate search engine function (see `nnir-engines')."
1738   (apply 'vconcat
1739          (mapcar
1740           (lambda (x)
1741             (let* ((server (car x))
1742                    (search-engine (nnir-server-to-search-engine server))
1743                    (search-func (cadr (assoc search-engine nnir-engines))))
1744               (and search-func
1745                    (funcall search-func (cdr (assq 'nnir-query-spec specs))
1746                             server (cadr x)))))
1747           (cdr (assq 'nnir-group-spec specs)))))
1748
1749 (defun nnir-server-to-search-engine (server)
1750   (or (nnir-read-server-parm 'nnir-search-engine server t)
1751       (cdr (assoc (car (gnus-server-to-method server))
1752                   nnir-method-default-engines))))
1753
1754 (defun nnir-read-server-parm (key server &optional not-global)
1755   "Returns the parameter value corresponding to `key' for
1756 `server'. If no server-specific value is found consult the global
1757 environment unless `not-global' is non-nil."
1758   (let ((method (gnus-server-to-method server)))
1759     (cond ((and method (assq key (cddr method)))
1760            (nth 1 (assq key (cddr method))))
1761           ((and (not not-global) (boundp key)) (symbol-value key))
1762           (t nil))))
1763
1764 (defun nnir-possibly-change-group (group &optional server)
1765   (or (not server) (nnir-server-opened server) (nnir-open-server server))
1766   (when (gnus-nnir-group-p group)
1767     (setq nnir-artlist (gnus-group-get-parameter
1768                         (gnus-group-prefixed-name
1769                          (gnus-group-short-name group) '(nnir "nnir"))
1770                         'nnir-artlist t))))
1771
1772 (defun nnir-server-opened (&optional server)
1773   (let ((backend (car (gnus-server-to-method server))))
1774     (nnoo-current-server-p (or backend 'nnir) server)))
1775
1776 (defun nnir-search-thread (header)
1777   "Make an nnir group based on the thread containing the article
1778 header. The current server will be searched. If the registry is
1779 installed, the server that the registry reports the current
1780 article came from is also searched."
1781   (let* ((query
1782           (list (cons 'query (nnimap-make-thread-query header))
1783                 (cons 'criteria "")))
1784          (server
1785           (list (list (gnus-method-to-server
1786            (gnus-find-method-for-group gnus-newsgroup-name)))))
1787          (registry-group (and
1788                           (gnus-bound-and-true-p 'gnus-registry-enabled)
1789                           (car (gnus-registry-get-id-key
1790                                 (mail-header-id header) 'group))))
1791          (registry-server
1792           (and registry-group
1793                (gnus-method-to-server
1794                 (gnus-find-method-for-group registry-group)))))
1795     (when registry-server (add-to-list 'server (list registry-server)))
1796     (gnus-group-make-nnir-group nil (list
1797                                      (cons 'nnir-query-spec query)
1798                                      (cons 'nnir-group-spec server)))
1799     (gnus-summary-goto-subject (gnus-id-to-article (mail-header-id header)))))
1800
1801 (defun nnir-get-active (srv)
1802   (let ((method (gnus-server-to-method srv))
1803         groups)
1804     (gnus-request-list method)
1805     (with-current-buffer nntp-server-buffer
1806       (let ((cur (current-buffer))
1807             name)
1808         (goto-char (point-min))
1809         (unless (or (null nnir-ignored-newsgroups)
1810                     (string= nnir-ignored-newsgroups ""))
1811           (delete-matching-lines nnir-ignored-newsgroups))
1812         (if (eq (car method) 'nntp)
1813             (while (not (eobp))
1814               (ignore-errors
1815                 (push (mm-string-as-unibyte
1816                        (gnus-group-full-name
1817                         (buffer-substring
1818                          (point)
1819                          (progn
1820                            (skip-chars-forward "^ \t")
1821                            (point))) method))
1822                       groups))
1823               (forward-line))
1824           (while (not (eobp))
1825             (ignore-errors
1826               (push (mm-string-as-unibyte
1827                      (if (eq (char-after) ?\")
1828                          (gnus-group-full-name (read cur) method)
1829                        (let ((p (point)) (name ""))
1830                          (skip-chars-forward "^ \t\\\\")
1831                          (setq name (buffer-substring p (point)))
1832                          (while (eq (char-after) ?\\)
1833                            (setq p (1+ (point)))
1834                            (forward-char 2)
1835                            (skip-chars-forward "^ \t\\\\")
1836                            (setq name (concat name (buffer-substring
1837                                                     p (point)))))
1838                          (gnus-group-full-name name method))))
1839                     groups))
1840             (forward-line)))))
1841     groups))
1842
1843 (defun nnir-registry-action (action data-header from &optional to method)
1844   "Call `gnus-registry-action' with the original article group."
1845   (gnus-registry-action
1846    action
1847    data-header
1848    (nnir-article-group (mail-header-number data-header))
1849    to
1850    method))
1851
1852 (defun nnir-mode ()
1853   (when (eq (car (gnus-find-method-for-group gnus-newsgroup-name)) 'nnir)
1854     (setq gnus-summary-line-format
1855           (or nnir-summary-line-format gnus-summary-line-format))
1856     (when (gnus-bound-and-true-p 'gnus-registry-enabled)
1857       (remove-hook 'gnus-summary-article-delete-hook 'gnus-registry-action t)
1858       (remove-hook 'gnus-summary-article-move-hook 'gnus-registry-action t)
1859       (remove-hook 'gnus-summary-article-expire-hook 'gnus-registry-action t)
1860       (add-hook 'gnus-summary-article-delete-hook 'nnir-registry-action t t)
1861       (add-hook 'gnus-summary-article-move-hook 'nnir-registry-action t t)
1862       (add-hook 'gnus-summary-article-expire-hook 'nnir-registry-action t t))))
1863
1864
1865 (defun gnus-summary-create-nnir-group ()
1866   (interactive)
1867   (or (nnir-server-opened "") (nnir-open-server "nnir"))
1868   (let ((name (gnus-read-group "Group name: "))
1869         (method '(nnir ""))
1870         (pgroup
1871          (gnus-group-guess-full-name-from-command-method gnus-newsgroup-name)))
1872     (with-current-buffer gnus-group-buffer
1873       (gnus-group-make-group
1874        name method nil
1875        (gnus-group-find-parameter pgroup)))))
1876
1877
1878 (deffoo nnir-request-create-group (group &optional server args)
1879   (message "Creating nnir group %s" group)
1880   (let* ((group (gnus-group-prefixed-name  group '(nnir "nnir")))
1881          (specs (assq 'nnir-specs args))
1882          (query-spec
1883           (or (cdr (assq 'nnir-query-spec specs))
1884               (list (cons 'query
1885                           (read-string "Query: " nil 'nnir-search-history)))))
1886          (group-spec
1887           (or (cdr (assq 'nnir-group-spec specs))
1888               (list (list (read-string "Server: " nil nil)))))
1889          (nnir-specs (list (cons 'nnir-query-spec query-spec)
1890                            (cons 'nnir-group-spec group-spec))))
1891     (gnus-group-set-parameter group 'nnir-specs nnir-specs)
1892     (gnus-group-set-parameter
1893      group 'nnir-artlist
1894      (or (cdr (assq 'nnir-artlist args))
1895          (nnir-run-query nnir-specs)))
1896     (nnir-request-update-info group (gnus-get-info group)))
1897   t)
1898
1899 (deffoo nnir-request-delete-group (group &optional force server)
1900   t)
1901
1902 (deffoo nnir-request-list (&optional server)
1903   t)
1904
1905 (deffoo nnir-request-scan (group method)
1906   t)
1907
1908 (deffoo nnir-request-close ()
1909   t)
1910
1911 (nnoo-define-skeleton nnir)
1912
1913 ;; The end.
1914 (provide 'nnir)
1915
1916 ;;; nnir.el ends here