cgit.sxemacs.org Git - gnus/blob - lisp/nnir.el

   1 ;;; nnir.el --- search mail with various search engines -*- coding: iso-8859-1 -*-
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Kai Großjohann <grossjohann@ls6.cs.uni-dortmund.de>
   7 ;; Swish-e and Swish++ backends by:
   8 ;;   Christoph Conrad <christoph.conrad@gmx.de>.
   9 ;; IMAP backend by: Simon Josefsson <jas@pdc.kth.se>.
  10 ;; IMAP search by: Torsten Hilbrich <torsten.hilbrich <at> gmx.net>
  11 ;; IMAP search improved by Daniel Pittman  <daniel@rimspace.net>.
  12 ;; nnmaildir support for Swish++ and Namazu backends by:
  13 ;;   Justus Piater <Justus <at> Piater.name>
  14 ;; Keywords: news mail searching ir
  15
  16 ;; This file is part of GNU Emacs.
  17
  18 ;; GNU Emacs is free software: you can redistribute it and/or modify
  19 ;; it under the terms of the GNU General Public License as published by
  20 ;; the Free Software Foundation, either version 3 of the License, or
  21 ;; (at your option) any later version.
  22
  23 ;; GNU Emacs is distributed in the hope that it will be useful,
  24 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  25 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26 ;; GNU General Public License for more details.
  27
  28 ;; You should have received a copy of the GNU General Public License
  29 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  30
  31 ;;; Commentary:
  32
  33 ;; TODO: Documentation in the Gnus manual
  34
  35 ;; From: Reiner Steib
  36 ;; Subject: Re: Including nnir.el
  37 ;; Newsgroups: gmane.emacs.gnus.general
  38 ;; Message-ID: <v9d5dnp6aq.fsf@marauder.physik.uni-ulm.de>
  39 ;; Date: 2006-06-05 22:49:01 GMT
  40 ;;
  41 ;; On Sun, Jun 04 2006, Sascha Wilde wrote:
  42 ;;
  43 ;; > The one thing most hackers like to forget: Documentation.  By now the
  44 ;; > documentation is only in the comments at the head of the source, I
  45 ;; > would use it as basis to cook up some minimal texinfo docs.
  46 ;; >
  47 ;; > Where in the existing gnus manual would this fit best?
  48
  49 ;; Maybe (info "(gnus)Combined Groups") for a general description.
  50 ;; `gnus-group-make-nnir-group' might be described in (info
  51 ;; "(gnus)Foreign Groups") as well.
  52
  53
  54 ;; The most recent version of this can always be fetched from the Gnus
  55 ;; repository.  See http://www.gnus.org/ for more information.
  56
  57 ;; This code is still in the development stage but I'd like other
  58 ;; people to have a look at it.  Please do not hesitate to contact me
  59 ;; with your ideas.
  60
  61 ;; What does it do?  Well, it allows you to index your mail using some
  62 ;; search engine (freeWAIS-sf, swish-e and others -- see later),
  63 ;; then type `G G' in the Group buffer and issue a query to the search
  64 ;; engine.  You will then get a buffer which shows all articles
  65 ;; matching the query, sorted by Retrieval Status Value (score).
  66
  67 ;; When looking at the retrieval result (in the Summary buffer) you
  68 ;; can type `G T' (aka M-x gnus-summary-nnir-goto-thread RET) on an
  69 ;; article.  You will be teleported into the group this article came
  70 ;; from, showing the thread this article is part of.  (See below for
  71 ;; restrictions.)
  72
  73 ;; The Lisp installation is simple: just put this file on your
  74 ;; load-path, byte-compile it, and load it from ~/.gnus or something.
  75 ;; This will install a new command `G G' in your Group buffer for
  76 ;; searching your mail.  Note that you also need to configure a number
  77 ;; of variables, as described below.
  78
  79 ;; Restrictions:
  80 ;;
  81 ;; * If you don't use HyREX as your search engine, this expects that
  82 ;;   you use nnml or another one-file-per-message backend, because the
  83 ;;   others doesn't support nnfolder.
  84 ;; * It can only search the mail backend's which are supported by one
  85 ;;   search engine, because of different query languages.
  86 ;; * There are restrictions to the Wais setup.
  87 ;; * There are restrictions to the imap setup.
  88 ;; * gnus-summary-nnir-goto-thread: Fetches whole group first, before
  89 ;;   limiting to the right articles.  This is much too slow, of
  90 ;;   course.  May issue a query for number of articles to fetch; you
  91 ;;   must accept the default of all articles at this point or things
  92 ;;   may break.
  93
  94 ;; The Lisp setup involves setting a few variables and setting up the
  95 ;; search engine. You can define the variables in the server definition
  96 ;; like this :
  97 ;;   (setq gnus-secondary-select-methods '(
  98 ;;       (nnimap "" (nnimap-address "localhost")
  99 ;;                  (nnir-search-engine hyrex)
 100 ;;                  (nnir-hyrex-additional-switches ("-d" "ddl-nnimap.xml"))
 101 ;;       )))
 102 ;; Or you can define the global ones. The variables set in the mailer-
 103 ;; definition will be used first.
 104 ;; The variable to set is `nnir-search-engine'.  Choose one of the engines
 105 ;; listed in `nnir-engines'.  (Actually `nnir-engines' is an alist,
 106 ;; type `C-h v nnir-engines RET' for more information; this includes
 107 ;; examples for setting `nnir-search-engine', too.)
 108 ;;
 109 ;; The variable nnir-mail-backend isn't used anymore.
 110 ;;
 111
 112 ;; You must also set up a search engine.  I'll tell you about the two
 113 ;; search engines currently supported:
 114
 115 ;; 1. freeWAIS-sf
 116 ;;
 117 ;; As always with freeWAIS-sf, you need a so-called `format file'.  I
 118 ;; use the following file:
 119 ;;
 120 ;; ,-----
 121 ;; | # Kai's format file for freeWAIS-sf for indexing mails.
 122 ;; | # Each mail is in a file, much like the MH format.
 123 ;; |
 124 ;; | # Document separator should never match -- each file is a document.
 125 ;; | record-sep: /^@this regex should never match@$/
 126 ;; |
 127 ;; | # Searchable fields specification.
 128 ;; |
 129 ;; | region: /^[sS]ubject:/ /^[sS]ubject: */
 130 ;; |         subject "Subject header" stemming TEXT BOTH
 131 ;; | end: /^[^ \t]/
 132 ;; |
 133 ;; | region: /^([tT][oO]|[cC][cC]):/ /^([tT][oO]|[cC][cC]): */
 134 ;; |         to "To and Cc headers" SOUNDEX BOTH
 135 ;; | end: /^[^ \t]/
 136 ;; |
 137 ;; | region: /^[fF][rR][oO][mM]:/ /^[fF][rR][oO][mM]: */
 138 ;; |         from "From header" SOUNDEX BOTH
 139 ;; | end: /^[^ \t]/
 140 ;; |
 141 ;; | region: /^$/
 142 ;; |         stemming TEXT GLOBAL
 143 ;; | end: /^@this regex should never match@$/
 144 ;; `-----
 145 ;;
 146 ;; 1998-07-22: waisindex would dump core on me for large articles with
 147 ;; the above settings.  I used /^$/ as the end regex for the global
 148 ;; field.  That seemed to work okay.
 149
 150 ;; There is a Perl module called `WAIS.pm' which is available from
 151 ;; CPAN as well as ls6-ftp.cs.uni-dortmund.de:/pub/wais/Perl.  This
 152 ;; module comes with a nifty tool called `makedb', which I use for
 153 ;; indexing.  Here's my `makedb.conf':
 154 ;;
 155 ;; ,-----
 156 ;; | # Config file for makedb
 157 ;; |
 158 ;; | # Global options
 159 ;; | waisindex = /usr/local/bin/waisindex
 160 ;; | wais_opt  = -stem -t fields
 161 ;; | # `-stem' option necessary when `stemming' is specified for the
 162 ;; | # global field in the *.fmt file
 163 ;; |
 164 ;; | # Own variables
 165 ;; | homedir = /home/kai
 166 ;; |
 167 ;; | # The mail database.
 168 ;; | database        = mail
 169 ;; | files           = `find $homedir/Mail -name \*[0-9] -print`
 170 ;; | dbdir           = $homedir/.wais
 171 ;; | limit           = 100
 172 ;; `-----
 173 ;;
 174 ;; The Lisp setup involves the `nnir-wais-*' variables.  The most
 175 ;; difficult to understand variable is probably
 176 ;; `nnir-wais-remove-prefix'.  Here's what it does: the output of
 177 ;; `waissearch' basically contains the file name and the (full)
 178 ;; directory name.  As Gnus works with group names rather than
 179 ;; directory names, the directory name is transformed into a group
 180 ;; name as follows: first, a prefix is removed from the (full)
 181 ;; directory name, then all `/' are replaced with `.'.  The variable
 182 ;; `nnir-wais-remove-prefix' should contain a regex matching exactly
 183 ;; this prefix.  It defaults to `$HOME/Mail/' (note the trailing
 184 ;; slash).
 185
 186 ;; 2. Namazu
 187 ;;
 188 ;; The Namazu backend requires you to have one directory containing all
 189 ;; index files, this is controlled by the `nnir-namazu-index-directory'
 190 ;; variable.  To function the `nnir-namazu-remove-prefix' variable must
 191 ;; also be correct, see the documentation for `nnir-wais-remove-prefix'
 192 ;; above.
 193 ;;
 194 ;; It is particularly important not to pass any any switches to namazu
 195 ;; that will change the output format.  Good switches to use include
 196 ;; `--sort', `--ascending', `--early' and `--late'.  Refer to the Namazu
 197 ;; documentation for further information on valid switches.
 198 ;;
 199 ;; To index my mail with the `mknmz' program I use the following
 200 ;; configuration file:
 201 ;;
 202 ;; ,----
 203 ;; | package conf;  # Don't remove this line!
 204 ;; |
 205 ;; | # Paths which will not be indexed. Don't use `^' or `$' anchors.
 206 ;; | $EXCLUDE_PATH = "spam|sent";
 207 ;; |
 208 ;; | # Header fields which should be searchable. case-insensitive
 209 ;; | $REMAIN_HEADER = "from|date|message-id|subject";
 210 ;; |
 211 ;; | # Searchable fields. case-insensitive
 212 ;; | $SEARCH_FIELD = "from|date|message-id|subject";
 213 ;; |
 214 ;; | # The max length of a word.
 215 ;; | $WORD_LENG_MAX = 128;
 216 ;; |
 217 ;; | # The max length of a field.
 218 ;; | $MAX_FIELD_LENGTH = 256;
 219 ;; `----
 220 ;;
 221 ;; My mail is stored in the directories ~/Mail/mail/, ~/Mail/lists/ and
 222 ;; ~/Mail/archive/, so to index them I go to the directory set in
 223 ;; `nnir-namazu-index-directory' and issue the following command.
 224 ;;
 225 ;;      mknmz --mailnews ~/Mail/archive/ ~/Mail/mail/ ~/Mail/lists/
 226 ;;
 227 ;; For maximum searching efficiency I have a cron job set to run this
 228 ;; command every four hours.
 229
 230 ;; 3. HyREX
 231 ;;
 232 ;; The HyREX backend requires you to have one directory from where all
 233 ;; your relative paths are to, if you use them. This directory must be
 234 ;; set in the `nnir-hyrex-index-directory' variable, which defaults to
 235 ;; your home directory. You must also pass the base, class and
 236 ;; directory options or simply your dll to the `nnir-hyrex-programm' by
 237 ;; setting the `nnir-hyrex-additional-switches' variable accordently.
 238 ;; To function the `nnir-hyrex-remove-prefix' variable must also be
 239 ;; correct, see the documentation for `nnir-wais-remove-prefix' above.
 240
 241 ;; 4. find-grep
 242 ;;
 243 ;; The find-grep engine simply runs find(1) to locate eligible
 244 ;; articles and searches them with grep(1).  This, of course, is much
 245 ;; slower than using a proper search engine but OTOH doesn't require
 246 ;; maintenance of an index and is still faster than using any built-in
 247 ;; means for searching.  The method specification of the server to
 248 ;; search must include a directory for this engine to work (E.g.,
 249 ;; `nnml-directory').  The tools must be POSIX compliant.  GNU Find
 250 ;; prior to version 4.2.12 (4.2.26 on Linux due to incorrect ARG_MAX
 251 ;; handling) does not work.
 252 ;; ,----
 253 ;; |    ;; find-grep configuration for searching the Gnus Cache
 254 ;; |
 255 ;; |    (nnml "cache"
 256 ;; |          (nnml-get-new-mail nil)
 257 ;; |          (nnir-search-engine find-grep)
 258 ;; |          (nnml-directory "~/News/cache/")
 259 ;; |          (nnml-active-file "~/News/cache/active"))
 260 ;; `----
 261
 262 ;; Developer information:
 263
 264 ;; I have tried to make the code expandable.  Basically, it is divided
 265 ;; into two layers.  The upper layer is somewhat like the `nnvirtual'
 266 ;; backend: given a specification of what articles to show from
 267 ;; another backend, it creates a group containing exactly those
 268 ;; articles.  The lower layer issues a query to a search engine and
 269 ;; produces such a specification of what articles to show from the
 270 ;; other backend.
 271
 272 ;; The interface between the two layers consists of the single
 273 ;; function `nnir-run-query', which just selects the appropriate
 274 ;; function for the search engine one is using.  The input to
 275 ;; `nnir-run-query' is a string, representing the query as input by
 276 ;; the user.  The output of `nnir-run-query' is supposed to be a
 277 ;; vector, each element of which should in turn be a three-element
 278 ;; vector.  The first element should be full group name of the article,
 279 ;; the second element should be the article number, and the third
 280 ;; element should be the Retrieval Status Value (RSV) as returned from
 281 ;; the search engine.  An RSV is the score assigned to the document by
 282 ;; the search engine.  For Boolean search engines, the
 283 ;; RSV is always 1000 (or 1 or 100, or whatever you like).
 284
 285 ;; The sorting order of the articles in the summary buffer created by
 286 ;; nnir is based on the order of the articles in the above mentioned
 287 ;; vector, so that's where you can do the sorting you'd like.  Maybe
 288 ;; it would be nice to have a way of displaying the search result
 289 ;; sorted differently?
 290
 291 ;; So what do you need to do when you want to add another search
 292 ;; engine?  You write a function that executes the query.  Temporary
 293 ;; data from the search engine can be put in `nnir-tmp-buffer'.  This
 294 ;; function should return the list of articles as a vector, as
 295 ;; described above.  Then, you need to register this backend in
 296 ;; `nnir-engines'.  Then, users can choose the backend by setting
 297 ;; `nnir-search-engine'.
 298
 299 ;; Todo, or future ideas:
 300
 301 ;; * It should be possible to restrict search to certain groups.
 302 ;;
 303 ;; * There is currently no error checking.
 304 ;;
 305 ;; * The summary buffer display is currently really ugly, with all the
 306 ;;   added information in the subjects.  How could I make this
 307 ;;   prettier?
 308 ;;
 309 ;; * A function which can be called from an nnir summary buffer which
 310 ;;   teleports you into the group the current article came from and
 311 ;;   shows you the whole thread this article is part of.
 312 ;;   Implementation suggestions?
 313 ;;   (1998-07-24: There is now a preliminary implementation, but
 314 ;;   it is much too slow and quite fragile.)
 315 ;;
 316 ;; * Support other mail backends.  In particular, probably quite a few
 317 ;;   people use nnfolder.  How would one go about searching nnfolders
 318 ;;   and producing the right data needed?  The group name and the RSV
 319 ;;   are simple, but what about the article number?
 320 ;;   - The article number is encoded in the `X-Gnus-Article-Number'
 321 ;;     header of each mail.
 322 ;;   - The HyREX engine supports nnfolder.
 323 ;;
 324 ;; * Support compressed mail files.  Probably, just stripping off the
 325 ;;   `.gz' or `.Z' file name extension is sufficient.
 326 ;;
 327 ;; * At least for imap, the query is performed twice.
 328 ;;
 329
 330 ;; Have you got other ideas?
 331
 332 ;;; Setup Code:
 333
 334 (require 'nnoo)
 335 (require 'gnus-group)
 336 (require 'gnus-sum)
 337 (require 'message)
 338 (require 'gnus-util)
 339 (eval-when-compile
 340   (require 'cl))
 341
 342 (nnoo-declare nnir)
 343 (nnoo-define-basics nnir)
 344
 345 (gnus-declare-backend "nnir" 'mail)
 346
 347 (defvar nnir-imap-search-field "TEXT"
 348   "The IMAP search item when doing an nnir search")
 349
 350 (defvar nnir-imap-search-arguments
 351   '(("Whole message" . "TEXT")
 352     ("Subject" . "SUBJECT")
 353     ("To" . "TO")
 354     ("From" . "FROM")
 355     (nil . "HEADER \"%s\""))
 356   "Mapping from user readable strings to IMAP search items for use in nnir")
 357
 358 (defvar nnir-imap-search-argument-history ()
 359   "The history for querying search options in nnir")
 360
 361 (defvar nnir-get-article-nov-override-function nil
 362   "If non-nil, a function that will be passed each search result.  This
 363 should return a message's headers in NOV format.
 364
 365 If this variable is nil, or if the provided function returns nil for a search
 366 result, `gnus-retrieve-headers' will be called instead.")
 367
 368
 369 ;;; Developer Extension Variable:
 370
 371 (defvar nnir-engines
 372   `((wais    nnir-run-waissearch
 373              ())
 374     (imap    nnir-run-imap
 375              ((criteria
 376                "Search in: "                      ; Prompt
 377                ,nnir-imap-search-arguments        ; alist for completing
 378                nil                                ; no filtering
 379                nil                                ; allow any user input
 380                nil                                ; initial value
 381                nnir-imap-search-argument-history  ; the history to use
 382                ,nnir-imap-search-field            ; default
 383                )))
 384     (swish++ nnir-run-swish++
 385              ((group . "Group spec: ")))
 386     (swish-e nnir-run-swish-e
 387              ((group . "Group spec: ")))
 388     (namazu  nnir-run-namazu
 389              ())
 390     (hyrex   nnir-run-hyrex
 391              ((group . "Group spec: ")))
 392   (find-grep nnir-run-find-grep
 393              ((grep-options . "Grep options: "))))
 394   "Alist of supported search engines.
 395 Each element in the alist is a three-element list (ENGINE FUNCTION ARGS).
 396 ENGINE is a symbol designating the searching engine.  FUNCTION is also
 397 a symbol, giving the function that does the search.  The third element
 398 ARGS is a list of cons pairs (PARAM . PROMPT).  When issuing a query,
 399 the FUNCTION will issue a query for each of the PARAMs, using PROMPT.
 400
 401 The value of `nnir-search-engine' must be one of the ENGINE symbols.
 402 For example, use the following line for searching using freeWAIS-sf:
 403     (setq nnir-search-engine 'wais)
 404 Use the following line if you read your mail via IMAP and your IMAP
 405 server supports searching:
 406     (setq nnir-search-engine 'imap)
 407 Note that you have to set additional variables for most backends.  For
 408 example, the `wais' backend needs the variables `nnir-wais-program',
 409 `nnir-wais-database' and `nnir-wais-remove-prefix'.
 410
 411 Add an entry here when adding a new search engine.")
 412
 413 ;;; User Customizable Variables:
 414
 415 (defgroup nnir nil
 416   "Search nnmh and nnml groups in Gnus with swish-e, freeWAIS-sf, or EWS."
 417   :group 'gnus)
 418
 419 ;; Mail backend.
 420
 421 ;; TODO:
 422 ;; If `nil', use server parameters to find out which server to search. CCC
 423 ;;
 424 (defcustom nnir-mail-backend '(nnml "")
 425   "*Specifies which backend should be searched.
 426 More precisely, this is used to determine from which backend to fetch the
 427 messages found.
 428
 429 This must be equal to an existing server, so maybe it is best to use
 430 something like the following:
 431     (setq nnir-mail-backend (nth 0 gnus-secondary-select-methods))
 432 The above line works fine if the mail backend you want to search is
 433 the first element of gnus-secondary-select-methods (`nth' starts counting
 434 at zero)."
 435   :type '(sexp)
 436   :group 'nnir)
 437
 438 ;; Search engine to use.
 439
 440 (defcustom nnir-search-engine 'wais
 441   "*The search engine to use.  Must be a symbol.
 442 See `nnir-engines' for a list of supported engines, and for example
 443 settings of `nnir-search-engine'."
 444   :type '(sexp)
 445   :group 'nnir)
 446
 447 ;; freeWAIS-sf.
 448
 449 (defcustom nnir-wais-program "waissearch"
 450   "*Name of waissearch executable."
 451   :type '(string)
 452   :group 'nnir)
 453
 454 (defcustom nnir-wais-database (expand-file-name "~/.wais/mail")
 455   "*Name of Wais database containing the mail.
 456
 457 Note that this should be a file name without extension.  For example,
 458 if you have a file /home/john/.wais/mail.fmt, use this:
 459     (setq nnir-wais-database \"/home/john/.wais/mail\")
 460 The string given here is passed to `waissearch -d' as-is."
 461   :type '(file)
 462   :group 'nnir)
 463
 464 (defcustom nnir-wais-remove-prefix (concat (getenv "HOME") "/Mail/")
 465   "*The prefix to remove from each directory name returned by waissearch
 466 in order to get a group name (albeit with / instead of .).  This is a
 467 regular expression.
 468
 469 For example, suppose that Wais returns file names such as
 470 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 471 setting:  (setq nnir-wais-remove-prefix \"/home/john/Mail/\")
 472 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 473 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 474 arrive at the correct group name, \"mail.misc\"."
 475   :type '(regexp)
 476   :group 'nnir)
 477
 478 (defcustom nnir-swish++-configuration-file
 479   (expand-file-name "~/Mail/swish++.conf")
 480   "*Configuration file for swish++."
 481   :type '(file)
 482   :group 'nnir)
 483
 484 (defcustom nnir-swish++-program "search"
 485   "*Name of swish++ search executable."
 486   :type '(string)
 487   :group 'nnir)
 488
 489 (defcustom nnir-swish++-additional-switches '()
 490   "*A list of strings, to be given as additional arguments to swish++.
 491
 492 Note that this should be a list.  Ie, do NOT use the following:
 493     (setq nnir-swish++-additional-switches \"-i -w\") ; wrong
 494 Instead, use this:
 495     (setq nnir-swish++-additional-switches '(\"-i\" \"-w\"))"
 496   :type '(repeat (string))
 497   :group 'nnir)
 498
 499 (defcustom nnir-swish++-remove-prefix (concat (getenv "HOME") "/Mail/")
 500   "*The prefix to remove from each file name returned by swish++
 501 in order to get a group name (albeit with / instead of .).  This is a
 502 regular expression.
 503
 504 This variable is very similar to `nnir-wais-remove-prefix', except
 505 that it is for swish++, not Wais."
 506   :type '(regexp)
 507   :group 'nnir)
 508
 509 ;; Swish-E.
 510 ;; URL: http://sunsite.berkeley.edu/SWISH-E/
 511 ;; New version: http://www.boe.es/swish-e
 512 ;; Variables `nnir-swish-e-index-file', `nnir-swish-e-program' and
 513 ;; `nnir-swish-e-additional-switches'
 514
 515 (make-obsolete-variable 'nnir-swish-e-index-file
 516                         'nnir-swish-e-index-files "Emacs 23.1")
 517 (defcustom nnir-swish-e-index-file
 518   (expand-file-name "~/Mail/index.swish-e")
 519   "*Index file for swish-e.
 520 This could be a server parameter.
 521 It is never consulted once `nnir-swish-e-index-files', which should be
 522 used instead, has been customized."
 523   :type '(file)
 524   :group 'nnir)
 525
 526 (defcustom nnir-swish-e-index-files
 527   (list nnir-swish-e-index-file)
 528   "*List of index files for swish-e.
 529 This could be a server parameter."
 530   :type '(repeat (file))
 531   :group 'nnir)
 532
 533 (defcustom nnir-swish-e-program "swish-e"
 534   "*Name of swish-e search executable.
 535 This cannot be a server parameter."
 536   :type '(string)
 537   :group 'nnir)
 538
 539 (defcustom nnir-swish-e-additional-switches '()
 540   "*A list of strings, to be given as additional arguments to swish-e.
 541
 542 Note that this should be a list.  Ie, do NOT use the following:
 543     (setq nnir-swish-e-additional-switches \"-i -w\") ; wrong
 544 Instead, use this:
 545     (setq nnir-swish-e-additional-switches '(\"-i\" \"-w\"))
 546
 547 This could be a server parameter."
 548   :type '(repeat (string))
 549   :group 'nnir)
 550
 551 (defcustom nnir-swish-e-remove-prefix (concat (getenv "HOME") "/Mail/")
 552   "*The prefix to remove from each file name returned by swish-e
 553 in order to get a group name (albeit with / instead of .).  This is a
 554 regular expression.
 555
 556 This variable is very similar to `nnir-wais-remove-prefix', except
 557 that it is for swish-e, not Wais.
 558
 559 This could be a server parameter."
 560   :type '(regexp)
 561   :group 'nnir)
 562
 563 ;; HyREX engine, see <URL:http://ls6-www.cs.uni-dortmund.de/>
 564
 565 (defcustom nnir-hyrex-program "nnir-search"
 566   "*Name of the nnir-search executable."
 567   :type '(string)
 568   :group 'nnir)
 569
 570 (defcustom nnir-hyrex-additional-switches '()
 571   "*A list of strings, to be given as additional arguments for nnir-search.
 572 Note that this should be a list. Ie, do NOT use the following:
 573     (setq nnir-hyrex-additional-switches \"-ddl ddl.xml -c nnir\") ; wrong !
 574 Instead, use this:
 575     (setq nnir-hyrex-additional-switches '(\"-ddl\" \"ddl.xml\" \"-c\" \"nnir\"))"
 576   :type '(repeat (string))
 577   :group 'nnir)
 578
 579 (defcustom nnir-hyrex-index-directory (getenv "HOME")
 580   "*Index directory for HyREX."
 581   :type '(directory)
 582   :group 'nnir)
 583
 584 (defcustom nnir-hyrex-remove-prefix (concat (getenv "HOME") "/Mail/")
 585   "*The prefix to remove from each file name returned by HyREX
 586 in order to get a group name (albeit with / instead of .).
 587
 588 For example, suppose that HyREX returns file names such as
 589 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 590 setting:  (setq nnir-hyrex-remove-prefix \"/home/john/Mail/\")
 591 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 592 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 593 arrive at the correct group name, \"mail.misc\"."
 594   :type '(directory)
 595   :group 'nnir)
 596
 597 ;; Namazu engine, see <URL:http://ww.namazu.org/>
 598
 599 (defcustom nnir-namazu-program "namazu"
 600   "*Name of Namazu search executable."
 601   :type '(string)
 602   :group 'nnir)
 603
 604 (defcustom nnir-namazu-index-directory (expand-file-name "~/Mail/namazu/")
 605   "*Index directory for Namazu."
 606   :type '(directory)
 607   :group 'nnir)
 608
 609 (defcustom nnir-namazu-additional-switches '()
 610   "*A list of strings, to be given as additional arguments to namazu.
 611 The switches `-q', `-a', and `-s' are always used, very few other switches
 612 make any sense in this context.
 613
 614 Note that this should be a list.  Ie, do NOT use the following:
 615     (setq nnir-namazu-additional-switches \"-i -w\") ; wrong
 616 Instead, use this:
 617     (setq nnir-namazu-additional-switches '(\"-i\" \"-w\"))"
 618   :type '(repeat (string))
 619   :group 'nnir)
 620
 621 (defcustom nnir-namazu-remove-prefix (concat (getenv "HOME") "/Mail/")
 622   "*The prefix to remove from each file name returned by Namazu
 623 in order to get a group name (albeit with / instead of .).
 624
 625 This variable is very similar to `nnir-wais-remove-prefix', except
 626 that it is for Namazu, not Wais."
 627   :type '(directory)
 628   :group 'nnir)
 629
 630 ;;; Internal Variables:
 631
 632 (defvar nnir-current-query nil
 633   "Internal: stores current query (= group name).")
 634
 635 (defvar nnir-current-server nil
 636   "Internal: stores current server (does it ever change?).")
 637
 638 (defvar nnir-current-group-marked nil
 639   "Internal: stores current list of process-marked groups.")
 640
 641 (defvar nnir-artlist nil
 642   "Internal: stores search result.")
 643
 644 (defvar nnir-tmp-buffer " *nnir*"
 645   "Internal: temporary buffer.")
 646
 647 ;;; Code:
 648
 649 ;; Gnus glue.
 650
 651 (defun gnus-group-make-nnir-group (extra-parms query)
 652   "Create an nnir group.  Asks for query."
 653   (interactive "P\nsQuery: ")
 654   (setq nnir-current-query nil
 655         nnir-current-server nil
 656         nnir-current-group-marked nil
 657         nnir-artlist nil)
 658   (let ((parms nil))
 659     (if extra-parms
 660         (setq parms (nnir-read-parms query))
 661       (setq parms (list (cons 'query query))))
 662     (add-to-list 'parms (cons 'unique-id (message-unique-id)) t)
 663     (gnus-group-read-ephemeral-group
 664      (concat "nnir:" (prin1-to-string parms)) '(nnir "") t
 665      (cons (current-buffer)
 666            gnus-current-window-configuration)
 667      nil)))
 668
 669 (eval-when-compile
 670   (when (featurep 'xemacs)
 671     ;; The `kbd' macro requires that the `read-kbd-macro' macro is available.
 672     (require 'edmacro)))
 673
 674 (defun nnir-group-mode-hook ()
 675   (define-key gnus-group-mode-map (kbd "G G")
 676     'gnus-group-make-nnir-group))
 677 (add-hook 'gnus-group-mode-hook 'nnir-group-mode-hook)
 678
 679 ;; Why is this needed? Is this for compatibility with old/new gnusae? Using
 680 ;; gnus-group-server instead works for me.  -- Justus Piater
 681 (defmacro nnir-group-server (group)
 682   "Return the server for a newsgroup GROUP.
 683 The returned format is as `gnus-server-to-method' needs it.  See
 684 `gnus-group-real-prefix' and `gnus-group-real-name'."
 685   `(let ((gname ,group))
 686      (if (string-match "^\\([^:]+\\):" gname)
 687          (progn
 688            (setq gname (match-string 1 gname))
 689            (if (string-match "^\\([^+]+\\)\\+\\(.+\\)$" gname)
 690                (format "%s:%s" (match-string 1 gname) (match-string 2 gname))
 691              (concat gname ":")))
 692        (format "%s:%s" (car gnus-select-method) (cadr gnus-select-method)))))
 693
 694 ;; Summary mode commands.
 695
 696 (defun gnus-summary-nnir-goto-thread ()
 697   "Only applies to nnir groups.  Go to group this article came from
 698 and show thread that contains this article."
 699   (interactive)
 700   (unless (eq 'nnir (car (gnus-find-method-for-group gnus-newsgroup-name)))
 701     (error "Can't execute this command unless in nnir group"))
 702   (let* ((cur (gnus-summary-article-number))
 703          (group (nnir-artlist-artitem-group nnir-artlist cur))
 704          (backend-number (nnir-artlist-artitem-number nnir-artlist cur))
 705          server backend-group)
 706     (setq server (nnir-group-server group))
 707     (setq backend-group (gnus-group-real-name group))
 708     (gnus-group-read-ephemeral-group
 709      backend-group
 710      (gnus-server-to-method server)
 711      t                                  ; activate
 712      (cons (current-buffer)
 713            'summary)                    ; window config
 714      nil
 715      (list backend-number))
 716     (gnus-summary-limit (list backend-number))
 717     (gnus-summary-refer-thread)))
 718
 719 (if (fboundp 'eval-after-load)
 720     (eval-after-load "gnus-sum"
 721       '(define-key gnus-summary-goto-map
 722          "T" 'gnus-summary-nnir-goto-thread))
 723   (add-hook 'gnus-summary-mode-hook
 724             (function (lambda ()
 725                         (define-key gnus-summary-goto-map
 726                           "T" 'gnus-summary-nnir-goto-thread)))))
 727
 728
 729
 730 ;; Gnus backend interface functions.
 731
 732 (deffoo nnir-open-server (server &optional definitions)
 733   ;; Just set the server variables appropriately.
 734   (nnoo-change-server 'nnir server definitions))
 735
 736 (deffoo nnir-request-group (group &optional server fast info)
 737   "GROUP is the query string."
 738   (nnir-possibly-change-server server)
 739   ;; Check for cache and return that if appropriate.
 740   (if (and (equal group nnir-current-query)
 741            (equal gnus-group-marked nnir-current-group-marked)
 742            (or (null server)
 743                (equal server nnir-current-server)))
 744       nnir-artlist
 745     ;; Cache miss.
 746     (setq nnir-artlist (nnir-run-query group)))
 747   (with-current-buffer nntp-server-buffer
 748     (if (zerop (length nnir-artlist))
 749         (progn
 750           (setq nnir-current-query nil
 751                 nnir-current-server nil
 752                 nnir-current-group-marked nil
 753                 nnir-artlist nil)
 754           (nnheader-report 'nnir "Search produced empty results."))
 755       ;; Remember data for cache.
 756       (setq nnir-current-query group)
 757       (when server (setq nnir-current-server server))
 758       (setq nnir-current-group-marked gnus-group-marked)
 759       (nnheader-insert "211 %d %d %d %s\n"
 760                        (nnir-artlist-length nnir-artlist) ; total #
 761                        1              ; first #
 762                        (nnir-artlist-length nnir-artlist) ; last #
 763                        group))))     ; group name
 764
 765 (deffoo nnir-retrieve-headers (articles &optional group server fetch-old)
 766   (save-excursion
 767     (let ((artlist (copy-sequence articles))
 768           art artitem artgroup artno artrsv artfullgroup
 769           novitem novdata foo server)
 770       (while (not (null artlist))
 771         (setq art (car artlist))
 772         (or (numberp art)
 773             (nnheader-report
 774              'nnir
 775              "nnir-retrieve-headers doesn't grok message ids: %s"
 776              art))
 777         (setq artitem (nnir-artlist-article nnir-artlist art))
 778         (setq artrsv (nnir-artitem-rsv artitem))
 779         (setq artfullgroup (nnir-artitem-group artitem))
 780         (setq artno (nnir-artitem-number artitem))
 781         (setq artgroup (gnus-group-real-name artfullgroup))
 782         (setq server (nnir-group-server artfullgroup))
 783         ;; retrieve NOV or HEAD data for this article, transform into
 784         ;; NOV data and prepend to `novdata'
 785         (set-buffer nntp-server-buffer)
 786         (nnir-possibly-change-server server)
 787         (let ((gnus-override-method
 788                (gnus-server-to-method server)))
 789           ;; if nnir-get-article-nov-override-function is set, use it
 790           (if nnir-get-article-nov-override-function
 791               (setq novitem (funcall nnir-get-article-nov-override-function
 792                                      artitem))
 793           ;; else, set novitem through nnheader-parse-nov/nnheader-parse-head
 794             (case (setq foo (gnus-retrieve-headers (list artno)
 795                                                    artfullgroup nil))
 796               (nov
 797                (goto-char (point-min))
 798                (setq novitem (nnheader-parse-nov))
 799                (unless novitem
 800                  (pop-to-buffer nntp-server-buffer)
 801                  (error
 802                   "nnheader-parse-nov returned nil for article %s in group %s"
 803                   artno artfullgroup)))
 804               (headers
 805                (goto-char (point-min))
 806                (setq novitem (nnheader-parse-head))
 807                (unless novitem
 808                  (pop-to-buffer nntp-server-buffer)
 809                  (error
 810                   "nnheader-parse-head returned nil for article %s in group %s"
 811                   artno artfullgroup)))
 812               (t (error "Unknown header type %s while requesting article %s of group %s"
 813                         foo artno artfullgroup)))))
 814         ;; replace article number in original group with article number
 815         ;; in nnir group
 816         (mail-header-set-number novitem art)
 817         (mail-header-set-from novitem
 818                               (mail-header-from novitem))
 819         (mail-header-set-subject
 820          novitem
 821          (format "[%d: %s/%d] %s"
 822                  artrsv artgroup artno
 823                  (mail-header-subject novitem)))
 824         ;;-(mail-header-set-extra novitem nil)
 825         (push novitem novdata)
 826         (setq artlist (cdr artlist)))
 827       (setq novdata (nreverse novdata))
 828       (set-buffer nntp-server-buffer) (erase-buffer)
 829       (mapc 'nnheader-insert-nov novdata)
 830       'nov)))
 831
 832 (deffoo nnir-request-article (article
 833                               &optional group server to-buffer)
 834   (if (stringp article)
 835       (nnheader-report
 836        'nnir
 837        "nnir-retrieve-headers doesn't grok message ids: %s"
 838        article)
 839     (save-excursion
 840       (let* ((artitem (nnir-artlist-article nnir-artlist
 841                                             article))
 842              (artfullgroup (nnir-artitem-group artitem))
 843              (artno (nnir-artitem-number artitem))
 844              ;; Bug?
 845              ;; Why must we bind nntp-server-buffer here?  It won't
 846              ;; work if `buf' is used, say.  (Of course, the set-buffer
 847              ;; line below must then be updated, too.)
 848              (nntp-server-buffer (or to-buffer nntp-server-buffer)))
 849         (set-buffer nntp-server-buffer)
 850         (erase-buffer)
 851         (message "Requesting article %d from group %s"
 852                  artno artfullgroup)
 853         (gnus-request-article artno artfullgroup nntp-server-buffer)
 854         (cons artfullgroup artno)))))
 855
 856
 857 (nnoo-define-skeleton nnir)
 858
 859
 860 (defmacro nnir-add-result (dirnam artno score prefix server artlist)
 861   "Ask `nnir-compose-result' to construct a result vector,
 862 and if it is non-nil, add it to artlist."
 863   `(let ((result (nnir-compose-result ,dirnam ,artno ,score ,prefix ,server)))
 864      (when (not (null result))
 865        (push result ,artlist))))
 866
 867 (autoload 'nnmaildir-base-name-to-article-number "nnmaildir")
 868
 869 ;; Helper function currently used by the Swish++ and Namazu backends;
 870 ;; perhaps useful for other backends as well
 871 (defun nnir-compose-result (dirnam article score prefix server)
 872   "Extract the group from dirnam, and create a result vector
 873 ready to be added to the list of search results."
 874
 875   ;; remove nnir-*-remove-prefix from beginning of dirnam filename
 876   (when (string-match (concat "^" prefix) dirnam)
 877     (setq dirnam (replace-match "" t t dirnam)))
 878
 879   (when (file-readable-p (concat prefix dirnam article))
 880     ;; remove trailing slash and, for nnmaildir, cur/new/tmp
 881     (setq dirnam
 882           (substring dirnam 0 (if (string= server "nnmaildir:") -5 -1)))
 883
 884     ;; Set group to dirnam without any leading dots or slashes,
 885     ;; and with all subsequent slashes replaced by dots
 886     (let ((group (gnus-replace-in-string
 887                  (gnus-replace-in-string dirnam "^[./\\]" "" t)
 888                  "[/\\]" "." t)))
 889
 890     (vector (nnir-group-full-name group server)
 891             (if (string= server "nnmaildir:")
 892                 (nnmaildir-base-name-to-article-number
 893                  (substring article 0 (string-match ":" article))
 894                  group nil)
 895               (string-to-number article))
 896             (string-to-number score)))))
 897
 898 ;;; Search Engine Interfaces:
 899
 900 ;; freeWAIS-sf interface.
 901 (defun nnir-run-waissearch (query server &optional group)
 902   "Run given query agains waissearch.  Returns vector of (group name, file name)
 903 pairs (also vectors, actually)."
 904   (when group
 905     (error "The freeWAIS-sf backend cannot search specific groups"))
 906   (save-excursion
 907     (let ((qstring (cdr (assq 'query query)))
 908           (prefix (nnir-read-server-parm 'nnir-wais-remove-prefix server))
 909           artlist score artno dirnam)
 910       (set-buffer (get-buffer-create nnir-tmp-buffer))
 911       (erase-buffer)
 912       (message "Doing WAIS query %s..." query)
 913       (call-process nnir-wais-program
 914                     nil                 ; input from /dev/null
 915                     t                   ; output to current buffer
 916                     nil                 ; don't redisplay
 917                     "-d" (nnir-read-server-parm 'nnir-wais-database server) ; database to search
 918                     qstring)
 919       (message "Massaging waissearch output...")
 920       ;; remove superfluous lines
 921       (keep-lines "Score:")
 922       ;; extract data from result lines
 923       (goto-char (point-min))
 924       (while (re-search-forward
 925               "Score: +\\([0-9]+\\).*'\\([0-9]+\\) +\\([^']+\\)/'" nil t)
 926         (setq score (match-string 1)
 927               artno (match-string 2)
 928               dirnam (match-string 3))
 929         (unless (string-match prefix dirnam)
 930           (nnheader-report 'nnir "Dir name %s doesn't contain prefix %s"
 931                            dirnam prefix))
 932         (setq group (gnus-replace-in-string
 933                      (replace-match "" t t dirnam) "/" "."))
 934         (push (vector (nnir-group-full-name group server)
 935                       (string-to-number artno)
 936                       (string-to-number score))
 937               artlist))
 938       (message "Massaging waissearch output...done")
 939       (apply 'vector
 940              (sort artlist
 941                    (function (lambda (x y)
 942                                (> (nnir-artitem-rsv x)
 943                                   (nnir-artitem-rsv y)))))))))
 944
 945 ;; IMAP interface.
 946 ;; todo:
 947 ;; nnir invokes this two (2) times???!
 948 ;; we should not use nnimap at all but open our own server connection
 949 ;; we should not LIST * but use nnimap-list-pattern from defs
 950 ;; send queries as literals
 951 ;; handle errors
 952
 953 (autoload 'nnimap-open-server "nnimap")
 954 (defvar nnimap-server-buffer) ;; nnimap.el
 955 (autoload 'imap-mailbox-select "imap")
 956 (autoload 'imap-search "imap")
 957 (autoload 'imap-quote-specials "imap")
 958
 959 (defun nnir-run-imap (query srv &optional group-option)
 960   "Run a search against an IMAP back-end server.
 961 This uses a custom query language parser; see `nnir-imap-make-query' for
 962 details on the language and supported extensions"
 963   (save-excursion
 964     (let ((qstring (cdr (assq 'query query)))
 965           (server (cadr (gnus-server-to-method srv)))
 966           (group (or group-option (gnus-group-group-name)))
 967           (defs (caddr (gnus-server-to-method srv)))
 968           (criteria (or (cdr (assq 'criteria query))
 969                         nnir-imap-search-field))
 970           artlist buf)
 971       (message "Opening server %s" server)
 972       (condition-case ()
 973           (when (nnimap-open-server server defs) ;; xxx
 974             (setq buf nnimap-server-buffer) ;; xxx
 975             (message "Searching %s..." group)
 976             (let ((arts 0)
 977                   (mbx (gnus-group-real-name group)))
 978               (when (imap-mailbox-select mbx nil buf)
 979                 (mapc
 980                  (lambda (artnum)
 981                    (push (vector group artnum 1) artlist)
 982                    (setq arts (1+ arts)))
 983                  (imap-search (nnir-imap-make-query criteria qstring) buf))
 984                 (message "Searching %s... %d matches" mbx arts)))
 985             (message "Searching %s...done" group))
 986         (quit nil))
 987       (reverse artlist))))
 988
 989 (defun nnir-imap-make-query (criteria qstring)
 990   "Parse the query string and criteria into an appropriate IMAP search
 991 expression, returning the string query to make.
 992
 993 This implements a little language designed to return the expected results
 994 to an arbitrary query string to the end user.
 995
 996 The search is always case-insensitive, as defined by RFC2060, and supports
 997 the following features (inspired by the Google search input language):
 998
 999 Automatic \"and\" queries
1000     If you specify multiple words then they will be treated as an \"and\"
1001     expression intended to match all components.
1002
1003 Phrase searches
1004     If you wrap your query in double-quotes then it will be treated as a
1005     literal string.
1006
1007 Negative terms
1008     If you precede a term with \"-\" then it will negate that.
1009
1010 \"OR\" queries
1011     If you include an upper-case \"OR\" in your search it will cause the
1012     term before it and the term after it to be treated as alternatives.
1013
1014 In future the following will be added to the language:
1015  * support for date matches
1016  * support for location of text matching within the query
1017  * from/to/etc headers
1018  * additional search terms
1019  * flag based searching
1020  * anything else that the RFC supports, basically."
1021   ;; Walk through the query and turn it into an IMAP query string.
1022   (nnir-imap-query-to-imap criteria (nnir-imap-parse-query qstring)))
1023
1024
1025 (defun nnir-imap-query-to-imap (criteria query)
1026   "Turn a s-expression format query into IMAP."
1027   (mapconcat
1028    ;; Turn the expressions into IMAP text
1029    (lambda (item)
1030      (nnir-imap-expr-to-imap criteria item))
1031    ;; The query, already in s-expr format.
1032    query
1033    ;; Append a space between each expression
1034    " "))
1035
1036
1037 (defun nnir-imap-expr-to-imap (criteria expr)
1038   "Convert EXPR into an IMAP search expression on CRITERIA"
1039   ;; What sort of expression is this, eh?
1040   (cond
1041    ;; Simple string term
1042    ((stringp expr)
1043     (format "%s \"%s\"" criteria (imap-quote-specials expr)))
1044    ;; Trivial term: and
1045    ((eq expr 'and) nil)
1046    ;; Composite term: or expression
1047    ((eq (car-safe expr) 'or)
1048     (format "OR %s %s"
1049             (nnir-imap-expr-to-imap criteria (second expr))
1050             (nnir-imap-expr-to-imap criteria (third expr))))
1051    ;; Composite term: just the fax, mam
1052    ((eq (car-safe expr) 'not)
1053     (format "NOT (%s)" (nnir-imap-query-to-imap criteria (rest expr))))
1054    ;; Composite term: just expand it all.
1055    ((and (not (null expr)) (listp expr))
1056     (format "(%s)" (nnir-imap-query-to-imap criteria expr)))
1057    ;; Complex value, give up for now.
1058    (t (error "Unhandled input: %S" expr))))
1059
1060
1061 (defun nnir-imap-parse-query (string)
1062   "Turn STRING into an s-expression based query based on the IMAP
1063 query language as defined in `nnir-imap-make-query'.
1064
1065 This involves turning individual tokens into higher level terms
1066 that the search language can then understand and use."
1067   (with-temp-buffer
1068     ;; Set up the parsing environment.
1069     (insert string)
1070     (goto-char (point-min))
1071     ;; Now, collect the output terms and return them.
1072     (let (out)
1073       (while (not (nnir-imap-end-of-input))
1074         (push (nnir-imap-next-expr) out))
1075       (reverse out))))
1076
1077
1078 (defun nnir-imap-next-expr (&optional count)
1079   "Return the next expression from the current buffer."
1080   (let ((term (nnir-imap-next-term count))
1081         (next (nnir-imap-peek-symbol)))
1082     ;; Are we looking at an 'or' expression?
1083     (cond
1084      ;; Handle 'expr or expr'
1085      ((eq next 'or)
1086       (list 'or term (nnir-imap-next-expr 2)))
1087      ;; Anything else
1088      (t term))))
1089
1090
1091 (defun nnir-imap-next-term (&optional count)
1092   "Return the next TERM from the current buffer."
1093   (let ((term (nnir-imap-next-symbol count)))
1094     ;; What sort of term is this?
1095     (cond
1096      ;; and -- just ignore it
1097      ((eq term 'and) 'and)
1098      ;; negated term
1099      ((eq term 'not) (list 'not (nnir-imap-next-expr)))
1100      ;; generic term
1101      (t term))))
1102
1103
1104 (defun nnir-imap-peek-symbol ()
1105   "Return the next symbol from the current buffer, but don't consume it."
1106   (save-excursion
1107     (nnir-imap-next-symbol)))
1108
1109 (defun nnir-imap-next-symbol (&optional count)
1110   "Return the next symbol from the current buffer, or nil if we are
1111 at the end of the buffer.  If supplied COUNT skips some symbols before
1112 returning the one at the supplied position."
1113   (when (and (numberp count) (> count 1))
1114     (nnir-imap-next-symbol (1- count)))
1115   (let ((case-fold-search t))
1116     ;; end of input stream?
1117     (unless (nnir-imap-end-of-input)
1118       ;; No, return the next symbol from the stream.
1119       (cond
1120        ;; negated expression -- return it and advance one char.
1121        ((looking-at "-") (forward-char 1) 'not)
1122        ;; quoted string
1123        ((looking-at "\"") (nnir-imap-delimited-string "\""))
1124        ;; list expression -- we parse the content and return this as a list.
1125        ((looking-at "(")
1126         (nnir-imap-parse-query (nnir-imap-delimited-string ")")))
1127        ;; keyword input -- return a symbol version
1128        ((looking-at "\\band\\b") (forward-char 3) 'and)
1129        ((looking-at "\\bor\\b")  (forward-char 2) 'or)
1130        ((looking-at "\\bnot\\b") (forward-char 3) 'not)
1131        ;; Simple, boring keyword
1132        (t (let ((start (point))
1133                 (end (if (search-forward-regexp "[[:blank:]]" nil t)
1134                          (prog1
1135                              (match-beginning 0)
1136                            ;; unskip if we hit a non-blank terminal character.
1137                            (when (string-match "[^[:blank:]]" (match-string 0))
1138                              (backward-char 1)))
1139                        (goto-char (point-max)))))
1140             (buffer-substring start end)))))))
1141
1142 (defun nnir-imap-delimited-string (delimiter)
1143   "Return a delimited string from the current buffer."
1144   (let ((start (point)) end)
1145     (forward-char 1)                    ; skip the first delimiter.
1146     (while (not end)
1147       (unless (search-forward delimiter nil t)
1148         (error "Unmatched delimited input with %s in query" delimiter))
1149       (let ((here (point)))
1150         (unless (equal (buffer-substring (- here 2) (- here 1)) "\\")
1151           (setq end (point)))))
1152     (buffer-substring (1+ start) (1- end))))
1153
1154 (defun nnir-imap-end-of-input ()
1155   "Are we at the end of input?"
1156   (skip-chars-forward "[[:blank:]]")
1157   (looking-at "$"))
1158
1159
1160 ;; Swish++ interface.
1161 ;; -cc- Todo
1162 ;; Search by
1163 ;; - group
1164 ;; Sort by
1165 ;; - rank (default)
1166 ;; - article number
1167 ;; - file size
1168 ;; - group
1169 (defun nnir-run-swish++ (query server &optional group)
1170   "Run QUERY against swish++.
1171 Returns a vector of (group name, file name) pairs (also vectors,
1172 actually).
1173
1174 Tested with swish++ 4.7 on GNU/Linux and with swish++ 5.0b2 on
1175 Windows NT 4.0."
1176
1177   (when group
1178     (error "The swish++ backend cannot search specific groups"))
1179
1180   (save-excursion
1181     (let ( (qstring (cdr (assq 'query query)))
1182            (groupspec (cdr (assq 'group query)))
1183            (prefix (nnir-read-server-parm 'nnir-swish++-remove-prefix server))
1184            artlist
1185            ;; nnml-use-compressed-files might be any string, but probably this
1186            ;; is sufficient.  Note that we can't only use the value of
1187            ;; nnml-use-compressed-files because old articles might have been
1188            ;; saved with a different value.
1189            (article-pattern (if (string= server "nnmaildir:")
1190                                 ":[0-9]+"
1191                               "^[0-9]+\\(\\.[a-z0-9]+\\)?$"))
1192            score artno dirnam filenam)
1193
1194       (when (equal "" qstring)
1195         (error "swish++: You didn't enter anything"))
1196
1197       (set-buffer (get-buffer-create nnir-tmp-buffer))
1198       (erase-buffer)
1199
1200       (if groupspec
1201           (message "Doing swish++ query %s on %s..." qstring groupspec)
1202         (message "Doing swish++ query %s..." qstring))
1203
1204       (let* ((cp-list `( ,nnir-swish++-program
1205                          nil            ; input from /dev/null
1206                          t              ; output
1207                          nil            ; don't redisplay
1208                          "--config-file" ,(nnir-read-server-parm 'nnir-swish++-configuration-file server)
1209                          ,@(nnir-read-server-parm 'nnir-swish++-additional-switches server)
1210                          ,qstring       ; the query, in swish++ format
1211                          ))
1212              (exitstatus
1213               (progn
1214                 (message "%s args: %s" nnir-swish++-program
1215                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1216                 (apply 'call-process cp-list))))
1217         (unless (or (null exitstatus)
1218                     (zerop exitstatus))
1219           (nnheader-report 'nnir "Couldn't run swish++: %s" exitstatus)
1220           ;; swish++ failure reason is in this buffer, show it if
1221           ;; the user wants it.
1222           (when (> gnus-verbose 6)
1223             (display-buffer nnir-tmp-buffer))))
1224
1225       ;; The results are output in the format of:
1226       ;; V 4.7 Linux
1227       ;; rank relative-path-name file-size file-title
1228       ;; V 5.0b2:
1229       ;; rank relative-path-name file-size topic??
1230       ;; where rank is an integer from 1 to 100.
1231       (goto-char (point-min))
1232       (while (re-search-forward
1233               "\\(^[0-9]+\\) \\([^ ]+\\) [0-9]+ \\(.*\\)$" nil t)
1234         (setq score (match-string 1)
1235               filenam (match-string 2)
1236               artno (file-name-nondirectory filenam)
1237               dirnam (file-name-directory filenam))
1238
1239         ;; don't match directories
1240         (when (string-match article-pattern artno)
1241           (when (not (null dirnam))
1242
1243             ;; maybe limit results to matching groups.
1244             (when (or (not groupspec)
1245                       (string-match groupspec dirnam))
1246               (nnir-add-result dirnam artno score prefix server artlist)))))
1247
1248       (message "Massaging swish++ output...done")
1249
1250       ;; Sort by score
1251       (apply 'vector
1252              (sort artlist
1253                    (function (lambda (x y)
1254                                (> (nnir-artitem-rsv x)
1255                                   (nnir-artitem-rsv y)))))))))
1256
1257 ;; Swish-E interface.
1258 (defun nnir-run-swish-e (query server &optional group)
1259   "Run given query against swish-e.
1260 Returns a vector of (group name, file name) pairs (also vectors,
1261 actually).
1262
1263 Tested with swish-e-2.0.1 on Windows NT 4.0."
1264
1265   ;; swish-e crashes with empty parameter to "-w" on commandline...
1266   (when group
1267     (error "The swish-e backend cannot search specific groups"))
1268
1269   (save-excursion
1270     (let ((qstring (cdr (assq 'query query)))
1271           (prefix
1272            (or (nnir-read-server-parm 'nnir-swish-e-remove-prefix server)
1273                (error "Missing parameter `nnir-swish-e-remove-prefix'")))
1274           artlist score artno dirnam group )
1275
1276       (when (equal "" qstring)
1277         (error "swish-e: You didn't enter anything"))
1278
1279       (set-buffer (get-buffer-create nnir-tmp-buffer))
1280       (erase-buffer)
1281
1282       (message "Doing swish-e query %s..." query)
1283       (let* ((index-files
1284               (or (nnir-read-server-parm
1285                    'nnir-swish-e-index-files server)
1286                   (error "Missing parameter `nnir-swish-e-index-files'")))
1287              (additional-switches
1288               (nnir-read-server-parm
1289                'nnir-swish-e-additional-switches server))
1290              (cp-list `(,nnir-swish-e-program
1291                         nil             ; input from /dev/null
1292                         t               ; output
1293                         nil             ; don't redisplay
1294                         "-f" ,@index-files
1295                         ,@additional-switches
1296                         "-w"
1297                         ,qstring        ; the query, in swish-e format
1298                         ))
1299              (exitstatus
1300               (progn
1301                 (message "%s args: %s" nnir-swish-e-program
1302                          (mapconcat 'identity (cddddr cp-list) " "))
1303                 (apply 'call-process cp-list))))
1304         (unless (or (null exitstatus)
1305                     (zerop exitstatus))
1306           (nnheader-report 'nnir "Couldn't run swish-e: %s" exitstatus)
1307           ;; swish-e failure reason is in this buffer, show it if
1308           ;; the user wants it.
1309           (when (> gnus-verbose 6)
1310             (display-buffer nnir-tmp-buffer))))
1311
1312       ;; The results are output in the format of:
1313       ;; rank path-name file-title file-size
1314       (goto-char (point-min))
1315       (while (re-search-forward
1316               "\\(^[0-9]+\\) \\([^ ]+\\) \"\\([^\"]+\\)\" [0-9]+$" nil t)
1317         (setq score (match-string 1)
1318               artno (match-string 3)
1319               dirnam (file-name-directory (match-string 2)))
1320
1321         ;; don't match directories
1322         (when (string-match "^[0-9]+$" artno)
1323           (when (not (null dirnam))
1324
1325             ;; remove nnir-swish-e-remove-prefix from beginning of dirname
1326             (when (string-match (concat "^" prefix) dirnam)
1327               (setq dirnam (replace-match "" t t dirnam)))
1328
1329             (setq dirnam (substring dirnam 0 -1))
1330             ;; eliminate all ".", "/", "\" from beginning. Always matches.
1331             (string-match "^[./\\]*\\(.*\\)$" dirnam)
1332             ;; "/" -> "."
1333             (setq group (gnus-replace-in-string (match-string 1 dirnam) "/" "."))
1334             ;; Windows "\\" -> "."
1335             (setq group (gnus-replace-in-string group "\\\\" "."))
1336
1337             (push (vector (nnir-group-full-name group server)
1338                           (string-to-number artno)
1339                           (string-to-number score))
1340                   artlist))))
1341
1342       (message "Massaging swish-e output...done")
1343
1344       ;; Sort by score
1345       (apply 'vector
1346              (sort artlist
1347                    (function (lambda (x y)
1348                                (> (nnir-artitem-rsv x)
1349                                   (nnir-artitem-rsv y)))))))))
1350
1351 ;; HyREX interface
1352 (defun nnir-run-hyrex (query server &optional group)
1353   (save-excursion
1354     (let ((artlist nil)
1355           (groupspec (cdr (assq 'group query)))
1356           (qstring (cdr (assq 'query query)))
1357           (prefix (nnir-read-server-parm 'nnir-hyrex-remove-prefix server))
1358           score artno dirnam)
1359       (when (and group groupspec)
1360         (error (concat "It does not make sense to use a group spec"
1361                        " with process-marked groups.")))
1362       (when group
1363         (setq groupspec (gnus-group-real-name group)))
1364       (when (and group (not (equal group (nnir-group-full-name groupspec server))))
1365         (message "%s vs. %s" group (nnir-group-full-name groupspec server))
1366         (error "Server with groupspec doesn't match group !"))
1367       (set-buffer (get-buffer-create nnir-tmp-buffer))
1368       (erase-buffer)
1369       (if groupspec
1370           (message "Doing hyrex-search query %s on %s..." query groupspec)
1371         (message "Doing hyrex-search query %s..." query))
1372       (let* ((cp-list
1373               `( ,nnir-hyrex-program
1374                  nil                    ; input from /dev/null
1375                  t                      ; output
1376                  nil                    ; don't redisplay
1377                  "-i",(nnir-read-server-parm 'nnir-hyrex-index-directory server) ; index directory
1378                  ,@(nnir-read-server-parm 'nnir-hyrex-additional-switches server)
1379                  ,qstring          ; the query, in hyrex-search format
1380                  ))
1381              (exitstatus
1382               (progn
1383                 (message "%s args: %s" nnir-hyrex-program
1384                          (mapconcat 'identity (cddddr cp-list) " "))
1385                 (apply 'call-process cp-list))))
1386         (unless (or (null exitstatus)
1387                     (zerop exitstatus))
1388           (nnheader-report 'nnir "Couldn't run hyrex-search: %s" exitstatus)
1389           ;; nnir-search failure reason is in this buffer, show it if
1390           ;; the user wants it.
1391           (when (> gnus-verbose 6)
1392             (display-buffer nnir-tmp-buffer)))) ;; FIXME: Dont clear buffer !
1393       (if groupspec
1394           (message "Doing hyrex-search query \"%s\" on %s...done" qstring groupspec)
1395         (message "Doing hyrex-search query \"%s\"...done" qstring))
1396       (sit-for 0)
1397       ;; nnir-search returns:
1398       ;;   for nnml/nnfolder: "filename mailid weigth"
1399       ;;   for nnimap:        "group mailid weigth"
1400       (goto-char (point-min))
1401       (delete-non-matching-lines "^\\S + [0-9]+ [0-9]+$")
1402       ;; HyREX couldn't search directly in groups -- so filter out here.
1403       (when groupspec
1404         (keep-lines groupspec))
1405       ;; extract data from result lines
1406       (goto-char (point-min))
1407       (while (re-search-forward
1408               "\\(\\S +\\) \\([0-9]+\\) \\([0-9]+\\)" nil t)
1409         (setq dirnam (match-string 1)
1410               artno (match-string 2)
1411               score (match-string 3))
1412         (when (string-match prefix dirnam)
1413           (setq dirnam (replace-match "" t t dirnam)))
1414         (push (vector (nnir-group-full-name
1415                        (gnus-replace-in-string dirnam "/" ".") server)
1416                       (string-to-number artno)
1417                       (string-to-number score))
1418               artlist))
1419       (message "Massaging hyrex-search output...done.")
1420       (apply 'vector
1421              (sort artlist
1422                    (function (lambda (x y)
1423                                (if (string-lessp (nnir-artitem-group x)
1424                                                  (nnir-artitem-group y))
1425                                    t
1426                                  (< (nnir-artitem-number x)
1427                                     (nnir-artitem-number y)))))))
1428       )))
1429
1430 ;; Namazu interface
1431 (defun nnir-run-namazu (query server &optional group)
1432   "Run given query against Namazu.  Returns a vector of (group name, file name)
1433 pairs (also vectors, actually).
1434
1435 Tested with Namazu 2.0.6 on a GNU/Linux system."
1436   (when group
1437     (error "The Namazu backend cannot search specific groups"))
1438   (save-excursion
1439     (let ((article-pattern (if (string= server "nnmaildir:")
1440                                ":[0-9]+"
1441                              "^[0-9]+$"))
1442           artlist
1443           (qstring (cdr (assq 'query query)))
1444           (prefix (nnir-read-server-parm 'nnir-namazu-remove-prefix server))
1445           score group article
1446           (process-environment (copy-sequence process-environment)))
1447       (setenv "LC_MESSAGES" "C")
1448       (set-buffer (get-buffer-create nnir-tmp-buffer))
1449       (erase-buffer)
1450       (let* ((cp-list
1451               `( ,nnir-namazu-program
1452                  nil                    ; input from /dev/null
1453                  t                      ; output
1454                  nil                    ; don't redisplay
1455                  "-q"                   ; don't be verbose
1456                  "-a"                   ; show all matches
1457                  "-s"                   ; use short format
1458                  ,@(nnir-read-server-parm 'nnir-namazu-additional-switches server)
1459                  ,qstring               ; the query, in namazu format
1460                  ,(nnir-read-server-parm 'nnir-namazu-index-directory server) ; index directory
1461                  ))
1462              (exitstatus
1463               (progn
1464                 (message "%s args: %s" nnir-namazu-program
1465                          (mapconcat 'identity (cddddr cp-list) " "))
1466                 (apply 'call-process cp-list))))
1467         (unless (or (null exitstatus)
1468                     (zerop exitstatus))
1469           (nnheader-report 'nnir "Couldn't run namazu: %s" exitstatus)
1470           ;; Namazu failure reason is in this buffer, show it if
1471           ;; the user wants it.
1472           (when (> gnus-verbose 6)
1473             (display-buffer nnir-tmp-buffer))))
1474
1475       ;; Namazu output looks something like this:
1476       ;; 2. Re: Gnus agent expire broken (score: 55)
1477       ;; /home/henrik/Mail/mail/sent/1310 (4,138 bytes)
1478
1479       (goto-char (point-min))
1480       (while (re-search-forward
1481               "^\\([0-9]+\\.\\).*\\((score: \\([0-9]+\\)\\))\n\\([^ ]+\\)"
1482               nil t)
1483         (setq score (match-string 3)
1484               group (file-name-directory (match-string 4))
1485               article (file-name-nondirectory (match-string 4)))
1486
1487         ;; make sure article and group is sane
1488         (when (and (string-match article-pattern article)
1489                    (not (null group)))
1490           (nnir-add-result group article score prefix server artlist)))
1491
1492       ;; sort artlist by score
1493       (apply 'vector
1494              (sort artlist
1495                    (function (lambda (x y)
1496                                (> (nnir-artitem-rsv x)
1497                                   (nnir-artitem-rsv y)))))))))
1498
1499 (defun nnir-run-find-grep (query server &optional group)
1500   "Run find and grep to obtain matching articles."
1501   (let* ((method (gnus-server-to-method server))
1502          (sym (intern
1503                (concat (symbol-name (car method)) "-directory")))
1504          (directory (cadr (assoc sym (cddr method))))
1505          (regexp (cdr (assoc 'query query)))
1506          (grep-options (cdr (assoc 'grep-options query)))
1507          artlist)
1508     (unless directory
1509       (error "No directory found in method specification of server %s"
1510              server))
1511     (message "Searching %s using find-grep..." (or group server))
1512     (save-window-excursion
1513       (set-buffer (get-buffer-create nnir-tmp-buffer))
1514       (erase-buffer)
1515       (if (> gnus-verbose 6)
1516           (pop-to-buffer (current-buffer)))
1517       (cd directory) ; Using relative paths simplifies postprocessing.
1518       (let ((group
1519              (if (not group)
1520                  "."
1521                ;; Try accessing the group literally as well as
1522                ;; interpreting dots as directory separators so the
1523                ;; engine works with plain nnml as well as the Gnus Cache.
1524                (let ((group (gnus-group-real-name group)))
1525                  ;; Replace cl-func find-if.
1526                  (if (file-directory-p group)
1527                      group
1528                    (if (file-directory-p
1529                         (setq group (gnus-replace-in-string group "\\." "/" t)))
1530                        group))))))
1531         (unless group
1532           (error "Cannot locate directory for group"))
1533         (save-excursion
1534           (apply
1535            'call-process "find" nil t
1536            "find" group "-type" "f" "-name" "[0-9]*" "-exec"
1537            "grep"
1538            `("-l" ,@(and grep-options
1539                          (split-string grep-options "\\s-" t))
1540              "-e" ,regexp "{}" "+"))))
1541
1542       ;; Translate relative paths to group names.
1543       (while (not (eobp))
1544         (let* ((path (split-string
1545                       (buffer-substring (point) (line-end-position)) "/" t))
1546                (art (string-to-number (car (last path)))))
1547           (while (string= "." (car path))
1548             (setq path (cdr path)))
1549           (let ((group (mapconcat 'identity
1550                                   ;; Replace cl-func: (subseq path 0 -1)
1551                                   (let ((end (1- (length path)))
1552                                         res)
1553                                     (while (>= (setq end (1- end)) 0)
1554                                       (push (pop path) res))
1555                                     (nreverse res))
1556                                   ".")))
1557             (push (vector (nnir-group-full-name group server) art 0)
1558                   artlist))
1559           (forward-line 1)))
1560       (message "Searching %s using find-grep...done" (or group server))
1561       artlist)))
1562
1563 ;;; Util Code:
1564
1565 (defun nnir-read-parms (query)
1566   "Reads additional search parameters according to `nnir-engines'."
1567   (let ((parmspec (caddr (assoc nnir-search-engine nnir-engines))))
1568     (cons (cons 'query query)
1569           (mapcar 'nnir-read-parm parmspec))))
1570
1571 (defun nnir-read-parm (parmspec)
1572   "Reads a single search parameter.
1573 `parmspec' is a cons cell, the car is a symbol, the cdr is a prompt."
1574   (let ((sym (car parmspec))
1575         (prompt (cdr parmspec)))
1576     (if (listp prompt)
1577         (let* ((result (apply 'completing-read prompt))
1578                (mapping (or (assoc result nnir-imap-search-arguments)
1579                             (assoc nil nnir-imap-search-arguments))))
1580           (cons sym (format (cdr mapping) result)))
1581       (cons sym (read-string prompt)))))
1582
1583 (defun nnir-run-query (query)
1584   "Invoke appropriate search engine function (see `nnir-engines').
1585 If some groups were process-marked, run the query for each of the groups
1586 and concat the results."
1587   (let ((q (car (read-from-string query))))
1588     (if gnus-group-marked
1589         (apply 'vconcat
1590                (mapcar (lambda (x)
1591                          (let ((server (nnir-group-server x))
1592                                search-func)
1593                            (setq search-func (cadr
1594                                               (assoc
1595                                                (nnir-read-server-parm 'nnir-search-engine server) nnir-engines)))
1596                            (if search-func
1597                                (funcall search-func q server x)
1598                              nil)))
1599                        gnus-group-marked)
1600                )
1601       (apply 'vconcat
1602              (mapcar (lambda (x)
1603                        (if (and (equal (cadr x) 'ok) (not (equal (cadar x) "-ephemeral")))
1604                            (let ((server (format "%s:%s" (caar x) (cadar x)))
1605                                  search-func)
1606                              (setq search-func (cadr
1607                                                 (assoc
1608                                                  (nnir-read-server-parm 'nnir-search-engine server) nnir-engines)))
1609                              (if search-func
1610                                  (funcall search-func q server nil)
1611                                nil))
1612                          nil))
1613                      gnus-opened-servers)
1614              ))
1615     ))
1616
1617 (defun nnir-read-server-parm (key server)
1618   "Returns the parameter value of for the given server, where server is of
1619 form 'backend:name'."
1620   (let ((method (gnus-server-to-method server)))
1621     (cond ((and method (assq key (cddr method)))
1622            (nth 1 (assq key (cddr method))))
1623           ((and nnir-mail-backend
1624                 (gnus-server-equal method nnir-mail-backend))
1625            (symbol-value key))
1626           (t nil))))
1627 ;;     (if method
1628 ;;       (if (assq key (cddr method))
1629 ;;        (nth 1 (assq key (cddr method)))
1630 ;;      (symbol-value key))
1631 ;;       (symbol-value key))
1632 ;;     ))
1633
1634 (defun nnir-group-full-name (shortname server)
1635   "For the given group name, return a full Gnus group name.
1636 The Gnus backend/server information is added."
1637   (gnus-group-prefixed-name shortname (gnus-server-to-method server)))
1638
1639 (defun nnir-possibly-change-server (server)
1640   (unless (and server (nnir-server-opened server))
1641     (nnir-open-server server)))
1642
1643
1644 ;; Data type article list.
1645
1646 (defun nnir-artlist-length (artlist)
1647   "Returns number of articles in artlist."
1648   (length artlist))
1649
1650 (defun nnir-artlist-article (artlist n)
1651   "Returns from ARTLIST the Nth artitem (counting starting at 1)."
1652   (elt artlist (1- n)))
1653
1654 (defun nnir-artitem-group (artitem)
1655   "Returns the group from the ARTITEM."
1656   (elt artitem 0))
1657
1658 (defun nnir-artlist-artitem-group (artlist n)
1659   "Returns from ARTLIST the group of the Nth artitem (counting from 1)."
1660   (nnir-artitem-group (nnir-artlist-article artlist n)))
1661
1662 (defun nnir-artitem-number (artitem)
1663   "Returns the number from the ARTITEM."
1664   (elt artitem 1))
1665
1666 (defun nnir-artlist-artitem-number (artlist n)
1667   "Returns from ARTLIST the number of the Nth artitem (counting from 1)."
1668   (nnir-artitem-number (nnir-artlist-article artlist n)))
1669
1670 (defun nnir-artitem-rsv (artitem)
1671   "Returns the Retrieval Status Value (RSV, score) from the ARTITEM."
1672   (elt artitem 2))
1673
1674 (defun nnir-artlist-artitem-rsv (artlist n)
1675   "Returns from ARTLIST the Retrieval Status Value of the Nth artitem
1676 \(counting from 1)."
1677   (nnir-artitem-rsv (nnir-artlist-article artlist n)))
1678
1679 ;; unused?
1680 (defun nnir-artlist-groups (artlist)
1681   "Returns a list of all groups in the given ARTLIST."
1682   (let ((res nil)
1683         (with-dups nil))
1684     ;; from each artitem, extract group component
1685     (setq with-dups (mapcar 'nnir-artitem-group artlist))
1686     ;; remove duplicates from above
1687     (mapc (function (lambda (x) (add-to-list 'res x)))
1688             with-dups)
1689     res))
1690
1691
1692 ;; The end.
1693 (provide 'nnir)
1694
1695 ;;; nnir.el ends here