cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   6 ;;         Jim Radford <radford@robby.caltech.edu>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Todo, major things:
  29 ;;
  30 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  31 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  32 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  33 ;;   o Sieve
  34 ;;   o MIME (partial article fetches)
  35 ;;   o Split to other backends, different split rules for different
  36 ;;     servers/inboxes
  37 ;;
  38 ;; Todo, minor things:
  39 ;;
  40 ;;   o Don't require half of Gnus -- backends should be standalone
  41 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  42 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  43 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  44 ;;   o What do I do with gnus-newsgroup-*?
  45 ;;   o Tell Gnus about new groups (how can we tell?)
  46 ;;   o Respooling (fix Gnus?) (unnecessary?)
  47 ;;   o Add support for the following: (if applicable)
  48 ;;       request-list-newsgroups, request-regenerate
  49 ;;       list-active-group,
  50 ;;       request-associate-buffer, request-restore-buffer,
  51 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  52 ;;   o Support RFC2221 (Login referrals)
  53 ;;   o IMAP2BIS compatibility? (RFC2061)
  54 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  55 ;;     .newsrc.eld)
  56 ;;   o What about Gnus's article editing, can we support it?  NO!
  57 ;;   o Use \Draft to support the draft group??
  58 ;;   o Duplicate suppression
  59 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  60
  61 ;;; Code:
  62
  63 (require 'imap)
  64 (require 'nnoo)
  65 (require 'nnmail)
  66 (require 'nnheader)
  67 (require 'mm-util)
  68 (require 'gnus)
  69 (require 'gnus-range)
  70 (require 'gnus-start)
  71 (require 'gnus-int)
  72
  73 (eval-when-compile (require 'cl))
  74
  75 (nnoo-declare nnimap)
  76
  77 (defconst nnimap-version "nnimap 1.0")
  78
  79 (defgroup nnimap nil
  80   "Reading IMAP mail with Gnus."
  81   :group 'gnus)
  82
  83 (defvoo nnimap-address nil
  84   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  85
  86 (defvoo nnimap-server-port nil
  87   "Port number on physical IMAP server.
  88 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  89
  90 ;; Splitting variables
  91
  92 (defcustom nnimap-split-crosspost t
  93   "If non-nil, do crossposting if several split methods match the mail.
  94 If nil, the first match found will be used."
  95   :group 'nnimap
  96   :type 'boolean)
  97
  98 (defcustom nnimap-split-inbox nil
  99   "Name of mailbox to split mail from.
 100
 101 Mail is read from this mailbox and split according to rules in
 102 `nnimap-split-rule'.
 103
 104 This can be a string or a list of strings."
 105   :group 'nnimap
 106   :type '(choice (string)
 107                  (repeat string)))
 108
 109 (define-widget 'nnimap-strict-function 'function
 110   "This widget only matches values that are functionp.
 111
 112 Warning: This means that a value that is the symbol of a not yet
 113 loaded function will not match.  Use with care."
 114   :match 'nnimap-strict-function-match)
 115
 116 (defun nnimap-strict-function-match (widget value)
 117   "Ignoring WIDGET, match if VALUE is a function."
 118   (functionp value))
 119
 120 (defcustom nnimap-split-rule nil
 121   "Mail will be split according to these rules.
 122
 123 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 124
 125 If you'd like, for instance, one mail group for mail from the
 126 \"gnus-imap\" mailing list, one group for junk mail and leave
 127 everything else in the incoming mailbox, you could do something like
 128 this:
 129
 130 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 131                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 132
 133 As you can see, `nnimap-split-rule' is a list of lists, where the
 134 first element in each \"rule\" is the name of the IMAP mailbox (or the
 135 symbol `junk' if you want to remove the mail), and the second is a
 136 regexp that nnimap will try to match on the header to find a fit.
 137
 138 The second element can also be a function.  In that case, it will be
 139 called narrowed to the headers with the first element of the rule as
 140 the argument.  It should return a non-nil value if it thinks that the
 141 mail belongs in that group.
 142
 143 This variable can also have a function as its value, the function will
 144 be called with the headers narrowed and should return a group where it
 145 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 146
 147 To allow for different split rules on different virtual servers, and
 148 even different split rules in different inboxes on the same server,
 149 the syntax of this variable have been extended along the lines of:
 150
 151 \(setq nnimap-split-rule
 152       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 153                                   (\"junk\"    \"From:.*Simon\")))
 154         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 155         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 156                                   (\"junk\"    my-junk-func)))))
 157
 158 The virtual server name is in fact a regexp, so that the same rules
 159 may apply to several servers.  In the example, the servers
 160 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 161 the inbox string is also a regexp.  The actual splitting rules are as
 162 before, either a function, or a list with group/regexp or
 163 group/function elements."
 164   :group 'nnimap
 165   :type '(choice :tag "Rule type"
 166                  (repeat :menu-tag "Single-server"
 167                          :tag "Single-server list"
 168                          (list (string :tag "Mailbox")
 169                                (choice :tag "Predicate"
 170                                        (regexp :tag "A regexp")
 171                                        (nnimap-strict-function :tag "A function"))))
 172                  (choice :menu-tag "A function"
 173                          :tag "A function"
 174                          (function-item nnimap-split-fancy)
 175                          (function-item nnmail-split-fancy)
 176                          (nnimap-strict-function :tag "User-defined function"))
 177                  (repeat :menu-tag "Multi-server (extended)"
 178                          :tag "Multi-server list"
 179                          (list (regexp :tag "Server regexp")
 180                                (list (regexp :tag "Incoming Mailbox regexp")
 181                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 182                                              (list (string :tag "Destination mailbox")
 183                                                    (choice :tag "Predicate"
 184                                                            (regexp :tag "A Regexp")
 185                                                            (nnimap-strict-function :tag "A Function")))))))))
 186
 187 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 188   "The predicate used to find articles to split.
 189 If you use another IMAP client to peek on articles but always would
 190 like nnimap to split them once it's started, you could change this to
 191 \"UNDELETED\". Other available predicates are available in
 192 RFC2060 section 6.4.4."
 193   :group 'nnimap
 194   :type 'string)
 195
 196 (defcustom nnimap-split-fancy nil
 197   "Like the variable `nnmail-split-fancy'."
 198   :group 'nnimap
 199   :type 'sexp)
 200
 201 (defvar nnimap-split-download-body-default nil
 202   "Internal variable with default value for `nnimap-split-download-body'.")
 203
 204 (defcustom nnimap-split-download-body 'default
 205   "Whether to download entire articles during splitting.
 206 This is generally not required, and will slow things down considerably.
 207 You may need it if you want to use an advanced splitting function that
 208 analyses the body before splitting the article.
 209 If this variable is nil, bodies will not be downloaded; if this
 210 variable is the symbol `default' the default behaviour is
 211 used (which currently is nil, unless you use a statistical
 212 spam.el test); if this variable is another non-nil value bodies
 213 will be downloaded."
 214   :version "22.1"
 215   :group 'nnimap
 216   :type '(choice (const :tag "Let system decide" deault)
 217                  boolean))
 218
 219 ;; Performance / bug workaround variables
 220
 221 (defcustom nnimap-close-asynchronous t
 222   "Close mailboxes asynchronously in `nnimap-close-group'.
 223 This means that errors caught by nnimap when closing the mailbox will
 224 not prevent Gnus from updating the group status, which may be harmful.
 225 However, it increases speed."
 226   :version "22.1"
 227   :type 'boolean
 228   :group 'nnimap)
 229
 230 (defcustom nnimap-dont-close t
 231   "Never close mailboxes.
 232 This increases the speed of closing mailboxes (quiting group) but may
 233 decrease the speed of selecting another mailbox later.  Re-selecting
 234 the same mailbox will be faster though."
 235   :version "22.1"
 236   :type 'boolean
 237   :group 'nnimap)
 238
 239 (defcustom nnimap-retrieve-groups-asynchronous t
 240   "Send asynchronous STATUS commands for each mailbox before checking mail.
 241 If you have mailboxes that rarely receives mail, this speeds up new
 242 mail checking.  It works by first sending STATUS commands for each
 243 mailbox, and then only checking groups which has a modified UIDNEXT
 244 more carefully for new mail.
 245
 246 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 247 it O(n).  If p is small, then the default is probably faster."
 248   :version "22.1"
 249   :type 'boolean
 250   :group 'nnimap)
 251
 252 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 253   "Unselect mailboxes before looking for new mail in them.
 254 Some servers seem to need this under some circumstances.")
 255
 256 ;; Authorization / Privacy variables
 257
 258 (defvoo nnimap-auth-method nil
 259   "Obsolete.")
 260
 261 (defvoo nnimap-stream nil
 262   "How nnimap will connect to the server.
 263
 264 The default, nil, will try to use the \"best\" method the server can
 265 handle.
 266
 267 Change this if
 268
 269 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 270    with IMAP is suboptimal so you'll have to tell it
 271    specifically.
 272
 273 2) your server is more capable than your environment -- i.e. your
 274    server accept Kerberos login's but you haven't installed the
 275    `imtest' program or your machine isn't configured for Kerberos.
 276
 277 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 278 See also `imap-streams' and `imap-stream-alist'.")
 279
 280 (defvoo nnimap-authenticator nil
 281   "How nnimap authenticate itself to the server.
 282
 283 The default, nil, will try to use the \"best\" method the server can
 284 handle.
 285
 286 There is only one reason for fiddling with this variable, and that is
 287 if your server is more capable than your environment -- i.e. you
 288 connect to a server that accept Kerberos login's but you haven't
 289 installed the `imtest' program or your machine isn't configured for
 290 Kerberos.
 291
 292 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 293 See also `imap-authenticators' and `imap-authenticator-alist'")
 294
 295 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 296   "Directory to keep NOV cache files for nnimap groups.
 297 See also `nnimap-nov-file-name'.")
 298
 299 (defvoo nnimap-nov-file-name "nnimap."
 300   "NOV cache base filename.
 301 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 302 typical complete file name would be
 303 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 304 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 305 `nnmail-use-long-file-names' is nil")
 306
 307 (defvoo nnimap-nov-file-name-suffix ".novcache"
 308   "Suffix for NOV cache base filename.")
 309
 310 (defvoo nnimap-nov-is-evil gnus-agent
 311   "If non-nil, never generate or use a local nov database for this backend.
 312 Using nov databases should speed up header fetching considerably.
 313 However, it will invoke a UID SEARCH UID command on the server, and
 314 some servers implement this command inefficiently by opening each and
 315 every message in the group, thus making it quite slow.
 316 Unlike other backends, you do not need to take special care if you
 317 flip this variable.")
 318
 319 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 320   "Whether to expunge a group when it is closed.
 321 When a IMAP group with articles marked for deletion is closed, this
 322 variable determine if nnimap should actually remove the articles or
 323 not.
 324
 325 If always, nnimap always perform a expunge when closing the group.
 326 If never, nnimap never expunges articles marked for deletion.
 327 If ask, nnimap will ask you if you wish to expunge marked articles.
 328
 329 When setting this variable to `never', you can only expunge articles
 330 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 331
 332 (defvoo nnimap-list-pattern "*"
 333   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 334 See below for available wildcards.
 335
 336 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 337 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 338 semantics of this are server specific, on the University of Washington
 339 server you can specify a directory.
 340
 341 Example:
 342  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 343
 344 There are two wildcards * and %. * matches everything, % matches
 345 everything in the current hierarchy.")
 346
 347 (defvoo nnimap-news-groups nil
 348   "IMAP support a news-like mode, also known as bulletin board mode,
 349 where replies is sent via IMAP instead of SMTP.
 350
 351 This variable should contain a regexp matching groups where you wish
 352 replies to be stored to the mailbox directly.
 353
 354 Example:
 355   '(\"^[^I][^N][^B][^O][^X].*$\")
 356
 357 This will match all groups not beginning with \"INBOX\".
 358
 359 Note that there is nothing technically different between mail-like and
 360 news-like mailboxes.  If you wish to have a group with todo items or
 361 similar which you wouldn't want to set up a mailing list for, you can
 362 use this to make replies go directly to the group.")
 363
 364 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 365   "IMAP search command to use for articles that are to be expired.
 366 The first %s is replaced by a UID set of articles to search on,
 367 and the second %s is replaced by a date criterium.
 368
 369 One useful (and perhaps the only useful) value to change this to would
 370 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 371 instead of the internal date of messages.  See section 6.4.4 of RFC
 372 2060 for more information on valid strings.")
 373
 374 (defvoo nnimap-importantize-dormant t
 375   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 376 Note that within Gnus, dormant articles will still (only) be
 377 marked as ticked.  This is to make \"dormant\" articles stand out,
 378 just like \"ticked\" articles, in other IMAP clients.")
 379
 380 (defvoo nnimap-server-address nil
 381   "Obsolete.  Use `nnimap-address'.")
 382
 383 (defcustom nnimap-authinfo-file "~/.authinfo"
 384   "Authorization information for IMAP servers.  In .netrc format."
 385   :type
 386   '(choice file
 387            (repeat :tag "Entries"
 388                    :menu-tag "Inline"
 389                    (list :format "%v"
 390                          :value ("" ("login" . "") ("password" . ""))
 391                          (string :tag "Host")
 392                          (checklist :inline t
 393                                     (cons :format "%v"
 394                                           (const :format "" "login")
 395                                           (string :format "Login: %v"))
 396                                     (cons :format "%v"
 397                                           (const :format "" "password")
 398                                           (string :format "Password: %v"))))))
 399   :group 'nnimap)
 400
 401 (defcustom nnimap-prune-cache t
 402   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 403   :type 'boolean
 404   :group 'nnimap)
 405
 406 (defvar nnimap-request-list-method 'imap-mailbox-list
 407   "Method to use to request a list of all folders from the server.
 408 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 409 restrict visible folders.")
 410
 411 (defcustom nnimap-id nil
 412   "Plist with client identity to send to server upon login.
 413 Nil means no information is sent, symbol `no' to disable ID query
 414 alltogheter, or plist with identifier-value pairs to send to
 415 server.  RFC 2971 describes the list as follows:
 416
 417    Any string may be sent as a field, but the following are defined to
 418    describe certain values that might be sent.  Implementations are free
 419    to send none, any, or all of these.  Strings are not case-sensitive.
 420    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 421    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 422    than 30 field-value pairs.
 423
 424      name            Name of the program
 425      version         Version number of the program
 426      os              Name of the operating system
 427      os-version      Version of the operating system
 428      vendor          Vendor of the client/server
 429      support-url     URL to contact for support
 430      address         Postal address of contact/vendor
 431      date            Date program was released, specified as a date-time
 432                        in IMAP4rev1
 433      command         Command used to start the program
 434      arguments       Arguments supplied on the command line, if any
 435                        if any
 436      environment     Description of environment, i.e., UNIX environment
 437                        variables or Windows registry settings
 438
 439    Implementations MUST NOT send the same field name more than once.
 440
 441 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 442 \"os\" system-configuration \"vendor\" \"GNU\")."
 443   :group 'nnimap
 444   :type '(choice (const :tag "No information" nil)
 445                  (const :tag "Disable ID query" no)
 446                  (plist :key-type string :value-type string)))
 447
 448 (defcustom nnimap-debug nil
 449   "If non-nil, random debug spews are placed in *nnimap-debug* buffer.
 450 Note that username, passwords and other privacy sensitive
 451 information (such as e-mail) may be stored in the *nnimap-debug*
 452 buffer.  It is not written to disk, however.  Do not enable this
 453 variable unless you are comfortable with that."
 454   :group 'nnimap
 455   :type 'boolean)
 456
 457 ;; Internal variables:
 458
 459 (defvar nnimap-debug-buffer "*nnimap-debug*")
 460 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 461 (defvar nnimap-current-move-server nil)
 462 (defvar nnimap-current-move-group nil)
 463 (defvar nnimap-current-move-article nil)
 464 (defvar nnimap-length)
 465 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 466 (defvar nnimap-progress-how-often 20)
 467 (defvar nnimap-counter)
 468 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 469 (defvar nnimap-current-server nil) ;; Current server
 470 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 471
 472 \f
 473
 474 (nnoo-define-basics nnimap)
 475
 476 ;; Utility functions:
 477
 478 (defsubst nnimap-get-server-buffer (server)
 479   "Return buffer for SERVER, if nil use current server."
 480   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 481
 482 (defun nnimap-remove-server-from-buffer-alist (server list)
 483   "Remove SERVER from LIST."
 484   (let (l)
 485     (dolist (e list)
 486       (unless (equal server (car-safe e))
 487         (push e l)))
 488     l))
 489
 490 (defun nnimap-possibly-change-server (server)
 491   "Return buffer for SERVER, changing the current server as a side-effect.
 492 If SERVER is nil, uses the current server."
 493   (setq nnimap-current-server (or server nnimap-current-server)
 494         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 495
 496 (defun nnimap-verify-uidvalidity (group server)
 497   "Verify stored uidvalidity match current one in GROUP on SERVER."
 498   (let* ((gnusgroup (gnus-group-prefixed-name
 499                      group (gnus-server-to-method
 500                             (format "nnimap:%s" server))))
 501          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 502          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 503          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 504          (nameuid (nnheader-translate-file-chars
 505                    (concat nnimap-nov-file-name
 506                            (if (equal server "")
 507                                "unnamed"
 508                              server) "." group "." old-uidvalidity
 509                            nnimap-nov-file-name-suffix) t))
 510          (file (if (or nnmail-use-long-file-names
 511                        (file-exists-p (expand-file-name nameuid dir)))
 512                    (expand-file-name nameuid dir)
 513                  (expand-file-name
 514                   (mm-encode-coding-string
 515                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 516                    nnmail-pathname-coding-system)
 517                   dir))))
 518     (if old-uidvalidity
 519         (if (not (equal old-uidvalidity new-uidvalidity))
 520             ;; uidvalidity clash
 521             (gnus-delete-file file)
 522           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 523           t)
 524       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 525       t)))
 526
 527 (defun nnimap-before-find-minmax-bugworkaround ()
 528   "Function called before iterating through mailboxes with
 529 `nnimap-find-minmax-uid'."
 530   (when nnimap-need-unselect-to-notice-new-mail
 531     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 532     ;; currently selected mailbox without a re-select/examine.
 533     (or (null (imap-current-mailbox nnimap-server-buffer))
 534         (imap-mailbox-unselect nnimap-server-buffer))))
 535
 536 (defun nnimap-find-minmax-uid (group &optional examine)
 537   "Find lowest and highest active article number in GROUP.
 538 If EXAMINE is non-nil the group is selected read-only."
 539   (with-current-buffer nnimap-server-buffer
 540     (when (or (string= group (imap-current-mailbox))
 541               (imap-mailbox-select group examine))
 542       (let (minuid maxuid)
 543         (when (> (imap-mailbox-get 'exists) 0)
 544           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 545           (imap-message-map (lambda (uid Uid)
 546                               (setq minuid (if minuid (min minuid uid) uid)
 547                                     maxuid (if maxuid (max maxuid uid) uid)))
 548                             'UID))
 549         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 550
 551 (defun nnimap-possibly-change-group (group &optional server)
 552   "Make GROUP the current group, and SERVER the current server."
 553   (when (nnimap-possibly-change-server server)
 554     (with-current-buffer nnimap-server-buffer
 555       (if (or (null group) (imap-current-mailbox-p group))
 556           imap-current-mailbox
 557         (if (imap-mailbox-select group)
 558             (if (or (nnimap-verify-uidvalidity
 559                      group (or server nnimap-current-server))
 560                     (zerop (imap-mailbox-get 'exists group))
 561                     t ;; for OGnus to see if ignoring uidvalidity
 562                     ;; changes has any bad effects.
 563                     (yes-or-no-p
 564                      (format
 565                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 566                 imap-current-mailbox
 567               (imap-mailbox-unselect)
 568               (error "nnimap: Group %s is not uid-valid" group))
 569           (nnheader-report 'nnimap (imap-error-text)))))))
 570
 571 (defun nnimap-replace-whitespace (string)
 572   "Return STRING with all whitespace replaced with space."
 573   (when string
 574     (while (string-match "[\r\n\t]+" string)
 575       (setq string (replace-match " " t t string)))
 576     string))
 577
 578 ;; Required backend functions
 579
 580 (defun nnimap-retrieve-headers-progress ()
 581   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 582   (and (numberp nnmail-large-newsgroup)
 583        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 584        (> nnimap-length nnmail-large-newsgroup)
 585        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 586                          (nth (/ (% nnimap-counter
 587                                     (* (length nnimap-progress-chars)
 588                                        nnimap-progress-how-often))
 589                                  nnimap-progress-how-often)
 590                               nnimap-progress-chars)))
 591   (with-current-buffer nntp-server-buffer
 592     (let (headers lines chars uid mbx)
 593       (with-current-buffer nnimap-server-buffer
 594         (setq uid imap-current-message
 595               mbx imap-current-mailbox
 596               headers (nnimap-demule
 597                        (if (imap-capability 'IMAP4rev1)
 598                            ;; xxx don't just use car? alist doesn't contain
 599                            ;; anything else now, but it might...
 600                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 601                          (imap-message-get uid 'RFC822.HEADER)))
 602               lines (imap-body-lines (imap-message-body imap-current-message))
 603               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 604       (nnheader-insert-nov
 605        (with-temp-buffer
 606          (buffer-disable-undo)
 607          (insert headers)
 608          (let ((head (nnheader-parse-naked-head uid)))
 609            (mail-header-set-number head uid)
 610            (mail-header-set-chars head chars)
 611            (mail-header-set-lines head lines)
 612            (mail-header-set-xref
 613             head (format "%s %s:%d" (system-name) mbx uid))
 614            head))))))
 615
 616 (defun nnimap-retrieve-which-headers (articles fetch-old)
 617   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 618   (with-current-buffer nnimap-server-buffer
 619     (if (numberp (car-safe articles))
 620         (imap-search
 621          (concat "UID "
 622                  (imap-range-to-message-set
 623                   (gnus-compress-sequence
 624                    (append (gnus-uncompress-sequence
 625                             (and fetch-old
 626                                  (cons (if (numberp fetch-old)
 627                                            (max 1 (- (car articles) fetch-old))
 628                                          1)
 629                                        (1- (car articles)))))
 630                            articles)))))
 631       (mapcar (lambda (msgid)
 632                 (imap-search
 633                  (format "HEADER Message-Id \"%s\"" msgid)))
 634               articles))))
 635
 636 (defun nnimap-group-overview-filename (group server)
 637   "Make file name for GROUP on SERVER."
 638   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 639          (uidvalidity (gnus-group-get-parameter
 640                        (gnus-group-prefixed-name
 641                         group (gnus-server-to-method
 642                                (format "nnimap:%s" server)))
 643                        'uidvalidity))
 644          (name (nnheader-translate-file-chars
 645                 (concat nnimap-nov-file-name
 646                         (if (equal server "")
 647                             "unnamed"
 648                           server) "." group nnimap-nov-file-name-suffix) t))
 649          (nameuid (nnheader-translate-file-chars
 650                    (concat nnimap-nov-file-name
 651                            (if (equal server "")
 652                                "unnamed"
 653                              server) "." group "." uidvalidity
 654                            nnimap-nov-file-name-suffix) t))
 655          (oldfile (if (or nnmail-use-long-file-names
 656                           (file-exists-p (expand-file-name name dir)))
 657                       (expand-file-name name dir)
 658                     (expand-file-name
 659                      (mm-encode-coding-string
 660                       (nnheader-replace-chars-in-string name ?. ?/)
 661                       nnmail-pathname-coding-system)
 662                      dir)))
 663          (newfile (if (or nnmail-use-long-file-names
 664                           (file-exists-p (expand-file-name nameuid dir)))
 665                       (expand-file-name nameuid dir)
 666                     (expand-file-name
 667                      (mm-encode-coding-string
 668                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 669                       nnmail-pathname-coding-system)
 670                      dir))))
 671     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 672       (message "nnimap: Upgrading novcache filename...")
 673       (sit-for 1)
 674       (gnus-make-directory (file-name-directory newfile))
 675       (unless (ignore-errors (rename-file oldfile newfile) t)
 676         (if (ignore-errors (copy-file oldfile newfile) t)
 677             (delete-file oldfile)
 678           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 679     newfile))
 680
 681 (defun nnimap-retrieve-headers-from-file (group server)
 682   (with-current-buffer nntp-server-buffer
 683     (let ((nov (nnimap-group-overview-filename group server)))
 684       (when (file-exists-p nov)
 685         (mm-insert-file-contents nov)
 686         (set-buffer-modified-p nil)
 687         (let ((min (ignore-errors (goto-char (point-min))
 688                                   (read (current-buffer))))
 689               (max (ignore-errors (goto-char (point-max))
 690                                   (forward-line -1)
 691                                   (read (current-buffer)))))
 692           (if (and (numberp min) (numberp max))
 693               (cons min max)
 694             ;; junk, remove it, it's saved later
 695             (erase-buffer)
 696             nil))))))
 697
 698 (defun nnimap-retrieve-headers-from-server (articles group server)
 699   (with-current-buffer nnimap-server-buffer
 700     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 701           (nnimap-length (gnus-range-length articles))
 702           (nnimap-counter 0))
 703       (imap-fetch (imap-range-to-message-set articles)
 704                   (concat "(UID RFC822.SIZE BODY "
 705                           (let ((headers
 706                                  (append '(Subject From Date Message-Id
 707                                                    References In-Reply-To Xref)
 708                                          (copy-sequence
 709                                           nnmail-extra-headers))))
 710                             (if (imap-capability 'IMAP4rev1)
 711                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 712                               (format "RFC822.HEADER.LINES %s)" headers)))))
 713       (with-current-buffer nntp-server-buffer
 714         (sort-numeric-fields 1 (point-min) (point-max)))
 715       (and (numberp nnmail-large-newsgroup)
 716            (> nnimap-length nnmail-large-newsgroup)
 717            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 718
 719 (defun nnimap-dont-use-nov-p (group server)
 720   (or gnus-nov-is-evil nnimap-nov-is-evil
 721       (unless (and (gnus-make-directory
 722                     (file-name-directory
 723                      (nnimap-group-overview-filename group server)))
 724                    (file-writable-p
 725                     (nnimap-group-overview-filename group server)))
 726         (message "nnimap: Nov cache not writable, %s"
 727                  (nnimap-group-overview-filename group server)))))
 728
 729 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 730   (when (nnimap-possibly-change-group group server)
 731     (with-current-buffer nntp-server-buffer
 732       (erase-buffer)
 733       (if (nnimap-dont-use-nov-p group server)
 734           (nnimap-retrieve-headers-from-server
 735            (gnus-compress-sequence articles) group server)
 736         (let (uids cached low high)
 737           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 738                       low (car uids)
 739                       high (car (last uids)))
 740             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 741                 (progn
 742                   ;; fetch articles with uids before cache block
 743                   (when (< low (car cached))
 744                     (goto-char (point-min))
 745                     (nnimap-retrieve-headers-from-server
 746                      (cons low (1- (car cached))) group server))
 747                   ;; fetch articles with uids after cache block
 748                   (when (> high (cdr cached))
 749                     (goto-char (point-max))
 750                     (nnimap-retrieve-headers-from-server
 751                      (cons (1+ (cdr cached)) high) group server))
 752                   (when nnimap-prune-cache
 753                     ;; remove nov's for articles which has expired on server
 754                     (goto-char (point-min))
 755                     (dolist (uid (gnus-set-difference articles uids))
 756                       (when (re-search-forward (format "^%d\t" uid) nil t)
 757                         (gnus-delete-line)))))
 758               ;; nothing cached, fetch whole range from server
 759               (nnimap-retrieve-headers-from-server
 760                (cons low high) group server))
 761             (when (buffer-modified-p)
 762               (nnmail-write-region
 763                (point-min) (point-max)
 764                (nnimap-group-overview-filename group server) nil 'nomesg))
 765             (nnheader-nov-delete-outside-range low high))))
 766       'nov)))
 767
 768 (defun nnimap-open-connection (server)
 769   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 770                       nnimap-authenticator nnimap-server-buffer))
 771       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 772     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 773                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 774       (imap-close nnimap-server-buffer)
 775       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 776     (let* ((list (netrc-parse nnimap-authinfo-file))
 777            (port (if nnimap-server-port
 778                      (int-to-string nnimap-server-port)
 779                    "imap"))
 780            (user (netrc-machine-user-or-password
 781                   "login"
 782                   list
 783                   (list server
 784                         (or nnimap-server-address
 785                             nnimap-address))
 786                   (list port)
 787                   (list "imap" "imaps")))
 788            (passwd (netrc-machine-user-or-password
 789                     "password"
 790                     list
 791                     (list server
 792                           (or nnimap-server-address
 793                               nnimap-address))
 794                     (list port)
 795                     (list "imap" "imaps"))))
 796       (if (imap-authenticate user passwd nnimap-server-buffer)
 797           (prog2
 798               (setq nnimap-server-buffer-alist
 799                     (nnimap-remove-server-from-buffer-alist
 800                      server
 801                      nnimap-server-buffer-alist))
 802               (push (list server nnimap-server-buffer)
 803                     nnimap-server-buffer-alist)
 804             (imap-id nnimap-id nnimap-server-buffer)
 805             (nnimap-possibly-change-server server))
 806         (imap-close nnimap-server-buffer)
 807         (kill-buffer nnimap-server-buffer)
 808         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 809
 810 (deffoo nnimap-open-server (server &optional defs)
 811   (nnheader-init-server-buffer)
 812   (if (nnimap-server-opened server)
 813       t
 814     (unless (assq 'nnimap-server-buffer defs)
 815       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 816     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 817     ;; for people that configured nnimap with a very old version
 818     (unless (assq 'nnimap-address defs)
 819       (if (assq 'nnimap-server-address defs)
 820           (push (list 'nnimap-address
 821                       (cadr (assq 'nnimap-server-address defs))) defs)
 822         (push (list 'nnimap-address server) defs)))
 823     (nnoo-change-server 'nnimap server defs)
 824     (or nnimap-server-buffer
 825         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 826     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 827       (nnoo-change-server 'nnimap server defs))
 828     (or (and nnimap-server-buffer
 829              (imap-opened nnimap-server-buffer)
 830              (if (with-current-buffer nnimap-server-buffer
 831                    (memq imap-state '(auth selected examine)))
 832                  t
 833                (imap-close nnimap-server-buffer)
 834                (nnimap-open-connection server)))
 835         (nnimap-open-connection server))))
 836
 837 (deffoo nnimap-server-opened (&optional server)
 838   "Whether SERVER is opened.
 839 If SERVER is the current virtual server, and the connection to the
 840 physical server is alive, this function return a non-nil value.  If
 841 SERVER is nil, it is treated as the current server."
 842   ;; clean up autologouts??
 843   (and (or server nnimap-current-server)
 844        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 845        (imap-opened (nnimap-get-server-buffer server))))
 846
 847 (deffoo nnimap-close-server (&optional server)
 848   "Close connection to server and free all resources connected to it.
 849 Return nil if the server couldn't be closed for some reason."
 850   (let ((server (or server nnimap-current-server)))
 851     (when (or (nnimap-server-opened server)
 852               (imap-opened (nnimap-get-server-buffer server)))
 853       (imap-close (nnimap-get-server-buffer server))
 854       (kill-buffer (nnimap-get-server-buffer server))
 855       (setq nnimap-server-buffer nil
 856             nnimap-current-server nil
 857             nnimap-server-buffer-alist
 858             (nnimap-remove-server-from-buffer-alist
 859              server
 860              nnimap-server-buffer-alist)))
 861     (nnoo-close-server 'nnimap server)))
 862
 863 (deffoo nnimap-request-close ()
 864   "Close connection to all servers and free all resources that the backend have reserved.
 865 All buffers that have been created by that
 866 backend should be killed.  (Not the nntp-server-buffer, though.) This
 867 function is generally only called when Gnus is shutting down."
 868   (mapc (lambda (server) (nnimap-close-server (car server)))
 869         nnimap-server-buffer-alist)
 870   (setq nnimap-server-buffer-alist nil))
 871
 872 (deffoo nnimap-status-message (&optional server)
 873   "This function returns the last error message from server."
 874   (when (nnimap-possibly-change-server server)
 875     (nnoo-status-message 'nnimap server)))
 876
 877 (defun nnimap-demule (string)
 878   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 879   ;; because it will turn accidental emacs-mule-valid byte sequences
 880   ;; into multibyte chars.  --Stef
 881   ;; Reverted, braindead got 7.5 out of 10 on imdb, so it can't be
 882   ;; that bad. --Simon
 883   (funcall (if (and (fboundp 'string-as-multibyte)
 884                     (subrp (symbol-function 'string-as-multibyte)))
 885                'string-as-multibyte
 886              'identity)
 887            (or string "")))
 888
 889 (defun nnimap-make-callback (article gnus-callback buffer)
 890   "Return a callback function."
 891   `(lambda ()
 892      (nnimap-callback ,article ,gnus-callback ,buffer)))
 893
 894 (defun nnimap-callback (article gnus-callback buffer)
 895   (when (eq article (imap-current-message))
 896     (remove-hook 'imap-fetch-data-hook
 897                  (nnimap-make-callback article gnus-callback buffer))
 898     (with-current-buffer buffer
 899       (insert
 900        (with-current-buffer nnimap-server-buffer
 901          (nnimap-demule
 902           (if (imap-capability 'IMAP4rev1)
 903               ;; xxx don't just use car? alist doesn't contain
 904               ;; anything else now, but it might...
 905               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 906             (imap-message-get article 'RFC822)))))
 907       (nnheader-ms-strip-cr)
 908       (funcall gnus-callback t))))
 909
 910 (defun nnimap-request-article-part (article part prop &optional
 911                                             group server to-buffer detail)
 912   (when (nnimap-possibly-change-group group server)
 913     (let ((article (if (stringp article)
 914                        (car-safe (imap-search
 915                                   (format "HEADER Message-Id \"%s\"" article)
 916                                   nnimap-server-buffer))
 917                      article)))
 918       (when article
 919         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 920                       article (or group imap-current-mailbox
 921                                   gnus-newsgroup-name))
 922         (if (not nnheader-callback-function)
 923             (with-current-buffer (or to-buffer nntp-server-buffer)
 924               (erase-buffer)
 925               (let ((data (imap-fetch article part prop nil
 926                                       nnimap-server-buffer)))
 927                 (insert (nnimap-demule (if detail
 928                                            (nth 2 (car data))
 929                                          data))))
 930               (nnheader-ms-strip-cr)
 931               (gnus-message
 932                10 "nnimap: Fetching (part of) article %d from %s...done"
 933                article (or group imap-current-mailbox gnus-newsgroup-name))
 934               (if (bobp)
 935                   (nnheader-report 'nnimap "No such article %d in %s: %s"
 936                                    article (or group imap-current-mailbox
 937                                                gnus-newsgroup-name)
 938                                    (imap-error-text nnimap-server-buffer))
 939                 (cons group article)))
 940           (add-hook 'imap-fetch-data-hook
 941                     (nnimap-make-callback article
 942                                           nnheader-callback-function
 943                                           nntp-server-buffer))
 944           (imap-fetch-asynch article part nil nnimap-server-buffer)
 945           (cons group article))))))
 946
 947 (deffoo nnimap-asynchronous-p ()
 948   t)
 949
 950 (deffoo nnimap-request-article (article &optional group server to-buffer)
 951   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 952       (nnimap-request-article-part
 953        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 954     (nnimap-request-article-part
 955      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 956
 957 (deffoo nnimap-request-head (article &optional group server to-buffer)
 958   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 959       (nnimap-request-article-part
 960        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 961     (nnimap-request-article-part
 962      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 963
 964 (deffoo nnimap-request-body (article &optional group server to-buffer)
 965   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 966       (nnimap-request-article-part
 967        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 968     (nnimap-request-article-part
 969      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 970
 971 (deffoo nnimap-request-group (group &optional server fast)
 972   (nnimap-request-update-info-internal
 973    group
 974    (gnus-get-info (gnus-group-prefixed-name
 975                    group (gnus-server-to-method (format "nnimap:%s" server))))
 976    server)
 977   (when (nnimap-possibly-change-group group server)
 978     (nnimap-before-find-minmax-bugworkaround)
 979     (let (info)
 980       (cond (fast group)
 981             ((null (setq info (nnimap-find-minmax-uid group t)))
 982              (nnheader-report 'nnimap "Could not get active info for %s"
 983                               group))
 984             (t
 985              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 986                               (max 1 (or (nth 1 info) 1))
 987                               (or (nth 2 info) 0) group)
 988              (nnheader-report 'nnimap "Group %s selected" group)
 989              t)))))
 990
 991 (defun nnimap-update-unseen (group &optional server)
 992   "Update the unseen count in `nnimap-mailbox-info'."
 993   (gnus-sethash
 994    (gnus-group-prefixed-name group server)
 995    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 996                                  nnimap-mailbox-info)))
 997      (list (nth 0 old) (nth 1 old)
 998            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 999            (nth 3 old)))
1000    nnimap-mailbox-info))
1001
1002 (defun nnimap-close-group (group &optional server)
1003   (with-current-buffer nnimap-server-buffer
1004     (when (and (imap-opened)
1005                (nnimap-possibly-change-group group server))
1006       (nnimap-update-unseen group server)
1007       (case nnimap-expunge-on-close
1008         (always (progn
1009                   (imap-mailbox-expunge nnimap-close-asynchronous)
1010                   (unless nnimap-dont-close
1011                     (imap-mailbox-close nnimap-close-asynchronous))))
1012         (ask (if (and (imap-search "DELETED")
1013                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
1014                                              imap-current-mailbox)))
1015                  (progn
1016                    (imap-mailbox-expunge nnimap-close-asynchronous)
1017                    (unless nnimap-dont-close
1018                      (imap-mailbox-close nnimap-close-asynchronous)))
1019                (imap-mailbox-unselect)))
1020         (t (imap-mailbox-unselect)))
1021       (not imap-current-mailbox))))
1022
1023 (defun nnimap-pattern-to-list-arguments (pattern)
1024   (mapcar (lambda (p)
1025             (cons (car-safe p) (or (cdr-safe p) p)))
1026           (if (and (listp pattern)
1027                    (listp (cdr pattern)))
1028               pattern
1029             (list pattern))))
1030
1031 (deffoo nnimap-request-list (&optional server)
1032   (when (nnimap-possibly-change-server server)
1033     (with-current-buffer nntp-server-buffer
1034       (erase-buffer))
1035     (gnus-message 5 "nnimap: Generating active list%s..."
1036                   (if (> (length server) 0) (concat " for " server) ""))
1037     (nnimap-before-find-minmax-bugworkaround)
1038     (with-current-buffer nnimap-server-buffer
1039       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1040         (dolist (mbx (funcall nnimap-request-list-method
1041                               (cdr pattern) (car pattern)))
1042           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1043               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1044                 (when info
1045                   (with-current-buffer nntp-server-buffer
1046                     (insert (format "\"%s\" %d %d y\n"
1047                                     mbx (or (nth 2 info) 0)
1048                                     (max 1 (or (nth 1 info) 1)))))))))))
1049     (gnus-message 5 "nnimap: Generating active list%s...done"
1050                   (if (> (length server) 0) (concat " for " server) ""))
1051     t))
1052
1053 (deffoo nnimap-request-post (&optional server)
1054   (let ((success t))
1055     (dolist (mbx (message-unquote-tokens
1056                   (message-tokenize-header
1057                    (message-fetch-field "Newsgroups") ", ")) success)
1058       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1059         (or (gnus-active to-newsgroup)
1060             (gnus-activate-group to-newsgroup)
1061             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1062                                        to-newsgroup))
1063                 (or (and (gnus-request-create-group
1064                           to-newsgroup gnus-command-method)
1065                          (gnus-activate-group to-newsgroup nil nil
1066                                               gnus-command-method))
1067                     (error "Couldn't create group %s" to-newsgroup)))
1068             (error "No such group: %s" to-newsgroup))
1069         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1070           (setq success nil))))))
1071
1072 ;; Optional backend functions
1073
1074 (defun nnimap-string-lessp-numerical (s1 s2)
1075   "Return t if first arg string is less than second in numerical order."
1076   (cond ((string= s1 s2)
1077          nil)
1078         ((> (length s1) (length s2))
1079          nil)
1080         ((< (length s1) (length s2))
1081          t)
1082         ((< (string-to-number (substring s1 0 1))
1083             (string-to-number (substring s2 0 1)))
1084          t)
1085         ((> (string-to-number (substring s1 0 1))
1086             (string-to-number (substring s2 0 1)))
1087          nil)
1088         (t
1089          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1090
1091 (deffoo nnimap-retrieve-groups (groups &optional server)
1092   (when (nnimap-possibly-change-server server)
1093     (gnus-message 5 "nnimap: Checking mailboxes...")
1094     (with-current-buffer nntp-server-buffer
1095       (erase-buffer)
1096       (nnimap-before-find-minmax-bugworkaround)
1097       (let (asyncgroups slowgroups)
1098         (if (null nnimap-retrieve-groups-asynchronous)
1099             (setq slowgroups groups)
1100           (dolist (group groups)
1101             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1102             (add-to-list (if (gnus-gethash-safe
1103                               (gnus-group-prefixed-name group server)
1104                               nnimap-mailbox-info)
1105                              'asyncgroups
1106                            'slowgroups)
1107                          (list group (imap-mailbox-status-asynch
1108                                       group '(uidvalidity uidnext unseen)
1109                                       nnimap-server-buffer))))
1110           (dolist (asyncgroup asyncgroups)
1111             (let ((group (nth 0 asyncgroup))
1112                   (tag   (nth 1 asyncgroup))
1113                   new old)
1114               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1115                 (if (or (not (string=
1116                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1117                                                     group server)
1118                                                    nnimap-mailbox-info))
1119                               (imap-mailbox-get 'uidvalidity group
1120                                                 nnimap-server-buffer)))
1121                         (not (string=
1122                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1123                                                     group server)
1124                                                    nnimap-mailbox-info))
1125                               (imap-mailbox-get 'uidnext group
1126                                                 nnimap-server-buffer))))
1127                     (push (list group) slowgroups)
1128                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1129                                                 group server)
1130                                                nnimap-mailbox-info))))))))
1131         (dolist (group slowgroups)
1132           (if nnimap-retrieve-groups-asynchronous
1133               (setq group (car group)))
1134           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1135           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1136           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1137                                                      nnimap-server-buffer))
1138               (let* ((info (nnimap-find-minmax-uid group 'examine))
1139                      (str (format "\"%s\" %d %d y\n" group
1140                                   (or (nth 2 info) 0)
1141                                   (max 1 (or (nth 1 info) 1)))))
1142                 (when (> (or (imap-mailbox-get 'recent group
1143                                                nnimap-server-buffer) 0)
1144                          0)
1145                   (push (list (cons group 0)) nnmail-split-history))
1146                 (insert str)
1147                 (when nnimap-retrieve-groups-asynchronous
1148                   (gnus-sethash
1149                    (gnus-group-prefixed-name group server)
1150                    (list (or (imap-mailbox-get
1151                               'uidvalidity group nnimap-server-buffer)
1152                              (imap-mailbox-status
1153                               group 'uidvalidity nnimap-server-buffer))
1154                          (or (imap-mailbox-get
1155                               'uidnext group nnimap-server-buffer)
1156                              (imap-mailbox-status
1157                               group 'uidnext nnimap-server-buffer))
1158                          (or (imap-mailbox-get
1159                               'unseen group nnimap-server-buffer)
1160                              (imap-mailbox-status
1161                               group 'unseen nnimap-server-buffer))
1162                          str)
1163                    nnimap-mailbox-info)))))))
1164     (gnus-message 5 "nnimap: Checking mailboxes...done")
1165     'active))
1166
1167 (deffoo nnimap-request-update-info-internal (group info &optional server)
1168   (when (nnimap-possibly-change-group group server)
1169     (when info ;; xxx what does this mean? should we create a info?
1170       (with-current-buffer nnimap-server-buffer
1171         (gnus-message 5 "nnimap: Updating info for %s..."
1172                       (gnus-info-group info))
1173
1174         (when (nnimap-mark-permanent-p 'read)
1175           (let (seen unseen)
1176             ;; read info could contain articles marked unread by other
1177             ;; imap clients!  we correct this
1178             (setq seen (gnus-uncompress-range (gnus-info-read info))
1179                   unseen (imap-search "UNSEEN UNDELETED")
1180                   seen (gnus-set-difference seen unseen)
1181                   ;; seen might lack articles marked as read by other
1182                   ;; imap clients! we correct this
1183                   seen (append seen (imap-search "SEEN"))
1184                   ;; remove dupes
1185                   seen (sort seen '<)
1186                   seen (gnus-compress-sequence seen t)
1187                   ;; we can't return '(1) since this isn't a "list of ranges",
1188                   ;; and we can't return '((1)) since g-list-of-unread-articles
1189                   ;; is buggy so we return '((1 . 1)).
1190                   seen (if (and (integerp (car seen))
1191                                 (null (cdr seen)))
1192                            (list (cons (car seen) (car seen)))
1193                          seen))
1194             (gnus-info-set-read info seen)))
1195
1196         (mapcar (lambda (pred)
1197                   (when (or (eq (cdr pred) 'recent)
1198                             (and (nnimap-mark-permanent-p (cdr pred))
1199                                  (member (nnimap-mark-to-flag (cdr pred))
1200                                          (imap-mailbox-get 'flags))))
1201                     (gnus-info-set-marks
1202                      info
1203                      (gnus-update-alist-soft
1204                       (cdr pred)
1205                       (gnus-compress-sequence
1206                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1207                       (gnus-info-marks info))
1208                      t)))
1209                 gnus-article-mark-lists)
1210
1211         (when nnimap-importantize-dormant
1212           ;; nnimap mark dormant article as ticked too (for other clients)
1213           ;; so we remove that mark for gnus since we support dormant
1214           (gnus-info-set-marks
1215            info
1216            (gnus-update-alist-soft
1217             'tick
1218             (gnus-remove-from-range
1219              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1220              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1221             (gnus-info-marks info))
1222            t))
1223
1224         (gnus-message 5 "nnimap: Updating info for %s...done"
1225                       (gnus-info-group info))
1226
1227         info))))
1228
1229 (deffoo nnimap-request-type (group &optional article)
1230   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1231       'news
1232     'mail))
1233
1234 (deffoo nnimap-request-set-mark (group actions &optional server)
1235   (when (nnimap-possibly-change-group group server)
1236     (with-current-buffer nnimap-server-buffer
1237       (let (action)
1238         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1239         (while (setq action (pop actions))
1240           (let ((range (nth 0 action))
1241                 (what  (nth 1 action))
1242                 (cmdmarks (nth 2 action))
1243                 marks)
1244             ;; bookmark can't be stored (not list/range
1245             (setq cmdmarks (delq 'bookmark cmdmarks))
1246             ;; killed can't be stored (not list/range
1247             (setq cmdmarks (delq 'killed cmdmarks))
1248             ;; unsent are for nndraft groups only
1249             (setq cmdmarks (delq 'unsent cmdmarks))
1250             ;; cache flags are pointless on the server
1251             (setq cmdmarks (delq 'cache cmdmarks))
1252             ;; seen flags are local to each gnus
1253             (setq cmdmarks (delq 'seen cmdmarks))
1254             ;; recent marks can't be set
1255             (setq cmdmarks (delq 'recent cmdmarks))
1256             (when nnimap-importantize-dormant
1257               ;; flag dormant articles as ticked
1258               (if (memq 'dormant cmdmarks)
1259                   (setq cmdmarks (cons 'tick cmdmarks))))
1260             ;; remove stuff we are forbidden to store
1261             (mapc (lambda (mark)
1262                     (if (imap-message-flag-permanent-p
1263                          (nnimap-mark-to-flag mark))
1264                         (setq marks (cons mark marks))))
1265                   cmdmarks)
1266             (when (and range marks)
1267               (cond ((eq what 'del)
1268                      (imap-message-flags-del
1269                       (imap-range-to-message-set range)
1270                       (nnimap-mark-to-flag marks nil t)))
1271                     ((eq what 'add)
1272                      (imap-message-flags-add
1273                       (imap-range-to-message-set range)
1274                       (nnimap-mark-to-flag marks nil t)))
1275                     ((eq what 'set)
1276                      (imap-message-flags-set
1277                       (imap-range-to-message-set range)
1278                       (nnimap-mark-to-flag marks nil t)))))))
1279         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1280   nil)
1281
1282 (defun nnimap-split-fancy ()
1283   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1284   (let ((nnmail-split-fancy nnimap-split-fancy))
1285     (nnmail-split-fancy)))
1286
1287 (defun nnimap-split-to-groups (rules)
1288   ;; tries to match all rules in nnimap-split-rule against content of
1289   ;; nntp-server-buffer, returns a list of groups that matched.
1290   (with-current-buffer nntp-server-buffer
1291     ;; Fold continuation lines.
1292     (goto-char (point-min))
1293     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1294       (replace-match " " t t))
1295     (if (functionp rules)
1296         (funcall rules)
1297       (let (to-groups regrepp)
1298         (catch 'split-done
1299           (dolist (rule rules to-groups)
1300             (let ((group (car rule))
1301                   (regexp (cadr rule)))
1302               (goto-char (point-min))
1303               (when (and (if (stringp regexp)
1304                              (progn
1305                                (if (not (stringp group))
1306                                    (setq group (eval group))
1307                                  (setq regrepp
1308                                        (string-match "\\\\[0-9&]" group)))
1309                                (re-search-forward regexp nil t))
1310                            (funcall regexp group))
1311                          ;; Don't enter the article into the same group twice.
1312                          (not (assoc group to-groups)))
1313                 (push (if regrepp
1314                           (nnmail-expand-newtext group)
1315                         group)
1316                       to-groups)
1317                 (or nnimap-split-crosspost
1318                     (throw 'split-done to-groups))))))))))
1319
1320 (defun nnimap-assoc-match (key alist)
1321   (let (element)
1322     (while (and alist (not element))
1323       (if (string-match (car (car alist)) key)
1324           (setq element (car alist)))
1325       (setq alist (cdr alist)))
1326     element))
1327
1328 (defun nnimap-split-find-rule (server inbox)
1329   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1330            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1331       ;; extended format
1332       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1333                                             server nnimap-split-rule))))
1334     nnimap-split-rule))
1335
1336 (defun nnimap-split-find-inbox (server)
1337   (if (listp nnimap-split-inbox)
1338       nnimap-split-inbox
1339     (list nnimap-split-inbox)))
1340
1341 (defun nnimap-split-articles (&optional group server)
1342   (when (nnimap-possibly-change-server server)
1343     (with-current-buffer nnimap-server-buffer
1344       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1345         ;; iterate over inboxes
1346         (while (and (setq inbox (pop inboxes))
1347                     (nnimap-possibly-change-group inbox)) ;; SELECT
1348           ;; find split rule for this server / inbox
1349           (when (setq rule (nnimap-split-find-rule server inbox))
1350             ;; iterate over articles
1351             (dolist (article (imap-search nnimap-split-predicate))
1352               (when (if (if (eq nnimap-split-download-body 'default)
1353                             nnimap-split-download-body-default
1354                           nnimap-split-download-body)
1355                         (and (nnimap-request-article article)
1356                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1357                       (nnimap-request-head article))
1358                 ;; copy article to right group(s)
1359                 (setq removeorig nil)
1360                 (dolist (to-group (nnimap-split-to-groups rule))
1361                   (cond ((eq to-group 'junk)
1362                          (message "IMAP split removed %s:%s:%d" server inbox
1363                                   article)
1364                          (setq removeorig t))
1365                         ((imap-message-copy (number-to-string article)
1366                                             to-group nil 'nocopyuid)
1367                          (message "IMAP split moved %s:%s:%d to %s" server
1368                                   inbox article to-group)
1369                          (setq removeorig t)
1370                          (when nnmail-cache-accepted-message-ids
1371                            (with-current-buffer nntp-server-buffer
1372                              (let (msgid)
1373                                (and (setq msgid
1374                                           (nnmail-fetch-field "message-id"))
1375                                     (nnmail-cache-insert msgid
1376                                                          to-group
1377                                                          (nnmail-fetch-field "subject"))))))
1378                          ;; Add the group-art list to the history list.
1379                          (push (list (cons to-group 0)) nnmail-split-history))
1380                         (t
1381                          (message "IMAP split failed to move %s:%s:%d to %s"
1382                                   server inbox article to-group))))
1383                 (if (if (eq nnimap-split-download-body 'default)
1384                         nnimap-split-download-body-default
1385                       nnimap-split-download-body)
1386                     (widen))
1387                 ;; remove article if it was successfully copied somewhere
1388                 (and removeorig
1389                      (imap-message-flags-add (format "%d" article)
1390                                              "\\Seen \\Deleted")))))
1391           (when (imap-mailbox-select inbox) ;; just in case
1392             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1393             (imap-mailbox-expunge)
1394             (imap-mailbox-close)))
1395         (when nnmail-cache-accepted-message-ids
1396           (nnmail-cache-close))
1397         t))))
1398
1399 (deffoo nnimap-request-scan (&optional group server)
1400   (nnimap-split-articles group server))
1401
1402 (deffoo nnimap-request-newgroups (date &optional server)
1403   (when (nnimap-possibly-change-server server)
1404     (with-current-buffer nntp-server-buffer
1405       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1406                     (if (> (length server) 0) " on " "") server)
1407       (erase-buffer)
1408       (nnimap-before-find-minmax-bugworkaround)
1409       (dolist (pattern (nnimap-pattern-to-list-arguments
1410                         nnimap-list-pattern))
1411         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1412                                         nnimap-server-buffer))
1413           (or (catch 'found
1414                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1415                                                    nnimap-server-buffer))
1416                   (if (string= (downcase mailbox) "\\noselect")
1417                       (throw 'found t)))
1418                 nil)
1419               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1420                 (when info
1421                   (insert (format "\"%s\" %d %d y\n"
1422                                   mbx (or (nth 2 info) 0)
1423                                   (max 1 (or (nth 1 info) 1)))))))))
1424       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1425                     (if (> (length server) 0) " on " "") server))
1426     t))
1427
1428 (deffoo nnimap-request-create-group (group &optional server args)
1429   (when (nnimap-possibly-change-server server)
1430     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1431         (imap-mailbox-create group nnimap-server-buffer)
1432         (nnheader-report 'nnimap "%S"
1433                          (imap-error-text nnimap-server-buffer)))))
1434
1435 (defun nnimap-time-substract (time1 time2)
1436   "Return TIME for TIME1 - TIME2."
1437   (let* ((ms (- (car time1) (car time2)))
1438          (ls (- (nth 1 time1) (nth 1 time2))))
1439     (if (< ls 0)
1440         (list (- ms 1) (+ (expt 2 16) ls))
1441       (list ms ls))))
1442
1443 (defun nnimap-date-days-ago (daysago)
1444   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1445   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1446          (date (format-time-string
1447                 (format "%%d-%s-%%Y"
1448                         (capitalize (car (rassoc (nth 4 (decode-time time))
1449                                                  parse-time-months))))
1450                 time)))
1451     (if (eq ?0 (string-to-char date))
1452         (substring date 1)
1453       date)))
1454
1455 (defun nnimap-request-expire-articles-progress ()
1456   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1457                 imap-current-message))
1458
1459 (defun nnimap-expiry-target (arts group server)
1460   (unless (eq nnmail-expiry-target 'delete)
1461     (with-temp-buffer
1462       (dolist (art arts)
1463         (nnimap-request-article art group server (current-buffer))
1464         ;; hints for optimization in `nnimap-request-accept-article'
1465         (let ((nnimap-current-move-article art)
1466               (nnimap-current-move-group group)
1467               (nnimap-current-move-server server))
1468           (nnmail-expiry-target-group nnmail-expiry-target group))))
1469     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1470     ;; current group to be changed or not, so we make sure here.
1471     (nnimap-possibly-change-group group server)))
1472
1473 ;; Notice that we don't actually delete anything, we just mark them deleted.
1474 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1475   (let ((artseq (gnus-compress-sequence articles)))
1476     (when (and artseq (nnimap-possibly-change-group group server))
1477       (with-current-buffer nnimap-server-buffer
1478         (let ((days (or (and nnmail-expiry-wait-function
1479                              (funcall nnmail-expiry-wait-function group))
1480                         nnmail-expiry-wait)))
1481           (cond ((or force (eq days 'immediate))
1482                  (let ((oldarts (imap-search
1483                                  (concat "UID "
1484                                          (imap-range-to-message-set artseq)))))
1485                    (when oldarts
1486                      (nnimap-expiry-target oldarts group server)
1487                      (when (imap-message-flags-add
1488                             (imap-range-to-message-set
1489                              (gnus-compress-sequence oldarts)) "\\Deleted")
1490                        (setq articles (gnus-set-difference
1491                                        articles oldarts))))))
1492                 ((numberp days)
1493                  (let ((oldarts (imap-search
1494                                  (format nnimap-expunge-search-string
1495                                          (imap-range-to-message-set artseq)
1496                                          (nnimap-date-days-ago days))))
1497                        (imap-fetch-data-hook
1498                         '(nnimap-request-expire-articles-progress)))
1499                    (when oldarts
1500                      (nnimap-expiry-target oldarts group server)
1501                      (when (imap-message-flags-add
1502                             (imap-range-to-message-set
1503                              (gnus-compress-sequence oldarts)) "\\Deleted")
1504                        (setq articles (gnus-set-difference
1505                                        articles oldarts)))))))))))
1506   ;; return articles not deleted
1507   articles)
1508
1509 (deffoo nnimap-request-move-article (article group server accept-form
1510                                              &optional last move-is-internal)
1511   (when (nnimap-possibly-change-server server)
1512     (save-excursion
1513       (let ((buf (get-buffer-create " *nnimap move*"))
1514             (nnimap-current-move-article article)
1515             (nnimap-current-move-group group)
1516             (nnimap-current-move-server nnimap-current-server)
1517             result)
1518         (gnus-message 10 "nnimap-request-move-article: this is an %s move"
1519                       (if move-is-internal
1520                           "internal"
1521                         "external"))
1522         ;; request the article only when the move is NOT internal
1523         (and (or move-is-internal
1524                  (nnimap-request-article article group server))
1525              (save-excursion
1526                (set-buffer buf)
1527                (buffer-disable-undo (current-buffer))
1528                (insert-buffer-substring nntp-server-buffer)
1529                (setq result (eval accept-form))
1530                (kill-buffer buf)
1531                result)
1532              (imap-message-flags-add
1533               (imap-range-to-message-set (list article))
1534               "\\Deleted" 'silent nnimap-server-buffer))
1535         result))))
1536
1537 (deffoo nnimap-request-accept-article (group &optional server last)
1538   (when (nnimap-possibly-change-server server)
1539     (let (uid)
1540       (if (setq uid
1541                 (if (string= nnimap-current-server nnimap-current-move-server)
1542                     ;; moving article within same server, speed it up...
1543                     (and (nnimap-possibly-change-group
1544                           nnimap-current-move-group)
1545                          (imap-message-copy (number-to-string
1546                                              nnimap-current-move-article)
1547                                             group 'dontcreate nil
1548                                             nnimap-server-buffer))
1549                   (with-current-buffer (current-buffer)
1550                     (goto-char (point-min))
1551                     ;; remove any 'From blabla' lines, some IMAP servers
1552                     ;; reject the entire message otherwise.
1553                     (when (looking-at "^From[^:]")
1554                       (delete-region (point) (progn (forward-line) (point))))
1555                     ;; turn into rfc822 format (\r\n eol's)
1556                     (while (search-forward "\n" nil t)
1557                       (replace-match "\r\n"))
1558                     (when nnmail-cache-accepted-message-ids
1559                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1560                                            group
1561                                            (nnmail-fetch-field "subject"))))
1562                   (when (and last nnmail-cache-accepted-message-ids)
1563                     (nnmail-cache-close))
1564                   ;; this 'or' is for Cyrus server bug
1565                   (or (null (imap-current-mailbox nnimap-server-buffer))
1566                       (imap-mailbox-unselect nnimap-server-buffer))
1567                   (imap-message-append group (current-buffer) nil nil
1568                                        nnimap-server-buffer)))
1569           (cons group (nth 1 uid))
1570         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1571
1572 (deffoo nnimap-request-delete-group (group force &optional server)
1573   (when (nnimap-possibly-change-server server)
1574     (with-current-buffer nnimap-server-buffer
1575       (if force
1576           (or (null (imap-mailbox-status group 'uidvalidity))
1577               (imap-mailbox-delete group))
1578         ;; UNSUBSCRIBE?
1579         t))))
1580
1581 (deffoo nnimap-request-rename-group (group new-name &optional server)
1582   (when (nnimap-possibly-change-server server)
1583     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1584
1585 (defun nnimap-expunge (mailbox server)
1586   (when (nnimap-possibly-change-group mailbox server)
1587     (imap-mailbox-expunge nil nnimap-server-buffer)))
1588
1589 (defun nnimap-acl-get (mailbox server)
1590   (when (nnimap-possibly-change-server server)
1591     (and (imap-capability 'ACL nnimap-server-buffer)
1592          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1593
1594 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1595   (when (nnimap-possibly-change-server (cadr method))
1596     (unless (imap-capability 'ACL nnimap-server-buffer)
1597       (error "Your server does not support ACL editing"))
1598     (with-current-buffer nnimap-server-buffer
1599       ;; delete all removed identifiers
1600       (mapc (lambda (old-acl)
1601               (unless (assoc (car old-acl) new-acls)
1602                 (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1603                     (error "Can't delete ACL for %s" (car old-acl)))))
1604             old-acls)
1605       ;; set all changed acl's
1606       (mapc (lambda (new-acl)
1607               (let ((new-rights (cdr new-acl))
1608                     (old-rights (cdr (assoc (car new-acl) old-acls))))
1609                 (unless (and old-rights new-rights
1610                              (string= old-rights new-rights))
1611                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1612                       (error "Can't set ACL for %s to %s" (car new-acl)
1613                              new-rights)))))
1614             new-acls)
1615       t)))
1616
1617 \f
1618 ;;; Internal functions
1619
1620 ;;
1621 ;; This is confusing.
1622 ;;
1623 ;; mark      => read, tick, draft, reply etc
1624 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1625 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1626 ;;
1627 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1628 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1629 ;;
1630
1631 (defconst nnimap-mark-to-predicate-alist
1632   (mapcar
1633    (lambda (pair)                       ; cdr is the mark
1634      (or (assoc (cdr pair)
1635                 '((read . "SEEN")
1636                   (tick . "FLAGGED")
1637                   (draft . "DRAFT")
1638                   (recent . "RECENT")
1639                   (reply . "ANSWERED")))
1640          (cons (cdr pair)
1641                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1642    (cons '(read . read) gnus-article-mark-lists)))
1643
1644 (defun nnimap-mark-to-predicate (pred)
1645   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1646 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1647 to be used within a IMAP SEARCH query."
1648   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1649
1650 (defconst nnimap-mark-to-flag-alist
1651   (mapcar
1652    (lambda (pair)
1653      (or (assoc (cdr pair)
1654                 '((read . "\\Seen")
1655                   (tick . "\\Flagged")
1656                   (draft . "\\Draft")
1657                   (recent . "\\Recent")
1658                   (reply . "\\Answered")))
1659          (cons (cdr pair)
1660                (format "gnus-%s" (symbol-name (cdr pair))))))
1661    (cons '(read . read) gnus-article-mark-lists)))
1662
1663 (defun nnimap-mark-to-flag-1 (preds)
1664   (if (and (not (null preds)) (listp preds))
1665       (cons (nnimap-mark-to-flag (car preds))
1666             (nnimap-mark-to-flag (cdr preds)))
1667     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1668
1669 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1670   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1671 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1672 be used in a STORE FLAGS command."
1673   (let ((result (nnimap-mark-to-flag-1 preds)))
1674     (setq result (if (and (or make-string always-list)
1675                           (not (listp result)))
1676                      (list result)
1677                    result))
1678     (if make-string
1679         (mapconcat (lambda (flag)
1680                      (if (listp flag)
1681                          (mapconcat 'identity flag " ")
1682                        flag))
1683                    result " ")
1684       result)))
1685
1686 (defun nnimap-mark-permanent-p (mark &optional group)
1687   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1688   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1689
1690 (when nnimap-debug
1691   (require 'trace)
1692   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1693   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1694           '(
1695             nnimap-possibly-change-server
1696             nnimap-verify-uidvalidity
1697             nnimap-find-minmax-uid
1698             nnimap-before-find-minmax-bugworkaround
1699             nnimap-possibly-change-group
1700             ;;nnimap-replace-whitespace
1701             nnimap-retrieve-headers-progress
1702             nnimap-retrieve-which-headers
1703             nnimap-group-overview-filename
1704             nnimap-retrieve-headers-from-file
1705             nnimap-retrieve-headers-from-server
1706             nnimap-retrieve-headers
1707             nnimap-open-connection
1708             nnimap-open-server
1709             nnimap-server-opened
1710             nnimap-close-server
1711             nnimap-request-close
1712             nnimap-status-message
1713             ;;nnimap-demule
1714             nnimap-request-article-part
1715             nnimap-request-article
1716             nnimap-request-head
1717             nnimap-request-body
1718             nnimap-request-group
1719             nnimap-close-group
1720             nnimap-pattern-to-list-arguments
1721             nnimap-request-list
1722             nnimap-request-post
1723             nnimap-retrieve-groups
1724             nnimap-request-update-info-internal
1725             nnimap-request-type
1726             nnimap-request-set-mark
1727             nnimap-split-to-groups
1728             nnimap-split-find-rule
1729             nnimap-split-find-inbox
1730             nnimap-split-articles
1731             nnimap-request-scan
1732             nnimap-request-newgroups
1733             nnimap-request-create-group
1734             nnimap-time-substract
1735             nnimap-date-days-ago
1736             nnimap-request-expire-articles-progress
1737             nnimap-request-expire-articles
1738             nnimap-request-move-article
1739             nnimap-request-accept-article
1740             nnimap-request-delete-group
1741             nnimap-request-rename-group
1742             gnus-group-nnimap-expunge
1743             gnus-group-nnimap-edit-acl
1744             gnus-group-nnimap-edit-acl-done
1745             nnimap-group-mode-hook
1746             nnimap-mark-to-predicate
1747             nnimap-mark-to-flag-1
1748             nnimap-mark-to-flag
1749             nnimap-mark-permanent-p
1750             )))
1751
1752 (provide 'nnimap)
1753
1754 ;; arch-tag: 2b001f20-3ff9-4094-a0ad-46807c1ba70b
1755 ;;; nnimap.el ends here