cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 ;; For Emacs <22.2 and XEmacs.
  30 (eval-and-compile
  31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  32
  33 (eval-and-compile
  34   (require 'nnheader)
  35   ;; In Emacs 24, `open-protocol-stream' is an autoloaded alias for
  36   ;; `make-network-stream'.
  37   (unless (fboundp 'open-protocol-stream)
  38     (require 'proto-stream)))
  39
  40 (eval-when-compile
  41   (require 'cl))
  42
  43 (require 'nnheader)
  44 (require 'gnus-util)
  45 (require 'gnus)
  46 (require 'nnoo)
  47 (require 'netrc)
  48 (require 'utf7)
  49 (require 'tls)
  50 (require 'parse-time)
  51 (require 'nnmail)
  52
  53 (autoload 'auth-source-forget+ "auth-source")
  54 (autoload 'auth-source-search "auth-source")
  55
  56 (nnoo-declare nnimap)
  57
  58 (defvoo nnimap-address nil
  59   "The address of the IMAP server.")
  60
  61 (defvoo nnimap-user nil
  62   "Username to use for authentication to the IMAP server.")
  63
  64 (defvoo nnimap-server-port nil
  65   "The IMAP port used.
  66 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  67 it will default to `imap'.")
  68
  69 (defvoo nnimap-stream 'undecided
  70   "How nnimap talks to the IMAP server.
  71 The value should be either `undecided', `ssl' or `tls',
  72 `network', `starttls', `plain', or `shell'.
  73
  74 If the value is `undecided', nnimap tries `ssl' first, then falls
  75 back on `network'.")
  76
  77 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  78                                  (if (listp imap-shell-program)
  79                                      (car imap-shell-program)
  80                                    imap-shell-program)
  81                                "ssh %s imapd"))
  82
  83 (defvoo nnimap-inbox nil
  84   "The mail box where incoming mail arrives and should be split out of.
  85 This can be a string or a list of strings
  86 For example, \"INBOX\" or (\"INBOX\" \"SENT\").")
  87
  88 (defvoo nnimap-split-methods nil
  89   "How mail is split.
  90 Uses the same syntax as `nnmail-split-methods'.")
  91
  92 (defvoo nnimap-split-fancy nil
  93   "Uses the same syntax as `nnmail-split-fancy'.")
  94
  95 (defvoo nnimap-unsplittable-articles '(%Deleted %Seen)
  96   "Articles with the flags in the list will not be considered when splitting.")
  97
  98 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  99                         "Emacs 24.1")
 100
 101 (defvoo nnimap-authenticator nil
 102   "How nnimap authenticate itself to the server.
 103 Possible choices are nil (use default methods) or `anonymous'.")
 104
 105 (defvoo nnimap-expunge t
 106   "If non-nil, expunge articles after deleting them.
 107 This is always done if the server supports UID EXPUNGE, but it's
 108 not done by default on servers that doesn't support that command.")
 109
 110 (defvoo nnimap-streaming t
 111   "If non-nil, try to use streaming commands with IMAP servers.
 112 Switching this off will make nnimap slower, but it helps with
 113 some servers.")
 114
 115 (defvoo nnimap-connection-alist nil)
 116
 117 (defvoo nnimap-current-infos nil)
 118
 119 (defvoo nnimap-fetch-partial-articles nil
 120   "If non-nil, Gnus will fetch partial articles.
 121 If t, Gnus will fetch only the first part.  If a string, it
 122 will fetch all parts that have types that match that string.  A
 123 likely value would be \"text/\" to automatically fetch all
 124 textual parts.")
 125
 126 (defgroup nnimap nil
 127   "IMAP for Gnus."
 128   :group 'gnus)
 129
 130 (defcustom nnimap-request-articles-find-limit nil
 131   "Limit the number of articles to look for after moving an article."
 132   :type 'integer
 133   :version "24.3"
 134   :group 'nnimap)
 135
 136 (defvar nnimap-process nil)
 137
 138 (defvar nnimap-status-string "")
 139
 140 (defvar nnimap-split-download-body-default nil
 141   "Internal variable with default value for `nnimap-split-download-body'.")
 142
 143 (defvar nnimap-keepalive-timer nil)
 144 (defvar nnimap-process-buffers nil)
 145
 146 (defstruct nnimap
 147   group process commands capabilities select-result newlinep server
 148   last-command-time greeting examined stream-type initial-resync)
 149
 150 (defvar nnimap-object nil)
 151
 152 (defvar nnimap-mark-alist
 153   '((read "\\Seen" %Seen)
 154     (tick "\\Flagged" %Flagged)
 155     (reply "\\Answered" %Answered)
 156     (expire "gnus-expire")
 157     (dormant "gnus-dormant")
 158     (score "gnus-score")
 159     (save "gnus-save")
 160     (download "gnus-download")
 161     (forward "gnus-forward")))
 162
 163 (defvar nnimap-quirks
 164   '(("QRESYNC" "Zimbra" "QRESYNC ")))
 165
 166 (defvar nnimap-inhibit-logging nil)
 167
 168 (defun nnimap-buffer ()
 169   (nnimap-find-process-buffer nntp-server-buffer))
 170
 171 (defun nnimap-header-parameters ()
 172   (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 173           (format
 174            (if (nnimap-ver4-p)
 175                "BODY.PEEK[HEADER.FIELDS %s]"
 176              "RFC822.HEADER.LINES %s")
 177            (append '(Subject From Date Message-Id
 178                              References In-Reply-To Xref)
 179                    nnmail-extra-headers))))
 180
 181 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 182   (when group
 183     (setq group (nnimap-decode-gnus-group group)))
 184   (with-current-buffer nntp-server-buffer
 185     (erase-buffer)
 186     (when (nnimap-change-group group server)
 187       (with-current-buffer (nnimap-buffer)
 188         (erase-buffer)
 189         (nnimap-wait-for-response
 190          (nnimap-send-command
 191           "UID FETCH %s %s"
 192           (nnimap-article-ranges (gnus-compress-sequence articles))
 193           (nnimap-header-parameters))
 194          t)
 195         (nnimap-transform-headers)
 196         (nnheader-remove-cr-followed-by-lf))
 197       (insert-buffer-substring
 198        (nnimap-find-process-buffer (current-buffer))))
 199     'headers))
 200
 201 (defun nnimap-transform-headers ()
 202   (goto-char (point-min))
 203   (let (article lines size string)
 204     (block nil
 205       (while (not (eobp))
 206         (while (not (looking-at "\\* [0-9]+ FETCH"))
 207           (delete-region (point) (progn (forward-line 1) (point)))
 208           (when (eobp)
 209             (return)))
 210         (goto-char (match-end 0))
 211         ;; Unfold quoted {number} strings.
 212         (while (re-search-forward
 213                 "[^]][ (]{\\([0-9]+\\)}\r?\n"
 214                 (save-excursion
 215                   ;; Start of the header section.
 216                   (or (re-search-forward "] {[0-9]+}\r?\n" nil t)
 217                       ;; Start of the next FETCH.
 218                       (re-search-forward "\\* [0-9]+ FETCH" nil t)
 219                       (point-max)))
 220                 t)
 221           (setq size (string-to-number (match-string 1)))
 222           (delete-region (+ (match-beginning 0) 2) (point))
 223           (setq string (buffer-substring (point) (+ (point) size)))
 224           (delete-region (point) (+ (point) size))
 225           (insert (format "%S" (mm-subst-char-in-string ?\n ?\s string))))
 226         (beginning-of-line)
 227         (setq article
 228               (and (re-search-forward "UID \\([0-9]+\\)" (line-end-position)
 229                                       t)
 230                    (match-string 1)))
 231         (setq lines nil)
 232         (setq size
 233               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 234                                       (line-end-position)
 235                                       t)
 236                    (match-string 1)))
 237         (beginning-of-line)
 238         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 239           (let ((structure (ignore-errors
 240                              (read (current-buffer)))))
 241             (while (and (consp structure)
 242                         (not (atom (car structure))))
 243               (setq structure (car structure)))
 244             (setq lines (if (and
 245                              (stringp (car structure))
 246                              (equal (upcase (nth 0 structure)) "MESSAGE")
 247                              (equal (upcase (nth 1 structure)) "RFC822"))
 248                             (nth 9 structure)
 249                           (nth 7 structure)))))
 250         (delete-region (line-beginning-position) (line-end-position))
 251         (insert (format "211 %s Article retrieved." article))
 252         (forward-line 1)
 253         (when size
 254           (insert (format "Chars: %s\n" size)))
 255         (when lines
 256           (insert (format "Lines: %s\n" lines)))
 257         (unless (re-search-forward "^\r$" nil t)
 258           (goto-char (point-max)))
 259         (delete-region (line-beginning-position) (line-end-position))
 260         (insert ".")
 261         (forward-line 1)))))
 262
 263 (defun nnimap-unfold-quoted-lines ()
 264   ;; Unfold quoted {number} strings.
 265   (let (size string)
 266     (while (re-search-forward " {\\([0-9]+\\)}\r?\n" nil t)
 267       (setq size (string-to-number (match-string 1)))
 268       (delete-region (1+ (match-beginning 0)) (point))
 269       (setq string (buffer-substring (point) (+ (point) size)))
 270       (delete-region (point) (+ (point) size))
 271       (insert (format "%S" string)))))
 272
 273 (defun nnimap-get-length ()
 274   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 275        (string-to-number (match-string 1))))
 276
 277 (defun nnimap-article-ranges (ranges)
 278   (let (result)
 279     (cond
 280      ((numberp ranges)
 281       (number-to-string ranges))
 282      ((numberp (cdr ranges))
 283       (format "%d:%d" (car ranges) (cdr ranges)))
 284      (t
 285       (dolist (elem ranges)
 286         (push
 287          (if (consp elem)
 288              (format "%d:%d" (car elem) (cdr elem))
 289            (number-to-string elem))
 290          result))
 291       (mapconcat #'identity (nreverse result) ",")))))
 292
 293 (deffoo nnimap-open-server (server &optional defs no-reconnect)
 294   (if (nnimap-server-opened server)
 295       t
 296     (unless (assq 'nnimap-address defs)
 297       (setq defs (append defs (list (list 'nnimap-address server)))))
 298     (nnoo-change-server 'nnimap server defs)
 299     (if no-reconnect
 300         (nnimap-find-connection nntp-server-buffer)
 301       (or (nnimap-find-connection nntp-server-buffer)
 302           (nnimap-open-connection nntp-server-buffer)))))
 303
 304 (defun nnimap-make-process-buffer (buffer)
 305   (with-current-buffer
 306       (generate-new-buffer (format " *nnimap %s %s %s*"
 307                                    nnimap-address nnimap-server-port
 308                                    (gnus-buffer-exists-p buffer)))
 309     (mm-disable-multibyte)
 310     (buffer-disable-undo)
 311     (gnus-add-buffer)
 312     (set (make-local-variable 'after-change-functions) nil)
 313     (set (make-local-variable 'nnimap-object)
 314          (make-nnimap :server (nnoo-current-server 'nnimap)
 315                       :initial-resync 0))
 316     (push (list buffer (current-buffer)) nnimap-connection-alist)
 317     (push (current-buffer) nnimap-process-buffers)
 318     (current-buffer)))
 319
 320 (defun nnimap-credentials (address ports user)
 321   (let* ((auth-source-creation-prompts
 322           '((user  . "IMAP user at %h: ")
 323             (secret . "IMAP password for %u@%h: ")))
 324          (found (nth 0 (auth-source-search :max 1
 325                                            :host address
 326                                            :port ports
 327                                            :user user
 328                                            :require '(:user :secret)
 329                                            :create t))))
 330     (if found
 331         (list (plist-get found :user)
 332               (let ((secret (plist-get found :secret)))
 333                 (if (functionp secret)
 334                     (funcall secret)
 335                   secret))
 336               (plist-get found :save-function))
 337       nil)))
 338
 339 (defun nnimap-keepalive ()
 340   (let ((now (current-time)))
 341     (dolist (buffer nnimap-process-buffers)
 342       (when (buffer-name buffer)
 343         (with-current-buffer buffer
 344           (when (and nnimap-object
 345                      (nnimap-last-command-time nnimap-object)
 346                      (> (gnus-float-time
 347                          (time-subtract
 348                           now
 349                           (nnimap-last-command-time nnimap-object)))
 350                         ;; More than five minutes since the last command.
 351                         (* 5 60)))
 352             (nnimap-send-command "NOOP")))))))
 353
 354 (defun nnimap-open-connection (buffer)
 355   ;; Be backwards-compatible -- the earlier value of nnimap-stream was
 356   ;; `ssl' when nnimap-server-port was nil.  Sort of.
 357   (when (and nnimap-server-port
 358              (eq nnimap-stream 'undecided))
 359     (setq nnimap-stream 'ssl))
 360   (let ((stream
 361          (if (eq nnimap-stream 'undecided)
 362              (loop for type in '(ssl network)
 363                    for stream = (let ((nnimap-stream type))
 364                                   (nnimap-open-connection-1 buffer))
 365                    while (eq stream 'no-connect)
 366                    finally (return stream))
 367            (nnimap-open-connection-1 buffer))))
 368     (if (eq stream 'no-connect)
 369         nil
 370       stream)))
 371
 372 (defun nnimap-map-port (port)
 373   (if (equal port "imaps")
 374       "993"
 375     port))
 376
 377 (defun nnimap-open-connection-1 (buffer)
 378   (unless nnimap-keepalive-timer
 379     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 380                                               'nnimap-keepalive)))
 381   (with-current-buffer (nnimap-make-process-buffer buffer)
 382     (let* ((coding-system-for-read 'binary)
 383            (coding-system-for-write 'binary)
 384            (ports
 385             (cond
 386              ((memq nnimap-stream '(network plain starttls))
 387               (nnheader-message 7 "Opening connection to %s..."
 388                                 nnimap-address)
 389               '("imap" "143"))
 390              ((eq nnimap-stream 'shell)
 391               (nnheader-message 7 "Opening connection to %s via shell..."
 392                                 nnimap-address)
 393               '("imap"))
 394              ((memq nnimap-stream '(ssl tls))
 395               (nnheader-message 7 "Opening connection to %s via tls..."
 396                                 nnimap-address)
 397               '("imaps" "imap" "993" "143"))
 398              (t
 399               (error "Unknown stream type: %s" nnimap-stream))))
 400            login-result credentials)
 401       (when nnimap-server-port
 402         (push nnimap-server-port ports))
 403       (let* ((stream-list
 404               (open-protocol-stream
 405                "*nnimap*" (current-buffer) nnimap-address
 406                (nnimap-map-port (car ports))
 407                :type nnimap-stream
 408                :return-list t
 409                :shell-command nnimap-shell-program
 410                :capability-command "1 CAPABILITY\r\n"
 411                :end-of-command "\r\n"
 412                :success " OK "
 413                :starttls-function
 414                (lambda (capabilities)
 415                  (when (gnus-string-match-p "STARTTLS" capabilities)
 416                    "1 STARTTLS\r\n"))))
 417              (stream (car stream-list))
 418              (props (cdr stream-list))
 419              (greeting (plist-get props :greeting))
 420              (capabilities (plist-get props :capabilities))
 421              (stream-type (plist-get props :type)))
 422         (when (and stream (not (memq (process-status stream) '(open run))))
 423           (setq stream nil))
 424
 425         (when (and (fboundp 'set-network-process-option) ;; Not in XEmacs.
 426                    (fboundp 'process-type) ;; Emacs 22 doesn't provide it.
 427                    (eq (process-type stream) 'network))
 428           ;; Use TCP-keepalive so that connections that pass through a NAT
 429           ;; router don't hang when left idle.
 430           (set-network-process-option stream :keepalive t))
 431
 432         (setf (nnimap-process nnimap-object) stream)
 433         (setf (nnimap-stream-type nnimap-object) stream-type)
 434         (if (not stream)
 435             (progn
 436               (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 437                                nnimap-address (car ports) nnimap-stream)
 438               'no-connect)
 439           (gnus-set-process-query-on-exit-flag stream nil)
 440           (if (not (gnus-string-match-p "[*.] \\(OK\\|PREAUTH\\)" greeting))
 441               (nnheader-report 'nnimap "%s" greeting)
 442             ;; Store the greeting (for debugging purposes).
 443             (setf (nnimap-greeting nnimap-object) greeting)
 444             (setf (nnimap-capabilities nnimap-object)
 445                   (mapcar #'upcase
 446                           (split-string capabilities)))
 447             (unless (gnus-string-match-p "[*.] PREAUTH" greeting)
 448               (if (not (setq credentials
 449                              (if (eq nnimap-authenticator 'anonymous)
 450                                  (list "anonymous"
 451                                        (message-make-address))
 452                                ;; Look for the credentials based on
 453                                ;; the virtual server name and the address
 454                                (nnimap-credentials
 455                                 (gnus-delete-duplicates
 456                                  (list
 457                                   nnimap-address
 458                                   (nnoo-current-server 'nnimap)))
 459                                 ports
 460                                 nnimap-user))))
 461                   (setq nnimap-object nil)
 462                 (let ((nnimap-inhibit-logging t))
 463                   (setq login-result
 464                         (nnimap-login (car credentials) (cadr credentials))))
 465                 (if (car login-result)
 466                     (progn
 467                       ;; Save the credentials if a save function exists
 468                       ;; (such a function will only be passed if a new
 469                       ;; token was created).
 470                       (when (functionp (nth 2 credentials))
 471                         (funcall (nth 2 credentials)))
 472                       ;; See if CAPABILITY is set as part of login
 473                       ;; response.
 474                       (dolist (response (cddr login-result))
 475                         (when (string= "CAPABILITY" (upcase (car response)))
 476                           (setf (nnimap-capabilities nnimap-object)
 477                                 (mapcar #'upcase (cdr response))))))
 478                   ;; If the login failed, then forget the credentials
 479                   ;; that are now possibly cached.
 480                   (dolist (host (list (nnoo-current-server 'nnimap)
 481                                       nnimap-address))
 482                     (dolist (port ports)
 483                       (auth-source-forget+ :host host :port port)))
 484                   (delete-process (nnimap-process nnimap-object))
 485                   (setq nnimap-object nil))))
 486             (when nnimap-object
 487               (when (nnimap-capability "QRESYNC")
 488                 (nnimap-command "ENABLE QRESYNC"))
 489               (nnheader-message 7 "Opening connection to %s...done"
 490                                 nnimap-address)
 491               (nnimap-process nnimap-object))))))))
 492
 493 (autoload 'rfc2104-hash "rfc2104")
 494
 495 (defun nnimap-login (user password)
 496   (cond
 497    ;; Prefer plain LOGIN if it's enabled (since it requires fewer
 498    ;; round trips than CRAM-MD5, and it's less likely to be buggy),
 499    ;; and we're using an encrypted connection.
 500    ((and (not (nnimap-capability "LOGINDISABLED"))
 501          (eq (nnimap-stream-type nnimap-object) 'tls))
 502     (nnimap-command "LOGIN %S %S" user password))
 503    ((nnimap-capability "AUTH=CRAM-MD5")
 504     (erase-buffer)
 505     (let ((sequence (nnimap-send-command "AUTHENTICATE CRAM-MD5"))
 506           (challenge (nnimap-wait-for-line "^\\+\\(.*\\)\n")))
 507       (process-send-string
 508        (get-buffer-process (current-buffer))
 509        (concat
 510         (base64-encode-string
 511          (concat user " "
 512                  (rfc2104-hash 'md5 64 16 password
 513                                (base64-decode-string challenge))))
 514         "\r\n"))
 515       (nnimap-wait-for-response sequence)))
 516    ((not (nnimap-capability "LOGINDISABLED"))
 517     (nnimap-command "LOGIN %S %S" user password))
 518    ((nnimap-capability "AUTH=PLAIN")
 519     (nnimap-command
 520      "AUTHENTICATE PLAIN %s"
 521      (base64-encode-string
 522       (format "\000%s\000%s"
 523               (nnimap-quote-specials user)
 524               (nnimap-quote-specials password)))))))
 525
 526 (defun nnimap-quote-specials (string)
 527   (with-temp-buffer
 528     (insert string)
 529     (goto-char (point-min))
 530     (while (re-search-forward "[\\\"]" nil t)
 531       (forward-char -1)
 532       (insert "\\")
 533       (forward-char 1))
 534     (buffer-string)))
 535
 536 (defun nnimap-find-parameter (parameter elems)
 537   (let (result)
 538     (dolist (elem elems)
 539       (cond
 540        ((equal (car elem) parameter)
 541         (setq result (cdr elem)))
 542        ((and (equal (car elem) "OK")
 543              (consp (cadr elem))
 544              (equal (caadr elem) parameter))
 545         (setq result (cdr (cadr elem))))))
 546     result))
 547
 548 (deffoo nnimap-close-server (&optional server)
 549   (when (nnoo-change-server 'nnimap server nil)
 550     (ignore-errors
 551       (delete-process (get-buffer-process (nnimap-buffer))))
 552     (nnoo-close-server 'nnimap server)
 553     t))
 554
 555 (deffoo nnimap-request-close ()
 556   t)
 557
 558 (deffoo nnimap-server-opened (&optional server)
 559   (and (nnoo-current-server-p 'nnimap server)
 560        nntp-server-buffer
 561        (gnus-buffer-live-p nntp-server-buffer)
 562        (nnimap-find-connection nntp-server-buffer)))
 563
 564 (deffoo nnimap-status-message (&optional server)
 565   nnimap-status-string)
 566
 567 (deffoo nnimap-request-article (article &optional group server to-buffer)
 568   (when group
 569     (setq group (nnimap-decode-gnus-group group)))
 570   (with-current-buffer nntp-server-buffer
 571     (let ((result (nnimap-change-group group server))
 572           parts structure)
 573       (when (stringp article)
 574         (setq article (nnimap-find-article-by-message-id group server article)))
 575       (when (and result
 576                  article)
 577         (erase-buffer)
 578         (with-current-buffer (nnimap-buffer)
 579           (erase-buffer)
 580           (when nnimap-fetch-partial-articles
 581             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 582             (goto-char (point-min))
 583             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 584               (setq structure (ignore-errors
 585                                 (let ((start (point)))
 586                                   (forward-sexp 1)
 587                                   (downcase-region start (point))
 588                                   (goto-char start)
 589                                   (read (current-buffer))))
 590                     parts (nnimap-find-wanted-parts structure))))
 591           (when (if parts
 592                     (nnimap-get-partial-article article parts structure)
 593                   (nnimap-get-whole-article article))
 594             (let ((buffer (current-buffer)))
 595               (with-current-buffer (or to-buffer nntp-server-buffer)
 596                 (nnheader-insert-buffer-substring buffer)
 597                 (nnheader-ms-strip-cr)))
 598             (cons group article)))))))
 599
 600 (deffoo nnimap-request-head (article &optional group server to-buffer)
 601   (when group
 602     (setq group (nnimap-decode-gnus-group group)))
 603   (when (nnimap-change-group group server)
 604     (with-current-buffer (nnimap-buffer)
 605       (when (stringp article)
 606         (setq article (nnimap-find-article-by-message-id group server article)))
 607       (if (null article)
 608           nil
 609         (nnimap-get-whole-article
 610          article (format "UID FETCH %%d %s"
 611                          (nnimap-header-parameters)))
 612         (let ((buffer (current-buffer)))
 613           (with-current-buffer (or to-buffer nntp-server-buffer)
 614             (erase-buffer)
 615             (insert-buffer-substring buffer)
 616             (nnheader-ms-strip-cr)
 617             (cons group article)))))))
 618
 619 (defun nnimap-get-whole-article (article &optional command)
 620   (let ((result
 621          (nnimap-command
 622           (or command
 623               (if (nnimap-ver4-p)
 624                   "UID FETCH %d BODY.PEEK[]"
 625                 "UID FETCH %d RFC822.PEEK"))
 626           article)))
 627     ;; Check that we really got an article.
 628     (goto-char (point-min))
 629     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 630       (setq result nil))
 631     (when result
 632       ;; Remove any data that may have arrived before the FETCH data.
 633       (beginning-of-line)
 634       (unless (bobp)
 635         (delete-region (point-min) (point)))
 636       (let ((bytes (nnimap-get-length)))
 637         (delete-region (line-beginning-position)
 638                        (progn (forward-line 1) (point)))
 639         (goto-char (+ (point) bytes))
 640         (delete-region (point) (point-max)))
 641       t)))
 642
 643 (defun nnimap-capability (capability)
 644   (member capability (nnimap-capabilities nnimap-object)))
 645
 646 (defun nnimap-ver4-p ()
 647   (nnimap-capability "IMAP4REV1"))
 648
 649 (defun nnimap-get-partial-article (article parts structure)
 650   (let ((result
 651          (nnimap-command
 652           "UID FETCH %d (%s %s)"
 653           article
 654           (if (nnimap-ver4-p)
 655               "BODY.PEEK[HEADER]"
 656             "RFC822.HEADER")
 657           (if (nnimap-ver4-p)
 658               (mapconcat (lambda (part)
 659                            (format "BODY.PEEK[%s]" part))
 660                          parts " ")
 661             (mapconcat (lambda (part)
 662                          (format "RFC822.PEEK[%s]" part))
 663                        parts " ")))))
 664     (when result
 665       (nnimap-convert-partial-article structure))))
 666
 667 (defun nnimap-convert-partial-article (structure)
 668   ;; First just skip past the headers.
 669   (goto-char (point-min))
 670   (let ((bytes (nnimap-get-length))
 671         id parts)
 672     ;; Delete "FETCH" line.
 673     (delete-region (line-beginning-position)
 674                    (progn (forward-line 1) (point)))
 675     (goto-char (+ (point) bytes))
 676     ;; Collect all the body parts.
 677     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 678       (setq id (match-string 1)
 679             bytes (or (nnimap-get-length) 0))
 680       (beginning-of-line)
 681       (delete-region (point) (progn (forward-line 1) (point)))
 682       (push (list id (buffer-substring (point) (+ (point) bytes)))
 683             parts)
 684       (delete-region (point) (+ (point) bytes)))
 685     ;; Delete trailing junk.
 686     (delete-region (point) (point-max))
 687     ;; Now insert all the parts again where they fit in the structure.
 688     (nnimap-insert-partial-structure structure parts)
 689     t))
 690
 691 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 692   (let (type boundary)
 693     (let ((bstruc structure))
 694       (while (consp (car bstruc))
 695         (pop bstruc))
 696       (setq type (car bstruc))
 697       (setq bstruc (car (cdr bstruc)))
 698       (let ((has-boundary (member "boundary" bstruc)))
 699         (when has-boundary
 700           (setq boundary (cadr has-boundary)))))
 701     (when subp
 702       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 703                       (downcase type) boundary)))
 704     (while (not (stringp (car structure)))
 705       (insert "\n--" boundary "\n")
 706       (if (consp (caar structure))
 707           (nnimap-insert-partial-structure (pop structure) parts t)
 708         (let ((bit (pop structure)))
 709           (insert (format "Content-type: %s/%s"
 710                           (downcase (nth 0 bit))
 711                           (downcase (nth 1 bit))))
 712           (if (member-ignore-case "CHARSET" (nth 2 bit))
 713               (insert (format
 714                        "; charset=%S\n"
 715                        (cadr (member-ignore-case "CHARSET" (nth 2 bit)))))
 716             (insert "\n"))
 717           (insert (format "Content-transfer-encoding: %s\n"
 718                           (nth 5 bit)))
 719           (insert "\n")
 720           (when (assoc (nth 9 bit) parts)
 721             (insert (cadr (assoc (nth 9 bit) parts)))))))
 722     (insert "\n--" boundary "--\n")))
 723
 724 (defun nnimap-find-wanted-parts (structure)
 725   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 726
 727 (defun nnimap-find-wanted-parts-1 (structure prefix)
 728   (let ((num 1)
 729         parts)
 730     (while (consp (car structure))
 731       (let ((sub (pop structure)))
 732         (if (consp (car sub))
 733             (push (nnimap-find-wanted-parts-1
 734                    sub (if (string= prefix "")
 735                            (number-to-string num)
 736                          (format "%s.%s" prefix num)))
 737                   parts)
 738           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 739                 (id (if (string= prefix "")
 740                         (number-to-string num)
 741                       (format "%s.%s" prefix num))))
 742             (setcar (nthcdr 9 sub) id)
 743             (when (if (eq nnimap-fetch-partial-articles t)
 744                       (equal id "1")
 745                     (string-match nnimap-fetch-partial-articles type))
 746               (push id parts))))
 747         (incf num)))
 748     (nreverse parts)))
 749
 750 (defun nnimap-decode-gnus-group (group)
 751   (decode-coding-string group 'utf-8))
 752
 753 (deffoo nnimap-request-group (group &optional server dont-check info)
 754   (setq group (nnimap-decode-gnus-group group))
 755   (let ((result (nnimap-change-group
 756                  ;; Don't SELECT the group if we're going to select it
 757                  ;; later, anyway.
 758                  (if (and (not dont-check)
 759                           (assoc group nnimap-current-infos))
 760                      nil
 761                    group)
 762                  server))
 763         articles active marks high low)
 764     (with-current-buffer nntp-server-buffer
 765       (when result
 766         (if (and dont-check
 767                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 768             (insert (format "211 %d %d %d %S\n"
 769                             (- (cdr active) (car active))
 770                             (car active)
 771                             (cdr active)
 772                             group))
 773           (with-current-buffer (nnimap-buffer)
 774             (erase-buffer)
 775             (let ((group-sequence
 776                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 777                   (flag-sequence
 778                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 779               (setf (nnimap-group nnimap-object) group)
 780               (nnimap-wait-for-response flag-sequence)
 781               (setq marks
 782                     (nnimap-flags-to-marks
 783                      (nnimap-parse-flags
 784                       (list (list group-sequence flag-sequence
 785                                   1 group "SELECT")))))
 786               (when (and info
 787                          marks)
 788                 (nnimap-update-infos marks (list info))
 789                 (nnimap-store-info info (gnus-active (gnus-info-group info))))
 790               (goto-char (point-max))
 791               (let ((uidnext (nth 5 (car marks))))
 792                 (setq high (or (if uidnext
 793                                    (1- uidnext)
 794                                  (nth 3 (car marks)))
 795                                0)
 796                       low (or (nth 4 (car marks)) uidnext 1)))))
 797           (erase-buffer)
 798           (insert
 799            (format
 800             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 801         t))))
 802
 803 (deffoo nnimap-request-create-group (group &optional server args)
 804   (setq group (nnimap-decode-gnus-group group))
 805   (when (nnimap-change-group nil server)
 806     (with-current-buffer (nnimap-buffer)
 807       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 808
 809 (deffoo nnimap-request-delete-group (group &optional force server)
 810   (setq group (nnimap-decode-gnus-group group))
 811   (when (nnimap-change-group nil server)
 812     (with-current-buffer (nnimap-buffer)
 813       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 814
 815 (deffoo nnimap-request-rename-group (group new-name &optional server)
 816   (setq group (nnimap-decode-gnus-group group))
 817   (when (nnimap-change-group nil server)
 818     (with-current-buffer (nnimap-buffer)
 819       (nnimap-unselect-group)
 820       (car (nnimap-command "RENAME %S %S"
 821                            (utf7-encode group t) (utf7-encode new-name t))))))
 822
 823 (defun nnimap-unselect-group ()
 824   ;; Make sure we don't have this group open read/write by asking
 825   ;; to examine a mailbox that doesn't exist.  This seems to be
 826   ;; the only way that allows us to reliably go back to unselected
 827   ;; state on Courier.
 828   (nnimap-command "EXAMINE DOES.NOT.EXIST"))
 829
 830 (deffoo nnimap-request-expunge-group (group &optional server)
 831   (setq group (nnimap-decode-gnus-group group))
 832   (when (nnimap-change-group group server)
 833     (with-current-buffer (nnimap-buffer)
 834       (car (nnimap-command "EXPUNGE")))))
 835
 836 (defun nnimap-get-flags (spec)
 837   (let ((articles nil)
 838         elems end)
 839     (with-current-buffer (nnimap-buffer)
 840       (erase-buffer)
 841       (nnimap-wait-for-response (nnimap-send-command
 842                                  "UID FETCH %s FLAGS" spec))
 843       (setq end (point))
 844       (subst-char-in-region (point-min) (point-max)
 845                             ?\\ ?% t)
 846       (goto-char (point-min))
 847       (while (search-forward " FETCH " end t)
 848         (setq elems (read (current-buffer)))
 849         (push (cons (cadr (memq 'UID elems))
 850                     (cadr (memq 'FLAGS elems)))
 851               articles)))
 852     (nreverse articles)))
 853
 854 (deffoo nnimap-close-group (group &optional server)
 855   t)
 856
 857 (deffoo nnimap-request-move-article (article group server accept-form
 858                                              &optional last internal-move-group)
 859   (setq group (nnimap-decode-gnus-group group))
 860   (with-temp-buffer
 861     (mm-disable-multibyte)
 862     (when (funcall (if internal-move-group
 863                        'nnimap-request-head
 864                      'nnimap-request-article)
 865                    article group server (current-buffer))
 866       ;; If the move is internal (on the same server), just do it the easy
 867       ;; way.
 868       (let ((message-id (message-field-value "message-id")))
 869         (if internal-move-group
 870             (let ((result
 871                    (with-current-buffer (nnimap-buffer)
 872                      (nnimap-command "UID COPY %d %S"
 873                                      article
 874                                      (utf7-encode internal-move-group t)))))
 875               (when (car result)
 876                 (nnimap-delete-article article)
 877                 (cons internal-move-group
 878                       (or (nnimap-find-uid-response "COPYUID" (cadr result))
 879                           (nnimap-find-article-by-message-id
 880                            internal-move-group server message-id
 881                            nnimap-request-articles-find-limit)))))
 882           ;; Move the article to a different method.
 883           (let ((result (eval accept-form)))
 884             (when result
 885               (nnimap-change-group group server)
 886               (nnimap-delete-article article)
 887               result)))))))
 888
 889 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 890   (setq group (nnimap-decode-gnus-group group))
 891   (cond
 892    ((null articles)
 893     nil)
 894    ((not (nnimap-change-group group server))
 895     articles)
 896    ((and force
 897          (eq nnmail-expiry-target 'delete))
 898     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 899       (nnheader-message 7 "Article marked for deletion, but not expunged."))
 900     nil)
 901    (t
 902     (let ((deletable-articles
 903            (if (or force
 904                    (eq nnmail-expiry-wait 'immediate))
 905                articles
 906              (gnus-sorted-intersection
 907               articles
 908               (nnimap-find-expired-articles group)))))
 909       (if (null deletable-articles)
 910           articles
 911         (if (eq nnmail-expiry-target 'delete)
 912             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 913           (setq deletable-articles
 914                 (nnimap-process-expiry-targets
 915                  deletable-articles group server)))
 916         ;; Return the articles we didn't delete.
 917         (gnus-sorted-complement articles deletable-articles))))))
 918
 919 (defun nnimap-process-expiry-targets (articles group server)
 920   (let ((deleted-articles nil))
 921     (cond
 922      ;; shortcut further processing if we're going to delete the articles
 923      ((eq nnmail-expiry-target 'delete)
 924       (setq deleted-articles articles)
 925       t)
 926      ;; or just move them to another folder on the same IMAP server
 927      ((and (not (functionp nnmail-expiry-target))
 928            (gnus-server-equal (gnus-group-method nnmail-expiry-target)
 929                               (gnus-server-to-method
 930                                (format "nnimap:%s" server))))
 931       (and (nnimap-change-group group server)
 932            (with-current-buffer (nnimap-buffer)
 933              (nnheader-message 7 "Expiring articles from %s: %s" group articles)
 934              (nnimap-command
 935               "UID COPY %s %S"
 936               (nnimap-article-ranges (gnus-compress-sequence articles))
 937               (utf7-encode (gnus-group-real-name nnmail-expiry-target) t))
 938              (setq deleted-articles articles)))
 939       t)
 940      (t
 941       (dolist (article articles)
 942         (let ((target nnmail-expiry-target))
 943           (with-temp-buffer
 944             (mm-disable-multibyte)
 945             (when (nnimap-request-article article group server (current-buffer))
 946               (when (functionp target)
 947                 (setq target (funcall target group)))
 948               (if (and target
 949                        (not (eq target 'delete)))
 950                   (if (or (gnus-request-group target t)
 951                           (gnus-request-create-group target))
 952                       (progn
 953                         (nnmail-expiry-target-group target group)
 954                         (nnheader-message 7 "Expiring article %s:%d to %s"
 955                                           group article target))
 956                     (setq target nil))
 957                 (nnheader-message 7 "Expiring article %s:%d" group article))
 958               (when target
 959                 (push article deleted-articles))))))))
 960     ;; Change back to the current group again.
 961     (nnimap-change-group group server)
 962     (setq deleted-articles (nreverse deleted-articles))
 963     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 964     deleted-articles))
 965
 966 (defun nnimap-find-expired-articles (group)
 967   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 968     (with-current-buffer (nnimap-buffer)
 969       (let ((result
 970              (nnimap-command
 971               "UID SEARCH SENTBEFORE %s"
 972               (format-time-string
 973                (format "%%d-%s-%%Y"
 974                        (upcase
 975                         (car (rassoc (nth 4 (decode-time cutoff))
 976                                      parse-time-months))))
 977                cutoff))))
 978         (and (car result)
 979              (delete 0 (mapcar #'string-to-number
 980                                (cdr (assoc "SEARCH" (cdr result))))))))))
 981
 982
 983 (defun nnimap-find-article-by-message-id (group server message-id)
 984   "Search for message with MESSAGE-ID in GROUP from SERVER."
 985   (with-current-buffer (nnimap-buffer)
 986     (erase-buffer)
 987     (nnimap-change-group group server nil t)
 988     (let ((sequence
 989            (nnimap-send-command "UID SEARCH HEADER Message-Id %S" message-id))
 990           article result)
 991       (setq result (nnimap-wait-for-response sequence))
 992       (when (and result
 993                  (car (setq result (nnimap-parse-response))))
 994         ;; Select the last instance of the message in the group.
 995         (and (setq article
 996                    (car (last (cdr (assoc "SEARCH" (cdr result))))))
 997              (string-to-number article))))))
 998
 999 (defun nnimap-delete-article (articles)
1000   (with-current-buffer (nnimap-buffer)
1001     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
1002                     (nnimap-article-ranges articles))
1003     (cond
1004      ((nnimap-capability "UIDPLUS")
1005       (nnimap-command "UID EXPUNGE %s"
1006                       (nnimap-article-ranges articles))
1007       t)
1008      (nnimap-expunge
1009       (nnimap-command "EXPUNGE")
1010       t)
1011      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
1012                                 "server doesn't support UIDPLUS, so we won't "
1013                                 "delete this article now"))))))
1014
1015 (deffoo nnimap-request-scan (&optional group server)
1016   (when group
1017     (setq group (nnimap-decode-gnus-group group)))
1018   (when (and (nnimap-change-group nil server)
1019              nnimap-inbox
1020              nnimap-split-methods)
1021     (nnheader-message 7 "nnimap %s splitting mail..." server)
1022     (if (listp nnimap-inbox)
1023        (dolist (nnimap-inbox nnimap-inbox)
1024          (nnimap-split-incoming-mail))
1025       (nnimap-split-incoming-mail))
1026     (nnheader-message 7 "nnimap %s splitting mail...done" server)))
1027
1028 (defun nnimap-marks-to-flags (marks)
1029   (let (flags flag)
1030     (dolist (mark marks)
1031       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
1032         (push flag flags)))
1033     flags))
1034
1035 (deffoo nnimap-request-update-group-status (group status &optional server)
1036   (setq group (nnimap-decode-gnus-group group))
1037   (when (nnimap-change-group nil server)
1038     (let ((command (assoc
1039                     status
1040                     '((subscribe "SUBSCRIBE")
1041                       (unsubscribe "UNSUBSCRIBE")))))
1042       (when command
1043         (with-current-buffer (nnimap-buffer)
1044           (nnimap-command "%s %S" (cadr command) (utf7-encode group t)))))))
1045
1046 (deffoo nnimap-request-set-mark (group actions &optional server)
1047   (setq group (nnimap-decode-gnus-group group))
1048   (when (nnimap-change-group group server)
1049     (let (sequence)
1050       (with-current-buffer (nnimap-buffer)
1051         (erase-buffer)
1052         ;; Just send all the STORE commands without waiting for
1053         ;; response.  If they're successful, they're successful.
1054         (dolist (action actions)
1055           (destructuring-bind (range action marks) action
1056             (let ((flags (nnimap-marks-to-flags marks)))
1057               (when flags
1058                 (setq sequence (nnimap-send-command
1059                                 "UID STORE %s %sFLAGS.SILENT (%s)"
1060                                 (nnimap-article-ranges range)
1061                                 (cond
1062                                  ((eq action 'del) "-")
1063                                  ((eq action 'add) "+")
1064                                  ((eq action 'set) ""))
1065                                 (mapconcat #'identity flags " ")))))))
1066         ;; Wait for the last command to complete to avoid later
1067         ;; synchronization problems with the stream.
1068         (when sequence
1069           (nnimap-wait-for-response sequence))))))
1070
1071 (deffoo nnimap-request-accept-article (group &optional server last)
1072   (setq group (nnimap-decode-gnus-group group))
1073   (when (nnimap-change-group nil server)
1074     (nnmail-check-syntax)
1075     (let ((message-id (message-field-value "message-id"))
1076           sequence message)
1077       (nnimap-add-cr)
1078       (setq message (buffer-substring-no-properties (point-min) (point-max)))
1079       (with-current-buffer (nnimap-buffer)
1080         (when (setq message (or (nnimap-process-quirk "OK Gimap " 'append message)
1081                                 message))
1082           ;; If we have this group open read-only, then unselect it
1083           ;; before appending to it.
1084           (when (equal (nnimap-examined nnimap-object) group)
1085             (nnimap-unselect-group))
1086           (erase-buffer)
1087           (setq sequence (nnimap-send-command
1088                           "APPEND %S {%d}" (utf7-encode group t)
1089                           (length message)))
1090           (unless nnimap-streaming
1091             (nnimap-wait-for-connection "^[+]"))
1092           (process-send-string (get-buffer-process (current-buffer)) message)
1093           (process-send-string (get-buffer-process (current-buffer))
1094                                (if (nnimap-newlinep nnimap-object)
1095                                    "\n"
1096                                  "\r\n"))
1097           (let ((result (nnimap-get-response sequence)))
1098             (if (not (nnimap-ok-p result))
1099                 (progn
1100                   (nnheader-report 'nnimap "%s" result)
1101                   nil)
1102               (cons group
1103                     (or (nnimap-find-uid-response "APPENDUID" (car result))
1104                         (nnimap-find-article-by-message-id
1105                          group server message-id
1106                          nnimap-request-articles-find-limit))))))))))
1107
1108 (defun nnimap-process-quirk (greeting-match type data)
1109   (when (and (nnimap-greeting nnimap-object)
1110              (string-match greeting-match (nnimap-greeting nnimap-object))
1111              (eq type 'append)
1112              (string-match "\000" data))
1113     (let ((choice (gnus-multiple-choice
1114                    "Message contains NUL characters.  Delete, continue, abort? "
1115                    '((?d "Delete NUL characters")
1116                      (?c "Try to APPEND the message as is")
1117                      (?a "Abort")))))
1118       (cond
1119        ((eq choice ?a)
1120         (nnheader-report 'nnimap "Aborted APPEND due to NUL characters"))
1121        ((eq choice ?c)
1122         data)
1123        (t
1124         (with-temp-buffer
1125           (insert data)
1126           (goto-char (point-min))
1127           (while (search-forward "\000" nil t)
1128             (replace-match "" t t))
1129           (buffer-string)))))))
1130
1131 (defun nnimap-ok-p (value)
1132   (and (consp value)
1133        (consp (car value))
1134        (equal (caar value) "OK")))
1135
1136 (defun nnimap-find-uid-response (name list)
1137   (let ((result (car (last (nnimap-find-response-element name list)))))
1138     (and result
1139          (string-to-number result))))
1140
1141 (defun nnimap-find-response-element (name list)
1142   (let (result)
1143     (dolist (elem list)
1144       (when (and (consp elem)
1145                  (equal name (car elem)))
1146         (setq result elem)))
1147     result))
1148
1149 (deffoo nnimap-request-replace-article (article group buffer)
1150   (setq group (nnimap-decode-gnus-group group))
1151   (let (group-art)
1152     (when (and (nnimap-change-group group)
1153                ;; Put the article into the group.
1154                (with-current-buffer buffer
1155                  (setq group-art
1156                        (nnimap-request-accept-article group nil t))))
1157       (nnimap-delete-article (list article))
1158       ;; Return the new article number.
1159       (cdr group-art))))
1160
1161 (defun nnimap-add-cr ()
1162   (goto-char (point-min))
1163   (while (re-search-forward "\r?\n" nil t)
1164     (replace-match "\r\n" t t)))
1165
1166 (defun nnimap-get-groups ()
1167   (erase-buffer)
1168   (let ((sequence (nnimap-send-command "LIST \"\" \"*\""))
1169         groups)
1170     (nnimap-wait-for-response sequence)
1171     (subst-char-in-region (point-min) (point-max)
1172                           ?\\ ?% t)
1173     (goto-char (point-min))
1174     (nnimap-unfold-quoted-lines)
1175     (goto-char (point-min))
1176     (while (search-forward "* LIST " nil t)
1177       (let ((flags (read (current-buffer)))
1178             (separator (read (current-buffer)))
1179             (group (read (current-buffer))))
1180         (unless (member '%NoSelect flags)
1181           (push (utf7-decode (if (stringp group)
1182                                  group
1183                                (format "%s" group)) t)
1184                 groups))))
1185     (nreverse groups)))
1186
1187 (deffoo nnimap-request-list (&optional server)
1188   (when (nnimap-change-group nil server)
1189     (with-current-buffer nntp-server-buffer
1190       (erase-buffer)
1191       (dolist (response
1192                (with-current-buffer (nnimap-buffer)
1193                  ;; Build a list of (group result-of-EXAMINE) for each group
1194                  (mapcar
1195                   (lambda (group)
1196                     (list group (cdr (nnimap-change-group group server nil t))))
1197                   (nnimap-get-groups))))
1198         (let ((group (encode-coding-string (car response) 'utf-8))
1199               (response (cadr response)))
1200           (when (equal (caar response) "OK")
1201             (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
1202                 highest exists)
1203               (dolist (elem response)
1204                 (when (equal (cadr elem) "EXISTS")
1205                   (setq exists (string-to-number (car elem)))))
1206               (when uidnext
1207                 (setq highest (1- (string-to-number (car uidnext)))))
1208               (cond
1209                ((null highest)
1210                 (insert (format "%S 0 1 y\n" group)))
1211                ((zerop exists)
1212                 ;; Empty group.
1213                 (insert (format "%S %d %d y\n" group
1214                                 highest (1+ highest))))
1215                (t
1216                 ;; Return the widest possible range.
1217                 (insert (format "%S %d 1 y\n" group
1218                                 (or highest exists)))))))))
1219       t)))
1220
1221 (deffoo nnimap-request-newgroups (date &optional server)
1222   (when (nnimap-change-group nil server)
1223     (with-current-buffer nntp-server-buffer
1224       (erase-buffer)
1225       (dolist (group (with-current-buffer (nnimap-buffer)
1226                        (nnimap-get-groups)))
1227         (unless (assoc group nnimap-current-infos)
1228           ;; Insert dummy numbers here -- they don't matter.
1229           (insert (format "%S 0 1 y\n" (encode-coding-string group 'utf-8)))))
1230       t)))
1231
1232 (deffoo nnimap-retrieve-group-data-early (server infos)
1233   (when (and (nnimap-change-group nil server)
1234              infos)
1235     (with-current-buffer (nnimap-buffer)
1236       (erase-buffer)
1237       (setf (nnimap-group nnimap-object) nil)
1238       (setf (nnimap-initial-resync nnimap-object) 0)
1239       (let ((qresyncp (nnimap-capability "QRESYNC"))
1240             params groups sequences active uidvalidity modseq group
1241             unexist)
1242         ;; Go through the infos and gather the data needed to know
1243         ;; what and how to request the data.
1244         (dolist (info infos)
1245           (setq params (gnus-info-params info)
1246                 group (nnimap-decode-gnus-group
1247                        (gnus-group-real-name (gnus-info-group info)))
1248                 active (cdr (assq 'active params))
1249                 unexist (assq 'unexist (gnus-info-marks info))
1250                 uidvalidity (cdr (assq 'uidvalidity params))
1251                 modseq (cdr (assq 'modseq params)))
1252           (setf (nnimap-examined nnimap-object) group)
1253           (if (and qresyncp
1254                    uidvalidity
1255                    active
1256                    modseq
1257                    unexist)
1258               (push
1259                (list (nnimap-send-command "EXAMINE %S (%s (%s %s))"
1260                                           (utf7-encode group t)
1261                                           (nnimap-quirk "QRESYNC")
1262                                           uidvalidity modseq)
1263                      'qresync
1264                      nil group 'qresync)
1265                sequences)
1266             (let ((command
1267                    (if uidvalidity
1268                        "EXAMINE"
1269                      ;; If we don't have a UIDVALIDITY, then this is
1270                      ;; the first time we've seen the group, so we
1271                      ;; have to do a SELECT (which is slower than an
1272                      ;; examine), but will tell us whether the group
1273                      ;; is read-only or not.
1274                      "SELECT"))
1275                   start)
1276               (if (and active uidvalidity unexist)
1277                   ;; Fetch the last 100 flags.
1278                   (setq start (max 1 (- (cdr active) 100)))
1279                 (incf (nnimap-initial-resync nnimap-object))
1280                 (setq start 1))
1281               (push (list (nnimap-send-command "%s %S" command
1282                                                (utf7-encode group t))
1283                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
1284                           start group command)
1285                     sequences))))
1286         sequences))))
1287
1288 (defun nnimap-quirk (command)
1289   (let ((quirk (assoc command nnimap-quirks)))
1290     ;; If this server is of a type that matches a quirk, then return
1291     ;; the "quirked" command instead of the proper one.
1292     (if (or (null quirk)
1293             (not (string-match (nth 1 quirk) (nnimap-greeting nnimap-object))))
1294         command
1295       (nth 2 quirk))))
1296
1297 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
1298   (when (and sequences
1299              (nnimap-change-group nil server t)
1300              ;; Check that the process is still alive.
1301              (get-buffer-process (nnimap-buffer))
1302              (memq (process-status (get-buffer-process (nnimap-buffer)))
1303                    '(open run)))
1304     (with-current-buffer (nnimap-buffer)
1305       ;; Wait for the final data to trickle in.
1306       (when (nnimap-wait-for-response (if (eq (cadar sequences) 'qresync)
1307                                           (caar sequences)
1308                                         (cadar sequences))
1309                                       t)
1310         ;; Now we should have most of the data we need, no matter
1311         ;; whether we're QRESYNCING, fetching all the flags from
1312         ;; scratch, or just fetching the last 100 flags per group.
1313         (nnimap-update-infos (nnimap-flags-to-marks
1314                               (nnimap-parse-flags
1315                                (nreverse sequences)))
1316                              infos)
1317         ;; Finally, just return something resembling an active file in
1318         ;; the nntp buffer, so that the agent can save the info, too.
1319         (with-current-buffer nntp-server-buffer
1320           (erase-buffer)
1321           (dolist (info infos)
1322             (let* ((group (gnus-info-group info))
1323                    (active (gnus-active group)))
1324               (when active
1325                 (insert (format "%S %d %d y\n"
1326                                 (decode-coding-string
1327                                  (gnus-group-real-name group) 'utf-8)
1328                                 (cdr active)
1329                                 (car active)))))))))))
1330
1331 (defun nnimap-update-infos (flags infos)
1332   (dolist (info infos)
1333     (let* ((group (nnimap-decode-gnus-group
1334                    (gnus-group-real-name (gnus-info-group info))))
1335            (marks (cdr (assoc group flags))))
1336       (when marks
1337         (nnimap-update-info info marks)))))
1338
1339 (defun nnimap-update-info (info marks)
1340   (destructuring-bind (existing flags high low uidnext start-article
1341                                 permanent-flags uidvalidity
1342                                 vanished highestmodseq) marks
1343     (cond
1344      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1345      ;; completely empty groups.
1346      ((and (not existing)
1347            (not uidnext))
1348       (let ((active (cdr (assq 'active (gnus-info-params info)))))
1349         (when active
1350           (gnus-set-active (gnus-info-group info) active))))
1351      ;; We have a mismatch between the old and new UIDVALIDITY
1352      ;; identifiers, so we have to re-request the group info (the next
1353      ;; time).  This virtually never happens.
1354      ((let ((old-uidvalidity
1355              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1356         (and old-uidvalidity
1357              (not (equal old-uidvalidity uidvalidity))
1358              (or (not start-article)
1359                  (> start-article 1))))
1360       (gnus-group-remove-parameter info 'uidvalidity)
1361       (gnus-group-remove-parameter info 'modseq))
1362      ;; We have the data needed to update.
1363      (t
1364       (let* ((group (gnus-info-group info))
1365              (completep (and start-article
1366                              (= start-article 1)))
1367              (active (or (gnus-active group)
1368                          (cdr (assq 'active (gnus-info-params info))))))
1369         (when uidnext
1370           (setq high (1- uidnext)))
1371         ;; First set the active ranges based on high/low.
1372         (if (or completep
1373                 (not (gnus-active group)))
1374             (gnus-set-active group
1375                              (cond
1376                               (active
1377                                (cons (min (or low (car active))
1378                                           (car active))
1379                                      (max (or high (cdr active))
1380                                           (cdr active))))
1381                               ((and low high)
1382                                (cons low high))
1383                               (uidnext
1384                                ;; No articles in this group.
1385                                (cons uidnext (1- uidnext)))
1386                               (start-article
1387                                (cons start-article (1- start-article)))
1388                               (t
1389                                ;; No articles and no uidnext.
1390                                nil)))
1391           (gnus-set-active group
1392                            (cons (car active)
1393                                  (or high (1- uidnext)))))
1394         ;; See whether this is a read-only group.
1395         (unless (eq permanent-flags 'not-scanned)
1396           (gnus-group-set-parameter
1397            info 'permanent-flags
1398            (and (or (memq '%* permanent-flags)
1399                     (memq '%Seen permanent-flags))
1400                 permanent-flags)))
1401         ;; Update marks and read articles if this isn't a
1402         ;; read-only IMAP group.
1403         (when (setq permanent-flags
1404                     (cdr (assq 'permanent-flags (gnus-info-params info))))
1405           (if (and highestmodseq
1406                    (not start-article))
1407               ;; We've gotten the data by QRESYNCing.
1408               (nnimap-update-qresync-info
1409                info existing (nnimap-imap-ranges-to-gnus-ranges vanished) flags)
1410             ;; Do normal non-QRESYNC flag updates.
1411             ;; Update the list of read articles.
1412             (let* ((unread
1413                     (gnus-compress-sequence
1414                      (gnus-set-difference
1415                       (gnus-set-difference
1416                        existing
1417                        (cdr (assoc '%Seen flags)))
1418                       (cdr (assoc '%Flagged flags)))))
1419                    (read (gnus-range-difference
1420                           (cons start-article high) unread)))
1421               (when (> start-article 1)
1422                 (setq read
1423                       (gnus-range-nconcat
1424                        (if (> start-article 1)
1425                            (gnus-sorted-range-intersection
1426                             (cons 1 (1- start-article))
1427                             (gnus-info-read info))
1428                          (gnus-info-read info))
1429                        read)))
1430               (when (or (not (listp permanent-flags))
1431                         (memq '%Seen permanent-flags))
1432                 (gnus-info-set-read info read))
1433               ;; Update the marks.
1434               (setq marks (gnus-info-marks info))
1435               (dolist (type (cdr nnimap-mark-alist))
1436                 (when (or (not (listp permanent-flags))
1437                           (memq (car (assoc (caddr type) flags))
1438                                 permanent-flags)
1439                           (memq '%* permanent-flags))
1440                   (let ((old-marks (assoc (car type) marks))
1441                         (new-marks
1442                          (gnus-compress-sequence
1443                           (cdr (or (assoc (caddr type) flags) ; %Flagged
1444                                    (assoc (intern (cadr type) obarray) flags)
1445                                    (assoc (cadr type) flags)))))) ; "\Flagged"
1446                     (setq marks (delq old-marks marks))
1447                     (pop old-marks)
1448                     (when (and old-marks
1449                                (> start-article 1))
1450                       (setq old-marks (gnus-range-difference
1451                                        old-marks
1452                                        (cons start-article high)))
1453                       (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1454                     (when new-marks
1455                       (push (cons (car type) new-marks) marks)))))
1456               ;; Keep track of non-existing articles.
1457               (let* ((old-unexists (assq 'unexist marks))
1458                      (active (gnus-active group))
1459                      (unexists
1460                       (if completep
1461                           (gnus-range-difference
1462                            active
1463                            (gnus-compress-sequence existing))
1464                         (gnus-add-to-range
1465                          (cdr old-unexists)
1466                          (gnus-list-range-difference
1467                           existing (gnus-active group))))))
1468                 (when (> (car active) 1)
1469                   (setq unexists (gnus-range-add
1470                                   (cons 1 (1- (car active)))
1471                                   unexists)))
1472                 (if old-unexists
1473                     (setcdr old-unexists unexists)
1474                   (push (cons 'unexist unexists) marks)))
1475               (gnus-info-set-marks info marks t))))
1476         ;; Tell Gnus whether there are any \Recent messages in any of
1477         ;; the groups.
1478         (let ((recent (cdr (assoc '%Recent flags))))
1479           (when (and active
1480                      recent
1481                      (> (car (last recent)) (cdr active)))
1482             (push (list (cons (gnus-group-real-name group) 0))
1483                   nnmail-split-history)))
1484         ;; Note the active level for the next run-through.
1485         (gnus-group-set-parameter info 'active (gnus-active group))
1486         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1487         (gnus-group-set-parameter info 'modseq highestmodseq)
1488         (nnimap-store-info info (gnus-active group)))))))
1489
1490 (defun nnimap-update-qresync-info (info existing vanished flags)
1491   ;; Add all the vanished articles to the list of read articles.
1492   (gnus-info-set-read
1493    info
1494    (gnus-add-to-range
1495     (gnus-add-to-range
1496      (gnus-range-add (gnus-info-read info)
1497                      vanished)
1498      (cdr (assq '%Flagged flags)))
1499     (cdr (assq '%Seen flags))))
1500   (let ((marks (gnus-info-marks info)))
1501     (dolist (type (cdr nnimap-mark-alist))
1502       (let ((ticks (assoc (car type) marks))
1503             (new-marks
1504              (cdr (or (assoc (caddr type) flags) ; %Flagged
1505                       (assoc (intern (cadr type) obarray) flags)
1506                       (assoc (cadr type) flags))))) ; "\Flagged"
1507         (setq marks (delq ticks marks))
1508         (pop ticks)
1509         ;; Add the new marks we got.
1510         (setq ticks (gnus-add-to-range ticks new-marks))
1511         ;; Remove the marks from messages that don't have them.
1512         (setq ticks (gnus-remove-from-range
1513                      ticks
1514                      (gnus-compress-sequence
1515                       (gnus-sorted-complement existing new-marks))))
1516         (when ticks
1517           (push (cons (car type) ticks) marks)))
1518       (gnus-info-set-marks info marks t))
1519     ;; Add vanished to the list of unexisting articles.
1520     (when vanished
1521       (let* ((old-unexists (assq 'unexist marks))
1522              (unexists (gnus-range-add (cdr old-unexists) vanished)))
1523         (if old-unexists
1524             (setcdr old-unexists unexists)
1525           (push (cons 'unexist unexists) marks)))
1526       (gnus-info-set-marks info marks t))))
1527
1528 (defun nnimap-imap-ranges-to-gnus-ranges (irange)
1529   (if (zerop (length irange))
1530       nil
1531     (let ((result nil))
1532       (dolist (elem (split-string irange ","))
1533         (push
1534          (if (string-match ":" elem)
1535              (let ((numbers (split-string elem ":")))
1536                (cons (string-to-number (car numbers))
1537                      (string-to-number (cadr numbers))))
1538            (string-to-number elem))
1539          result))
1540       (nreverse result))))
1541
1542 (defun nnimap-store-info (info active)
1543   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1544          (entry (assoc group nnimap-current-infos)))
1545     (if entry
1546         (setcdr entry (list info active))
1547       (push (list group info active) nnimap-current-infos))))
1548
1549 (defun nnimap-flags-to-marks (groups)
1550   (let (data group totalp uidnext articles start-article mark permanent-flags
1551              uidvalidity vanished highestmodseq)
1552     (dolist (elem groups)
1553       (setq group (car elem)
1554             uidnext (nth 1 elem)
1555             start-article (nth 2 elem)
1556             permanent-flags (nth 3 elem)
1557             uidvalidity (nth 4 elem)
1558             vanished (nth 5 elem)
1559             highestmodseq (nth 6 elem)
1560             articles (nthcdr 7 elem))
1561       (let ((high (caar articles))
1562             marks low existing)
1563         (dolist (article articles)
1564           (setq low (car article))
1565           (push (car article) existing)
1566           (dolist (flag (cdr article))
1567             (setq mark (assoc flag marks))
1568             (if (not mark)
1569                 (push (list flag (car article)) marks)
1570               (setcdr mark (cons (car article) (cdr mark))))))
1571         (push (list group existing marks high low uidnext start-article
1572                     permanent-flags uidvalidity vanished highestmodseq)
1573               data)))
1574     data))
1575
1576 (defun nnimap-parse-flags (sequences)
1577   (goto-char (point-min))
1578   ;; Change \Delete etc to %Delete, so that the Emacs Lisp reader can
1579   ;; read it.
1580   (subst-char-in-region (point-min) (point-max)
1581                         ?\\ ?% t)
1582   ;; Remove any MODSEQ entries in the buffer, because they may contain
1583   ;; numbers that are too large for 32-bit Emacsen.
1584   (while (re-search-forward " MODSEQ ([0-9]+)" nil t)
1585     (replace-match "" t t))
1586   (goto-char (point-min))
1587   (let (start end articles groups uidnext elems permanent-flags
1588               uidvalidity vanished highestmodseq)
1589     (dolist (elem sequences)
1590       (destructuring-bind (group-sequence flag-sequence totalp group command)
1591           elem
1592         (setq start (point))
1593         (when (and
1594                ;; The EXAMINE was successful.
1595                (search-forward (format "\n%d OK " group-sequence) nil t)
1596                (progn
1597                  (forward-line 1)
1598                  (setq end (point))
1599                  (goto-char start)
1600                  (setq permanent-flags
1601                        (if (equal command "SELECT")
1602                            (and (search-forward "PERMANENTFLAGS "
1603                                                 (or end (point-min)) t)
1604                                 (read (current-buffer)))
1605                          'not-scanned))
1606                  (goto-char start)
1607                  (setq uidnext
1608                        (and (search-forward "UIDNEXT "
1609                                             (or end (point-min)) t)
1610                             (read (current-buffer))))
1611                  (goto-char start)
1612                  (setq uidvalidity
1613                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1614                                                (or end (point-min)) t)
1615                             ;; Store UIDVALIDITY as a string, as it's
1616                             ;; too big for 32-bit Emacsen, usually.
1617                             (match-string 1)))
1618                  (goto-char start)
1619                  (setq vanished
1620                        (and (eq flag-sequence 'qresync)
1621                             (re-search-forward "^\\* VANISHED .*? \\([0-9:,]+\\)"
1622                                                (or end (point-min)) t)
1623                             (match-string 1)))
1624                  (goto-char start)
1625                  (setq highestmodseq
1626                        (and (re-search-forward "HIGHESTMODSEQ \\([0-9]+\\)"
1627                                             (or end (point-min)) t)
1628                             (match-string 1)))
1629                  (goto-char end)
1630                  (forward-line -1))
1631                ;; The UID FETCH FLAGS was successful.
1632                (or (eq flag-sequence 'qresync)
1633                    (search-forward (format "\n%d OK " flag-sequence) nil t)))
1634           (if (eq flag-sequence 'qresync)
1635               (progn
1636                 (goto-char start)
1637                 (setq start end))
1638             (setq start (point))
1639             (goto-char end))
1640           (while (re-search-forward "^\\* [0-9]+ FETCH " start t)
1641             (let ((p (point)))
1642               (setq elems (read (current-buffer)))
1643               (push (cons (cadr (memq 'UID elems))
1644                           (cadr (memq 'FLAGS elems)))
1645                     articles)))
1646           (push (nconc (list group uidnext totalp permanent-flags uidvalidity
1647                              vanished highestmodseq)
1648                        articles)
1649                 groups)
1650           (if (eq flag-sequence 'qresync)
1651               (goto-char end)
1652             (setq end (point)))
1653           (setq articles nil))))
1654     groups))
1655
1656 (defun nnimap-find-process-buffer (buffer)
1657   (cadr (assoc buffer nnimap-connection-alist)))
1658
1659 (deffoo nnimap-request-post (&optional server)
1660   (setq nnimap-status-string "Read-only server")
1661   nil)
1662
1663 (defvar gnus-refer-thread-use-nnir) ;; gnus-sum.el
1664 (declare-function gnus-fetch-headers "gnus-sum"
1665                   (articles &optional limit force-new dependencies))
1666
1667 (autoload 'nnir-search-thread "nnir")
1668
1669 (deffoo nnimap-request-thread (header &optional group server)
1670   (when group
1671     (setq group (nnimap-decode-gnus-group group)))
1672   (if gnus-refer-thread-use-nnir
1673       (nnir-search-thread header)
1674     (when (nnimap-change-group group server)
1675       (let* ((cmd (nnimap-make-thread-query header))
1676              (result (with-current-buffer (nnimap-buffer)
1677                        (nnimap-command  "UID SEARCH %s" cmd))))
1678         (when result
1679           (gnus-fetch-headers
1680            (and (car result)
1681                 (delete 0 (mapcar #'string-to-number
1682                                   (cdr (assoc "SEARCH" (cdr result))))))
1683            nil t))))))
1684
1685 (defun nnimap-change-group (group &optional server no-reconnect read-only)
1686   "Change group to GROUP.
1687 If SERVER is set, check that server is connected, otherwise retry
1688 to reconnect, unless NO-RECONNECT is set to t.
1689 if READ-ONLY is set, send EXAMINE rather than SELECT to the server."
1690   (let ((open-result t))
1691     (when (and server
1692                (not (nnimap-server-opened server)))
1693       (setq open-result (nnimap-open-server server nil no-reconnect)))
1694     (cond
1695      ((not open-result)
1696       nil)
1697      ((not group)
1698       t)
1699      (t
1700       (with-current-buffer (nnimap-buffer)
1701         (let ((result (nnimap-command "%s %S"
1702                                       (if read-only
1703                                           "EXAMINE"
1704                                         "SELECT")
1705                                       (utf7-encode group t))))
1706           (when (car result)
1707             (setf (nnimap-group nnimap-object) group
1708                   (nnimap-select-result nnimap-object) result)
1709             result)))))))
1710
1711 (defun nnimap-find-connection (buffer)
1712   "Find the connection delivering to BUFFER."
1713   (let ((entry (assoc buffer nnimap-connection-alist)))
1714     (when entry
1715       (if (and (buffer-name (cadr entry))
1716                (get-buffer-process (cadr entry))
1717                (memq (process-status (get-buffer-process (cadr entry)))
1718                      '(open run)))
1719           (get-buffer-process (cadr entry))
1720         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1721         nil))))
1722
1723 (defvar nnimap-sequence 0)
1724
1725 (defun nnimap-send-command (&rest args)
1726   (setf (nnimap-last-command-time nnimap-object) (current-time))
1727   (process-send-string
1728    (get-buffer-process (current-buffer))
1729    (nnimap-log-command
1730     (format "%d %s%s\n"
1731             (incf nnimap-sequence)
1732             (apply #'format args)
1733             (if (nnimap-newlinep nnimap-object)
1734                 ""
1735               "\r"))))
1736   ;; Some servers apparently can't have many outstanding
1737   ;; commands, so throttle them.
1738   (unless nnimap-streaming
1739     (nnimap-wait-for-response nnimap-sequence))
1740   nnimap-sequence)
1741
1742 (defvar nnimap-record-commands nil
1743   "If non-nil, log commands to the \"*imap log*\" buffer.")
1744
1745 (defun nnimap-log-buffer ()
1746   (let ((name "*imap log*"))
1747     (or (get-buffer name)
1748         (with-current-buffer (get-buffer-create name)
1749           (when (boundp 'window-point-insertion-type)
1750             (make-local-variable 'window-point-insertion-type)
1751             (setq window-point-insertion-type t))
1752           (current-buffer)))))
1753
1754 (defun nnimap-log-command (command)
1755   (when nnimap-record-commands
1756     (with-current-buffer (nnimap-log-buffer)
1757       (goto-char (point-max))
1758       (insert (format-time-string "%H:%M:%S")
1759               " [" nnimap-address "] "
1760               (if nnimap-inhibit-logging
1761                   "(inhibited)\n"
1762                 command))))
1763   command)
1764
1765 (defun nnimap-command (&rest args)
1766   (erase-buffer)
1767   (let* ((sequence (apply #'nnimap-send-command args))
1768          (response (nnimap-get-response sequence)))
1769     (if (equal (caar response) "OK")
1770         (cons t response)
1771       (nnheader-report 'nnimap "%s"
1772                        (mapconcat (lambda (a)
1773                                     (format "%s" a))
1774                                   (car response) " "))
1775       nil)))
1776
1777 (defun nnimap-get-response (sequence)
1778   (nnimap-wait-for-response sequence)
1779   (nnimap-parse-response))
1780
1781 (defun nnimap-wait-for-connection (&optional regexp)
1782   (nnimap-wait-for-line (or regexp "^[*.] .*\n") "[*.] \\([A-Z0-9]+\\)"))
1783
1784 (defun nnimap-wait-for-line (regexp &optional response-regexp)
1785   (let ((process (get-buffer-process (current-buffer))))
1786     (goto-char (point-min))
1787     (while (and (memq (process-status process)
1788                       '(open run))
1789                 (not (re-search-forward regexp nil t)))
1790       (nnheader-accept-process-output process)
1791       (goto-char (point-min)))
1792     (forward-line -1)
1793     (and (looking-at (or response-regexp regexp))
1794          (match-string 1))))
1795
1796 (defun nnimap-wait-for-response (sequence &optional messagep)
1797   (let ((process (get-buffer-process (current-buffer)))
1798         openp)
1799     (condition-case nil
1800         (progn
1801           (goto-char (point-max))
1802           (while (and (setq openp (memq (process-status process)
1803                                         '(open run)))
1804                       (progn
1805                         ;; Skip past any "*" lines that the server has
1806                         ;; output.
1807                         (while (and (not (bobp))
1808                                     (progn
1809                                       (forward-line -1)
1810                                       (looking-at "\\*"))))
1811                         (not (looking-at (format "%d .*\n" sequence)))))
1812             (when messagep
1813               (nnheader-message-maybe
1814                7 "nnimap read %dk from %s%s" (/ (buffer-size) 1000)
1815                nnimap-address
1816                (if (not (zerop (nnimap-initial-resync nnimap-object)))
1817                    (format " (initial sync of %d group%s; please wait)"
1818                            (nnimap-initial-resync nnimap-object)
1819                            (if (= (nnimap-initial-resync nnimap-object) 1)
1820                                ""
1821                              "s"))
1822                  "")))
1823             (nnheader-accept-process-output process)
1824             (goto-char (point-max)))
1825           (setf (nnimap-initial-resync nnimap-object) 0)
1826           openp)
1827       (quit
1828        (when debug-on-quit
1829          (debug "Quit"))
1830        ;; The user hit C-g while we were waiting: kill the process, in case
1831        ;; it's a gnutls-cli process that's stuck (tends to happen a lot behind
1832        ;; NAT routers).
1833        (delete-process process)
1834        nil))))
1835
1836 (defun nnimap-parse-response ()
1837   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1838         result)
1839     (dolist (line lines)
1840       (push (cdr (nnimap-parse-line line)) result))
1841     ;; Return the OK/error code first, and then all the "continuation
1842     ;; lines" afterwards.
1843     (cons (pop result)
1844           (nreverse result))))
1845
1846 ;; Parse an IMAP response line lightly.  They look like
1847 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1848 ;; the lines into a list of strings and lists of string.
1849 (defun nnimap-parse-line (line)
1850   (let (char result)
1851     (with-temp-buffer
1852       (mm-disable-multibyte)
1853       (insert line)
1854       (goto-char (point-min))
1855       (while (not (eobp))
1856         (if (eql (setq char (following-char)) ? )
1857             (forward-char 1)
1858           (push
1859            (cond
1860             ((eql char ?\[)
1861              (split-string
1862               (buffer-substring
1863                (1+ (point))
1864                (if (search-forward "]" (line-end-position) 'move)
1865                    (1- (point))
1866                  (point)))))
1867             ((eql char ?\()
1868              (split-string
1869               (buffer-substring
1870                (1+ (point))
1871                (if (search-forward ")" (line-end-position) 'move)
1872                    (1- (point))
1873                  (point)))))
1874             ((eql char ?\")
1875              (forward-char 1)
1876              (buffer-substring
1877               (point)
1878               (1- (or (search-forward "\"" (line-end-position) 'move)
1879                       (point)))))
1880             (t
1881              (buffer-substring (point) (if (search-forward " " nil t)
1882                                            (1- (point))
1883                                          (goto-char (point-max))))))
1884            result)))
1885       (nreverse result))))
1886
1887 (defun nnimap-last-response-string ()
1888   (save-excursion
1889     (forward-line 1)
1890     (let ((end (point)))
1891       (forward-line -1)
1892       (when (not (bobp))
1893         (forward-line -1)
1894         (while (and (not (bobp))
1895                     (eql (following-char) ?*))
1896           (forward-line -1))
1897         (unless (eql (following-char) ?*)
1898           (forward-line 1)))
1899       (buffer-substring (point) end))))
1900
1901 (defvar nnimap-incoming-split-list nil)
1902
1903 (defun nnimap-fetch-inbox (articles)
1904   (erase-buffer)
1905   (nnimap-wait-for-response
1906    (nnimap-send-command
1907     "UID FETCH %s %s"
1908     (nnimap-article-ranges articles)
1909     (format "(UID %s%s)"
1910             (format
1911              (if (nnimap-ver4-p)
1912                  "BODY.PEEK"
1913                "RFC822.PEEK"))
1914             (cond
1915              (nnimap-split-download-body-default
1916               "[]")
1917              ((nnimap-ver4-p)
1918               "[HEADER]")
1919              (t
1920               "[1]"))))
1921    t))
1922
1923 (defun nnimap-split-incoming-mail ()
1924   (with-current-buffer (nnimap-buffer)
1925     (let ((nnimap-incoming-split-list nil)
1926           (nnmail-split-methods
1927            (cond
1928             ((eq nnimap-split-methods 'default)
1929              nnmail-split-methods)
1930             (nnimap-split-methods
1931              nnimap-split-methods)
1932             (nnimap-split-fancy
1933              'nnmail-split-fancy)))
1934           (nnmail-split-fancy (or nnimap-split-fancy
1935                                   nnmail-split-fancy))
1936           (nnmail-inhibit-default-split-group t)
1937           (groups (nnimap-get-groups))
1938           new-articles)
1939       (erase-buffer)
1940       (nnimap-command "SELECT %S" nnimap-inbox)
1941       (setf (nnimap-group nnimap-object) nnimap-inbox)
1942       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1943       (when new-articles
1944         (nnimap-fetch-inbox new-articles)
1945         (nnimap-transform-split-mail)
1946         (nnheader-ms-strip-cr)
1947         (nnmail-cache-open)
1948         (nnmail-split-incoming (current-buffer)
1949                                #'nnimap-save-mail-spec
1950                                nil nil
1951                                #'nnimap-dummy-active-number
1952                                #'nnimap-save-mail-spec)
1953         (when nnimap-incoming-split-list
1954           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1955                 sequences junk-articles)
1956             ;; Create any groups that doesn't already exist on the
1957             ;; server first.
1958             (dolist (spec specs)
1959               (when (and (not (member (car spec) groups))
1960                          (not (eq (car spec) 'junk)))
1961                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1962             ;; Then copy over all the messages.
1963             (erase-buffer)
1964             (dolist (spec specs)
1965               (let ((group (car spec))
1966                     (ranges (cdr spec)))
1967                 (if (eq group 'junk)
1968                     (setq junk-articles ranges)
1969                   (push (list (nnimap-send-command
1970                                "UID COPY %s %S"
1971                                (nnimap-article-ranges ranges)
1972                                (utf7-encode group t))
1973                               ranges)
1974                         sequences))))
1975             ;; Wait for the last COPY response...
1976             (when sequences
1977               (nnimap-wait-for-response (caar sequences))
1978               ;; And then mark the successful copy actions as deleted,
1979               ;; and possibly expunge them.
1980               (nnimap-mark-and-expunge-incoming
1981                (nnimap-parse-copied-articles sequences)))
1982             (nnimap-mark-and-expunge-incoming junk-articles)))))))
1983
1984 (defun nnimap-mark-and-expunge-incoming (range)
1985   (when range
1986     (setq range (nnimap-article-ranges range))
1987     (erase-buffer)
1988     (let ((sequence
1989            (nnimap-send-command
1990             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
1991       (cond
1992        ;; If the server supports it, we now delete the message we have
1993        ;; just copied over.
1994        ((nnimap-capability "UIDPLUS")
1995         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
1996        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1997        ;; user has configured it.
1998        (nnimap-expunge
1999         (setq sequence (nnimap-send-command "EXPUNGE"))))
2000       (nnimap-wait-for-response sequence))))
2001
2002 (defun nnimap-parse-copied-articles (sequences)
2003   (let (sequence copied range)
2004     (goto-char (point-min))
2005     (while (re-search-forward "^\\([0-9]+\\) OK\\b" nil t)
2006       (setq sequence (string-to-number (match-string 1)))
2007       (when (setq range (cadr (assq sequence sequences)))
2008         (push (gnus-uncompress-range range) copied)))
2009     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
2010
2011 (defun nnimap-new-articles (flags)
2012   (let (new)
2013     (dolist (elem flags)
2014       (unless (gnus-list-memq-of-list nnimap-unsplittable-articles
2015                                       (cdr elem))
2016         (push (car elem) new)))
2017     (gnus-compress-sequence (nreverse new))))
2018
2019 (defun nnimap-make-split-specs (list)
2020   (let ((specs nil)
2021         entry)
2022     (dolist (elem list)
2023       (destructuring-bind (article spec) elem
2024         (dolist (group (delete nil (mapcar #'car spec)))
2025           (unless (setq entry (assoc group specs))
2026             (push (setq entry (list group)) specs))
2027           (setcdr entry (cons article (cdr entry))))))
2028     (dolist (entry specs)
2029       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
2030     specs))
2031
2032 (defun nnimap-transform-split-mail ()
2033   (goto-char (point-min))
2034   (let (article bytes)
2035     (block nil
2036       (while (not (eobp))
2037         (while (not (looking-at "\\* [0-9]+ FETCH.+UID \\([0-9]+\\)"))
2038           (delete-region (point) (progn (forward-line 1) (point)))
2039           (when (eobp)
2040             (return)))
2041         (setq article (match-string 1)
2042               bytes (nnimap-get-length))
2043         (delete-region (line-beginning-position) (line-end-position))
2044         ;; Insert MMDF separator, and a way to remember what this
2045         ;; article UID is.
2046         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
2047         (forward-char (1+ bytes))
2048         (setq bytes (nnimap-get-length))
2049         (delete-region (line-beginning-position) (line-end-position))
2050         ;; There's a body; skip past that.
2051         (when bytes
2052           (forward-char (1+ bytes))
2053           (delete-region (line-beginning-position) (line-end-position)))))))
2054
2055 (defun nnimap-dummy-active-number (group &optional server)
2056   1)
2057
2058 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
2059   (let (article)
2060     (goto-char (point-min))
2061     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
2062         (error "Invalid nnimap mail")
2063       (setq article (string-to-number (match-string 1))))
2064     (push (list article
2065                 (if (eq group-art 'junk)
2066                     (list (cons 'junk 1))
2067                   group-art))
2068           nnimap-incoming-split-list)))
2069
2070 (defun nnimap-make-thread-query (header)
2071   (let* ((id  (mail-header-id header))
2072          (refs (split-string
2073                 (or (mail-header-references header)
2074                     "")))
2075          (value
2076           (format
2077            "(OR HEADER REFERENCES %S HEADER Message-Id %S)"
2078            id id)))
2079     (dolist (refid refs value)
2080       (setq value (format
2081                    "(OR (OR HEADER Message-Id %S HEADER REFERENCES %S) %s)"
2082                    refid refid value)))))
2083
2084
2085 (provide 'nnimap)
2086
2087 ;;; nnimap.el ends here