cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'nnheader))
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'nnheader)
  36 (require 'gnus-util)
  37 (require 'gnus)
  38 (require 'nnoo)
  39 (require 'netrc)
  40 (require 'utf7)
  41 (require 'tls)
  42 (require 'parse-time)
  43
  44 (autoload 'auth-source-forget-user-or-password "auth-source")
  45 (autoload 'auth-source-user-or-password "auth-source")
  46
  47 (nnoo-declare nnimap)
  48
  49 (defvoo nnimap-address nil
  50   "The address of the IMAP server.")
  51
  52 (defvoo nnimap-server-port nil
  53   "The IMAP port used.
  54 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  55 it will default to `imap'.")
  56
  57 (defvoo nnimap-stream 'ssl
  58   "How nnimap will talk to the IMAP server.
  59 Values are `ssl', `network', `starttls' or `shell'.")
  60
  61 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  62                                  (if (listp imap-shell-program)
  63                                      (car imap-shell-program)
  64                                    imap-shell-program)
  65                                "ssh %s imapd"))
  66
  67 (defvoo nnimap-inbox nil
  68   "The mail box where incoming mail arrives and should be split out of.")
  69
  70 (defvoo nnimap-split-methods nil
  71   "How mail is split.
  72 Uses the same syntax as nnmail-split-methods")
  73
  74 (defvoo nnimap-split-fancy nil
  75   "Uses the same syntax as nnmail-split-fancy.")
  76
  77 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  78                         "Emacs 24.1")
  79
  80 (defvoo nnimap-authenticator nil
  81   "How nnimap authenticate itself to the server.
  82 Possible choices are nil (use default methods) or `anonymous'.")
  83
  84 (defvoo nnimap-expunge t
  85   "If non-nil, expunge articles after deleting them.
  86 This is always done if the server supports UID EXPUNGE, but it's
  87 not done by default on servers that doesn't support that command.")
  88
  89 (defvoo nnimap-streaming t
  90   "If non-nil, try to use streaming commands with IMAP servers.
  91 Switching this off will make nnimap slower, but it helps with
  92 some servers.")
  93
  94 (defvoo nnimap-connection-alist nil)
  95
  96 (defvoo nnimap-current-infos nil)
  97
  98 (defvoo nnimap-fetch-partial-articles nil
  99   "If non-nil, Gnus will fetch partial articles.
 100 If t, nnimap will fetch only the first part.  If a string, it
 101 will fetch all parts that have types that match that string.  A
 102 likely value would be \"text/\" to automatically fetch all
 103 textual parts.")
 104
 105 (defvar nnimap-process nil)
 106
 107 (defvar nnimap-status-string "")
 108
 109 (defvar nnimap-split-download-body-default nil
 110   "Internal variable with default value for `nnimap-split-download-body'.")
 111
 112 (defvar nnimap-keepalive-timer nil)
 113 (defvar nnimap-process-buffers nil)
 114
 115 (defstruct nnimap
 116   group process commands capabilities select-result newlinep server
 117   last-command-time greeting)
 118
 119 (defvar nnimap-object nil)
 120
 121 (defvar nnimap-mark-alist
 122   '((read "\\Seen" %Seen)
 123     (tick "\\Flagged" %Flagged)
 124     (reply "\\Answered" %Answered)
 125     (expire "gnus-expire")
 126     (dormant "gnus-dormant")
 127     (score "gnus-score")
 128     (save "gnus-save")
 129     (download "gnus-download")
 130     (forward "gnus-forward")))
 131
 132 (defun nnimap-buffer ()
 133   (nnimap-find-process-buffer nntp-server-buffer))
 134
 135 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 136   (with-current-buffer nntp-server-buffer
 137     (erase-buffer)
 138     (when (nnimap-possibly-change-group group server)
 139       (with-current-buffer (nnimap-buffer)
 140         (erase-buffer)
 141         (nnimap-wait-for-response
 142          (nnimap-send-command
 143           "UID FETCH %s %s"
 144           (nnimap-article-ranges (gnus-compress-sequence articles))
 145           (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 146                   (format
 147                    (if (nnimap-ver4-p)
 148                        "BODY.PEEK[HEADER.FIELDS %s]"
 149                      "RFC822.HEADER.LINES %s")
 150                    (append '(Subject From Date Message-Id
 151                                      References In-Reply-To Xref)
 152                            nnmail-extra-headers))))
 153          t)
 154         (nnimap-transform-headers))
 155       (insert-buffer-substring
 156        (nnimap-find-process-buffer (current-buffer))))
 157     'headers))
 158
 159 (defun nnimap-transform-headers ()
 160   (goto-char (point-min))
 161   (let (article bytes lines size string)
 162     (block nil
 163       (while (not (eobp))
 164         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 165           (delete-region (point) (progn (forward-line 1) (point)))
 166           (when (eobp)
 167             (return)))
 168         (setq article (match-string 1))
 169         ;; Unfold quoted {number} strings.
 170         (while (re-search-forward "[^]] {\\([0-9]+\\)}\r\n"
 171                                   (1+ (line-end-position)) t)
 172           (setq size (string-to-number (match-string 1)))
 173           (delete-region (+ (match-beginning 0) 2) (point))
 174           (setq string (delete-region (point) (+ (point) size)))
 175           (insert (format "%S" string)))
 176         (setq bytes (nnimap-get-length)
 177               lines nil)
 178         (beginning-of-line)
 179         (setq size
 180               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 181                                       (line-end-position)
 182                                       t)
 183                    (match-string 1)))
 184         (beginning-of-line)
 185         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 186           (let ((structure (ignore-errors
 187                              (read (current-buffer)))))
 188             (while (and (consp structure)
 189                         (not (stringp (car structure))))
 190               (setq structure (car structure)))
 191             (setq lines (nth 7 structure))))
 192         (delete-region (line-beginning-position) (line-end-position))
 193         (insert (format "211 %s Article retrieved." article))
 194         (forward-line 1)
 195         (when size
 196           (insert (format "Chars: %s\n" size)))
 197         (when lines
 198           (insert (format "Lines: %s\n" lines)))
 199         (re-search-forward "^\r$")
 200         (delete-region (line-beginning-position) (line-end-position))
 201         (insert ".")
 202         (forward-line 1)))))
 203
 204 (defun nnimap-get-length ()
 205   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 206        (string-to-number (match-string 1))))
 207
 208 (defun nnimap-article-ranges (ranges)
 209   (let (result)
 210     (cond
 211      ((numberp ranges)
 212       (number-to-string ranges))
 213      ((numberp (cdr ranges))
 214       (format "%d:%d" (car ranges) (cdr ranges)))
 215      (t
 216       (dolist (elem ranges)
 217         (push
 218          (if (consp elem)
 219              (format "%d:%d" (car elem) (cdr elem))
 220            (number-to-string elem))
 221          result))
 222       (mapconcat #'identity (nreverse result) ",")))))
 223
 224 (deffoo nnimap-open-server (server &optional defs)
 225   (if (nnimap-server-opened server)
 226       t
 227     (unless (assq 'nnimap-address defs)
 228       (setq defs (append defs (list (list 'nnimap-address server)))))
 229     (nnoo-change-server 'nnimap server defs)
 230     (or (nnimap-find-connection nntp-server-buffer)
 231         (nnimap-open-connection nntp-server-buffer))))
 232
 233 (defun nnimap-make-process-buffer (buffer)
 234   (with-current-buffer
 235       (generate-new-buffer (format "*nnimap %s %s %s*"
 236                                    nnimap-address nnimap-server-port
 237                                    (gnus-buffer-exists-p buffer)))
 238     (mm-disable-multibyte)
 239     (buffer-disable-undo)
 240     (gnus-add-buffer)
 241     (set (make-local-variable 'after-change-functions) nil)
 242     (set (make-local-variable 'nnimap-object)
 243          (make-nnimap :server (nnoo-current-server 'nnimap)))
 244     (push (list buffer (current-buffer)) nnimap-connection-alist)
 245     (push (current-buffer) nnimap-process-buffers)
 246     (current-buffer)))
 247
 248 (defun nnimap-open-shell-stream (name buffer host port)
 249   (let ((process-connection-type nil))
 250     (start-process name buffer shell-file-name
 251                    shell-command-switch
 252                    (format-spec
 253                     nnimap-shell-program
 254                     (format-spec-make
 255                      ?s host
 256                      ?p port)))))
 257
 258 (defun nnimap-credentials (address ports &optional inhibit-create)
 259   (let (port credentials)
 260     ;; Request the credentials from all ports, but only query on the
 261     ;; last port if all the previous ones have failed.
 262     (while (and (null credentials)
 263                 (setq port (pop ports)))
 264       (setq credentials
 265             (auth-source-user-or-password
 266              '("login" "password") address port nil
 267              (if inhibit-create
 268                  nil
 269                (null ports)))))
 270     credentials))
 271
 272 (defun nnimap-keepalive ()
 273   (let ((now (current-time)))
 274     (dolist (buffer nnimap-process-buffers)
 275       (when (buffer-name buffer)
 276         (with-current-buffer buffer
 277           (when (and nnimap-object
 278                      (nnimap-last-command-time nnimap-object)
 279                      (> (time-to-seconds
 280                          (time-subtract
 281                           now
 282                           (nnimap-last-command-time nnimap-object)))
 283                         ;; More than five minutes since the last command.
 284                         (* 5 60)))
 285             (nnimap-send-command "NOOP")))))))
 286
 287 (defun nnimap-open-connection (buffer)
 288   (unless nnimap-keepalive-timer
 289     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 290                                               'nnimap-keepalive)))
 291   (block nil
 292     (with-current-buffer (nnimap-make-process-buffer buffer)
 293       (let* ((coding-system-for-read 'binary)
 294              (coding-system-for-write 'binary)
 295              (port nil)
 296              (ports
 297               (cond
 298                ((eq nnimap-stream 'network)
 299                 (open-network-stream
 300                  "*nnimap*" (current-buffer) nnimap-address
 301                  (setq port
 302                        (or nnimap-server-port
 303                            (if (netrc-find-service-number "imap")
 304                                "imap"
 305                              "143"))))
 306                 '("143" "imap"))
 307                ((eq nnimap-stream 'shell)
 308                 (nnimap-open-shell-stream
 309                  "*nnimap*" (current-buffer) nnimap-address
 310                  (setq port (or nnimap-server-port "imap")))
 311                 '("imap"))
 312                ((eq nnimap-stream 'starttls)
 313                 (let ((tls-program (nnimap-extend-tls-programs)))
 314                   (open-tls-stream
 315                    "*nnimap*" (current-buffer) nnimap-address
 316                    (setq port (or nnimap-server-port "imap"))
 317                    'starttls))
 318                 '("imap"))
 319                ((memq nnimap-stream '(ssl tls))
 320                 (funcall (if (fboundp 'open-gnutls-stream)
 321                              'open-gnutls-stream
 322                            'open-tls-stream)
 323                          "*nnimap*" (current-buffer) nnimap-address
 324                          (setq port
 325                                (or nnimap-server-port
 326                                    (if (netrc-find-service-number "imaps")
 327                                        "imaps"
 328                                      "993"))))
 329                 '("143" "993" "imap" "imaps"))
 330                (t
 331                 (error "Unknown stream type: %s" nnimap-stream))))
 332              connection-result login-result credentials)
 333         (setf (nnimap-process nnimap-object)
 334               (get-buffer-process (current-buffer)))
 335         (if (not (and (nnimap-process nnimap-object)
 336                       (memq (process-status (nnimap-process nnimap-object))
 337                             '(open run))))
 338             (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 339                              nnimap-address port nnimap-stream)
 340           (gnus-set-process-query-on-exit-flag
 341            (nnimap-process nnimap-object) nil)
 342           (if (not (setq connection-result (nnimap-wait-for-connection)))
 343               (nnheader-report 'nnimap
 344                                "%s" (buffer-substring
 345                                      (point) (line-end-position)))
 346             ;; Store the greeting (for debugging purposes).
 347             (setf (nnimap-greeting nnimap-object)
 348                   (buffer-substring (line-beginning-position)
 349                                     (line-end-position)))
 350             ;; Store the capabilities.
 351             (setf (nnimap-capabilities nnimap-object)
 352                   (mapcar
 353                    #'upcase
 354                    (nnimap-find-parameter
 355                     "CAPABILITY" (cdr (nnimap-command "CAPABILITY")))))
 356             (when nnimap-server-port
 357               (push (format "%s" nnimap-server-port) ports))
 358             ;; If this is a STARTTLS-capable server, then sever the
 359             ;; connection and start a STARTTLS connection instead.
 360             (when (and (eq nnimap-stream 'network)
 361                        (member "STARTTLS" (nnimap-capabilities nnimap-object)))
 362               (let ((nnimap-stream 'starttls))
 363                 (let ((tls-process
 364                        (nnimap-open-connection buffer)))
 365                   ;; If the STARTTLS connection was successful, we
 366                   ;; kill our first non-encrypted connection.  If it
 367                   ;; wasn't successful, we just use our unencrypted
 368                   ;; connection.
 369                   (when (memq (process-status tls-process) '(open run))
 370                     (delete-process (nnimap-process nnimap-object))
 371                     (kill-buffer (current-buffer))
 372                     (return tls-process)))))
 373             (unless (equal connection-result "PREAUTH")
 374               (if (not (setq credentials
 375                              (if (eq nnimap-authenticator 'anonymous)
 376                                  (list "anonymous"
 377                                        (message-make-address))
 378                                (or
 379                                 ;; First look for the credentials based
 380                                 ;; on the virtual server name.
 381                                 (nnimap-credentials
 382                                  (nnoo-current-server 'nnimap) ports t)
 383                                 ;; Then look them up based on the
 384                                 ;; physical address.
 385                                 (nnimap-credentials nnimap-address ports)))))
 386                   (setq nnimap-object nil)
 387                 (setq login-result (nnimap-command "LOGIN %S %S"
 388                                                    (car credentials)
 389                                                    (cadr credentials)))
 390                 (unless (car login-result)
 391                   ;; If the login failed, then forget the credentials
 392                   ;; that are now possibly cached.
 393                   (dolist (host (list (nnoo-current-server 'nnimap)
 394                                       nnimap-address))
 395                     (dolist (port ports)
 396                       (dolist (element '("login" "password"))
 397                         (auth-source-forget-user-or-password
 398                          element host port))))
 399                   (delete-process (nnimap-process nnimap-object))
 400                   (setq nnimap-object nil))))
 401             (when nnimap-object
 402               (when (member "QRESYNC" (nnimap-capabilities nnimap-object))
 403                 (nnimap-command "ENABLE QRESYNC"))
 404               (nnimap-process nnimap-object))))))))
 405
 406 (defun nnimap-extend-tls-programs ()
 407   (let ((programs tls-program)
 408         result)
 409     (unless (consp programs)
 410       (setq programs (list programs)))
 411     (dolist (program programs)
 412       (when (assoc (car (split-string program)) tls-starttls-switches)
 413         (push (if (not (string-match "%s" program))
 414                   (concat program " " "%s")
 415                 program)
 416               result)))
 417     (nreverse result)))
 418
 419 (defun nnimap-find-parameter (parameter elems)
 420   (let (result)
 421     (dolist (elem elems)
 422       (cond
 423        ((equal (car elem) parameter)
 424         (setq result (cdr elem)))
 425        ((and (equal (car elem) "OK")
 426              (consp (cadr elem))
 427              (equal (caadr elem) parameter))
 428         (setq result (cdr (cadr elem))))))
 429     result))
 430
 431 (deffoo nnimap-close-server (&optional server)
 432   (when (nnoo-change-server 'nnimap server nil)
 433     (ignore-errors
 434       (delete-process (get-buffer-process (nnimap-buffer))))
 435     t))
 436
 437 (deffoo nnimap-request-close ()
 438   t)
 439
 440 (deffoo nnimap-server-opened (&optional server)
 441   (and (nnoo-current-server-p 'nnimap server)
 442        nntp-server-buffer
 443        (gnus-buffer-live-p nntp-server-buffer)
 444        (nnimap-find-connection nntp-server-buffer)))
 445
 446 (deffoo nnimap-status-message (&optional server)
 447   nnimap-status-string)
 448
 449 (deffoo nnimap-request-article (article &optional group server to-buffer)
 450   (with-current-buffer nntp-server-buffer
 451     (let ((result (nnimap-possibly-change-group group server))
 452           parts structure)
 453       (when (stringp article)
 454         (setq article (nnimap-find-article-by-message-id group article)))
 455       (when (and result
 456                  article)
 457         (erase-buffer)
 458         (with-current-buffer (nnimap-buffer)
 459           (erase-buffer)
 460           (when nnimap-fetch-partial-articles
 461             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 462             (goto-char (point-min))
 463             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 464               (setq structure (ignore-errors
 465                                 (let ((start (point)))
 466                                   (forward-sexp 1)
 467                                   (downcase-region start (point))
 468                                   (goto-char (point))
 469                                   (read (current-buffer))))
 470                     parts (nnimap-find-wanted-parts structure))))
 471           (when (if parts
 472                     (nnimap-get-partial-article article parts structure)
 473                   (nnimap-get-whole-article article))
 474             (let ((buffer (current-buffer)))
 475               (with-current-buffer (or to-buffer nntp-server-buffer)
 476                 (erase-buffer)
 477                 (insert-buffer-substring buffer)
 478                 (nnheader-ms-strip-cr)
 479                 (cons group article)))))))))
 480
 481 (defun nnimap-get-whole-article (article)
 482   (let ((result
 483          (nnimap-command
 484           (if (nnimap-ver4-p)
 485               "UID FETCH %d BODY.PEEK[]"
 486             "UID FETCH %d RFC822.PEEK")
 487           article)))
 488     ;; Check that we really got an article.
 489     (goto-char (point-min))
 490     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 491       (setq result nil))
 492     (when result
 493       ;; Remove any data that may have arrived before the FETCH data.
 494       (beginning-of-line)
 495       (unless (bobp)
 496         (delete-region (point-min) (point)))
 497       (let ((bytes (nnimap-get-length)))
 498         (delete-region (line-beginning-position)
 499                        (progn (forward-line 1) (point)))
 500         (goto-char (+ (point) bytes))
 501         (delete-region (point) (point-max)))
 502       t)))
 503
 504 (defun nnimap-ver4-p ()
 505   (member "IMAP4REV1" (nnimap-capabilities nnimap-object)))
 506
 507 (defun nnimap-get-partial-article (article parts structure)
 508   (let ((result
 509          (nnimap-command
 510           "UID FETCH %d (%s %s)"
 511           article
 512           (if (nnimap-ver4-p)
 513               "BODY.PEEK[HEADER]"
 514             "RFC822.HEADER")
 515           (if (nnimap-ver4-p)
 516               (mapconcat (lambda (part)
 517                            (format "BODY.PEEK[%s]" part))
 518                          parts " ")
 519             (mapconcat (lambda (part)
 520                          (format "RFC822.PEEK[%s]" part))
 521                        parts " ")))))
 522     (when result
 523       (nnimap-convert-partial-article structure))))
 524
 525 (defun nnimap-convert-partial-article (structure)
 526   ;; First just skip past the headers.
 527   (goto-char (point-min))
 528   (let ((bytes (nnimap-get-length))
 529         id parts)
 530     ;; Delete "FETCH" line.
 531     (delete-region (line-beginning-position)
 532                    (progn (forward-line 1) (point)))
 533     (goto-char (+ (point) bytes))
 534     ;; Collect all the body parts.
 535     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 536       (setq id (match-string 1)
 537             bytes (nnimap-get-length))
 538       (beginning-of-line)
 539       (delete-region (point) (progn (forward-line 1) (point)))
 540       (push (list id (buffer-substring (point) (+ (point) bytes)))
 541             parts)
 542       (delete-region (point) (+ (point) bytes)))
 543     ;; Delete trailing junk.
 544     (delete-region (point) (point-max))
 545     ;; Now insert all the parts again where they fit in the structure.
 546     (nnimap-insert-partial-structure structure parts)
 547     t))
 548
 549 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 550   (let (type boundary)
 551     (let ((bstruc structure))
 552       (while (consp (car bstruc))
 553         (pop bstruc))
 554       (setq type (car bstruc))
 555       (setq bstruc (car (cdr bstruc)))
 556       (when (and (stringp (car bstruc))
 557                  (string= (downcase (car bstruc)) "boundary"))
 558         (setq boundary (cadr bstruc))))
 559     (when subp
 560       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 561                       (downcase type) boundary)))
 562     (while (not (stringp (car structure)))
 563       (insert "\n--" boundary "\n")
 564       (if (consp (caar structure))
 565           (nnimap-insert-partial-structure (pop structure) parts t)
 566         (let ((bit (pop structure)))
 567           (insert (format  "Content-type: %s/%s"
 568                            (downcase (nth 0 bit))
 569                            (downcase (nth 1 bit))))
 570           (if (member "CHARSET" (nth 2 bit))
 571               (insert (format
 572                        "; charset=%S\n" (cadr (member "CHARSET" (nth 2 bit)))))
 573             (insert "\n"))
 574           (insert (format "Content-transfer-encoding: %s\n"
 575                           (nth 5 bit)))
 576           (insert "\n")
 577           (when (assoc (nth 9 bit) parts)
 578             (insert (cadr (assoc (nth 9 bit) parts)))))))
 579     (insert "\n--" boundary "--\n")))
 580
 581 (defun nnimap-find-wanted-parts (structure)
 582   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 583
 584 (defun nnimap-find-wanted-parts-1 (structure prefix)
 585   (let ((num 1)
 586         parts)
 587     (while (consp (car structure))
 588       (let ((sub (pop structure)))
 589         (if (consp (car sub))
 590             (push (nnimap-find-wanted-parts-1
 591                    sub (if (string= prefix "")
 592                            (number-to-string num)
 593                          (format "%s.%s" prefix num)))
 594                   parts)
 595           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 596                 (id (if (string= prefix "")
 597                         (number-to-string num)
 598                       (format "%s.%s" prefix num))))
 599             (setcar (nthcdr 9 sub) id)
 600             (when (if (eq nnimap-fetch-partial-articles t)
 601                       (equal id "1")
 602                     (string-match nnimap-fetch-partial-articles type))
 603               (push id parts))))
 604         (incf num)))
 605     (nreverse parts)))
 606
 607 (deffoo nnimap-request-group (group &optional server dont-check info)
 608   (let ((result (nnimap-possibly-change-group group server))
 609         articles active marks high low)
 610     (with-current-buffer nntp-server-buffer
 611       (when result
 612         (if (and dont-check
 613                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 614             (insert (format "211 %d %d %d %S\n"
 615                             (- (cdr active) (car active))
 616                             (car active)
 617                             (cdr active)
 618                             group))
 619           (with-current-buffer (nnimap-buffer)
 620             (erase-buffer)
 621             (let ((group-sequence
 622                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 623                   (flag-sequence
 624                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 625               (nnimap-wait-for-response flag-sequence)
 626               (setq marks
 627                     (nnimap-flags-to-marks
 628                      (nnimap-parse-flags
 629                       (list (list group-sequence flag-sequence
 630                                   1 group "SELECT")))))
 631               (when (and info
 632                          marks)
 633                 (nnimap-update-infos marks (list info)))
 634               (goto-char (point-max))
 635               (let ((uidnext (nth 5 (car marks))))
 636                 (setq high (or (if uidnext
 637                                    (1- uidnext)
 638                                  (nth 3 (car marks)))
 639                                0)
 640                       low (or (nth 4 (car marks)) uidnext 1)))))
 641           (erase-buffer)
 642           (insert
 643            (format
 644             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 645         t))))
 646
 647 (deffoo nnimap-request-create-group (group &optional server args)
 648   (when (nnimap-possibly-change-group nil server)
 649     (with-current-buffer (nnimap-buffer)
 650       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 651
 652 (deffoo nnimap-request-delete-group (group &optional force server)
 653   (when (nnimap-possibly-change-group nil server)
 654     (with-current-buffer (nnimap-buffer)
 655       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 656
 657 (deffoo nnimap-request-rename-group (group new-name &optional server)
 658   (when (nnimap-possibly-change-group nil server)
 659     (with-current-buffer (nnimap-buffer)
 660       (car (nnimap-command "RENAME %S %S"
 661                            (utf7-encode group t) (utf7-encode new-name t))))))
 662
 663 (deffoo nnimap-request-expunge-group (group &optional server)
 664   (when (nnimap-possibly-change-group group server)
 665     (with-current-buffer (nnimap-buffer)
 666       (car (nnimap-command "EXPUNGE")))))
 667
 668 (defun nnimap-get-flags (spec)
 669   (let ((articles nil)
 670         elems end)
 671     (with-current-buffer (nnimap-buffer)
 672       (erase-buffer)
 673       (nnimap-wait-for-response (nnimap-send-command
 674                                  "UID FETCH %s FLAGS" spec))
 675       (setq end (point))
 676       (subst-char-in-region (point-min) (point-max)
 677                             ?\\ ?% t)
 678       (goto-char (point-min))
 679       (while (search-forward " FETCH " end t)
 680         (setq elems (read (current-buffer)))
 681         (push (cons (cadr (memq 'UID elems))
 682                     (cadr (memq 'FLAGS elems)))
 683               articles)))
 684     (nreverse articles)))
 685
 686 (deffoo nnimap-close-group (group &optional server)
 687   t)
 688
 689 (deffoo nnimap-request-move-article (article group server accept-form
 690                                              &optional last internal-move-group)
 691   (with-temp-buffer
 692     (when (nnimap-request-article article group server (current-buffer))
 693       ;; If the move is internal (on the same server), just do it the easy
 694       ;; way.
 695       (let ((message-id (message-field-value "message-id")))
 696         (if internal-move-group
 697             (let ((result
 698                    (with-current-buffer (nnimap-buffer)
 699                      (nnimap-command "UID COPY %d %S"
 700                                      article
 701                                      (utf7-encode internal-move-group t)))))
 702               (when (car result)
 703                 (nnimap-delete-article article)
 704                 (cons internal-move-group
 705                       (nnimap-find-article-by-message-id
 706                        internal-move-group message-id))))
 707           ;; Move the article to a different method.
 708           (let ((result (eval accept-form)))
 709             (when result
 710               (nnimap-delete-article article)
 711               result)))))))
 712
 713 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 714   (cond
 715    ((null articles)
 716     nil)
 717    ((not (nnimap-possibly-change-group group server))
 718     articles)
 719    ((and force
 720          (eq nnmail-expiry-target 'delete))
 721     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 722       (message "Article marked for deletion, but not expunged."))
 723     nil)
 724    (t
 725     (let ((deletable-articles
 726            (if (or force
 727                    (eq nnmail-expiry-wait 'immediate))
 728                articles
 729              (gnus-sorted-intersection
 730               articles
 731               (nnimap-find-expired-articles group)))))
 732       (if (null deletable-articles)
 733           articles
 734         (if (eq nnmail-expiry-target 'delete)
 735             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 736           (setq deletable-articles
 737                 (nnimap-process-expiry-targets
 738                  deletable-articles group server)))
 739         ;; Return the articles we didn't delete.
 740         (gnus-sorted-complement articles deletable-articles))))))
 741
 742 (defun nnimap-process-expiry-targets (articles group server)
 743   (let ((deleted-articles nil))
 744     (dolist (article articles)
 745       (let ((target nnmail-expiry-target))
 746         (with-temp-buffer
 747           (when (nnimap-request-article article group server (current-buffer))
 748             (message "Expiring article %s:%d" group article)
 749             (when (functionp target)
 750               (setq target (funcall target group)))
 751             (when (and target
 752                        (not (eq target 'delete)))
 753               (if (or (gnus-request-group target t)
 754                       (gnus-request-create-group target))
 755                   (nnmail-expiry-target-group target group)
 756                 (setq target nil)))
 757             (when target
 758               (push article deleted-articles))))))
 759     ;; Change back to the current group again.
 760     (nnimap-possibly-change-group group server)
 761     (setq deleted-articles (nreverse deleted-articles))
 762     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 763     deleted-articles))
 764
 765 (defun nnimap-find-expired-articles (group)
 766   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 767     (with-current-buffer (nnimap-buffer)
 768       (let ((result
 769              (nnimap-command
 770               "UID SEARCH SENTBEFORE %s"
 771               (format-time-string
 772                (format "%%d-%s-%%Y"
 773                        (upcase
 774                         (car (rassoc (nth 4 (decode-time cutoff))
 775                                      parse-time-months))))
 776                cutoff))))
 777         (and (car result)
 778              (delete 0 (mapcar #'string-to-number
 779                                (cdr (assoc "SEARCH" (cdr result))))))))))
 780
 781
 782 (defun nnimap-find-article-by-message-id (group message-id)
 783   (with-current-buffer (nnimap-buffer)
 784     (erase-buffer)
 785     (setf (nnimap-group nnimap-object) nil)
 786     (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 787     (let ((sequence
 788            (nnimap-send-command "UID SEARCH HEADER Message-Id %S" message-id))
 789           article result)
 790       (setq result (nnimap-wait-for-response sequence))
 791       (when (and result
 792                  (car (setq result (nnimap-parse-response))))
 793         ;; Select the last instance of the message in the group.
 794         (and (setq article
 795                    (car (last (assoc "SEARCH" (cdr result)))))
 796              (string-to-number article))))))
 797
 798 (defun nnimap-delete-article (articles)
 799   (with-current-buffer (nnimap-buffer)
 800     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 801                     (nnimap-article-ranges articles))
 802     (cond
 803      ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
 804       (nnimap-command "UID EXPUNGE %s"
 805                       (nnimap-article-ranges articles))
 806       t)
 807      (nnimap-expunge
 808       (nnimap-command "EXPUNGE")
 809       t)
 810      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
 811                                 "server doesn't support UIDPLUS, so we won't "
 812                                 "delete this article now"))))))
 813
 814 (deffoo nnimap-request-scan (&optional group server)
 815   (when (and (nnimap-possibly-change-group nil server)
 816              nnimap-inbox
 817              nnimap-split-methods)
 818     (message "nnimap %s splitting mail..." server)
 819     (nnimap-split-incoming-mail)))
 820
 821 (defun nnimap-marks-to-flags (marks)
 822   (let (flags flag)
 823     (dolist (mark marks)
 824       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 825         (push flag flags)))
 826     flags))
 827
 828 (deffoo nnimap-request-set-mark (group actions &optional server)
 829   (when (nnimap-possibly-change-group group server)
 830     (let (sequence)
 831       (with-current-buffer (nnimap-buffer)
 832         (erase-buffer)
 833         ;; Just send all the STORE commands without waiting for
 834         ;; response.  If they're successful, they're successful.
 835         (dolist (action actions)
 836           (destructuring-bind (range action marks) action
 837             (let ((flags (nnimap-marks-to-flags marks)))
 838               (when flags
 839                 (setq sequence (nnimap-send-command
 840                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 841                                 (nnimap-article-ranges range)
 842                                 (if (eq action 'del)
 843                                     "-"
 844                                   "+")
 845                                 (mapconcat #'identity flags " ")))))))
 846         ;; Wait for the last command to complete to avoid later
 847         ;; syncronisation problems with the stream.
 848         (when sequence
 849           (nnimap-wait-for-response sequence))))))
 850
 851 (deffoo nnimap-request-accept-article (group &optional server last)
 852   (when (nnimap-possibly-change-group nil server)
 853     (nnmail-check-syntax)
 854     (let ((message-id (message-field-value "message-id"))
 855           sequence message)
 856       (nnimap-add-cr)
 857       (setq message (buffer-string))
 858       (with-current-buffer (nnimap-buffer)
 859         (setq sequence (nnimap-send-command
 860                         "APPEND %S {%d}" (utf7-encode group t)
 861                         (length message)))
 862         (process-send-string (get-buffer-process (current-buffer)) message)
 863         (process-send-string (get-buffer-process (current-buffer))
 864                              (if (nnimap-newlinep nnimap-object)
 865                                  "\n"
 866                                "\r\n"))
 867         (let ((result (nnimap-get-response sequence)))
 868           (if (not (car result))
 869               (progn
 870                 (message "%s" (nnheader-get-report-string 'nnimap))
 871                 nil)
 872             (cons group
 873                   (nnimap-find-article-by-message-id group message-id))))))))
 874
 875 (defun nnimap-add-cr ()
 876   (goto-char (point-min))
 877   (while (re-search-forward "\r?\n" nil t)
 878     (replace-match "\r\n" t t)))
 879
 880 (defun nnimap-get-groups ()
 881   (let ((result (nnimap-command "LIST \"\" \"*\""))
 882         groups)
 883     (when (car result)
 884       (dolist (line (cdr result))
 885         (when (and (equal (car line) "LIST")
 886                    (not (and (caadr line)
 887                              (string-match "noselect" (caadr line)))))
 888           (push (car (last line)) groups)))
 889       (nreverse groups))))
 890
 891 (deffoo nnimap-request-list (&optional server)
 892   (nnimap-possibly-change-group nil server)
 893   (with-current-buffer nntp-server-buffer
 894     (erase-buffer)
 895     (let ((groups
 896            (with-current-buffer (nnimap-buffer)
 897              (nnimap-get-groups)))
 898           sequences responses)
 899       (when groups
 900         (with-current-buffer (nnimap-buffer)
 901           (setf (nnimap-group nnimap-object) nil)
 902           (dolist (group groups)
 903             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 904                         group)
 905                   sequences))
 906           (nnimap-wait-for-response (caar sequences))
 907           (setq responses
 908                 (nnimap-get-responses (mapcar #'car sequences))))
 909         (dolist (response responses)
 910           (let* ((sequence (car response))
 911                  (response (cadr response))
 912                  (group (cadr (assoc sequence sequences))))
 913             (when (and group
 914                        (equal (caar response) "OK"))
 915               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
 916                     highest exists)
 917                 (dolist (elem response)
 918                   (when (equal (cadr elem) "EXISTS")
 919                     (setq exists (string-to-number (car elem)))))
 920                 (when uidnext
 921                   (setq highest (1- (string-to-number (car uidnext)))))
 922                 (cond
 923                  ((null highest)
 924                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
 925                  ((zerop exists)
 926                   ;; Empty group.
 927                   (insert (format "%S %d %d y\n"
 928                                   (utf7-decode group t) highest (1+ highest))))
 929                  (t
 930                   ;; Return the widest possible range.
 931                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
 932                                   (or highest exists)))))))))
 933         t))))
 934
 935 (deffoo nnimap-request-newgroups (date &optional server)
 936   (nnimap-possibly-change-group nil server)
 937   (with-current-buffer nntp-server-buffer
 938     (erase-buffer)
 939     (dolist (group (with-current-buffer (nnimap-buffer)
 940                      (nnimap-get-groups)))
 941       (unless (assoc group nnimap-current-infos)
 942         ;; Insert dummy numbers here -- they don't matter.
 943         (insert (format "%S 0 1 y\n" group))))
 944     t))
 945
 946 (deffoo nnimap-retrieve-group-data-early (server infos)
 947   (when (nnimap-possibly-change-group nil server)
 948     (with-current-buffer (nnimap-buffer)
 949       (erase-buffer)
 950       (setf (nnimap-group nnimap-object) nil)
 951       ;; QRESYNC handling isn't implemented.
 952       (let ((qresyncp (member "notQRESYNC" (nnimap-capabilities nnimap-object)))
 953             params groups sequences active uidvalidity modseq group)
 954         ;; Go through the infos and gather the data needed to know
 955         ;; what and how to request the data.
 956         (dolist (info infos)
 957           (setq params (gnus-info-params info)
 958                 group (gnus-group-real-name (gnus-info-group info))
 959                 active (cdr (assq 'active params))
 960                 uidvalidity (cdr (assq 'uidvalidity params))
 961                 modseq (cdr (assq 'modseq params)))
 962           (if (and qresyncp
 963                    uidvalidity
 964                    modseq)
 965               (push
 966                (list (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
 967                                           group uidvalidity modseq)
 968                      'qresync
 969                      nil group 'qresync)
 970                sequences)
 971             (let ((start
 972                    (if (and active uidvalidity)
 973                        ;; Fetch the last 100 flags.
 974                        (max 1 (- (cdr active) 100))
 975                      1))
 976                   (command
 977                    (if uidvalidity
 978                        "EXAMINE"
 979                      ;; If we don't have a UIDVALIDITY, then this is
 980                      ;; the first time we've seen the group, so we
 981                      ;; have to do a SELECT (which is slower than an
 982                      ;; examine), but will tell us whether the group
 983                      ;; is read-only or not.
 984                      "SELECT")))
 985               (push (list (nnimap-send-command "%s %S" command group)
 986                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
 987                           start group command)
 988                     sequences)))
 989           ;; Some servers apparently can't have many outstanding
 990           ;; commands, so throttle them.
 991           (when (and (not nnimap-streaming)
 992                      (car sequences))
 993             (nnimap-wait-for-response (caar sequences))))
 994         sequences))))
 995
 996 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
 997   (when (and sequences
 998              (nnimap-possibly-change-group nil server))
 999     (with-current-buffer (nnimap-buffer)
1000       ;; Wait for the final data to trickle in.
1001       (when (nnimap-wait-for-response (if (eq (cadar sequences) 'qresync)
1002                                           (caar sequences)
1003                                         (cadar sequences))
1004                                       t)
1005         ;; Now we should have most of the data we need, no matter
1006         ;; whether we're QRESYNCING, fetching all the flags from
1007         ;; scratch, or just fetching the last 100 flags per group.
1008         (nnimap-update-infos (nnimap-flags-to-marks
1009                               (nnimap-parse-flags
1010                                (nreverse sequences)))
1011                              infos)
1012         ;; Finally, just return something resembling an active file in
1013         ;; the nntp buffer, so that the agent can save the info, too.
1014         (with-current-buffer nntp-server-buffer
1015           (erase-buffer)
1016           (dolist (info infos)
1017             (let* ((group (gnus-info-group info))
1018                    (active (gnus-active group)))
1019               (when active
1020                 (insert (format "%S %d %d y\n"
1021                                 (gnus-group-real-name group)
1022                                 (cdr active)
1023                                 (car active)))))))))))
1024
1025 (defun nnimap-update-infos (flags infos)
1026   (dolist (info infos)
1027     (let* ((group (gnus-group-real-name (gnus-info-group info)))
1028            (marks (cdr (assoc group flags))))
1029       (when marks
1030         (nnimap-update-info info marks)))))
1031
1032 (defun nnimap-update-info (info marks)
1033   (destructuring-bind (existing flags high low uidnext start-article
1034                                 permanent-flags uidvalidity
1035                                 vanished highestmodseq) marks
1036     (cond
1037      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1038      ;; completely empty groups.
1039      ((and (not existing)
1040            (not uidnext))
1041       )
1042      ;; We have a mismatch between the old and new UIDVALIDITY
1043      ;; identifiers, so we have to re-request the group info (the next
1044      ;; time).  This virtually never happens.
1045      ((let ((old-uidvalidity
1046              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1047         (and old-uidvalidity
1048              (not (equal old-uidvalidity uidvalidity))
1049              (> start-article 1)))
1050       (gnus-group-remove-parameter info 'uidvalidity)
1051       (gnus-group-remove-parameter info 'modseq))
1052      ;; We have the data needed to update.
1053      (t
1054       (let ((group (gnus-info-group info))
1055             (completep (and start-article
1056                             (= start-article 1))))
1057         (when uidnext
1058           (setq high (1- uidnext)))
1059         ;; First set the active ranges based on high/low.
1060         (if (or completep
1061                 (not (gnus-active group)))
1062             (gnus-set-active group
1063                              (cond
1064                               ((and low high)
1065                                (cons low high))
1066                               (uidnext
1067                                ;; No articles in this group.
1068                                (cons uidnext (1- uidnext)))
1069                               (start-article
1070                                (cons start-article (1- start-article)))
1071                               (t
1072                                ;; No articles and no uidnext.
1073                                nil)))
1074           (gnus-set-active
1075            group
1076            (cons (car (gnus-active group))
1077                  (or high (1- uidnext)))))
1078         ;; See whether this is a read-only group.
1079         (unless (eq permanent-flags 'not-scanned)
1080           (gnus-group-set-parameter
1081            info 'permanent-flags
1082            (if (memq '%* permanent-flags)
1083                t
1084              nil)))
1085         ;; Update marks and read articles if this isn't a
1086         ;; read-only IMAP group.
1087         (when (cdr (assq 'permanent-flags (gnus-info-params info)))
1088           (if (and highestmodseq
1089                    (not start-article))
1090               ;; We've gotten the data by QRESYNCing.
1091               (nnimap-update-qresync-info
1092                info (nnimap-imap-ranges-to-gnus-ranges vanished) flags)
1093             ;; Do normal non-QRESYNC flag updates.
1094             ;; Update the list of read articles.
1095             (let* ((unread
1096                     (gnus-compress-sequence
1097                      (gnus-set-difference
1098                       (gnus-set-difference
1099                        existing
1100                        (cdr (assoc '%Seen flags)))
1101                       (cdr (assoc '%Flagged flags)))))
1102                    (read (gnus-range-difference
1103                           (cons start-article high) unread)))
1104               (when (> start-article 1)
1105                 (setq read
1106                       (gnus-range-nconcat
1107                        (if (> start-article 1)
1108                            (gnus-sorted-range-intersection
1109                             (cons 1 (1- start-article))
1110                             (gnus-info-read info))
1111                          (gnus-info-read info))
1112                        read)))
1113               (gnus-info-set-read info read)
1114               ;; Update the marks.
1115               (setq marks (gnus-info-marks info))
1116               (dolist (type (cdr nnimap-mark-alist))
1117                 (let ((old-marks (assoc (car type) marks))
1118                       (new-marks
1119                        (gnus-compress-sequence
1120                         (cdr (or (assoc (caddr type) flags) ; %Flagged
1121                                  (assoc (intern (cadr type) obarray) flags)
1122                                  (assoc (cadr type) flags)))))) ; "\Flagged"
1123                   (setq marks (delq old-marks marks))
1124                   (pop old-marks)
1125                   (when (and old-marks
1126                              (> start-article 1))
1127                     (setq old-marks (gnus-range-difference
1128                                      old-marks
1129                                      (cons start-article high)))
1130                     (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1131                   (when new-marks
1132                     (push (cons (car type) new-marks) marks)))
1133                 (gnus-info-set-marks info marks t)))))
1134         ;; Note the active level for the next run-through.
1135         (gnus-group-set-parameter info 'active (gnus-active group))
1136         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1137         (gnus-group-set-parameter info 'modseq highestmodseq)
1138         (nnimap-store-info info (gnus-active group)))))))
1139
1140 (defun nnimap-update-qresync-info (info vanished flags)
1141   ;; Add all the vanished articles to the list of read articles.
1142   (gnus-info-set-read
1143    info
1144    (gnus-range-add (gnus-info-read info)
1145                    vanished))
1146   )
1147
1148 (defun nnimap-imap-ranges-to-gnus-ranges (irange)
1149   (if (zerop (length irange))
1150       nil
1151     (let ((result nil))
1152       (dolist (elem (split-string irange ","))
1153         (push
1154          (if (string-match ":" elem)
1155              (let ((numbers (split-string elem ":")))
1156                (cons (string-to-number (car numbers))
1157                      (string-to-number (cadr numbers))))
1158            (string-to-number elem))
1159          result))
1160       (nreverse result))))
1161
1162 (defun nnimap-store-info (info active)
1163   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1164          (entry (assoc group nnimap-current-infos)))
1165     (if entry
1166         (setcdr entry (list info active))
1167       (push (list group info active) nnimap-current-infos))))
1168
1169 (defun nnimap-flags-to-marks (groups)
1170   (let (data group totalp uidnext articles start-article mark permanent-flags
1171              uidvalidity vanished highestmodseq)
1172     (dolist (elem groups)
1173       (setq group (car elem)
1174             uidnext (nth 1 elem)
1175             start-article (nth 2 elem)
1176             permanent-flags (nth 3 elem)
1177             uidvalidity (nth 4 elem)
1178             vanished (nth 5 elem)
1179             highestmodseq (nth 6 elem)
1180             articles (nthcdr 7 elem))
1181       (let ((high (caar articles))
1182             marks low existing)
1183         (dolist (article articles)
1184           (setq low (car article))
1185           (push (car article) existing)
1186           (dolist (flag (cdr article))
1187             (setq mark (assoc flag marks))
1188             (if (not mark)
1189                 (push (list flag (car article)) marks)
1190               (setcdr mark (cons (car article) (cdr mark))))))
1191         (push (list group existing marks high low uidnext start-article
1192                     permanent-flags uidvalidity vanished highestmodseq)
1193               data)))
1194     data))
1195
1196 (defun nnimap-parse-flags (sequences)
1197   (goto-char (point-min))
1198   ;; Change \Delete etc to %Delete, so that the reader can read it.
1199   (subst-char-in-region (point-min) (point-max)
1200                         ?\\ ?% t)
1201   (let (start end articles groups uidnext elems permanent-flags
1202               uidvalidity vanished highestmodseq)
1203     (dolist (elem sequences)
1204       (destructuring-bind (group-sequence flag-sequence totalp group command)
1205           elem
1206         (setq start (point))
1207         (when (and
1208                ;; The EXAMINE was successful.
1209                (search-forward (format "\n%d OK " group-sequence) nil t)
1210                (progn
1211                  (forward-line 1)
1212                  (setq end (point))
1213                  (goto-char start)
1214                  (setq permanent-flags
1215                        (if (equal command "SELECT")
1216                            (and (search-forward "PERMANENTFLAGS "
1217                                                 (or end (point-min)) t)
1218                                 (read (current-buffer)))
1219                          'not-scanned))
1220                  (goto-char start)
1221                  (setq uidnext
1222                        (and (search-forward "UIDNEXT "
1223                                             (or end (point-min)) t)
1224                             (read (current-buffer))))
1225                  (goto-char start)
1226                  (setq uidvalidity
1227                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1228                                                (or end (point-min)) t)
1229                             ;; Store UIDVALIDITY as a string, as it's
1230                             ;; too big for 32-bit Emacsen, usually.
1231                             (match-string 1)))
1232                  (goto-char start)
1233                  (setq vanished
1234                        (and (eq flag-sequence 'qresync)
1235                             (re-search-forward "VANISHED.* \\([0-9:,]+\\)"
1236                                                (or end (point-min)) t)
1237                             (match-string 1)))
1238                  (goto-char start)
1239                  (setq highestmodseq
1240                        (and (search-forward "HIGHESTMODSEQ "
1241                                             (or end (point-min)) t)
1242                             (read (current-buffer))))
1243                  (goto-char end)
1244                  (forward-line -1))
1245                ;; The UID FETCH FLAGS was successful.
1246                (or (eq flag-sequence 'qresync)
1247                    (search-forward (format "\n%d OK " flag-sequence) nil t)))
1248           (if (eq flag-sequence 'qresync)
1249               (progn
1250                 (goto-char start)
1251                 (setq start end))
1252             (setq start (point))
1253             (goto-char end))
1254           (while (search-forward " FETCH " start t)
1255             (setq elems (read (current-buffer)))
1256             (push (cons (cadr (memq 'UID elems))
1257                         (cadr (memq 'FLAGS elems)))
1258                   articles))
1259           (push (nconc (list group uidnext totalp permanent-flags uidvalidity
1260                              vanished highestmodseq)
1261                        articles)
1262                 groups)
1263           (goto-char end)
1264           (setq articles nil))))
1265     groups))
1266
1267 (defun nnimap-find-process-buffer (buffer)
1268   (cadr (assoc buffer nnimap-connection-alist)))
1269
1270 (deffoo nnimap-request-post (&optional server)
1271   (setq nnimap-status-string "Read-only server")
1272   nil)
1273
1274 (defun nnimap-possibly-change-group (group server)
1275   (let ((open-result t))
1276     (when (and server
1277                (not (nnimap-server-opened server)))
1278       (setq open-result (nnimap-open-server server)))
1279     (cond
1280      ((not open-result)
1281       nil)
1282      ((not group)
1283       t)
1284      (t
1285       (with-current-buffer (nnimap-buffer)
1286         (if (equal group (nnimap-group nnimap-object))
1287             t
1288           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
1289             (when (car result)
1290               (setf (nnimap-group nnimap-object) group
1291                     (nnimap-select-result nnimap-object) result)
1292               result))))))))
1293
1294 (defun nnimap-find-connection (buffer)
1295   "Find the connection delivering to BUFFER."
1296   (let ((entry (assoc buffer nnimap-connection-alist)))
1297     (when entry
1298       (if (and (buffer-name (cadr entry))
1299                (get-buffer-process (cadr entry))
1300                (memq (process-status (get-buffer-process (cadr entry)))
1301                      '(open run)))
1302           (get-buffer-process (cadr entry))
1303         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1304         nil))))
1305
1306 (defvar nnimap-sequence 0)
1307
1308 (defun nnimap-send-command (&rest args)
1309   (process-send-string
1310    (get-buffer-process (current-buffer))
1311    (nnimap-log-command
1312     (format "%d %s%s\n"
1313             (incf nnimap-sequence)
1314             (apply #'format args)
1315             (if (nnimap-newlinep nnimap-object)
1316                 ""
1317               "\r"))))
1318   nnimap-sequence)
1319
1320 (defun nnimap-log-command (command)
1321   (with-current-buffer (get-buffer-create "*imap log*")
1322     (goto-char (point-max))
1323     (insert (format-time-string "%H:%M:%S") " " command))
1324   command)
1325
1326 (defun nnimap-command (&rest args)
1327   (erase-buffer)
1328   (setf (nnimap-last-command-time nnimap-object) (current-time))
1329   (let* ((sequence (apply #'nnimap-send-command args))
1330          (response (nnimap-get-response sequence)))
1331     (if (equal (caar response) "OK")
1332         (cons t response)
1333       (nnheader-report 'nnimap "%s"
1334                        (mapconcat (lambda (a)
1335                                     (format "%s" a))
1336                                   (car response) " "))
1337       nil)))
1338
1339 (defun nnimap-get-response (sequence)
1340   (nnimap-wait-for-response sequence)
1341   (nnimap-parse-response))
1342
1343 (defun nnimap-wait-for-connection ()
1344   (let ((process (get-buffer-process (current-buffer))))
1345     (goto-char (point-min))
1346     (while (and (memq (process-status process)
1347                       '(open run))
1348                 (not (re-search-forward "^[*.] .*\n" nil t)))
1349       (nnheader-accept-process-output process)
1350       (goto-char (point-min)))
1351     (forward-line -1)
1352     (and (looking-at "[*.] \\([A-Z0-9]+\\)")
1353          (match-string 1))))
1354
1355 (defun nnimap-wait-for-response (sequence &optional messagep)
1356   (let ((process (get-buffer-process (current-buffer)))
1357         openp)
1358     (condition-case nil
1359         (progn
1360           (goto-char (point-max))
1361           (while (and (setq openp (memq (process-status process)
1362                                         '(open run)))
1363                       (not (re-search-backward
1364                             (format "^%d .*\n" sequence)
1365                             (if nnimap-streaming
1366                                 (max (point-min) (- (point) 500))
1367                               (point-min))
1368                             t)))
1369             (when messagep
1370               (message "nnimap read %dk" (/ (buffer-size) 1000)))
1371             (nnheader-accept-process-output process)
1372             (goto-char (point-max)))
1373           openp)
1374       (quit
1375        ;; The user hit C-g while we were waiting: kill the process, in case
1376        ;; it's a gnutls-cli process that's stuck (tends to happen a lot behind
1377        ;; NAT routers).
1378        (delete-process process)
1379        nil))))
1380
1381 (defun nnimap-parse-response ()
1382   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1383         result)
1384     (dolist (line lines)
1385       (push (cdr (nnimap-parse-line line)) result))
1386     ;; Return the OK/error code first, and then all the "continuation
1387     ;; lines" afterwards.
1388     (cons (pop result)
1389           (nreverse result))))
1390
1391 ;; Parse an IMAP response line lightly.  They look like
1392 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1393 ;; the lines into a list of strings and lists of string.
1394 (defun nnimap-parse-line (line)
1395   (let (char result)
1396     (with-temp-buffer
1397       (insert line)
1398       (goto-char (point-min))
1399       (while (not (eobp))
1400         (if (eql (setq char (following-char)) ? )
1401             (forward-char 1)
1402           (push
1403            (cond
1404             ((eql char ?\[)
1405              (split-string
1406               (buffer-substring
1407                (1+ (point))
1408                (1- (search-forward "]" (line-end-position) 'move)))))
1409             ((eql char ?\()
1410              (split-string
1411               (buffer-substring
1412                (1+ (point))
1413                (1- (search-forward ")" (line-end-position) 'move)))))
1414             ((eql char ?\")
1415              (forward-char 1)
1416              (buffer-substring
1417               (point)
1418               (1- (or (search-forward "\"" (line-end-position) 'move)
1419                       (point)))))
1420             (t
1421              (buffer-substring (point) (if (search-forward " " nil t)
1422                                            (1- (point))
1423                                          (goto-char (point-max))))))
1424            result)))
1425       (nreverse result))))
1426
1427 (defun nnimap-last-response-string ()
1428   (save-excursion
1429     (forward-line 1)
1430     (let ((end (point)))
1431       (forward-line -1)
1432       (when (not (bobp))
1433         (forward-line -1)
1434         (while (and (not (bobp))
1435                     (eql (following-char) ?*))
1436           (forward-line -1))
1437         (unless (eql (following-char) ?*)
1438           (forward-line 1)))
1439       (buffer-substring (point) end))))
1440
1441 (defun nnimap-get-responses (sequences)
1442   (let (responses)
1443     (dolist (sequence sequences)
1444       (goto-char (point-min))
1445       (when (re-search-forward (format "^%d " sequence) nil t)
1446         (push (list sequence (nnimap-parse-response))
1447               responses)))
1448     responses))
1449
1450 (defvar nnimap-incoming-split-list nil)
1451
1452 (defun nnimap-fetch-inbox (articles)
1453   (erase-buffer)
1454   (nnimap-wait-for-response
1455    (nnimap-send-command
1456     "UID FETCH %s %s"
1457     (nnimap-article-ranges articles)
1458     (format "(UID %s%s)"
1459             (format
1460              (if (nnimap-ver4-p)
1461                  "BODY.PEEK[HEADER] BODY.PEEK"
1462                "RFC822.PEEK"))
1463             (if nnimap-split-download-body-default
1464                 "[]"
1465               "[1]")))
1466    t))
1467
1468 (defun nnimap-split-incoming-mail ()
1469   (with-current-buffer (nnimap-buffer)
1470     (let ((nnimap-incoming-split-list nil)
1471           (nnmail-split-methods (if (eq nnimap-split-methods 'default)
1472                                     nnmail-split-methods
1473                                   nnimap-split-methods))
1474           (nnmail-split-fancy (or nnimap-split-fancy
1475                                   nnmail-split-fancy))
1476           (nnmail-inhibit-default-split-group t)
1477           (groups (nnimap-get-groups))
1478           new-articles)
1479       (erase-buffer)
1480       (nnimap-command "SELECT %S" nnimap-inbox)
1481       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1482       (when new-articles
1483         (nnimap-fetch-inbox new-articles)
1484         (nnimap-transform-split-mail)
1485         (nnheader-ms-strip-cr)
1486         (nnmail-cache-open)
1487         (nnmail-split-incoming (current-buffer)
1488                                #'nnimap-save-mail-spec
1489                                nil nil
1490                                #'nnimap-dummy-active-number
1491                                #'nnimap-save-mail-spec)
1492         (when nnimap-incoming-split-list
1493           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1494                 sequences junk-articles)
1495             ;; Create any groups that doesn't already exist on the
1496             ;; server first.
1497             (dolist (spec specs)
1498               (when (and (not (member (car spec) groups))
1499                          (not (eq (car spec) 'junk)))
1500                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1501             ;; Then copy over all the messages.
1502             (erase-buffer)
1503             (dolist (spec specs)
1504               (let ((group (car spec))
1505                     (ranges (cdr spec)))
1506                 (if (eq group 'junk)
1507                     (setq junk-articles ranges)
1508                   (push (list (nnimap-send-command
1509                                "UID COPY %s %S"
1510                                (nnimap-article-ranges ranges)
1511                                (utf7-encode group t))
1512                               ranges)
1513                         sequences))))
1514             ;; Wait for the last COPY response...
1515             (when sequences
1516               (nnimap-wait-for-response (caar sequences))
1517               ;; And then mark the successful copy actions as deleted,
1518               ;; and possibly expunge them.
1519               (nnimap-mark-and-expunge-incoming
1520                (nnimap-parse-copied-articles sequences)))
1521             (nnimap-mark-and-expunge-incoming junk-articles)))))))
1522
1523 (defun nnimap-mark-and-expunge-incoming (range)
1524   (when range
1525     (setq range (nnimap-article-ranges range))
1526     (erase-buffer)
1527     (let ((sequence
1528            (nnimap-send-command
1529             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
1530       (cond
1531        ;; If the server supports it, we now delete the message we have
1532        ;; just copied over.
1533        ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
1534         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
1535        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1536        ;; user has configured it.
1537        (nnimap-expunge
1538         (setq sequence (nnimap-send-command "EXPUNGE"))))
1539       (nnimap-wait-for-response sequence))))
1540
1541 (defun nnimap-parse-copied-articles (sequences)
1542   (let (sequence copied range)
1543     (goto-char (point-min))
1544     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1545       (setq sequence (string-to-number (match-string 1)))
1546       (when (setq range (cadr (assq sequence sequences)))
1547         (push (gnus-uncompress-range range) copied)))
1548     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1549
1550 (defun nnimap-new-articles (flags)
1551   (let (new)
1552     (dolist (elem flags)
1553       (when (or (null (cdr elem))
1554                 (and (not (memq '%Deleted (cdr elem)))
1555                      (not (memq '%Seen (cdr elem)))))
1556         (push (car elem) new)))
1557     (gnus-compress-sequence (nreverse new))))
1558
1559 (defun nnimap-make-split-specs (list)
1560   (let ((specs nil)
1561         entry)
1562     (dolist (elem list)
1563       (destructuring-bind (article spec) elem
1564         (dolist (group (delete nil (mapcar #'car spec)))
1565           (unless (setq entry (assoc group specs))
1566             (push (setq entry (list group)) specs))
1567           (setcdr entry (cons article (cdr entry))))))
1568     (dolist (entry specs)
1569       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1570     specs))
1571
1572 (defun nnimap-transform-split-mail ()
1573   (goto-char (point-min))
1574   (let (article bytes)
1575     (block nil
1576       (while (not (eobp))
1577         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1578           (delete-region (point) (progn (forward-line 1) (point)))
1579           (when (eobp)
1580             (return)))
1581         (setq article (match-string 1)
1582               bytes (nnimap-get-length))
1583         (delete-region (line-beginning-position) (line-end-position))
1584         ;; Insert MMDF separator, and a way to remember what this
1585         ;; article UID is.
1586         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1587         (forward-char (1+ bytes))
1588         (setq bytes (nnimap-get-length))
1589         (delete-region (line-beginning-position) (line-end-position))
1590         (forward-char (1+ bytes))
1591         (delete-region (line-beginning-position) (line-end-position))))))
1592
1593 (defun nnimap-dummy-active-number (group &optional server)
1594   1)
1595
1596 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1597   (let (article)
1598     (goto-char (point-min))
1599     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1600         (error "Invalid nnimap mail")
1601       (setq article (string-to-number (match-string 1))))
1602     (push (list article
1603                 (if (eq group-art 'junk)
1604                     (list (cons 'junk 1))
1605                   group-art))
1606           nnimap-incoming-split-list)))
1607
1608 (provide 'nnimap)
1609
1610 ;;; nnimap.el ends here