cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'nnheader))
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'nnheader)
  36 (require 'gnus-util)
  37 (require 'gnus)
  38 (require 'nnoo)
  39 (require 'netrc)
  40
  41 (nnoo-declare nnimap)
  42
  43 (defvoo nnimap-address nil
  44   "The address of the IMAP server.")
  45
  46 (defvoo nnimap-server-port nil
  47   "The IMAP port used.
  48 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  49 it will default to `imap'.")
  50
  51 (defvoo nnimap-stream 'ssl
  52   "How nnimap will talk to the IMAP server.
  53 Values are `ssl' and `network'.")
  54
  55 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  56                                  (if (listp imap-shell-program)
  57                                      (car imap-shell-program)
  58                                    imap-shell-program)
  59                                "ssh %s imapd"))
  60
  61 (defvoo nnimap-inbox nil
  62   "The mail box where incoming mail arrives and should be split out of.")
  63
  64 (defvoo nnimap-expunge-inbox nil
  65   "If non-nil, expunge the inbox after fetching mail.
  66 This is always done if the server supports UID EXPUNGE, but it's
  67 not done by default on servers that doesn't support that command.")
  68
  69 (defvoo nnimap-authenticator nil
  70   "How nnimap authenticate itself to the server.
  71 Possible choices are nil (use default methods) or `anonymous'.")
  72
  73 (defvoo nnimap-fetch-partial-articles nil
  74   "If non-nil, nnimap will fetch partial articles.
  75 If t, nnimap will fetch only the first part.  If a string, it
  76 will fetch all parts that have types that match that string.  A
  77 likely value would be \"text/\" to automatically fetch all
  78 textual parts.")
  79
  80 (defvoo nnimap-connection-alist nil)
  81
  82 (defvoo nnimap-current-infos nil)
  83
  84 (defvar nnimap-process nil)
  85
  86 (defvar nnimap-status-string "")
  87
  88 (defvar nnimap-split-download-body-default nil
  89   "Internal variable with default value for `nnimap-split-download-body'.")
  90
  91 (defstruct nnimap
  92   group process commands capabilities select-result newlinep)
  93
  94 (defvar nnimap-object nil)
  95
  96 (defvar nnimap-mark-alist
  97   '((read "\\Seen")
  98     (tick "\\Flagged")
  99     (reply "\\Answered")
 100     (expire "gnus-expire")
 101     (dormant "gnus-dormant")
 102     (score "gnus-score")
 103     (save "gnus-save")
 104     (download "gnus-download")
 105     (forward "gnus-forward")))
 106
 107 (defvar nnimap-split-methods nil)
 108
 109 (defun nnimap-buffer ()
 110   (nnimap-find-process-buffer nntp-server-buffer))
 111
 112 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 113   (with-current-buffer nntp-server-buffer
 114     (erase-buffer)
 115     (when (nnimap-possibly-change-group group server)
 116       (with-current-buffer (nnimap-buffer)
 117         (nnimap-send-command "SELECT %S" (utf7-encode group t))
 118         (erase-buffer)
 119         (nnimap-wait-for-response
 120          (nnimap-send-command
 121           "UID FETCH %s %s"
 122           (nnimap-article-ranges (gnus-compress-sequence articles))
 123           (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 124                   (format
 125                    (if (member "IMAP4REV1"
 126                                (nnimap-capabilities nnimap-object))
 127                        "BODY.PEEK[HEADER.FIELDS %s]"
 128                      "RFC822.HEADER.LINES %s")
 129                    (append '(Subject From Date Message-Id
 130                                      References In-Reply-To Xref)
 131                            nnmail-extra-headers))))
 132          t)
 133         (nnimap-transform-headers))
 134       (insert-buffer-substring
 135        (nnimap-find-process-buffer (current-buffer))))
 136     t))
 137
 138 (defun nnimap-transform-headers ()
 139   (goto-char (point-min))
 140   (let (article bytes lines size)
 141     (block nil
 142       (while (not (eobp))
 143         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 144           (delete-region (point) (progn (forward-line 1) (point)))
 145           (when (eobp)
 146             (return)))
 147         (setq article (match-string 1)
 148               bytes (nnimap-get-length)
 149               lines nil)
 150         (beginning-of-line)
 151         (setq size
 152               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 153                                       (line-end-position)
 154                                       t)
 155                    (match-string 1)))
 156         (beginning-of-line)
 157         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 158           (let ((structure (ignore-errors (read (current-buffer)))))
 159             (while (and (consp structure)
 160                         (not (stringp (car structure))))
 161               (setq structure (car structure)))
 162             (setq lines (nth 7 structure))))
 163         (delete-region (line-beginning-position) (line-end-position))
 164         (insert (format "211 %s Article retrieved." article))
 165         (forward-line 1)
 166         (when size
 167           (insert (format "Chars: %s\n" size)))
 168         (when lines
 169           (insert (format "Lines: %s\n" lines)))
 170         (re-search-forward "^\r$")
 171         (delete-region (line-beginning-position) (line-end-position))
 172         (insert ".")
 173         (forward-line 1)))))
 174
 175 (defun nnimap-get-length ()
 176   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 177        (string-to-number (match-string 1))))
 178
 179 (defun nnimap-article-ranges (ranges)
 180   (let (result)
 181     (cond
 182      ((numberp ranges)
 183       (number-to-string ranges))
 184      ((numberp (cdr ranges))
 185       (format "%d:%d" (car ranges) (cdr ranges)))
 186      (t
 187       (dolist (elem ranges)
 188         (push
 189          (if (consp elem)
 190              (format "%d:%d" (car elem) (cdr elem))
 191            (number-to-string elem))
 192          result))
 193       (mapconcat #'identity (nreverse result) ",")))))
 194
 195 (deffoo nnimap-open-server (server &optional defs)
 196   (if (nnimap-server-opened server)
 197       t
 198     (unless (assq 'nnimap-address defs)
 199       (setq defs (append defs (list (list 'nnimap-address server)))))
 200     (nnoo-change-server 'nnimap server defs)
 201     (or (nnimap-find-connection nntp-server-buffer)
 202         (nnimap-open-connection nntp-server-buffer))))
 203
 204 (defun nnimap-make-process-buffer (buffer)
 205   (with-current-buffer
 206       (generate-new-buffer (format "*nnimap %s %s %s*"
 207                                    nnimap-address nnimap-server-port
 208                                    (gnus-buffer-exists-p buffer)))
 209     (mm-disable-multibyte)
 210     (buffer-disable-undo)
 211     (gnus-add-buffer)
 212     (set (make-local-variable 'after-change-functions) nil)
 213     (set (make-local-variable 'nnimap-object) (make-nnimap))
 214     (push (list buffer (current-buffer)) nnimap-connection-alist)
 215     (current-buffer)))
 216
 217 (defun nnimap-open-shell-stream (name buffer host port)
 218   (let ((process-connection-type nil))
 219     (start-process name buffer shell-file-name
 220                    shell-command-switch
 221                    (format-spec
 222                     nnimap-shell-program
 223                     (format-spec-make
 224                      ?s host
 225                      ?p port)))))
 226
 227 (defun nnimap-credentials (address ports)
 228   (let (port credentials)
 229     ;; Request the credentials from all ports, but only query on the
 230     ;; last port if all the previous ones have failed.
 231     (while (and (null credentials)
 232                 (setq port (pop ports)))
 233       (setq credentials
 234             (auth-source-user-or-password
 235              '("login" "password") address port nil (null ports))))
 236     credentials))
 237
 238 (defun nnimap-open-connection (buffer)
 239   (with-current-buffer (nnimap-make-process-buffer buffer)
 240     (let* ((coding-system-for-read 'binary)
 241            (coding-system-for-write 'binary)
 242            (ports
 243             (cond
 244              ((eq nnimap-stream 'network)
 245               (open-network-stream
 246                "*nnimap*" (current-buffer) nnimap-address
 247                (or nnimap-server-port
 248                    (if (netrc-find-service-number "imap")
 249                        "imap"
 250                      "143")))
 251               '("143" "imap"))
 252              ((eq nnimap-stream 'shell)
 253               (nnimap-open-shell-stream
 254                "*nnimap*" (current-buffer) nnimap-address
 255                (or nnimap-server-port "imap"))
 256               '("imap"))
 257              ((eq nnimap-stream 'ssl)
 258               (open-tls-stream
 259                "*nnimap*" (current-buffer) nnimap-address
 260                (or nnimap-server-port
 261                    (if (netrc-find-service-number "imaps")
 262                        "imaps"
 263                      "993")))
 264               '("143" "993" "imap" "imaps"))))
 265            connection-result login-result credentials)
 266       (setf (nnimap-process nnimap-object)
 267             (get-buffer-process (current-buffer)))
 268       (when (and (nnimap-process nnimap-object)
 269                  (memq (process-status (nnimap-process nnimap-object))
 270                        '(open run)))
 271         (gnus-set-process-query-on-exit-flag (nnimap-process nnimap-object) nil)
 272         (when (setq connection-result (nnimap-wait-for-connection))
 273           (unless (equal connection-result "PREAUTH")
 274             (if (not (setq credentials
 275                            (if (eq nnimap-authenticator 'anonymous)
 276                                (list "anonymous"
 277                                      (message-make-address))
 278                              (nnimap-credentials
 279                               nnimap-address
 280                               (if nnimap-server-port
 281                                   (cons (format "%s" nnimap-server-port) ports)
 282                                 ports)))))
 283                 (setq nnimap-object nil)
 284               (setq login-result (nnimap-command "LOGIN %S %S"
 285                                                  (car credentials)
 286                                                  (cadr credentials)))
 287               (unless (car login-result)
 288                 (delete-process (nnimap-process nnimap-object))
 289                 (setq nnimap-object nil))))
 290           (when nnimap-object
 291             (setf (nnimap-capabilities nnimap-object)
 292                   (mapcar
 293                    #'upcase
 294                    (or (nnimap-find-parameter "CAPABILITY" (cdr login-result))
 295                        (nnimap-find-parameter
 296                         "CAPABILITY" (cdr (nnimap-command "CAPABILITY"))))))
 297             (when (member "QRESYNC" (nnimap-capabilities nnimap-object))
 298               (nnimap-command "ENABLE QRESYNC"))
 299             t))))))
 300
 301 (defun nnimap-find-parameter (parameter elems)
 302   (let (result)
 303     (dolist (elem elems)
 304       (cond
 305        ((equal (car elem) parameter)
 306         (setq result (cdr elem)))
 307        ((and (equal (car elem) "OK")
 308              (consp (cadr elem))
 309              (equal (caadr elem) parameter))
 310         (setq result (cdr (cadr elem))))))
 311     result))
 312
 313 (deffoo nnimap-close-server (&optional server)
 314   t)
 315
 316 (deffoo nnimap-request-close ()
 317   t)
 318
 319 (deffoo nnimap-server-opened (&optional server)
 320   (and (nnoo-current-server-p 'nnimap server)
 321        nntp-server-buffer
 322        (gnus-buffer-live-p nntp-server-buffer)
 323        (nnimap-find-connection nntp-server-buffer)))
 324
 325 (deffoo nnimap-status-message (&optional server)
 326   nnimap-status-string)
 327
 328 (deffoo nnimap-request-article (article &optional group server to-buffer)
 329   (with-current-buffer nntp-server-buffer
 330     (let ((result (nnimap-possibly-change-group group server))
 331           parts)
 332       (when (stringp article)
 333         (setq article (nnimap-find-article-by-message-id group article)))
 334       (when (and result
 335                  article)
 336         (erase-buffer)
 337         (with-current-buffer (nnimap-buffer)
 338           (erase-buffer)
 339           (when nnimap-fetch-partial-articles
 340             (if (eq nnimap-fetch-partial-articles t)
 341                 (setq parts '(1))
 342               (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 343               (goto-char (point-min))
 344               (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 345                 (let ((structure (ignore-errors (read (current-buffer)))))
 346                   (setq parts (nnimap-find-wanted-parts structure))))))
 347           (setq result
 348                 (nnimap-command
 349                  (if (member "IMAP4REV1" (nnimap-capabilities nnimap-object))
 350                      "UID FETCH %d BODY.PEEK[]"
 351                    "UID FETCH %d RFC822.PEEK")
 352                  article))
 353           ;; Check that we really got an article.
 354           (goto-char (point-min))
 355           (unless (looking-at "\\* [0-9]+ FETCH")
 356             (setq result nil)))
 357         (let ((buffer (nnimap-find-process-buffer (current-buffer))))
 358           (when (car result)
 359             (with-current-buffer (or to-buffer nntp-server-buffer)
 360               (insert-buffer-substring buffer)
 361               (goto-char (point-min))
 362               (let ((bytes (nnimap-get-length)))
 363                 (delete-region (line-beginning-position)
 364                                (progn (forward-line 1) (point)))
 365                 (goto-char (+ (point) bytes))
 366                 (delete-region (point) (point-max))
 367                 (nnheader-ms-strip-cr))
 368               (cons group article))))))))
 369
 370 (defun nnimap-find-wanted-parts (structure)
 371   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 372
 373 (defun nnimap-find-wanted-parts-1 (structure prefix)
 374   (let ((num 1)
 375         parts)
 376     (while (consp (car structure))
 377       (let ((sub (pop structure)))
 378         (if (consp (car sub))
 379             (push (nnimap-find-wanted-parts-1
 380                    sub (if (string= prefix "")
 381                            (number-to-string num)
 382                          (format "%s.%s" prefix num)))
 383                   parts)
 384           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub))))
 385             (when (string-match nnimap-fetch-partial-articles type)
 386               (push (if (string= prefix "")
 387                         (number-to-string num)
 388                       (format "%s.%s" prefix num))
 389                     parts)))
 390           (incf num))))
 391     (nreverse parts)))
 392
 393 (deffoo nnimap-request-group (group &optional server dont-check info)
 394   (let ((result (nnimap-possibly-change-group group server))
 395         articles active marks high low)
 396     (with-current-buffer nntp-server-buffer
 397       (when result
 398         (if (and dont-check
 399                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 400             (insert (format "211 %d %d %d %S\n"
 401                             (- (cdr active) (car active))
 402                             (car active)
 403                             (cdr active)
 404                             group))
 405           (with-current-buffer (nnimap-buffer)
 406             (erase-buffer)
 407             (let ((group-sequence
 408                    (nnimap-send-command "SELECT %S" (utf7-encode group)))
 409                   (flag-sequence
 410                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 411               (nnimap-wait-for-response flag-sequence)
 412               (setq marks
 413                     (nnimap-flags-to-marks
 414                      (nnimap-parse-flags
 415                       (list (list group-sequence flag-sequence 1 group)))))
 416               (when info
 417                 (nnimap-update-infos marks (list info)))
 418               (goto-char (point-max))
 419               (cond
 420                (marks
 421                 (setq high (nth 3 (car marks))
 422                       low (nth 4 (car marks))))
 423                ((re-search-backward "UIDNEXT \\([0-9]+\\)" nil t)
 424                 (setq high (string-to-number (match-string 1))
 425                       low 1)))))
 426           (erase-buffer)
 427           (insert
 428            (format
 429             "211 %d %d %d %S\n"
 430             (1+ (- high low))
 431             low high group))))
 432       t)))
 433
 434 (deffoo nnimap-request-create-group (group &optional server args)
 435   (when (nnimap-possibly-change-group nil server)
 436     (with-current-buffer (nnimap-buffer)
 437       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 438
 439 (deffoo nnimap-request-delete-group (group &optional force server)
 440   (when (nnimap-possibly-change-group nil server)
 441     (with-current-buffer (nnimap-buffer)
 442       (car (nnimap-command "DELETE %S" (utf7-encode group))))))
 443
 444 (defun nnimap-get-flags (spec)
 445   (let ((articles nil)
 446         elems)
 447     (with-current-buffer (nnimap-buffer)
 448       (erase-buffer)
 449       (nnimap-wait-for-response (nnimap-send-command
 450                                  "UID FETCH %s FLAGS" spec))
 451       (goto-char (point-min))
 452       (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" nil t)
 453         (setq elems (nnimap-parse-line (match-string 1)))
 454         (push (cons (string-to-number (cadr (member "UID" elems)))
 455                     (cadr (member "FLAGS" elems)))
 456               articles)))
 457     (nreverse articles)))
 458
 459 (deffoo nnimap-close-group (group &optional server)
 460   t)
 461
 462 (deffoo nnimap-request-move-article (article group server accept-form
 463                                              &optional last internal-move-group)
 464   (when (nnimap-possibly-change-group group server)
 465     ;; If the move is internal (on the same server), just do it the easy
 466     ;; way.
 467     (let ((message-id (message-field-value "message-id")))
 468       (if internal-move-group
 469           (let ((result
 470                  (with-current-buffer (nnimap-buffer)
 471                    (nnimap-command "UID COPY %d %S"
 472                                    article
 473                                    (utf7-encode internal-move-group t)))))
 474             (when (car result)
 475               (nnimap-delete-article article)
 476               (cons internal-move-group
 477                     (nnimap-find-article-by-message-id
 478                      internal-move-group message-id))))
 479         (with-temp-buffer
 480           (when (nnimap-request-article article group server (current-buffer))
 481             (let ((result (eval accept-form)))
 482               (when result
 483                 (nnimap-delete-article article)
 484                 result))))))))
 485
 486 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 487   (cond
 488    ((not (nnimap-possibly-change-group group server))
 489     articles)
 490    (force
 491     (unless (nnimap-delete-article articles)
 492       (message "Article marked for deletion, but not expunged."))
 493     nil)
 494    (t
 495     articles)))
 496
 497 (defun nnimap-find-article-by-message-id (group message-id)
 498   (when (nnimap-possibly-change-group group nil)
 499     (with-current-buffer (nnimap-buffer)
 500       (let ((result
 501              (nnimap-command "UID SEARCH HEADER Message-Id %S" message-id))
 502             article)
 503         (when (car result)
 504           ;; Select the last instance of the message in the group.
 505           (and (setq article
 506                      (car (last (assoc "SEARCH" (cdr result)))))
 507                (string-to-number article)))))))
 508
 509 (defun nnimap-delete-article (articles)
 510   (with-current-buffer (nnimap-buffer)
 511     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 512                     (nnimap-article-ranges articles))
 513     (when (member "UIDPLUS" (nnimap-capabilities nnimap-object))
 514       (nnimap-send-command "UID EXPUNGE %s"
 515                            (nnimap-article-ranges articles))
 516       t)))
 517
 518 (deffoo nnimap-request-scan (&optional group server)
 519   (when (and (nnimap-possibly-change-group nil server)
 520              (equal group nnimap-inbox)
 521              nnimap-inbox
 522              nnimap-split-methods)
 523     (nnimap-split-incoming-mail)))
 524
 525 (defun nnimap-marks-to-flags (marks)
 526   (let (flags flag)
 527     (dolist (mark marks)
 528       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 529         (push flag flags)))
 530     flags))
 531
 532 (deffoo nnimap-request-set-mark (group actions &optional server)
 533   (when (nnimap-possibly-change-group group server)
 534     (let (sequence)
 535       (with-current-buffer (nnimap-buffer)
 536         ;; Just send all the STORE commands without waiting for
 537         ;; response.  If they're successful, they're successful.
 538         (dolist (action actions)
 539           (destructuring-bind (range action marks) action
 540             (let ((flags (nnimap-marks-to-flags marks)))
 541               (when flags
 542                 (setq sequence (nnimap-send-command
 543                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 544                                 (nnimap-article-ranges range)
 545                                 (if (eq action 'del)
 546                                     "-"
 547                                   "+")
 548                                 (mapconcat #'identity flags " ")))))))
 549         ;; Wait for the last command to complete to avoid later
 550         ;; syncronisation problems with the stream.
 551         (when sequence
 552           (nnimap-wait-for-response sequence))))))
 553
 554 (deffoo nnimap-request-accept-article (group &optional server last)
 555   (when (nnimap-possibly-change-group nil server)
 556     (nnmail-check-syntax)
 557     (let ((message (buffer-string))
 558           (message-id (message-field-value "message-id"))
 559           sequence)
 560       (with-current-buffer (nnimap-buffer)
 561         (setq sequence (nnimap-send-command
 562                         "APPEND %S {%d}" (utf7-encode group t)
 563                         (length message)))
 564         (process-send-string (get-buffer-process (current-buffer)) message)
 565         (process-send-string (get-buffer-process (current-buffer))
 566                              (if (nnimap-newlinep nnimap-object)
 567                                  "\n"
 568                                "\r\n"))
 569         (let ((result (nnimap-get-response sequence)))
 570           (when result
 571             (cons group
 572                   (nnimap-find-article-by-message-id group message-id))))))))
 573
 574 (defun nnimap-add-cr ()
 575   (goto-char (point-min))
 576   (while (re-search-forward "\r?\n" nil t)
 577     (replace-match "\r\n" t t)))
 578
 579 (defun nnimap-get-groups ()
 580   (let ((result (nnimap-command "LIST \"\" \"*\""))
 581         groups)
 582     (when (car result)
 583       (dolist (line (cdr result))
 584         (when (and (equal (car line) "LIST")
 585                    (not (and (caadr line)
 586                              (string-match "noselect" (caadr line)))))
 587           (push (car (last line)) groups)))
 588       (nreverse groups))))
 589
 590 (deffoo nnimap-request-list (&optional server)
 591   (nnimap-possibly-change-group nil server)
 592   (with-current-buffer nntp-server-buffer
 593     (erase-buffer)
 594     (let ((groups
 595            (with-current-buffer (nnimap-buffer)
 596              (nnimap-get-groups)))
 597           sequences responses)
 598       (when groups
 599         (with-current-buffer (nnimap-buffer)
 600           (dolist (group groups)
 601             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 602                         group)
 603                   sequences))
 604           (nnimap-wait-for-response (caar sequences))
 605           (setq responses
 606                 (nnimap-get-responses (mapcar #'car sequences))))
 607         (dolist (response responses)
 608           (let* ((sequence (car response))
 609                  (response (cadr response))
 610                  (group (cadr (assoc sequence sequences))))
 611             (when (and group
 612                        (equal (caar response) "OK"))
 613               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
 614                     highest exists)
 615                 (dolist (elem response)
 616                   (when (equal (cadr elem) "EXISTS")
 617                     (setq exists (string-to-number (car elem)))))
 618                 (when uidnext
 619                   (setq highest (1- (string-to-number (car uidnext)))))
 620                 (cond
 621                  ((null highest)
 622                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
 623                  ((zerop exists)
 624                   ;; Empty group.
 625                   (insert (format "%S %d %d y\n"
 626                                   (utf7-decode group t) highest (1+ highest))))
 627                  (t
 628                   ;; Return the widest possible range.
 629                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
 630                                   (or highest exists)))))))))
 631         t))))
 632
 633 (deffoo nnimap-retrieve-group-data-early (server infos)
 634   (when (nnimap-possibly-change-group nil server)
 635     (with-current-buffer (nnimap-buffer)
 636       ;; QRESYNC handling isn't implemented.
 637       (let ((qresyncp (member "notQRESYNC" (nnimap-capabilities nnimap-object)))
 638             marks groups sequences)
 639         ;; Go through the infos and gather the data needed to know
 640         ;; what and how to request the data.
 641         (dolist (info infos)
 642           (setq marks (gnus-info-marks info))
 643           (push (list (gnus-group-real-name (gnus-info-group info))
 644                       (cdr (assq 'active marks))
 645                       (cdr (assq 'uid marks)))
 646                 groups))
 647         ;; Then request the data.
 648         (erase-buffer)
 649         (dolist (elem groups)
 650           (if (and qresyncp
 651                    (nth 2 elem))
 652               (push
 653                (list 'qresync
 654                      (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
 655                                           (car elem)
 656                                           (car (nth 2 elem))
 657                                           (cdr (nth 2 elem)))
 658                      nil
 659                      (car elem))
 660                sequences)
 661             (let ((start
 662                    (if (nth 1 elem)
 663                        ;; Fetch the last 100 flags.
 664                        (max 1 (- (cdr (nth 1 elem)) 100))
 665                      1)))
 666               (push (list (nnimap-send-command "EXAMINE %S" (car elem))
 667                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
 668                           start
 669                           (car elem))
 670                     sequences))))
 671         sequences))))
 672
 673 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
 674   (when (and sequences
 675              (nnimap-possibly-change-group nil server))
 676     (with-current-buffer (nnimap-buffer)
 677       ;; Wait for the final data to trickle in.
 678       (nnimap-wait-for-response (cadar sequences))
 679       ;; Now we should have all the data we need, no matter whether
 680       ;; we're QRESYNCING, fetching all the flags from scratch, or
 681       ;; just fetching the last 100 flags per group.
 682       (nnimap-update-infos (nnimap-flags-to-marks
 683                             (nnimap-parse-flags
 684                              (nreverse sequences)))
 685                            infos)
 686       ;; Finally, just return something resembling an active file in
 687       ;; the nntp buffer, so that the agent can save the info, too.
 688       (with-current-buffer nntp-server-buffer
 689         (erase-buffer)
 690         (dolist (info infos)
 691           (let* ((group (gnus-info-group info))
 692                  (active (gnus-active group)))
 693             (when active
 694               (insert (format "%S %d %d y\n"
 695                               (gnus-group-real-name group)
 696                               (cdr active)
 697                               (car active))))))))))
 698
 699 (defun nnimap-update-infos (flags infos)
 700   (dolist (info infos)
 701     (let ((group (gnus-group-real-name (gnus-info-group info))))
 702       (nnimap-update-info info (cdr (assoc group flags))))))
 703
 704 (defun nnimap-update-info (info marks)
 705   (when marks
 706     (destructuring-bind (existing flags high low uidnext start-article) marks
 707       (let ((group (gnus-info-group info))
 708             (completep (and start-article
 709                             (= start-article 1))))
 710         ;; First set the active ranges based on high/low.
 711         (if (or completep
 712                 (not (gnus-active group)))
 713             (gnus-set-active group
 714                              (if high
 715                                  (cons low high)
 716                                ;; No articles in this group.
 717                                (cons (1- uidnext) uidnext)))
 718           (setcdr (gnus-active group) high))
 719         ;; Then update the list of read articles.
 720         (let* ((unread
 721                 (gnus-compress-sequence
 722                  (gnus-set-difference
 723                   (gnus-set-difference
 724                    existing
 725                    (cdr (assoc "\\Seen" flags)))
 726                   (cdr (assoc "\\Flagged" flags)))))
 727                (read (gnus-range-difference
 728                       (cons start-article high) unread)))
 729           (when (> start-article 1)
 730             (setq read
 731                   (gnus-range-nconcat
 732                    (if (> start-article 1)
 733                        (gnus-sorted-range-intersection
 734                         (cons 1 (1- start-article))
 735                         (gnus-info-read info))
 736                      (gnus-info-read info))
 737                    read)))
 738           (gnus-info-set-read info read)
 739           ;; Update the marks.
 740           (setq marks (gnus-info-marks info))
 741           ;; Note the active level for the next run-through.
 742           (let ((active (assq 'active marks)))
 743             (if active
 744                 (setcdr active (gnus-active group))
 745               (push (cons 'active (gnus-active group)) marks)))
 746           (dolist (type (cdr nnimap-mark-alist))
 747             (let ((old-marks (assoc (car type) marks))
 748                   (new-marks (gnus-compress-sequence
 749                               (cdr (assoc (cadr type) flags)))))
 750               (setq marks (delq old-marks marks))
 751               (pop old-marks)
 752               (when (and old-marks
 753                          (> start-article 1))
 754                 (setq old-marks (gnus-range-difference
 755                                  old-marks
 756                                  (cons start-article high)))
 757                 (setq new-marks (gnus-range-nconcat old-marks new-marks)))
 758               (when new-marks
 759                 (push (cons (car type) new-marks) marks)))
 760             (gnus-info-set-marks info marks t)
 761             (nnimap-store-info info (gnus-active group))))))))
 762
 763 (defun nnimap-store-info (info active)
 764   (let* ((group (gnus-group-real-name (gnus-info-group info)))
 765          (entry (assoc group nnimap-current-infos)))
 766     (if entry
 767         (setcdr entry (list info active))
 768       (push (list group info active) nnimap-current-infos))))
 769
 770 (defun nnimap-flags-to-marks (groups)
 771   (let (data group totalp uidnext articles start-article mark)
 772     (dolist (elem groups)
 773       (setq group (car elem)
 774             uidnext (cadr elem)
 775             start-article (caddr elem)
 776             articles (cdddr elem))
 777       (let ((high (caar articles))
 778             marks low existing)
 779         (dolist (article articles)
 780           (setq low (car article))
 781           (push (car article) existing)
 782           (dolist (flag (cdr article))
 783             (setq mark (assoc flag marks))
 784             (if (not mark)
 785                 (push (list flag (car article)) marks)
 786               (setcdr mark (cons (car article) (cdr mark)))))
 787           (push (list group existing marks high low uidnext start-article)
 788                 data))))
 789     data))
 790
 791 (defun nnimap-parse-flags (sequences)
 792   (goto-char (point-min))
 793   (let (start end articles groups uidnext elems)
 794     (dolist (elem sequences)
 795       (destructuring-bind (group-sequence flag-sequence totalp group) elem
 796         ;; The EXAMINE was successful.
 797         (when (and (search-forward (format "\n%d OK " group-sequence) nil t)
 798                    (progn
 799                      (forward-line 1)
 800                      (setq start (point))
 801                      (if (re-search-backward "UIDNEXT \\([0-9]+\\)"
 802                                                (or end (point-min)) t)
 803                          (setq uidnext (string-to-number (match-string 1)))
 804                        (setq uidnext nil))
 805                      (goto-char start))
 806                    ;; The UID FETCH FLAGS was successful.
 807                    (search-forward (format "\n%d OK " flag-sequence) nil t))
 808           (setq end (point))
 809           (goto-char start)
 810           (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" end t)
 811             (setq elems (nnimap-parse-line (match-string 1)))
 812             (push (cons (string-to-number (cadr (member "UID" elems)))
 813                         (cadr (member "FLAGS" elems)))
 814                   articles))
 815           (push (nconc (list group uidnext totalp) articles) groups)
 816           (setq articles nil))))
 817     groups))
 818
 819 (defun nnimap-find-process-buffer (buffer)
 820   (cadr (assoc buffer nnimap-connection-alist)))
 821
 822 (deffoo nnimap-request-post (&optional server)
 823   (setq nnimap-status-string "Read-only server")
 824   nil)
 825
 826 (defun nnimap-possibly-change-group (group server)
 827   (let ((open-result t))
 828     (when (and server
 829                (not (nnimap-server-opened server)))
 830       (setq open-result (nnimap-open-server server)))
 831     (cond
 832      ((not open-result)
 833       nil)
 834      ((not group)
 835       t)
 836      (t
 837       (with-current-buffer (nnimap-buffer)
 838         (if (equal group (nnimap-group nnimap-object))
 839             t
 840           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
 841             (when (car result)
 842               (setf (nnimap-group nnimap-object) group
 843                     (nnimap-select-result nnimap-object) result)
 844               result))))))))
 845
 846 (defun nnimap-find-connection (buffer)
 847   "Find the connection delivering to BUFFER."
 848   (let ((entry (assoc buffer nnimap-connection-alist)))
 849     (when entry
 850       (if (and (buffer-name (cadr entry))
 851                (get-buffer-process (cadr entry))
 852                (memq (process-status (get-buffer-process (cadr entry)))
 853                      '(open run)))
 854           (get-buffer-process (cadr entry))
 855         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
 856         nil))))
 857
 858 (defvar nnimap-sequence 0)
 859
 860 (defun nnimap-send-command (&rest args)
 861   (process-send-string
 862    (get-buffer-process (current-buffer))
 863    (nnimap-log-command
 864     (format "%d %s%s\n"
 865             (incf nnimap-sequence)
 866             (apply #'format args)
 867             (if (nnimap-newlinep nnimap-object)
 868                 ""
 869               "\r"))))
 870   nnimap-sequence)
 871
 872 (defun nnimap-log-command (command)
 873   (with-current-buffer (get-buffer-create "*imap log*")
 874     (goto-char (point-max))
 875     (insert (format-time-string "%H:%M:%S") " " command))
 876   command)
 877
 878 (defun nnimap-command (&rest args)
 879   (erase-buffer)
 880   (let* ((sequence (apply #'nnimap-send-command args))
 881          (response (nnimap-get-response sequence)))
 882     (if (equal (caar response) "OK")
 883         (cons t response)
 884       (nnheader-report 'nnimap "%s"
 885                        (mapconcat (lambda (a)
 886                                     (format "%s" a))
 887                                   (car response) " "))
 888       nil)))
 889
 890 (defun nnimap-get-response (sequence)
 891   (nnimap-wait-for-response sequence)
 892   (nnimap-parse-response))
 893
 894 (defun nnimap-wait-for-connection ()
 895   (let ((process (get-buffer-process (current-buffer))))
 896     (goto-char (point-min))
 897     (while (and (memq (process-status process)
 898                       '(open run))
 899                 (not (re-search-forward "^\\* .*\n" nil t)))
 900       (nnheader-accept-process-output process)
 901       (goto-char (point-min)))
 902     (forward-line -1)
 903     (and (looking-at "\\* \\([A-Z0-9]+\\)")
 904          (match-string 1))))
 905
 906 (defun nnimap-wait-for-response (sequence &optional messagep)
 907   (let ((process (get-buffer-process (current-buffer))))
 908     (goto-char (point-max))
 909     (while (and (memq (process-status process)
 910                       '(open run))
 911                 (not (re-search-backward (format "^%d .*\n" sequence)
 912                                          (max (point-min) (- (point) 500))
 913                                          t)))
 914       (when messagep
 915         (message "Read %dKB" (/ (buffer-size) 1000)))
 916       (nnheader-accept-process-output process)
 917       (goto-char (point-max)))))
 918
 919 (defun nnimap-parse-response ()
 920   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
 921         result)
 922     (dolist (line lines)
 923       (push (cdr (nnimap-parse-line line)) result))
 924     ;; Return the OK/error code first, and then all the "continuation
 925     ;; lines" afterwards.
 926     (cons (pop result)
 927           (nreverse result))))
 928
 929 ;; Parse an IMAP response line lightly.  They look like
 930 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
 931 ;; the lines into a list of strings and lists of string.
 932 (defun nnimap-parse-line (line)
 933   (let (char result)
 934     (with-temp-buffer
 935       (insert line)
 936       (goto-char (point-min))
 937       (while (not (eobp))
 938         (if (eql (setq char (following-char)) ? )
 939             (forward-char 1)
 940           (push
 941            (cond
 942             ((eql char ?\[)
 943              (split-string (buffer-substring
 944                             (1+ (point)) (1- (search-forward "]")))))
 945             ((eql char ?\()
 946              (split-string (buffer-substring
 947                             (1+ (point)) (1- (search-forward ")")))))
 948             ((eql char ?\")
 949              (forward-char 1)
 950              (buffer-substring (point) (1- (search-forward "\""))))
 951             (t
 952              (buffer-substring (point) (if (search-forward " " nil t)
 953                                            (1- (point))
 954                                          (goto-char (point-max))))))
 955            result)))
 956       (nreverse result))))
 957
 958 (defun nnimap-last-response-string ()
 959   (save-excursion
 960     (forward-line 1)
 961     (let ((end (point)))
 962       (forward-line -1)
 963       (when (not (bobp))
 964         (forward-line -1)
 965         (while (and (not (bobp))
 966                     (eql (following-char) ?*))
 967           (forward-line -1))
 968         (unless (eql (following-char) ?*)
 969           (forward-line 1)))
 970       (buffer-substring (point) end))))
 971
 972 (defun nnimap-get-responses (sequences)
 973   (let (responses)
 974     (dolist (sequence sequences)
 975       (goto-char (point-min))
 976       (when (re-search-forward (format "^%d " sequence) nil t)
 977         (push (list sequence (nnimap-parse-response))
 978               responses)))
 979     responses))
 980
 981 (defvar nnimap-incoming-split-list nil)
 982
 983 (defun nnimap-fetch-inbox (articles)
 984   (erase-buffer)
 985   (nnimap-wait-for-response
 986    (nnimap-send-command
 987     "UID FETCH %s %s"
 988     (nnimap-article-ranges articles)
 989     (format "(UID %s%s)"
 990             (format
 991              (if (member "IMAP4REV1"
 992                          (nnimap-capabilities nnimap-object))
 993                  "BODY.PEEK[HEADER] BODY.PEEK"
 994                "RFC822.PEEK"))
 995             (if nnimap-split-download-body-default
 996                 "[]"
 997               "[1]")))
 998    t))
 999
1000 (defun nnimap-split-incoming-mail ()
1001   (with-current-buffer (nnimap-buffer)
1002     (let ((nnimap-incoming-split-list nil)
1003           (nnmail-split-methods nnimap-split-methods)
1004           (nnmail-inhibit-default-split-group t)
1005           (groups (nnimap-get-groups))
1006           new-articles)
1007       (erase-buffer)
1008       (nnimap-command "SELECT %S" nnimap-inbox)
1009       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1010       (when new-articles
1011         (nnimap-fetch-inbox new-articles)
1012         (nnimap-transform-split-mail)
1013         (nnheader-ms-strip-cr)
1014         (nnmail-cache-open)
1015         (nnmail-split-incoming (current-buffer)
1016                                #'nnimap-save-mail-spec
1017                                nil nil
1018                                #'nnimap-dummy-active-number)
1019         (when nnimap-incoming-split-list
1020           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1021                 sequences)
1022             ;; Create any groups that doesn't already exist on the
1023             ;; server first.
1024             (dolist (spec specs)
1025               (unless (member (car spec) groups)
1026                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1027             ;; Then copy over all the messages.
1028             (erase-buffer)
1029             (dolist (spec specs)
1030               (let ((group (car spec))
1031                     (ranges (cdr spec)))
1032                 (push (list (nnimap-send-command "UID COPY %s %S"
1033                                                  (nnimap-article-ranges ranges)
1034                                                  (utf7-encode group t))
1035                             ranges)
1036                       sequences)))
1037             ;; Wait for the last COPY response...
1038             (when sequences
1039               (nnimap-wait-for-response (caar sequences))
1040               ;; And then mark the successful copy actions as deleted,
1041               ;; and possibly expunge them.
1042               (nnimap-mark-and-expunge-incoming
1043                (nnimap-parse-copied-articles sequences)))))))))
1044
1045 (defun nnimap-mark-and-expunge-incoming (range)
1046   (when range
1047     (setq range (nnimap-article-ranges range))
1048     (nnimap-send-command
1049      "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)
1050     (cond
1051      ;; If the server supports it, we now delete the message we have
1052      ;; just copied over.
1053      ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
1054       (nnimap-send-command "UID EXPUNGE %s" range))
1055      ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1056      ;; user has configured it.
1057      (nnimap-expunge-inbox
1058       (nnimap-send-command "EXPUNGE")))))
1059
1060 (defun nnimap-parse-copied-articles (sequences)
1061   (let (sequence copied range)
1062     (goto-char (point-min))
1063     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1064       (setq sequence (string-to-number (match-string 1)))
1065       (when (setq range (cadr (assq sequence sequences)))
1066         (push (gnus-uncompress-range range) copied)))
1067     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1068
1069 (defun nnimap-new-articles (flags)
1070   (let (new)
1071     (dolist (elem flags)
1072       (when (or (null (cdr elem))
1073                 (and (not (member "\\Deleted" (cdr elem)))
1074                      (not (member "\\Seen" (cdr elem)))))
1075         (push (car elem) new)))
1076     (gnus-compress-sequence (nreverse new))))
1077
1078 (defun nnimap-make-split-specs (list)
1079   (let ((specs nil)
1080         entry)
1081     (dolist (elem list)
1082       (destructuring-bind (article spec) elem
1083         (dolist (group (delete nil (mapcar #'car spec)))
1084           (unless (setq entry (assoc group specs))
1085             (push (setq entry (list group)) specs))
1086           (setcdr entry (cons article (cdr entry))))))
1087     (dolist (entry specs)
1088       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1089     specs))
1090
1091 (defun nnimap-transform-split-mail ()
1092   (goto-char (point-min))
1093   (let (article bytes)
1094     (block nil
1095       (while (not (eobp))
1096         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1097           (delete-region (point) (progn (forward-line 1) (point)))
1098           (when (eobp)
1099             (return)))
1100         (setq article (match-string 1)
1101               bytes (nnimap-get-length))
1102         (delete-region (line-beginning-position) (line-end-position))
1103         ;; Insert MMDF separator, and a way to remember what this
1104         ;; article UID is.
1105         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1106         (forward-char (1+ bytes))
1107         (setq bytes (nnimap-get-length))
1108         (delete-region (line-beginning-position) (line-end-position))
1109         (forward-char (1+ bytes))
1110         (delete-region (line-beginning-position) (line-end-position))))))
1111
1112 (defun nnimap-dummy-active-number (group &optional server)
1113   1)
1114
1115 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1116   (let (article)
1117     (goto-char (point-min))
1118     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1119         (error "Invalid nnimap mail")
1120       (setq article (string-to-number (match-string 1))))
1121     (push (list article group-art)
1122           nnimap-incoming-split-list)))
1123
1124 (provide 'nnimap)
1125
1126 ;;; nnimap.el ends here